DEADSOFTWARE

GIT / REPO / FRED-BOY
Projects / d2df-sdl.git / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
gl: reset gfx on map start
[d2df-sdl.git] / src / game / renders / opengl / r_map.pas
1 (* Copyright (C) Doom 2D: Forever Developers
2 *
3 * This program is free software: you can redistribute it and/or modify
4 * it under the terms of the GNU General Public License as published by
5 * the Free Software Foundation, version 3 of the License ONLY.
6 *
7 * This program is distributed in the hope that it will be useful,
8 * but WITHOUT ANY WARRANTY; without even the implied warranty of
9 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
10 * GNU General Public License for more details.
11 *
12 * You should have received a copy of the GNU General Public License
13 * along with this program. If not, see <http://www.gnu.org/licenses/>.
14 *)
15 {$INCLUDE ../../../shared/a_modes.inc}
16 unit r_map;
17
18 interface
19
20 uses g_base, g_player, g_playermodel; // TRectWH, TPlayer, TPlayerModel
21
22 procedure r_Map_Initialize;
23 procedure r_Map_Finalize;
24
25 procedure r_Map_Load;
26 procedure r_Map_Free;
27
28 procedure r_Map_LoadTextures;
29 procedure r_Map_FreeTextures;
30
31 {$IFDEF ENABLE_GFX}
32 procedure r_Map_NewGFX (typ, x, y: Integer);
33 {$ENDIF}
34 {$IFDEF ENABLE_GIBS}
35 function r_Map_GetGibSize (m, i: Integer): TRectWH;
36 {$ENDIF}
37 {$IFDEF ENABLE_MENU}
38 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer; alpha: Byte);
39 {$ENDIF}
40
41 procedure r_Map_Reset;
42 procedure r_Map_Update;
43
44 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer; player: TPlayer; out acx, acy: Integer);
45
46 implementation
47
48 uses
49 {$I ../../../nogl/noGLuses.inc}
50 Math, SysUtils,
51 e_log,
52 binheap, MAPDEF, utils,
53 g_options, g_animations, g_basic, g_phys,
54 g_game, g_map, g_panel, g_items, g_monsters, g_weapons,
55 g_console, g_language,
56 {$IFDEF ENABLE_CORPSES}
57 g_corpses,
58 {$ENDIF}
59 {$IFDEF ENABLE_SHELLS}
60 g_shells,
61 {$ENDIF}
62 {$IFDEF ENABLE_GIBS}
63 g_gibs,
64 {$ENDIF}
65 {$IFDEF ENABLE_GFX}
66 g_gfx,
67 {$ENDIF}
68 r_textures, r_draw, r_common
69 ;
70
71 const
72 MTABLE: array [0..MONSTER_MAN] of record
73 w, h: Integer;
74 end = (
75 (w: 64; h: 64), // NONE
76 (w: 64; h: 64), // DEMON
77 (w: 64; h: 64), // IMP
78 (w: 64; h: 64), // ZOMBY
79 (w: 64; h: 64), // SERG
80 (w: 128; h: 128), // CYBER
81 (w: 64; h: 64), // CGUN
82 (w: 128; h: 128), // BARON
83 (w: 128; h: 128), // KNIGHT
84 (w: 128; h: 128), // CACO
85 (w: 64; h: 64), // SOUL (DIE is 128x128, see load code)
86 (w: 128; h: 128), // PAIN
87 (w: 256; h: 128), // SPIDER
88 (w: 128; h: 64), // BSP
89 (w: 128; h: 128), // MANCUB
90 (w: 128; h: 128), // SKEL
91 (w: 128; h: 128), // VILE
92 (w: 32; h: 32), // FISH
93 (w: 64; h: 64), // BARREL
94 (w: 128; h: 128), // ROBO
95 (w: 64; h: 64) // MAN
96 );
97 VILEFIRE_DX = 32;
98 VILEFIRE_DY = 128;
99
100 ItemAnim: array [0..ITEM_LAST] of record
101 name: AnsiString;
102 w, h: Integer;
103 anim: TAnimInfo;
104 end = (
105 (name: 'NOTEXTURE'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
106 (name: 'MED1'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
107 (name: 'MED2'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
108 (name: 'BMED'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
109 (name: 'ARMORGREEN'; w: 32; h: 16; anim: (loop: true; delay: 20; frames: 3; back: true)),
110 (name: 'ARMORBLUE'; w: 32; h: 16; anim: (loop: true; delay: 20; frames: 3; back: true)),
111 (name: 'SBLUE'; w: 32; h: 32; anim: (loop: true; delay: 15; frames: 4; back: true)),
112 (name: 'SWHITE'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
113 (name: 'SUIT'; w: 32; h: 64; anim: (loop: true; delay: 1; frames: 1; back: false)),
114 (name: 'OXYGEN'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
115 (name: 'INVUL'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
116 (name: 'SAW'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
117 (name: 'SHOTGUN1'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
118 (name: 'SHOTGUN2'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
119 (name: 'MGUN'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
120 (name: 'RLAUNCHER'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
121 (name: 'PGUN'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
122 (name: 'BFG'; w: 64; h: 64; anim: (loop: true; delay: 1; frames: 1; back: false)),
123 (name: 'SPULEMET'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
124 (name: 'CLIP'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
125 (name: 'AMMO'; w: 32; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
126 (name: 'SHELL1'; w: 16; h: 8; anim: (loop: true; delay: 1; frames: 1; back: false)),
127 (name: 'SHELL2'; w: 32; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
128 (name: 'ROCKET'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
129 (name: 'ROCKETS'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
130 (name: 'CELL'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
131 (name: 'CELL2'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
132 (name: 'BPACK'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
133 (name: 'KEYR'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
134 (name: 'KEYG'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
135 (name: 'KEYB'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
136 (name: 'KASTET'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
137 (name: 'PISTOL'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
138 (name: 'BOTTLE'; w: 16; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
139 (name: 'HELMET'; w: 16; h: 16; anim: (loop: true; delay: 20; frames: 4; back: true)),
140 (name: 'JETPACK'; w: 32; h: 32; anim: (loop: true; delay: 15; frames: 3; back: true)),
141 (name: 'INVIS'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
142 (name: 'FLAMETHROWER'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
143 (name: 'FUELCAN'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false))
144 );
145
146 {$IFDEF ENABLE_GFX}
147 GFXAnim: array [0..R_GFX_LAST] of record
148 name: AnsiString;
149 w, h: Integer;
150 anim: TAnimInfo;
151 rdelay: Integer;
152 alpha: Integer;
153 end = (
154 (name: ''; w: 0; h: 0; anim: (loop: false; delay: 0; frames: 0; back: false); rdelay: 0; alpha: 0),
155 (name: 'TELEPORT'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 10; back: false); rdelay: 0; alpha: 0),
156 (name: 'FLAME'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 11; back: false); rdelay: 0; alpha: 0),
157 (name: 'EROCKET'; w: 128; h: 128; anim: (loop: false; delay: 6; frames: 6; back: false); rdelay: 0; alpha: 0),
158 (name: 'EBFG'; w: 128; h: 128; anim: (loop: false; delay: 6; frames: 6; back: false); rdelay: 0; alpha: 0),
159 (name: 'BFGHIT'; w: 64; h: 64; anim: (loop: false; delay: 4; frames: 4; back: false); rdelay: 0; alpha: 0),
160 (name: 'FIRE'; w: 64; h: 128; anim: (loop: false; delay: 4; frames: 8; back: false); rdelay: 2; alpha: 0),
161 (name: 'ITEMRESPAWN'; w: 32; h: 32; anim: (loop: false; delay: 4; frames: 5; back: true); rdelay: 0; alpha: 0),
162 (name: 'SMOKE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 0),
163 (name: 'ESKELFIRE'; w: 64; h: 64; anim: (loop: false; delay: 8; frames: 3; back: false); rdelay: 0; alpha: 0),
164 (name: 'EPLASMA'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 4; back: true); rdelay: 0; alpha: 0),
165 (name: 'EBSPFIRE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 5; back: false); rdelay: 0; alpha: 0),
166 (name: 'EIMPFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
167 (name: 'ECACOFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
168 (name: 'EBARONFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
169 (name: 'TELEPORT'; w: 64; h: 64; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 0), // fast
170 (name: 'SMOKE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 150), // transparent
171 (name: 'FLAME'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 11; back: false); rdelay: 2; alpha: 0) // random
172 );
173 {$ENDIF}
174
175 ShotAnim: array [0..WEAPON_LAST] of record
176 name: AnsiString;
177 w, h: Integer;
178 anim: TAnimInfo;
179 end = (
180 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 0 KASTET
181 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 1 SAW
182 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 2 PISTOL
183 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 3 SHOTGUN1
184 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 4 SHOTGUN2
185 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 5 CHAINGUN
186 (name: 'BROCKET'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)), // 6 ROCKETLAUNCHER
187 (name: 'BPLASMA'; w: 16; h: 16; anim: (loop: true; delay: 5; frames: 2; back: false)), // 7 PLASMA
188 (name: 'BBFG'; w: 64; h: 64; anim: (loop: true; delay: 6; frames: 2; back: false)), // 8 BFG
189 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 9 SUPERPULEMET
190 (name: 'FLAME'; w: 32; h: 32; anim: (loop: true; delay: 6; frames: 0{11}; back: false)), // 10 FLAMETHROWER
191 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 11
192 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 12
193 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 13
194 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 14
195 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 15
196 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 16
197 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 17
198 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 18
199 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 19
200 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 20 ZOMPY_PISTOL
201 (name: 'BIMPFIRE'; w: 16; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 21 IMP_FIRE
202 (name: 'BBSPFIRE'; w: 16; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 22 BSP_FIRE
203 (name: 'BCACOFIRE'; w: 16; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 23 CACO_FIRE
204 (name: 'BBARONFIRE'; w: 64; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 24 BARON_FIRE
205 (name: 'BMANCUBFIRE'; w: 64; h: 32; anim: (loop: true; delay: 4; frames: 2; back: false)), // 25 MANCUB_FIRE
206 (name: 'BSKELFIRE'; w: 64; h: 64; anim: (loop: true; delay: 5; frames: 2; back: false)) // 26 SKEL_FIRE
207 );
208
209 {$IFDEF ENABLE_SHELLS}
210 ShellAnim: array [0..SHELL_LAST] of record
211 name: AnsiString;
212 dx, dy: Integer;
213 end = (
214 (name: 'EBULLET'; dx: 2; dy: 1), // 0 SHELL_BULLET
215 (name: 'ESHELL'; dx: 4; dy: 2), // 1 SHELL_SHELL
216 (name: 'ESHELL'; dx: 4; dy: 2) // 2 SHELL_DBLSHELL
217 );
218 {$ENDIF}
219
220 PunchAnim: TAnimInfo = (loop: false; delay: 1; frames: 4; back: false);
221 FlagAnim: TAnimInfo = (loop: true; delay: 8; frames: 5; back: false);
222 VileFireAnim: TAnimInfo = (loop: true; delay: 2; frames: 8; back: false);
223
224 type
225 TBinHeapPanelDrawCmp = class
226 public
227 class function less (const a, b: TPanel): Boolean; inline;
228 end;
229
230 TBinHeapPanelDraw = specialize TBinaryHeapBase<TPanel, TBinHeapPanelDrawCmp>;
231
232 TMonsterAnims = array [0..ANIM_LAST, TDirection] of TGLMultiTexture;
233
234 var
235 DebugCameraScale: Single;
236 FillOutsizeArea: Boolean;
237 SkyTexture: TGLTexture;
238 RenTextures: array of record
239 spec: LongInt;
240 tex: TGLMultiTexture;
241 anim: TAnimInfo;
242 end;
243 Items: array [0..ITEM_LAST] of record
244 tex: TGLMultiTexture;
245 frame: Integer;
246 end;
247 MonTextures: array [0..MONSTER_MAN] of TMonsterAnims;
248 WeapTextures: array [0..WP_LAST, 0..W_POS_LAST, 0..W_ACT_LAST] of TGLTexture;
249 ShotTextures: array [0..WEAPON_LAST] of TGLMultiTexture;
250 FlagTextures: array [0..FLAG_LAST] of TGLMultiTexture;
251 PunchTextures: array [Boolean, 0..2] of TGLMultiTexture; // [berserk, center/up/down]
252 VileFire: TGLMultiTexture;
253 InvulPenta: TGLTexture;
254 IndicatorTexture: TGLTexture;
255 TalkTexture: TGLTexture;
256 Models: array of record
257 anim: array [TDirection, 0..A_LAST] of record
258 base, mask: TGLMultiTexture;
259 end;
260 {$IFDEF ENABLE_GIBS}
261 gibs: record
262 base, mask: TGLTextureArray;
263 rect: TRectArray;
264 end;
265 {$ENDIF}
266 end;
267
268 {$IFDEF ENABLE_SHELLS}
269 ShellTextures: array [0..SHELL_LAST] of TGLTexture;
270 {$ENDIF}
271 {$IFDEF ENABLE_GFX}
272 GFXTextures: array [0..R_GFX_LAST] of TGLMultiTexture;
273 gfxlist: array of record
274 typ: Byte;
275 x, y: Integer;
276 oldX, oldY: Integer;
277 anim: TAnimInfo;
278 time: LongWord;
279 frame: LongInt;
280 end = nil;
281 {$ENDIF}
282
283 FlagFrame: LongInt;
284 plist: TBinHeapPanelDraw = nil;
285
286 class function TBinHeapPanelDrawCmp.less (const a, b: TPanel): Boolean; inline;
287 begin
288 if a.tag < b.tag then begin result := true; exit; end;
289 if a.tag > b.tag then begin result := false; exit; end;
290 result := a.arrIdx < b.arrIdx;
291 end;
292
293 procedure r_Map_Initialize;
294 begin
295 FlagFrame := 0;
296 plist := TBinHeapPanelDraw.Create();
297 end;
298
299 procedure r_Map_Finalize;
300 begin
301 r_Common_FreeAndNil(plist);
302 FlagFrame := 0;
303 end;
304
305 procedure r_Map_FreeModel (i: Integer);
306 var a: Integer; d: TDirection;
307 begin
308 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
309 begin
310 for a := A_STAND to A_LAST do
311 begin
312 r_Common_FreeAndNil(Models[i].anim[d, a].base);
313 r_Common_FreeAndNil(Models[i].anim[d, a].mask);
314 end;
315 end;
316 {$IFDEF ENABLE_GIBS}
317 if Models[i].gibs.base <> nil then
318 for a := 0 to High(Models[i].gibs.base) do
319 r_Common_FreeAndNil(Models[i].gibs.base[a]);
320 if Models[i].gibs.mask <> nil then
321 for a := 0 to High(Models[i].gibs.mask) do
322 r_Common_FreeAndNil(Models[i].gibs.mask[a]);
323 Models[i].gibs.base := nil;
324 Models[i].gibs.mask := nil;
325 Models[i].gibs.rect := nil;
326 {$ENDIF}
327 end;
328
329 procedure r_Map_LoadModel (i: Integer);
330 var prefix: AnsiString; a: Integer; d: TDirection; m: ^TPlayerModelInfo;
331 begin
332 ASSERT(i < Length(Models));
333 ASSERT(i < Length(PlayerModelsArray));
334 r_Map_FreeModel(i);
335 m := @PlayerModelsArray[i];
336 prefix := m.FileName + ':TEXTURES/';
337 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
338 begin
339 for a := A_STAND to A_LAST do
340 begin
341 Models[i].anim[d, a].base := nil;
342 Models[i].anim[d, a].mask := nil;
343 if m.anim[d, a].resource <> '' then
344 Models[i].anim[d, a].base := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].resource, 64, 64, m.anim[d, a].frames, [TGLHints.txNoRepeat], true);
345 if m.anim[d, a].mask <> '' then
346 Models[i].anim[d, a].mask := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].mask, 64, 64, m.anim[d, a].frames, [TGLHints.txNoRepeat], true);
347 end
348 end;
349 {$IFDEF ENABLE_GIBS}
350 Models[i].gibs.base := nil;
351 Models[i].gibs.mask := nil;
352 Models[i].gibs.rect := nil;
353 if m.GibsCount > 0 then
354 begin
355 SetLength(Models[i].gibs.base, m.GibsCount);
356 SetLength(Models[i].gibs.mask, m.GibsCount);
357 SetLength(Models[i].gibs.rect, m.GibsCount);
358 for a := 0 to m.GibsCount - 1 do
359 Models[i].gibs.rect[a] := DefaultGibSize;
360 if r_Textures_LoadStreamFromFile(prefix + m.GibsResource, 32, 32, m.GibsCount, m.GibsCount, Models[i].gibs.base, Models[i].gibs.rect, [TGLHints.txNoRepeat]) then
361 begin
362 if r_Textures_LoadStreamFromFile(prefix + m.GibsMask, 32, 32, m.GibsCount, m.GibsCount, Models[i].gibs.mask, nil, [TGLHints.txNoRepeat]) then
363 begin
364 // ok
365 end;
366 end;
367 end;
368 {$ENDIF}
369 end;
370
371 procedure r_Map_LoadMonsterAnim (m, a: Integer; d: TDirection);
372 const dir: array [TDirection] of AnsiString = ('_L', '');
373 var w, h, count: Integer;
374 begin
375 count := MONSTER_ANIMTABLE[m].AnimCount[a];
376 if count > 0 then
377 begin
378 w := MTABLE[m].w;
379 h := MTABLE[m].h;
380 if (m = MONSTER_SOUL) and (a = ANIM_DIE) then
381 begin
382 // special case
383 w := 128;
384 h := 128;
385 end;
386 MonTextures[m, a, d] := r_Textures_LoadMultiFromFileAndInfo(
387 GameWAD + ':MTEXTURES/' + MONSTERTABLE[m].name + '_' + ANIMTABLE[a].name + dir[d],
388 w,
389 h,
390 count,
391 [TGLHints.txNoRepeat],
392 False
393 );
394 end
395 else
396 MonTextures[m, a, d] := nil;
397 end;
398
399 procedure r_Map_Load;
400 const
401 WeapName: array [0..WP_LAST] of AnsiString = ('', 'CSAW', 'HGUN', 'SG', 'SSG', 'MGUN', 'RKT', 'PLZ', 'BFG', 'SPL', 'FLM');
402 WeapPos: array [0..W_POS_LAST] of AnsiString = ('', '_UP', '_DN');
403 WeapAct: array [0..W_ACT_LAST] of AnsiString = ('', '_FIRE');
404 PunchName: array [Boolean] of AnsiString = ('PUNCH', 'PUNCHB');
405 var
406 i, j, k: Integer; d: TDirection; b: Boolean;
407 begin
408 // --------- items --------- //
409 r_Common_SetLoading(_lc[I_LOAD_ITEMS_DATA], ITEM_LAST + 1);
410 for i := 0 to ITEM_LAST do
411 begin
412 Items[i].tex := r_Common_LoadTextureMultiFromFileAndInfo(
413 GameWAD + ':TEXTURES/' + ItemAnim[i].name,
414 ItemAnim[i].w,
415 ItemAnim[i].h,
416 ItemAnim[i].anim.frames,
417 [TGLHints.txNoRepeat],
418 false
419 );
420 Items[i].frame := 0;
421 end;
422 // --------- monsters --------- //
423 r_Common_SetLoading(_lc[I_LOAD_MONSTER_TEXTURES], MONSTER_MAN - MONSTER_DEMON + 1);
424 for i := MONSTER_DEMON to MONSTER_MAN do
425 begin
426 for j := 0 to ANIM_LAST do
427 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
428 r_Map_LoadMonsterAnim(i, j, d);
429 r_Common_StepLoading(1);
430 end;
431 VileFire := r_Textures_LoadMultiFromFileAndInfo(GameWAD + ':TEXTURES/FIRE', 64, 128, VileFireAnim.frames, [TGLHints.txNoRepeat]);
432 // --------- player models --------- //
433 if PlayerModelsArray <> nil then
434 begin
435 r_Common_SetLoading(_lc[I_LOAD_MODELS], Length(PlayerModelsArray));
436 SetLength(Models, Length(PlayerModelsArray));
437 for i := 0 to High(PlayerModelsArray) do
438 begin
439 r_Map_LoadModel(i);
440 r_Common_StepLoading(1);
441 end;
442 end;
443 // --------- player weapons --------- //
444 r_Common_SetLoading(_lc[I_LOAD_WEAPONS_DATA], WP_LAST);
445 for i := 1 to WP_LAST do
446 begin
447 for j := 0 to W_POS_LAST do
448 for k := 0 to W_ACT_LAST do
449 WeapTextures[i, j, k] := r_Textures_LoadFromFile(GameWAD + ':WEAPONS\' + WeapName[i] + WeapPos[j] + WeapAct[k], [TGLHints.txNoRepeat]);
450 r_Common_StepLoading(1);
451 end;
452 // --------- gfx animations --------- //
453 {$IFDEF ENABLE_GFX}
454 r_Common_SetLoading('GFX Effects', R_GFX_LAST);
455 for i := 1 to R_GFX_LAST do
456 begin
457 if GFXAnim[i].anim.frames > 0 then
458 GFXTextures[i] := r_Common_LoadTextureMultiFromFileAndInfo(GameWad + ':TEXTURES/' + GFXAnim[i].name, GFXAnim[i].w, GFXAnim[i].h, GFXAnim[i].anim.frames, [TGLHints.txNoRepeat]);
459 end;
460 {$ENDIF}
461 // --------- shots --------- //
462 r_Common_SetLoading('Weapon splahses', WEAPON_LAST + 1);
463 for i := 0 to WEAPON_LAST do
464 begin
465 if ShotAnim[i].anim.frames > 0 then
466 ShotTextures[i] := r_Common_LoadTextureMultiFromFileAndInfo(GameWad + ':TEXTURES/' + ShotAnim[i].name, ShotAnim[i].w, ShotAnim[i].h, ShotAnim[i].anim.frames, [TGLHints.txNoRepeat]);
467 end;
468 // --------- flags --------- //
469 r_Common_SetLoading('Flags', 2);
470 FlagTextures[FLAG_NONE] := nil;
471 FlagTextures[FLAG_RED] := r_Common_LoadTextureMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGRED', 64, 64, 5, [TGLHints.txNoRepeat]);
472 FlagTextures[FLAG_BLUE] := r_Common_LoadTextureMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGBLUE', 64, 64, 5, [TGLHints.txNoRepeat]);
473 // FlagTextures[FLAG_DOM] := r_Common_LoadTextureMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGDOM', 64, 64, 8, [TGLHints.txNoRepeat]);
474 // --------- shells --------- //
475 {$IFDEF ENABLE_SHELLS}
476 r_Common_SetLoading('Shells', SHELL_LAST + 1);
477 for i := 0 to SHELL_LAST do
478 ShellTextures[i] := r_Common_LoadTextureFromFile(GameWad + ':TEXTURES/' + ShellAnim[i].name, [TGLHints.txNoRepeat]);
479 {$ENDIF}
480 // --------- other --------- //
481 r_Common_SetLoading('Effects', 3 * 2 + 3);
482 for b := false to true do
483 begin
484 for i := 0 to 2 do
485 PunchTextures[b, i] := r_Common_LoadTextureMultiFromFileAndInfo(GameWad + ':WEAPONS/' + PunchName[b] + WeapPos[i], 64, 64, PunchAnim.frames, [TGLHints.txNoRepeat]);
486 end;
487 InvulPenta := r_Common_LoadTextureFromFile(GameWad + ':TEXTURES/PENTA', [TGLHints.txNoRepeat]);
488 IndicatorTexture := r_Common_LoadTextureFromFile(GameWad + ':TEXTURES/PLRIND', [TGLHints.txNoRepeat]);
489 TalkTexture := r_Common_LoadTextureFromFile(GameWad + ':TEXTURES/TALKBUBBLE', [TGLHints.txNoRepeat]);
490 end;
491
492 procedure r_Map_Free;
493 var i, j, k: Integer; d: TDirection; b: Boolean;
494 begin
495 r_Common_FreeAndNil(TalkTexture);
496 r_Common_FreeAndNil(IndicatorTexture);
497 r_Common_FreeAndNil(InvulPenta);
498 for b := false to true do
499 for i := 0 to 2 do
500 r_Common_FreeAndNil(PunchTextures[b, i]);
501 {$IFDEF ENABLE_SHELLS}
502 for i := 0 to SHELL_LAST do
503 r_Common_FreeAndNil(ShellTextures[i]);
504 {$ENDIF}
505 for i := 0 to FLAG_LAST do
506 r_Common_FreeAndNil(FlagTextures[i]);
507 for i := 0 to WEAPON_LAST do
508 r_Common_FreeAndNil(ShotTextures[i]);
509 {$IFDEF ENABLE_GFX}
510 SetLength(gfxlist, 0);
511 for i := 0 to R_GFX_LAST do
512 r_Common_FreeAndNil(GFXTextures[i]);
513 {$ENDIF}
514 for i := 1 to WP_LAST do
515 for j := 0 to W_POS_LAST do
516 for k := 0 to W_ACT_LAST do
517 r_Common_FreeAndNil(WeapTextures[i, j, k]);
518 if Models <> nil then
519 for i := 0 to High(Models) do
520 r_Map_FreeModel(i);
521 for i := MONSTER_DEMON to MONSTER_MAN do
522 for j := 0 to ANIM_LAST do
523 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
524 r_Common_FreeAndNil(MonTextures[i, j, d]);
525 for i := 0 to ITEM_LAST do
526 r_Common_FreeAndNil(Items[i].tex);
527 end;
528
529 procedure r_Map_FreeTextures;
530 var i: Integer;
531 begin
532 plist.Clear;
533 r_Common_FreeAndNil(SkyTexture);
534 if RenTextures <> nil then
535 for i := 0 to High(RenTextures) do
536 r_Common_FreeAndNil(RenTextures[i].tex);
537 SetLength(RenTextures, 0);
538 end;
539
540 procedure r_Map_LoadTextures;
541 const DefaultAnimInfo: TAnimInfo = (loop: true; delay: 1; frames: 1; back: false);
542 var i, n: Integer; txt: TAnimTextInfo;
543 begin
544 r_Map_FreeTextures;
545 if Textures <> nil then
546 begin
547 n := Length(Textures);
548 SetLength(RenTextures, n);
549 r_Common_SetLoading(_lc[I_LOAD_TEXTURES], n);
550 for i := 0 to n - 1 do
551 begin
552 RenTextures[i].tex := nil;
553 RenTextures[i].anim := DefaultAnimInfo;
554 case Textures[i].TextureName of
555 TEXTURE_NAME_WATER: RenTextures[i].spec := TEXTURE_SPECIAL_WATER;
556 TEXTURE_NAME_ACID1: RenTextures[i].spec := TEXTURE_SPECIAL_ACID1;
557 TEXTURE_NAME_ACID2: RenTextures[i].spec := TEXTURE_SPECIAL_ACID2;
558 else
559 RenTextures[i].spec := 0;
560 RenTextures[i].tex := r_Textures_LoadMultiTextFromFile(Textures[i].FullName, txt, []);
561 if RenTextures[i].tex <> nil then
562 begin
563 RenTextures[i].anim := txt.anim;
564 r_Common_StepLoading(1);
565 end
566 else
567 begin
568 e_LogWritefln('r_Map_LoadTextures: failed to load texture: %s', [Textures[i].FullName]);
569 end;
570 end;
571 ASSERT(RenTextures[i].anim.frames > 0);
572 ASSERT(RenTextures[i].anim.delay > 0);
573 end;
574 end;
575 if gMapInfo.SkyFullName <> '' then
576 begin
577 r_Common_SetLoading(_lc[I_LOAD_SKY], 1);
578 SkyTexture := r_Common_LoadTextureFromFile(gMapInfo.SkyFullName, [TGLHints.txNoRepeat]);
579 end;
580 plist.Clear;
581 end;
582
583 procedure r_Map_DrawPanel (p: TPanel);
584 var Texture: Integer; t: TGLMultiTexture; tex: TGLTexture; count, frame: LongInt; a: TAnimInfo;
585 begin
586 ASSERT(p <> nil);
587 if p.FCurTexture >= 0 then
588 begin
589 ASSERT(p.FCurTexture <= High(p.TextureIDs));
590 Texture := p.TextureIDs[p.FCurTexture].Texture;
591 t := nil;
592 ASSERT(Texture >= -1);
593 ASSERT(Texture <= High(RenTextures));
594 if Texture >= 0 then
595 begin
596 t := RenTextures[Texture].tex;
597 if (RenTextures[Texture].spec = 0) or (t <> nil) then
598 begin
599 count := 0; frame := 0;
600 if p.AnimTime <= gTime then
601 begin
602 a := RenTextures[Texture].anim;
603 a.loop := p.AnimLoop;
604 g_Anim_GetFrameByTime(a, (gTime - p.AnimTime) DIV GAME_TICK, count, frame);
605 end;
606 if t <> nil then
607 begin
608 tex := t.GetTexture(frame);
609 r_Draw_TextureRepeat(tex, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending);
610 end
611 else
612 r_Draw_TextureRepeat(nil, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255, false);
613 end;
614 end;
615
616 if t = nil then
617 begin
618 case RenTextures[Texture].spec of
619 TEXTURE_SPECIAL_WATER: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 0, 255, 255);
620 TEXTURE_SPECIAL_ACID1: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 230, 0, 255);
621 TEXTURE_SPECIAL_ACID2: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 230, 0, 0, 255);
622 end
623 end
624 end
625 end;
626
627 procedure r_Map_DrawPanelType (panelTyp: DWORD);
628 var tagMask, i: Integer; p: TPanel;
629 begin
630 i := 0;
631 tagMask := PanelTypeToTag(panelTyp);
632 while plist.count > 0 do
633 begin
634 p := TPanel(plist.Front());
635 if (p.tag and tagMask) = 0 then
636 break;
637 r_Map_DrawPanel(p);
638 Inc(i);
639 plist.PopFront
640 end;
641 end;
642
643 procedure r_Map_DrawItems (x, y, w, h: Integer; drop: Boolean);
644 var i, xx, yy: Integer; it: PItem; t: TGLMultiTexture; tex: TGLTexture;
645 begin
646 if ggItems <> nil then
647 begin
648 for i := 0 to High(ggItems) do
649 begin
650 it := @ggItems[i];
651 if it.used and it.alive and (it.dropped = drop) and (it.ItemType > ITEM_NONE) and (it.ItemType <= ITEM_LAST) then
652 begin
653 t := Items[it.ItemType].tex;
654 if g_Collide(it.obj.x, it.obj.y, t.width, t.height, x, y, w, h) then
655 begin
656 r_Common_GetObjectPos(it.obj, xx, yy);
657 tex := t.GetTexture(Items[it.ItemType].frame);
658 r_Draw_TextureRepeat(tex, xx, yy, tex.width, tex.height, false, 255, 255, 255, 255, false);
659 end;
660 end;
661 end;
662 end;
663 // TODO draw g_debug_frames
664 end;
665
666 function r_Map_GetMonsterTexture (m, a: Integer; d: TDirection; out t: TGLMultiTexture; out dx, dy: Integer; out flip: Boolean): Boolean;
667 // var c: Integer;
668 begin
669 t := nil; dx := 0; dy := 0; flip := false;
670 result := MonTextures[m, a, d] <> nil;
671 if result = false then
672 begin
673 flip := true;
674 if d = TDirection.D_RIGHT then d := TDirection.D_LEFT else d := TDirection.D_RIGHT;
675 result := MonTextures[m, a, d] <> nil;
676 end;
677 if result = true then
678 begin
679 t := MonTextures[m, a, d];
680 if d = TDirection.D_LEFT then
681 begin
682 dx := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].X;
683 dy := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].Y;
684 end
685 else
686 begin
687 dx := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].X;
688 dy := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].Y;
689 end;
690 if flip then
691 begin
692 // c := (MONSTERTABLE[MonsterType].Rect.X - dx) + MONSTERTABLE[MonsterType].Rect.Width;
693 // dx := MTABLE[m].width - c - MONSTERTABLE[MonsterType].Rect.X;
694 dx := -dx;
695 end;
696 end;
697 end;
698
699 procedure r_Map_DrawMonsterAttack (constref mon: TMonster);
700 var o: TObj; count, frame, xx, yy: LongInt; tex: TGLTexture;
701 begin
702 if VileFire <> nil then
703 begin
704 if (mon.MonsterType = MONSTER_VILE) and (mon.MonsterState = MONSTATE_SHOOT) and (mon.VileFireTime <= gTime) then
705 begin
706 if r_Common_GetPosByUID(mon.MonsterTargetUID, o, xx, yy) then
707 begin
708 g_Anim_GetFrameByTime(VileFireAnim, (gTime - mon.VileFireTime) DIV GAME_TICK, count, frame);
709 tex := VileFire.GetTexture(frame);
710 r_Draw_TextureRepeat(tex, xx + o.rect.x + (o.rect.width div 2) - VILEFIRE_DX, yy + o.rect.y + o.rect.height - VILEFIRE_DY, tex.width, tex.height, False, 255, 255, 255, 255, false);
711 end;
712 end;
713 end;
714 end;
715
716 procedure r_Map_DrawMonster (constref mon: TMonster);
717 var m, a, xx, yy, dx, dy: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture;
718 begin
719 m := mon.MonsterType;
720 a := mon.MonsterAnim;
721 d := mon.GameDirection;
722
723 if r_Map_GetMonsterTexture(m, a, d, t, dx, dy, flip) then
724 begin
725 r_Common_GetObjectPos(mon.obj, xx, yy);
726 r_Draw_MultiTextureRepeat(t, mon.DirAnim[a, d], false, xx + dx, yy + dy, t.width, t.height, flip, 255, 255, 255, 255, false);
727 end;
728
729 // TODO draw g_debug_frames
730 end;
731
732 procedure r_Map_DrawMonsters (x, y, w, h: Integer);
733 var i: Integer; m: TMonster;
734 begin
735 if gMonsters <> nil then
736 begin
737 for i := 0 to High(gMonsters) do
738 begin
739 m := gMonsters[i];
740 if m <> nil then
741 begin
742 r_Map_DrawMonsterAttack(m);
743 // TODO select from grid
744 if g_Collide(m.obj.x + m.obj.rect.x, m.obj.y + m.obj.rect.y, m.obj.rect.width, m.obj.rect.height, x, y, w, h) then
745 r_Map_DrawMonster(m);
746 end;
747 end;
748 end;
749 end;
750
751 function r_Map_GetPlayerModelTex (i: Integer; var a: Integer; var d: TDirection; out flip: Boolean): Boolean;
752 begin
753 flip := false;
754 result := Models[i].anim[d, a].base <> nil;
755 if result = false then
756 begin
757 flip := true;
758 if d = TDirection.D_LEFT then d := TDirection.D_RIGHT else d := TDirection.D_LEFT;
759 result := Models[i].anim[d, a].base <> nil;
760 end;
761 end;
762
763 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer; alpha: Byte);
764 var a, pos, act, xx, yy, angle: Integer; d: TDirection; flip, back: Boolean; t: TGLMultiTexture; tex: TGLTexture; c: TRGB;
765 begin
766 a := pm.CurrentAnimation;
767 d := pm.Direction;
768
769 (* draw flag*)
770 t := FlagTextures[pm.Flag];
771 if (t <> nil) and not (a in [A_DIE1, A_DIE2]) then
772 begin
773 flip := d = TDirection.D_RIGHT;
774 angle := PlayerModelsArray[pm.id].FlagAngle;
775 xx := PlayerModelsArray[pm.id].FlagPoint.X;
776 yy := PlayerModelsArray[pm.id].FlagPoint.Y;
777 tex := t.GetTexture(FlagFrame);
778 r_Draw_TextureRepeatRotate(
779 tex,
780 x + IfThen(flip, 2 * FLAG_BASEPOINT.X - xx + 1, xx - 1) - FLAG_BASEPOINT.X,
781 y + yy - FLAG_BASEPOINT.Y + 1,
782 tex.width,
783 tex.height,
784 flip,
785 255, 255, 255, 255, false,
786 IfThen(flip, 64 - FLAG_BASEPOINT.X, FLAG_BASEPOINT.X),
787 FLAG_BASEPOINT.Y,
788 IfThen(flip, angle, -angle)
789 );
790 end;
791
792 (* draw weapon *)
793 if PlayerModelsArray[pm.id].HaveWeapon and not (a in [A_DIE1, A_DIE2, A_PAIN]) then
794 begin
795 case a of
796 A_SEEUP, A_ATTACKUP: pos := W_POS_UP;
797 A_SEEDOWN, A_ATTACKDOWN: pos := W_POS_DOWN;
798 else pos := W_POS_NORMAL;
799 end;
800 if (a in [A_ATTACK, A_ATTACKUP, A_ATTACKDOWN]) or pm.GetFire() then
801 act := W_ACT_FIRE
802 else
803 act := W_ACT_NORMAL;
804 tex := WeapTextures[pm.CurrentWeapon, pos, act];
805 if tex <> nil then
806 begin
807 xx := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].X;
808 yy := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].Y;
809 r_Draw_Texture(
810 tex,
811 x + xx,
812 y + yy,
813 tex.width,
814 tex.height,
815 d = TDirection.D_LEFT,
816 255, 255, 255, alpha, false
817 );
818 end;
819 end;
820
821 (* draw body *)
822 if r_Map_GetPlayerModelTex(pm.id, a, d, flip) then
823 begin
824 t := Models[pm.id].anim[d, a].base;
825 back := PlayerModelsArray[pm.id].anim[d, a].back;
826 r_Draw_MultiTextureRepeat(t, pm.AnimState, back, x, y, t.width, t.height, flip, 255, 255, 255, alpha, false);
827 t := Models[pm.id].anim[d, a].mask;
828 if t <> nil then
829 begin
830 c := pm.Color;
831 r_Draw_MultiTextureRepeat(t, pm.AnimState, back, x, y, t.width, t.height, flip, c.r, c.g, c.b, alpha, false);
832 end;
833 end;
834 end;
835
836 procedure r_Map_DrawBubble (x, y: Integer; cb, cf: TRGB);
837 const w = 20; h = 14;
838 const dx = 6; dy = 8; dot = 6; size = 2;
839 const tx = 6; ty = h - 1;
840 begin
841 // Outer box (top/down)
842 r_Draw_FillRect(x + 1, y, x + w - 1, y + 1, cb.R, cb.G, cb.B, 255);
843 r_Draw_FillRect(x + 1, y + h - 1, x + w - 1, y + h, cb.R, cb.G, cb.B, 255);
844 // Outer box (left/right)
845 r_Draw_FillRect(x, y + 1, x + 1, y + h - 1, cb.R, cb.G, cb.B, 255);
846 r_Draw_FillRect(x + w - 1, y + 1, x + w, y + h - 1, cb.R, cb.G, cb.B, 255);
847 // Outer tail
848 r_Draw_FillRect(x + tx - 1, y + ty + 0, x + tx + 3 + 1, y + ty + 1, cb.R, cb.G, cb.B, 255);
849 r_Draw_FillRect(x + tx - 1, y + ty + 1, x + tx + 2 + 1, y + ty + 2, cb.R, cb.G, cb.B, 255);
850 r_Draw_FillRect(x + tx - 1, y + ty + 2, x + tx + 1 + 1, y + ty + 3, cb.R, cb.G, cb.B, 255);
851 r_Draw_FillRect(x + tx - 1, y + ty + 3, x + tx + 0 + 1, y + ty + 4, cb.R, cb.G, cb.B, 255);
852 // Inner tail
853 r_Draw_FillRect(x + tx, y + ty + 0, x + tx + 3, y + ty + 1, cf.R, cf.G, cf.B, 255);
854 r_Draw_FillRect(x + tx, y + ty + 1, x + tx + 2, y + ty + 2, cf.R, cf.G, cf.B, 255);
855 r_Draw_FillRect(x + tx, y + ty + 2, x + tx + 1, y + ty + 3, cf.R, cf.G, cf.B, 255);
856 // Inner box
857 r_Draw_FillRect(x + 1, y + 1, x + w - 1, y + h - 1, cf.R, cf.G, cf.B, 255);
858 // Dots
859 r_Draw_FillRect(x + dx + 0*3, y + dy, x + dx + 0*3 + size, y + dy + size, cb.R, cb.G, cb.B, 255);
860 r_Draw_FillRect(x + dx + 1*3, y + dy, x + dx + 1*3 + size, y + dy + size, cb.R, cb.G, cb.B, 255);
861 r_Draw_FillRect(x + dx + 2*3, y + dy, x + dx + 2*3 + size, y + dy + size, cb.R, cb.G, cb.B, 255);
862 end;
863
864 procedure r_Map_DrawTalkBubble (p: TPlayer);
865 var xx, yy, x, y: Integer; cb, cf: TRGB;
866 begin
867 r_Common_GetPlayerPos(p, xx, yy);
868 x := xx + p.obj.rect.x + p.obj.rect.width div 2;
869 y := yy;
870 cb := _RGB(63, 63, 63);
871 cf := _RGB(240, 240, 240);
872 case gChatBubble of
873 1: // simple text
874 begin
875 r_Common_DrawText('[...]', x, y, 255, 255, 255, 255, stdfont, TBasePoint.BP_DOWN);
876 end;
877 2: // adv team color
878 begin
879 case p.Team of
880 TEAM_RED: cb := _RGB(255, 63, 63);
881 TEAM_BLUE: cb := _RGB(63, 63, 255);
882 end;
883 r_Map_DrawBubble(x, y - 18, cb, cf);
884 end;
885 3: // adv player color
886 begin
887 cb := p.Model.Color;
888 cf.R := MIN(cb.R * 2 + 64, 255);
889 cf.G := MIN(cb.G * 2 + 64, 255);
890 cf.B := MIN(cb.B * 2 + 64, 255);
891 if (ABS(cf.R - cb.R) < 32) or (ABS(cf.G - cb.G) < 32) or (ABS(cf.B - cb.B) < 32) then
892 begin
893 cb.R := MAX(cf.R div 2 - 16, 0);
894 cb.G := MAX(cf.G div 2 - 16, 0);
895 cb.B := MAX(cf.B div 2 - 16, 0);
896 end;
897 r_Map_DrawBubble(x, y - 18, cb, cf);
898 end;
899 4: // textured
900 if TalkTexture <> nil then
901 begin
902 r_Common_DrawTexture(TalkTexture, x + 5, y, TalkTexture.width, TalkTexture.height, TBasePoint.BP_DOWN);
903 end;
904 end;
905 end;
906
907 procedure r_Map_DrawPlayer (p, drawed: TPlayer);
908 var x, y, ax, ay, w, h: Integer; b, flip: Boolean; t: TGLMultiTexture; tex: TGLTexture; alpha: Byte; count, frame: LongInt;
909 begin
910 if p.alive then
911 begin
912 r_Common_GetPlayerPos(p, x, y);
913
914 (* punch effect *)
915 if p.PunchTime <= gTime then
916 begin
917 g_Anim_GetFrameByTime(PunchAnim, (gTime - p.PunchTime) DIV GAME_TICK, count, frame);
918 if count < 1 then
919 begin
920 b := R_BERSERK in p.FRulez;
921 if p.FKeys[KEY_DOWN].pressed then
922 t := PunchTextures[b, 2]
923 else if p.FKeys[KEY_UP].pressed then
924 t := PunchTextures[b, 1]
925 else
926 t := PunchTextures[b, 0];
927 if t <> nil then
928 begin
929 flip := p.Direction = TDirection.D_LEFT;
930 ax := IfThen(flip, 15 - p.Obj.Rect.X, p.Obj.Rect.X - 15); // ???
931 ay := p.Obj.Rect.Y - 11;
932 tex := t.GetTexture(frame);
933 r_Draw_TextureRepeat(tex, x + ax, y + ay, tex.width, tex.height, flip, 255, 255, 255, 255, false)
934 end;
935 end;
936 end;
937
938 (* invulnerability effect *)
939 if (InvulPenta <> nil) and (p.FMegaRulez[MR_INVUL] > gTime) and ((p <> drawed) or (p.SpawnInvul >= gTime)) then
940 begin
941 w := InvulPenta.width;
942 h := InvulPenta.height;
943 ax := p.Obj.Rect.X + (p.Obj.Rect.Width div 2) - (w div 2); // + IfThen(flip, +4, -2) // ???
944 ay := p.Obj.Rect.Y + (p.Obj.Rect.Height div 2) - (h div 2) - 7; // ???
945 r_Draw_Texture(InvulPenta, x + ax, y + ay, w, h, false, 255, 255, 255, 255, false);
946 end;
947
948 (* invisibility effect *)
949 alpha := 255;
950 if p.FMegaRulez[MR_INVIS] > gTime then
951 begin
952 if (drawed <> nil) and ((p = drawed) or ((p.Team = drawed.Team) and (gGameSettings.GameMode <> GM_DM))) then
953 begin
954 if (p.FMegaRulez[MR_INVIS] - gTime > 2100) or not ODD((p.FMegaRulez[MR_INVIS] - gTime) div 300) then
955 alpha := 55;
956 end
957 else
958 alpha := 1; // ???
959 end;
960
961 r_Map_DrawPlayerModel(p.Model, x, y, alpha);
962 end;
963 // TODO draw g_debug_frames
964
965 if (gChatBubble > 0) and p.FKeys[KEY_CHAT].Pressed and (p.Ghost = false) then
966 if (p.FMegaRulez[MR_INVIS] <= gTime) or ((drawed <> nil) and ((p = drawed) or (p.Team = drawed.Team) and (gGameSettings.GameMode <> GM_DM))) then
967 r_Map_DrawTalkBubble(p);
968
969 // TODO draw aim
970 end;
971
972 procedure r_Map_DrawPlayers (x, y, w, h: Integer; player: TPlayer);
973 var i: Integer;
974 begin
975 if gPlayers <> nil then
976 for i := 0 to High(gPlayers) do
977 if gPlayers[i] <> nil then
978 r_Map_DrawPlayer(gPlayers[i], player);
979 end;
980
981 {$IFDEF ENABLE_GIBS}
982 function r_Map_GetGibSize (m, i: Integer): TRectWH;
983 begin
984 result := Models[m].gibs.rect[i];
985 end;
986
987 procedure r_Map_DrawGibs (x, y, w, h: Integer);
988 var i, xx, yy, m, id, rx, ry, ra: Integer; p: PObj; t: TGLTexture;
989 begin
990 if gGibs <> nil then
991 begin
992 for i := 0 to High(gGibs) do
993 begin
994 if gGibs[i].alive then
995 begin
996 p := @gGibs[i].Obj;
997 if g_Obj_Collide(x, y, w, h, p) then
998 begin
999 r_Common_GetObjectPos(p^, xx, yy);
1000 id := gGibs[i].GibID;
1001 m := gGibs[i].ModelID;
1002 t := Models[m].gibs.base[id];
1003 if t <> nil then
1004 begin
1005 rx := p.Rect.X + p.Rect.Width div 2;
1006 ry := p.Rect.Y + p.Rect.Height div 2;
1007 ra := gGibs[i].RAngle;
1008 r_Draw_TextureRepeatRotate(t, xx, yy, t.width, t.height, false, 255, 255, 255, 255, false, rx, ry, ra);
1009 t := Models[m].gibs.mask[id];
1010 if t <> nil then
1011 r_Draw_TextureRepeatRotate(t, xx, yy, t.width, t.height, false, gGibs[i].Color.R, gGibs[i].Color.G, gGibs[i].Color.B, 255, false, rx, ry, ra);
1012 // r_Draw_TextureRepeatRotate(nil, xx + p.Rect.X, yy + p.Rect.Y, p.Rect.Width, p.Rect.Height, false, 255, 255, 255, 255, false, p.Rect.Width div 2, p.Rect.Height div 2, ra);
1013 end;
1014 end;
1015 end;
1016 end;
1017 end;
1018 // TODO draw g_debug_frames
1019 end;
1020 {$ENDIF}
1021
1022 {$IFDEF ENABLE_CORPSES}
1023 procedure r_Map_DrawCorpses (x, y, w, h: Integer);
1024 var i, xx, yy: Integer; p: TCorpse;
1025 begin
1026 if gCorpses <> nil then
1027 begin
1028 for i := 0 to High(gCorpses) do
1029 begin
1030 p := gCorpses[i];
1031 if (p <> nil) and (p.state <> CORPSE_STATE_REMOVEME) and (p.model <> nil) then
1032 begin
1033 r_Common_GetObjectPos(p.obj, xx, yy);
1034 r_Map_DrawPlayerModel(p.model, xx, yy, 255);
1035 end;
1036 end;
1037 end;
1038 // TODO draw g_debug_frames
1039 end;
1040 {$ENDIF}
1041
1042 {$IFDEF ENABLE_GFX}
1043 function r_Map_GetGFXID (): Integer;
1044 var i: Integer;
1045 begin
1046 i := 0;
1047 if gfxlist <> nil then
1048 begin
1049 while (i < Length(gfxlist)) and (gfxlist[i].typ > 0) do
1050 Inc(i);
1051 if i >= Length(gfxlist) then
1052 SetLength(gfxlist, Length(gfxlist) + 1)
1053 end
1054 else
1055 SetLength(gfxlist, 1);
1056 gfxlist[i].typ := R_GFX_NONE;
1057 result := i
1058 end;
1059
1060 procedure r_Map_NewGFX (typ, x, y: Integer);
1061 var i: Integer;
1062 begin
1063 if gpart_dbg_enabled and (typ > 0) and (typ <= R_GFX_LAST) then
1064 begin
1065 i := r_Map_GetGFXID();
1066 if i >= 0 then
1067 begin
1068 gfxlist[i].typ := typ;
1069 gfxlist[i].x := x;
1070 gfxlist[i].y := y;
1071 gfxlist[i].oldX := x;
1072 gfxlist[i].oldY := y;
1073 gfxlist[i].anim := GFXAnim[typ].anim;
1074 gfxlist[i].time := gTime DIV GAME_TICK;
1075 gfxlist[i].frame := 0;
1076 INC(gfxlist[i].anim.delay, Random(GFXAnim[typ].rdelay));
1077 end;
1078 end;
1079 end;
1080
1081 procedure r_Map_ResetGFX;
1082 begin
1083 SetLength(gfxlist, 0);
1084 end;
1085
1086 procedure r_Map_UpdateGFX (tick: LongWord);
1087 var i: Integer; count: LongInt;
1088 begin
1089 if gfxlist <> nil then
1090 begin
1091 for i := 0 to High(gfxlist) do
1092 begin
1093 if (gfxlist[i].typ > 0) and (tick >= gfxlist[i].time) then
1094 begin
1095 g_Anim_GetFrameByTime(gfxlist[i].anim, tick - gfxlist[i].time, count, gfxlist[i].frame);
1096 if count < 1 then
1097 begin
1098 gfxlist[i].oldX := gfxlist[i].x;
1099 gfxlist[i].oldY := gfxlist[i].y;
1100 case gfxlist[i].typ of
1101 R_GFX_FLAME, R_GFX_SMOKE:
1102 begin
1103 if Random(3) = 0 then
1104 gfxlist[i].x := gfxlist[i].x - 1 + Random(3);
1105 if Random(2) = 0 then
1106 gfxlist[i].y := gfxlist[i].y - Random(2);
1107 end;
1108 end;
1109 end
1110 else
1111 gfxlist[i].typ := R_GFX_NONE;
1112 end;
1113 end;
1114 end;
1115 end;
1116
1117 procedure r_Map_DrawGFX (x, y, w, h: Integer);
1118 var i, fx, fy, typ: Integer; t: TGLMultiTexture; tex: TGLTexture;
1119 begin
1120 if gfxlist <> nil then
1121 begin
1122 for i := 0 to High(gfxlist) do
1123 begin
1124 if gfxlist[i].typ > 0 then
1125 begin
1126 typ := gfxlist[i].typ;
1127 t := GFXTextures[typ];
1128 if t <> nil then
1129 begin
1130 fx := nlerp(gfxlist[i].oldX, gfxlist[i].x, gLerpFactor);
1131 fy := nlerp(gfxlist[i].oldY, gfxlist[i].y, gLerpFactor);
1132 tex := t.GetTexture(gfxlist[i].frame);
1133 r_Draw_TextureRepeat(tex, fx, fy, tex.width, tex.height, false, 255, 255, 255, 255 - GFXAnim[typ].alpha, false);
1134 end;
1135 end;
1136 end;
1137 end;
1138 end;
1139
1140 procedure r_Map_DrawParticles (x, y, w, h: Integer);
1141 var i, fx, fy: Integer; factor: Single;
1142 begin
1143 if gpart_dbg_enabled and (Particles <> nil) then
1144 begin
1145 r_Draw_EnableTexture2D(false);
1146 factor := r_pixel_scale * g_dbg_scale;
1147 if factor < 0.6 then
1148 glPointSize(1)
1149 else if factor > 1.3 then
1150 glPointSize(factor + 1)
1151 else
1152 glPointSize(2);
1153 glDisable(GL_POINT_SMOOTH);
1154 glEnable(GL_BLEND);
1155 glBlendFunc(GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA);
1156
1157 r_Draw_SetColor(255, 255, 255, 255);
1158 glBegin(GL_POINTS);
1159 for i := 0 to High(Particles) do
1160 begin
1161 if Particles[i].alive then
1162 begin
1163 fx := nlerp(Particles[i].oldX, Particles[i].x, gLerpFactor);
1164 fy := nlerp(Particles[i].oldY, Particles[i].y, gLerpFactor);
1165 glColor4ub(Particles[i].red, Particles[i].green, Particles[i].blue, Particles[i].alpha);
1166 glVertex2i(fx, fy);
1167 end;
1168 end;
1169 glEnd;
1170 r_Draw_SetColor(0, 0, 0, 255);
1171
1172 glDisable(GL_BLEND);
1173 end;
1174 end;
1175 {$ENDIF}
1176
1177 procedure r_Map_DrawShots (x, y, w, h: Integer);
1178 var i, a, xx, yy, pX, pY, typ: Integer; count, frame: LongInt; t: TGLMultiTexture; tex: TGLTexture;
1179 begin
1180 if Shots <> nil then
1181 begin
1182 for i := 0 to High(Shots) do
1183 begin
1184 typ := Shots[i].ShotType;
1185 if typ <> 0 then
1186 begin
1187 t := ShotTextures[typ];
1188 if t <> nil then
1189 begin
1190 a := 0;
1191 case typ of
1192 WEAPON_ROCKETLAUNCHER, WEAPON_BARON_FIRE, WEAPON_MANCUB_FIRE, WEAPON_SKEL_FIRE:
1193 a := -GetAngle2(Shots[i].Obj.Vel.X, Shots[i].Obj.Vel.Y)
1194 end;
1195 r_Common_GetObjectPos(Shots[i].Obj, xx, yy);
1196 pX := Shots[i].Obj.Rect.Width div 2;
1197 pY := Shots[i].Obj.Rect.Height div 2;
1198 g_Anim_GetFrameByTime(ShotAnim[typ].anim, (gTime - Shots[i].time) DIV GAME_TICK, count, frame);
1199 tex := t.GetTexture(frame);
1200 r_Draw_TextureRepeatRotate(tex, xx, yy, tex.width, tex.height, false, 255, 255, 255, 255, false, pX, pY, a);
1201 end;
1202 end;
1203 end;
1204 end;
1205 // TODO draw g_debug_frames
1206 end;
1207
1208 procedure r_Map_DrawFlags (x, y, w, h: Integer);
1209 var i, dx, xx, yy: Integer; flip: Boolean; t: TGLMultiTexture; tex: TGLTexture;
1210 begin
1211 if gGameSettings.GameMode = GM_CTF then
1212 begin
1213 for i := FLAG_RED to FLAG_BLUE do
1214 begin
1215 if not (gFlags[i].state in [FLAG_STATE_NONE, FLAG_STATE_CAPTURED]) then
1216 begin
1217 r_Common_GetObjectPos(gFlags[i].Obj, xx, yy);
1218 flip := gFlags[i].Direction = TDirection.D_LEFT;
1219 if flip then dx := -1 else dx := +1;
1220 t := FlagTextures[i];
1221 tex := t.GetTexture(FlagFrame);
1222 r_Draw_TextureRepeat(tex, xx + dx, yy + 1, tex.width, tex.height, flip, 255, 255, 255, 255, false)
1223 end;
1224 end;
1225 end;
1226 // TODO g_debug_frames
1227 end;
1228
1229 {$IFDEF ENABLE_SHELLS}
1230 procedure r_Map_DrawShells (x, y, w, h: Integer);
1231 var i, xx, yy, typ: Integer; t: TGLTexture; p: PObj;
1232 begin
1233 if gShells <> nil then
1234 begin
1235 for i := 0 to High(gShells) do
1236 begin
1237 if gShells[i].alive then
1238 begin
1239 typ := gShells[i].SType;
1240 if typ <= SHELL_LAST then
1241 begin
1242 p := @gShells[i].Obj;
1243 if g_Obj_Collide(x, y, w, h, p) then
1244 begin
1245 t := ShellTextures[typ];
1246 if t <> nil then
1247 begin
1248 r_Common_GetObjectPos(p^, xx, yy);
1249 r_Draw_TextureRepeatRotate(t, xx, yy, t.width, t.height, false, 255, 255, 255, 255, false, ShellAnim[typ].dx, ShellAnim[typ].dy, gShells[i].RAngle);
1250 end;
1251 end;
1252 end;
1253 end;
1254 end;
1255 end;
1256 end;
1257 {$ENDIF}
1258
1259 procedure r_Map_CalcSkyParallax (cx, cy, vw, vh, sw, sh, mw, mh: LongInt; out x, y, w, h: LongInt);
1260 const
1261 factor = 120; (* size ratio between view and sky (120%) *)
1262 limit = 100; (* max speed for parallax *)
1263 var
1264 msw, msh, mvw, mvh, svw, svh: LongInt;
1265 begin
1266 msw := vw * factor div 100;
1267 msh := vh * factor div 100;
1268 r_Common_CalcAspect(sw, sh, msw, msh, (sw / sh) <= (msw / msh), w, h);
1269
1270 (* calc x parallax or sky center on speed limit *)
1271 mvw := MAX(1, mw - vw);
1272 svw := w - vw;
1273 if 100 * svw div mvw <= limit then
1274 x := -cx * svw div mvw
1275 else
1276 x := -svw div 2;
1277
1278 (* calc y parallax or sky center on speed limit *)
1279 mvh := MAX(1, mh - vh);
1280 svh := h - vh;
1281 if 100 * svh div mvh <= limit then
1282 y := -cy * svh div mvh
1283 else
1284 y := -svh div 2;
1285
1286 (* handle out of map bounds *)
1287 if x > 0 then x := 0;
1288 if y > 0 then y := 0;
1289 if x < -svw then x := -svw;
1290 if y < -svh then y := -svh;
1291 end;
1292
1293 procedure r_Map_DrawScreenEffect (x, y, w, h, level: Integer; r, g, b: Byte);
1294 var i: Integer;
1295 begin
1296 if level > 0 then
1297 begin
1298 case level of
1299 0..14: i := 0;
1300 15..34: i := 1;
1301 35..54: i := 2;
1302 55..74: i := 3;
1303 75..94: i := 4;
1304 else i := 5
1305 end;
1306 r_Draw_FillRect(x, y, x + w, y + h, r, g, b, i * 50)
1307 end;
1308 end;
1309
1310 procedure r_Map_DrawScreenEffects (x, y, w, h: Integer; p: TPlayer);
1311 begin
1312 if p <> nil then
1313 begin
1314 r_Map_DrawScreenEffect(x, y, w, h, p.pain, 255, 0, 0);
1315 r_Map_DrawScreenEffect(x, y, w, h, p.pickup, 150, 200, 150);
1316 if (p.FMegaRulez[MR_INVUL] >= gTime) and (p.SpawnInvul < gTime) then
1317 begin
1318 if ((p.FMegaRulez[MR_INVUL] - gTime) > 2100) or not ODD((p.FMegaRulez[MR_INVUL] - gTime) div 300) then
1319 r_Draw_InvertRect(x, y, x + w, y + h, 191, 191, 191, 255);
1320 end;
1321 if p.FMegaRulez[MR_SUIT] >= gTime then
1322 begin
1323 if ((p.FMegaRulez[MR_SUIT] - gTime) > 2100) or not ODD((p.FMegaRulez[MR_SUIT] - gTime) div 300) then
1324 r_Draw_FillRect(x, y, x + w, y + h, 0, 96, 0, 55);
1325 end;
1326 if (p.Berserk >= 0) and (p.Berserk >= gTime) and (gFlash = 2) then
1327 begin
1328 r_Draw_FillRect(x, y, x + w, y + h, 255, 0, 0, 55);
1329 end;
1330 end;
1331 end;
1332
1333 procedure r_Map_DrawIndicator (p: TPlayer; color: TRGB; cx, cy, cw, ch: Integer);
1334 var a, ax, ay, fx, fy, xx, yy: Integer;
1335 begin
1336 if (p <> nil) and p.Alive and (p.Spectator = false) then
1337 begin
1338 r_Common_GetPlayerPos(p, fx, fy);
1339 case gPlayerIndicatorStyle of
1340 0:
1341 if IndicatorTexture <> nil then
1342 begin
1343 ax := IndicatorTexture.width div 2;
1344 ay := IndicatorTexture.height div 2;
1345 if (p.obj.x + p.obj.rect.x) < cx then
1346 begin
1347 a := 90;
1348 xx := fx + p.obj.rect.x + p.obj.rect.width;
1349 yy := fy + p.obj.rect.y + (p.obj.rect.height - IndicatorTexture.width) div 2;
1350 end
1351 else if (p.obj.x + p.obj.rect.x + p.obj.rect.width) > (cx + cw) then
1352 begin
1353 a := 270;
1354 xx := fx + p.obj.rect.x - IndicatorTexture.height;
1355 yy := fy + p.obj.rect.y - (p.obj.rect.height - IndicatorTexture.width) div 2;
1356 end
1357 else if (p.obj.y - IndicatorTexture.height) < cy then
1358 begin
1359 a := 180;
1360 xx := fx + p.obj.rect.x + (p.obj.rect.width - IndicatorTexture.width) div 2;
1361 yy := fy + p.obj.rect.y + p.obj.rect.height;
1362 end
1363 else
1364 begin
1365 a := 0;
1366 xx := fx + p.obj.rect.x + (p.obj.rect.width - IndicatorTexture.width) div 2;
1367 yy := fy - IndicatorTexture.height;
1368 end;
1369 xx := MIN(MAX(xx, cx), cx + cw - IndicatorTexture.width);
1370 yy := MIN(MAX(yy, cy), cy + ch - IndicatorTexture.height);
1371 r_Draw_TextureRepeatRotate(IndicatorTexture, xx, yy, IndicatorTexture.width, IndicatorTexture.height, false, color.r, color.g, color.b, 255, false, ax, ay, a);
1372 end;
1373 1:
1374 begin
1375 xx := fx + p.obj.rect.x + p.obj.rect.width div 2;
1376 yy := fy;
1377 r_Common_DrawText(p.Name, xx, yy, color.r, color.g, color.b, 255, stdfont, TBasePoint.BP_DOWN);
1378 end;
1379 end;
1380 end;
1381 end;
1382
1383 procedure r_Map_DrawPlayerIndicators (player: TPlayer; cx, cy, cw, ch: Integer);
1384 var i: Integer; p: TPlayer;
1385 begin
1386 case gPlayerIndicator of
1387 1:
1388 if player <> nil then
1389 begin
1390 r_Map_DrawIndicator(player, _RGB(255, 255, 255), cx, cy, cw, ch);
1391 end;
1392 2:
1393 if gPlayers <> nil then
1394 begin
1395 for i := 0 to HIGH(gPlayers) do
1396 begin
1397 p := gPlayers[i];
1398 if p <> nil then
1399 begin
1400 if (player <> nil) and (p = player) then
1401 begin
1402 r_Map_DrawIndicator(p, _RGB(255, 255, 255), cx, cy, cw, ch);
1403 end
1404 else if (player = nil) or ((p.Team = player.Team) and (p.Team <> TEAM_NONE)) then
1405 begin
1406 case gPlayerIndicatorStyle of
1407 0: r_Map_DrawIndicator(p, p.GetColor(), cx, cy, cw, ch);
1408 1: r_Map_DrawIndicator(p, _RGB(192, 192, 192), cx, cy, cw, ch);
1409 end;
1410 end;
1411 end;
1412 end;
1413 end;
1414 end;
1415 end;
1416
1417 procedure r_Map_DrawGame (xx, yy, ww, hh: Integer; player: TPlayer);
1418 (* xx/yy/ww/hh are in map units *)
1419 var iter: TPanelGrid.Iter; p: PPanel;
1420 begin
1421 plist.Clear;
1422 iter := mapGrid.ForEachInAABB(xx, yy, ww, hh, GridDrawableMask);
1423 for p in iter do
1424 if ((p^.tag and GridTagDoor) <> 0) = p^.door then
1425 plist.Insert(p^);
1426 iter.Release;
1427
1428 r_Map_DrawPanelType(PANEL_BACK);
1429 r_Map_DrawPanelType(PANEL_STEP);
1430 r_Map_DrawItems(xx, yy, ww, hh, false);
1431 r_Map_DrawShots(xx, yy, ww, hh);
1432 {$IFDEF ENABLE_SHELLS}
1433 r_Map_DrawShells(xx, yy, ww, hh);
1434 {$ENDIF}
1435 r_Map_DrawPlayers(xx, yy, ww, hh, player);
1436 {$IFDEF ENABLE_GIBS}
1437 r_Map_DrawGibs(xx, yy, ww, hh);
1438 {$ENDIF}
1439 {$IFDEF ENABLE_CORPSES}
1440 r_Map_DrawCorpses(xx, yy, ww, hh);
1441 {$ENDIF}
1442 r_Map_DrawPanelType(PANEL_WALL);
1443 r_Map_DrawMonsters(xx, yy, ww, hh);
1444 r_Map_DrawItems(xx, yy, ww, hh, true);
1445 r_Map_DrawPanelType(PANEL_CLOSEDOOR);
1446 {$IFDEF ENABLE_GFX}
1447 r_Map_DrawParticles(xx, yy, ww, hh);
1448 r_Map_DrawGFX(xx, yy, ww, hh);
1449 {$ENDIF}
1450 r_Map_DrawFlags(xx, yy, ww, hh);
1451 r_Map_DrawPanelType(PANEL_ACID1);
1452 r_Map_DrawPanelType(PANEL_ACID2);
1453 r_Map_DrawPanelType(PANEL_WATER);
1454 r_Map_DrawPanelType(PANEL_FORE);
1455 // TODO draw monsters health bar
1456 // TODO draw players health bar
1457 end;
1458
1459 procedure r_Map_DrawScaled (w, h, camx, camy: Integer; player: TPlayer; out acx, acy, acw, ach, axx, ayy, aww, ahh: Integer);
1460 (* w/h/camx/camy are in map units (scaled) *)
1461 const limit = 32767;
1462 var cx, cy, cw, ch, xx, yy, ww, hh{, ml, mt, mr, mb}: Integer; sx, sy, sw, sh: LongInt;
1463 begin
1464 (* camera rect *)
1465 cx := camx - w div 2;
1466 cy := camy - h div 2;
1467 cw := w;
1468 ch := h;
1469
1470 (* camera bounds *)
1471 if g_dbg_ignore_bounds = false then
1472 begin
1473 if w > gMapInfo.Width then
1474 cx := gMapInfo.Width div 2 - w div 2
1475 else if cx + cw > gMapInfo.Width then
1476 cx := gMapInfo.Width - cw
1477 else if cx < 0 then
1478 cx := 0;
1479
1480 if h > gMapInfo.Height then
1481 cy := gMapInfo.Height div 2 - h div 2
1482 else if cy + ch > gMapInfo.Height then
1483 cy := gMapInfo.Height - ch
1484 else if cy < 0 then
1485 cy := 0;
1486 end;
1487
1488 acx := cx;
1489 acy := cy;
1490 acw := cw;
1491 ach := ch;
1492
1493 (* map bounds *)
1494 xx := cx;
1495 yy := cy;
1496 ww := cw;
1497 hh := ch;
1498 if xx + ww > gMapInfo.Width then
1499 xx := gMapInfo.Width - ww;
1500 if yy + hh > gMapInfo.Height then
1501 yy := gMapInfo.Height - hh;
1502 if xx < 0 then
1503 xx := 0;
1504 if yy < 0 then
1505 yy := 0;
1506 axx := xx;
1507 ayy := yy;
1508 aww := ww;
1509 ahh := hh;
1510
1511 {
1512 (* view bounds *)
1513 ml := x; mt := y; mr := x + w; mb := y + h;
1514 if FillOutsizeArea and (DebugCameraScale = 1.0) then
1515 begin
1516 ml := MAX(cx + ml, 0) - cx;
1517 mt := MAX(cy + mt, 0) - cy;
1518 mr := MIN(cx + mr, gMapInfo.Width - 1) - cx;
1519 mb := MIN(cy + mb, gMapInfo.Height - 1) - cy;
1520 end;
1521 r_Draw_SetRect(ml, mt, mr, mb);
1522 }
1523
1524 if DebugCameraScale <> 1.0 then
1525 begin
1526 glTranslatef(cw div 2, ch div 2, 0);
1527 glScalef(DebugCameraScale, DebugCameraScale, 1);
1528 glTranslatef(-w div 2, -h div 2, 0);
1529 end;
1530
1531 if SkyTexture <> nil then
1532 begin
1533 r_Map_CalcSkyParallax(cx, cy, w, h, SkyTexture.width, SkyTexture.height, gMapInfo.Width, gMapInfo.Height, sx, sy, sw, sh);
1534 r_Draw_Texture(SkyTexture, sx, sy, sw, sh, false, 255, 255, 255, 255, false);
1535 end;
1536
1537 glTranslatef(-cx, -cy, 0);
1538 r_Map_DrawGame(xx, yy, ww, hh, player);
1539 if FillOutsizeArea and (DebugCameraScale = 1.0) then
1540 begin
1541 (* top *) r_Draw_FillRect(0 - limit, 0 - limit, gMapInfo.Width + limit, 0, 0, 0, 0, 255);
1542 (* left *) r_Draw_FillRect(0 - limit, 0, 0, gMapInfo.Height + limit, 0, 0, 0, 255);
1543 (* right *) r_Draw_FillRect(gMapInfo.Width, 0, gMapInfo.Width + limit, gMapInfo.Height + limit, 0, 0, 0, 255);
1544 (* bottom *) r_Draw_FillRect(0 - limit, gMapInfo.Height, gMapInfo.Width + limit, gMapInfo.Height + limit, 0, 0, 0, 255);
1545 end;
1546 glTranslatef(cx, cy, 0);
1547 end;
1548
1549 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer; player: TPlayer; out acx, acy: Integer);
1550 var cx, cy, cw, ch, xx, yy, ww, hh, ml, mt, mr, mb, mcx, mcy: Integer; l, t, r, b: Integer;
1551 begin
1552 glPushMatrix;
1553 r_Draw_GetRect(l, t, r, b);
1554 glTranslatef(x, y, 0);
1555 glScalef(g_dbg_scale, g_dbg_scale, 0);
1556
1557 r_Draw_SetRect(x, y, x + w, y + h);
1558 r_Map_DrawScaled(Round(w / g_dbg_scale), Round(h / g_dbg_scale), camx, camy, player, cx, cy, cw, ch, xx, yy, ww, hh);
1559 acx := cx;
1560 acy := cy;
1561 r_Draw_SetRect(x, y, x + w, y + h);
1562
1563 if DebugCameraScale <> 1.0 then
1564 begin
1565 r_Draw_Rect(0, 0, cw, ch, 0, 255, 0, 255);
1566 r_Draw_Rect(-cx + xx, -cy + yy, -cx + xx + ww, -cy + yy + hh, 255, 0, 0, 255);
1567 end;
1568
1569 if gGameSettings.GameMode <> GM_SINGLE then
1570 begin
1571 glTranslatef(-cx, -cy, 0);
1572 r_Map_DrawPlayerIndicators(player, cx, cy, cw, ch);
1573 end;
1574
1575 // TODO draw g_debug_player
1576
1577 //glTranslatef(-x, -y, 0);
1578 r_Draw_SetRect(l, t, r, b);
1579 glPopMatrix;
1580
1581 r_Map_DrawScreenEffects(x, y, w, h, player);
1582 end;
1583
1584 procedure r_Map_Reset;
1585 begin
1586 {$IFDEF ENABLE_GFX}
1587 r_Map_ResetGFX;
1588 {$ENDIF}
1589 end;
1590
1591 procedure r_Map_Update;
1592 var i, count, tick: LongInt;
1593 begin
1594 tick := gTime div GAME_TICK;
1595 for i := 0 to ITEM_LAST do
1596 g_Anim_GetFrameByTime(ItemAnim[i].anim, tick, count, Items[i].frame);
1597 r_Map_UpdateGFX(tick);
1598 g_Anim_GetFrameByTime(FlagAnim, tick, count, FlagFrame);
1599 end;
1600
1601 initialization
1602 conRegVar('r_debug_camera_scale', @DebugCameraScale, 0.0001, 1000.0, '', '');
1603 conRegVar('r_gl_fill_outside', @FillOutsizeArea, '', '');
1604 DebugCameraScale := 1.0;
1605 FillOutsizeArea := true;
1606 end.
[MIRROR] a port of Doom 2D Forever to FPC/SDL
[25/02/2024 19:55:35]
DEADSOFTWARE 2012-2024