src/game/sdl/g_system.pas

   1 (* Copyright (C)  Doom 2D: Forever Developers
   2  *
   3  * This program is free software: you can redistribute it and/or modify
   4  * it under the terms of the GNU General Public License as published by
   5  * the Free Software Foundation, version 3 of the License ONLY.
   6  *
   7  * This program is distributed in the hope that it will be useful,
   8  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   9  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  10  * GNU General Public License for more details.
  11  *
  12  * You should have received a copy of the GNU General Public License
  13  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  14  *)
  15 {$INCLUDE ../shared/a_modes.inc}
  16 unit g_system;
  17
  18 interface
  19
  20   uses Utils;
  21
  22   (* --- Utils --- *)
  23   function sys_GetTicks (): Int64;
  24   procedure sys_Delay (ms: Integer);
  25
  26   (* --- Graphics --- *)
  27   function sys_GetDisplayModes (bpp: Integer): SSArray;
  28   function sys_SetDisplayMode (w, h, bpp: Integer; fullscreen: Boolean): Boolean;
  29   procedure sys_EnableVSync (yes: Boolean);
  30   procedure sys_Repaint;
  31
  32   (* --- Input --- *)
  33   function sys_HandleInput (): Boolean;
  34   procedure sys_RequestQuit;
  35
  36   (* --- Init --- *)
  37   procedure sys_Init;
  38   procedure sys_Final;
  39
  40 implementation
  41
  42   uses
  43     SysUtils, SDL, Math,
  44     {$INCLUDE ../nogl/noGLuses.inc}
  45     e_log, e_graphics, e_input, e_sound,
  46     g_options, g_window, g_console, g_game, g_menu, g_gui, g_main, g_basic;
  47
  48   const
  49     GameTitle = 'Doom 2D: Forever (SDL 1.2, %s)';
  50
  51   var
  52     userResize: Boolean;
  53     modeResize: Integer;
  54     screen: PSDL_Surface;
  55     JoystickHandle: array [0..e_MaxJoys - 1] of PSDL_Joystick;
  56     JoystickHatState: array [0..e_MaxJoys - 1, 0..e_MaxJoyHats - 1, HAT_LEFT..HAT_DOWN] of Boolean;
  57     JoystickZeroAxes: array [0..e_MaxJoys - 1, 0..e_MaxJoyAxes - 1] of Integer;
  58
  59   (* --------- Utils --------- *)
  60
  61   function sys_GetTicks (): Int64;
  62   begin
  63     result := SDL_GetTicks()
  64   end;
  65
  66   procedure sys_Delay (ms: Integer);
  67   begin
  68     SDL_Delay(ms)
  69   end;
  70
  71   (* --------- Graphics --------- *)
  72
  73   procedure UpdateSize (w, h: Integer);
  74   begin
  75     gWinSizeX := w;
  76     gWinSizeY := h;
  77     gWinRealPosX := 0;
  78     gWinRealPosY := 0;
  79     gScreenWidth := w;
  80     gScreenHeight := h;
  81     {$IFDEF ENABLE_HOLMES}
  82       fuiScrWdt := w;
  83       fuiScrHgt := h;
  84     {$ENDIF}
  85     e_ResizeWindow(w, h);
  86     e_InitGL;
  87     g_Game_SetupScreenSize;
  88     g_Menu_Reset;
  89     g_Game_ClearLoading;
  90   end;
  91
  92   function GetTitle (): PChar;
  93     var info: AnsiString;
  94   begin
  95     info := g_GetBuildHash(false);
  96     if info = 'custom build' then
  97       info := info + ' by ' + g_GetBuilderName() + ' ' + GAME_BUILDDATE + ' ' + GAME_BUILDTIME;
  98     result := PChar(Format(GameTitle, [info]))
  99   end;
 100
 101   function InitWindow (w, h, bpp: Integer; fullScreen: Boolean): Boolean;
 102     var flags: Uint32;
 103   begin
 104     e_LogWritefln('InitWindow %s %s %s %s', [w, h, bpp, fullScreen]);
 105     result := False;
 106     SDL_GL_SetAttribute(SDL_GL_RED_SIZE, 8);
 107     SDL_GL_SetAttribute(SDL_GL_GREEN_SIZE, 8);
 108     SDL_GL_SetAttribute(SDL_GL_BLUE_SIZE, 8);
 109     SDL_GL_SetAttribute(SDL_GL_DEPTH_SIZE, 16);
 110     SDL_GL_SetAttribute(SDL_GL_DOUBLEBUFFER, 1);
 111     SDL_GL_SetAttribute(SDL_GL_STENCIL_SIZE, 8); // lights; it is enough to have 1-bit stencil buffer for lighting, but...
 112     flags := SDL_OPENGL;
 113     if fullScreen then flags := flags or SDL_FULLSCREEN;
 114     if userResize then flags := flags or SDL_VIDEORESIZE;
 115     if (screen = nil) or (SDL_VideoModeOk(w, h, bpp, flags) <> 0) then
 116     begin
 117       SDL_FreeSurface(screen);
 118       screen := SDL_SetVideoMode(w, h, bpp, flags);
 119       if screen <> nil then
 120       begin
 121         {$IFDEF NOGL_INIT}
 122           nogl_Init;
 123         {$ENDIF}
 124         SDL_WM_SetCaption(GetTitle(), nil);
 125         UpdateSize(w, h);
 126         result := True
 127       end
 128     end
 129     else
 130     begin
 131       e_LogWritefln('SDL: video mode not supported', [])
 132     end
 133   end;
 134
 135   procedure sys_Repaint;
 136   begin
 137     SDL_GL_SwapBuffers
 138   end;
 139
 140   procedure sys_EnableVSync (yes: Boolean);
 141   begin
 142     (* ??? *)
 143   end;
 144
 145   function sys_GetDisplayModes (bpp: Integer): SSArray;
 146     var m: PPSDL_Rect; f: TSDL_PixelFormat; i, count: Integer;
 147   begin
 148     SetLength(result, 0);
 149     FillChar(f, sizeof(f), 0);
 150     f.palette := nil;
 151     f.BitsPerPixel := bpp;
 152     f.BytesPerPixel := (bpp + 7) div 8;
 153     m := SDL_ListModes(@f, SDL_OPENGL or SDL_FULLSCREEN);
 154     if (m <> NIL) and (UIntPtr(m) <> UIntPtr(-1)) then
 155     begin
 156       count := 0;
 157       while m[count] <> nil do inc(count);
 158       SetLength(result, count);
 159       for i := 0 to count - 1 do
 160         result[i] := IntToStr(m[i].w) + 'x' + IntToStr(m[i].h);
 161     end
 162   end;
 163
 164   function sys_SetDisplayMode (w, h, bpp: Integer; fullscreen: Boolean): Boolean;
 165   begin
 166     result := InitWindow(w, h, bpp, fullscreen)
 167   end;
 168
 169   (* --------- Joystick --------- *)
 170
 171   procedure HandleJoyButton (var ev: TSDL_JoyButtonEvent);
 172     var down: Boolean; key: Integer;
 173   begin
 174     if (ev.which < e_MaxJoys) and (ev.button < e_MaxJoyBtns) then
 175     begin
 176       key := e_JoyButtonToKey(ev.which, ev.button);
 177       down := ev.type_ = SDL_JOYBUTTONDOWN;
 178       if g_dbg_input then
 179         e_LogWritefln('Input Debug: jbutton, joy=%s, button=%s, keycode=%s, press=%s', [ev.which, ev.button, key, down]);
 180       e_KeyUpDown(key, down);
 181       g_Console_ProcessBind(key, down)
 182     end
 183     else
 184     begin
 185       if g_dbg_input then
 186       begin
 187         down := ev.type_ = SDL_JOYBUTTONDOWN;
 188         e_LogWritefln('Input Debug: NOT IN RANGE! jbutton, joy=%s, button=%s, press=%s', [ev.which, ev.button, down])
 189       end
 190     end
 191   end;
 192
 193   procedure HandleJoyAxis (var ev: TSDL_JoyAxisEvent);
 194     var key, minuskey: Integer;
 195   begin
 196     if (ev.which < e_MaxJoys) and (ev.axis < e_MaxJoyAxes) then
 197     begin
 198       key := e_JoyAxisToKey(ev.which, ev.axis, AX_PLUS);
 199       minuskey := e_JoyAxisToKey(ev.which, ev.axis, AX_MINUS);
 200
 201       if g_dbg_input then
 202           e_LogWritefln('Input Debug: jaxis, joy=%s, axis=%s, value=%s, zeroaxes=%s, deadzone=%s', [ev.which, ev.axis, ev.value, JoystickZeroAxes[ev.which, ev.axis], e_JoystickDeadzones[ev.which]]);
 203
 204       if ev.value < JoystickZeroAxes[ev.which, ev.axis] - e_JoystickDeadzones[ev.which] then
 205       begin
 206         if (e_KeyPressed(key)) then
 207         begin
 208           e_KeyUpDown(key, False);
 209           g_Console_ProcessBind(key, False)
 210         end;
 211         e_KeyUpDown(minuskey, True);
 212         g_Console_ProcessBind(minuskey, True)
 213       end
 214       else if ev.value > JoystickZeroAxes[ev.which, ev.axis] + e_JoystickDeadzones[ev.which] then
 215       begin
 216         if (e_KeyPressed(minuskey)) then
 217         begin
 218           e_KeyUpDown(minuskey, False);
 219           g_Console_ProcessBind(minuskey, False)
 220         end;
 221         e_KeyUpDown(key, True);
 222         g_Console_ProcessBind(key, True)
 223       end
 224       else
 225       begin
 226         if (e_KeyPressed(minuskey)) then
 227         begin
 228           e_KeyUpDown(minuskey, False);
 229           g_Console_ProcessBind(minuskey, False)
 230         end;
 231         if (e_KeyPressed(key)) then
 232         begin
 233           e_KeyUpDown(key, False);
 234           g_Console_ProcessBind(key, False)
 235         end
 236       end
 237     end
 238     else
 239     begin
 240       if g_dbg_input then
 241         e_LogWritefln('Input Debug: NOT IN RANGE! jaxis, joy=%s, axis=%s, value=%s, zeroaxes=%s, deadzone=%s', [ev.which, ev.axis, ev.value, JoystickZeroAxes[ev.which, ev.axis], e_JoystickDeadzones[ev.which]])
 242     end
 243   end;
 244
 245   procedure HandleJoyHat (var ev: TSDL_JoyHatEvent);
 246     var
 247       down: Boolean;
 248       i, key: Integer;
 249       hat: array [HAT_LEFT..HAT_DOWN] of Boolean;
 250   begin
 251     if (ev.which < e_MaxJoys) and (ev.hat < e_MaxJoyHats) then
 252     begin
 253       if g_dbg_input then
 254         e_LogWritefln('Input Debug: jhat, joy=%s, hat=%s, value=%s', [ev.which, ev.hat, ev.value]);
 255       hat[HAT_UP] := LongBool(ev.value and SDL_HAT_UP);
 256       hat[HAT_DOWN] := LongBool(ev.value and SDL_HAT_DOWN);
 257       hat[HAT_LEFT] := LongBool(ev.value and SDL_HAT_LEFT);
 258       hat[HAT_RIGHT] := LongBool(ev.value and SDL_HAT_RIGHT);
 259       for i := HAT_LEFT to HAT_DOWN do
 260       begin
 261         if JoystickHatState[ev.which, ev.hat, i] <> hat[i] then
 262         begin
 263           down := hat[i];
 264           key := e_JoyHatToKey(ev.which, ev.hat, i);
 265           e_KeyUpDown(key, down);
 266           g_Console_ProcessBind(key, down)
 267         end
 268       end;
 269       JoystickHatState[ev.which, ev.hat] := hat
 270     end
 271     else
 272     begin
 273       if g_dbg_input then
 274         e_LogWritefln('Input Debug: NOT IN RANGE! jhat, joy=%s, hat=%s, value=%s', [ev.which, ev.hat, ev.value])
 275     end
 276   end;
 277
 278   procedure AddJoystick (which: Integer);
 279     var i: Integer;
 280   begin
 281     assert(which < e_MaxJoys);
 282     JoystickHandle[which] := SDL_JoystickOpen(which);
 283     if JoystickHandle[which] <> nil then
 284     begin
 285       e_LogWritefln('Added Joystick %s', [which]);
 286       e_JoystickAvailable[which] := True;
 287       for i := 0 to Min(SDL_JoystickNumAxes(JoystickHandle[which]), e_MaxJoyAxes) - 1 do
 288         JoystickZeroAxes[which, i] := SDL_JoystickGetAxis(JoystickHandle[which], i)
 289     end
 290     else
 291     begin
 292       e_LogWritefln('Failed to open Joystick %s', [which])
 293     end
 294   end;
 295
 296   procedure RemoveJoystick (which: Integer);
 297   begin
 298     assert(which < e_MaxJoys);
 299     e_LogWritefln('Remove Joystick %s', [which]);
 300     e_JoystickAvailable[which] := False;
 301     if JoystickHandle[which] <> nil then
 302       SDL_JoystickClose(JoystickHandle[which]);
 303     JoystickHandle[which] := nil
 304   end;
 305
 306   (* --------- Input --------- *)
 307
 308   function Key2Stub (key: Integer): Integer;
 309     var x: Integer;
 310   begin
 311     case key of
 312       SDLK_ESCAPE: x := IK_ESCAPE;
 313       SDLK_RETURN: x := IK_RETURN;
 314       SDLK_KP_ENTER: x := IK_KPRETURN;
 315       SDLK_KP0: x := IK_KPINSERT;
 316       SDLK_UP: x := IK_UP;
 317       SDLK_KP8: x := IK_KPUP;
 318       SDLK_DOWN: x := IK_DOWN;
 319       SDLK_KP2: x := IK_KPDOWN;
 320       SDLK_LEFT: x := IK_LEFT;
 321       SDLK_KP4: x := IK_KPLEFT;
 322       SDLK_RIGHT: x := IK_RIGHT;
 323       SDLK_KP6: x := IK_KPRIGHT;
 324       SDLK_DELETE: x := IK_DELETE;
 325       SDLK_HOME: x := IK_HOME;
 326       SDLK_KP7: x := IK_KPHOME;
 327       SDLK_INSERT: x := IK_INSERT;
 328       SDLK_SPACE: x := IK_SPACE;
 329       SDLK_LSHIFT: x := IK_SHIFT;
 330       SDLK_LALT: x := IK_ALT;
 331       SDLK_TAB: x := IK_TAB;
 332       SDLK_PAGEUP: x := IK_PAGEUP;
 333       SDLK_KP9: x := IK_KPPAGEUP;
 334       SDLK_PAGEDOWN: x := IK_PAGEDN;
 335       SDLK_KP3: x := IK_KPPAGEDN;
 336       SDLK_KP5: x := IK_KP5;
 337       SDLK_NUMLOCK: x := IK_NUMLOCK;
 338       SDLK_KP_DIVIDE: x := IK_KPDIVIDE;
 339       SDLK_KP_MULTIPLY: x := IK_KPMULTIPLE;
 340       SDLK_KP_MINUS: x := IK_KPMINUS;
 341       SDLK_KP_PLUS: x := IK_KPPLUS;
 342       SDLK_KP_PERIOD: x := IK_KPDOT;
 343       SDLK_CAPSLOCK: x := IK_CAPSLOCK;
 344       SDLK_RSHIFT: x := IK_RSHIFT;
 345       SDLK_LCTRL: x := IK_CTRL;
 346       SDLK_RCTRL: x := IK_RCTRL;
 347       SDLK_RALT: x := IK_RALT;
 348       SDLK_LSUPER: x := IK_WIN;
 349       SDLK_RSUPER: x := IK_RWIN;
 350       SDLK_MENU: x := IK_MENU;
 351       SDLK_PRINT: x := IK_PRINTSCR;
 352       SDLK_SCROLLOCK: x := IK_SCROLLLOCK;
 353       SDLK_LEFTBRACKET: x := IK_LBRACKET;
 354       SDLK_RIGHTBRACKET: x := IK_RBRACKET;
 355       SDLK_SEMICOLON: x := IK_SEMICOLON;
 356       SDLK_QUOTE: x := IK_QUOTE;
 357       SDLK_BACKSLASH: x := IK_BACKSLASH;
 358       SDLK_SLASH: x := IK_SLASH;
 359       SDLK_COMMA: x := IK_COMMA;
 360       SDLK_PERIOD: x := IK_DOT;
 361       SDLK_EQUALS: x := IK_EQUALS;
 362       SDLK_0: x := IK_0;
 363       SDLK_1: x := IK_1;
 364       SDLK_2: x := IK_2;
 365       SDLK_3: x := IK_3;
 366       SDLK_4: x := IK_4;
 367       SDLK_5: x := IK_5;
 368       SDLK_6: x := IK_6;
 369       SDLK_7: x := IK_7;
 370       SDLK_8: x := IK_8;
 371       SDLK_9: x := IK_9;
 372       SDLK_F1: x := IK_F1;
 373       SDLK_F2: x := IK_F2;
 374       SDLK_F3: x := IK_F3;
 375       SDLK_F4: x := IK_F4;
 376       SDLK_F5: x := IK_F5;
 377       SDLK_F6: x := IK_F6;
 378       SDLK_F7: x := IK_F7;
 379       SDLK_F8: x := IK_F8;
 380       SDLK_F9: x := IK_F9;
 381       SDLK_F10: x := IK_F10;
 382       SDLK_F11: x := IK_F11;
 383       SDLK_F12: x := IK_F12;
 384       SDLK_END: x := IK_END;
 385       SDLK_KP1: x := IK_KPEND;
 386       SDLK_BACKSPACE: x := IK_BACKSPACE;
 387       SDLK_BACKQUOTE: x := IK_BACKQUOTE;
 388       SDLK_PAUSE: x := IK_PAUSE;
 389       SDLK_A..SDLK_Z: x := IK_A + (key - SDLK_A);
 390       SDLK_MINUS: x := IK_MINUS;
 391       SDLK_RMETA: x := IK_RMETA;
 392       SDLK_LMETA: x := IK_LMETA;
 393     else
 394       x := IK_INVALID
 395     end;
 396     result := x
 397   end;
 398
 399   procedure HandleKeyboard (var ev: TSDL_KeyboardEvent);
 400     var down, repeated: Boolean; key: Integer; ch: Char;
 401   begin
 402     key := Key2Stub(ev.keysym.sym);
 403     down := (ev.type_ = SDL_KEYDOWN);
 404     repeated := down and e_KeyPressed(key);
 405     ch := wchar2win(WideChar(ev.keysym.unicode));
 406     if g_dbg_input then
 407       e_LogWritefln('Input Debug: keysym, down=%s, sym=%s, state=%s, unicode=%s, stubsym=%s, cp1251=%s', [down, ev.keysym.sym, ev.state, ev.keysym.unicode, key, Ord(ch)]);
 408     if not repeated then
 409     begin
 410       e_KeyUpDown(key, down);
 411       g_Console_ProcessBind(key, down);
 412     end
 413     else if gConsoleShow or gChatShow or (g_ActiveWindow <> nil) then
 414     begin
 415       KeyPress(key) // key repeat in menus and shit
 416     end;
 417     if down and IsValid1251(ev.keysym.unicode) and IsPrintable1251(ch) then
 418       CharPress(ch)
 419   end;
 420
 421   procedure HandleResize (var ev: TSDL_ResizeEvent);
 422   begin
 423     if g_dbg_input then
 424       e_LogWritefln('Input Debug: SDL_VIDEORESIZE %s %s', [ev.w, ev.h]);
 425     if modeResize = 1 then
 426       UpdateSize(ev.w, ev.h)
 427     else if modeResize > 1 then
 428       InitWindow(ev.w, ev.h, gBPP, gFullscreen)
 429   end;
 430
 431   function sys_HandleInput (): Boolean;
 432     var ev: TSDL_Event;
 433   begin
 434     result := false;
 435     while SDL_PollEvent(@ev) <> 0 do
 436     begin
 437       case ev.type_ of
 438         SDL_QUITEV: result := true;
 439         SDL_VIDEORESIZE: HandleResize(ev.resize);
 440         SDL_KEYUP, SDL_KEYDOWN: HandleKeyboard(ev.key);
 441         SDL_JOYBUTTONDOWN, SDL_JOYBUTTONUP: HandleJoyButton(ev.jbutton);
 442         SDL_JOYAXISMOTION: HandleJoyAxis(ev.jaxis);
 443         SDL_JOYHATMOTION: HandleJoyHat(ev.jhat);
 444         SDL_VIDEOEXPOSE: sys_Repaint;
 445         SDL_ACTIVEEVENT: e_MuteChannels((ev.active.gain = 0) and gMuteWhenInactive);
 446       end
 447     end
 448   end;
 449
 450   procedure sys_RequestQuit;
 451     var ev: TSDL_Event;
 452   begin
 453     ev.quit.type_ := SDL_QUITEV;
 454     SDL_PushEvent(@ev)
 455   end;
 456
 457   (* --------- Init --------- *)
 458
 459   procedure sys_Init;
 460     var flags: Uint32; i: Integer;
 461   begin
 462     e_WriteLog('Init SDL', TMsgType.Notify);
 463     flags := SDL_INIT_VIDEO or SDL_INIT_AUDIO or
 464              SDL_INIT_TIMER or SDL_INIT_JOYSTICK
 465              (*or SDL_INIT_NOPARACHUTE*);
 466     if SDL_Init(flags) <> 0 then
 467       raise Exception.Create('SDL: Init failed: ' + SDL_GetError);
 468     SDL_EnableUNICODE(1);
 469     SDL_EnableKeyRepeat(SDL_DEFAULT_REPEAT_DELAY, SDL_DEFAULT_REPEAT_INTERVAL);
 470     for i := 0 to e_MaxJoys - 1 do
 471       AddJoystick(i)
 472   end;
 473
 474   procedure sys_Final;
 475     var i: Integer;
 476   begin
 477     e_WriteLog('Releasing SDL', TMsgType.Notify);
 478     for i := 0 to e_MaxJoys - 1 do
 479       RemoveJoystick(i);
 480     if screen <> nil then
 481     begin
 482       {$IFDEF NOGL_INIT}
 483         nogl_Quit;
 484       {$ENDIF}
 485       SDL_FreeSurface(screen)
 486     end;
 487     SDL_Quit
 488   end;
 489
 490 initialization
 491   (* window resize are broken both on linux and osx, so disabled by default *)
 492   conRegVar('sdl_allow_resize', @userResize, 'allow to resize window by user', 'allow to resize window by user');
 493   conRegVar('sdl_resize_action', @modeResize, 'set window resize mode (0: ignore, 1: change, 2: reset)', '');
 494   userResize := false;
 495   modeResize := 0;
 496 end.