src/game/g_console.pas

   1 (* Copyright (C)  Doom 2D: Forever Developers
   2  *
   3  * This program is free software: you can redistribute it and/or modify
   4  * it under the terms of the GNU General Public License as published by
   5  * the Free Software Foundation, version 3 of the License ONLY.
   6  *
   7  * This program is distributed in the hope that it will be useful,
   8  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   9  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  10  * GNU General Public License for more details.
  11  *
  12  * You should have received a copy of the GNU General Public License
  13  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  14  *)
  15 {$INCLUDE ../shared/a_modes.inc}
  16 unit g_console;
  17
  18 interface
  19
  20 uses
  21   utils; // for SSArray
  22
  23   const
  24     ACTION_JUMP = 0;
  25     ACTION_MOVELEFT = 1;
  26     ACTION_MOVERIGHT = 2;
  27     ACTION_LOOKDOWN = 3;
  28     ACTION_LOOKUP = 4;
  29     ACTION_ATTACK = 5;
  30     ACTION_SCORES = 6;
  31     ACTION_ACTIVATE = 7;
  32     ACTION_STRAFE = 8;
  33     ACTION_WEAPNEXT = 9;
  34     ACTION_WEAPPREV = 10;
  35
  36     FIRST_ACTION = ACTION_JUMP;
  37     LAST_ACTION = ACTION_WEAPPREV;
  38
  39 procedure g_Console_Init;
  40 procedure g_Console_SysInit;
  41 procedure g_Console_Update;
  42 procedure g_Console_Draw (MessagesOnly: Boolean = False);
  43 procedure g_Console_Char (C: AnsiChar);
  44 procedure g_Console_Control (K: Word);
  45 procedure g_Console_Process (L: AnsiString; quiet: Boolean=false);
  46 procedure g_Console_Add (L: AnsiString; show: Boolean=false);
  47 procedure g_Console_Clear;
  48 function  g_Console_CommandBlacklisted (C: AnsiString): Boolean;
  49 procedure g_Console_ReadConfig (filename: String);
  50 procedure g_Console_WriteConfig (filename: String);
  51 procedure g_Console_WriteGameConfig;
  52
  53 function  g_Console_Interactive: Boolean;
  54 function  g_Console_Action (action: Integer): Boolean;
  55 function  g_Console_MatchBind (key: Integer; down: AnsiString; up: AnsiString = ''): Boolean;
  56 function  g_Console_FindBind (n: Integer; down: AnsiString; up: AnsiString = ''): Integer;
  57 procedure g_Console_BindKey (key: Integer; down: AnsiString; up: AnsiString = '');
  58 procedure g_Console_ProcessBind (key: Integer; down: Boolean);
  59 procedure g_Console_ResetBinds;
  60
  61 procedure conwriteln (const s: AnsiString; show: Boolean=false);
  62 procedure conwritefln (const s: AnsiString; args: array of const; show: Boolean=false);
  63
  64 procedure conRegVar (const conname: AnsiString; pvar: PBoolean; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
  65 procedure conRegVar (const conname: AnsiString; pvar: PSingle; amin, amax: Single; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
  66 procedure conRegVar (const conname: AnsiString; pvar: PInteger; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
  67 procedure conRegVar (const conname: AnsiString; pvar: PWord; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
  68 procedure conRegVar (const conname: AnsiString; pvar: PCardinal; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
  69 procedure conRegVar (const conname: AnsiString; pvar: PAnsiString; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
  70
  71 // <0: no arg; 0/1: true/false
  72 function conGetBoolArg (p: SSArray; idx: Integer): Integer;
  73
  74 // poor man's floating literal parser; i'm sorry, but `StrToFloat()` sux cocks
  75 function conParseFloat (var res: Single; const s: AnsiString): Boolean;
  76
  77 const
  78   defaultConfigScript = 'dfconfig.cfg';
  79
  80 var
  81   gConsoleShow: Boolean = false; // True - êîíñîëü îòêðûòà èëè îòêðûâàåòñÿ
  82   gChatShow: Boolean = false;
  83   gChatTeam: Boolean = false;
  84   gAllowConsoleMessages: Boolean = true;
  85   gJustChatted: Boolean = false; // ÷òîáû àäìèí â èíòåðå ÷àòÿñü íå ïðîìàòûâàë ñòàòèñòèêó
  86   gParsingBinds: Boolean = true; // íå ïåðåñîõðàíÿòü êîíôèã âî âðåìÿ ïàðñèíãà
  87   gPlayerAction: Array [0..1, 0..LAST_ACTION] of Boolean; // [player, action]
  88   gConfigScript: string = defaultConfigScript;
  89
  90 implementation
  91
  92 uses
  93   g_textures, g_main, e_graphics, e_input, g_game, g_gfx, g_player, g_items,
  94   SysUtils, g_basic, g_options, Math, g_touch, e_res,
  95   g_menu, g_gui, g_language, g_net, g_netmsg, e_log, conbuf;
  96
  97 const
  98   autoexecScript = 'autoexec.cfg';
  99   configComment = 'generated by doom2d, do not modify';
 100
 101 type
 102   PCommand = ^TCommand;
 103
 104   TCmdProc = procedure (p: SSArray);
 105   TCmdProcEx = procedure (me: PCommand; p: SSArray);
 106
 107   TCommand = record
 108     cmd: AnsiString;
 109     proc: TCmdProc;
 110     procEx: TCmdProcEx;
 111     help: AnsiString;
 112     hidden: Boolean;
 113     ptr: Pointer; // various data
 114     msg: AnsiString; // message for var changes
 115     cheat: Boolean;
 116     action: Integer; // >= 0 for action commands
 117     player: Integer; // used for action commands
 118   end;
 119
 120   TAlias = record
 121     name: AnsiString;
 122     commands: SSArray;
 123   end;
 124
 125
 126 const
 127   MsgTime = 144;
 128   MaxScriptRecursion = 16;
 129
 130   DEBUG_STRING = 'DEBUG MODE';
 131
 132 var
 133   ID: DWORD;
 134   RecursionDepth: Word = 0;
 135   RecursionLimitHit: Boolean = False;
 136   Cons_Y: SmallInt;
 137   ConsoleHeight: Single;
 138   Cons_Shown: Boolean; // draw console
 139   InputReady: Boolean; // allow text input in console/chat
 140   Line: AnsiString;
 141   CPos: Word;
 142   //ConsoleHistory: SSArray;
 143   CommandHistory: SSArray;
 144   Whitelist: SSArray;
 145   commands: Array of TCommand = nil;
 146   Aliases: Array of TAlias = nil;
 147   CmdIndex: Word;
 148   conSkipLines: Integer = 0;
 149   MsgArray: Array [0..4] of record
 150                               Msg: AnsiString;
 151                               Time: Word;
 152                             end;
 153
 154   gInputBinds: Array [0..e_MaxInputKeys - 1] of record
 155     down, up: SSArray;
 156   end;
 157   menu_toggled: BOOLEAN; (* hack for menu controls *)
 158   ChatTop: BOOLEAN;
 159   ConsoleStep: Single;
 160   ConsoleTrans: Single;
 161
 162
 163 procedure g_Console_Switch;
 164 begin
 165   Cons_Y := Min(0, Max(Cons_Y, -Floor(gScreenHeight * ConsoleHeight)));
 166   if Cons_Shown = False then
 167     Cons_Y := -Floor(gScreenHeight * ConsoleHeight);
 168   gChatShow := False;
 169   gConsoleShow := not gConsoleShow;
 170   Cons_Shown := True;
 171   InputReady := False;
 172   g_Touch_ShowKeyboard(gConsoleShow or gChatShow);
 173 end;
 174
 175 procedure g_Console_Chat_Switch (Team: Boolean = False);
 176 begin
 177   if not g_Game_IsNet then Exit;
 178   Cons_Y := Min(0, Max(Cons_Y, -Floor(gScreenHeight * ConsoleHeight)));
 179   if Cons_Shown = False then
 180     Cons_Y := -Floor(gScreenHeight * ConsoleHeight);
 181   gConsoleShow := False;
 182   gChatShow := not gChatShow;
 183   gChatTeam := Team;
 184   Cons_Shown := True;
 185   InputReady := False;
 186   Line := '';
 187   CPos := 1;
 188   g_Touch_ShowKeyboard(gConsoleShow or gChatShow);
 189 end;
 190
 191 // poor man's floating literal parser; i'm sorry, but `StrToFloat()` sux cocks
 192 function conParseFloat (var res: Single; const s: AnsiString): Boolean;
 193 var
 194   pos: Integer = 1;
 195   frac: Single = 1;
 196   slen: Integer;
 197 begin
 198   result := false;
 199   res := 0;
 200   slen := Length(s);
 201   while (slen > 0) and (s[slen] <= ' ') do Dec(slen);
 202   while (pos <= slen) and (s[pos] <= ' ') do Inc(pos);
 203   if (pos > slen) then exit;
 204   if (slen-pos = 1) and (s[pos] = '.') then exit; // single dot
 205   // integral part
 206   while (pos <= slen) do
 207   begin
 208     if (s[pos] < '0') or (s[pos] > '9') then break;
 209     res := res*10+Byte(s[pos])-48;
 210     Inc(pos);
 211   end;
 212   if (pos <= slen) then
 213   begin
 214     // must be a dot
 215     if (s[pos] <> '.') then exit;
 216     Inc(pos);
 217     while (pos <= slen) do
 218     begin
 219       if (s[pos] < '0') or (s[pos] > '9') then break;
 220       frac := frac/10;
 221       res += frac*(Byte(s[pos])-48);
 222       Inc(pos);
 223     end;
 224   end;
 225   if (pos <= slen) then exit; // oops
 226   result := true;
 227 end;
 228
 229
 230 // ////////////////////////////////////////////////////////////////////////// //
 231 // <0: no arg; 0/1: true/false; 666: toggle
 232 function conGetBoolArg (p: SSArray; idx: Integer): Integer;
 233 begin
 234   if (idx < 0) or (idx > High(p)) then begin result := -1; exit; end;
 235   result := 0;
 236   if (p[idx] = '1') or (CompareText(p[idx], 'on') = 0) or (CompareText(p[idx], 'true') = 0) or
 237      (CompareText(p[idx], 'tan') = 0) or (CompareText(p[idx], 'yes') = 0) then result := 1
 238   else if (CompareText(p[idx], 'toggle') = 0) or (CompareText(p[idx], 'switch') = 0) or
 239           (CompareText(p[idx], 't') = 0) then result := 666;
 240 end;
 241
 242
 243 procedure boolVarHandler (me: PCommand; p: SSArray);
 244   procedure binaryFlag (var flag: Boolean; msg: AnsiString);
 245   var
 246     old: Boolean;
 247   begin
 248     if (Length(p) > 2) then
 249     begin
 250       conwritefln('too many arguments to ''%s''', [p[0]]);
 251     end
 252     else
 253     begin
 254       old := flag;
 255       case conGetBoolArg(p, 1) of
 256         -1: begin end;
 257          0: if not me.cheat or conIsCheatsEnabled then flag := false else begin conwriteln('not available'); exit; end;
 258          1: if not me.cheat or conIsCheatsEnabled then flag := true else begin conwriteln('not available'); exit; end;
 259          666: if not me.cheat or conIsCheatsEnabled then flag := not flag else begin conwriteln('not available'); exit; end;
 260       end;
 261       if flag <> old then
 262         g_Console_WriteGameConfig();
 263       if (Length(msg) = 0) then msg := p[0] else msg += ':';
 264       if flag then conwritefln('%s tan', [msg]) else conwritefln('%s ona', [msg]);
 265     end;
 266   end;
 267 begin
 268   binaryFlag(PBoolean(me.ptr)^, me.msg);
 269 end;
 270
 271
 272 procedure intVarHandler (me: PCommand; p: SSArray);
 273 var
 274   old: Integer;
 275 begin
 276   if (Length(p) <> 2) then
 277   begin
 278     conwritefln('%s %d', [me.cmd, PInteger(me.ptr)^]);
 279   end
 280   else
 281   begin
 282     try
 283       old := PInteger(me.ptr)^;
 284       PInteger(me.ptr)^ := StrToInt(p[1]);
 285       if PInteger(me.ptr)^ <> old then
 286         g_Console_WriteGameConfig();
 287     except
 288       conwritefln('invalid integer value: "%s"', [p[1]]);
 289     end;
 290   end;
 291 end;
 292
 293
 294 procedure wordVarHandler (me: PCommand; p: SSArray);
 295 var
 296   old: Integer;
 297 begin
 298   if (Length(p) <> 2) then
 299   begin
 300     conwritefln('%s %d', [me.cmd, PInteger(me.ptr)^]);
 301   end
 302   else
 303   begin
 304     try
 305       old := PWord(me.ptr)^;
 306       PWord(me.ptr)^ := min($FFFF, StrToDWord(p[1]));
 307       if PWord(me.ptr)^ <> old then
 308         g_Console_WriteGameConfig();
 309     except
 310       conwritefln('invalid word value: "%s"', [p[1]]);
 311     end;
 312   end;
 313 end;
 314
 315
 316 procedure dwordVarHandler (me: PCommand; p: SSArray);
 317 var
 318   old: Integer;
 319 begin
 320   if (Length(p) <> 2) then
 321   begin
 322     conwritefln('%s %d', [me.cmd, PInteger(me.ptr)^]);
 323   end
 324   else
 325   begin
 326     try
 327       old := PCardinal(me.ptr)^;
 328       PCardinal(me.ptr)^ := StrToDWord(p[1]);
 329       if PCardinal(me.ptr)^ <> old then
 330         g_Console_WriteGameConfig();
 331     except
 332       conwritefln('invalid dword value: "%s"', [p[1]]);
 333     end;
 334   end;
 335 end;
 336
 337
 338 procedure strVarHandler (me: PCommand; p: SSArray);
 339 var
 340   old: AnsiString;
 341 begin
 342   if (Length(p) <> 2) then
 343   begin
 344     conwritefln('%s %s', [me.cmd, QuoteStr(PAnsiString(me.ptr)^)]);
 345   end
 346   else
 347   begin
 348     old := PAnsiString(me.ptr)^;
 349     PAnsiString(me.ptr)^ := p[1];
 350     if PAnsiString(me.ptr)^ <> old then
 351       g_Console_WriteGameConfig();
 352   end;
 353 end;
 354
 355
 356 procedure conRegVar (const conname: AnsiString; pvar: PBoolean; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
 357 var
 358   f: Integer;
 359   cp: PCommand;
 360 begin
 361   f := Length(commands);
 362   SetLength(commands, f+1);
 363   cp := @commands[f];
 364   cp.cmd := LowerCase(conname);
 365   cp.proc := nil;
 366   cp.procEx := boolVarHandler;
 367   cp.help := ahelp;
 368   cp.hidden := ahidden;
 369   cp.ptr := pvar;
 370   cp.msg := amsg;
 371   cp.cheat := acheat;
 372   cp.action := -1;
 373   cp.player := -1;
 374 end;
 375
 376
 377 procedure conRegVar (const conname: AnsiString; pvar: PInteger; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
 378 var
 379   f: Integer;
 380   cp: PCommand;
 381 begin
 382   f := Length(commands);
 383   SetLength(commands, f+1);
 384   cp := @commands[f];
 385   cp.cmd := LowerCase(conname);
 386   cp.proc := nil;
 387   cp.procEx := intVarHandler;
 388   cp.help := ahelp;
 389   cp.hidden := ahidden;
 390   cp.ptr := pvar;
 391   cp.msg := amsg;
 392   cp.cheat := acheat;
 393   cp.action := -1;
 394   cp.player := -1;
 395 end;
 396
 397
 398 procedure conRegVar (const conname: AnsiString; pvar: PWord; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
 399 var
 400   f: Integer;
 401   cp: PCommand;
 402 begin
 403   f := Length(commands);
 404   SetLength(commands, f+1);
 405   cp := @commands[f];
 406   cp.cmd := LowerCase(conname);
 407   cp.proc := nil;
 408   cp.procEx := wordVarHandler;
 409   cp.help := ahelp;
 410   cp.hidden := ahidden;
 411   cp.ptr := pvar;
 412   cp.msg := amsg;
 413   cp.cheat := acheat;
 414   cp.action := -1;
 415   cp.player := -1;
 416 end;
 417
 418
 419 procedure conRegVar (const conname: AnsiString; pvar: PCardinal; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
 420 var
 421   f: Integer;
 422   cp: PCommand;
 423 begin
 424   f := Length(commands);
 425   SetLength(commands, f+1);
 426   cp := @commands[f];
 427   cp.cmd := LowerCase(conname);
 428   cp.proc := nil;
 429   cp.procEx := dwordVarHandler;
 430   cp.help := ahelp;
 431   cp.hidden := ahidden;
 432   cp.ptr := pvar;
 433   cp.msg := amsg;
 434   cp.cheat := acheat;
 435   cp.action := -1;
 436   cp.player := -1;
 437 end;
 438
 439
 440 procedure conRegVar (const conname: AnsiString; pvar: PAnsiString; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
 441 var
 442   f: Integer;
 443   cp: PCommand;
 444 begin
 445   f := Length(commands);
 446   SetLength(commands, f+1);
 447   cp := @commands[f];
 448   cp.cmd := LowerCase(conname);
 449   cp.proc := nil;
 450   cp.procEx := strVarHandler;
 451   cp.help := ahelp;
 452   cp.hidden := ahidden;
 453   cp.ptr := pvar;
 454   cp.msg := amsg;
 455   cp.cheat := acheat;
 456   cp.action := -1;
 457   cp.player := -1;
 458 end;
 459
 460 // ////////////////////////////////////////////////////////////////////////// //
 461 type
 462   PVarSingle = ^TVarSingle;
 463   TVarSingle = record
 464     val: PSingle;
 465     min, max, def: Single; // default will be starting value
 466   end;
 467
 468
 469 procedure singleVarHandler (me: PCommand; p: SSArray);
 470 var
 471   pv: PVarSingle;
 472   nv, old: Single;
 473   msg: AnsiString;
 474 begin
 475   if (Length(p) > 2) then
 476   begin
 477     conwritefln('too many arguments to ''%s''', [me.cmd]);
 478     exit;
 479   end;
 480   pv := PVarSingle(me.ptr);
 481   old := pv.val^;
 482   if (Length(p) = 2) then
 483   begin
 484     if me.cheat and (not conIsCheatsEnabled) then begin conwriteln('not available'); exit; end;
 485     if (CompareText(p[1], 'default') = 0) or (CompareText(p[1], 'def') = 0) or
 486        (CompareText(p[1], 'd') = 0) or (CompareText(p[1], 'off') = 0) or
 487        (CompareText(p[1], 'ona') = 0) then
 488     begin
 489       pv.val^ := pv.def;
 490     end
 491     else
 492     begin
 493       if not conParseFloat(nv, p[1]) then
 494       begin
 495         conwritefln('%s: ''%s'' doesn''t look like a floating number', [me.cmd, p[1]]);
 496         exit;
 497       end;
 498       if (nv < pv.min) then nv := pv.min;
 499       if (nv > pv.max) then nv := pv.max;
 500       pv.val^ := nv;
 501     end;
 502   end;
 503   if pv.val^ <> old then
 504     g_Console_WriteGameConfig();
 505   msg := me.msg;
 506   if (Length(msg) = 0) then msg := me.cmd else msg += ':';
 507   conwritefln('%s %s', [msg, pv.val^]);
 508 end;
 509
 510
 511 procedure conRegVar (const conname: AnsiString; pvar: PSingle; amin, amax: Single; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
 512 var
 513   f: Integer;
 514   cp: PCommand;
 515   pv: PVarSingle;
 516 begin
 517   GetMem(pv, sizeof(TVarSingle));
 518   pv.val := pvar;
 519   pv.min := amin;
 520   pv.max := amax;
 521   pv.def := pvar^;
 522   f := Length(commands);
 523   SetLength(commands, f+1);
 524   cp := @commands[f];
 525   cp.cmd := LowerCase(conname);
 526   cp.proc := nil;
 527   cp.procEx := singleVarHandler;
 528   cp.help := ahelp;
 529   cp.hidden := ahidden;
 530   cp.ptr := pv;
 531   cp.msg := amsg;
 532   cp.cheat := acheat;
 533   cp.action := -1;
 534   cp.player := -1;
 535 end;
 536
 537
 538 // ////////////////////////////////////////////////////////////////////////// //
 539 function GetStrACmd(var Str: AnsiString): AnsiString;
 540 var
 541   a: Integer;
 542 begin
 543   Result := '';
 544   for a := 1 to Length(Str) do
 545     if (a = Length(Str)) or (Str[a+1] = ';') then
 546     begin
 547       Result := Copy(Str, 1, a);
 548       Delete(Str, 1, a+1);
 549       Str := Trim(Str);
 550       Exit;
 551     end;
 552 end;
 553
 554 function ParseAlias(Str: AnsiString): SSArray;
 555 begin
 556   Result := nil;
 557
 558   Str := Trim(Str);
 559
 560   if Str = '' then
 561     Exit;
 562
 563   while Str <> '' do
 564   begin
 565     SetLength(Result, Length(Result)+1);
 566     Result[High(Result)] := GetStrACmd(Str);
 567   end;
 568 end;
 569
 570 procedure ConsoleCommands(p: SSArray);
 571 var
 572   cmd, s: AnsiString;
 573   a, b: Integer;
 574   (* F: TextFile; *)
 575 begin
 576   cmd := LowerCase(p[0]);
 577   s := '';
 578
 579   if cmd = 'clear' then
 580   begin
 581     //ConsoleHistory := nil;
 582     cbufClear();
 583     conSkipLines := 0;
 584
 585     for a := 0 to High(MsgArray) do
 586       with MsgArray[a] do
 587       begin
 588         Msg := '';
 589         Time := 0;
 590       end;
 591   end;
 592
 593   if cmd = 'clearhistory' then
 594     CommandHistory := nil;
 595
 596   if cmd = 'showhistory' then
 597     if CommandHistory <> nil then
 598     begin
 599       g_Console_Add('');
 600       for a := 0 to High(CommandHistory) do
 601         g_Console_Add('  '+CommandHistory[a]);
 602     end;
 603
 604   if cmd = 'commands' then
 605   begin
 606     g_Console_Add('');
 607     g_Console_Add('commands list:');
 608     for a := High(commands) downto 0 do
 609     begin
 610       if (Length(commands[a].help) > 0) then
 611       begin
 612         g_Console_Add('  '+commands[a].cmd+' -- '+commands[a].help);
 613       end
 614       else
 615       begin
 616         g_Console_Add('  '+commands[a].cmd);
 617       end;
 618     end;
 619   end;
 620
 621   if cmd = 'time' then
 622     g_Console_Add(TimeToStr(Now), True);
 623
 624   if cmd = 'date' then
 625     g_Console_Add(DateToStr(Now), True);
 626
 627   if cmd = 'echo' then
 628     if Length(p) > 1 then
 629       begin
 630         if p[1] = 'ololo' then
 631           gCheats := True
 632         else
 633         begin
 634           s := '';
 635           for a := 1 to High(p) do
 636             s := s + p[a] + ' ';
 637           g_Console_Add(b_Text_Format(s), True);
 638         end;
 639       end
 640     else
 641       g_Console_Add('');
 642
 643   if cmd = 'dump' then
 644   begin
 645     (*
 646     if ConsoleHistory <> nil then
 647     begin
 648       if Length(P) > 1 then
 649         s := P[1]
 650       else
 651         s := GameDir+'/console.txt';
 652
 653       {$I-}
 654       AssignFile(F, s);
 655       Rewrite(F);
 656       if IOResult <> 0 then
 657       begin
 658         g_Console_Add(Format(_lc[I_CONSOLE_ERROR_WRITE], [s]));
 659         CloseFile(F);
 660         Exit;
 661       end;
 662
 663       for a := 0 to High(ConsoleHistory) do
 664         WriteLn(F, ConsoleHistory[a]);
 665
 666       CloseFile(F);
 667       g_Console_Add(Format(_lc[I_CONSOLE_DUMPED], [s]));
 668       {$I+}
 669     end;
 670     *)
 671   end;
 672
 673   if cmd = 'exec' then
 674   begin
 675     // exec <filename>
 676     if Length(p) = 2 then
 677       g_Console_ReadConfig(p[1])
 678     else
 679       g_Console_Add('exec <script file>');
 680   end;
 681
 682   if cmd = 'writeconfig' then
 683   begin
 684     // writeconfig <filename>
 685     if Length(p) = 2 then
 686     begin
 687       s := e_GetWriteableDir(ConfigDirs);
 688       g_Console_WriteConfig(e_CatPath(s, p[1]))
 689     end
 690     else
 691     begin
 692       g_Console_Add('writeconfig <file>')
 693     end
 694   end;
 695
 696   if (cmd = 'ver') or (cmd = 'version') then
 697   begin
 698     conwriteln('Doom 2D: Forever v. ' + GAME_VERSION);
 699     conwritefln('Net protocol v. %d', [NET_PROTOCOL_VER]);
 700     conwritefln('Build date: %s at %s', [GAME_BUILDDATE, GAME_BUILDTIME]);
 701   end;
 702
 703   if cmd = 'alias' then
 704   begin
 705     // alias [alias_name] [commands]
 706     if Length(p) > 1 then
 707     begin
 708       for a := 0 to High(Aliases) do
 709         if Aliases[a].name = p[1] then
 710         begin
 711           if Length(p) > 2 then
 712             Aliases[a].commands := ParseAlias(p[2])
 713           else
 714             for b := 0 to High(Aliases[a].commands) do
 715               g_Console_Add(Aliases[a].commands[b]);
 716           Exit;
 717         end;
 718       SetLength(Aliases, Length(Aliases)+1);
 719       a := High(Aliases);
 720       Aliases[a].name := p[1];
 721       if Length(p) > 2 then
 722         Aliases[a].commands := ParseAlias(p[2])
 723       else
 724         for b := 0 to High(Aliases[a].commands) do
 725           g_Console_Add(Aliases[a].commands[b]);
 726     end else
 727       for a := 0 to High(Aliases) do
 728         if Aliases[a].commands <> nil then
 729           g_Console_Add(Aliases[a].name);
 730   end;
 731
 732   if cmd = 'call' then
 733   begin
 734     // call <alias_name>
 735     if Length(p) > 1 then
 736     begin
 737       if Aliases = nil then
 738         Exit;
 739       for a := 0 to High(Aliases) do
 740         if Aliases[a].name = p[1] then
 741         begin
 742           if Aliases[a].commands <> nil then
 743           begin
 744             // with this system proper endless loop detection seems either impossible
 745             // or very dirty to implement, so let's have this instead
 746             // prevents endless loops
 747             for b := 0 to High(Aliases[a].commands) do
 748             begin
 749               Inc(RecursionDepth);
 750               RecursionLimitHit := (RecursionDepth > MaxScriptRecursion) or RecursionLimitHit;
 751               if not RecursionLimitHit then
 752                 g_Console_Process(Aliases[a].commands[b], True);
 753               Dec(RecursionDepth);
 754             end;
 755             if (RecursionDepth = 0) and RecursionLimitHit then
 756             begin
 757               g_Console_Add(Format(_lc[I_CONSOLE_ERROR_CALL], [s]));
 758               RecursionLimitHit := False;
 759             end;
 760           end;
 761           Exit;
 762         end;
 763     end
 764     else
 765       g_Console_Add('call <alias name>');
 766   end;
 767 end;
 768
 769 procedure WhitelistCommand(cmd: AnsiString);
 770 var
 771   a: Integer;
 772 begin
 773   SetLength(Whitelist, Length(Whitelist)+1);
 774   a := High(Whitelist);
 775   Whitelist[a] := LowerCase(cmd);
 776 end;
 777
 778 procedure segfault (p: SSArray);
 779 var
 780   pp: PByte = nil;
 781 begin
 782   pp^ := 0;
 783 end;
 784
 785 function GetCommandString (p: SSArray): AnsiString;
 786   var i: Integer;
 787 begin
 788   result := '';
 789   if Length(p) >= 1 then
 790   begin
 791     result := p[0];
 792     for i := 1 to High(p) do
 793       result := result + '; ' + p[i]
 794   end
 795 end;
 796
 797 function QuoteStr(str: String): String;
 798 begin
 799   if Pos(' ', str) > 0 then
 800     Result := '"' + str + '"'
 801   else
 802     Result := str;
 803 end;
 804
 805 procedure BindCommands (p: SSArray);
 806   var cmd, key: AnsiString; i: Integer;
 807 begin
 808   cmd := LowerCase(p[0]);
 809   case cmd of
 810   'bind':
 811     // bind <key> [down [up]]
 812     if (Length(p) >= 2) and (Length(p) <= 4) then
 813     begin
 814       i := 0;
 815       key := LowerCase(p[1]);
 816       while (i < e_MaxInputKeys) and (key <> LowerCase(e_KeyNames[i])) do inc(i);
 817       if i < e_MaxInputKeys then
 818       begin
 819         if Length(p) = 2 then
 820           g_Console_Add(QuoteStr(e_KeyNames[i]) + ' = ' + QuoteStr(GetCommandString(gInputBinds[i].down)) + ' ' + QuoteStr(GetCommandString(gInputBinds[i].up)))
 821         else if Length(p) = 3 then
 822           g_Console_BindKey(i, p[2], '')
 823         else (* len = 4 *)
 824           g_Console_BindKey(i, p[2], p[3])
 825       end
 826       else
 827         g_Console_Add('bind: "' + p[1] + '" is not a key')
 828     end
 829     else
 830     begin
 831       g_Console_Add('bind <key> <down action> [up action]')
 832     end;
 833   'bindlist':
 834     for i := 0 to e_MaxInputKeys - 1 do
 835       if (gInputBinds[i].down <> nil) or (gInputBinds[i].up <> nil) then
 836         g_Console_Add(e_KeyNames[i] + ' ' + QuoteStr(GetCommandString(gInputBinds[i].down)) + ' ' + QuoteStr(GetCommandString(gInputBinds[i].up)));
 837   'unbind':
 838     // unbind <key>
 839     if Length(p) = 2 then
 840     begin
 841       key := LowerCase(p[1]);
 842       i := 0;
 843       while (i < e_MaxInputKeys) and (key <> LowerCase(e_KeyNames[i])) do inc(i);
 844       if i < e_MaxInputKeys then
 845         g_Console_BindKey(i, '')
 846       else
 847         g_Console_Add('unbind: "' + p[1] + '" is not a key')
 848     end
 849     else
 850       g_Console_Add('unbind <key>');
 851   'unbindall':
 852     for i := 0 to e_MaxInputKeys - 1 do
 853       g_Console_BindKey(i, '');
 854   'showkeyboard':
 855     g_Touch_ShowKeyboard(True);
 856   'hidekeyboard':
 857     g_Touch_ShowKeyboard(False);
 858   'togglemenu':
 859     begin
 860       if gConsoleShow then
 861         g_Console_Switch
 862       else if gChatShow then
 863         g_Console_Chat_Switch
 864       else
 865         KeyPress(VK_ESCAPE);
 866       menu_toggled := True
 867     end;
 868   'toggleconsole':
 869     g_Console_Switch;
 870   'togglechat':
 871     g_Console_Chat_Switch;
 872   'toggleteamchat':
 873     if gGameSettings.GameMode in [GM_TDM, GM_CTF] then
 874       g_Console_Chat_Switch(True);
 875   end
 876 end;
 877
 878 procedure AddCommand(cmd: AnsiString; proc: TCmdProc; ahelp: AnsiString=''; ahidden: Boolean=false; acheat: Boolean=false);
 879 var
 880   a: Integer;
 881   cp: PCommand;
 882 begin
 883   SetLength(commands, Length(commands)+1);
 884   a := High(commands);
 885   cp := @commands[a];
 886   cp.cmd := LowerCase(cmd);
 887   cp.proc := proc;
 888   cp.procEx := nil;
 889   cp.help := ahelp;
 890   cp.hidden := ahidden;
 891   cp.ptr := nil;
 892   cp.msg := '';
 893   cp.cheat := acheat;
 894   cp.action := -1;
 895   cp.player := -1;
 896 end;
 897
 898 procedure AddAction (cmd: AnsiString; action: Integer; help: AnsiString = ''; hidden: Boolean = False; cheat: Boolean = False);
 899   const
 900     PrefixList: array [0..1] of AnsiString = ('+', '-');
 901     PlayerList: array [0..1] of Integer = (1, 2);
 902   var
 903     s: AnsiString;
 904     i: Integer;
 905
 906   procedure NewAction (cmd: AnsiString; player: Integer);
 907     var cp: PCommand;
 908   begin
 909     SetLength(commands, Length(commands) + 1);
 910     cp := @commands[High(commands)];
 911     cp.cmd := LowerCase(cmd);
 912     cp.proc := nil;
 913     cp.procEx := nil;
 914     cp.help := help;
 915     cp.hidden := hidden;
 916     cp.ptr := nil;
 917     cp.msg := '';
 918     cp.cheat := cheat;
 919     cp.action := action;
 920     cp.player := player;
 921   end;
 922
 923 begin
 924   ASSERT(action >= FIRST_ACTION);
 925   ASSERT(action <= LAST_ACTION);
 926   for s in PrefixList do
 927   begin
 928     NewAction(s + cmd, 0);
 929     for i in PlayerList do
 930       NewAction(s + 'p' + IntToStr(i) + '_' + cmd, i - 1)
 931   end
 932 end;
 933
 934 procedure g_Console_SysInit;
 935   var a: Integer;
 936 begin
 937   Cons_Y := -Floor(gScreenHeight * ConsoleHeight);
 938   gConsoleShow := False;
 939   gChatShow := False;
 940   Cons_Shown := False;
 941   InputReady := False;
 942   CPos := 1;
 943
 944   for a := 0 to High(MsgArray) do
 945     with MsgArray[a] do
 946     begin
 947       Msg := '';
 948       Time := 0;
 949     end;
 950
 951   AddCommand('segfault', segfault, 'make segfault');
 952
 953   AddCommand('quit', SystemCommands);
 954   AddCommand('exit', SystemCommands);
 955   AddCommand('r_reset', SystemCommands);
 956   AddCommand('g_language', SystemCommands);
 957
 958   AddCommand('bind', BindCommands);
 959   AddCommand('bindlist', BindCommands);
 960   AddCommand('unbind', BindCommands);
 961   AddCommand('unbindall', BindCommands);
 962   AddCommand('showkeyboard', BindCommands);
 963   AddCommand('hidekeyboard', BindCommands);
 964   AddCommand('togglemenu', BindCommands);
 965   AddCommand('toggleconsole', BindCommands);
 966   AddCommand('togglechat', BindCommands);
 967   AddCommand('toggleteamchat', BindCommands);
 968
 969   AddCommand('clear', ConsoleCommands, 'clear console');
 970   AddCommand('clearhistory', ConsoleCommands);
 971   AddCommand('showhistory', ConsoleCommands);
 972   AddCommand('commands', ConsoleCommands);
 973   AddCommand('time', ConsoleCommands);
 974   AddCommand('date', ConsoleCommands);
 975   AddCommand('echo', ConsoleCommands);
 976   AddCommand('dump', ConsoleCommands);
 977   AddCommand('exec', ConsoleCommands);
 978   AddCommand('writeconfig', ConsoleCommands);
 979   AddCommand('alias', ConsoleCommands);
 980   AddCommand('call', ConsoleCommands);
 981   AddCommand('ver', ConsoleCommands);
 982   AddCommand('version', ConsoleCommands);
 983
 984   AddCommand('d_window', DebugCommands);
 985   AddCommand('d_sounds', DebugCommands);
 986   AddCommand('d_frames', DebugCommands);
 987   AddCommand('d_winmsg', DebugCommands);
 988   AddCommand('d_monoff', DebugCommands);
 989   AddCommand('d_botoff', DebugCommands);
 990   AddCommand('d_monster', DebugCommands);
 991   AddCommand('d_health', DebugCommands);
 992   AddCommand('d_player', DebugCommands);
 993   AddCommand('d_joy', DebugCommands);
 994   AddCommand('d_mem', DebugCommands);
 995
 996   AddCommand('p1_name', PlayerSettingsCVars);
 997   AddCommand('p2_name', PlayerSettingsCVars);
 998   AddCommand('p1_color', PlayerSettingsCVars);
 999   AddCommand('p2_color', PlayerSettingsCVars);
1000   AddCommand('p1_model', PlayerSettingsCVars);
1001   AddCommand('p2_model', PlayerSettingsCVars);
1002
1003   AddCommand('g_max_particles', GameCVars);
1004   AddCommand('g_max_shells', GameCVars);
1005   AddCommand('g_max_gibs', GameCVars);
1006   AddCommand('g_max_corpses', GameCVars);
1007   AddCommand('g_gamemode', GameCVars);
1008   AddCommand('g_friendlyfire', GameCVars);
1009   AddCommand('g_weaponstay', GameCVars);
1010   AddCommand('g_allow_exit', GameCVars);
1011   AddCommand('g_dm_keys', GameCVars);
1012   AddCommand('g_allow_monsters', GameCVars);
1013   AddCommand('g_bot_vsmonsters', GameCVars);
1014   AddCommand('g_bot_vsplayers', GameCVars);
1015   AddCommand('g_scorelimit', GameCVars);
1016   AddCommand('g_timelimit', GameCVars);
1017   AddCommand('g_maxlives', GameCVars);
1018   AddCommand('g_warmup_time', GameCVars);
1019   AddCommand('g_spawn_invul', GameCVars);
1020   AddCommand('g_item_respawn_time', GameCVars);
1021   AddCommand('sv_intertime', GameCVars);
1022
1023   AddCommand('sv_name', NetServerCVars);
1024   AddCommand('sv_passwd', NetServerCVars);
1025   AddCommand('sv_maxplrs', NetServerCVars);
1026   AddCommand('sv_public', NetServerCVars);
1027   AddCommand('sv_port', NetServerCVars);
1028
1029   AddCommand('pause', GameCommands);
1030   AddCommand('endgame', GameCommands);
1031   AddCommand('restart', GameCommands);
1032   AddCommand('addbot', GameCommands);
1033   AddCommand('bot_add', GameCommands);
1034   AddCommand('bot_addlist', GameCommands);
1035   AddCommand('bot_addred', GameCommands);
1036   AddCommand('bot_addblue', GameCommands);
1037   AddCommand('bot_removeall', GameCommands);
1038   AddCommand('chat', GameCommands);
1039   AddCommand('teamchat', GameCommands);
1040   AddCommand('game', GameCommands);
1041   AddCommand('host', GameCommands);
1042   AddCommand('map', GameCommands);
1043   AddCommand('nextmap', GameCommands);
1044   AddCommand('endmap', GameCommands);
1045   AddCommand('goodbye', GameCommands);
1046   AddCommand('suicide', GameCommands);
1047   AddCommand('spectate', GameCommands);
1048   AddCommand('ready', GameCommands);
1049   AddCommand('kick', GameCommands);
1050   AddCommand('kick_id', GameCommands);
1051   AddCommand('ban', GameCommands);
1052   AddCommand('permban', GameCommands);
1053   AddCommand('ban_id', GameCommands);
1054   AddCommand('permban_id', GameCommands);
1055   AddCommand('unban', GameCommands);
1056   AddCommand('connect', GameCommands);
1057   AddCommand('disconnect', GameCommands);
1058   AddCommand('reconnect', GameCommands);
1059   AddCommand('say', GameCommands);
1060   AddCommand('tell', GameCommands);
1061   AddCommand('centerprint', GameCommands);
1062   AddCommand('overtime', GameCommands);
1063   AddCommand('rcon_password', GameCommands);
1064   AddCommand('rcon', GameCommands);
1065   AddCommand('callvote', GameCommands);
1066   AddCommand('vote', GameCommands);
1067   AddCommand('clientlist', GameCommands);
1068   AddCommand('event', GameCommands);
1069   AddCommand('screenshot', GameCommands);
1070   AddCommand('weapon', GameCommands);
1071   AddCommand('p1_weapon', GameCommands);
1072   AddCommand('p2_weapon', GameCommands);
1073
1074   AddCommand('god', GameCheats);
1075   AddCommand('notarget', GameCheats);
1076   AddCommand('give', GameCheats); // "exit" too ;-)
1077   AddCommand('open', GameCheats);
1078   AddCommand('fly', GameCheats);
1079   AddCommand('noclip', GameCheats);
1080   AddCommand('speedy', GameCheats);
1081   AddCommand('jumpy', GameCheats);
1082   AddCommand('noreload', GameCheats);
1083   AddCommand('aimline', GameCheats);
1084   AddCommand('automap', GameCheats);
1085
1086   AddAction('jump', ACTION_JUMP);
1087   AddAction('moveleft', ACTION_MOVELEFT);
1088   AddAction('moveright', ACTION_MOVERIGHT);
1089   AddAction('lookup', ACTION_LOOKUP);
1090   AddAction('lookdown', ACTION_LOOKDOWN);
1091   AddAction('attack', ACTION_ATTACK);
1092   AddAction('scores', ACTION_SCORES);
1093   AddAction('activate', ACTION_ACTIVATE);
1094   AddAction('strafe', ACTION_STRAFE);
1095   AddAction('weapnext', ACTION_WEAPNEXT);
1096   AddAction('weapprev', ACTION_WEAPPREV);
1097
1098   WhitelistCommand('say');
1099   WhitelistCommand('tell');
1100   WhitelistCommand('overtime');
1101   WhitelistCommand('ready');
1102   WhitelistCommand('map');
1103   WhitelistCommand('nextmap');
1104   WhitelistCommand('endmap');
1105   WhitelistCommand('restart');
1106   WhitelistCommand('kick');
1107   WhitelistCommand('ban');
1108   WhitelistCommand('centerprint');
1109
1110   WhitelistCommand('addbot');
1111   WhitelistCommand('bot_add');
1112   WhitelistCommand('bot_addred');
1113   WhitelistCommand('bot_addblue');
1114   WhitelistCommand('bot_removeall');
1115
1116   WhitelistCommand('g_gamemode');
1117   WhitelistCommand('g_friendlyfire');
1118   WhitelistCommand('g_weaponstay');
1119   WhitelistCommand('g_allow_exit');
1120   WhitelistCommand('g_allow_monsters');
1121   WhitelistCommand('g_scorelimit');
1122   WhitelistCommand('g_timelimit');
1123   WhitelistCommand('g_dm_keys');
1124   WhitelistCommand('g_spawn_invul');
1125   WhitelistCommand('g_item_respawn_time');
1126   WhitelistCommand('g_warmup_time');
1127
1128   g_Console_ResetBinds;
1129   g_Console_ReadConfig(gConfigScript);
1130   g_Console_ReadConfig(autoexecScript);
1131   gParsingBinds := False;
1132 end;
1133
1134 procedure g_Console_Init;
1135 begin
1136   g_Texture_CreateWAD(ID, GameWAD+':TEXTURES\CONSOLE');
1137   g_Console_Add(Format(_lc[I_CONSOLE_WELCOME], [GAME_VERSION]));
1138   g_Console_Add('');
1139 end;
1140
1141 procedure g_Console_Update;
1142 var
1143   a, b, Step: Integer;
1144 begin
1145   if Cons_Shown then
1146   begin
1147     Step := Max(1, Round(Floor(gScreenHeight * ConsoleHeight) * ConsoleStep));
1148     if gConsoleShow then
1149     begin
1150       (* Open animation *)
1151       Cons_Y := Min(Cons_Y + Step, 0);
1152       InputReady := True
1153     end
1154     else
1155     begin
1156       (* Close animation *)
1157       Cons_Y := Max(Cons_Y - Step, -Floor(gScreenHeight * ConsoleHeight));
1158       Cons_Shown := Cons_Y > -Floor(gScreenHeight * ConsoleHeight);
1159       InputReady := False
1160     end;
1161
1162     if gChatShow then
1163       InputReady := True
1164   end;
1165
1166   a := 0;
1167   while a <= High(MsgArray) do
1168   begin
1169     if MsgArray[a].Time > 0 then
1170     begin
1171       if MsgArray[a].Time = 1 then
1172         begin
1173           if a < High(MsgArray) then
1174           begin
1175             for b := a to High(MsgArray)-1 do
1176               MsgArray[b] := MsgArray[b+1];
1177
1178             MsgArray[High(MsgArray)].Time := 0;
1179
1180             a := a - 1;
1181           end;
1182         end
1183       else
1184         Dec(MsgArray[a].Time);
1185     end;
1186
1187     a := a + 1;
1188   end;
1189 end;
1190
1191
1192 procedure drawConsoleText ();
1193 var
1194   CWidth, CHeight: Byte;
1195   ty: Integer;
1196   sp, ep: LongWord;
1197   skip: Integer;
1198
1199   procedure putLine (sp, ep: LongWord);
1200   var
1201     p: LongWord;
1202     wdt, cw: Integer;
1203   begin
1204     p := sp;
1205     wdt := 0;
1206     while p <> ep do
1207     begin
1208       cw := e_TextureFontCharWidth(cbufAt(p), gStdFont);
1209       if wdt+cw > gScreenWidth-8 then break;
1210       //e_TextureFontPrintChar(X, Y: Integer; Ch: Char; FontID: DWORD; Shadow: Boolean = False);
1211       Inc(wdt, cw);
1212       cbufNext(p);
1213     end;
1214     if p <> ep then putLine(p, ep); // do rest of the line first
1215     // now print our part
1216     if skip = 0 then
1217     begin
1218       ep := p;
1219       p := sp;
1220       wdt := 2;
1221       while p <> ep do
1222       begin
1223         cw := e_TextureFontCharWidth(cbufAt(p), gStdFont);
1224         e_TextureFontPrintCharEx(wdt, ty, cbufAt(p), gStdFont);
1225         Inc(wdt, cw);
1226         cbufNext(p);
1227       end;
1228       Dec(ty, CHeight);
1229     end
1230     else
1231     begin
1232       Dec(skip);
1233     end;
1234   end;
1235
1236 begin
1237   e_TextureFontGetSize(gStdFont, CWidth, CHeight);
1238   ty := Floor(gScreenHeight * ConsoleHeight) - 4 - 2 * CHeight - Abs(Cons_Y);
1239   skip := conSkipLines;
1240   cbufLastLine(sp, ep);
1241   repeat
1242     putLine(sp, ep);
1243     if ty+CHeight <= 0 then break;
1244   until not cbufLineUp(sp, ep);
1245 end;
1246
1247 procedure g_Console_Draw(MessagesOnly: Boolean = False);
1248 var
1249   CWidth, CHeight: Byte;
1250   mfW, mfH: Word;
1251   a, b, offset_y: Integer;
1252 begin
1253   e_TextureFontGetSize(gStdFont, CWidth, CHeight);
1254
1255   if ChatTop and gChatShow then
1256     offset_y := CHeight
1257   else
1258     offset_y := 0;
1259
1260   for a := 0 to High(MsgArray) do
1261     if MsgArray[a].Time > 0 then
1262       e_TextureFontPrintFmt(0, offset_y + CHeight * a, MsgArray[a].Msg, gStdFont, True);
1263
1264   if MessagesOnly then Exit;
1265
1266   if gChatShow then
1267   begin
1268     if ChatTop then
1269       offset_y := 0
1270     else
1271       offset_y := gScreenHeight - CHeight - 1;
1272     if gChatTeam then
1273     begin
1274       e_TextureFontPrintEx(0, offset_y, 'say team> ' + Line, gStdFont, 255, 255, 255, 1, True);
1275       e_TextureFontPrintEx((CPos + 9) * CWidth, offset_y, '_', gStdFont, 255, 255, 255, 1, True);
1276     end
1277     else
1278     begin
1279       e_TextureFontPrintEx(0, offset_y, 'say> ' + Line, gStdFont, 255, 255, 255, 1, True);
1280       e_TextureFontPrintEx((CPos + 4) * CWidth, offset_y, '_', gStdFont, 255, 255, 255, 1, True);
1281     end
1282   end;
1283
1284   if not Cons_Shown then
1285     Exit;
1286
1287   if gDebugMode then
1288   begin
1289     e_CharFont_GetSize(gMenuFont, DEBUG_STRING, mfW, mfH);
1290     a := (gScreenWidth - 2*mfW) div 2;
1291     b := Cons_Y + (Floor(gScreenHeight * ConsoleHeight) - 2 * mfH) div 2;
1292     e_CharFont_PrintEx(gMenuFont, a div 2, b div 2, DEBUG_STRING,
1293                        _RGB(128, 0, 0), 2.0);
1294   end;
1295
1296   e_DrawSize(ID, 0, Cons_Y, Round(ConsoleTrans * 255), False, False, gScreenWidth, Floor(gScreenHeight * ConsoleHeight));
1297   e_TextureFontPrint(0, Cons_Y + Floor(gScreenHeight * ConsoleHeight) - CHeight - 4, '> ' + Line, gStdFont);
1298
1299   drawConsoleText();
1300   (*
1301   if ConsoleHistory <> nil then
1302   begin
1303     b := 0;
1304     if CHeight > 0 then
1305       if Length(ConsoleHistory) > (Floor(gScreenHeight * ConsoleHeight) div CHeight) - 1 then
1306         b := Length(ConsoleHistory) - (Floor(gScreenHeight * ConsoleHeight) div CHeight) + 1;
1307
1308     b := Max(b-Offset, 0);
1309     d := Max(High(ConsoleHistory)-Offset, 0);
1310
1311     c := 2;
1312     for a := d downto b do
1313     begin
1314       e_TextureFontPrintFmt(0, Floor(gScreenHeight * ConsoleHeight) - 4 - c * CHeight - Abs(Cons_Y), ConsoleHistory[a], gStdFont, True);
1315       c := c + 1;
1316     end;
1317   end;
1318   *)
1319
1320   e_TextureFontPrint((CPos + 1) * CWidth, Cons_Y + Floor(gScreenHeight * ConsoleHeight) - 21, '_', gStdFont);
1321 end;
1322
1323 procedure g_Console_Char(C: AnsiChar);
1324 begin
1325   if InputReady and (gConsoleShow or gChatShow) then
1326   begin
1327     Insert(C, Line, CPos);
1328     CPos := CPos + 1;
1329   end
1330 end;
1331
1332
1333 var
1334   tcomplist: array of AnsiString = nil;
1335   tcompidx: array of Integer = nil;
1336
1337 procedure Complete ();
1338 var
1339   i, c: Integer;
1340   tused: Integer;
1341   ll, lpfx, cmd: AnsiString;
1342 begin
1343   if (Length(Line) = 0) then
1344   begin
1345     g_Console_Add('');
1346     for i := 0 to High(commands) do
1347     begin
1348       // hidden commands are hidden when cheats aren't enabled
1349       if commands[i].hidden and not conIsCheatsEnabled then continue;
1350       if (Length(commands[i].help) > 0) then
1351       begin
1352         g_Console_Add('  '+commands[i].cmd+' -- '+commands[i].help);
1353       end
1354       else
1355       begin
1356         g_Console_Add('  '+commands[i].cmd);
1357       end;
1358     end;
1359     exit;
1360   end;
1361
1362   ll := LowerCase(Line);
1363   lpfx := '';
1364
1365   if (Length(ll) > 1) and (ll[Length(ll)] = ' ') then
1366   begin
1367     ll := Copy(ll, 0, Length(ll)-1);
1368     for i := 0 to High(commands) do
1369     begin
1370       // hidden commands are hidden when cheats aren't enabled
1371       if commands[i].hidden and not conIsCheatsEnabled then continue;
1372       if (commands[i].cmd = ll) then
1373       begin
1374         if (Length(commands[i].help) > 0) then
1375         begin
1376           g_Console_Add('  '+commands[i].cmd+' -- '+commands[i].help);
1377         end;
1378       end;
1379     end;
1380     exit;
1381   end;
1382
1383   // build completion list
1384   tused := 0;
1385   for i := 0 to High(commands) do
1386   begin
1387     // hidden commands are hidden when cheats aren't enabled
1388     if commands[i].hidden and not conIsCheatsEnabled then continue;
1389     cmd := commands[i].cmd;
1390     if (Length(cmd) >= Length(ll)) and (ll = Copy(cmd, 0, Length(ll))) then
1391     begin
1392       if (tused = Length(tcomplist)) then
1393       begin
1394         SetLength(tcomplist, Length(tcomplist)+128);
1395         SetLength(tcompidx, Length(tcompidx)+128);
1396       end;
1397       tcomplist[tused] := cmd;
1398       tcompidx[tused] := i;
1399       Inc(tused);
1400       if (Length(cmd) > Length(lpfx)) then lpfx := cmd;
1401     end;
1402   end;
1403
1404   // get longest prefix
1405   for i := 0 to tused-1 do
1406   begin
1407     cmd := tcomplist[i];
1408     for c := 1 to Length(lpfx) do
1409     begin
1410       if (c > Length(cmd)) then break;
1411       if (cmd[c] <> lpfx[c]) then begin lpfx := Copy(lpfx, 0, c-1); break; end;
1412     end;
1413   end;
1414
1415   if (tused = 0) then exit;
1416
1417   if (tused = 1) then
1418   begin
1419     Line := tcomplist[0]+' ';
1420     CPos := Length(Line)+1;
1421   end
1422   else
1423   begin
1424     // has longest prefix?
1425     if (Length(lpfx) > Length(ll)) then
1426     begin
1427       Line := lpfx;
1428       CPos:= Length(Line)+1;
1429     end
1430     else
1431     begin
1432       g_Console_Add('');
1433       for i := 0 to tused-1 do
1434       begin
1435         if (Length(commands[tcompidx[i]].help) > 0) then
1436         begin
1437           g_Console_Add('  '+tcomplist[i]+' -- '+commands[tcompidx[i]].help);
1438         end
1439         else
1440         begin
1441           g_Console_Add('  '+tcomplist[i]);
1442         end;
1443       end;
1444     end;
1445   end;
1446 end;
1447
1448
1449 procedure g_Console_Control(K: Word);
1450 begin
1451   case K of
1452     IK_BACKSPACE:
1453       if (Length(Line) > 0) and (CPos > 1) then
1454       begin
1455         Delete(Line, CPos-1, 1);
1456         CPos := CPos-1;
1457       end;
1458     IK_DELETE:
1459       if (Length(Line) > 0) and (CPos <= Length(Line)) then
1460         Delete(Line, CPos, 1);
1461     IK_LEFT, IK_KPLEFT, VK_LEFT, JOY0_LEFT, JOY1_LEFT, JOY2_LEFT, JOY3_LEFT:
1462       if CPos > 1 then
1463         CPos := CPos - 1;
1464     IK_RIGHT, IK_KPRIGHT, VK_RIGHT, JOY0_RIGHT, JOY1_RIGHT, JOY2_RIGHT, JOY3_RIGHT:
1465       if CPos <= Length(Line) then
1466         CPos := CPos + 1;
1467     IK_RETURN, IK_KPRETURN, VK_OPEN, VK_FIRE, JOY0_ATTACK, JOY1_ATTACK, JOY2_ATTACK, JOY3_ATTACK:
1468     begin
1469       if gConsoleShow then
1470         g_Console_Process(Line)
1471       else
1472         if gChatShow then
1473         begin
1474           if (Length(Line) > 0) and g_Game_IsNet then
1475           begin
1476             if gChatTeam then
1477             begin
1478               if g_Game_IsClient then
1479                 MC_SEND_Chat(b_Text_Format(Line), NET_CHAT_TEAM)
1480               else
1481                 MH_SEND_Chat('[' + gPlayer1Settings.name + ']: ' + b_Text_Format(Line),
1482                   NET_CHAT_TEAM, gPlayer1Settings.Team);
1483             end
1484             else
1485             begin
1486               if g_Game_IsClient then
1487                 MC_SEND_Chat(b_Text_Format(Line), NET_CHAT_PLAYER)
1488               else
1489                 MH_SEND_Chat('[' + gPlayer1Settings.name + ']: ' + b_Text_Format(Line),
1490                 NET_CHAT_PLAYER);
1491             end;
1492           end;
1493
1494           Line := '';
1495           CPos := 1;
1496           gJustChatted := True;
1497           g_Console_Chat_Switch;
1498           InputReady := False;
1499         end;
1500     end;
1501     IK_TAB:
1502       if not gChatShow then
1503         Complete();
1504     IK_DOWN, IK_KPDOWN, VK_DOWN, JOY0_DOWN, JOY1_DOWN, JOY2_DOWN, JOY3_DOWN:
1505       if not gChatShow then
1506         if (CommandHistory <> nil) and
1507            (CmdIndex < Length(CommandHistory)) then
1508         begin
1509           if CmdIndex < Length(CommandHistory)-1 then
1510             CmdIndex := CmdIndex + 1;
1511           Line := CommandHistory[CmdIndex];
1512           CPos := Length(Line) + 1;
1513         end;
1514     IK_UP, IK_KPUP, VK_UP, JOY0_UP, JOY1_UP, JOY2_UP, JOY3_UP:
1515       if not gChatShow then
1516         if (CommandHistory <> nil) and
1517            (CmdIndex <= Length(CommandHistory)) then
1518         begin
1519           if CmdIndex > 0 then
1520             CmdIndex := CmdIndex - 1;
1521           Line := CommandHistory[CmdIndex];
1522           Cpos := Length(Line) + 1;
1523         end;
1524     IK_PAGEUP, IK_KPPAGEUP, VK_PREV, JOY0_PREV, JOY1_PREV, JOY2_PREV, JOY3_PREV: // PgUp
1525       if not gChatShow then Inc(conSkipLines);
1526     IK_PAGEDN, IK_KPPAGEDN, VK_NEXT, JOY0_NEXT, JOY1_NEXT, JOY2_NEXT, JOY3_NEXT: // PgDown
1527       if not gChatShow and (conSkipLines > 0) then Dec(conSkipLines);
1528     IK_HOME, IK_KPHOME:
1529       CPos := 1;
1530     IK_END, IK_KPEND:
1531       CPos := Length(Line) + 1;
1532     IK_A..IK_Z, IK_SPACE, IK_SHIFT, IK_RSHIFT, IK_CAPSLOCK, IK_LBRACKET, IK_RBRACKET,
1533     IK_SEMICOLON, IK_QUOTE, IK_BACKSLASH, IK_SLASH, IK_COMMA, IK_DOT, (*IK_EQUALS,*)
1534     IK_0, IK_1, IK_2, IK_3, IK_4, IK_5, IK_6, IK_7, IK_8, IK_9, IK_MINUS, IK_EQUALS:
1535       (* see TEXTINPUT event *)
1536   end
1537 end;
1538
1539 function GetStr(var Str: AnsiString): AnsiString;
1540 var
1541   a, b: Integer;
1542 begin
1543   Result := '';
1544   if Str[1] = '"' then
1545   begin
1546     for b := 1 to Length(Str) do
1547       if (b = Length(Str)) or (Str[b+1] = '"') then
1548       begin
1549         Result := Copy(Str, 2, b-1);
1550         Delete(Str, 1, b+1);
1551         Str := Trim(Str);
1552         Exit;
1553       end;
1554   end;
1555
1556   for a := 1 to Length(Str) do
1557     if (a = Length(Str)) or (Str[a+1] = ' ') then
1558     begin
1559       Result := Copy(Str, 1, a);
1560       Delete(Str, 1, a+1);
1561       Str := Trim(Str);
1562       Exit;
1563     end;
1564 end;
1565
1566 function ParseString(Str: AnsiString): SSArray;
1567 begin
1568   Result := nil;
1569
1570   Str := Trim(Str);
1571
1572   if Str = '' then
1573     Exit;
1574
1575   while Str <> '' do
1576   begin
1577     SetLength(Result, Length(Result)+1);
1578     Result[High(Result)] := GetStr(Str);
1579   end;
1580 end;
1581
1582 procedure g_Console_Add (L: AnsiString; show: Boolean=false);
1583
1584   procedure conmsg (s: AnsiString);
1585   var
1586     a: Integer;
1587   begin
1588     if length(s) = 0 then exit;
1589     for a := 0 to High(MsgArray) do
1590     begin
1591       with MsgArray[a] do
1592       begin
1593         if Time = 0 then
1594         begin
1595           Msg := s;
1596           Time := MsgTime;
1597           exit;
1598         end;
1599       end;
1600     end;
1601     for a := 0 to High(MsgArray)-1 do MsgArray[a] := MsgArray[a+1];
1602     with MsgArray[High(MsgArray)] do
1603     begin
1604       Msg := L;
1605       Time := MsgTime;
1606     end;
1607   end;
1608
1609 var
1610   f: Integer;
1611 begin
1612   // put it to console
1613   cbufPut(L);
1614   if (length(L) = 0) or ((L[length(L)] <> #10) and (L[length(L)] <> #13)) then cbufPut(#10);
1615
1616   // now show 'em out of console too
1617   show := show and gAllowConsoleMessages;
1618   if show and gShowMessages then
1619   begin
1620     // Âûâîä ñòðîê ñ ïåðåíîñàìè ïî î÷åðåäè
1621     while length(L) > 0 do
1622     begin
1623       f := Pos(#10, L);
1624       if f <= 0 then f := length(L)+1;
1625       conmsg(Copy(L, 1, f-1));
1626       Delete(L, 1, f);
1627     end;
1628   end;
1629
1630   //SetLength(ConsoleHistory, Length(ConsoleHistory)+1);
1631   //ConsoleHistory[High(ConsoleHistory)] := L;
1632
1633   (*
1634 {$IFDEF HEADLESS}
1635   e_WriteLog('CON: ' + L, MSG_NOTIFY);
1636 {$ENDIF}
1637   *)
1638 end;
1639
1640
1641 var
1642   consolewriterLastWasEOL: Boolean = false;
1643
1644 procedure consolewriter (constref buf; len: SizeUInt);
1645 var
1646   b: PByte;
1647 begin
1648   if (len < 1) then exit;
1649   b := PByte(@buf);
1650   consolewriterLastWasEOL := (b[len-1] = 13) or (b[len-1] = 10);
1651   while (len > 0) do
1652   begin
1653     if (b[0] <> 13) and (b[0] <> 10) then
1654     begin
1655       cbufPut(AnsiChar(b[0]));
1656     end
1657     else
1658     begin
1659       if (len > 1) and (b[0] = 13) then begin len -= 1; b += 1; end;
1660       cbufPut(#10);
1661     end;
1662     len -= 1;
1663     b += 1;
1664   end;
1665 end;
1666
1667
1668 // returns formatted string if `writerCB` is `nil`, empty string otherwise
1669 //function formatstrf (const fmt: AnsiString; args: array of const; writerCB: TFormatStrFCallback=nil): AnsiString;
1670 //TFormatStrFCallback = procedure (constref buf; len: SizeUInt);
1671 procedure conwriteln (const s: AnsiString; show: Boolean=false);
1672 begin
1673   g_Console_Add(s, show);
1674 end;
1675
1676
1677 procedure conwritefln (const s: AnsiString; args: array of const; show: Boolean=false);
1678 begin
1679   if show then
1680   begin
1681     g_Console_Add(formatstrf(s, args), true);
1682   end
1683   else
1684   begin
1685     consolewriterLastWasEOL := false;
1686     formatstrf(s, args, consolewriter);
1687     if not consolewriterLastWasEOL then cbufPut(#10);
1688   end;
1689 end;
1690
1691
1692 procedure g_Console_Clear();
1693 begin
1694   //ConsoleHistory := nil;
1695   cbufClear();
1696   conSkipLines := 0;
1697 end;
1698
1699 procedure AddToHistory(L: AnsiString);
1700 var
1701   len: Integer;
1702 begin
1703   len := Length(CommandHistory);
1704
1705   if (len = 0) or
1706      (LowerCase(CommandHistory[len-1]) <> LowerCase(L)) then
1707   begin
1708     SetLength(CommandHistory, len+1);
1709     CommandHistory[len] := L;
1710   end;
1711
1712   CmdIndex := Length(CommandHistory);
1713 end;
1714
1715 function g_Console_CommandBlacklisted(C: AnsiString): Boolean;
1716 var
1717   Arr: SSArray;
1718   i: Integer;
1719 begin
1720   Result := True;
1721
1722   Arr := nil;
1723
1724   if Trim(C) = '' then
1725     Exit;
1726
1727   Arr := ParseString(C);
1728   if Arr = nil then
1729     Exit;
1730
1731   for i := 0 to High(Whitelist) do
1732     if Whitelist[i] = LowerCase(Arr[0]) then
1733       Result := False;
1734 end;
1735
1736 procedure g_Console_Process(L: AnsiString; quiet: Boolean = False);
1737 var
1738   Arr: SSArray;
1739   i: Integer;
1740 begin
1741   Arr := nil;
1742
1743   if Trim(L) = '' then
1744     Exit;
1745
1746   conSkipLines := 0; // "unscroll"
1747
1748   if L = 'goobers' then
1749   begin
1750     Line := '';
1751     CPos := 1;
1752     gCheats := true;
1753     g_Console_Add('Your memory serves you well.');
1754     exit;
1755   end;
1756
1757   if not quiet then
1758   begin
1759     g_Console_Add('> '+L);
1760     Line := '';
1761     CPos := 1;
1762   end;
1763
1764   Arr := ParseString(L);
1765   if Arr = nil then
1766     Exit;
1767
1768   if commands = nil then
1769     Exit;
1770
1771   if not quiet then
1772     AddToHistory(L);
1773
1774   for i := 0 to High(commands) do
1775   begin
1776     if commands[i].cmd = LowerCase(Arr[0]) then
1777     begin
1778       if commands[i].action >= 0 then
1779       begin
1780         gPlayerAction[commands[i].player, commands[i].action] := commands[i].cmd[1] = '+';
1781         exit
1782       end;
1783       if assigned(commands[i].procEx) then
1784       begin
1785         commands[i].procEx(@commands[i], Arr);
1786         exit
1787       end;
1788       if assigned(commands[i].proc) then
1789       begin
1790         commands[i].proc(Arr);
1791         exit
1792       end
1793     end
1794   end;
1795
1796   g_Console_Add(Format(_lc[I_CONSOLE_UNKNOWN], [Arr[0]]));
1797 end;
1798
1799
1800 function g_Console_Interactive: Boolean;
1801 begin
1802   Result := gConsoleShow
1803 end;
1804
1805 procedure g_Console_BindKey (key: Integer; down: AnsiString; up: AnsiString = '');
1806 begin
1807   //e_LogWritefln('bind "%s" "%s" <%s>', [LowerCase(e_KeyNames[key]), cmd, key]);
1808   ASSERT(key >= 0);
1809   ASSERT(key < e_MaxInputKeys);
1810   if key > 0 then
1811   begin
1812     gInputBinds[key].down := ParseAlias(down);
1813     gInputBinds[key].up := ParseAlias(up);
1814   end;
1815   g_Console_WriteGameConfig();
1816 end;
1817
1818 function g_Console_MatchBind (key: Integer; down: AnsiString; up: AnsiString = ''): Boolean;
1819
1820   function EqualsCommandLists (a, b: SSArray): Boolean;
1821     var i, len: Integer;
1822   begin
1823     result := False;
1824     len := Length(a);
1825     if len = Length(b) then
1826     begin
1827       i := 0;
1828       while (i < len) and (a[i] = b[i]) do inc(i);
1829       if i >= len then
1830         result := True
1831     end
1832   end;
1833
1834 begin
1835   ASSERT(key >= 0);
1836   ASSERT(key < e_MaxInputKeys);
1837   result := EqualsCommandLists(ParseAlias(down), gInputBinds[key].down) and EqualsCommandLists(ParseAlias(up), gInputBinds[key].up)
1838 end;
1839
1840 function g_Console_FindBind (n: Integer; down: AnsiString; up: AnsiString = ''): Integer;
1841   var i: Integer;
1842 begin
1843   ASSERT(n >= 1);
1844   result := 0;
1845   if commands = nil then Exit;
1846   i := 0;
1847   while (n >= 1) and (i < e_MaxInputKeys) do
1848   begin
1849     if g_Console_MatchBind(i, down, up) then
1850     begin
1851       result := i;
1852       dec(n)
1853     end;
1854     inc(i)
1855   end;
1856   if n >= 1 then
1857     result := 0
1858 end;
1859
1860 function g_Console_Action (action: Integer): Boolean;
1861   var i, len: Integer;
1862 begin
1863   ASSERT(action >= FIRST_ACTION);
1864   ASSERT(action <= LAST_ACTION);
1865   i := 0;
1866   len := Length(gPlayerAction);
1867   while (i < len) and (not gPlayerAction[i, action]) do inc(i);
1868   Result := i < len
1869 end;
1870
1871 function BindsAllowed (key: Integer): Boolean;
1872 begin
1873   Result := False;
1874   if (not g_GUIGrabInput) and (key >= 0) and (key < e_MaxInputKeys) and ((gInputBinds[key].down <> nil) or (gInputBinds[key].up <> nil)) then
1875   begin
1876     if gChatShow then
1877       Result := g_Console_MatchBind(key, 'togglemenu') or
1878                 g_Console_MatchBind(key, 'showkeyboard') or
1879                 g_Console_MatchBind(key, 'hidekeyboard')
1880     else if gConsoleShow or (g_ActiveWindow <> nil) or (gGameSettings.GameType = GT_NONE) then
1881       Result := g_Console_MatchBind(key, 'togglemenu') or
1882                 g_Console_MatchBind(key, 'toggleconsole') or
1883                 g_Console_MatchBind(key, 'showkeyboard') or
1884                 g_Console_MatchBind(key, 'hidekeyboard')
1885     else (* in game *)
1886       Result := True
1887   end
1888 end;
1889
1890 procedure g_Console_ProcessBind (key: Integer; down: Boolean);
1891   var i: Integer;
1892 begin
1893   if BindsAllowed(key) then
1894   begin
1895     if down then
1896       for i := 0 to High(gInputBinds[key].down) do
1897         g_Console_Process(gInputBinds[key].down[i], True)
1898     else
1899       for i := 0 to High(gInputBinds[key].up) do
1900         g_Console_Process(gInputBinds[key].up[i], True)
1901   end;
1902   if down and not menu_toggled then
1903     KeyPress(key);
1904   menu_toggled := False
1905 end;
1906
1907 procedure g_Console_ResetBinds;
1908   var i: Integer;
1909 begin
1910   for i := 0 to e_MaxInputKeys - 1 do
1911     g_Console_BindKey(i, '', '');
1912
1913   g_Console_BindKey(IK_GRAVE, 'toggleconsole');
1914   g_Console_BindKey(IK_ESCAPE, 'togglemenu');
1915   g_Console_BindKey(IK_A, '+p1_moveleft', '-p1_moveleft');
1916   g_Console_BindKey(IK_D, '+p1_moveright', '-p1_moveright');
1917   g_Console_BindKey(IK_W, '+p1_lookup', '-p1_lookup');
1918   g_Console_BindKey(IK_S, '+p1_lookdown', '-p1_lookdown');
1919   g_Console_BindKey(IK_SPACE, '+p1_jump', '-p1_jump');
1920   g_Console_BindKey(IK_H, '+p1_attack', '-p1_attack');
1921   g_Console_BindKey(IK_J, '+p1_activate', '-p1_activate');
1922   g_Console_BindKey(IK_E, '+p1_weapnext', '-p1_weapnext');
1923   g_Console_BindKey(IK_Q, '+p1_weapprev', '-p1_weapprev');
1924   g_Console_BindKey(IK_ALT, '+p1_strafe', '-p1_strafe');
1925   g_Console_BindKey(IK_1, 'p1_weapon 1');
1926   g_Console_BindKey(IK_2, 'p1_weapon 2');
1927   g_Console_BindKey(IK_3, 'p1_weapon 3');
1928   g_Console_BindKey(IK_4, 'p1_weapon 4');
1929   g_Console_BindKey(IK_5, 'p1_weapon 5');
1930   g_Console_BindKey(IK_6, 'p1_weapon 6');
1931   g_Console_BindKey(IK_7, 'p1_weapon 7');
1932   g_Console_BindKey(IK_8, 'p1_weapon 8');
1933   g_Console_BindKey(IK_9, 'p1_weapon 9');
1934   g_Console_BindKey(IK_0, 'p1_weapon 10');
1935   g_Console_BindKey(IK_MINUS, 'p1_weapon 11');
1936   g_Console_BindKey(IK_T, 'togglechat');
1937   g_Console_BindKey(IK_Y, 'toggleteamchat');
1938   g_Console_BindKey(IK_F11, 'screenshot');
1939   g_Console_BindKey(IK_TAB, '+p1_scores', '-p1_scores');
1940   g_Console_BindKey(IK_PAUSE, 'pause');
1941   g_Console_BindKey(IK_F1, 'vote');
1942
1943   (* for i := 0 to e_MaxJoys - 1 do *)
1944   for i := 0 to 1 do
1945   begin
1946     g_Console_BindKey(e_JoyHatToKey(i, 0, HAT_LEFT), '+p' + IntToStr(i mod 2 + 1) + '_moveleft', '-p' + IntToStr(i mod 2 + 1) + '_moveleft');
1947     g_Console_BindKey(e_JoyHatToKey(i, 0, HAT_RIGHT), '+p' + IntToStr(i mod 2 + 1) + '_moveright', '-p' + IntToStr(i mod 2 + 1) + '_moveright');
1948     g_Console_BindKey(e_JoyHatToKey(i, 0, HAT_UP), '+p' + IntToStr(i mod 2 + 1) + '_lookup', '-p' + IntToStr(i mod 2 + 1) + '_lookup');
1949     g_Console_BindKey(e_JoyHatToKey(i, 0, HAT_DOWN), '+p' + IntToStr(i mod 2 + 1) + '_lookdown', '-p' + IntToStr(i mod 2 + 1) + '_lookdown');
1950     g_Console_BindKey(e_JoyButtonToKey(i, 2), '+p' + IntToStr(i mod 2 + 1) + '_jump', '-p' + IntToStr(i mod 2 + 1) + '_jump');
1951     g_Console_BindKey(e_JoyButtonToKey(i, 0), '+p' + IntToStr(i mod 2 + 1) + '_attack', '-p' + IntToStr(i mod 2 + 1) + '_attack');
1952     g_Console_BindKey(e_JoyButtonToKey(i, 3), '+p' + IntToStr(i mod 2 + 1) + '_activate', '-p' + IntToStr(i mod 2 + 1) + '_activate');
1953     g_Console_BindKey(e_JoyButtonToKey(i, 1), '+p' + IntToStr(i mod 2 + 1) + '_weapnext', '-p' + IntToStr(i mod 2 + 1) + '_weapnext');
1954     g_Console_BindKey(e_JoyButtonToKey(i, 4), '+p' + IntToStr(i mod 2 + 1) + '_weapprev', '-p' + IntToStr(i mod 2 + 1) + '_weapprev');
1955     g_Console_BindKey(e_JoyButtonToKey(i, 7), '+p' + IntToStr(i mod 2 + 1) + '_strafe', '-p' + IntToStr(i mod 2 + 1) + '_strafe');
1956     g_Console_BindKey(e_JoyButtonToKey(i, 10), 'togglemenu');
1957   end;
1958
1959   g_Console_BindKey(VK_ESCAPE, 'togglemenu');
1960   g_Console_BindKey(VK_LSTRAFE, '+moveleft; +strafe', '-moveleft; -strafe');
1961   g_Console_BindKey(VK_RSTRAFE, '+moveright; +strafe', '-moveright; -strafe');
1962   g_Console_BindKey(VK_LEFT, '+moveleft', '-moveleft');
1963   g_Console_BindKey(VK_RIGHT, '+moveright', '-moveright');
1964   g_Console_BindKey(VK_UP, '+lookup', '-lookup');
1965   g_Console_BindKey(VK_DOWN, '+lookdown', '-lookdown');
1966   g_Console_BindKey(VK_JUMP, '+jump', '-jump');
1967   g_Console_BindKey(VK_FIRE, '+attack', '-attack');
1968   g_Console_BindKey(VK_OPEN, '+activate', '-activate');
1969   g_Console_BindKey(VK_NEXT, '+weapnext', '-weapnext');
1970   g_Console_BindKey(VK_PREV, '+weapprev', '-weapprev');
1971   g_Console_BindKey(VK_STRAFE, '+strafe', '-strafe');
1972   g_Console_BindKey(VK_0, 'weapon 1');
1973   g_Console_BindKey(VK_1, 'weapon 2');
1974   g_Console_BindKey(VK_2, 'weapon 3');
1975   g_Console_BindKey(VK_3, 'weapon 4');
1976   g_Console_BindKey(VK_4, 'weapon 5');
1977   g_Console_BindKey(VK_5, 'weapon 6');
1978   g_Console_BindKey(VK_6, 'weapon 7');
1979   g_Console_BindKey(VK_7, 'weapon 8');
1980   g_Console_BindKey(VK_8, 'weapon 9');
1981   g_Console_BindKey(VK_9, 'weapon 10');
1982   g_Console_BindKey(VK_A, 'weapon 11');
1983   g_Console_BindKey(VK_CHAT, 'togglechat');
1984   g_Console_BindKey(VK_TEAM, 'toggleteamchat');
1985   g_Console_BindKey(VK_CONSOLE, 'toggleconsole');
1986   g_Console_BindKey(VK_PRINTSCR, 'screenshot');
1987   g_Console_BindKey(VK_STATUS, '+scores', '-scores');
1988   g_Console_BindKey(VK_SHOWKBD, 'showkeyboard');
1989   g_Console_BindKey(VK_HIDEKBD, 'hidekeyboard');
1990 end;
1991
1992 procedure g_Console_ReadConfig (filename: String);
1993   var f: TextFile; s: AnsiString; i, len: Integer;
1994 begin
1995   e_LogWritefln('g_Console_ReadConfig (1) "%s"', [filename]);
1996   if e_FindResource(ConfigDirs, filename, false) = true then
1997   begin
1998     e_LogWritefln('g_Console_ReadConfig (2) "%s"', [filename]);
1999     AssignFile(f, filename);
2000     Reset(f);
2001     while not EOF(f) do
2002     begin
2003       ReadLn(f, s);
2004       len := Length(s);
2005       if len > 0 then
2006       begin
2007         i := 1;
2008         (* skip spaces *)
2009         while (i <= len) and (s[i] <= ' ') do inc(i);
2010         (* skip comments *)
2011         if (i <= len) and ((s[i] <> '#') and ((i + 1 > len) or (s[i] <> '/') or (s[i + 1] <> '/'))) then
2012           g_Console_Process(s, True);
2013       end
2014     end;
2015     CloseFile(f);
2016   end
2017 end;
2018
2019 procedure g_Console_WriteConfig (filename: String);
2020   var f: TextFile; i, j: Integer;
2021
2022   procedure WriteFlag(name: string; flag: LongWord);
2023   begin
2024     WriteLn(f, name, IfThen(LongBool(gsGameFlags and flag), 1, 0));
2025   end;
2026
2027 begin
2028   AssignFile(f, filename);
2029   Rewrite(f);
2030   WriteLn(f, '// ' + configComment);
2031
2032   // binds
2033   WriteLn(f, 'unbindall');
2034   for i := 0 to e_MaxInputKeys - 1 do
2035     if (Length(gInputBinds[i].down) > 0) or (Length(gInputBinds[i].up) > 0) then
2036     begin
2037       Write(f, 'bind ', e_KeyNames[i], ' ', QuoteStr(GetCommandString(gInputBinds[i].down)));
2038       if Length(gInputBinds[i].down) = 0 then
2039         Write(f, '""');
2040       if Length(gInputBinds[i].up) > 0 then
2041         Write(f, ' ', QuoteStr(GetCommandString(gInputBinds[i].up)));
2042       WriteLn(f, '');
2043     end;
2044
2045   // lang
2046   if gAskLanguage then
2047     WriteLn(f, 'g_language ask')
2048   else
2049     WriteLn(f, 'g_language ', gLanguage);
2050
2051   // net server
2052   WriteLn(f, 'sv_name ', QuoteStr(NetServerName));
2053   WriteLn(f, 'sv_passwd ', QuoteStr(NetPassword));
2054   WriteLn(f, 'sv_maxplrs ', NetMaxClients);
2055   WriteLn(f, 'sv_port ', NetPort);
2056   WriteLn(f, 'sv_public ', IfThen(NetUseMaster, 1, 0));
2057
2058   // game settings
2059   WriteLn(f, 'g_max_particles ', g_GFX_GetMax());
2060   WriteLn(f, 'g_max_shells ', g_Shells_GetMax());
2061   WriteLn(f, 'g_max_gibs ', g_Gibs_GetMax());
2062   WriteLn(f, 'g_max_corpses ', g_Corpses_GetMax());
2063   WriteLn(f, 'sv_intertime ', gDefInterTime);
2064
2065   // gameplay settings
2066   WriteLn(f, 'g_gamemode ', gsGameMode);
2067   WriteLn(f, 'g_scorelimit ', gsGoalLimit);
2068   WriteLn(f, 'g_timelimit ', gsTimeLimit);
2069   WriteLn(f, 'g_maxlives ', gsMaxLives);
2070   WriteLn(f, 'g_item_respawn_time ', gsItemRespawnTime);
2071   WriteLn(f, 'g_spawn_invul ', gsSpawnInvul);
2072   WriteLn(f, 'g_warmup_time ', gsWarmupTime);
2073
2074   WriteFlag('g_friendlyfire ', GAME_OPTION_TEAMDAMAGE);
2075   WriteFlag('g_allow_exit ', GAME_OPTION_ALLOWEXIT);
2076   WriteFlag('g_allow_monsters ', GAME_OPTION_MONSTERS);
2077   WriteFlag('g_dm_keys ', GAME_OPTION_DMKEYS);
2078   WriteFlag('g_weaponstay ', GAME_OPTION_WEAPONSTAY);
2079   WriteFlag('g_bot_vsmonsters ', GAME_OPTION_BOTVSMONSTER);
2080   WriteFlag('g_bot_vsplayers ', GAME_OPTION_BOTVSPLAYER);
2081
2082   // players
2083   with gPlayer1Settings do
2084   begin
2085     WriteLn(f, 'p1_name ', QuoteStr(Name));
2086     WriteLn(f, 'p1_color ', Color.R, ' ', Color.G, ' ', Color.B);
2087     WriteLn(f, 'p1_model ', QuoteStr(Model));
2088   end;
2089   with gPlayer2Settings do
2090   begin
2091     WriteLn(f, 'p2_name ', QuoteStr(Name));
2092     WriteLn(f, 'p2_color ', Color.R, ' ', Color.G, ' ', Color.B);
2093     WriteLn(f, 'p2_model ', QuoteStr(Model));
2094   end;
2095
2096   // all cvars
2097   for i := 0 to High(commands) do
2098   begin
2099     if not commands[i].cheat then
2100     begin
2101       if @commands[i].procEx = @boolVarHandler then
2102       begin
2103         if PBoolean(commands[i].ptr)^ then j := 1 else j := 0;
2104         WriteLn(f, commands[i].cmd, ' ', j)
2105       end
2106       else if @commands[i].procEx = @intVarHandler then
2107       begin
2108         WriteLn(f, commands[i].cmd, ' ', PInteger(commands[i].ptr)^)
2109       end
2110       else if @commands[i].procEx = @wordVarHandler then
2111       begin
2112         WriteLn(f, commands[i].cmd, ' ', PWord(commands[i].ptr)^)
2113       end
2114       else if @commands[i].procEx = @dwordVarHandler then
2115       begin
2116         WriteLn(f, commands[i].cmd, ' ', PCardinal(commands[i].ptr)^)
2117       end
2118       else if @commands[i].procEx = @singleVarHandler then
2119       begin
2120         WriteLn(f, commands[i].cmd, ' ', PVarSingle(commands[i].ptr).val^:0:6)
2121       end
2122       else if @commands[i].procEx = @strVarHandler then
2123       begin
2124         if Length(PAnsiString(commands[i].ptr)^) = 0 then
2125           WriteLn(f, commands[i].cmd, ' ""')
2126         else
2127           WriteLn(f, commands[i].cmd, ' ', QuoteStr(PAnsiString(commands[i].ptr)^))
2128       end
2129     end
2130   end;
2131
2132   WriteLn(f, 'r_reset');
2133   CloseFile(f)
2134 end;
2135
2136 procedure g_Console_WriteGameConfig;
2137   var s: AnsiString;
2138 begin
2139   if gParsingBinds = false then
2140   begin
2141     s := e_GetWriteableDir(ConfigDirs);
2142     g_Console_WriteConfig(e_CatPath(s, gConfigScript))
2143   end
2144 end;
2145
2146 procedure Init;
2147   var i: Integer;
2148 begin
2149   conRegVar('chat_at_top', @ChatTop, 'draw chat at top border', 'draw chat at top border');
2150   conRegVar('console_height', @ConsoleHeight, 0.0, 1.0, 'set console size', 'set console size');
2151   conRegVar('console_trans', @ConsoleTrans, 0.0, 1.0, 'set console transparency', 'set console transparency');
2152   conRegVar('console_step', @ConsoleStep, 0.0, 1.0, 'set console animation speed', 'set console animation speed');
2153 {$IFDEF ANDROID}
2154   ChatTop := True;
2155   ConsoleHeight := 0.35;
2156 {$ELSE}
2157   ChatTop := False;
2158   ConsoleHeight := 0.5;
2159 {$ENDIF}
2160   ConsoleTrans := 0.1;
2161   ConsoleStep := 0.07;
2162   conRegVar('d_eres', @debug_e_res, '', '');
2163   for i := 1 to e_MaxJoys do
2164     conRegVar('joy' + IntToStr(i) + '_deadzone', @e_JoystickDeadzones[i - 1], '', '')
2165 end;
2166
2167 initialization
2168   Init
2169 end.