src/game/g_panel.pas

   1 (* Copyright (C)  DooM 2D:Forever Developers
   2  *
   3  * This program is free software: you can redistribute it and/or modify
   4  * it under the terms of the GNU General Public License as published by
   5  * the Free Software Foundation, either version 3 of the License, or
   6  * (at your option) any later version.
   7  *
   8  * This program is distributed in the hope that it will be useful,
   9  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11  * GNU General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License
  14  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15  *)
  16 {$INCLUDE ../shared/a_modes.inc}
  17 {$M+}
  18 unit g_panel;
  19
  20 interface
  21
  22 uses
  23   MAPDEF, BinEditor, g_textures, xdynrec;
  24
  25 type
  26   TAddTextureArray = Array of
  27     record
  28       Texture: Cardinal;
  29       Anim: Boolean;
  30     end;
  31
  32   TPanel = Class (TObject)
  33   private
  34     const
  35   private
  36     mGUID: Integer; // will be assigned in "g_map.pas"
  37     FTextureWidth:    Word;
  38     FTextureHeight:   Word;
  39     FAlpha:           Byte;
  40     FBlending:        Boolean;
  41     FTextureIDs:      Array of
  42                         record
  43                           case Anim: Boolean of
  44                             False: (Tex: Cardinal);
  45                             True:  (AnTex: TAnimation);
  46                         end;
  47
  48     mMovingSpeed: TDFPoint;
  49     mMovingStart: TDFPoint;
  50     mMovingEnd: TDFPoint;
  51     mMovingActive: Boolean;
  52
  53   private
  54     function getx1 (): Integer; inline;
  55     function gety1 (): Integer; inline;
  56     function getvisvalid (): Boolean; inline;
  57
  58     function getMovingSpeedX (): Integer; inline;
  59     procedure setMovingSpeedX (v: Integer); inline;
  60     function getMovingSpeedY (): Integer; inline;
  61     procedure setMovingSpeedY (v: Integer); inline;
  62
  63     function getMovingStartX (): Integer; inline;
  64     procedure setMovingStartX (v: Integer); inline;
  65     function getMovingStartY (): Integer; inline;
  66     procedure setMovingStartY (v: Integer); inline;
  67
  68     function getMovingEndX (): Integer; inline;
  69     procedure setMovingEndX (v: Integer); inline;
  70     function getMovingEndY (): Integer; inline;
  71     procedure setMovingEndY (v: Integer); inline;
  72
  73   public
  74     FCurTexture:      Integer; // Íîìåð òåêóùåé òåêñòóðû
  75     FCurFrame:        Integer;
  76     FCurFrameCount:   Byte;
  77     FX, FY:           Integer;
  78     FWidth, FHeight:  Word;
  79     FPanelType:       Word;
  80     FSaveIt:          Boolean; // Ñîõðàíÿòü ïðè SaveState?
  81     FEnabled:         Boolean;
  82     FDoor:            Boolean;
  83     FMoved:           Boolean;
  84     FLiftType:        Byte;
  85     FLastAnimLoop:    Byte;
  86     // sorry, there fields are public to allow setting 'em in g_map; this should be fixed later
  87     // for now, PLEASE, don't modify 'em, or all hell will break loose
  88     arrIdx:           Integer; // index in one of internal arrays; sorry
  89     tag:              Integer; // used in coldets and such; sorry; see g_map.GridTagXXX
  90     proxyId:          Integer; // proxy id in map grid (DO NOT USE!)
  91     mapId:            AnsiString; // taken directly from map file; dunno why it is here
  92
  93     constructor Create(PanelRec: TDynRecord;
  94                        AddTextures: TAddTextureArray;
  95                        CurTex: Integer;
  96                        var Textures: TLevelTextureArray; aguid: Integer);
  97     destructor  Destroy(); override;
  98
  99     procedure   Draw();
 100     procedure   DrawShadowVolume(lightX: Integer; lightY: Integer; radius: Integer);
 101     procedure   Update();
 102     procedure   SetFrame(Frame: Integer; Count: Byte);
 103     procedure   NextTexture(AnimLoop: Byte = 0);
 104     procedure   SetTexture(ID: Integer; AnimLoop: Byte = 0);
 105     function    GetTextureID(): Cardinal;
 106     function    GetTextureCount(): Integer;
 107
 108     procedure   SaveState(var Mem: TBinMemoryWriter);
 109     procedure   LoadState(var Mem: TBinMemoryReader);
 110
 111     procedure positionChanged (); inline;
 112
 113     function getIsGBack (): Boolean; inline; // gRenderBackgrounds
 114     function getIsGStep (): Boolean; inline; // gSteps
 115     function getIsGWall (): Boolean; inline; // gWalls
 116     function getIsGAcid1 (): Boolean; inline; // gAcid1
 117     function getIsGAcid2 (): Boolean; inline; // gAcid2
 118     function getIsGWater (): Boolean; inline; // gWater
 119     function getIsGFore (): Boolean; inline; // gRenderForegrounds
 120     function getIsGLift (): Boolean; inline; // gLifts
 121     function getIsGBlockMon (): Boolean; inline; // gBlockMon
 122
 123   public
 124     property visvalid: Boolean read getvisvalid; // panel is "visvalid" when it's width and height are positive
 125
 126   published
 127     property guid: Integer read mGUID; // will be assigned in "g_map.pas"
 128     property x0: Integer read FX;
 129     property y0: Integer read FY;
 130     property x1: Integer read getx1; // inclusive!
 131     property y1: Integer read gety1; // inclusive!
 132     property x: Integer read FX write FX;
 133     property y: Integer read FY write FY;
 134     property width: Word read FWidth write FWidth;
 135     property height: Word read FHeight write FHeight;
 136     property panelType: Word read FPanelType write FPanelType;
 137     property saveIt: Boolean read FSaveIt write FSaveIt; // Ñîõðàíÿòü ïðè SaveState?
 138     property enabled: Boolean read FEnabled write FEnabled; // Ñîõðàíÿòü ïðè SaveState?
 139     property door: Boolean read FDoor write FDoor; // Ñîõðàíÿòü ïðè SaveState?
 140     property moved: Boolean read FMoved write FMoved; // Ñîõðàíÿòü ïðè SaveState?
 141     property liftType: Byte read FLiftType write FLiftType; // Ñîõðàíÿòü ïðè SaveState?
 142     property lastAnimLoop: Byte read FLastAnimLoop write FLastAnimLoop; // Ñîõðàíÿòü ïðè SaveState?
 143
 144     property movingSpeedX: Integer read getMovingSpeedX write setMovingSpeedX;
 145     property movingSpeedY: Integer read getMovingSpeedY write setMovingSpeedY;
 146     property movingStartX: Integer read getMovingStartX write setMovingStartX;
 147     property movingStartY: Integer read getMovingStartY write setMovingStartY;
 148     property movingEndX: Integer read getMovingEndX write setMovingEndX;
 149     property movingEndY: Integer read getMovingEndY write setMovingEndY;
 150     property movingActive: Boolean read mMovingActive write mMovingActive;
 151
 152     property isGBack: Boolean read getIsGBack;
 153     property isGStep: Boolean read getIsGStep;
 154     property isGWall: Boolean read getIsGWall;
 155     property isGAcid1: Boolean read getIsGAcid1;
 156     property isGAcid2: Boolean read getIsGAcid2;
 157     property isGWater: Boolean read getIsGWater;
 158     property isGFore: Boolean read getIsGFore;
 159     property isGLift: Boolean read getIsGLift;
 160     property isGBlockMon: Boolean read getIsGBlockMon;
 161
 162   public
 163     property movingSpeed: TDFPoint read mMovingSpeed write mMovingSpeed;
 164     property movingStart: TDFPoint read mMovingStart write mMovingStart;
 165     property movingEnd: TDFPoint read mMovingEnd write mMovingEnd;
 166   end;
 167
 168   TPanelArray = Array of TPanel;
 169
 170 var
 171   g_dbgpan_mplat_active: Boolean = {$IF DEFINED(D2F_DEBUG)}false{$ELSE}true{$ENDIF};
 172   g_dbgpan_mplat_step: Boolean = false; // one step, and stop
 173
 174
 175 implementation
 176
 177 uses
 178   SysUtils, g_basic, g_map, g_game, g_gfx, e_graphics, g_weapons,
 179   g_console, g_language, g_monsters, g_player, e_log, GL;
 180
 181 const
 182   PANEL_SIGNATURE = $4C4E4150; // 'PANL'
 183
 184 { T P a n e l : }
 185
 186 constructor TPanel.Create(PanelRec: TDynRecord;
 187                           AddTextures: TAddTextureArray;
 188                           CurTex: Integer;
 189                           var Textures: TLevelTextureArray; aguid: Integer);
 190 var
 191   i: Integer;
 192 begin
 193   X := PanelRec.X;
 194   Y := PanelRec.Y;
 195   Width := PanelRec.Width;
 196   Height := PanelRec.Height;
 197   FAlpha := 0;
 198   FBlending := False;
 199   FCurFrame := 0;
 200   FCurFrameCount := 0;
 201   LastAnimLoop := 0;
 202   Moved := False;
 203
 204   mapId := PanelRec.id;
 205   mGUID := aguid;
 206
 207   mMovingSpeed := PanelRec.moveSpeed;
 208   mMovingStart := PanelRec.moveStart;
 209   mMovingEnd := PanelRec.moveEnd;
 210   mMovingActive := PanelRec['move_active'].varvalue;
 211
 212 // Òèï ïàíåëè:
 213   PanelType := PanelRec.PanelType;
 214   Enabled := True;
 215   Door := False;
 216   LiftType := 0;
 217   SaveIt := False;
 218
 219   case PanelType of
 220     PANEL_OPENDOOR:
 221       begin
 222         Enabled := False;
 223         Door := True;
 224         SaveIt := True;
 225       end;
 226     PANEL_CLOSEDOOR:
 227       begin
 228         Door := True;
 229         SaveIt := True;
 230       end;
 231     PANEL_LIFTUP:
 232       SaveIt := True;
 233     PANEL_LIFTDOWN:
 234       begin
 235         LiftType := 1;
 236         SaveIt := True;
 237       end;
 238     PANEL_LIFTLEFT:
 239       begin
 240         LiftType := 2;
 241         SaveIt := True;
 242       end;
 243     PANEL_LIFTRIGHT:
 244       begin
 245         LiftType := 3;
 246         SaveIt := True;
 247       end;
 248   end;
 249
 250 // Íåâèäèìàÿ:
 251   if ByteBool(PanelRec.Flags and PANEL_FLAG_HIDE) then
 252   begin
 253     SetLength(FTextureIDs, 0);
 254     FCurTexture := -1;
 255     Exit;
 256   end;
 257 // Ïàíåëè, íå èñïîëüçóþùèå òåêñòóðû:
 258   if ByteBool(PanelType and
 259     (PANEL_LIFTUP or
 260      PANEL_LIFTDOWN or
 261      PANEL_LIFTLEFT or
 262      PANEL_LIFTRIGHT or
 263      PANEL_BLOCKMON)) then
 264   begin
 265     SetLength(FTextureIDs, 0);
 266     FCurTexture := -1;
 267     Exit;
 268   end;
 269
 270 // Åñëè ýòî æèäêîñòü áåç òåêñòóðû - ñïåöòåêñòóðó:
 271   if WordBool(PanelType and (PANEL_WATER or PANEL_ACID1 or PANEL_ACID2)) and
 272      (not ByteBool(PanelRec.Flags and PANEL_FLAG_WATERTEXTURES)) then
 273   begin
 274     SetLength(FTextureIDs, 1);
 275     FTextureIDs[0].Anim := False;
 276
 277     case PanelRec.PanelType of
 278       PANEL_WATER:
 279         FTextureIDs[0].Tex := LongWord(TEXTURE_SPECIAL_WATER);
 280       PANEL_ACID1:
 281         FTextureIDs[0].Tex := LongWord(TEXTURE_SPECIAL_ACID1);
 282       PANEL_ACID2:
 283         FTextureIDs[0].Tex := LongWord(TEXTURE_SPECIAL_ACID2);
 284     end;
 285
 286     FCurTexture := 0;
 287     Exit;
 288   end;
 289
 290   SetLength(FTextureIDs, Length(AddTextures));
 291
 292   if CurTex < 0 then
 293     FCurTexture := -1
 294   else
 295     if CurTex >= Length(FTextureIDs) then
 296       FCurTexture := Length(FTextureIDs) - 1
 297     else
 298       FCurTexture := CurTex;
 299
 300   for i := 0 to Length(FTextureIDs)-1 do
 301   begin
 302     FTextureIDs[i].Anim := AddTextures[i].Anim;
 303     if FTextureIDs[i].Anim then
 304       begin // Àíèìèðîâàííàÿ òåêñòóðà
 305         FTextureIDs[i].AnTex :=
 306            TAnimation.Create(Textures[AddTextures[i].Texture].FramesID,
 307                              True, Textures[AddTextures[i].Texture].Speed);
 308         FTextureIDs[i].AnTex.Blending := ByteBool(PanelRec.Flags and PANEL_FLAG_BLENDING);
 309         FTextureIDs[i].AnTex.Alpha := PanelRec.Alpha;
 310         SaveIt := True;
 311       end
 312     else
 313       begin // Îáû÷íàÿ òåêñòóðà
 314         FTextureIDs[i].Tex := Textures[AddTextures[i].Texture].TextureID;
 315       end;
 316   end;
 317
 318 // Òåêñòóð íåñêîëüêî - íóæíî ñîõðàíÿòü òåêóùóþ:
 319   if Length(FTextureIDs) > 1 then
 320     SaveIt := True;
 321
 322 // Åñëè íå ñïåöòåêñòóðà, òî çàäàåì ðàçìåðû:
 323   if PanelRec.TextureNum > High(Textures) then
 324   begin
 325     e_WriteLog(Format('WTF?! PanelRec.TextureNum is out of limits! (%d : %d)', [PanelRec.TextureNum, High(Textures)]), MSG_FATALERROR);
 326     FTextureWidth := 2;
 327     FTextureHeight := 2;
 328     FAlpha := 0;
 329     FBlending := ByteBool(0);
 330   end
 331   else if not g_Map_IsSpecialTexture(Textures[PanelRec.TextureNum].TextureName) then
 332   begin
 333     FTextureWidth := Textures[PanelRec.TextureNum].Width;
 334     FTextureHeight := Textures[PanelRec.TextureNum].Height;
 335     FAlpha := PanelRec.Alpha;
 336     FBlending := ByteBool(PanelRec.Flags and PANEL_FLAG_BLENDING);
 337   end;
 338 end;
 339
 340 destructor TPanel.Destroy();
 341 var
 342   i: Integer;
 343 begin
 344   for i := 0 to High(FTextureIDs) do
 345     if FTextureIDs[i].Anim then
 346       FTextureIDs[i].AnTex.Free();
 347   SetLength(FTextureIDs, 0);
 348
 349   Inherited;
 350 end;
 351
 352 function TPanel.getx1 (): Integer; inline; begin result := X+Width-1; end;
 353 function TPanel.gety1 (): Integer; inline; begin result := Y+Height-1; end;
 354 function TPanel.getvisvalid (): Boolean; inline; begin result := (Width > 0) and (Height > 0); end;
 355
 356 function TPanel.getMovingSpeedX (): Integer; inline; begin result := mMovingSpeed.X; end;
 357 procedure TPanel.setMovingSpeedX (v: Integer); inline; begin mMovingSpeed.X := v; end;
 358 function TPanel.getMovingSpeedY (): Integer; inline; begin result := mMovingSpeed.Y; end;
 359 procedure TPanel.setMovingSpeedY (v: Integer); inline; begin mMovingSpeed.Y := v; end;
 360
 361 function TPanel.getMovingStartX (): Integer; inline; begin result := mMovingStart.X; end;
 362 procedure TPanel.setMovingStartX (v: Integer); inline; begin mMovingStart.X := v; end;
 363 function TPanel.getMovingStartY (): Integer; inline; begin result := mMovingStart.Y; end;
 364 procedure TPanel.setMovingStartY (v: Integer); inline; begin mMovingStart.Y := v; end;
 365
 366 function TPanel.getMovingEndX (): Integer; inline; begin result := mMovingEnd.X; end;
 367 procedure TPanel.setMovingEndX (v: Integer); inline; begin mMovingEnd.X := v; end;
 368 function TPanel.getMovingEndY (): Integer; inline; begin result := mMovingEnd.Y; end;
 369 procedure TPanel.setMovingEndY (v: Integer); inline; begin mMovingEnd.Y := v; end;
 370
 371 function TPanel.getIsGBack (): Boolean; inline; begin result := ((tag and GridTagBack) <> 0); end;
 372 function TPanel.getIsGStep (): Boolean; inline; begin result := ((tag and GridTagStep) <> 0); end;
 373 function TPanel.getIsGWall (): Boolean; inline; begin result := ((tag and (GridTagWall or GridTagDoor)) <> 0); end;
 374 function TPanel.getIsGAcid1 (): Boolean; inline; begin result := ((tag and GridTagAcid1) <> 0); end;
 375 function TPanel.getIsGAcid2 (): Boolean; inline; begin result := ((tag and GridTagAcid2) <> 0); end;
 376 function TPanel.getIsGWater (): Boolean; inline; begin result := ((tag and GridTagWater) <> 0); end;
 377 function TPanel.getIsGFore (): Boolean; inline; begin result := ((tag and GridTagFore) <> 0); end;
 378 function TPanel.getIsGLift (): Boolean; inline; begin result := ((tag and GridTagLift) <> 0); end;
 379 function TPanel.getIsGBlockMon (): Boolean; inline; begin result := ((tag and GridTagBlockMon) <> 0); end;
 380
 381 procedure TPanel.Draw();
 382 var
 383   xx, yy: Integer;
 384   NoTextureID: DWORD;
 385   NW, NH: Word;
 386 begin
 387   if {Enabled and} (FCurTexture >= 0) and
 388      (Width > 0) and (Height > 0) and (FAlpha < 255) and
 389      ((g_dbg_scale <> 1.0) or g_Collide(X, Y, Width, Height, sX, sY, sWidth, sHeight)) then
 390   begin
 391     if FTextureIDs[FCurTexture].Anim then
 392       begin // Àíèìèðîâàííàÿ òåêñòóðà
 393         if FTextureIDs[FCurTexture].AnTex = nil then
 394           Exit;
 395
 396         for xx := 0 to (Width div FTextureWidth)-1 do
 397           for yy := 0 to (Height div FTextureHeight)-1 do
 398             FTextureIDs[FCurTexture].AnTex.Draw(
 399               X + xx*FTextureWidth,
 400               Y + yy*FTextureHeight, M_NONE);
 401       end
 402     else
 403       begin // Îáû÷íàÿ òåêñòóðà
 404         case FTextureIDs[FCurTexture].Tex of
 405           LongWord(TEXTURE_SPECIAL_WATER):
 406             e_DrawFillQuad(X, Y, X+Width-1, Y+Height-1,
 407                            0, 0, 255, 0, B_FILTER);
 408           LongWord(TEXTURE_SPECIAL_ACID1):
 409             e_DrawFillQuad(X, Y, X+Width-1, Y+Height-1,
 410                            0, 128, 0, 0, B_FILTER);
 411           LongWord(TEXTURE_SPECIAL_ACID2):
 412             e_DrawFillQuad(X, Y, X+Width-1, Y+Height-1,
 413                            128, 0, 0, 0, B_FILTER);
 414           LongWord(TEXTURE_NONE):
 415             if g_Texture_Get('NOTEXTURE', NoTextureID) then
 416             begin
 417               e_GetTextureSize(NoTextureID, @NW, @NH);
 418               e_DrawFill(NoTextureID, X, Y, Width div NW, Height div NH,
 419                          0, False, False);
 420             end else
 421             begin
 422               xx := X + (Width div 2);
 423               yy := Y + (Height div 2);
 424               e_DrawFillQuad(X, Y, xx, yy,
 425                              255, 0, 255, 0);
 426               e_DrawFillQuad(xx, Y, X+Width-1, yy,
 427                              255, 255, 0, 0);
 428               e_DrawFillQuad(X, yy, xx, Y+Height-1,
 429                              255, 255, 0, 0);
 430               e_DrawFillQuad(xx, yy, X+Width-1, Y+Height-1,
 431                              255, 0, 255, 0);
 432             end;
 433
 434           else
 435             e_DrawFill(FTextureIDs[FCurTexture].Tex, X, Y,
 436                        Width div FTextureWidth,
 437                        Height div FTextureHeight,
 438                        FAlpha, True, FBlending);
 439         end;
 440       end;
 441   end;
 442 end;
 443
 444 procedure TPanel.DrawShadowVolume(lightX: Integer; lightY: Integer; radius: Integer);
 445   procedure extrude (x: Integer; y: Integer);
 446   begin
 447     glVertex2i(x+(x-lightX)*500, y+(y-lightY)*500);
 448     //e_WriteLog(Format('  : (%d,%d)', [x+(x-lightX)*300, y+(y-lightY)*300]), MSG_WARNING);
 449   end;
 450
 451   procedure drawLine (x0: Integer; y0: Integer; x1: Integer; y1: Integer);
 452   begin
 453     // does this side facing the light?
 454     if ((x1-x0)*(lightY-y0)-(lightX-x0)*(y1-y0) >= 0) then exit;
 455     //e_WriteLog(Format('lightpan: (%d,%d)-(%d,%d)', [x0, y0, x1, y1]), MSG_WARNING);
 456     // this edge is facing the light, extrude and draw it
 457     glVertex2i(x0, y0);
 458     glVertex2i(x1, y1);
 459     extrude(x1, y1);
 460     extrude(x0, y0);
 461   end;
 462
 463 begin
 464   if radius < 4 then exit;
 465   if Enabled and (FCurTexture >= 0) and (Width > 0) and (Height > 0) and (FAlpha < 255) and g_Collide(X, Y, Width, Height, sX, sY, sWidth, sHeight) then
 466   begin
 467     if not FTextureIDs[FCurTexture].Anim then
 468     begin
 469       case FTextureIDs[FCurTexture].Tex of
 470         LongWord(TEXTURE_SPECIAL_WATER): exit;
 471         LongWord(TEXTURE_SPECIAL_ACID1): exit;
 472         LongWord(TEXTURE_SPECIAL_ACID2): exit;
 473         LongWord(TEXTURE_NONE): exit;
 474       end;
 475     end;
 476     if (X+Width < lightX-radius) then exit;
 477     if (Y+Height < lightY-radius) then exit;
 478     if (X > lightX+radius) then exit;
 479     if (Y > lightY+radius) then exit;
 480     //e_DrawFill(FTextureIDs[FCurTexture].Tex, X, Y, Width div FTextureWidth, Height div FTextureHeight, FAlpha, True, FBlending);
 481
 482     glBegin(GL_QUADS);
 483       drawLine(x,       y,        x+width, y); // top
 484       drawLine(x+width, y,        x+width, y+height); // right
 485       drawLine(x+width, y+height, x,       y+height); // bottom
 486       drawLine(x,       y+height, x,       y); // left
 487     glEnd();
 488   end;
 489 end;
 490
 491
 492 procedure TPanel.positionChanged (); inline;
 493 var
 494   px, py, pw, ph: Integer;
 495 begin
 496   if (proxyId >= 0) then
 497   begin
 498     mapGrid.getBodyDims(proxyId, px, py, pw, ph);
 499     if (px <> x) or (py <> y) or (pw <> Width) or (ph <> Height) then
 500     begin
 501       {
 502       e_LogWritefln('panel moved: arridx=%s; guid=%s; proxyid=%s; old:(%s,%s)-(%sx%s); new:(%s,%s)-(%sx%s)',
 503         [arrIdx, mGUID, proxyId, px, py, pw, ph, x, y, width, height]);
 504       }
 505       g_Mark(px, py, pw, ph, MARK_WALL, false);
 506       if (pw <> Width) or (ph <> Height) then mapGrid.moveResizeBody(proxyId, X, Y, Width, Height)
 507       else mapGrid.moveBody(proxyId, X, Y);
 508       g_Mark(X, Y, Width, Height, MARK_WALL);
 509     end;
 510   end;
 511 end;
 512
 513
 514 var
 515   monMoveList: array of TMonster = nil;
 516   monMoveListUsed: Integer = 0;
 517
 518 procedure TPanel.Update();
 519 var
 520   nx, ny: Integer;
 521
 522   function doPush (px, py, pw, ph: Integer; out dx, dy: Integer): Boolean;
 523   begin
 524     result := g_Collide(px, py, pw, ph, nx, ny, Width, Height);
 525     if result then
 526     begin
 527       // need to push
 528            if (mMovingSpeed.X < 0) then dx := nx-(px+pw)
 529       else if (mMovingSpeed.X > 0) then dx := (nx+Width)-px
 530       else dx := 0;
 531            if (mMovingSpeed.Y < 0) then dy := ny-(py+ph)
 532       else if (mMovingSpeed.Y > 0) then dy := (ny+Height)-py
 533       else dy := 0;
 534     end
 535     else
 536     begin
 537       dx := 0;
 538       dy := 0;
 539     end;
 540   end;
 541
 542   function monMove (mon: TMonster): Boolean;
 543   begin
 544     result := false; // don't stop
 545     //mon.GameX := mon.GameX+mMovingSpeed.X;
 546     //mon.GameY := mon.GameY+mMovingSpeed.Y;
 547     mon.setPosition(mon.GameX+mMovingSpeed.X, mon.GameY+mMovingSpeed.Y, false); // we can't call `positionChanged()` in grid callback
 548     if (monMoveListUsed >= Length(monMoveList)) then SetLength(monMoveList, monMoveListUsed+64);
 549     monMoveList[monMoveListUsed] := mon;
 550     Inc(monMoveListUsed);
 551   end;
 552
 553   function monPush (mon: TMonster): Boolean;
 554   var
 555     px, py, pw, ph, dx, dy: Integer;
 556   begin
 557     result := false; // don't stop
 558     mon.getMapBox(px, py, pw, ph);
 559     if doPush(px, py, pw, ph, dx, dy) then
 560     begin
 561       //mon.GameX := mon.GameX+dx;
 562       //mon.GameY := mon.GameY+dy;
 563       mon.setPosition(mon.GameX+dx, mon.GameY+dy, false); // we can't call `positionChanged()` in grid callback
 564       if (monMoveListUsed >= Length(monMoveList)) then SetLength(monMoveList, monMoveListUsed+64);
 565       monMoveList[monMoveListUsed] := mon;
 566       Inc(monMoveListUsed);
 567     end;
 568   end;
 569
 570   procedure plrMove (plr: TPlayer);
 571   var
 572     px, py, pw, ph, dx, dy: Integer;
 573   begin
 574     if (plr = nil) then exit;
 575     plr.getMapBox(px, py, pw, ph);
 576     if (py+ph <> Y) then
 577     begin
 578       // push player
 579       if doPush(px, py, pw, ph, dx, dy) then
 580       begin
 581         plr.GameX := plr.GameX+dx;
 582         plr.GameY := plr.GameY+dy;
 583         plr.positionChanged();
 584         // check if we're squashed
 585         if plr.live then
 586         begin
 587           plr.getMapBox(px, py, pw, ph);
 588           if g_Map_CollidePanel(px, py, pw, ph, (PANEL_WALL or PANEL_OPENDOOR or PANEL_CLOSEDOOR)) then
 589           begin
 590             plr.Damage(15000, 0, 0, 0, HIT_TRAP);
 591           end;
 592         end;
 593       end;
 594       exit;
 595     end;
 596     if (px+pw <= X) then exit;
 597     if (px >= X+Width) then exit;
 598     plr.GameX := plr.GameX+mMovingSpeed.X;
 599     plr.GameY := plr.GameY+mMovingSpeed.Y;
 600     plr.positionChanged();
 601   end;
 602
 603 var
 604   f: Integer;
 605   mon: TMonster;
 606   px, py, pw, ph: Integer;
 607 begin
 608   if Enabled and (FCurTexture >= 0) and
 609     (FTextureIDs[FCurTexture].Anim) and
 610     (FTextureIDs[FCurTexture].AnTex <> nil) and
 611     (Width > 0) and (Height > 0) and (FAlpha < 255) then
 612   begin
 613     FTextureIDs[FCurTexture].AnTex.Update();
 614     FCurFrame := FTextureIDs[FCurTexture].AnTex.CurrentFrame;
 615     FCurFrameCount := FTextureIDs[FCurTexture].AnTex.CurrentCounter;
 616   end;
 617
 618   if mMovingActive and (not mMovingSpeed.isZero) and g_dbgpan_mplat_active then
 619   begin
 620     monMoveListUsed := 0;
 621     nx := X+mMovingSpeed.X;
 622     ny := Y+mMovingSpeed.Y;
 623     // move monsters on lifts
 624     g_Mons_ForEachAt(X, Y-1, Width, 1, monMove);
 625     X := nx;
 626     Y := ny;
 627     // fix grid
 628     positionChanged();
 629     // push monsters
 630     g_Mons_ForEachAt(nx, ny, Width, Height, monPush);
 631     // move and push players
 632     for f := 0 to High(gPlayers) do plrMove(gPlayers[f]);
 633     // reverse moving direction, if necessary
 634          if (mMovingSpeed.X < 0) and (nx <= mMovingStart.X) then mMovingSpeed.X := -mMovingSpeed.X
 635     else if (mMovingSpeed.X > 0) and (nx >= mMovingEnd.X) then mMovingSpeed.X := -mMovingSpeed.X;
 636          if (mMovingSpeed.Y < 0) and (ny <= mMovingStart.Y) then mMovingSpeed.Y := -mMovingSpeed.Y
 637     else if (mMovingSpeed.Y > 0) and (ny >= mMovingEnd.Y) then mMovingSpeed.Y := -mMovingSpeed.Y;
 638     // notify moved monsters about their movement
 639     for f := 0 to monMoveListUsed-1 do
 640     begin
 641       monMoveList[f].positionChanged();
 642     end;
 643     for f := 0 to monMoveListUsed-1 do
 644     begin
 645       mon := monMoveList[f];
 646       // check if it is squashed
 647       if mon.live then
 648       begin
 649         mon.getMapBox(px, py, pw, ph);
 650         if g_Map_CollidePanel(px, py, pw, ph, (PANEL_WALL or PANEL_OPENDOOR or PANEL_CLOSEDOOR)) then
 651         begin
 652           mon.Damage(15000, 0, 0, 0, HIT_TRAP);
 653         end;
 654       end;
 655     end;
 656   end;
 657 end;
 658
 659 procedure TPanel.SetFrame(Frame: Integer; Count: Byte);
 660
 661   function ClampInt(X, A, B: Integer): Integer;
 662   begin
 663     Result := X;
 664     if X < A then Result := A else if X > B then Result := B;
 665   end;
 666
 667 begin
 668   if Enabled and (FCurTexture >= 0) and
 669     (FTextureIDs[FCurTexture].Anim) and
 670     (FTextureIDs[FCurTexture].AnTex <> nil) and
 671     (Width > 0) and (Height > 0) and (FAlpha < 255) then
 672   begin
 673     FCurFrame := ClampInt(Frame, 0, FTextureIDs[FCurTexture].AnTex.TotalFrames);
 674     FCurFrameCount := Count;
 675     FTextureIDs[FCurTexture].AnTex.CurrentFrame := FCurFrame;
 676     FTextureIDs[FCurTexture].AnTex.CurrentCounter := FCurFrameCount;
 677   end;
 678 end;
 679
 680 procedure TPanel.NextTexture(AnimLoop: Byte = 0);
 681 begin
 682   Assert(FCurTexture >= -1, 'FCurTexture < -1');
 683
 684 // Íåò òåêñòóð:
 685   if Length(FTextureIDs) = 0 then
 686     FCurTexture := -1
 687   else
 688   // Òîëüêî îäíà òåêñòóðà:
 689     if Length(FTextureIDs) = 1 then
 690       begin
 691         if FCurTexture = 0 then
 692           FCurTexture := -1
 693         else
 694           FCurTexture := 0;
 695       end
 696     else
 697     // Áîëüøå îäíîé òåêñòóðû:
 698       begin
 699       // Ñëåäóþùàÿ:
 700         Inc(FCurTexture);
 701       // Ñëåäóþùåé íåò - âîçâðàò ê íà÷àëó:
 702         if FCurTexture >= Length(FTextureIDs) then
 703           FCurTexture := 0;
 704       end;
 705
 706 // Ïåðåêëþ÷èëèñü íà âèäèìóþ àíèì. òåêñòóðó:
 707   if (FCurTexture >= 0) and FTextureIDs[FCurTexture].Anim then
 708   begin
 709     if (FTextureIDs[FCurTexture].AnTex = nil) then
 710     begin
 711       g_FatalError(_lc[I_GAME_ERROR_SWITCH_TEXTURE]);
 712       Exit;
 713     end;
 714
 715     if AnimLoop = 1 then
 716       FTextureIDs[FCurTexture].AnTex.Loop := True
 717     else
 718       if AnimLoop = 2 then
 719         FTextureIDs[FCurTexture].AnTex.Loop := False;
 720
 721     FTextureIDs[FCurTexture].AnTex.Reset();
 722   end;
 723
 724   LastAnimLoop := AnimLoop;
 725 end;
 726
 727 procedure TPanel.SetTexture(ID: Integer; AnimLoop: Byte = 0);
 728 begin
 729 // Íåò òåêñòóð:
 730   if Length(FTextureIDs) = 0 then
 731     FCurTexture := -1
 732   else
 733   // Òîëüêî îäíà òåêñòóðà:
 734     if Length(FTextureIDs) = 1 then
 735       begin
 736         if (ID = 0) or (ID = -1) then
 737           FCurTexture := ID;
 738       end
 739     else
 740     // Áîëüøå îäíîé òåêñòóðû:
 741       begin
 742         if (ID >= -1) and (ID <= High(FTextureIDs)) then
 743           FCurTexture := ID;
 744       end;
 745
 746 // Ïåðåêëþ÷èëèñü íà âèäèìóþ àíèì. òåêñòóðó:
 747   if (FCurTexture >= 0) and FTextureIDs[FCurTexture].Anim then
 748   begin
 749     if (FTextureIDs[FCurTexture].AnTex = nil) then
 750     begin
 751       g_FatalError(_lc[I_GAME_ERROR_SWITCH_TEXTURE]);
 752       Exit;
 753     end;
 754
 755     if AnimLoop = 1 then
 756       FTextureIDs[FCurTexture].AnTex.Loop := True
 757     else
 758       if AnimLoop = 2 then
 759         FTextureIDs[FCurTexture].AnTex.Loop := False;
 760
 761     FTextureIDs[FCurTexture].AnTex.Reset();
 762   end;
 763
 764   LastAnimLoop := AnimLoop;
 765 end;
 766
 767 function TPanel.GetTextureID(): DWORD;
 768 begin
 769   Result := LongWord(TEXTURE_NONE);
 770
 771   if (FCurTexture >= 0) then
 772   begin
 773     if FTextureIDs[FCurTexture].Anim then
 774       Result := FTextureIDs[FCurTexture].AnTex.FramesID
 775     else
 776       Result := FTextureIDs[FCurTexture].Tex;
 777   end;
 778 end;
 779
 780 function TPanel.GetTextureCount(): Integer;
 781 begin
 782   Result := Length(FTextureIDs);
 783   if Enabled and (FCurTexture >= 0) then
 784      if (FTextureIDs[FCurTexture].Anim) and
 785         (FTextureIDs[FCurTexture].AnTex <> nil) and
 786         (Width > 0) and (Height > 0) and (FAlpha < 255) then
 787        Result := Result + 100;
 788 end;
 789
 790 procedure TPanel.SaveState(Var Mem: TBinMemoryWriter);
 791 var
 792   sig: DWORD;
 793   anim: Boolean;
 794 begin
 795   if (Mem = nil) then exit;
 796   //if not SaveIt then exit;
 797
 798 // Ñèãíàòóðà ïàíåëè:
 799   sig := PANEL_SIGNATURE; // 'PANL'
 800   Mem.WriteDWORD(sig);
 801 // Îòêðûòà/çàêðûòà, åñëè äâåðü:
 802   Mem.WriteBoolean(FEnabled);
 803 // Íàïðàâëåíèå ëèôòà, åñëè ëèôò:
 804   Mem.WriteByte(FLiftType);
 805 // Íîìåð òåêóùåé òåêñòóðû:
 806   Mem.WriteInt(FCurTexture);
 807 // Êîîðäû
 808   Mem.WriteInt(FX);
 809   Mem.WriteInt(FY);
 810 // Àíèìèðîâàííàÿ ëè òåêóùàÿ òåêñòóðà:
 811   if (FCurTexture >= 0) and (FTextureIDs[FCurTexture].Anim) then
 812     begin
 813       Assert(FTextureIDs[FCurTexture].AnTex <> nil,
 814              'TPanel.SaveState: No animation object');
 815       anim := True;
 816     end
 817   else
 818     anim := False;
 819   Mem.WriteBoolean(anim);
 820 // Åñëè äà - ñîõðàíÿåì àíèìàöèþ:
 821   if anim then
 822     FTextureIDs[FCurTexture].AnTex.SaveState(Mem);
 823   // moving platform state
 824   Mem.WriteInt(mMovingSpeed.X);
 825   Mem.WriteInt(mMovingSpeed.Y);
 826   Mem.WriteInt(mMovingStart.X);
 827   Mem.WriteInt(mMovingStart.Y);
 828   Mem.WriteInt(mMovingEnd.X);
 829   Mem.WriteInt(mMovingEnd.Y);
 830   Mem.WriteBoolean(mMovingActive);
 831 end;
 832
 833 procedure TPanel.LoadState(var Mem: TBinMemoryReader);
 834 var
 835   sig: DWORD;
 836   anim: Boolean;
 837   //ox, oy: Integer;
 838 begin
 839   if (Mem = nil) then exit;
 840   //if not SaveIt then exit;
 841
 842 // Ñèãíàòóðà ïàíåëè:
 843   Mem.ReadDWORD(sig);
 844   if sig <> PANEL_SIGNATURE then // 'PANL'
 845   begin
 846     raise EBinSizeError.Create('TPanel.LoadState: Wrong Panel Signature');
 847   end;
 848 // Îòêðûòà/çàêðûòà, åñëè äâåðü:
 849   Mem.ReadBoolean(FEnabled);
 850 // Íàïðàâëåíèå ëèôòà, åñëè ëèôò:
 851   Mem.ReadByte(FLiftType);
 852 // Íîìåð òåêóùåé òåêñòóðû:
 853   Mem.ReadInt(FCurTexture);
 854 // Êîîðäû
 855   //ox := FX;
 856   //oy := FY;
 857   Mem.ReadInt(FX);
 858   Mem.ReadInt(FY);
 859   //e_LogWritefln('panel %s(%s): old=(%s,%s); new=(%s,%s); delta=(%s,%s)', [arrIdx, proxyId, ox, oy, FX, FY, FX-ox, FY-oy]);
 860 // Àíèìèðîâàííàÿ ëè òåêóùàÿ òåêñòóðà:
 861   Mem.ReadBoolean(anim);
 862 // Åñëè äà - çàãðóæàåì àíèìàöèþ:
 863   if anim then
 864   begin
 865     Assert((FCurTexture >= 0) and
 866            (FTextureIDs[FCurTexture].Anim) and
 867            (FTextureIDs[FCurTexture].AnTex <> nil),
 868            'TPanel.LoadState: No animation object');
 869     FTextureIDs[FCurTexture].AnTex.LoadState(Mem);
 870   end;
 871   // moving platform state
 872   Mem.ReadInt(mMovingSpeed.X);
 873   Mem.ReadInt(mMovingSpeed.Y);
 874   Mem.ReadInt(mMovingStart.X);
 875   Mem.ReadInt(mMovingStart.Y);
 876   Mem.ReadInt(mMovingEnd.X);
 877   Mem.ReadInt(mMovingEnd.Y);
 878   Mem.ReadBoolean(mMovingActive);
 879
 880   positionChanged();
 881   //mapGrid.proxyEnabled[proxyId] := FEnabled; // done in g_map.pas
 882 end;
 883
 884 end.