src/game/g_touch.pas

   1 (* Copyright (C)  Doom 2D: Forever Developers
   2  *
   3  * This program is free software: you can redistribute it and/or modify
   4  * it under the terms of the GNU General Public License as published by
   5  * the Free Software Foundation, either version 3 of the License, or
   6  * (at your option) any later version.
   7  *
   8  * This program is distributed in the hope that it will be useful,
   9  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11  * GNU General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License
  14  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15  *)
  16 {$INCLUDE ../shared/a_modes.inc}
  17 unit g_touch;
  18
  19 interface
  20
  21   uses
  22     SDL2;
  23
  24   var
  25     g_touch_enabled: Boolean = False;
  26     g_touch_size: Single = 1.0;
  27     g_touch_offset: Single = 50.0;
  28     g_touch_fire: Boolean = True;
  29     g_touch_alt: Boolean = False;
  30
  31   procedure g_Touch_Init;
  32   procedure g_Touch_ShowKeyboard(yes: Boolean);
  33   procedure g_Touch_HandleEvent(const ev: TSDL_TouchFingerEvent);
  34   procedure g_Touch_Draw;
  35
  36 implementation
  37
  38   uses
  39     SysUtils,
  40     e_log, e_graphics, e_input, g_options, g_game, g_main, g_weapons, g_console;
  41
  42   var
  43     angleFire: Boolean;
  44     keyFinger: array [VK_FIRSTKEY..VK_LASTKEY] of Integer;
  45
  46   procedure GetKeyRect(key: Integer; out x, y, w, h: Integer; out founded: Boolean);
  47     var
  48       sw, sh, sz: Integer;
  49       dpi: Single;
  50
  51     procedure S (xx, yy, ww, hh: Single);
  52     begin
  53       x := Trunc(xx);
  54       y := Trunc(yy);
  55       w := Trunc(ww);
  56       h := Trunc(hh);
  57       founded := true;
  58     end;
  59
  60   begin
  61     founded := false;
  62     if SDL_GetDisplayDPI(0, @dpi, nil, nil) <> 0 then
  63       dpi := 96;
  64
  65     sz := Trunc(g_touch_size * dpi); sw := gScreenWidth; sh := gScreenHeight;
  66     x := 0; y := Round(sh * g_touch_offset / 100);
  67     w := sz; h := sz;
  68
  69     if SDL_IsTextInputActive() = SDL_True then
  70       case key of
  71         VK_HIDEKBD: S(sw - (sz/2), 0, sz / 2, sz / 2);
  72       end
  73     else if g_touch_alt then
  74       case key of
  75         (* top ------- x ------------------------------- y  w ----- h -- *)
  76         VK_CONSOLE:  S(0,                                0, sz / 2, sz / 2);
  77         VK_ESCAPE:   S(sw - 1*(sz/2) - 1,                0, sz / 2, sz / 2);
  78         VK_SHOWKBD:  S(sw - 2*(sz/2) - 1,                0, sz / 2, sz / 2);
  79         VK_CHAT:     S(sw / 2 - (sz/2) / 2 - (sz/2) - 1, 0, sz / 2, sz / 2);
  80         VK_STATUS:   S(sw / 2 - (sz/2) / 2 - 1,          0, sz / 2, sz / 2);
  81         VK_TEAM:     S(sw / 2 - (sz/2) / 2 + (sz/2) - 1, 0, sz / 2, sz / 2);
  82         (* left --- x - y -------------- w - h --- *)
  83         VK_PREV:  S(0,  sh - 3.0*sz - 1, sz, sz / 2);
  84         VK_LEFT:  S(0,  sh - 2.0*sz - 1, sz, sz * 2);
  85         VK_RIGHT: S(sz, sh - 2.0*sz - 1, sz, sz * 2);
  86         (* right - x ------------ y -------------- w - h -- *)
  87         VK_NEXT: S(sw - 1*sz - 1, sh - 3.0*sz - 1, sz, sz / 2);
  88         VK_UP:   S(sw - 2*sz - 1, sh - 2.0*sz - 1, sz, sz / 2);
  89         VK_FIRE: S(sw - 2*sz - 1, sh - 1.5*sz - 1, sz, sz);
  90         VK_DOWN: S(sw - 2*sz - 1, sh - 0.5*sz - 1, sz, sz / 2);
  91         VK_JUMP: S(sw - 1*sz - 1, sh - 2.0*sz - 1, sz, sz);
  92         VK_OPEN: S(sw - 1*sz - 1, sh - 1.0*sz - 1, sz, sz);
  93       end
  94     else
  95       case key of
  96         (* left ----- x ----- y -------------- w ----- h -- *)
  97         VK_ESCAPE:  S(0.0*sz, y - 1*sz - sz/2, sz,     sz / 2);
  98         VK_LSTRAFE: S(0.0*sz, y - 0*sz - sz/2, sz / 2, sz);
  99         VK_LEFT:    S(0.5*sz, y - 0*sz - sz/2, sz,     sz);
 100         VK_RIGHT:   S(1.5*sz, y - 0*sz - sz/2, sz,     sz);
 101         VK_RSTRAFE: S(2.5*sz, y - 0*sz - sz/2, sz / 2, sz);
 102         (* right - x ------------ y --------------- w - h *)
 103         VK_UP:   S(sw - 1*sz - 1, y -  1*sz - sz/2, sz, sz);
 104         VK_FIRE: S(sw - 1*sz - 1, y -  0*sz - sz/2, sz, sz);
 105         VK_DOWN: S(sw - 1*sz - 1, y - -1*sz - sz/2, sz, sz);
 106         VK_NEXT: S(sw - 2*sz - 1, y -  1*sz - sz/2, sz, sz);
 107         VK_JUMP: S(sw - 2*sz - 1, y -  0*sz - sz/2, sz, sz);
 108         VK_PREV: S(sw - 3*sz - 1, y -  1*sz - sz/2, sz, sz);
 109         VK_OPEN: S(sw - 3*sz - 1, y -  0*sz - sz/2, sz, sz);
 110         (* bottom ---- x -------------------------- y ---------------- w ----- h -- *)
 111         VK_CHAT:     S(sw/2 - sz/4 -  2*(sz/2) - 1, sh - 2*(sz/2) - 1, sz / 2, sz / 2);
 112         VK_CONSOLE:  S(sw/2 - sz/4 -  1*(sz/2) - 1, sh - 2*(sz/2) - 1, sz / 2, sz / 2);
 113         VK_STATUS:   S(sw/2 - sz/4 -  0*(sz/2) - 1, sh - 2*(sz/2) - 1, sz / 2, sz / 2);
 114         VK_TEAM:     S(sw/2 - sz/4 - -1*(sz/2) - 1, sh - 2*(sz/2) - 1, sz / 2, sz / 2);
 115         VK_SHOWKBD:  S(sw/2 - sz/4 - -2*(sz/2) - 1, sh - 2*(sz/2) - 1, sz / 2, sz / 2);
 116         VK_0:        S(sw/2 - sz/4 -  5*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 117         VK_1:        S(sw/2 - sz/4 -  4*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 118         VK_2:        S(sw/2 - sz/4 -  3*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 119         VK_3:        S(sw/2 - sz/4 -  2*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 120         VK_4:        S(sw/2 - sz/4 -  1*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 121         VK_5:        S(sw/2 - sz/4 -  0*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 122         VK_6:        S(sw/2 - sz/4 - -1*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 123         VK_7:        S(sw/2 - sz/4 - -2*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 124         VK_8:        S(sw/2 - sz/4 - -3*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 125         VK_9:        S(sw/2 - sz/4 - -4*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 126         VK_A:        S(sw/2 - sz/4 - -5*(sz/2) - 1, sh - 1*(sz/2) - 1, sz / 2, sz / 2);
 127       end
 128   end;
 129
 130   function GetKeyName(key: Integer): String;
 131   begin
 132     case key of
 133       VK_SHOWKBD: result := 'KBD';
 134       VK_HIDEKBD: result := 'KBD';
 135       VK_LEFT:    result := 'LEFT';
 136       VK_RIGHT:   result := 'RIGHT';
 137       VK_UP:      result := 'UP';
 138       VK_DOWN:    result := 'DOWN';
 139       VK_FIRE:    result := 'FIRE';
 140       VK_OPEN:    result := 'OPEN';
 141       VK_JUMP:    result := 'JUMP';
 142       VK_CHAT:    result := 'CHAT';
 143       VK_ESCAPE:  result := 'ESC';
 144       VK_0:       result := '0';
 145       VK_1:       result := '1';
 146       VK_2:       result := '2';
 147       VK_3:       result := '3';
 148       VK_4:       result := '4';
 149       VK_5:       result := '5';
 150       VK_6:       result := '6';
 151       VK_7:       result := '7';
 152       VK_8:       result := '8';
 153       VK_9:       result := '9';
 154       VK_A:       result := '10';
 155       VK_B:       result := '11';
 156       VK_C:       result := '12';
 157       VK_D:       result := '13';
 158       VK_E:       result := '14';
 159       VK_F:       result := '15';
 160       VK_CONSOLE: result := 'CON';
 161       VK_STATUS:  result := 'STAT';
 162       VK_TEAM:    result := 'TEAM';
 163       VK_PREV:    result := '<PREW';
 164       VK_NEXT:    result := 'NEXT>';
 165       VK_LSTRAFE: result := '<';
 166       VK_RSTRAFE: result := '>';
 167     else
 168       if (key > 0) and (key < e_MaxInputKeys) then
 169         result := e_KeyNames[key]
 170       else
 171        result := '<' + IntToStr(key) + '>'
 172     end
 173   end;
 174
 175   function IntersectControl(ctl, xx, yy: Integer): Boolean;
 176     var
 177       x, y, w, h: Integer;
 178       founded: Boolean;
 179   begin
 180     GetKeyRect(ctl, x, y, w, h, founded);
 181     result := founded and (xx >= x) and (yy >= y) and (xx <= x + w) and (yy <= y + h);
 182   end;
 183
 184   procedure g_Touch_Init;
 185   begin
 186 {$IFNDEF HEADLESS}
 187     g_touch_enabled := SDL_GetNumTouchDevices() > 0
 188 {$ENDIF}
 189   end;
 190
 191   procedure g_Touch_ShowKeyboard(yes: Boolean);
 192   begin
 193 {$IFNDEF HEADLESS}
 194     if not g_touch_enabled then
 195       Exit;
 196
 197     if yes then
 198       SDL_StartTextInput
 199     else
 200       SDL_StopTextInput
 201 {$ENDIF}
 202   end;
 203
 204   procedure g_Touch_HandleEvent(const ev: TSDL_TouchFingerEvent);
 205     var
 206       x, y, i, finger: Integer;
 207
 208     procedure KeyUp (finger, i: Integer);
 209     begin
 210       keyFinger[i] := 0;
 211       e_KeyUpDown(i, False);
 212       g_Console_ProcessBind(i, False);
 213
 214       (* up/down + fire hack *)
 215       if g_touch_fire and (gGameSettings.GameType <> GT_NONE) and angleFire then
 216       begin
 217         if (i = VK_UP) or (i = VK_DOWN) then
 218         begin
 219           angleFire := False;
 220           keyFinger[VK_FIRE] := 0;
 221           e_KeyUpDown(VK_FIRE, False);
 222           g_Console_ProcessBind(VK_FIRE, False)
 223         end
 224       end
 225     end;
 226
 227     procedure KeyDown (finger, i: Integer);
 228     begin
 229       KeyPress(i); // Menu events
 230       keyFinger[i] := finger;
 231       e_KeyUpDown(i, True);
 232       g_Console_ProcessBind(i, True);
 233
 234       (* up/down + fire hack *)
 235       if g_touch_fire and (gGameSettings.GameType <> GT_NONE) then
 236       begin
 237         if i = VK_UP then
 238         begin
 239           angleFire := True;
 240           keyFinger[VK_FIRE] := -1;
 241           e_KeyUpDown(VK_FIRE, True);
 242           g_Console_ProcessBind(VK_FIRE, True)
 243         end
 244         else if i = VK_DOWN then
 245         begin
 246           angleFire := True;
 247           keyFinger[VK_FIRE] := -1;
 248           e_KeyUpDown(VK_FIRE, True);
 249           g_Console_ProcessBind(VK_FIRE, True)
 250         end
 251       end
 252     end;
 253
 254     procedure KeyMotion (finger, i: Integer);
 255     begin
 256       if keyFinger[i] <> finger then
 257       begin
 258         KeyUp(finger, i);
 259         KeyDown(finger, i)
 260       end
 261     end;
 262
 263   begin
 264     if not g_touch_enabled then
 265       Exit;
 266
 267     finger := ev.fingerId + 2;
 268     x := Trunc(ev.x * gScreenWidth);
 269     y := Trunc(ev.y * gScreenHeight);
 270
 271     for i := VK_FIRSTKEY to VK_LASTKEY do
 272     begin
 273       if IntersectControl(i, x, y) then
 274       begin
 275         if ev.type_ = SDL_FINGERUP then
 276           KeyUp(finger, i)
 277         else if ev.type_ = SDL_FINGERMOTION then
 278           KeyMotion(finger, i)
 279         else if ev.type_ = SDL_FINGERDOWN then
 280           keyDown(finger, i)
 281       end
 282       else if keyFinger[i] = finger then
 283       begin
 284         if ev.type_ = SDL_FINGERUP then
 285           KeyUp(finger, i)
 286         else if ev.type_ = SDL_FINGERMOTION then
 287           KeyUp(finger, i)
 288       end
 289     end
 290   end;
 291
 292   procedure g_Touch_Draw;
 293     var i, x, y, w, h: Integer; founded: Boolean;
 294   begin
 295 {$IFNDEF HEADLESS}
 296     if not g_touch_enabled then
 297       Exit;
 298
 299     for i := VK_FIRSTKEY to VK_LASTKEY do
 300     begin
 301       GetKeyRect(i, x, y, w, h, founded);
 302       if founded then
 303       begin
 304         e_DrawQuad(x, y, x + w, y + h, 0, 255, 0, 31);
 305         e_TextureFontPrintEx(x, y, GetKeyName(i), gStdFont, 255, 255, 255, 1, True)
 306       end
 307     end
 308 {$ENDIF}
 309   end;
 310
 311 initialization
 312   conRegVar('touch_enable', @g_touch_enabled, 'enable/disable virtual buttons', 'draw buttons');
 313   conRegVar('touch_fire', @g_touch_fire, 'enable/disable fire when press virtual up/down', 'fire when press up/down');
 314   conRegVar('touch_size', @g_touch_size, 0.1, 10, 'size of virtual buttons', 'button size');
 315   conRegVar('touch_offset', @g_touch_offset, 0, 100, '', '');
 316   conRegVar('touch_alt', @g_touch_alt, 'althernative virtual buttons layout', 'althernative layout');
 317 end.