DEADSOFTWARE

GIT / REPO / FRED-BOY
Projects / d2df-sdl.git / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
panels: handle panel animation in render (bump protocol)
[d2df-sdl.git] / src / game / renders / opengl / r_map.pas
1 (* Copyright (C) Doom 2D: Forever Developers
2 *
3 * This program is free software: you can redistribute it and/or modify
4 * it under the terms of the GNU General Public License as published by
5 * the Free Software Foundation, version 3 of the License ONLY.
6 *
7 * This program is distributed in the hope that it will be useful,
8 * but WITHOUT ANY WARRANTY; without even the implied warranty of
9 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
10 * GNU General Public License for more details.
11 *
12 * You should have received a copy of the GNU General Public License
13 * along with this program. If not, see <http://www.gnu.org/licenses/>.
14 *)
15 {$INCLUDE ../../../shared/a_modes.inc}
16 unit r_map;
17
18 interface
19
20 uses g_base, g_player, g_playermodel; // TRectWH, TPlayer, TPlayerModel
21
22 procedure r_Map_Initialize;
23 procedure r_Map_Finalize;
24
25 procedure r_Map_Load;
26 procedure r_Map_Free;
27
28 procedure r_Map_LoadTextures;
29 procedure r_Map_FreeTextures;
30
31 {$IFDEF ENABLE_GFX}
32 procedure r_Map_NewGFX (typ, x, y: Integer);
33 {$ENDIF}
34 {$IFDEF ENABLE_GIBS}
35 function r_Map_GetGibSize (m, i: Integer): TRectWH;
36 {$ENDIF}
37 {$IFDEF ENABLE_MENU}
38 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer; alpha: Byte);
39 {$ENDIF}
40
41 procedure r_Map_Update;
42
43 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer; player: TPlayer);
44
45 implementation
46
47 uses
48 Math, SysUtils,
49 {$IFDEF USE_GLES1}
50 GLES11,
51 {$ELSE}
52 GL, GLEXT,
53 {$ENDIF}
54 e_log,
55 binheap, MAPDEF, utils,
56 g_options, g_animations, g_basic, g_phys,
57 g_game, g_map, g_panel, g_items, g_monsters, g_weapons,
58 {$IFDEF ENABLE_CORPSES}
59 g_corpses,
60 {$ENDIF}
61 {$IFDEF ENABLE_SHELLS}
62 g_shells,
63 {$ENDIF}
64 {$IFDEF ENABLE_GIBS}
65 g_gibs,
66 {$ENDIF}
67 {$IFDEF ENABLE_GFX}
68 g_gfx,
69 {$ENDIF}
70 r_textures, r_draw, r_common
71 ;
72
73 const
74 MTABLE: array [0..MONSTER_MAN] of record
75 w, h: Integer;
76 end = (
77 (w: 64; h: 64), // NONE
78 (w: 64; h: 64), // DEMON
79 (w: 64; h: 64), // IMP
80 (w: 64; h: 64), // ZOMBY
81 (w: 64; h: 64), // SERG
82 (w: 128; h: 128), // CYBER
83 (w: 64; h: 64), // CGUN
84 (w: 128; h: 128), // BARON
85 (w: 128; h: 128), // KNIGHT
86 (w: 128; h: 128), // CACO
87 (w: 64; h: 64), // SOUL (DIE is 128x128, see load code)
88 (w: 128; h: 128), // PAIN
89 (w: 256; h: 128), // SPIDER
90 (w: 128; h: 64), // BSP
91 (w: 128; h: 128), // MANCUB
92 (w: 128; h: 128), // SKEL
93 (w: 128; h: 128), // VILE
94 (w: 32; h: 32), // FISH
95 (w: 64; h: 64), // BARREL
96 (w: 128; h: 128), // ROBO
97 (w: 64; h: 64) // MAN
98 );
99 VILEFIRE_DX = 32;
100 VILEFIRE_DY = 128;
101
102 ItemAnim: array [0..ITEM_LAST] of record
103 name: AnsiString;
104 w, h: Integer;
105 anim: TAnimInfo;
106 end = (
107 (name: 'NOTEXTURE'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
108 (name: 'MED1'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
109 (name: 'MED2'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
110 (name: 'BMED'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
111 (name: 'ARMORGREEN'; w: 32; h: 16; anim: (loop: true; delay: 20; frames: 3; back: true)),
112 (name: 'ARMORBLUE'; w: 32; h: 16; anim: (loop: true; delay: 20; frames: 3; back: true)),
113 (name: 'SBLUE'; w: 32; h: 32; anim: (loop: true; delay: 15; frames: 4; back: true)),
114 (name: 'SWHITE'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
115 (name: 'SUIT'; w: 32; h: 64; anim: (loop: true; delay: 1; frames: 1; back: false)),
116 (name: 'OXYGEN'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
117 (name: 'INVUL'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
118 (name: 'SAW'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
119 (name: 'SHOTGUN1'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
120 (name: 'SHOTGUN2'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
121 (name: 'MGUN'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
122 (name: 'RLAUNCHER'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
123 (name: 'PGUN'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
124 (name: 'BFG'; w: 64; h: 64; anim: (loop: true; delay: 1; frames: 1; back: false)),
125 (name: 'SPULEMET'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
126 (name: 'CLIP'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
127 (name: 'AMMO'; w: 32; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
128 (name: 'SHELL1'; w: 16; h: 8; anim: (loop: true; delay: 1; frames: 1; back: false)),
129 (name: 'SHELL2'; w: 32; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
130 (name: 'ROCKET'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
131 (name: 'ROCKETS'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
132 (name: 'CELL'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
133 (name: 'CELL2'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
134 (name: 'BPACK'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
135 (name: 'KEYR'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
136 (name: 'KEYG'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
137 (name: 'KEYB'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
138 (name: 'KASTET'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
139 (name: 'PISTOL'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
140 (name: 'BOTTLE'; w: 16; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
141 (name: 'HELMET'; w: 16; h: 16; anim: (loop: true; delay: 20; frames: 4; back: true)),
142 (name: 'JETPACK'; w: 32; h: 32; anim: (loop: true; delay: 15; frames: 3; back: true)),
143 (name: 'INVIS'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
144 (name: 'FLAMETHROWER'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
145 (name: 'FUELCAN'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false))
146 );
147
148 {$IFDEF ENABLE_GFX}
149 GFXAnim: array [0..R_GFX_LAST] of record
150 name: AnsiString;
151 w, h: Integer;
152 anim: TAnimInfo;
153 rdelay: Integer;
154 alpha: Integer;
155 end = (
156 (name: ''; w: 0; h: 0; anim: (loop: false; delay: 0; frames: 0; back: false); rdelay: 0; alpha: 0),
157 (name: 'TELEPORT'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 10; back: false); rdelay: 0; alpha: 0),
158 (name: 'FLAME'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 11; back: false); rdelay: 0; alpha: 0),
159 (name: 'EROCKET'; w: 128; h: 128; anim: (loop: false; delay: 6; frames: 6; back: false); rdelay: 0; alpha: 0),
160 (name: 'EBFG'; w: 128; h: 128; anim: (loop: false; delay: 6; frames: 6; back: false); rdelay: 0; alpha: 0),
161 (name: 'BFGHIT'; w: 64; h: 64; anim: (loop: false; delay: 4; frames: 4; back: false); rdelay: 0; alpha: 0),
162 (name: 'FIRE'; w: 64; h: 128; anim: (loop: false; delay: 4; frames: 8; back: false); rdelay: 2; alpha: 0),
163 (name: 'ITEMRESPAWN'; w: 32; h: 32; anim: (loop: false; delay: 4; frames: 5; back: true); rdelay: 0; alpha: 0),
164 (name: 'SMOKE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 0),
165 (name: 'ESKELFIRE'; w: 64; h: 64; anim: (loop: false; delay: 8; frames: 3; back: false); rdelay: 0; alpha: 0),
166 (name: 'EPLASMA'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 4; back: true); rdelay: 0; alpha: 0),
167 (name: 'EBSPFIRE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 5; back: false); rdelay: 0; alpha: 0),
168 (name: 'EIMPFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
169 (name: 'ECACOFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
170 (name: 'EBARONFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
171 (name: 'TELEPORT'; w: 64; h: 64; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 0), // fast
172 (name: 'SMOKE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 150), // transparent
173 (name: 'FLAME'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 11; back: false); rdelay: 2; alpha: 0) // random
174 );
175 {$ENDIF}
176
177 ShotAnim: array [0..WEAPON_LAST] of record
178 name: AnsiString;
179 w, h: Integer;
180 anim: TAnimInfo;
181 end = (
182 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 0 KASTET
183 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 1 SAW
184 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 2 PISTOL
185 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 3 SHOTGUN1
186 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 4 SHOTGUN2
187 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 5 CHAINGUN
188 (name: 'BROCKET'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)), // 6 ROCKETLAUNCHER
189 (name: 'BPLASMA'; w: 16; h: 16; anim: (loop: true; delay: 5; frames: 2; back: false)), // 7 PLASMA
190 (name: 'BBFG'; w: 64; h: 64; anim: (loop: true; delay: 6; frames: 2; back: false)), // 8 BFG
191 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 9 SUPERPULEMET
192 (name: 'FLAME'; w: 32; h: 32; anim: (loop: true; delay: 6; frames: 0{11}; back: false)), // 10 FLAMETHROWER
193 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 11
194 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 12
195 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 13
196 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 14
197 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 15
198 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 16
199 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 17
200 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 18
201 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 19
202 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 20 ZOMPY_PISTOL
203 (name: 'BIMPFIRE'; w: 16; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 21 IMP_FIRE
204 (name: 'BBSPFIRE'; w: 16; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 22 BSP_FIRE
205 (name: 'BCACOFIRE'; w: 16; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 23 CACO_FIRE
206 (name: 'BBARONFIRE'; w: 64; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 24 BARON_FIRE
207 (name: 'BMANCUBFIRE'; w: 64; h: 32; anim: (loop: true; delay: 4; frames: 2; back: false)), // 25 MANCUB_FIRE
208 (name: 'BSKELFIRE'; w: 64; h: 64; anim: (loop: true; delay: 5; frames: 2; back: false)) // 26 SKEL_FIRE
209 );
210
211 {$IFDEF ENABLE_SHELLS}
212 ShellAnim: array [0..SHELL_LAST] of record
213 name: AnsiString;
214 dx, dy: Integer;
215 end = (
216 (name: 'EBULLET'; dx: 2; dy: 1), // 0 SHELL_BULLET
217 (name: 'ESHELL'; dx: 4; dy: 2), // 1 SHELL_SHELL
218 (name: 'ESHELL'; dx: 4; dy: 2) // 2 SHELL_DBLSHELL
219 );
220 {$ENDIF}
221
222 PunchAnim: TAnimInfo = (loop: false; delay: 1; frames: 4; back: false);
223 FlagAnim: TAnimInfo = (loop: true; delay: 8; frames: 5; back: false);
224 VileFireAnim: TAnimInfo = (loop: true; delay: 2; frames: 8; back: false);
225
226 type
227 TBinHeapPanelDrawCmp = class
228 public
229 class function less (const a, b: TPanel): Boolean; inline;
230 end;
231
232 TBinHeapPanelDraw = specialize TBinaryHeapBase<TPanel, TBinHeapPanelDrawCmp>;
233
234 TMonsterAnims = array [0..ANIM_LAST, TDirection] of TGLMultiTexture;
235
236 var
237 SkyTexture: TGLTexture;
238 RenTextures: array of record
239 spec: LongInt;
240 tex: TGLMultiTexture;
241 anim: TAnimInfo;
242 end;
243 Items: array [0..ITEM_LAST] of record
244 tex: TGLMultiTexture;
245 frame: Integer;
246 end;
247 MonTextures: array [0..MONSTER_MAN] of TMonsterAnims;
248 WeapTextures: array [0..WP_LAST, 0..W_POS_LAST, 0..W_ACT_LAST] of TGLTexture;
249 ShotTextures: array [0..WEAPON_LAST] of TGLMultiTexture;
250 FlagTextures: array [0..FLAG_LAST] of TGLMultiTexture;
251 PunchTextures: array [Boolean, 0..2] of TGLMultiTexture; // [berserk, center/up/down]
252 VileFire: TGLMultiTexture;
253 InvulPenta: TGLTexture;
254 Models: array of record
255 anim: array [TDirection, 0..A_LAST] of record
256 base, mask: TGLMultiTexture;
257 end;
258 {$IFDEF ENABLE_GIBS}
259 gibs: record
260 base, mask: TGLTextureArray;
261 rect: TRectArray;
262 end;
263 {$ENDIF}
264 end;
265
266 {$IFDEF ENABLE_SHELLS}
267 ShellTextures: array [0..SHELL_LAST] of TGLTexture;
268 {$ENDIF}
269 {$IFDEF ENABLE_GFX}
270 GFXTextures: array [0..R_GFX_LAST] of TGLMultiTexture;
271 gfxlist: array of record
272 typ: Byte;
273 x, y: Integer;
274 oldX, oldY: Integer;
275 anim: TAnimInfo;
276 time: LongWord;
277 frame: LongInt;
278 end = nil;
279 {$ENDIF}
280
281 FlagFrame: LongInt;
282 plist: TBinHeapPanelDraw = nil;
283
284 class function TBinHeapPanelDrawCmp.less (const a, b: TPanel): Boolean; inline;
285 begin
286 if a.tag < b.tag then begin result := true; exit; end;
287 if a.tag > b.tag then begin result := false; exit; end;
288 result := a.arrIdx < b.arrIdx;
289 end;
290
291 procedure r_Map_Initialize;
292 begin
293 FlagFrame := 0;
294 plist := TBinHeapPanelDraw.Create();
295 end;
296
297 procedure r_Map_Finalize;
298 begin
299 plist.Free;
300 FlagFrame := 0;
301 end;
302
303 procedure r_Map_FreeModel (i: Integer);
304 var a: Integer; d: TDirection;
305 begin
306 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
307 begin
308 for a := A_STAND to A_LAST do
309 begin
310 if Models[i].anim[d, a].base <> nil then
311 Models[i].anim[d, a].base.Free;
312 if Models[i].anim[d, a].mask <> nil then
313 Models[i].anim[d, a].mask.Free;
314 Models[i].anim[d, a].base := nil;
315 Models[i].anim[d, a].mask := nil;
316 end;
317 end;
318 {$IFDEF ENABLE_GIBS}
319 if Models[i].gibs.base <> nil then
320 for a := 0 to High(Models[i].gibs.base) do
321 Models[i].gibs.base[a].Free;
322 if Models[i].gibs.mask <> nil then
323 for a := 0 to High(Models[i].gibs.mask) do
324 Models[i].gibs.mask[a].Free;
325 Models[i].gibs.base := nil;
326 Models[i].gibs.mask := nil;
327 Models[i].gibs.rect := nil;
328 {$ENDIF}
329 end;
330
331 procedure r_Map_LoadModel (i: Integer);
332 var prefix: AnsiString; a: Integer; d: TDirection; m: ^TPlayerModelInfo;
333 begin
334 ASSERT(i < Length(Models));
335 ASSERT(i < Length(PlayerModelsArray));
336 r_Map_FreeModel(i);
337 m := @PlayerModelsArray[i];
338 prefix := m.FileName + ':TEXTURES/';
339 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
340 begin
341 for a := A_STAND to A_LAST do
342 begin
343 Models[i].anim[d, a].base := nil;
344 Models[i].anim[d, a].mask := nil;
345 if m.anim[d, a].resource <> '' then
346 Models[i].anim[d, a].base := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].resource, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
347 if m.anim[d, a].mask <> '' then
348 Models[i].anim[d, a].mask := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].mask, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
349 end
350 end;
351 {$IFDEF ENABLE_GIBS}
352 Models[i].gibs.base := nil;
353 Models[i].gibs.mask := nil;
354 Models[i].gibs.rect := nil;
355 if m.GibsCount > 0 then
356 begin
357 SetLength(Models[i].gibs.base, m.GibsCount);
358 SetLength(Models[i].gibs.mask, m.GibsCount);
359 SetLength(Models[i].gibs.rect, m.GibsCount);
360 for a := 0 to m.GibsCount - 1 do
361 Models[i].gibs.rect[a] := DefaultGibSize;
362 if r_Textures_LoadStreamFromFile(prefix + m.GibsResource, 32, 32, m.GibsCount, m.GibsCount, Models[i].gibs.base, Models[i].gibs.rect) then
363 begin
364 if r_Textures_LoadStreamFromFile(prefix + m.GibsMask, 32, 32, m.GibsCount, m.GibsCount, Models[i].gibs.mask, nil) then
365 begin
366 // ok
367 end;
368 end;
369 end;
370 {$ENDIF}
371 end;
372
373 procedure r_Map_LoadMonsterAnim (m, a: Integer; d: TDirection);
374 const dir: array [TDirection] of AnsiString = ('_L', '');
375 var w, h, count: Integer;
376 begin
377 count := MONSTER_ANIMTABLE[m].AnimCount[a];
378 if count > 0 then
379 begin
380 w := MTABLE[m].w;
381 h := MTABLE[m].h;
382 if (m = MONSTER_SOUL) and (a = ANIM_DIE) then
383 begin
384 // special case
385 w := 128;
386 h := 128;
387 end;
388 MonTextures[m, a, d] := r_Textures_LoadMultiFromFileAndInfo(
389 GameWAD + ':MTEXTURES/' + MONSTERTABLE[m].name + '_' + ANIMTABLE[a].name + dir[d],
390 w,
391 h,
392 count,
393 False,
394 False
395 );
396 end
397 else
398 MonTextures[m, a, d] := nil;
399 end;
400
401 procedure r_Map_Load;
402 const
403 WeapName: array [0..WP_LAST] of AnsiString = ('', 'CSAW', 'HGUN', 'SG', 'SSG', 'MGUN', 'RKT', 'PLZ', 'BFG', 'SPL', 'FLM');
404 WeapPos: array [0..W_POS_LAST] of AnsiString = ('', '_UP', '_DN');
405 WeapAct: array [0..W_ACT_LAST] of AnsiString = ('', '_FIRE');
406 PunchName: array [Boolean] of AnsiString = ('PUNCH', 'PUNCHB');
407 var
408 i, j, k: Integer; d: TDirection; b: Boolean;
409 begin
410 // --------- items --------- //
411 for i := 0 to ITEM_LAST do
412 begin
413 Items[i].tex := r_Textures_LoadMultiFromFileAndInfo(
414 GameWAD + ':TEXTURES/' + ItemAnim[i].name,
415 ItemAnim[i].w,
416 ItemAnim[i].h,
417 ItemAnim[i].anim.frames,
418 ItemAnim[i].anim.back,
419 false
420 );
421 Items[i].frame := 0;
422 end;
423 // --------- monsters --------- //
424 for i := MONSTER_DEMON to MONSTER_MAN do
425 for j := 0 to ANIM_LAST do
426 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
427 r_Map_LoadMonsterAnim(i, j, d);
428 VileFire := r_Textures_LoadMultiFromFileAndInfo(GameWAD + ':TEXTURES/FIRE', 64, 128, VileFireAnim.frames, VileFireAnim.back);
429 // --------- player models --------- //
430 if PlayerModelsArray <> nil then
431 begin
432 SetLength(Models, Length(PlayerModelsArray));
433 for i := 0 to High(PlayerModelsArray) do
434 r_Map_LoadModel(i);
435 end;
436 // --------- player weapons --------- //
437 for i := 1 to WP_LAST do
438 for j := 0 to W_POS_LAST do
439 for k := 0 to W_ACT_LAST do
440 WeapTextures[i, j, k] := r_Textures_LoadFromFile(GameWAD + ':WEAPONS\' + WeapName[i] + WeapPos[j] + WeapAct[k]);
441 // --------- gfx animations --------- //
442 {$IFDEF ENABLE_GFX}
443 for i := 1 to R_GFX_LAST do
444 if GFXAnim[i].anim.frames > 0 then
445 GFXTextures[i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/' + GFXAnim[i].name, GFXAnim[i].w, GFXAnim[i].h, GFXAnim[i].anim.frames, GFXAnim[i].anim.back);
446 {$ENDIF}
447 // --------- shots --------- //
448 for i := 0 to WEAPON_LAST do
449 if ShotAnim[i].anim.frames > 0 then
450 ShotTextures[i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/' + ShotAnim[i].name, ShotAnim[i].w, ShotAnim[i].h, ShotAnim[i].anim.frames, ShotAnim[i].anim.back);
451 // --------- flags --------- //
452 FlagTextures[FLAG_NONE] := nil;
453 FlagTextures[FLAG_RED] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGRED', 64, 64, 5, false);
454 FlagTextures[FLAG_BLUE] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGBLUE', 64, 64, 5, false);
455 // FlagTextures[FLAG_DOM] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGDOM', 64, 64, 8, false);
456 // --------- shells --------- //
457 {$IFDEF ENABLE_SHELLS}
458 for i := 0 to SHELL_LAST do
459 ShellTextures[i] := r_Textures_LoadFromFile(GameWad + ':TEXTURES/' + ShellAnim[i].name);
460 {$ENDIF}
461 // --------- punch --------- //
462 for b := false to true do
463 begin
464 for i := 0 to 2 do
465 PunchTextures[b, i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':WEAPONS/' + PunchName[b] + WeapPos[i], 64, 64, PunchAnim.frames, PunchAnim.back);
466 end;
467 // --------- other --------- //
468 InvulPenta := r_Textures_LoadFromFile(GameWad + ':TEXTURES/PENTA');
469 end;
470
471 procedure r_Map_Free;
472 var i, j, k: Integer; d: TDirection; b: Boolean;
473 begin
474 if InvulPenta <> nil then
475 InvulPenta.Free;
476 InvulPenta := nil;
477 for b := false to true do
478 begin
479 for i := 0 to 2 do
480 begin
481 if PunchTextures[b, i] <> nil then
482 PunchTextures[b, i].Free;
483 PunchTextures[b, i] := nil;
484 end;
485 end;
486 {$IFDEF ENABLE_SHELLS}
487 for i := 0 to SHELL_LAST do
488 begin
489 if ShellTextures[i] <> nil then
490 ShellTextures[i].Free;
491 ShellTextures[i] := nil;
492 end;
493 {$ENDIF}
494 for i := 0 to FLAG_LAST do
495 begin
496 if FlagTextures[i] <> nil then
497 FlagTextures[i].Free;
498 FlagTextures[i] := nil;
499 end;
500 for i := 0 to WEAPON_LAST do
501 begin
502 if ShotTextures[i] <> nil then
503 ShotTextures[i].Free;
504 ShotTextures[i] := nil;
505 end;
506 {$IFDEF ENABLE_GFX}
507 gfxlist := nil;
508 for i := 0 to R_GFX_LAST do
509 begin
510 if GFXTextures[i] <> nil then
511 GFXTextures[i].Free;
512 GFXTextures[i] := nil;
513 end;
514 {$ENDIF}
515 for i := 1 to WP_LAST do
516 begin
517 for j := 0 to W_POS_LAST do
518 begin
519 for k := 0 to W_ACT_LAST do
520 begin
521 if WeapTextures[i, j, k] <> nil then
522 WeapTextures[i, j, k].Free;
523 WeapTextures[i, j, k] := nil;
524 end;
525 end;
526 end;
527 if Models <> nil then
528 for i := 0 to High(Models) do
529 r_Map_FreeModel(i);
530 for i := MONSTER_DEMON to MONSTER_MAN do
531 begin
532 for j := 0 to ANIM_LAST do
533 begin
534 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
535 begin
536 if MonTextures[i, j, d] <> nil then
537 MonTextures[i, j, d].Free;
538 MonTextures[i, j, d] := nil;
539 end;
540 end;
541 end;
542 for i := 0 to ITEM_LAST do
543 begin
544 if Items[i].tex <> nil then
545 Items[i].tex.Free;
546 Items[i].tex := nil;
547 end;
548 end;
549
550 procedure r_Map_LoadTextures;
551 const DefaultAnimInfo: TAnimInfo = (loop: true; delay: 1; frames: 1; back: false);
552 var i, n: Integer; txt: TAnimTextInfo;
553 begin
554 if Textures <> nil then
555 begin
556 n := Length(Textures);
557 SetLength(RenTextures, n);
558 for i := 0 to n - 1 do
559 begin
560 txt.anim := DefaultAnimInfo;
561 RenTextures[i].tex := nil;
562 case Textures[i].TextureName of
563 TEXTURE_NAME_WATER: RenTextures[i].spec := TEXTURE_SPECIAL_WATER;
564 TEXTURE_NAME_ACID1: RenTextures[i].spec := TEXTURE_SPECIAL_ACID1;
565 TEXTURE_NAME_ACID2: RenTextures[i].spec := TEXTURE_SPECIAL_ACID2;
566 else
567 RenTextures[i].spec := 0;
568 e_LogWritefln('r_Map_LoadTextures: begin load texture: %s', [Textures[i].FullName]);
569 RenTextures[i].tex := r_Textures_LoadMultiTextFromFile(Textures[i].FullName, txt);
570 e_LogWritefln('r_Map_LoadTextures: end load texture: %s', [Textures[i].FullName]);
571 if RenTextures[i].tex = nil then
572 e_LogWritefln('r_Map_LoadTextures: failed to load texture: %s', [Textures[i].FullName]);
573 end;
574 RenTextures[i].anim := txt.anim;
575 end;
576 end;
577 if gMapInfo.SkyFullName <> '' then
578 SkyTexture := r_Textures_LoadFromFile(gMapInfo.SkyFullName);
579 plist.Clear;
580 end;
581
582 procedure r_Map_FreeTextures;
583 var i: Integer;
584 begin
585 plist.Clear;
586 if SkyTexture <> nil then
587 SkyTexture.Free;
588 SkyTexture := nil;
589 if RenTextures <> nil then
590 for i := 0 to High(RenTextures) do
591 if RenTextures[i].tex <> nil then
592 RenTextures[i].tex.Free;
593 RenTextures := nil;
594 end;
595
596 procedure r_Map_DrawPanel (p: TPanel);
597 var Texture: Integer; t: TGLMultiTexture; tex: TGLTexture; count, frame: LongInt; a: TAnimInfo;
598 begin
599 ASSERT(p <> nil);
600 if p.FCurTexture >= 0 then
601 begin
602 Texture := p.TextureIDs[p.FCurTexture].Texture;
603 t := RenTextures[Texture].tex;
604 if (RenTextures[Texture].spec = 0) or (t <> nil) then
605 begin
606 count := 0; frame := 0;
607 if p.AnimTime <= gTime then
608 begin
609 a := RenTextures[Texture].anim;
610 a.loop := p.AnimLoop;
611 g_Anim_GetFrameByTime(a, (gTime - p.AnimTime) DIV GAME_TICK, count, frame);
612 end;
613 if t <> nil then
614 begin
615 tex := t.GetTexture(frame);
616 r_Draw_TextureRepeat(tex, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending);
617 end
618 else
619 r_Draw_TextureRepeat(nil, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255, false);
620 end;
621
622 if t = nil then
623 begin
624 case RenTextures[Texture].spec of
625 TEXTURE_SPECIAL_WATER: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 0, 255, 255);
626 TEXTURE_SPECIAL_ACID1: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 230, 0, 255);
627 TEXTURE_SPECIAL_ACID2: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 230, 0, 0, 255);
628 end
629 end
630 end
631 end;
632
633 procedure r_Map_DrawPanelType (panelTyp: DWORD);
634 var tagMask, i: Integer; p: TPanel;
635 begin
636 i := 0;
637 tagMask := PanelTypeToTag(panelTyp);
638 while plist.count > 0 do
639 begin
640 p := TPanel(plist.Front());
641 if (p.tag and tagMask) = 0 then
642 break;
643 r_Map_DrawPanel(p);
644 Inc(i);
645 plist.PopFront
646 end;
647 end;
648
649 procedure r_Map_DrawItems (x, y, w, h: Integer; drop: Boolean);
650 var i, fX, fY: Integer; it: PItem; t: TGLMultiTexture; tex: TGLTexture;
651 begin
652 if ggItems <> nil then
653 begin
654 for i := 0 to High(ggItems) do
655 begin
656 it := @ggItems[i];
657 if it.used and it.alive and (it.dropped = drop) and (it.ItemType > ITEM_NONE) and (it.ItemType <= ITEM_LAST) then
658 begin
659 t := Items[it.ItemType].tex;
660 if g_Collide(it.obj.x, it.obj.y, t.width, t.height, x, y, w, h) then
661 begin
662 it.obj.Lerp(gLerpFactor, fX, fY);
663 tex := t.GetTexture(Items[it.ItemType].frame);
664 r_Draw_TextureRepeat(tex, fX, fY, tex.width, tex.height, false, 255, 255, 255, 255, false);
665 end;
666 end;
667 end;
668 end;
669 // TODO draw g_debug_frames
670 end;
671
672 function r_Map_GetMonsterTexture (m, a: Integer; d: TDirection; out t: TGLMultiTexture; out dx, dy: Integer; out flip: Boolean): Boolean;
673 // var c: Integer;
674 begin
675 t := nil; dx := 0; dy := 0; flip := false;
676 result := MonTextures[m, a, d] <> nil;
677 if result = false then
678 begin
679 flip := true;
680 if d = TDirection.D_RIGHT then d := TDirection.D_LEFT else d := TDirection.D_RIGHT;
681 result := MonTextures[m, a, d] <> nil;
682 end;
683 if result = true then
684 begin
685 t := MonTextures[m, a, d];
686 if d = TDirection.D_LEFT then
687 begin
688 dx := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].X;
689 dy := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].Y;
690 end
691 else
692 begin
693 dx := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].X;
694 dy := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].Y;
695 end;
696 if flip then
697 begin
698 // c := (MONSTERTABLE[MonsterType].Rect.X - dx) + MONSTERTABLE[MonsterType].Rect.Width;
699 // dx := MTABLE[m].width - c - MONSTERTABLE[MonsterType].Rect.X;
700 dx := -dx;
701 end;
702 end;
703 end;
704
705 procedure r_Map_DrawMonsterAttack (constref mon: TMonster);
706 var o: TObj; count, frame: LongInt; tex: TGLTexture;
707 begin
708 if VileFire <> nil then
709 if (mon.MonsterType = MONSTER_VILE) and (mon.MonsterState = MONSTATE_SHOOT) then
710 if (mon.VileFireTime <= gTime) and GetPos(mon.MonsterTargetUID, @o) then
711 begin
712 g_Anim_GetFrameByTime(VileFireAnim, (gTime - mon.VileFireTime) DIV GAME_TICK, count, frame);
713 tex := VileFire.GetTexture(frame);
714 r_Draw_TextureRepeat(tex, o.x + o.rect.x + (o.rect.width div 2) - VILEFIRE_DX, o.y + o.rect.y + o.rect.height - VILEFIRE_DY, tex.width, tex.height, False, 255, 255, 255, 255, false);
715 end;
716 end;
717
718 procedure r_Map_DrawMonster (constref mon: TMonster);
719 var m, a, fX, fY, dx, dy: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture;
720 begin
721 m := mon.MonsterType;
722 a := mon.MonsterAnim;
723 d := mon.GameDirection;
724
725 mon.obj.Lerp(gLerpFactor, fX, fY);
726
727 if r_Map_GetMonsterTexture(m, a, d, t, dx, dy, flip) then
728 r_Draw_MultiTextureRepeat(t, mon.DirAnim[a, d], fX + dx, fY + dy, t.width, t.height, flip, 255, 255, 255, 255, false);
729
730 // TODO draw g_debug_frames
731 end;
732
733 procedure r_Map_DrawMonsters (x, y, w, h: Integer);
734 var i: Integer; m: TMonster;
735 begin
736 if gMonsters <> nil then
737 begin
738 for i := 0 to High(gMonsters) do
739 begin
740 m := gMonsters[i];
741 if m <> nil then
742 begin
743 r_Map_DrawMonsterAttack(m);
744 // TODO select from grid
745 if g_Collide(m.obj.x + m.obj.rect.x, m.obj.y + m.obj.rect.y, m.obj.rect.width, m.obj.rect.height, x, y, w, h) then
746 r_Map_DrawMonster(m);
747 end;
748 end;
749 end;
750 end;
751
752 function r_Map_GetPlayerModelTex (i: Integer; var a: Integer; var d: TDirection; out flip: Boolean): Boolean;
753 begin
754 flip := false;
755 result := Models[i].anim[d, a].base <> nil;
756 if result = false then
757 begin
758 flip := true;
759 if d = TDirection.D_LEFT then d := TDirection.D_RIGHT else d := TDirection.D_LEFT;
760 result := Models[i].anim[d, a].base <> nil;
761 end;
762 end;
763
764 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer; alpha: Byte);
765 var a, pos, act, xx, yy, angle: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture; tex: TGLTexture; c: TRGB;
766 begin
767 a := pm.CurrentAnimation;
768 d := pm.Direction;
769
770 (* draw flag*)
771 t := FlagTextures[pm.Flag];
772 if (t <> nil) and not (a in [A_DIE1, A_DIE2]) then
773 begin
774 flip := d = TDirection.D_RIGHT;
775 angle := PlayerModelsArray[pm.id].FlagAngle;
776 xx := PlayerModelsArray[pm.id].FlagPoint.X;
777 yy := PlayerModelsArray[pm.id].FlagPoint.Y;
778 tex := t.GetTexture(FlagFrame);
779 r_Draw_TextureRepeatRotate(
780 tex,
781 x + IfThen(flip, 2 * FLAG_BASEPOINT.X - xx + 1, xx - 1) - FLAG_BASEPOINT.X,
782 y + yy - FLAG_BASEPOINT.Y + 1,
783 tex.width,
784 tex.height,
785 flip,
786 255, 255, 255, 255, false,
787 IfThen(flip, 64 - FLAG_BASEPOINT.X, FLAG_BASEPOINT.X),
788 FLAG_BASEPOINT.Y,
789 IfThen(flip, angle, -angle)
790 );
791 end;
792
793 (* draw weapon *)
794 if PlayerModelsArray[pm.id].HaveWeapon and not (a in [A_DIE1, A_DIE2, A_PAIN]) then
795 begin
796 case a of
797 A_SEEUP, A_ATTACKUP: pos := W_POS_UP;
798 A_SEEDOWN, A_ATTACKDOWN: pos := W_POS_DOWN;
799 else pos := W_POS_NORMAL;
800 end;
801 if (a in [A_ATTACK, A_ATTACKUP, A_ATTACKDOWN]) or pm.GetFire() then
802 act := W_ACT_FIRE
803 else
804 act := W_ACT_NORMAL;
805 tex := WeapTextures[pm.CurrentWeapon, pos, act];
806 if tex <> nil then
807 begin
808 xx := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].X;
809 yy := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].Y;
810 r_Draw_Texture(
811 tex,
812 x + xx,
813 y + yy,
814 tex.width,
815 tex.height,
816 d = TDirection.D_LEFT,
817 255, 255, 255, alpha, false
818 );
819 end;
820 end;
821
822 (* draw body *)
823 if r_Map_GetPlayerModelTex(pm.id, a, d, flip) then
824 begin
825 t := Models[pm.id].anim[d, a].base;
826 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip, 255, 255, 255, alpha, false);
827 t := Models[pm.id].anim[d, a].mask;
828 if t <> nil then
829 begin
830 c := pm.Color;
831 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip, c.r, c.g, c.b, alpha, false);
832 end;
833 end;
834 end;
835
836 procedure r_Map_DrawPlayer (p, drawed: TPlayer);
837 var fX, fY, fSlope, ax, ay, w, h: Integer; b, flip: Boolean; t: TGLMultiTexture; tex: TGLTexture; alpha: Byte; count, frame: LongInt;
838 begin
839 if p.alive then
840 begin
841 fX := p.obj.x; fY := p.obj.y;
842 // TODO fix lerp
843 //p.obj.Lerp(gLerpFactor, fX, fY);
844 fSlope := nlerp(p.SlopeOld, p.obj.slopeUpLeft, gLerpFactor);
845
846 (* punch effect *)
847 if p.PunchTime <= gTime then
848 begin
849 g_Anim_GetFrameByTime(PunchAnim, (gTime - p.PunchTime) DIV GAME_TICK, count, frame);
850 if count < 1 then
851 begin
852 b := R_BERSERK in p.FRulez;
853 if p.FKeys[KEY_DOWN].pressed then
854 t := PunchTextures[b, 2]
855 else if p.FKeys[KEY_UP].pressed then
856 t := PunchTextures[b, 1]
857 else
858 t := PunchTextures[b, 0];
859 if t <> nil then
860 begin
861 flip := p.Direction = TDirection.D_LEFT;
862 ax := IfThen(flip, 15 - p.Obj.Rect.X, p.Obj.Rect.X - 15); // ???
863 ay := p.Obj.Rect.Y - 11;
864 tex := t.GetTexture(frame);
865 r_Draw_TextureRepeat(tex, fx + ax, fy + fSlope + ay, tex.width, tex.height, flip, 255, 255, 255, 255, false)
866 end;
867 end;
868 end;
869
870 (* invulnerability effect *)
871 if (InvulPenta <> nil) and (p.FMegaRulez[MR_INVUL] > gTime) and ((p <> drawed) or (p.SpawnInvul >= gTime)) then
872 begin
873 w := InvulPenta.width;
874 h := InvulPenta.height;
875 ax := p.Obj.Rect.X + (p.Obj.Rect.Width div 2) - (w div 2); // + IfThen(flip, +4, -2) // ???
876 ay := p.Obj.Rect.Y + (p.Obj.Rect.Height div 2) - (h div 2) - 7; // ???
877 r_Draw_Texture(InvulPenta, fx + ax, fy + ay + fSlope, w, h, false, 255, 255, 255, 255, false);
878 end;
879
880 (* invisibility effect *)
881 alpha := 255;
882 if p.FMegaRulez[MR_INVIS] > gTime then
883 begin
884 if (drawed <> nil) and ((p = drawed) or ((p.Team = drawed.Team) and (gGameSettings.GameMode <> GM_DM))) then
885 begin
886 if (p.FMegaRulez[MR_INVIS] - gTime > 2100) or not ODD((p.FMegaRulez[MR_INVIS] - gTime) div 300) then
887 alpha := 55;
888 end
889 else
890 alpha := 1; // ???
891 end;
892
893 r_Map_DrawPlayerModel(p.Model, fX, fY + fSlope, alpha);
894 end;
895 // TODO draw g_debug_frames
896 // TODO draw chat bubble
897 // TODO draw aim
898 end;
899
900 procedure r_Map_DrawPlayers (x, y, w, h: Integer; player: TPlayer);
901 var i: Integer;
902 begin
903 if gPlayers <> nil then
904 for i := 0 to High(gPlayers) do
905 if gPlayers[i] <> nil then
906 r_Map_DrawPlayer(gPlayers[i], player);
907 end;
908
909 {$IFDEF ENABLE_GIBS}
910 function r_Map_GetGibSize (m, i: Integer): TRectWH;
911 begin
912 result := Models[m].gibs.rect[i];
913 end;
914
915 procedure r_Map_DrawGibs (x, y, w, h: Integer);
916 var i, fx, fy, m, id, rx, ry, ra: Integer; p: PObj; t: TGLTexture;
917 begin
918 if gGibs <> nil then
919 begin
920 for i := 0 to High(gGibs) do
921 begin
922 if gGibs[i].alive then
923 begin
924 p := @gGibs[i].Obj;
925 if g_Obj_Collide(x, y, w, h, p) then
926 begin
927 p.Lerp(gLerpFactor, fx, fy);
928 id := gGibs[i].GibID;
929 m := gGibs[i].ModelID;
930 t := Models[m].gibs.base[id];
931 if t <> nil then
932 begin
933 rx := p.Rect.X + p.Rect.Width div 2;
934 ry := p.Rect.Y + p.Rect.Height div 2;
935 ra := gGibs[i].RAngle;
936 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, 255, 255, 255, 255, false, rx, ry, ra);
937 t := Models[m].gibs.mask[id];
938 if t <> nil then
939 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, gGibs[i].Color.R, gGibs[i].Color.G, gGibs[i].Color.B, 255, false, rx, ry, ra);
940 // r_Draw_TextureRepeatRotate(nil, fx + p.Rect.X, fy + p.Rect.Y, p.Rect.Width, p.Rect.Height, false, 255, 255, 255, 255, false, p.Rect.Width div 2, p.Rect.Height div 2, ra);
941 end;
942 end;
943 end;
944 end;
945 end;
946 // TODO draw g_debug_frames
947 end;
948 {$ENDIF}
949
950 {$IFDEF ENABLE_CORPSES}
951 procedure r_Map_DrawCorpses (x, y, w, h: Integer);
952 var i, fX, fY: Integer; p: TCorpse;
953 begin
954 if gCorpses <> nil then
955 begin
956 for i := 0 to High(gCorpses) do
957 begin
958 p := gCorpses[i];
959 if (p <> nil) and (p.state <> CORPSE_STATE_REMOVEME) and (p.model <> nil) then
960 begin
961 p.obj.Lerp(gLerpFactor, fX, fY);
962 r_Map_DrawPlayerModel(p.model, fX, fY, 255);
963 end;
964 end;
965 end;
966 // TODO draw g_debug_frames
967 end;
968 {$ENDIF}
969
970 {$IFDEF ENABLE_GFX}
971 function r_Map_GetGFXID (): Integer;
972 var i: Integer;
973 begin
974 i := 0;
975 if gfxlist <> nil then
976 begin
977 while (i < Length(gfxlist)) and (gfxlist[i].typ > 0) do
978 Inc(i);
979 if i >= Length(gfxlist) then
980 SetLength(gfxlist, Length(gfxlist) + 1)
981 end
982 else
983 SetLength(gfxlist, 1);
984 gfxlist[i].typ := R_GFX_NONE;
985 result := i
986 end;
987
988 procedure r_Map_NewGFX (typ, x, y: Integer);
989 var i: Integer;
990 begin
991 if gpart_dbg_enabled and (typ > 0) and (typ <= R_GFX_LAST) then
992 begin
993 i := r_Map_GetGFXID();
994 if i >= 0 then
995 begin
996 gfxlist[i].typ := typ;
997 gfxlist[i].x := x;
998 gfxlist[i].y := y;
999 gfxlist[i].oldX := x;
1000 gfxlist[i].oldY := y;
1001 gfxlist[i].anim := GFXAnim[typ].anim;
1002 gfxlist[i].time := gTime DIV GAME_TICK;
1003 gfxlist[i].frame := 0;
1004 INC(gfxlist[i].anim.delay, Random(GFXAnim[typ].rdelay));
1005 end;
1006 end;
1007 end;
1008
1009 procedure r_Map_UpdateGFX (tick: LongWord);
1010 var i: Integer; count: LongInt;
1011 begin
1012 if gfxlist <> nil then
1013 begin
1014 for i := 0 to High(gfxlist) do
1015 begin
1016 if (gfxlist[i].typ > 0) and (tick >= gfxlist[i].time) then
1017 begin
1018 g_Anim_GetFrameByTime(gfxlist[i].anim, tick - gfxlist[i].time, count, gfxlist[i].frame);
1019 if count < 1 then
1020 begin
1021 gfxlist[i].oldX := gfxlist[i].x;
1022 gfxlist[i].oldY := gfxlist[i].y;
1023 case gfxlist[i].typ of
1024 R_GFX_FLAME, R_GFX_SMOKE:
1025 begin
1026 if Random(3) = 0 then
1027 gfxlist[i].x := gfxlist[i].x - 1 + Random(3);
1028 if Random(2) = 0 then
1029 gfxlist[i].y := gfxlist[i].y - Random(2);
1030 end;
1031 end;
1032 end
1033 else
1034 gfxlist[i].typ := R_GFX_NONE;
1035 end;
1036 end;
1037 end;
1038 end;
1039
1040 procedure r_Map_DrawGFX (x, y, w, h: Integer);
1041 var i, fx, fy, typ: Integer; t: TGLMultiTexture; tex: TGLTexture;
1042 begin
1043 if gfxlist <> nil then
1044 begin
1045 for i := 0 to High(gfxlist) do
1046 begin
1047 if gfxlist[i].typ > 0 then
1048 begin
1049 typ := gfxlist[i].typ;
1050 t := GFXTextures[typ];
1051 if t <> nil then
1052 begin
1053 fx := nlerp(gfxlist[i].oldX, gfxlist[i].x, gLerpFactor);
1054 fy := nlerp(gfxlist[i].oldY, gfxlist[i].y, gLerpFactor);
1055 tex := t.GetTexture(gfxlist[i].frame);
1056 r_Draw_TextureRepeat(tex, fx, fy, tex.width, tex.height, false, 255, 255, 255, 255 - GFXAnim[typ].alpha, false);
1057 end;
1058 end;
1059 end;
1060 end;
1061 end;
1062
1063 procedure r_Map_DrawParticles (x, y, w, h: Integer);
1064 var i, fx, fy: Integer;
1065 begin
1066 if gpart_dbg_enabled and (Particles <> nil) then
1067 begin
1068 glDisable(GL_TEXTURE_2D);
1069 if (g_dbg_scale < 0.6) then
1070 glPointSize(1)
1071 else if (g_dbg_scale > 1.3) then
1072 glPointSize(g_dbg_scale + 1)
1073 else
1074 glPointSize(2);
1075 glDisable(GL_POINT_SMOOTH);
1076 glEnable(GL_BLEND);
1077 glBlendFunc(GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA);
1078
1079 glBegin(GL_POINTS);
1080 for i := 0 to High(Particles) do
1081 begin
1082 if Particles[i].alive then
1083 begin
1084 fx := nlerp(Particles[i].oldX, Particles[i].x, gLerpFactor);
1085 fy := nlerp(Particles[i].oldY, Particles[i].y, gLerpFactor);
1086 glColor4ub(Particles[i].red, Particles[i].green, Particles[i].blue, Particles[i].alpha);
1087 glVertex2f(fx, fy);
1088 end;
1089 end;
1090 glEnd;
1091
1092 glDisable(GL_BLEND);
1093 end;
1094 end;
1095 {$ENDIF}
1096
1097 procedure r_Map_DrawShots (x, y, w, h: Integer);
1098 var i, a, fX, fY, pX, pY, typ: Integer; count, frame: LongInt; t: TGLMultiTexture; tex: TGLTexture;
1099 begin
1100 if Shots <> nil then
1101 begin
1102 for i := 0 to High(Shots) do
1103 begin
1104 typ := Shots[i].ShotType;
1105 if typ <> 0 then
1106 begin
1107 t := ShotTextures[typ];
1108 if t <> nil then
1109 begin
1110 a := 0;
1111 case typ of
1112 WEAPON_ROCKETLAUNCHER, WEAPON_BARON_FIRE, WEAPON_MANCUB_FIRE, WEAPON_SKEL_FIRE:
1113 a := -GetAngle2(Shots[i].Obj.Vel.X, Shots[i].Obj.Vel.Y)
1114 end;
1115 Shots[i].Obj.Lerp(gLerpFactor, fX, fY);
1116 pX := Shots[i].Obj.Rect.Width div 2;
1117 pY := Shots[i].Obj.Rect.Height div 2;
1118 g_Anim_GetFrameByTime(ShotAnim[typ].anim, (gTime - Shots[i].time) DIV GAME_TICK, count, frame);
1119 tex := t.GetTexture(frame);
1120 r_Draw_TextureRepeatRotate(tex, fX, fY, tex.width, tex.height, false, 255, 255, 255, 255, false, pX, pY, a);
1121 end;
1122 end;
1123 end;
1124 end;
1125 // TODO draw g_debug_frames
1126 end;
1127
1128 procedure r_Map_DrawFlags (x, y, w, h: Integer);
1129 var i, dx, fx, fy: Integer; flip: Boolean; t: TGLMultiTexture; tex: TGLTexture;
1130 begin
1131 if gGameSettings.GameMode = GM_CTF then
1132 begin
1133 for i := FLAG_RED to FLAG_BLUE do
1134 begin
1135 if not (gFlags[i].state in [FLAG_STATE_NONE, FLAG_STATE_CAPTURED]) then
1136 begin
1137 gFlags[i].Obj.Lerp(gLerpFactor, fx, fy);
1138 flip := gFlags[i].Direction = TDirection.D_LEFT;
1139 if flip then dx := -1 else dx := +1;
1140 t := FlagTextures[i];
1141 tex := t.GetTexture(FlagFrame);
1142 r_Draw_TextureRepeat(tex, fx + dx, fy + 1, tex.width, tex.height, flip, 255, 255, 255, 255, false)
1143 end;
1144 end;
1145 end;
1146 // TODO g_debug_frames
1147 end;
1148
1149 {$IFDEF ENABLE_SHELLS}
1150 procedure r_Map_DrawShells (x, y, w, h: Integer);
1151 var i, fx, fy, typ: Integer; t: TGLTexture; p: PObj;
1152 begin
1153 if gShells <> nil then
1154 begin
1155 for i := 0 to High(gShells) do
1156 begin
1157 if gShells[i].alive then
1158 begin
1159 typ := gShells[i].SType;
1160 if typ <= SHELL_LAST then
1161 begin
1162 p := @gShells[i].Obj;
1163 if g_Obj_Collide(x, y, w, h, p) then
1164 begin
1165 t := ShellTextures[typ];
1166 if t <> nil then
1167 begin
1168 p.Lerp(gLerpFactor, fx, fy);
1169 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, 255, 255, 255, 255, false, ShellAnim[typ].dx, ShellAnim[typ].dy, gShells[i].RAngle);
1170 end;
1171 end;
1172 end;
1173 end;
1174 end;
1175 end;
1176 end;
1177 {$ENDIF}
1178
1179 procedure r_Map_CalcAspect (ow, oh, nw, nh: LongInt; horizontal: Boolean; out ww, hh: LongInt);
1180 begin
1181 if horizontal then
1182 begin
1183 ww := nw;
1184 hh := nw * oh div ow;
1185 end
1186 else
1187 begin
1188 ww := nh * ow div oh;
1189 hh := nh;
1190 end;
1191 end;
1192
1193 procedure r_Map_CalcSkyParallax (cx, cy, vw, vh, sw, sh, mw, mh: LongInt; out x, y, w, h: LongInt);
1194 const
1195 factor = 120; (* size ratio between view and sky (120%) *)
1196 limit = 100; (* max speed for parallax *)
1197 var
1198 msw, msh, mvw, mvh, svw, svh: LongInt;
1199 begin
1200 msw := vw * factor div 100;
1201 msh := vh * factor div 100;
1202 r_Map_CalcAspect(sw, sh, msw, msh, (sw / sh) <= (msw / msh), w, h);
1203
1204 (* calc x parallax or sky center on speed limit *)
1205 mvw := MAX(1, mw - vw);
1206 svw := w - vw;
1207 if 100 * svw div mvw <= limit then
1208 x := -cx * svw div mvw
1209 else
1210 x := -svw div 2;
1211
1212 (* calc y parallax or sky center on speed limit *)
1213 mvh := MAX(1, mh - vh);
1214 svh := h - vh;
1215 if 100 * svh div mvh <= limit then
1216 y := -cy * svh div mvh
1217 else
1218 y := -svh div 2;
1219
1220 (* handle out of map bounds *)
1221 if x > 0 then x := 0;
1222 if y > 0 then y := 0;
1223 if x < -svw then x := -svw;
1224 if y < -svh then y := -svh;
1225 end;
1226
1227 procedure r_Map_DrawScreenEffect (x, y, w, h, level: Integer; r, g, b: Byte);
1228 var i: Integer;
1229 begin
1230 if level > 0 then
1231 begin
1232 case level of
1233 0..14: i := 0;
1234 15..34: i := 1;
1235 35..54: i := 2;
1236 55..74: i := 3;
1237 75..94: i := 4;
1238 else i := 5
1239 end;
1240 r_Draw_FillRect(x, y, x + w, y + h, r, g, b, i * 50)
1241 end;
1242 end;
1243
1244 procedure r_Map_DrawScreenEffects (x, y, w, h: Integer; p: TPlayer);
1245 begin
1246 if p <> nil then
1247 begin
1248 r_Map_DrawScreenEffect(x, y, w, h, p.pain, 255, 0, 0);
1249 r_Map_DrawScreenEffect(x, y, w, h, p.pickup, 150, 200, 150);
1250 if (p.FMegaRulez[MR_INVUL] >= gTime) and (p.SpawnInvul < gTime) then
1251 begin
1252 if ((p.FMegaRulez[MR_INVUL] - gTime) > 2100) or not ODD((p.FMegaRulez[MR_INVUL] - gTime) div 300) then
1253 r_Draw_InvertRect(x, y, x + w, y + h, 191, 191, 191, 255);
1254 end;
1255 if p.FMegaRulez[MR_SUIT] >= gTime then
1256 begin
1257 if ((p.FMegaRulez[MR_SUIT] - gTime) > 2100) or not ODD((p.FMegaRulez[MR_SUIT] - gTime) div 300) then
1258 r_Draw_FillRect(x, y, x + w, y + h, 0, 96, 0, 55);
1259 end;
1260 if (p.Berserk >= 0) and (p.Berserk >= gTime) and (gFlash = 2) then
1261 begin
1262 r_Draw_FillRect(x, y, x + w, y + h, 255, 0, 0, 55);
1263 end;
1264 end;
1265 end;
1266
1267 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer; player: TPlayer);
1268 var iter: TPanelGrid.Iter; p: PPanel; cx, cy, xx, yy, ww, hh: Integer; sx, sy, sw, sh: LongInt;
1269 begin
1270 cx := camx - w div 2;
1271 cy := camy - h div 2;
1272 xx := x + cx;
1273 yy := y + cy;
1274 ww := w;
1275 hh := h;
1276
1277 if g_dbg_ignore_bounds = false then
1278 begin
1279 if xx + ww > gMapInfo.Width then
1280 xx := gMapInfo.Width - ww;
1281 if yy + hh > gMapInfo.Height then
1282 yy := gMapInfo.Height - hh;
1283 if xx < 0 then
1284 xx := 0;
1285 if yy < 0 then
1286 yy := 0;
1287 cx := xx - x;
1288 cy := yy - y;
1289 end;
1290
1291 if SkyTexture <> nil then
1292 begin
1293 r_Map_CalcSkyParallax(cx, cy, ww, hh, SkyTexture.width, SkyTexture.height, gMapInfo.Width, gMapInfo.Height, sx, sy, sw, sh);
1294 r_Draw_Texture(SkyTexture, x + sx, y + sy, sw, sh, false, 255, 255, 255, 255, false);
1295 end;
1296
1297 plist.Clear;
1298 iter := mapGrid.ForEachInAABB(xx, yy, ww, hh, GridDrawableMask);
1299 for p in iter do
1300 if ((p^.tag and GridTagDoor) <> 0) = p^.door then
1301 plist.Insert(p^);
1302 iter.Release;
1303
1304 glPushMatrix;
1305 glTranslatef(-cx, -cy, 0);
1306 r_Map_DrawPanelType(PANEL_BACK);
1307 r_Map_DrawPanelType(PANEL_STEP);
1308 r_Map_DrawItems(xx, yy, ww, hh, false);
1309 r_Map_DrawShots(xx, yy, ww, hh);
1310 {$IFDEF ENABLE_SHELLS}
1311 r_Map_DrawShells(xx, yy, ww, hh);
1312 {$ENDIF}
1313 r_Map_DrawPlayers(xx, yy, ww, hh, player);
1314 {$IFDEF ENABLE_GIBS}
1315 r_Map_DrawGibs(xx, yy, ww, hh);
1316 {$ENDIF}
1317 {$IFDEF ENABLE_CORPSES}
1318 r_Map_DrawCorpses(xx, yy, ww, hh);
1319 {$ENDIF}
1320 r_Map_DrawPanelType(PANEL_WALL);
1321 r_Map_DrawMonsters(xx, yy, ww, hh);
1322 r_Map_DrawItems(xx, yy, ww, hh, true);
1323 r_Map_DrawPanelType(PANEL_CLOSEDOOR);
1324 {$IFDEF ENABLE_GFX}
1325 r_Map_DrawParticles(xx, yy, ww, hh);
1326 r_Map_DrawGFX(xx, yy, ww, hh);
1327 {$ENDIF}
1328 r_Map_DrawFlags(xx, yy, ww, hh);
1329 r_Map_DrawPanelType(PANEL_ACID1);
1330 r_Map_DrawPanelType(PANEL_ACID2);
1331 r_Map_DrawPanelType(PANEL_WATER);
1332 r_Map_DrawPanelType(PANEL_FORE);
1333 // TODO draw monsters health bar
1334 // TODO draw players health bar
1335 // TODO draw players indicators
1336 glPopMatrix;
1337
1338 r_Map_DrawScreenEffects(x, y, w, h, player);
1339
1340 // TODO draw minimap (gShowMap)
1341 // TODO draw g_debug_player
1342 end;
1343
1344 procedure r_Map_Update;
1345 var i, count, tick: LongInt;
1346 begin
1347 tick := gTime div GAME_TICK;
1348 for i := 0 to ITEM_LAST do
1349 g_Anim_GetFrameByTime(ItemAnim[i].anim, tick, count, Items[i].frame);
1350 r_Map_UpdateGFX(tick);
1351 g_Anim_GetFrameByTime(FlagAnim, tick, count, FlagFrame);
1352 end;
1353
1354 end.
[MIRROR] a port of Doom 2D Forever to FPC/SDL
[25/02/2024 19:55:35]
DEADSOFTWARE 2012-2024