src/shared/utils.pas

   1 {$MODE DELPHI}
   2 unit utils;
   3
   4 interface
   5
   6 uses
   7   SysUtils, Classes;
   8
   9
  10 // does filename have one of ".wad", ".pk3", ".zip" extensions?
  11 function hasWadExtension (fn: AnsiString): Boolean;
  12
  13 // does filepath have ".XXX:\" in it?
  14 function isWadPath (fn: AnsiString): Boolean;
  15
  16 // adds ".wad" extension if filename doesn't have one of ".wad", ".pk3", ".zip"
  17 function addWadExtension (fn: AnsiString): AnsiString;
  18
  19 // convert number to strig with nice commas
  20 function Int64ToStrComma (i: Int64): AnsiString;
  21
  22 function UpCase1251 (ch: Char): Char;
  23 function LoCase1251 (ch: Char): Char;
  24
  25 // `true` if strings are equal; ignoring case for cp1251
  26 function StrEquCI1251 (const s0, s1: AnsiString): Boolean;
  27
  28 function utf8Valid (const s: AnsiString): Boolean;
  29
  30 function utf8to1251 (s: AnsiString): AnsiString;
  31
  32 // `pathname` will be modified if path is valid
  33 // `lastIsDir` should be `true` if we are searching for directory
  34 // nobody cares about shitdoze, so i'll use the same code path for it
  35 function findFileCI (var pathname: AnsiString; lastIsDir: Boolean=false): Boolean;
  36
  37 // they throws
  38 function openDiskFileRO (pathname: AnsiString): TStream;
  39 function createDiskFile (pathname: AnsiString): TStream;
  40
  41 // little endian
  42 procedure writeInt (st: TStream; v: Byte); overload;
  43 procedure writeInt (st: TStream; v: ShortInt); overload;
  44 procedure writeInt (st: TStream; v: Word); overload;
  45 procedure writeInt (st: TStream; v: SmallInt); overload;
  46 procedure writeInt (st: TStream; v: LongWord); overload;
  47 procedure writeInt (st: TStream; v: LongInt); overload;
  48 procedure writeInt (st: TStream; v: Int64); overload;
  49 procedure writeInt (st: TStream; v: UInt64); overload;
  50
  51 function readByte (st: TStream): Byte;
  52 function readShortInt (st: TStream): ShortInt;
  53 function readWord (st: TStream): Word;
  54 function readSmallInt (st: TStream): SmallInt;
  55 function readLongWord (st: TStream): LongWord;
  56 function readLongInt (st: TStream): LongInt;
  57 function readInt64 (st: TStream): Int64;
  58 function readUInt64 (st: TStream): UInt64;
  59
  60 // big endian
  61 procedure writeIntBE (st: TStream; v: Byte); overload;
  62 procedure writeIntBE (st: TStream; v: ShortInt); overload;
  63 procedure writeIntBE (st: TStream; v: Word); overload;
  64 procedure writeIntBE (st: TStream; v: SmallInt); overload;
  65 procedure writeIntBE (st: TStream; v: LongWord); overload;
  66 procedure writeIntBE (st: TStream; v: LongInt); overload;
  67 procedure writeIntBE (st: TStream; v: Int64); overload;
  68 procedure writeIntBE (st: TStream; v: UInt64); overload;
  69
  70 function readByteBE (st: TStream): Byte;
  71 function readShortIntBE (st: TStream): ShortInt;
  72 function readWordBE (st: TStream): Word;
  73 function readSmallIntBE (st: TStream): SmallInt;
  74 function readLongWordBE (st: TStream): LongWord;
  75 function readLongIntBE (st: TStream): LongInt;
  76 function readInt64BE (st: TStream): Int64;
  77 function readUInt64BE (st: TStream): UInt64;
  78
  79
  80 implementation
  81
  82
  83 function hasWadExtension (fn: AnsiString): Boolean;
  84 begin
  85   fn := ExtractFileExt(fn);
  86   result := StrEquCI1251(fn, '.wad') or StrEquCI1251(fn, '.pk3') or StrEquCI1251(fn, '.zip');
  87 end;
  88
  89
  90 function addWadExtension (fn: AnsiString): AnsiString;
  91 begin
  92   result := fn;
  93   if not hasWadExtension(result) then result := result+'.wad';
  94 end;
  95
  96
  97 function isWadPath (fn: AnsiString): Boolean;
  98 var
  99   p: Integer;
 100   s: AnsiString;
 101 begin
 102   result := false;
 103   while true do
 104   begin
 105     p := Pos(':', fn);
 106     if (p = 0) or (length(fn)-p < 1) then break;
 107     if (p-4 > 1) and (fn[p-4] = '.') and ((fn[p+1] = '\') or (fn[p+1] = '/')) then
 108     begin
 109       s := Copy(fn, p-4, 4);
 110       if StrEquCI1251(s, '.wad') or StrEquCI1251(s, '.pk3') or StrEquCI1251(s, '.zip') then
 111       begin
 112         result := true;
 113         exit;
 114       end;
 115     end;
 116     Delete(fn, 1, p);
 117   end;
 118 end;
 119
 120
 121 function Int64ToStrComma (i: Int64): AnsiString;
 122 var
 123   f: Integer;
 124 begin
 125   Str(i, result);
 126   f := Length(result)+1;
 127   while f > 4 do
 128   begin
 129     Dec(f, 3); Insert(',', result, f);
 130   end;
 131 end;
 132
 133
 134 function UpCase1251 (ch: Char): Char;
 135 begin
 136   if ch < #128 then
 137   begin
 138     if (ch >= 'a') and (ch <= 'z') then Dec(ch, 32);
 139   end
 140   else
 141   begin
 142     if (ch >= #224) and (ch <= #255) then
 143     begin
 144       Dec(ch, 32);
 145     end
 146     else
 147     begin
 148       case ch of
 149         #184, #186, #191: Dec(ch, 16);
 150         #162, #179: Dec(ch);
 151       end;
 152     end;
 153   end;
 154   result := ch;
 155 end;
 156
 157
 158 function LoCase1251 (ch: Char): Char;
 159 begin
 160   if ch < #128 then
 161   begin
 162     if (ch >= 'A') and (ch <= 'Z') then Inc(ch, 32);
 163   end
 164   else
 165   begin
 166     if (ch >= #192) and (ch <= #223) then
 167     begin
 168       Inc(ch, 32);
 169     end
 170     else
 171     begin
 172       case ch of
 173         #168, #170, #175: Inc(ch, 16);
 174         #161, #178: Inc(ch);
 175       end;
 176     end;
 177   end;
 178   result := ch;
 179 end;
 180
 181
 182 function StrEquCI1251 (const s0, s1: AnsiString): Boolean;
 183 var
 184   i: Integer;
 185 begin
 186   result := false;
 187   if length(s0) <> length(s1) then exit;
 188   for i := 1 to length(s0) do if UpCase1251(s0[i]) <> UpCase1251(s1[i]) then exit;
 189   result := true;
 190 end;
 191
 192
 193 // ////////////////////////////////////////////////////////////////////////// //
 194 // utils
 195 // `ch`: utf8 start
 196 // -1: invalid utf8
 197 function utf8CodeLen (ch: Word): Integer;
 198 begin
 199   if ch < $80 then begin result := 1; exit; end;
 200   if (ch and $FE) = $FC then begin result := 6; exit; end;
 201   if (ch and $FC) = $F8 then begin result := 5; exit; end;
 202   if (ch and $F8) = $F0 then begin result := 4; exit; end;
 203   if (ch and $F0) = $E0 then begin result := 3; exit; end;
 204   if (ch and $E0) = $C0 then begin result := 2; exit; end;
 205   result := -1; // invalid
 206 end;
 207
 208
 209 function utf8Valid (const s: AnsiString): Boolean;
 210 var
 211   pos, len: Integer;
 212 begin
 213   result := false;
 214   pos := 1;
 215   while pos <= length(s) do
 216   begin
 217     len := utf8CodeLen(Byte(s[pos]));
 218     if len < 1 then exit; // invalid sequence start
 219     if pos+len-1 > length(s) then exit; // out of chars in string
 220     Dec(len);
 221     Inc(pos);
 222     // check other sequence bytes
 223     while len > 0 do
 224     begin
 225       if (Byte(s[pos]) and $C0) <> $80 then exit;
 226       Dec(len);
 227       Inc(pos);
 228     end;
 229   end;
 230   result := true;
 231 end;
 232
 233
 234 // ////////////////////////////////////////////////////////////////////////// //
 235 const
 236   uni2wint: array [128..255] of Word = (
 237     $0402,$0403,$201A,$0453,$201E,$2026,$2020,$2021,$20AC,$2030,$0409,$2039,$040A,$040C,$040B,$040F,
 238     $0452,$2018,$2019,$201C,$201D,$2022,$2013,$2014,$003F,$2122,$0459,$203A,$045A,$045C,$045B,$045F,
 239     $00A0,$040E,$045E,$0408,$00A4,$0490,$00A6,$00A7,$0401,$00A9,$0404,$00AB,$00AC,$00AD,$00AE,$0407,
 240     $00B0,$00B1,$0406,$0456,$0491,$00B5,$00B6,$00B7,$0451,$2116,$0454,$00BB,$0458,$0405,$0455,$0457,
 241     $0410,$0411,$0412,$0413,$0414,$0415,$0416,$0417,$0418,$0419,$041A,$041B,$041C,$041D,$041E,$041F,
 242     $0420,$0421,$0422,$0423,$0424,$0425,$0426,$0427,$0428,$0429,$042A,$042B,$042C,$042D,$042E,$042F,
 243     $0430,$0431,$0432,$0433,$0434,$0435,$0436,$0437,$0438,$0439,$043A,$043B,$043C,$043D,$043E,$043F,
 244     $0440,$0441,$0442,$0443,$0444,$0445,$0446,$0447,$0448,$0449,$044A,$044B,$044C,$044D,$044E,$044F
 245   );
 246
 247
 248 function decodeUtf8Char (s: AnsiString; var pos: Integer): char;
 249 var
 250   b, c: Integer;
 251 begin
 252   (* The following encodings are valid, except for the 5 and 6 byte
 253    * combinations:
 254    *  0xxxxxxx
 255    *  110xxxxx 10xxxxxx
 256    *  1110xxxx 10xxxxxx 10xxxxxx
 257    *  11110xxx 10xxxxxx 10xxxxxx 10xxxxxx
 258    *  111110xx 10xxxxxx 10xxxxxx 10xxxxxx 10xxxxxx
 259    *  1111110x 10xxxxxx 10xxxxxx 10xxxxxx 10xxxxxx 10xxxxxx
 260    *)
 261   result := '?';
 262   if pos > length(s) then exit;
 263
 264   b := Byte(s[pos]);
 265   Inc(pos);
 266   if b < $80 then begin result := char(b); exit; end;
 267
 268   // mask out unused bits
 269        if (b and $FE) = $FC then b := b and $01
 270   else if (b and $FC) = $F8 then b := b and $03
 271   else if (b and $F8) = $F0 then b := b and $07
 272   else if (b and $F0) = $E0 then b := b and $0F
 273   else if (b and $E0) = $C0 then b := b and $1F
 274   else exit; // invalid utf8
 275
 276   // now continue
 277   while pos <= length(s) do
 278   begin
 279     c := Byte(s[pos]);
 280     if (c and $C0) <> $80 then break; // no more
 281     b := b shl 6;
 282     b := b or (c and $3F);
 283     Inc(pos);
 284   end;
 285
 286   // done, try 1251
 287   for c := 128 to 255 do if uni2wint[c] = b then begin result := char(c and $FF); exit; end;
 288   // alas
 289 end;
 290
 291
 292 function utf8to1251 (s: AnsiString): AnsiString;
 293 var
 294   pos: Integer;
 295 begin
 296   if not utf8Valid(s) then begin result := s; exit; end;
 297   pos := 1;
 298   while pos <= length(s) do
 299   begin
 300     if Byte(s[pos]) >= $80 then break;
 301     Inc(pos);
 302   end;
 303   if pos > length(s) then begin result := s; exit; end; // nothing to do here
 304   result := '';
 305   pos := 1;
 306   while pos <= length(s) do result := result+decodeUtf8Char(s, pos);
 307 end;
 308
 309
 310 // ////////////////////////////////////////////////////////////////////////// //
 311 // `pathname` will be modified if path is valid
 312 // `lastIsDir` should be `true` if we are searching for directory
 313 // nobody cares about shitdoze, so i'll use the same code path for it
 314 function findFileCI (var pathname: AnsiString; lastIsDir: Boolean=false): Boolean;
 315 var
 316   sr: TSearchRec;
 317   npt: AnsiString;
 318   newname: AnsiString = '';
 319   curname: AnsiString;
 320   wantdir: Boolean;
 321   attr: LongInt;
 322   foundher: Boolean;
 323 begin
 324   npt := pathname;
 325   result := (length(npt) > 0);
 326   if (length(npt) > 0) and ((npt[1] = '/') or (npt[1] = '\')) then newname := '/';
 327   while length(npt) > 0 do
 328   begin
 329     // remove trailing slashes
 330     while (length(npt) > 0) and ((npt[1] = '/') or (npt[1] = '\')) do Delete(npt, 1, 1);
 331     if length(npt) = 0 then break;
 332     // extract name
 333     curname := '';
 334     while (length(npt) > 0) and (npt[1] <> '/') and (npt[1] <> '\') do
 335     begin
 336       curname := curname+npt[1];
 337       Delete(npt, 1, 1);
 338     end;
 339     // remove trailing slashes again
 340     while (length(npt) > 0) and ((npt[1] = '/') or (npt[1] = '\')) do Delete(npt, 1, 1);
 341     wantdir := lastIsDir or (length(npt) > 0); // do we want directory here?
 342     //writeln(Format('npt=[%s]; newname=[%s]; curname=[%s]; wantdir=%d', [npt, newname, curname, Integer(wantdir)]));
 343     // try the easiest case first
 344     attr := FileGetAttr(newname+curname);
 345     if attr <> -1 then
 346     begin
 347       if wantdir = ((attr and faDirectory) <> 0) then
 348       begin
 349         // i found her!
 350         newname := newname+curname;
 351         if wantdir then newname := newname+'/';
 352         continue;
 353       end;
 354     end;
 355     //writeln(Format('npt=[%s]; newname=[%s]; curname=[%s]; wantdir=%d', [npt, newname, curname, Integer(wantdir)]));
 356     // alas, either not found, or invalid attributes
 357     foundher := false;
 358     try
 359       if FindFirst(newname+'*', faAnyFile, sr) = 0 then
 360       repeat
 361         if (wantdir = ((sr.attr and faDirectory) <> 0)) and StrEquCI1251(sr.name, curname) then
 362         begin
 363           // i found her!
 364           newname := newname+sr.name;
 365           if wantdir then newname := newname+'/';
 366           foundher := true;
 367           break;
 368         end;
 369       until FindNext(sr) <> 0;
 370     finally
 371       FindClose(sr);
 372     end;
 373     if not foundher then begin newname := ''; result := false; break; end;
 374   end;
 375   if result then pathname := newname;
 376 end;
 377
 378
 379 function openDiskFileRO (pathname: AnsiString): TStream;
 380 begin
 381   if not findFileCI(pathname) then raise Exception.Create('can''t open file "'+pathname+'"');
 382   result := TFileStream.Create(pathname, fmOpenRead or {fmShareDenyWrite}fmShareDenyNone);
 383 end;
 384
 385 function createDiskFile (pathname: AnsiString): TStream;
 386 var
 387   path: AnsiString;
 388 begin
 389   path := ExtractFilePath(pathname);
 390   if length(path) > 0 then
 391   begin
 392     if not findFileCI(path, true) then raise Exception.Create('can''t create file "'+pathname+'"');
 393   end;
 394   result := TFileStream.Create(path+ExtractFileName(pathname), fmCreate);
 395 end;
 396
 397
 398 procedure writeIntegerLE (st: TStream; vp: Pointer; size: Integer);
 399 {$IFDEF ENDIAN_LITTLE}
 400 begin
 401   st.writeBuffer(vp^, size);
 402 end;
 403 {$ELSE}
 404 var
 405   p: PByte;
 406 begin
 407   p := PByte(vp)+size-1;
 408   while size > 0 do
 409   begin
 410     st.writeBuffer(p^, 1);
 411     Dec(size);
 412     Dec(p);
 413   end;
 414 end;
 415 {$ENDIF}
 416
 417 procedure writeIntegerBE (st: TStream; vp: Pointer; size: Integer);
 418 {$IFDEF ENDIAN_LITTLE}
 419 var
 420   p: PByte;
 421 begin
 422   p := PByte(vp)+size-1;
 423   while size > 0 do
 424   begin
 425     st.writeBuffer(p^, 1);
 426     Dec(size);
 427     Dec(p);
 428   end;
 429 end;
 430 {$ELSE}
 431 begin
 432   st.writeBuffer(vp^, size);
 433 end;
 434 {$ENDIF}
 435
 436 procedure writeInt (st: TStream; v: Byte); overload; begin writeIntegerLE(st, @v, 1); end;
 437 procedure writeInt (st: TStream; v: ShortInt); overload; begin writeIntegerLE(st, @v, 1); end;
 438 procedure writeInt (st: TStream; v: Word); overload; begin writeIntegerLE(st, @v, 2); end;
 439 procedure writeInt (st: TStream; v: SmallInt); overload; begin writeIntegerLE(st, @v, 2); end;
 440 procedure writeInt (st: TStream; v: LongWord); overload; begin writeIntegerLE(st, @v, 4); end;
 441 procedure writeInt (st: TStream; v: LongInt); overload; begin writeIntegerLE(st, @v, 4); end;
 442 procedure writeInt (st: TStream; v: Int64); overload; begin writeIntegerLE(st, @v, 8); end;
 443 procedure writeInt (st: TStream; v: UInt64); overload; begin writeIntegerLE(st, @v, 8); end;
 444
 445 procedure writeIntBE (st: TStream; v: Byte); overload; begin writeIntegerBE(st, @v, 1); end;
 446 procedure writeIntBE (st: TStream; v: ShortInt); overload; begin writeIntegerBE(st, @v, 1); end;
 447 procedure writeIntBE (st: TStream; v: Word); overload; begin writeIntegerBE(st, @v, 2); end;
 448 procedure writeIntBE (st: TStream; v: SmallInt); overload; begin writeIntegerBE(st, @v, 2); end;
 449 procedure writeIntBE (st: TStream; v: LongWord); overload; begin writeIntegerBE(st, @v, 4); end;
 450 procedure writeIntBE (st: TStream; v: LongInt); overload; begin writeIntegerBE(st, @v, 4); end;
 451 procedure writeIntBE (st: TStream; v: Int64); overload; begin writeIntegerBE(st, @v, 8); end;
 452 procedure writeIntBE (st: TStream; v: UInt64); overload; begin writeIntegerBE(st, @v, 8); end;
 453
 454
 455 procedure readIntegerLE (st: TStream; vp: Pointer; size: Integer);
 456 {$IFDEF ENDIAN_LITTLE}
 457 begin
 458   st.readBuffer(vp^, size);
 459 end;
 460 {$ELSE}
 461 var
 462   p: PByte;
 463 begin
 464   p := PByte(vp)+size-1;
 465   while size > 0 do
 466   begin
 467     st.readBuffer(p^, 1);
 468     Dec(size);
 469     Dec(p);
 470   end;
 471 end;
 472 {$ENDIF}
 473
 474 procedure readIntegerBE (st: TStream; vp: Pointer; size: Integer);
 475 {$IFDEF ENDIAN_LITTLE}
 476 var
 477   p: PByte;
 478 begin
 479   p := PByte(vp)+size-1;
 480   while size > 0 do
 481   begin
 482     st.readBuffer(p^, 1);
 483     Dec(size);
 484     Dec(p);
 485   end;
 486 end;
 487 {$ELSE}
 488 begin
 489   st.readBuffer(vp^, size);
 490 end;
 491 {$ENDIF}
 492
 493 function readByte (st: TStream): Byte; begin readIntegerLE(st, @result, 1); end;
 494 function readShortInt (st: TStream): ShortInt; begin readIntegerLE(st, @result, 1); end;
 495 function readWord (st: TStream): Word; begin readIntegerLE(st, @result, 2); end;
 496 function readSmallInt (st: TStream): SmallInt; begin readIntegerLE(st, @result, 2); end;
 497 function readLongWord (st: TStream): LongWord; begin readIntegerLE(st, @result, 4); end;
 498 function readLongInt (st: TStream): LongInt; begin readIntegerLE(st, @result, 4); end;
 499 function readInt64 (st: TStream): Int64; begin readIntegerLE(st, @result, 8); end;
 500 function readUInt64 (st: TStream): UInt64; begin readIntegerLE(st, @result, 8); end;
 501
 502 function readByteBE (st: TStream): Byte; begin readIntegerBE(st, @result, 1); end;
 503 function readShortIntBE (st: TStream): ShortInt; begin readIntegerBE(st, @result, 1); end;
 504 function readWordBE (st: TStream): Word; begin readIntegerBE(st, @result, 2); end;
 505 function readSmallIntBE (st: TStream): SmallInt; begin readIntegerBE(st, @result, 2); end;
 506 function readLongWordBE (st: TStream): LongWord; begin readIntegerBE(st, @result, 4); end;
 507 function readLongIntBE (st: TStream): LongInt; begin readIntegerBE(st, @result, 4); end;
 508 function readInt64BE (st: TStream): Int64; begin readIntegerBE(st, @result, 8); end;
 509 function readUInt64BE (st: TStream): UInt64; begin readIntegerBE(st, @result, 8); end;
 510
 511
 512 end.