src/game/g_touch.pas

   1 (* Copyright (C)  Doom 2D: Forever Developers
   2  *
   3  * This program is free software: you can redistribute it and/or modify
   4  * it under the terms of the GNU General Public License as published by
   5  * the Free Software Foundation, either version 3 of the License, or
   6  * (at your option) any later version.
   7  *
   8  * This program is distributed in the hope that it will be useful,
   9  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11  * GNU General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License
  14  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15  *)
  16 {$INCLUDE ../shared/a_modes.inc}
  17 unit g_touch;
  18
  19 interface
  20
  21   uses
  22     SDL2;
  23
  24   var
  25     g_touch_enabled: Boolean = False;
  26     g_touch_size: Single = 1.0;
  27     g_touch_offset: Single = 50.0;
  28     g_touch_fire: Boolean = True;
  29     g_touch_alt: Boolean = False;
  30
  31   procedure g_Touch_Init;
  32   procedure g_Touch_ShowKeyboard(yes: Boolean);
  33   procedure g_Touch_HandleEvent(const ev: TSDL_TouchFingerEvent);
  34   procedure g_Touch_Draw;
  35
  36 implementation
  37
  38   uses
  39     SysUtils,
  40     e_log, e_graphics, e_input, g_options, g_game, g_main, g_gui, g_weapons, g_console, g_window;
  41
  42   var
  43     angleFire: Boolean;
  44     keyFinger: array [VK_FIRSTKEY..VK_LASTKEY] of Integer;
  45
  46   procedure GetKeyRect(key: Integer; out x, y, w, h: Integer; out founded: Boolean);
  47     var
  48       sw, sh, sz: Integer;
  49       dpi: Single;
  50
  51     procedure S (xx, yy, ww, hh: Single);
  52     begin
  53       x := Trunc(xx);
  54       y := Trunc(yy);
  55       w := Trunc(ww);
  56       h := Trunc(hh);
  57       founded := true;
  58     end;
  59
  60   begin
  61     founded := false;
  62     if SDL_GetDisplayDPI(0, @dpi, nil, nil) <> 0 then
  63       dpi := 96;
  64
  65     sz := Trunc(g_touch_size * dpi); sw := gScreenWidth; sh := gScreenHeight;
  66     x := 0; y := Round(sh * g_touch_offset / 100);
  67     w := sz; h := sz;
  68
  69     if SDL_IsTextInputActive() = SDL_True then
  70       case key of
  71         VK_HIDEKBD: S(sw - (sz/2), 0, sz / 2, sz / 2);
  72       end
  73     else if g_touch_alt then
  74       case key of
  75         (* top ------- x ------------------------------- y  w ----- h -- *)
  76         VK_CONSOLE:  S(0,                                0, sz / 2, sz / 2);
  77         VK_ESCAPE:   S(sw - 1*(sz/2) - 1,                0, sz / 2, sz / 2);
  78         VK_SHOWKBD:  S(sw - 2*(sz/2) - 1,                0, sz / 2, sz / 2);
  79         VK_CHAT:     S(sw / 2 - (sz/2) / 2 - (sz/2) - 1, 0, sz / 2, sz / 2);
  80         VK_STATUS:   S(sw / 2 - (sz/2) / 2 - 1,          0, sz / 2, sz / 2);
  81         VK_TEAM:     S(sw / 2 - (sz/2) / 2 + (sz/2) - 1, 0, sz / 2, sz / 2);
  82         (* left --- x - y -------------- w - h --- *)
  83         VK_PREV:  S(0,  sh - 3.0*sz - 1, sz, sz / 2);
  84         VK_LEFT:  S(0,  sh - 2.0*sz - 1, sz, sz * 2);
  85         VK_RIGHT: S(sz, sh - 2.0*sz - 1, sz, sz * 2);
  86         (* right - x ------------ y -------------- w - h -- *)
  87         VK_NEXT: S(sw - 1*sz - 1, sh - 3.0*sz - 1, sz, sz / 2);
  88         VK_UP:   S(sw - 2*sz - 1, sh - 2.0*sz - 1, sz, sz / 2);
  89         VK_FIRE: S(sw - 2*sz - 1, sh - 1.5*sz - 1, sz, sz);
  90         VK_DOWN: S(sw - 2*sz - 1, sh - 0.5*sz - 1, sz, sz / 2);
  91         VK_JUMP: S(sw - 1*sz - 1, sh - 2.0*sz - 1, sz, sz);
  92         VK_OPEN: S(sw - 1*sz - 1, sh - 1.0*sz - 1, sz, sz);
  93       end
  94     else
  95       case key of
  96         (* left ----- x ----- y -------------- w ----- h -- *)
  97         VK_ESCAPE:  S(0.0*sz, y - 1*sz - sz/2, sz,     sz / 2);
  98         VK_LSTRAFE: S(0.0*sz, y - 0*sz - sz/2, sz / 2, sz);
  99         VK_LEFT:    S(0.5*sz, y - 0*sz - sz/2, sz,     sz);
 100         VK_RIGHT:   S(1.5*sz, y - 0*sz - sz/2, sz,     sz);
 101         VK_RSTRAFE: S(2.5*sz, y - 0*sz - sz/2, sz / 2, sz);
 102         (* right - x ------------ y --------------- w - h *)
 103         VK_UP:   S(sw - 1*sz - 1, y -  1*sz - sz/2, sz, sz);
 104         VK_FIRE: S(sw - 1*sz - 1, y -  0*sz - sz/2, sz, sz);
 105         VK_DOWN: S(sw - 1*sz - 1, y - -1*sz - sz/2, sz, sz);
 106         VK_NEXT: S(sw - 2*sz - 1, y -  1*sz - sz/2, sz, sz);
 107         VK_JUMP: S(sw - 2*sz - 1, y -  0*sz - sz/2, sz, sz);
 108         VK_PREV: S(sw - 3*sz - 1, y -  1*sz - sz/2, sz, sz);
 109         VK_OPEN: S(sw - 3*sz - 1, y -  0*sz - sz/2, sz, sz);
 110         (* bottom ---- x -------------------------- y ---------------- w ----- h -- *)
 111         VK_CHAT:     S(sw/2 - sz/4 -  2*(sz/2) - 1, sh - 2*(sz/2) - 1, sz / 2, sz / 2);
 112         VK_CONSOLE:  S(sw/2 - sz/4 -  1*(sz/2) - 1, sh - 2*(sz/2) - 1, sz / 2, sz / 2);
 113         VK_STATUS:   S(sw/2 - sz/4 -  0*(sz/2) - 1, sh - 2*(sz/2) - 1, sz / 2, sz / 2);
 114         VK_TEAM:     S(sw/2 - sz/4 - -1*(sz/2) - 1, sh - 2*(sz/2) - 1, sz / 2, sz / 2);
 115         VK_SHOWKBD:  S(sw/2 - sz/4 - -2*(sz/2) - 1, sh - 2*(sz/2) - 1, sz / 2, sz / 2);
 116         VK_0:        S(sw/2 - sz/4 -  5*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 117         VK_1:        S(sw/2 - sz/4 -  4*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 118         VK_2:        S(sw/2 - sz/4 -  3*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 119         VK_3:        S(sw/2 - sz/4 -  2*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 120         VK_4:        S(sw/2 - sz/4 -  1*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 121         VK_5:        S(sw/2 - sz/4 -  0*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 122         VK_6:        S(sw/2 - sz/4 - -1*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 123         VK_7:        S(sw/2 - sz/4 - -2*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 124         VK_8:        S(sw/2 - sz/4 - -3*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 125         VK_9:        S(sw/2 - sz/4 - -4*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 126         VK_A:        S(sw/2 - sz/4 - -5*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 127       end
 128   end;
 129
 130   function GetKeyName(key: Integer): String;
 131   begin
 132     case key of
 133       VK_SHOWKBD: result := 'KBD';
 134       VK_HIDEKBD: result := 'KBD';
 135       VK_LEFT:    result := 'LEFT';
 136       VK_RIGHT:   result := 'RIGHT';
 137       VK_UP:      result := 'UP';
 138       VK_DOWN:    result := 'DOWN';
 139       VK_FIRE:    result := 'FIRE';
 140       VK_OPEN:    result := 'OPEN';
 141       VK_JUMP:    result := 'JUMP';
 142       VK_CHAT:    result := 'CHAT';
 143       VK_ESCAPE:  result := 'ESC';
 144       VK_0:       result := '0';
 145       VK_1:       result := '1';
 146       VK_2:       result := '2';
 147       VK_3:       result := '3';
 148       VK_4:       result := '4';
 149       VK_5:       result := '5';
 150       VK_6:       result := '6';
 151       VK_7:       result := '7';
 152       VK_8:       result := '8';
 153       VK_9:       result := '9';
 154       VK_A:       result := '10';
 155       VK_B:       result := '11';
 156       VK_C:       result := '12';
 157       VK_D:       result := '13';
 158       VK_E:       result := '14';
 159       VK_F:       result := '15';
 160       VK_CONSOLE: result := 'CON';
 161       VK_STATUS:  result := 'STAT';
 162       VK_TEAM:    result := 'TEAM';
 163       VK_PREV:    result := '<PREW';
 164       VK_NEXT:    result := 'NEXT>';
 165       VK_LSTRAFE: result := '<';
 166       VK_RSTRAFE: result := '>';
 167     else
 168       if (key > 0) and (key < e_MaxInputKeys) then
 169         result := e_KeyNames[key]
 170       else
 171        result := '<' + IntToStr(key) + '>'
 172     end
 173   end;
 174
 175   function IntersectControl(ctl, xx, yy: Integer): Boolean;
 176     var
 177       x, y, w, h: Integer;
 178       founded: Boolean;
 179   begin
 180     GetKeyRect(ctl, x, y, w, h, founded);
 181     result := founded and (xx >= x) and (yy >= y) and (xx <= x + w) and (yy <= y + h);
 182   end;
 183
 184   procedure g_Touch_Init;
 185   begin
 186 {$IFNDEF HEADLESS}
 187     g_touch_enabled := SDL_GetNumTouchDevices() > 0
 188 {$ENDIF}
 189   end;
 190
 191   procedure g_Touch_ShowKeyboard(yes: Boolean);
 192   begin
 193 {$IFNDEF HEADLESS}
 194     if not g_touch_enabled then
 195       Exit;
 196
 197     if yes then
 198       SDL_StartTextInput
 199     else
 200       SDL_StopTextInput
 201 {$ENDIF}
 202   end;
 203
 204   procedure g_Touch_HandleEvent(const ev: TSDL_TouchFingerEvent);
 205     var
 206       x, y, i, finger: Integer;
 207
 208     procedure KeyUp (finger, i: Integer);
 209     begin
 210       if g_dbg_input then
 211         e_LogWritefln('Input Debug: g_touch.KeyUp, finger=%s, key=%s', [finger, i]);
 212
 213       keyFinger[i] := 0;
 214       e_KeyUpDown(i, False);
 215       g_Console_ProcessBind(i, False);
 216
 217       (* up/down + fire hack *)
 218       if g_touch_fire and (gGameSettings.GameType <> GT_NONE) and (g_ActiveWindow = nil) and angleFire then
 219       begin
 220         if (i = VK_UP) or (i = VK_DOWN) then
 221         begin
 222           angleFire := False;
 223           keyFinger[VK_FIRE] := 0;
 224           e_KeyUpDown(VK_FIRE, False);
 225           g_Console_ProcessBind(VK_FIRE, False)
 226         end
 227       end
 228     end;
 229
 230     procedure KeyDown (finger, i: Integer);
 231     begin
 232       if g_dbg_input then
 233         e_LogWritefln('Input Debug: g_touch.KeyDown, finger=%s, key=%s', [finger, i]);
 234
 235       keyFinger[i] := finger;
 236       e_KeyUpDown(i, True);
 237       g_Console_ProcessBind(i, True);
 238
 239       (* up/down + fire hack *)
 240       if g_touch_fire and (gGameSettings.GameType <> GT_NONE) and (g_ActiveWindow = nil) then
 241       begin
 242         if i = VK_UP then
 243         begin
 244           angleFire := True;
 245           keyFinger[VK_FIRE] := -1;
 246           e_KeyUpDown(VK_FIRE, True);
 247           g_Console_ProcessBind(VK_FIRE, True)
 248         end
 249         else if i = VK_DOWN then
 250         begin
 251           angleFire := True;
 252           keyFinger[VK_FIRE] := -1;
 253           e_KeyUpDown(VK_FIRE, True);
 254           g_Console_ProcessBind(VK_FIRE, True)
 255         end
 256       end
 257     end;
 258
 259     procedure KeyMotion (finger, i: Integer);
 260     begin
 261       if keyFinger[i] <> finger then
 262       begin
 263         KeyUp(finger, i);
 264         KeyDown(finger, i)
 265       end
 266     end;
 267
 268   begin
 269     if not g_touch_enabled then
 270       Exit;
 271
 272     finger := ev.fingerId + 2;
 273     x := Trunc(ev.x * gScreenWidth);
 274     y := Trunc(ev.y * gScreenHeight);
 275
 276     for i := VK_FIRSTKEY to VK_LASTKEY do
 277     begin
 278       if IntersectControl(i, x, y) then
 279       begin
 280         if ev.type_ = SDL_FINGERUP then
 281           KeyUp(finger, i)
 282         else if ev.type_ = SDL_FINGERMOTION then
 283           KeyMotion(finger, i)
 284         else if ev.type_ = SDL_FINGERDOWN then
 285           keyDown(finger, i)
 286       end
 287       else if keyFinger[i] = finger then
 288       begin
 289         if ev.type_ = SDL_FINGERUP then
 290           KeyUp(finger, i)
 291         else if ev.type_ = SDL_FINGERMOTION then
 292           KeyUp(finger, i)
 293       end
 294     end
 295   end;
 296
 297   procedure g_Touch_Draw;
 298     var i, x, y, w, h: Integer; founded: Boolean;
 299   begin
 300 {$IFNDEF HEADLESS}
 301     if not g_touch_enabled then
 302       Exit;
 303
 304     for i := VK_FIRSTKEY to VK_LASTKEY do
 305     begin
 306       GetKeyRect(i, x, y, w, h, founded);
 307       if founded then
 308       begin
 309         e_DrawQuad(x, y, x + w, y + h, 0, 255, 0, 31);
 310         e_TextureFontPrintEx(x, y, GetKeyName(i), gStdFont, 255, 255, 255, 1, True)
 311       end
 312     end
 313 {$ENDIF}
 314   end;
 315
 316 initialization
 317   conRegVar('touch_enable', @g_touch_enabled, 'enable/disable virtual buttons', 'draw buttons');
 318   conRegVar('touch_fire', @g_touch_fire, 'enable/disable fire when press virtual up/down', 'fire when press up/down');
 319   conRegVar('touch_size', @g_touch_size, 0.1, 10, 'size of virtual buttons', 'button size');
 320   conRegVar('touch_offset', @g_touch_offset, 0, 100, '', '');
 321   conRegVar('touch_alt', @g_touch_alt, 'althernative virtual buttons layout', 'althernative layout');
 322 end.