src/game/g_main.pas

   1 (* Copyright (C)  Doom 2D: Forever Developers
   2  *
   3  * This program is free software: you can redistribute it and/or modify
   4  * it under the terms of the GNU General Public License as published by
   5  * the Free Software Foundation, version 3 of the License ONLY.
   6  *
   7  * This program is distributed in the hope that it will be useful,
   8  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   9  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  10  * GNU General Public License for more details.
  11  *
  12  * You should have received a copy of the GNU General Public License
  13  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  14  *)
  15 {$INCLUDE ../shared/a_modes.inc}
  16 unit g_main;
  17
  18 interface
  19
  20   uses Utils;
  21
  22 procedure Main ();
  23 procedure Init ();
  24 procedure Release ();
  25 procedure Update ();
  26 procedure Draw ();
  27 procedure KeyPress (K: Word);
  28 procedure CharPress (C: AnsiChar);
  29
  30 var
  31   {--- Read-only dirs ---}
  32   GameWAD: string;
  33   DataDirs: SSArray;
  34   ModelDirs: SSArray;
  35   MegawadDirs: SSArray;
  36   MapDirs: SSArray;
  37   WadDirs: SSArray;
  38   AllMapDirs: SSArray; // Maps + Megawads
  39
  40   {--- Read-Write dirs ---}
  41   LogFileName: string;
  42   LogDirs: SSArray;
  43   SaveDirs: SSArray;
  44   CacheDirs: SSArray;
  45   ConfigDirs: SSArray;
  46   ScreenshotDirs: SSArray;
  47   StatsDirs: SSArray;
  48   MapDownloadDirs: SSArray;
  49   WadDownloadDirs: SSArray;
  50
  51   GameWADName: string = 'GAME';
  52
  53 implementation
  54
  55 uses
  56 {$INCLUDE ../nogl/noGLuses.inc}
  57 {$IFDEF ENABLE_HOLMES}
  58   g_holmes, sdlcarcass, fui_ctls, fui_wadread, fui_style, fui_gfx_gl,
  59 {$ENDIF}
  60 {$IFDEF LINUX}
  61   BaseUnix,
  62 {$ENDIF}
  63 {$IFDEF DARWIN}
  64   MacOSAll, CocoaAll,
  65 {$ENDIF}
  66 {$IFDEF USE_SDL2}
  67   SDL2,
  68 {$ENDIF}
  69   wadreader, e_log, g_window,
  70   e_graphics, e_input, g_game, g_console, g_gui,
  71   e_sound, g_options, g_sound, g_player, g_basic,
  72   g_weapons, SysUtils, g_triggers, MAPDEF, g_map, e_res,
  73   g_menu, g_language, g_net, g_touch, g_system, g_res_downloader,
  74   conbuf, envvars,
  75   xparser;
  76
  77
  78 var
  79   charbuff: packed array [0..15] of AnsiChar;
  80   binPath: AnsiString = '';
  81   forceBinDir: Boolean;
  82
  83 function GetBinaryPath (): AnsiString;
  84 {$IFDEF LINUX}
  85 var
  86   //cd: AnsiString;
  87   sl: AnsiString;
  88 {$ENDIF}
  89 begin
  90   result := ExtractFilePath(ParamStr(0));
  91   {$IFDEF LINUX}
  92   // it may be a symlink; do some guesswork here
  93   sl := fpReadLink(ExtractFileName(ParamStr(0)));
  94   if (sl = ParamStr(0)) then
  95   begin
  96     // use current directory, as we don't have anything better
  97     //result := '.';
  98     GetDir(0, result);
  99   end;
 100   {$ENDIF}
 101   result := fixSlashes(result);
 102   if (length(result) > 0) and (result[length(result)] <> '/') then result := result+'/';
 103 end;
 104
 105 procedure PrintDirs (msg: AnsiString; dirs: SSArray);
 106   var dir: AnsiString;
 107 begin
 108   e_LogWriteln(msg + ':');
 109   for dir in dirs do
 110     e_LogWriteln('  ' + dir);
 111 end;
 112
 113 {$IFDEF DARWIN}
 114   function NSStringToAnsiString (s: NSString): AnsiString;
 115     var i: Integer;
 116   begin
 117     result := '';
 118     for i := 0 to s.length - 1 do
 119       result := result + AnsiChar(s.characterAtIndex(i));
 120   end;
 121
 122   function GetBundlePath (): AnsiString;
 123     var pathRef: CFURLRef; pathCFStr: CFStringRef; pathStr: ShortString;
 124   begin
 125     pathRef := CFBundleCopyBundleURL(CFBundleGetMainBundle());
 126     pathCFStr := CFURLCopyFileSystemPath(pathRef, kCFURLPOSIXPathStyle);
 127     CFStringGetPascalString(pathCFStr, @pathStr, 255, CFStringGetSystemEncoding());
 128     CFRelease(pathRef);
 129     CFRelease(pathCFStr);
 130     Result := pathStr;
 131   end;
 132 {$ENDIF}
 133
 134 procedure InitPath;
 135   var i: Integer; rwdir, rodir: AnsiString; rwdirs, rodirs: SSArray;
 136
 137   procedure AddDir (var dirs: SSArray; append: AnsiString);
 138   begin
 139     SetLength(dirs, Length(dirs) + 1);
 140     dirs[High(dirs)] := ExpandFileName(append)
 141   end;
 142
 143   function IsSep (ch: Char): Boolean;
 144   begin
 145     {$IFDEF WINDOWS}
 146     result := (ch = '/') or (ch = '\');
 147     {$ELSE}
 148     result := (ch = '/');
 149     {$ENDIF}
 150   end;
 151
 152   function OptimizePath (dir: AnsiString): AnsiString;
 153     var i, len: Integer; s: AnsiString;
 154   begin
 155     i := 1; len := Length(dir); s := '';
 156     while i <= len do
 157     begin
 158       if IsSep(dir[i]) then
 159       begin
 160         s := s + DirectorySeparator;
 161         Inc(i);
 162         while (i <= len) and IsSep(dir[i]) do Inc(i);
 163         if (i <= len) and (dir[i] = '.') then
 164         begin
 165           if (i = len) or IsSep(dir[i + 1]) then
 166           begin
 167             Inc(i)
 168           end
 169           else if (i + 1 <= len) and (dir[i + 1] = '.') then
 170           begin
 171             if (i + 1 = len) or IsSep(dir[i + 2]) then
 172             begin
 173               s := e_UpperDir(s);
 174               Inc(i, 2)
 175             end
 176           end
 177         end
 178       end
 179       else
 180       begin
 181         s := s + dir[i];
 182         Inc(i)
 183       end
 184     end;
 185     result := s
 186   end;
 187
 188   procedure OptimizeDirs (var dirs: SSArray);
 189     var i, j, k: Integer;
 190   begin
 191     for i := 0 to High(dirs) do
 192       dirs[i] := OptimizePath(dirs[i]);
 193     // deduplicate
 194     i := High(dirs);
 195     while i >= 0 do
 196     begin
 197       j := 0;
 198       while j < i do
 199       begin
 200         if dirs[j] = dirs[i] then
 201         begin
 202           for k := j + 1 to High(dirs) do
 203             dirs[k - 1] := dirs[k];
 204           Dec(i);
 205           SetLength(dirs, High(dirs))
 206         end
 207         else
 208         begin
 209           Inc(j)
 210         end
 211       end;
 212       Dec(i)
 213     end
 214   end;
 215
 216   procedure AddDef (var dirs: SSArray; base: SSArray; append: AnsiString);
 217     var s: AnsiString;
 218   begin
 219     if Length(dirs) = 0 then
 220       for s in base do
 221         AddDir(dirs, e_CatPath(s, append));
 222     OptimizeDirs(dirs)
 223   end;
 224
 225   function GetDefaultRODirs (): SSArray;
 226     {$IF DEFINED(UNIX) AND NOT DEFINED(DARWIN) AND NOT DEFINED(ANDROID)}
 227       var home: AnsiString;
 228     {$ENDIF}
 229     {$IFDEF WINDOWS}
 230       var appdata: AnsiString;
 231     {$ENDIF}
 232     {$IFDEF DARWIN}
 233       var bundle, s: AnsiString; dirArr: NSArray; i: Integer;
 234     {$ENDIF}
 235   begin
 236     result := nil;
 237     {$IFDEF DARWIN}
 238       bundle := GetBundlePath();
 239       if ExtractFileExt(bundle) <> '.app' then
 240         AddDir(result, binpath);
 241     {$ELSE}
 242       AddDir(result, binPath);
 243     {$ENDIF}
 244     if forceBinDir = false then
 245     begin
 246       {$IFDEF USE_SDL2}
 247         AddDir(result, SDL_GetBasePath());
 248         AddDir(result, SDL_GetPrefPath('', 'doom2df'));
 249       {$ENDIF}
 250       {$IFDEF WINDOWS}
 251         appdata := GetEnvironmentVariable('APPDATA') + '\doom2df';
 252         if appdata <> '' then
 253           AddDir(result, appdata);
 254       {$ENDIF}
 255       {$IF DEFINED(UNIX) AND NOT DEFINED(DARWIN) AND NOT DEFINED(ANDROID)}
 256         AddDir(result, '/usr/share/doom2df');
 257         AddDir(result, '/usr/local/share/doom2df');
 258         home := GetEnvironmentVariable('HOME');
 259         if home <> '' then
 260           AddDir(result, e_CatPath(home, '.doom2df'));
 261       {$ENDIF}
 262       {$IFDEF DARWIN}
 263         bundle := GetBundlePath();
 264         if bundle <> '' then
 265           AddDir(result, e_CatPath(bundle, 'Contents/Resources'));
 266         dirArr := NSSearchPathForDirectoriesInDomains(NSApplicationSupportDirectory, NSUserDomainMask, true);
 267         for i := 0 to dirArr.count - 1 do
 268         begin
 269           s := NSStringToAnsiString(dirArr.objectAtIndex(i));
 270           AddDir(result, e_CatPath(s, 'Doom 2D Forever'))
 271         end;
 272       {$ENDIF}
 273       {$IF DEFINED(ANDROID) AND DEFINED(USE_SDL2)}
 274         AddDir(result, SDL_AndroidGetInternalStoragePath());
 275         if SDL_AndroidGetExternalStorageState() <> 0 then
 276           AddDir(result, SDL_AndroidGetExternalStoragePath());
 277       {$ENDIF}
 278     end
 279   end;
 280
 281   function GetDefaultRWDirs (): SSArray;
 282     {$IF DEFINED(UNIX) AND NOT DEFINED(DARWIN) AND NOT DEFINED(ANDROID)}
 283       var home: AnsiString;
 284     {$ENDIF}
 285     {$IFDEF WINDOWS}
 286       var appdata: AnsiString;
 287     {$ENDIF}
 288     {$IFDEF DARWIN}
 289       var bundle, s: AnsiString; dirArr: NSArray; i: Integer;
 290     {$ENDIF}
 291   begin
 292     result := nil;
 293     {$IFDEF DARWIN}
 294       bundle := GetBundlePath();
 295       if ExtractFileExt(bundle) <> '.app' then
 296         AddDir(result, binPath);
 297     {$ELSE}
 298       AddDir(result, binPath);
 299     {$ENDIF}
 300     if forceBinDir = false then
 301     begin
 302       {$IFDEF USE_SDL2}
 303         AddDir(result, SDL_GetPrefPath('', 'doom2df'));
 304       {$ENDIF}
 305       {$IFDEF WINDOWS}
 306         appdata := GetEnvironmentVariable('APPDATA') + '\doom2df';
 307         if appdata <> '' then
 308           AddDir(result, appdata);
 309       {$ENDIF}
 310       {$IF DEFINED(UNIX) AND NOT DEFINED(DARWIN) AND NOT DEFINED(ANDROID)}
 311         home := GetEnvironmentVariable('HOME');
 312         if home <> '' then
 313           AddDir(result, e_CatPath(home, '.doom2df'));
 314       {$ENDIF}
 315       {$IFDEF DARWIN}
 316         dirArr := NSSearchPathForDirectoriesInDomains(NSApplicationSupportDirectory, NSUserDomainMask, true);
 317         for i := 0 to dirArr.count - 1 do
 318         begin
 319           s := NSStringToAnsiString(dirArr.objectAtIndex(i));
 320           AddDir(result, e_CatPath(s, 'Doom 2D Forever'))
 321         end;
 322       {$ENDIF}
 323       {$IF DEFINED(ANDROID) AND DEFINED(USE_SDL2)}
 324         if SDL_AndroidGetExternalStorageState() <> 0 then
 325           AddDir(result, SDL_AndroidGetExternalStoragePath());
 326       {$ENDIF}
 327     end
 328   end;
 329
 330 begin
 331   forceBinDir := false;
 332   binPath := GetBinaryPath();
 333
 334   i := 1;
 335   while i < ParamCount do
 336   begin
 337     case ParamStr(i) of
 338     '--like-windoze': forceBinDir := true;
 339     '--rw-dir':
 340       begin
 341         Inc(i);
 342         rwdir := ParamStr(i);
 343         (* RW *)
 344         AddDir(LogDirs, e_CatPath(rwdir, ''));
 345         AddDir(SaveDirs, e_CatPath(rwdir, 'data'));
 346         AddDir(CacheDirs, e_CatPath(rwdir, 'data/cache'));
 347         AddDir(ConfigDirs, e_CatPath(rwdir, ''));
 348         AddDir(MapDownloadDirs, e_CatPath(rwdir, 'maps/downloads'));
 349         AddDir(WadDownloadDirs, e_CatPath(rwdir, 'wads/downloads'));
 350         AddDir(ScreenshotDirs, e_CatPath(rwdir, 'screenshots'));
 351         AddDir(StatsDirs, e_CatPath(rwdir, 'stats'));
 352         (* RO *)
 353         AddDir(DataDirs, e_CatPath(rwdir, 'data'));
 354         AddDir(ModelDirs, e_CatPath(rwdir, 'data/models'));
 355         AddDir(MegawadDirs, e_CatPath(rwdir, 'maps/megawads'));
 356         AddDir(MapDirs, e_CatPath(rwdir, 'maps'));
 357         AddDir(WadDirs, e_CatPath(rwdir, 'wads'));
 358       end;
 359     '--ro-dir':
 360       begin
 361         Inc(i);
 362         rodir := ParamStr(i);
 363         (* RO *)
 364         AddDir(DataDirs, e_CatPath(rodir, 'data'));
 365         AddDir(ModelDirs, e_CatPath(rodir, 'data/models'));
 366         AddDir(MegawadDirs, e_CatPath(rodir, 'maps/megawads'));
 367         AddDir(MapDirs, e_CatPath(rodir, 'maps'));
 368         AddDir(WadDirs, e_CatPath(rodir, 'wads'));
 369       end;
 370     '--game-wad':
 371       begin
 372         Inc(i);
 373         GameWADName := ParamStr(i);
 374       end;
 375     end;
 376     Inc(i)
 377   end;
 378
 379   // prefer bin dir if it writable and contains game.wad
 380   if forceBinDir = false then
 381   begin
 382     if findDiskWad(binPath + 'data' + '/' + GameWADName) <> '' then
 383       if e_CanCreateFilesAt(binPath) then
 384         forceBinDir := true
 385   end;
 386
 387   (* RO *)
 388   rodirs := GetDefaultRODirs();
 389   AddDef(DataDirs, rodirs, 'data');
 390   AddDef(ModelDirs, rodirs, 'data/models');
 391   AddDef(MegawadDirs, rodirs, 'maps/megawads');
 392   AddDef(MapDirs, rodirs, 'maps');
 393   AddDef(WadDirs, rodirs, 'wads');
 394
 395   (* RW *)
 396   rwdirs := GetDefaultRWDirs();
 397   AddDef(LogDirs, rwdirs, '');
 398   AddDef(SaveDirs, rwdirs, 'data');
 399   AddDef(CacheDirs, rwdirs, 'data/cache');
 400   AddDef(ConfigDirs, rwdirs, '');
 401   AddDef(MapDownloadDirs, rwdirs, 'maps/downloads');
 402   AddDef(WadDownloadDirs, rwdirs, 'wads/downloads');
 403   AddDef(ScreenshotDirs, rwdirs, 'screenshots');
 404   AddDef(StatsDirs, rwdirs, 'stats');
 405
 406   for i := 0 to High(MapDirs) do
 407     AddDir(AllMapDirs, MapDirs[i]);
 408   for i := 0 to High(MegawadDirs) do
 409     AddDir(AllMapDirs, MegawadDirs[i]);
 410   OptimizeDirs(AllMapDirs);
 411
 412   if LogFileName = '' then
 413   begin
 414     rwdir := e_GetWriteableDir(LogDirs, false);
 415     if rwdir <> '' then
 416     begin
 417       {$IFDEF HEADLESS}
 418         LogFileName := e_CatPath(rwdir, 'Doom2DF_H.log');
 419       {$ELSE}
 420         LogFileName := e_CatPath(rwdir, 'Doom2DF.log');
 421       {$ENDIF}
 422     end
 423   end;
 424
 425   // HACK: ensure the screenshots folder also has a stats subfolder in it
 426   rwdir := e_GetWriteableDir(ScreenshotDirs, false);
 427   if rwdir <> '' then CreateDir(rwdir + '/stats');
 428 end;
 429
 430 procedure InitPrep;
 431   {$IF DEFINED(ANDROID) AND DEFINED(USE_SDLMIXER)}
 432     var timiditycfg: AnsiString;
 433   {$ENDIF}
 434   var i: Integer;
 435 begin
 436   {$IFDEF HEADLESS}
 437     conbufDumpToStdOut := true;
 438   {$ENDIF}
 439   for i := 1 to ParamCount do
 440   begin
 441     if (ParamStr(i) = '--con-stdout') then
 442     begin
 443       conbufDumpToStdOut := true;
 444       break
 445     end
 446   end;
 447
 448   if LogFileName <> '' then
 449     e_InitLog(LogFileName, TWriteMode.WM_NEWFILE);
 450   e_InitWritelnDriver();
 451   e_WriteLog('Doom 2D: Forever version ' + GAME_VERSION + ' proto ' + IntToStr(NET_PROTOCOL_VER), TMsgType.Notify);
 452   e_WriteLog('Build date: ' + GAME_BUILDDATE + ' ' + GAME_BUILDTIME, TMsgType.Notify);
 453   e_WriteLog('Build hash: ' + g_GetBuildHash(), TMsgType.Notify);
 454   e_WriteLog('Build by: ' + g_GetBuilderName(), TMsgType.Notify);
 455
 456   e_LogWritefln('Force bin dir: %s', [forceBinDir], TMsgType.Notify);
 457   e_LogWritefln('BINARY PATH: [%s]', [binPath], TMsgType.Notify);
 458
 459   PrintDirs('DataDirs', DataDirs);
 460   PrintDirs('ModelDirs', ModelDirs);
 461   PrintDirs('MegawadDirs', MegawadDirs);
 462   PrintDirs('MapDirs', MapDirs);
 463   PrintDirs('WadDirs', WadDirs);
 464
 465   PrintDirs('LogDirs', LogDirs);
 466   PrintDirs('SaveDirs', SaveDirs);
 467   PrintDirs('CacheDirs', CacheDirs);
 468   PrintDirs('ConfigDirs', ConfigDirs);
 469   PrintDirs('ScreenshotDirs', ScreenshotDirs);
 470   PrintDirs('StatsDirs', StatsDirs);
 471   PrintDirs('MapDownloadDirs', MapDownloadDirs);
 472   PrintDirs('WadDownloadDirs', WadDownloadDirs);
 473
 474   GameWAD := e_FindWad(DataDirs, GameWADName);
 475   if GameWad = '' then
 476   begin
 477     e_WriteLog('WAD ' + GameWADName + ' not found in data directories.', TMsgType.Fatal);
 478     {$IF DEFINED(USE_SDL2) AND NOT DEFINED(HEADLESS)}
 479       if forceBinDir = false then
 480         SDL_ShowSimpleMessageBox(
 481           SDL_MESSAGEBOX_ERROR,
 482           'Doom 2D Forever',
 483           PChar('WAD ' + GameWADName + ' not found in data directories.'),
 484           nil
 485         );
 486     {$ENDIF}
 487     e_DeinitLog;
 488     Halt(1);
 489   end;
 490
 491   {$IF DEFINED(ANDROID) AND DEFINED(USE_SDLMIXER)}
 492     timiditycfg := 'timidity.cfg';
 493     if e_FindResource(ConfigDirs, timiditycfg) = true then
 494     begin
 495       timiditycfg := ExpandFileName(timiditycfg);
 496       SetEnvVar('TIMIDITY_CFG', timiditycfg);
 497       e_LogWritefln('Set TIMIDITY_CFG = "%s"', [timiditycfg]);
 498     end;
 499   {$ENDIF}
 500 end;
 501
 502 procedure Main();
 503 {$IFDEF ENABLE_HOLMES}
 504   var flexloaded: Boolean;
 505 {$ENDIF}
 506   var s: AnsiString;
 507 begin
 508   InitPath;
 509   InitPrep;
 510   e_InitInput;
 511   sys_Init;
 512
 513   g_Options_SetDefault;
 514   g_Options_SetDefaultVideo;
 515   s := CONFIG_FILENAME;
 516   if e_FindResource(ConfigDirs, s) = true then
 517     g_Options_Read(s);
 518   g_Console_SysInit;
 519   if sys_SetDisplayMode(gRC_Width, gRC_Height, gBPP, gRC_FullScreen, gRC_Maximized) = False then
 520     raise Exception.Create('Failed to set videomode on startup.');
 521
 522   e_WriteLog(gLanguage, TMsgType.Notify);
 523   g_Language_Set(gLanguage);
 524
 525 {$IF not DEFINED(HEADLESS) and DEFINED(ENABLE_HOLMES)}
 526   flexloaded := true;
 527   if not fuiAddWad('flexui.wad') then
 528   begin
 529     if not fuiAddWad('./data/flexui.wad') then fuiAddWad('./flexui.wad');
 530   end;
 531   try
 532     fuiGfxLoadFont('win8', 'flexui/fonts/win8.fuifont');
 533     fuiGfxLoadFont('win14', 'flexui/fonts/win14.fuifont');
 534     fuiGfxLoadFont('win16', 'flexui/fonts/win16.fuifont');
 535     fuiGfxLoadFont('dos8', 'flexui/fonts/dos8.fuifont');
 536     fuiGfxLoadFont('msx6', 'flexui/fonts/msx6.fuifont');
 537   except on e: Exception do
 538     begin
 539       writeln('ERROR loading FlexUI fonts');
 540       flexloaded := false;
 541       //raise;
 542     end;
 543   else
 544     begin
 545       flexloaded := false;
 546       //raise;
 547     end;
 548   end;
 549   if (flexloaded) then
 550   begin
 551     try
 552       e_LogWriteln('FlexUI: loading stylesheet...');
 553       uiLoadStyles('flexui/widgets.wgs');
 554     except on e: TParserException do
 555       begin
 556         writeln('ERROR at (', e.tokLine, ',', e.tokCol, '): ', e.message);
 557         //raise;
 558         flexloaded := false;
 559       end;
 560     else
 561       begin
 562         //raise;
 563         flexloaded := false;
 564       end;
 565     end;
 566   end;
 567   g_holmes_imfunctional := not flexloaded;
 568
 569   if (not g_holmes_imfunctional) then
 570   begin
 571     uiInitialize();
 572     uiContext.font := 'win14';
 573   end;
 574
 575   if assigned(oglInitCB) then oglInitCB;
 576 {$ENDIF}
 577
 578   //g_Res_CreateDatabases(true); // it will be done before connecting to the server for the first time
 579
 580   e_WriteLog('Entering SDLMain', TMsgType.Notify);
 581
 582   {$WARNINGS OFF}
 583     SDLMain();
 584   {$WARNINGS ON}
 585
 586   {$IFDEF ENABLE_HOLMES}
 587     if assigned(oglDeinitCB) then oglDeinitCB;
 588   {$ENDIF}
 589
 590   g_Console_WriteGameConfig;
 591   sys_Final;
 592 end;
 593
 594 procedure Init();
 595 var
 596   NoSound: Boolean;
 597 begin
 598   Randomize;
 599
 600 {$IFDEF HEADLESS}
 601  {$IFDEF USE_SDLMIXER}
 602   NoSound := False; // hope env has set SDL_AUDIODRIVER to dummy
 603  {$ELSE}
 604   NoSound := True; // FMOD backend will sort it out
 605  {$ENDIF}
 606 {$ELSE}
 607   NoSound := False;
 608 {$ENDIF}
 609
 610   g_Touch_Init;
 611
 612 (*
 613   if (e_JoysticksAvailable > 0) then
 614     e_WriteLog('Input: Joysticks available.', TMsgType.Notify)
 615   else
 616     e_WriteLog('Input: No Joysticks.', TMsgType.Notify);
 617 *)
 618
 619   if (not gNoSound) then
 620   begin
 621     e_WriteLog('Initializing sound system', TMsgType.Notify);
 622     e_InitSoundSystem(NoSound);
 623   end;
 624
 625   e_WriteLog('Init game', TMsgType.Notify);
 626   g_Game_Init();
 627
 628   FillChar(charbuff, sizeof(charbuff), ' ');
 629 end;
 630
 631
 632 procedure Release();
 633 begin
 634   e_WriteLog('Releasing engine', TMsgType.Notify);
 635   e_ReleaseEngine();
 636
 637   e_WriteLog('Releasing input', TMsgType.Notify);
 638   e_ReleaseInput();
 639
 640   if not gNoSound then
 641   begin
 642     e_WriteLog('Releasing sound', TMsgType.Notify);
 643     e_ReleaseSoundSystem();
 644   end;
 645 end;
 646
 647
 648 procedure Update ();
 649 begin
 650   g_Game_Update();
 651 end;
 652
 653
 654 procedure Draw ();
 655 begin
 656   g_Game_Draw();
 657 end;
 658
 659
 660 function Translit (const S: AnsiString): AnsiString;
 661 var
 662   i: Integer;
 663 begin
 664   Result := S;
 665   for i := 1 to Length(Result) do
 666   begin
 667     case Result[i] of
 668       'É': Result[i] := 'Q';
 669       'Ö': Result[i] := 'W';
 670       'Ó': Result[i] := 'E';
 671       'Ê': Result[i] := 'R';
 672       'Å': Result[i] := 'T';
 673       'Í': Result[i] := 'Y';
 674       'Ã': Result[i] := 'U';
 675       'Ø': Result[i] := 'I';
 676       'Ù': Result[i] := 'O';
 677       'Ç': Result[i] := 'P';
 678       'Õ': Result[i] := '['; //Chr(219);
 679       'Ú': Result[i] := ']'; //Chr(221);
 680       'Ô': Result[i] := 'A';
 681       'Û': Result[i] := 'S';
 682       'Â': Result[i] := 'D';
 683       'À': Result[i] := 'F';
 684       'Ï': Result[i] := 'G';
 685       'Ð': Result[i] := 'H';
 686       'Î': Result[i] := 'J';
 687       'Ë': Result[i] := 'K';
 688       'Ä': Result[i] := 'L';
 689       'Æ': Result[i] := ';'; //Chr(186);
 690       'Ý': Result[i] := #39; //Chr(222);
 691       'ß': Result[i] := 'Z';
 692       '×': Result[i] := 'X';
 693       'Ñ': Result[i] := 'C';
 694       'Ì': Result[i] := 'V';
 695       'È': Result[i] := 'B';
 696       'Ò': Result[i] := 'N';
 697       'Ü': Result[i] := 'M';
 698       'Á': Result[i] := ','; //Chr(188);
 699       'Þ': Result[i] := '.'; //Chr(190);
 700     end;
 701   end;
 702 end;
 703
 704
 705 function CheckCheat (ct: TStrings_Locale; eofs: Integer=0): Boolean;
 706 var
 707   ls1, ls2: string;
 708 begin
 709   ls1 :=          CheatEng[ct];
 710   ls2 := Translit(CheatRus[ct]);
 711   if length(ls1) = 0 then ls1 := '~';
 712   if length(ls2) = 0 then ls2 := '~';
 713   result :=
 714     (Copy(charbuff, 17-Length(ls1)-eofs, Length(ls1)) = ls1) or
 715     (Translit(Copy(charbuff, 17-Length(ls1)-eofs, Length(ls1))) = ls1) or
 716     (Copy(charbuff, 17-Length(ls2)-eofs, Length(ls2)) = ls2) or
 717     (Translit(Copy(charbuff, 17-Length(ls2)-eofs, Length(ls2))) = ls2);
 718   {
 719   if ct = I_GAME_CHEAT_JETPACK then
 720   begin
 721     e_WriteLog('ls1: ['+ls1+']', MSG_NOTIFY);
 722     e_WriteLog('ls2: ['+ls2+']', MSG_NOTIFY);
 723     e_WriteLog('bf0: ['+Copy(charbuff, 17-Length(ls1)-eofs, Length(ls1))+']', MSG_NOTIFY);
 724     e_WriteLog('bf1: ['+Translit(Copy(charbuff, 17-Length(ls1)-eofs, Length(ls1)))+']', MSG_NOTIFY);
 725     e_WriteLog('bf2: ['+Copy(charbuff, 17-Length(ls2)-eofs, Length(ls2))+']', MSG_NOTIFY);
 726     e_WriteLog('bf3: ['+Translit(Copy(charbuff, 17-Length(ls2)-eofs, Length(ls2)))+']', MSG_NOTIFY);
 727   end;
 728   }
 729 end;
 730
 731
 732 procedure Cheat ();
 733 const
 734   CHEAT_DAMAGE = 500;
 735 label
 736   Cheated;
 737 var
 738   s, s2: string;
 739   c: ShortString;
 740   a: Integer;
 741 begin
 742   {
 743   if (not gGameOn) or (not gCheats) or ((gGameSettings.GameType <> GT_SINGLE) and
 744     (gGameSettings.GameMode <> GM_COOP) and (not gDebugMode))
 745     or g_Game_IsNet then Exit;
 746   }
 747   if not gGameOn then exit;
 748   if not conIsCheatsEnabled then exit;
 749
 750   s := 'SOUND_GAME_RADIO';
 751
 752   //
 753   if CheckCheat(I_GAME_CHEAT_GODMODE) then
 754   begin
 755     if gPlayer1 <> nil then gPlayer1.GodMode := not gPlayer1.GodMode;
 756     if gPlayer2 <> nil then gPlayer2.GodMode := not gPlayer2.GodMode;
 757     goto Cheated;
 758   end;
 759   // RAMBO
 760   if CheckCheat(I_GAME_CHEAT_WEAPONS) then
 761   begin
 762     if gPlayer1 <> nil then gPlayer1.AllRulez(False);
 763     if gPlayer2 <> nil then gPlayer2.AllRulez(False);
 764     goto Cheated;
 765   end;
 766   // TANK
 767   if CheckCheat(I_GAME_CHEAT_HEALTH) then
 768   begin
 769     if gPlayer1 <> nil then gPlayer1.AllRulez(True);
 770     if gPlayer2 <> nil then gPlayer2.AllRulez(True);
 771     goto Cheated;
 772   end;
 773   // IDDQD
 774   if CheckCheat(I_GAME_CHEAT_DEATH) then
 775   begin
 776     if gPlayer1 <> nil then gPlayer1.Damage(CHEAT_DAMAGE, 0, 0, 0, HIT_TRAP);
 777     if gPlayer2 <> nil then gPlayer2.Damage(CHEAT_DAMAGE, 0, 0, 0, HIT_TRAP);
 778     s := 'SOUND_MONSTER_HAHA';
 779     goto Cheated;
 780   end;
 781   //
 782   if CheckCheat(I_GAME_CHEAT_DOORS) then
 783   begin
 784     g_Triggers_OpenAll();
 785     goto Cheated;
 786   end;
 787   // GOODBYE
 788   if CheckCheat(I_GAME_CHEAT_NEXTMAP) then
 789   begin
 790     if gTriggers <> nil then
 791       for a := 0 to High(gTriggers) do
 792         if gTriggers[a].TriggerType = TRIGGER_EXIT then
 793         begin
 794           gExitByTrigger := True;
 795           //g_Game_ExitLevel(gTriggers[a].Data.MapName);
 796           g_Game_ExitLevel(gTriggers[a].tgcMap);
 797           Break;
 798         end;
 799     goto Cheated;
 800   end;
 801   //
 802   s2 := Copy(charbuff, 15, 2);
 803   if CheckCheat(I_GAME_CHEAT_CHANGEMAP, 2) and (s2[1] >= '0') and (s2[1] <= '9') and (s2[2] >= '0') and (s2[2] <= '9') then
 804   begin
 805     if g_Map_Exist(gGameSettings.WAD + ':\MAP' + s2) then
 806     begin
 807       c := 'MAP' + s2;
 808       g_Game_ExitLevel(c);
 809     end;
 810     goto Cheated;
 811   end;
 812   //
 813   if CheckCheat(I_GAME_CHEAT_FLY) then
 814   begin
 815     gFly := not gFly;
 816     goto Cheated;
 817   end;
 818   // BULLFROG
 819   if CheckCheat(I_GAME_CHEAT_JUMPS) then
 820   begin
 821     VEL_JUMP := 30-VEL_JUMP;
 822     goto Cheated;
 823   end;
 824   // FORMULA1
 825   if CheckCheat(I_GAME_CHEAT_SPEED) then
 826   begin
 827     MAX_RUNVEL := 32-MAX_RUNVEL;
 828     goto Cheated;
 829   end;
 830   // CONDOM
 831   if CheckCheat(I_GAME_CHEAT_SUIT) then
 832   begin
 833     if gPlayer1 <> nil then gPlayer1.GiveItem(ITEM_SUIT);
 834     if gPlayer2 <> nil then gPlayer2.GiveItem(ITEM_SUIT);
 835     goto Cheated;
 836   end;
 837   //
 838   if CheckCheat(I_GAME_CHEAT_AIR) then
 839   begin
 840     if gPlayer1 <> nil then gPlayer1.GiveItem(ITEM_OXYGEN);
 841     if gPlayer2 <> nil then gPlayer2.GiveItem(ITEM_OXYGEN);
 842     goto Cheated;
 843   end;
 844   // PURELOVE
 845   if CheckCheat(I_GAME_CHEAT_BERSERK) then
 846   begin
 847     if gPlayer1 <> nil then gPlayer1.GiveItem(ITEM_MEDKIT_BLACK);
 848     if gPlayer2 <> nil then gPlayer2.GiveItem(ITEM_MEDKIT_BLACK);
 849     goto Cheated;
 850   end;
 851   //
 852   if CheckCheat(I_GAME_CHEAT_JETPACK) then
 853   begin
 854     if gPlayer1 <> nil then gPlayer1.GiveItem(ITEM_JETPACK);
 855     if gPlayer2 <> nil then gPlayer2.GiveItem(ITEM_JETPACK);
 856     goto Cheated;
 857   end;
 858   // CASPER
 859   if CheckCheat(I_GAME_CHEAT_NOCLIP) then
 860   begin
 861     if gPlayer1 <> nil then gPlayer1.SwitchNoClip;
 862     if gPlayer2 <> nil then gPlayer2.SwitchNoClip;
 863     goto Cheated;
 864   end;
 865   //
 866   if CheckCheat(I_GAME_CHEAT_NOTARGET) then
 867   begin
 868     if gPlayer1 <> nil then gPlayer1.NoTarget := not gPlayer1.NoTarget;
 869     if gPlayer2 <> nil then gPlayer2.NoTarget := not gPlayer2.NoTarget;
 870     goto Cheated;
 871   end;
 872   // INFERNO
 873   if CheckCheat(I_GAME_CHEAT_NORELOAD) then
 874   begin
 875     if gPlayer1 <> nil then gPlayer1.NoReload := not gPlayer1.NoReload;
 876     if gPlayer2 <> nil then gPlayer2.NoReload := not gPlayer2.NoReload;
 877     goto Cheated;
 878   end;
 879   if CheckCheat(I_GAME_CHEAT_AIMLINE) then
 880   begin
 881     gAimLine := not gAimLine;
 882     goto Cheated;
 883   end;
 884   if CheckCheat(I_GAME_CHEAT_AUTOMAP) then
 885   begin
 886     gShowMap := not gShowMap;
 887     goto Cheated;
 888   end;
 889   Exit;
 890
 891 Cheated:
 892   g_Sound_PlayEx(s);
 893 end;
 894
 895
 896 procedure KeyPress (K: Word);
 897 {$IFNDEF HEADLESS}
 898 var
 899   Msg: g_gui.TMessage;
 900 {$ENDIF}
 901 begin
 902 {$IFNDEF HEADLESS}
 903   case K of
 904     VK_ESCAPE: // <Esc>:
 905       begin
 906         if (g_ActiveWindow <> nil) then
 907         begin
 908           Msg.Msg := WM_KEYDOWN;
 909           Msg.WParam := VK_ESCAPE;
 910           g_ActiveWindow.OnMessage(Msg);
 911           if (not g_Game_IsNet) and (g_ActiveWindow = nil) then g_Game_Pause(false); //Fn loves to do this
 912         end
 913         else if (gState <> STATE_FOLD) then
 914         begin
 915           if gGameOn or (gState = STATE_INTERSINGLE) or (gState = STATE_INTERCUSTOM) then
 916           begin
 917             g_Game_InGameMenu(True);
 918           end
 919           else if (gExit = 0) and (gState <> STATE_SLIST) then
 920           begin
 921             if (gState <> STATE_MENU) then
 922             begin
 923               if (NetMode <> NET_NONE) then
 924               begin
 925                 g_Game_StopAllSounds(True);
 926                 g_Game_Free;
 927                 gState := STATE_MENU;
 928                 Exit;
 929               end;
 930             end;
 931             g_GUI_ShowWindow('MainMenu');
 932             g_Sound_PlayEx('MENU_OPEN');
 933           end;
 934         end;
 935       end;
 936
 937     IK_F2, IK_F3, IK_F4, IK_F5, IK_F6, IK_F7, IK_F10:
 938       begin // <F2> .. <F6> � <F12>
 939         if gGameOn and (not gConsoleShow) and (not gChatShow) then
 940         begin
 941           while (g_ActiveWindow <> nil) do g_GUI_HideWindow(False);
 942           if (not g_Game_IsNet) then g_Game_Pause(True);
 943           case K of
 944             IK_F2: g_Menu_Show_SaveMenu();
 945             IK_F3: g_Menu_Show_LoadMenu();
 946             IK_F4: g_Menu_Show_GameSetGame();
 947             IK_F5: g_Menu_Show_OptionsVideo();
 948             IK_F6: g_Menu_Show_OptionsSound();
 949             IK_F7: g_Menu_Show_EndGameMenu();
 950             IK_F10: g_Menu_Show_QuitGameMenu();
 951           end;
 952         end;
 953       end;
 954
 955     else
 956       begin
 957         gJustChatted := False;
 958         if gConsoleShow or gChatShow then
 959         begin
 960           g_Console_Control(K);
 961         end
 962         else if (g_ActiveWindow <> nil) then
 963         begin
 964           Msg.Msg := WM_KEYDOWN;
 965           Msg.WParam := K;
 966           g_ActiveWindow.OnMessage(Msg);
 967         end
 968         else if (gState = STATE_MENU) then
 969         begin
 970           g_GUI_ShowWindow('MainMenu');
 971           g_Sound_PlayEx('MENU_OPEN');
 972         end;
 973       end;
 974   end;
 975 {$ENDIF}
 976 end;
 977
 978
 979 procedure CharPress (C: AnsiChar);
 980 var
 981   Msg: g_gui.TMessage;
 982   a: Integer;
 983 begin
 984   if gConsoleShow or gChatShow then
 985   begin
 986     g_Console_Char(C)
 987   end
 988   else if (g_ActiveWindow <> nil) then
 989   begin
 990     Msg.Msg := WM_CHAR;
 991     Msg.WParam := Ord(C);
 992     g_ActiveWindow.OnMessage(Msg);
 993   end
 994   else
 995   begin
 996     for a := 0 to 14 do charbuff[a] := charbuff[a+1];
 997     charbuff[15] := upcase1251(C);
 998     Cheat();
 999   end;
1000 end;
1001
1002 end.