src/game/g_panel.pas

   1 (* Copyright (C)  Doom 2D: Forever Developers
   2  *
   3  * This program is free software: you can redistribute it and/or modify
   4  * it under the terms of the GNU General Public License as published by
   5  * the Free Software Foundation, version 3 of the License ONLY.
   6  *
   7  * This program is distributed in the hope that it will be useful,
   8  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   9  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  10  * GNU General Public License for more details.
  11  *
  12  * You should have received a copy of the GNU General Public License
  13  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  14  *)
  15 {$INCLUDE ../shared/a_modes.inc}
  16 {$M+}
  17 unit g_panel;
  18
  19 interface
  20
  21 uses
  22   SysUtils, Classes,
  23   MAPDEF, g_textures, xdynrec;
  24
  25 type
  26   TAddTextureArray = array of record
  27     Texture: Cardinal; // Textures[Texture]
  28   end;
  29
  30   ATextureID = array of record
  31     Texture: Cardinal; // Textures[Texture]
  32     case Anim: Boolean of
  33       False: ();
  34       True:  (AnTex: TAnimationState);
  35   end;
  36
  37   PPanel = ^TPanel;
  38   TPanel = Class (TObject)
  39   private
  40     const
  41   private
  42     mGUID: Integer; // will be assigned in "g_map.pas"
  43     FAlpha:           Byte;
  44     FBlending:        Boolean;
  45     FTextureIDs:      ATextureID;
  46     mMovingSpeed: TDFPoint;
  47     mMovingStart: TDFPoint;
  48     mMovingEnd: TDFPoint;
  49     mMovingActive: Boolean;
  50     mMoveOnce: Boolean;
  51
  52     mOldMovingActive: Boolean;
  53
  54     mSizeSpeed: TDFSize;
  55     mSizeEnd: TDFSize;
  56
  57     mEndPosTrig: Integer;
  58     mEndSizeTrig: Integer;
  59
  60     mNeedSend: Boolean; // for network
  61
  62   private
  63     function getx1 (): Integer; inline;
  64     function gety1 (): Integer; inline;
  65     function getvisvalid (): Boolean; inline;
  66
  67     function getMovingSpeedX (): Integer; inline;
  68     procedure setMovingSpeedX (v: Integer); inline;
  69     function getMovingSpeedY (): Integer; inline;
  70     procedure setMovingSpeedY (v: Integer); inline;
  71
  72     function getMovingStartX (): Integer; inline;
  73     procedure setMovingStartX (v: Integer); inline;
  74     function getMovingStartY (): Integer; inline;
  75     procedure setMovingStartY (v: Integer); inline;
  76
  77     function getMovingEndX (): Integer; inline;
  78     procedure setMovingEndX (v: Integer); inline;
  79     function getMovingEndY (): Integer; inline;
  80     procedure setMovingEndY (v: Integer); inline;
  81
  82     function getSizeSpeedX (): Integer; inline;
  83     procedure setSizeSpeedX (v: Integer); inline;
  84     function getSizeSpeedY (): Integer; inline;
  85     procedure setSizeSpeedY (v: Integer); inline;
  86
  87     function getSizeEndX (): Integer; inline;
  88     procedure setSizeEndX (v: Integer); inline;
  89     function getSizeEndY (): Integer; inline;
  90     procedure setSizeEndY (v: Integer); inline;
  91
  92   public
  93     FCurTexture:      Integer; // Íîìåð òåêóùåé òåêñòóðû
  94     FCurFrame:        Integer;
  95     FCurFrameCount:   Byte;
  96     FX, FY:           Integer;
  97     FWidth, FHeight:  Word;
  98     FPanelType:       Word;
  99     FEnabled:         Boolean;
 100     FDoor:            Boolean;
 101     FLiftType:        Byte;
 102     FLastAnimLoop:    Byte;
 103     // sorry, there fields are public to allow setting 'em in g_map; this should be fixed later
 104     // for now, PLEASE, don't modify 'em, or all hell will break loose
 105     arrIdx:           Integer; // index in one of internal arrays; sorry
 106     tag:              Integer; // used in coldets and such; sorry; see g_map.GridTagXXX
 107     proxyId:          Integer; // proxy id in map grid (DO NOT USE!)
 108     mapId:            AnsiString; // taken directly from map file; dunno why it is here
 109     hasTexTrigger:    Boolean; // HACK: true when there's a trigger than can change my texture
 110
 111     constructor Create(PanelRec: TDynRecord;
 112                        AddTextures: TAddTextureArray;
 113                        CurTex: Integer;
 114                        var Textures: TLevelTextureArray; aguid: Integer);
 115     destructor  Destroy(); override;
 116
 117     procedure   Update();
 118     procedure   SetFrame(Frame: Integer; Count: Byte);
 119     procedure   NextTexture(AnimLoop: Byte = 0);
 120     procedure   SetTexture(ID: Integer; AnimLoop: Byte = 0);
 121     function    GetTextureID(): Cardinal;
 122     function    GetTextureCount(): Integer;
 123     function    CanChangeTexture(): Boolean;
 124
 125     procedure   SaveState (st: TStream);
 126     procedure   LoadState (st: TStream);
 127
 128     procedure positionChanged (); inline;
 129
 130     function getIsGBack (): Boolean; inline; // gRenderBackgrounds
 131     function getIsGStep (): Boolean; inline; // gSteps
 132     function getIsGWall (): Boolean; inline; // gWalls
 133     function getIsGAcid1 (): Boolean; inline; // gAcid1
 134     function getIsGAcid2 (): Boolean; inline; // gAcid2
 135     function getIsGWater (): Boolean; inline; // gWater
 136     function getIsGFore (): Boolean; inline; // gRenderForegrounds
 137     function getIsGLift (): Boolean; inline; // gLifts
 138     function getIsGBlockMon (): Boolean; inline; // gBlockMon
 139
 140     // get-and-clear
 141     function gncNeedSend (): Boolean; inline;
 142     procedure setDirty (); inline; // why `dirty`? 'cause i may introduce property `needSend` later
 143
 144   public
 145     property visvalid: Boolean read getvisvalid; // panel is "visvalid" when it's width and height are positive
 146
 147   published
 148     property guid: Integer read mGUID; // will be assigned in "g_map.pas"
 149     property x0: Integer read FX;
 150     property y0: Integer read FY;
 151     property x1: Integer read getx1; // inclusive!
 152     property y1: Integer read gety1; // inclusive!
 153     property x: Integer read FX write FX;
 154     property y: Integer read FY write FY;
 155     property width: Word read FWidth write FWidth;
 156     property height: Word read FHeight write FHeight;
 157     property panelType: Word read FPanelType write FPanelType;
 158     property enabled: Boolean read FEnabled write FEnabled;
 159     property door: Boolean read FDoor write FDoor;
 160     property liftType: Byte read FLiftType write FLiftType;
 161     property lastAnimLoop: Byte read FLastAnimLoop write FLastAnimLoop;
 162
 163     property movingSpeedX: Integer read getMovingSpeedX write setMovingSpeedX;
 164     property movingSpeedY: Integer read getMovingSpeedY write setMovingSpeedY;
 165     property movingStartX: Integer read getMovingStartX write setMovingStartX;
 166     property movingStartY: Integer read getMovingStartY write setMovingStartY;
 167     property movingEndX: Integer read getMovingEndX write setMovingEndX;
 168     property movingEndY: Integer read getMovingEndY write setMovingEndY;
 169     property movingActive: Boolean read mMovingActive write mMovingActive;
 170     property moveOnce: Boolean read mMoveOnce write mMoveOnce;
 171
 172     property sizeSpeedX: Integer read getSizeSpeedX write setSizeSpeedX;
 173     property sizeSpeedY: Integer read getSizeSpeedY write setSizeSpeedY;
 174     property sizeEndX: Integer read getSizeEndX write setSizeEndX;
 175     property sizeEndY: Integer read getSizeEndY write setSizeEndY;
 176
 177     property isGBack: Boolean read getIsGBack;
 178     property isGStep: Boolean read getIsGStep;
 179     property isGWall: Boolean read getIsGWall;
 180     property isGAcid1: Boolean read getIsGAcid1;
 181     property isGAcid2: Boolean read getIsGAcid2;
 182     property isGWater: Boolean read getIsGWater;
 183     property isGFore: Boolean read getIsGFore;
 184     property isGLift: Boolean read getIsGLift;
 185     property isGBlockMon: Boolean read getIsGBlockMon;
 186
 187     (* private state *)
 188     property Alpha: Byte read FAlpha;
 189     property Blending: Boolean read FBlending;
 190     property TextureIDs: ATextureID read FTextureIDs;
 191
 192   public
 193     property movingSpeed: TDFPoint read mMovingSpeed write mMovingSpeed;
 194     property movingStart: TDFPoint read mMovingStart write mMovingStart;
 195     property movingEnd: TDFPoint read mMovingEnd write mMovingEnd;
 196
 197     property sizeSpeed: TDFSize read mSizeSpeed write mSizeSpeed;
 198     property sizeEnd: TDFSize read mSizeEnd write mSizeEnd;
 199
 200     property endPosTrigId: Integer read mEndPosTrig write mEndPosTrig;
 201     property endSizeTrigId: Integer read mEndSizeTrig write mEndSizeTrig;
 202   end;
 203
 204   TPanelArray = Array of TPanel;
 205
 206 const
 207   LIFTTYPE_UP = 0;
 208   LIFTTYPE_DOWN = 1;
 209   LIFTTYPE_LEFT = 2;
 210   LIFTTYPE_RIGHT = 3;
 211
 212 var
 213   g_dbgpan_mplat_active: Boolean = {$IF DEFINED(D2F_DEBUG)}true{$ELSE}true{$ENDIF};
 214   g_dbgpan_mplat_step: Boolean = false; // one step, and stop
 215
 216
 217 implementation
 218
 219 uses
 220   g_basic, g_map, g_game, g_gfx, g_weapons, g_triggers,
 221   g_console, g_language, g_monsters, g_player, g_grid, e_log, geom, utils, xstreams;
 222
 223 const
 224   PANEL_SIGNATURE = $4C4E4150; // 'PANL'
 225
 226 { T P a n e l : }
 227
 228   function FindTextureByName (const name: String): Integer;
 229     var i: Integer;
 230   begin
 231     Result := -1;
 232     if Textures <> nil then
 233     begin
 234       for i := 0 to High(Textures) do
 235       begin
 236         if Textures[i].TextureName = name then
 237         begin
 238           Result := i;
 239           break;
 240         end
 241       end
 242     end
 243   end;
 244
 245 constructor TPanel.Create(PanelRec: TDynRecord;
 246                           AddTextures: TAddTextureArray;
 247                           CurTex: Integer;
 248                           var Textures: TLevelTextureArray; aguid: Integer);
 249 var
 250   i: Integer;
 251   tnum: Integer;
 252 begin
 253   X := PanelRec.X;
 254   Y := PanelRec.Y;
 255   Width := PanelRec.Width;
 256   Height := PanelRec.Height;
 257   FAlpha := 0;
 258   FBlending := False;
 259   FCurFrame := 0;
 260   FCurFrameCount := 0;
 261   LastAnimLoop := 0;
 262
 263   mapId := PanelRec.id;
 264   mGUID := aguid;
 265
 266   mMovingSpeed := PanelRec.moveSpeed;
 267   mMovingStart := PanelRec.moveStart;
 268   mMovingEnd := PanelRec.moveEnd;
 269   mMovingActive := PanelRec['move_active'].value;
 270   mOldMovingActive := mMovingActive;
 271   mMoveOnce := PanelRec.moveOnce;
 272
 273   mSizeSpeed := PanelRec.sizeSpeed;
 274   mSizeEnd := PanelRec.sizeEnd;
 275
 276   mEndPosTrig := PanelRec.endPosTrig;
 277   mEndSizeTrig := PanelRec.endSizeTrig;
 278
 279   mNeedSend := false;
 280
 281 // Òèï ïàíåëè:
 282   PanelType := PanelRec.PanelType;
 283   Enabled := True;
 284   Door := False;
 285   LiftType := LIFTTYPE_UP;
 286   hasTexTrigger := False;
 287
 288   case PanelType of
 289     PANEL_OPENDOOR: begin Enabled := False; Door := True; end;
 290     PANEL_CLOSEDOOR: Door := True;
 291     PANEL_LIFTUP: LiftType := LIFTTYPE_UP; //???
 292     PANEL_LIFTDOWN: LiftType := LIFTTYPE_DOWN;
 293     PANEL_LIFTLEFT: LiftType := LIFTTYPE_LEFT;
 294     PANEL_LIFTRIGHT: LiftType := LIFTTYPE_RIGHT;
 295   end;
 296
 297 // Íåâèäèìàÿ:
 298   if ByteBool(PanelRec.Flags and PANEL_FLAG_HIDE) then
 299   begin
 300     SetLength(FTextureIDs, 0);
 301     FCurTexture := -1;
 302     Exit;
 303   end;
 304 // Ïàíåëè, íå èñïîëüçóþùèå òåêñòóðû:
 305   if ByteBool(PanelType and
 306     (PANEL_LIFTUP or
 307      PANEL_LIFTDOWN or
 308      PANEL_LIFTLEFT or
 309      PANEL_LIFTRIGHT or
 310      PANEL_BLOCKMON)) then
 311   begin
 312     SetLength(FTextureIDs, 0);
 313     FCurTexture := -1;
 314     Exit;
 315   end;
 316
 317 // Åñëè ýòî æèäêîñòü áåç òåêñòóðû - ñïåöòåêñòóðó:
 318   if WordBool(PanelType and (PANEL_WATER or PANEL_ACID1 or PANEL_ACID2)) and
 319      (not ByteBool(PanelRec.Flags and PANEL_FLAG_WATERTEXTURES)) then
 320   begin
 321     SetLength(FTextureIDs, 1);
 322     FTextureIDs[0].Anim := False;
 323     case PanelRec.PanelType of
 324       PANEL_WATER: FTextureIDs[0].Texture := FindTextureByName(TEXTURE_NAME_WATER);
 325       PANEL_ACID1: FTextureIDs[0].Texture := FindTextureByName(TEXTURE_NAME_ACID1);
 326       PANEL_ACID2: FTextureIDs[0].Texture := FindTextureByName(TEXTURE_NAME_ACID2);
 327     end;
 328     FCurTexture := 0;
 329     Exit;
 330   end;
 331
 332   SetLength(FTextureIDs, Length(AddTextures));
 333
 334   if CurTex < 0 then
 335     FCurTexture := -1
 336   else
 337     if CurTex >= Length(FTextureIDs) then
 338       FCurTexture := Length(FTextureIDs) - 1
 339     else
 340       FCurTexture := CurTex;
 341
 342   for i := 0 to Length(FTextureIDs)-1 do
 343   begin
 344     FTextureIDs[i].Texture := AddTextures[i].Texture;
 345     FTextureIDs[i].Anim := Textures[AddTextures[i].Texture].FramesCount > 0;
 346     if FTextureIDs[i].Anim then
 347     begin // Àíèìèðîâàííàÿ òåêñòóðà
 348       FTextureIDs[i].AnTex := TAnimationState.Create(True, Textures[AddTextures[i].Texture].Speed, Textures[AddTextures[i].Texture].FramesCount);
 349       FTextureIDs[i].AnTex.Blending := ByteBool(PanelRec.Flags and PANEL_FLAG_BLENDING);
 350       FTextureIDs[i].AnTex.Alpha := PanelRec.Alpha;
 351     end
 352   end;
 353
 354 // Òåêñòóð íåñêîëüêî - íóæíî ñîõðàíÿòü òåêóùóþ:
 355   //if Length(FTextureIDs) > 1 then SaveIt := True;
 356
 357   if (PanelRec.TextureRec = nil) then tnum := -1 else tnum := PanelRec.tagInt;
 358   if (tnum < 0) then tnum := Length(Textures);
 359
 360 // Åñëè íå ñïåöòåêñòóðà, òî çàäàåì ðàçìåðû:
 361   if ({PanelRec.TextureNum}tnum > High(Textures)) then
 362   begin
 363     e_WriteLog(Format('WTF?! tnum is out of limits! (%d : %d)', [tnum, High(Textures)]), TMsgType.Warning);
 364     FAlpha := 0;
 365     FBlending := ByteBool(0);
 366   end
 367   else if not g_Map_IsSpecialTexture(Textures[{PanelRec.TextureNum}tnum].TextureName) then
 368   begin
 369     FAlpha := PanelRec.Alpha;
 370     FBlending := ByteBool(PanelRec.Flags and PANEL_FLAG_BLENDING);
 371   end;
 372 end;
 373
 374 destructor TPanel.Destroy();
 375 var
 376   i: Integer;
 377 begin
 378   for i := 0 to High(FTextureIDs) do
 379     if FTextureIDs[i].Anim then
 380       FTextureIDs[i].AnTex.Free();
 381   SetLength(FTextureIDs, 0);
 382
 383   Inherited;
 384 end;
 385
 386 function TPanel.getx1 (): Integer; inline; begin result := X+Width-1; end;
 387 function TPanel.gety1 (): Integer; inline; begin result := Y+Height-1; end;
 388 function TPanel.getvisvalid (): Boolean; inline; begin result := (Width > 0) and (Height > 0); end;
 389
 390 function TPanel.getMovingSpeedX (): Integer; inline; begin result := mMovingSpeed.X; end;
 391 procedure TPanel.setMovingSpeedX (v: Integer); inline; begin mMovingSpeed.X := v; end;
 392 function TPanel.getMovingSpeedY (): Integer; inline; begin result := mMovingSpeed.Y; end;
 393 procedure TPanel.setMovingSpeedY (v: Integer); inline; begin mMovingSpeed.Y := v; end;
 394
 395 function TPanel.getMovingStartX (): Integer; inline; begin result := mMovingStart.X; end;
 396 procedure TPanel.setMovingStartX (v: Integer); inline; begin mMovingStart.X := v; end;
 397 function TPanel.getMovingStartY (): Integer; inline; begin result := mMovingStart.Y; end;
 398 procedure TPanel.setMovingStartY (v: Integer); inline; begin mMovingStart.Y := v; end;
 399
 400 function TPanel.getMovingEndX (): Integer; inline; begin result := mMovingEnd.X; end;
 401 procedure TPanel.setMovingEndX (v: Integer); inline; begin mMovingEnd.X := v; end;
 402 function TPanel.getMovingEndY (): Integer; inline; begin result := mMovingEnd.Y; end;
 403 procedure TPanel.setMovingEndY (v: Integer); inline; begin mMovingEnd.Y := v; end;
 404
 405 function TPanel.getSizeSpeedX (): Integer; inline; begin result := mSizeSpeed.w; end;
 406 procedure TPanel.setSizeSpeedX (v: Integer); inline; begin mSizeSpeed.w := v; end;
 407 function TPanel.getSizeSpeedY (): Integer; inline; begin result := mSizeSpeed.h; end;
 408 procedure TPanel.setSizeSpeedY (v: Integer); inline; begin mSizeSpeed.h := v; end;
 409
 410 function TPanel.getSizeEndX (): Integer; inline; begin result := mSizeEnd.w; end;
 411 procedure TPanel.setSizeEndX (v: Integer); inline; begin mSizeEnd.w := v; end;
 412 function TPanel.getSizeEndY (): Integer; inline; begin result := mSizeEnd.h; end;
 413 procedure TPanel.setSizeEndY (v: Integer); inline; begin mSizeEnd.h := v; end;
 414
 415 function TPanel.getIsGBack (): Boolean; inline; begin result := ((tag and GridTagBack) <> 0); end;
 416 function TPanel.getIsGStep (): Boolean; inline; begin result := ((tag and GridTagStep) <> 0); end;
 417 function TPanel.getIsGWall (): Boolean; inline; begin result := ((tag and (GridTagWall or GridTagDoor)) <> 0); end;
 418 function TPanel.getIsGAcid1 (): Boolean; inline; begin result := ((tag and GridTagAcid1) <> 0); end;
 419 function TPanel.getIsGAcid2 (): Boolean; inline; begin result := ((tag and GridTagAcid2) <> 0); end;
 420 function TPanel.getIsGWater (): Boolean; inline; begin result := ((tag and GridTagWater) <> 0); end;
 421 function TPanel.getIsGFore (): Boolean; inline; begin result := ((tag and GridTagFore) <> 0); end;
 422 function TPanel.getIsGLift (): Boolean; inline; begin result := ((tag and GridTagLift) <> 0); end;
 423 function TPanel.getIsGBlockMon (): Boolean; inline; begin result := ((tag and GridTagBlockMon) <> 0); end;
 424
 425 function TPanel.gncNeedSend (): Boolean; inline; begin result := mNeedSend; mNeedSend := false; end;
 426 procedure TPanel.setDirty (); inline; begin mNeedSend := true; end;
 427
 428 procedure TPanel.positionChanged (); inline;
 429 var
 430   px, py, pw, ph: Integer;
 431 begin
 432   if (proxyId >= 0) then
 433   begin
 434     mapGrid.getBodyDims(proxyId, px, py, pw, ph);
 435     if (px <> x) or (py <> y) or (pw <> Width) or (ph <> Height) then
 436     begin
 437       {
 438       e_LogWritefln('panel moved: arridx=%s; guid=%s; proxyid=%s; old:(%s,%s)-(%sx%s); new:(%s,%s)-(%sx%s)',
 439         [arrIdx, mGUID, proxyId, px, py, pw, ph, x, y, width, height]);
 440       }
 441       g_Mark(px, py, pw, ph, MARK_WALL, false);
 442       if (Width < 1) or (Height < 1) then
 443       begin
 444         mapGrid.proxyEnabled[proxyId] := false;
 445       end
 446       else
 447       begin
 448         mapGrid.proxyEnabled[proxyId] := Enabled;
 449         if (pw <> Width) or (ph <> Height) then
 450         begin
 451           //writeln('panel resize!');
 452           mapGrid.moveResizeBody(proxyId, X, Y, Width, Height)
 453         end
 454         else
 455         begin
 456           mapGrid.moveBody(proxyId, X, Y);
 457         end;
 458         g_Mark(X, Y, Width, Height, MARK_WALL);
 459       end;
 460     end;
 461   end;
 462 end;
 463
 464
 465 var
 466   monCheckList: array of TMonster = nil;
 467   monCheckListUsed: Integer = 0;
 468
 469 procedure TPanel.Update();
 470 var
 471   ox, oy: Integer;
 472   nx, ny, nw, nh: Integer;
 473   ex, ey, nex, ney: Integer;
 474   mpw, mph: Integer;
 475
 476   // return `true` if we should move by dx,dy
 477   function tryMPlatMove (px, py, pw, ph: Integer; out dx, dy: Integer; out squash: Boolean; ontop: PBoolean=nil): Boolean;
 478   var
 479     u0: Single;
 480     tex, tey: Integer;
 481     pdx, pdy: Integer;
 482     trtag: Integer;
 483     szdx, szdy: Integer;
 484   begin
 485     squash := false;
 486     tex := px;
 487     tey := py;
 488     pdx := mMovingSpeed.X;
 489     pdy := mMovingSpeed.Y;
 490     // standing on the platform?
 491     if (py+ph = oy) then
 492     begin
 493       if (ontop <> nil) then ontop^ := true;
 494       // yes, move with it; but skip steps (no need to process size change here, 'cause platform top cannot be changed with it)
 495       mapGrid.traceBox(tex, tey, px, py, pw, ph, pdx, pdy, (GridTagWall or GridTagDoor));
 496     end
 497     else
 498     begin
 499       if (ontop <> nil) then ontop^ := false;
 500       // not standing on the platform: trace platform to see if it hits the entity
 501       // first, process size change (as we cannot sweeptest both move and size change)
 502       // but we don't have to check for pushing if the panel is shrinking
 503       szdx := nw-mpw;
 504       szdy := nh-mph;
 505       if (szdx > 0) or (szdy > 0) then
 506       begin
 507         // ignore shrinking dimension
 508         if (szdx < 0) then szdx := 0;
 509         if (szdy < 0) then szdy := 0;
 510         // move platform by szd* back, and check for szd* movement
 511         if sweepAABB(ox-szdx, oy-szdy, nw, nh, szdx, szdy, px, py, pw, ph, @u0) then
 512         begin
 513           // yes, platform hits the entity, push the entity in the resizing direction
 514           u0 := 1.0-u0; // how much path left?
 515           szdx := trunc(szdx*u0);
 516           szdy := trunc(szdy*u0);
 517           if (szdx <> 0) or (szdy <> 0) then
 518           begin
 519             // has some path to go, trace the entity
 520             trtag := (GridTagWall or GridTagDoor);
 521             // if we're moving down, consider steps too
 522             if (szdy > 0) then trtag := trtag or GridTagStep;
 523             mapGrid.traceBox(tex, tey, px, py, pw, ph, szdx, szdy, trtag);
 524           end;
 525         end;
 526       end;
 527       // second, process platform movement, using te* as entity starting point
 528       if sweepAABB(ox, oy, nw, nh, pdx, pdy, tex, tey, pw, ph, @u0) then
 529       begin
 530         //e_LogWritefln('T: platsweep; u0=%s; u1=%s; hedge=%s; sweepAABB(%s, %s, %s, %s, %s, %s, %s, %s, %s, %s)', [u0, u1, hedge, ox, oy, mpw, mph, pdx, pdy, px-1, py-1, pw+2, ph+2]);
 531         // yes, platform hits the entity, push the entity in the direction of the platform
 532         u0 := 1.0-u0; // how much path left?
 533         pdx := trunc(pdx*u0);
 534         pdy := trunc(pdy*u0);
 535         //e_LogWritefln(' platsweep; uleft=%s; pd=(%s,%s)', [u0, pdx, pdy]);
 536         if (pdx <> 0) or (pdy <> 0) then
 537         begin
 538           // has some path to go, trace the entity
 539           trtag := (GridTagWall or GridTagDoor);
 540           // if we're moving down, consider steps too
 541           if (pdy > 0) then trtag := trtag or GridTagStep;
 542           mapGrid.traceBox(tex, tey, px, py, pw, ph, pdx, pdy, trtag);
 543         end;
 544       end;
 545     end;
 546     // done with entity movement, new coords are in te*
 547     dx := tex-px;
 548     dy := tey-py;
 549     result := (dx <> 0) or (dy <> 0);
 550     if ((tag and (GridTagWall or GridTagDoor)) <> 0) then
 551     begin
 552       // check for squashing; as entity cannot be pushed into a wall, check only collision with the platform itself
 553       squash := g_Collide(tex, tey, pw, ph, nx, ny, nw, nh); // squash, if still in platform
 554     end;
 555   end;
 556
 557   function monCollect (mon: TMonster): Boolean;
 558   begin
 559     result := false; // don't stop
 560     if (monCheckListUsed >= Length(monCheckList)) then SetLength(monCheckList, monCheckListUsed+128);
 561     monCheckList[monCheckListUsed] := mon;
 562     Inc(monCheckListUsed);
 563   end;
 564
 565 var
 566   cx0, cy0, cx1, cy1, cw, ch: Integer;
 567   f: Integer;
 568   px, py, pw, ph, pdx, pdy: Integer;
 569   squash: Boolean;
 570   plr: TPlayer;
 571   gib: PGib;
 572   cor: TCorpse;
 573   mon: TMonster;
 574   mpfrid: LongWord;
 575   ontop: Boolean;
 576   actMoveTrig: Boolean;
 577   actSizeTrig: Boolean;
 578 begin
 579   if (not Enabled) or (Width < 1) or (Height < 1) then exit;
 580
 581   if (FCurTexture >= 0) and
 582     (FTextureIDs[FCurTexture].Anim) and
 583     (FTextureIDs[FCurTexture].AnTex <> nil) and
 584     (FAlpha < 255) then
 585   begin
 586     FTextureIDs[FCurTexture].AnTex.Update();
 587     FCurFrame := FTextureIDs[FCurTexture].AnTex.CurrentFrame;
 588     FCurFrameCount := FTextureIDs[FCurTexture].AnTex.CurrentCounter;
 589   end;
 590
 591   if not g_dbgpan_mplat_active then exit;
 592
 593   if (mOldMovingActive <> mMovingActive) then mNeedSend := true;
 594   mOldMovingActive := mMovingActive;
 595
 596   if not mMovingActive then exit;
 597   if mMovingSpeed.isZero and mSizeSpeed.isZero then exit;
 598
 599   //TODO: write wall size change processing
 600
 601   // moving platform?
 602   begin
 603     (*
 604      * collect all monsters and players (aka entities) along the possible platform path
 605      *   if entity is standing on a platform:
 606      *     try to move it along the platform path, checking wall collisions
 607      *   if entity is NOT standing on a platform, but hit with sweeped platform aabb:
 608      *     try to push entity
 609      *     if we can't push entity all the way, squash it
 610      *)
 611     ox := X;
 612     oy := Y;
 613     mpw := Width;
 614     mph := Height;
 615
 616     nw := mpw+mSizeSpeed.w;
 617     nh := mph+mSizeSpeed.h;
 618     nx := ox+mMovingSpeed.X;
 619     ny := oy+mMovingSpeed.Y;
 620
 621     // force network updates only if some sudden change happened
 622     // set the flag here, so we can sync affected monsters
 623     if not mSizeSpeed.isZero and (nw = mSizeEnd.w) and (nh = mSizeEnd.h) then
 624     begin
 625       mNeedSend := true;
 626     end
 627     else if ((mMovingSpeed.X < 0) and (nx <= mMovingStart.X)) or ((mMovingSpeed.X > 0) and (nx >= mMovingEnd.X)) then
 628     begin
 629       mNeedSend := true;
 630     end
 631     else if ((mMovingSpeed.Y < 0) and (ny <= mMovingStart.Y)) or ((mMovingSpeed.Y > 0) and (ny >= mMovingEnd.Y)) then
 632     begin
 633       mNeedSend := true;
 634     end;
 635
 636     // if pannel disappeared, we don't have to do anything
 637     if (nw > 0) and (nh > 0) then
 638     begin
 639       // old rect
 640       ex := ox+mpw-1;
 641       ey := ox+mph-1;
 642       // new rect
 643       nex := nx+nw-1;
 644       ney := ny+nh-1;
 645       // full rect
 646       cx0 := nmin(ox, nx);
 647       cy0 := nmin(oy, ny);
 648       cx1 := nmax(ex, nex);
 649       cy1 := nmax(ey, ney);
 650       // extrude
 651       cx0 -= 1;
 652       cy0 -= 1;
 653       cx1 += 1;
 654       cy1 += 1;
 655       cw := cx1-cx0+1;
 656       ch := cy1-cy0+1;
 657
 658       // process "obstacle" panels
 659       if ((tag and GridTagObstacle) <> 0) then
 660       begin
 661         // temporarily turn off this panel, so it won't interfere with collision checks
 662         mapGrid.proxyEnabled[proxyId] := false;
 663
 664         // process players
 665         for f := 0 to High(gPlayers) do
 666         begin
 667           plr := gPlayers[f];
 668           if (plr = nil) or (not plr.alive) then continue;
 669           plr.getMapBox(px, py, pw, ph);
 670           if not g_Collide(px, py, pw, ph, cx0, cy0, cw, ch) then continue;
 671           if tryMPlatMove(px, py, pw, ph, pdx, pdy, squash) then
 672           begin
 673             // set new position
 674             plr.moveBy(pdx, pdy); // this will call `positionChanged()` for us
 675           end;
 676           // squash player, if necessary
 677           if not g_Game_IsClient and squash then plr.Damage(15000, 0, 0, 0, HIT_TRAP);
 678         end;
 679
 680         // process gibs
 681         for f := 0 to High(gGibs) do
 682         begin
 683           gib := @gGibs[f];
 684           if not gib.alive then continue;
 685           gib.getMapBox(px, py, pw, ph);
 686           if not g_Collide(px, py, pw, ph, cx0, cy0, cw, ch) then continue;
 687           if tryMPlatMove(px, py, pw, ph, pdx, pdy, squash, @ontop) then
 688           begin
 689             // set new position
 690             gib.moveBy(pdx, pdy); // this will call `positionChanged()` for us
 691           end;
 692         end;
 693
 694         // move and push corpses
 695         for f := 0 to High(gCorpses) do
 696         begin
 697           cor := gCorpses[f];
 698           if (cor = nil) then continue;
 699           cor.getMapBox(px, py, pw, ph);
 700           if not g_Collide(px, py, pw, ph, cx0, cy0, cw, ch) then continue;
 701           if tryMPlatMove(px, py, pw, ph, pdx, pdy, squash, @ontop) then
 702           begin
 703             // set new position
 704             cor.moveBy(pdx, pdy); // this will call `positionChanged()` for us
 705           end;
 706         end;
 707
 708         // collect monsters
 709         monCheckListUsed := 0;
 710         g_Mons_ForEachAt(cx0, cy0, cw, ch, monCollect);
 711
 712         // process collected monsters
 713         if (monCheckListUsed > 0) then
 714         begin
 715           mpfrid := g_Mons_getNewMPlatFrameId();
 716           for f := 0 to monCheckListUsed do
 717           begin
 718             mon := monCheckList[f];
 719             if (mon = nil) or (not mon.alive) or (mon.mplatCheckFrameId = mpfrid) then continue;
 720             mon.mplatCheckFrameId := mpfrid;
 721             mon.getMapBox(px, py, pw, ph);
 722             //if not g_Collide(px, py, pw, ph, cx0, cy0, cw, ch) then continue;
 723             if tryMPlatMove(px, py, pw, ph, pdx, pdy, squash) then
 724             begin
 725               // set new position
 726               mon.moveBy(pdx, pdy); // this will call `positionChanged()` for us
 727               //???FIXME: do we really need to send monsters over the net?
 728               //          i don't think so, as dead reckoning should take care of 'em
 729               // ok, send new monster position only if platform is going to change it's direction
 730               if mNeedSend then mon.setDirty();
 731             end;
 732             // squash monster, if necessary
 733             if not g_Game_IsClient and squash then mon.Damage(15000, 0, 0, 0, HIT_TRAP);
 734           end;
 735         end;
 736
 737         // restore panel state
 738         mapGrid.proxyEnabled[proxyId] := true;
 739       end;
 740     end;
 741
 742     // move panel
 743     X := nx;
 744     Y := ny;
 745     FWidth := nw;
 746     FHeight := nh;
 747     positionChanged();
 748
 749     actMoveTrig := false;
 750     actSizeTrig := false;
 751
 752     // `mNeedSend` was set above
 753
 754     // check "size stop"
 755     if not mSizeSpeed.isZero and (nw = mSizeEnd.w) and (nh = mSizeEnd.h) then
 756     begin
 757       mSizeSpeed.w := 0;
 758       mSizeSpeed.h := 0;
 759       actSizeTrig := true;
 760       if (nw < 1) or (nh < 1) then mMovingActive := false; //HACK!
 761     end;
 762
 763     // reverse moving direction, if necessary
 764     if ((mMovingSpeed.X < 0) and (nx <= mMovingStart.X)) or ((mMovingSpeed.X > 0) and (nx >= mMovingEnd.X)) then
 765     begin
 766       if mMoveOnce then mMovingActive := false else mMovingSpeed.X := -mMovingSpeed.X;
 767       actMoveTrig := true;
 768     end;
 769
 770     if ((mMovingSpeed.Y < 0) and (ny <= mMovingStart.Y)) or ((mMovingSpeed.Y > 0) and (ny >= mMovingEnd.Y)) then
 771     begin
 772       if mMoveOnce then mMovingActive := false else mMovingSpeed.Y := -mMovingSpeed.Y;
 773       actMoveTrig := true;
 774     end;
 775
 776     if (mOldMovingActive <> mMovingActive) then mNeedSend := true;
 777     mOldMovingActive := mMovingActive;
 778
 779     if not g_Game_IsClient then
 780     begin
 781       if actMoveTrig then g_Triggers_Press(mEndPosTrig, ACTIVATE_CUSTOM);
 782       if actSizeTrig then g_Triggers_Press(mEndSizeTrig, ACTIVATE_CUSTOM);
 783     end;
 784
 785     // some triggers may activate this, don't delay sending
 786     //TODO: when triggers will be able to control speed and size, check that here too
 787     if (mOldMovingActive <> mMovingActive) then mNeedSend := true;
 788     mOldMovingActive := mMovingActive;
 789   end;
 790 end;
 791
 792
 793 procedure TPanel.SetFrame(Frame: Integer; Count: Byte);
 794
 795   function ClampInt(X, A, B: Integer): Integer;
 796   begin
 797     Result := X;
 798     if X < A then Result := A else if X > B then Result := B;
 799   end;
 800
 801 begin
 802   if Enabled and (FCurTexture >= 0) and
 803     (FTextureIDs[FCurTexture].Anim) and
 804     (FTextureIDs[FCurTexture].AnTex <> nil) and
 805     (Width > 0) and (Height > 0) and (FAlpha < 255) then
 806   begin
 807     FCurFrame := ClampInt(Frame, 0, FTextureIDs[FCurTexture].AnTex.TotalFrames - 1);
 808     FCurFrameCount := Count;
 809     FTextureIDs[FCurTexture].AnTex.CurrentFrame := FCurFrame;
 810     FTextureIDs[FCurTexture].AnTex.CurrentCounter := FCurFrameCount;
 811   end;
 812 end;
 813
 814 procedure TPanel.NextTexture(AnimLoop: Byte = 0);
 815 begin
 816   Assert(FCurTexture >= -1, 'FCurTexture < -1');
 817
 818 // Íåò òåêñòóð:
 819   if Length(FTextureIDs) = 0 then
 820     FCurTexture := -1
 821   else
 822   // Òîëüêî îäíà òåêñòóðà:
 823     if Length(FTextureIDs) = 1 then
 824       begin
 825         if FCurTexture = 0 then
 826           FCurTexture := -1
 827         else
 828           FCurTexture := 0;
 829       end
 830     else
 831     // Áîëüøå îäíîé òåêñòóðû:
 832       begin
 833       // Ñëåäóþùàÿ:
 834         Inc(FCurTexture);
 835       // Ñëåäóþùåé íåò - âîçâðàò ê íà÷àëó:
 836         if FCurTexture >= Length(FTextureIDs) then
 837           FCurTexture := 0;
 838       end;
 839
 840 // Ïåðåêëþ÷èëèñü íà âèäèìóþ àíèì. òåêñòóðó:
 841   if (FCurTexture >= 0) and FTextureIDs[FCurTexture].Anim then
 842   begin
 843     if (FTextureIDs[FCurTexture].AnTex = nil) then
 844     begin
 845       g_FatalError(_lc[I_GAME_ERROR_SWITCH_TEXTURE]);
 846       Exit;
 847     end;
 848
 849     if AnimLoop = 1 then
 850       FTextureIDs[FCurTexture].AnTex.Loop := True
 851     else
 852       if AnimLoop = 2 then
 853         FTextureIDs[FCurTexture].AnTex.Loop := False;
 854
 855     FTextureIDs[FCurTexture].AnTex.Reset();
 856   end;
 857
 858   LastAnimLoop := AnimLoop;
 859 end;
 860
 861 procedure TPanel.SetTexture(ID: Integer; AnimLoop: Byte = 0);
 862 begin
 863   if (ID >= -1) and (ID < Length(FTextureIDs)) then
 864     FCurTexture := ID;
 865
 866 // Ïåðåêëþ÷èëèñü íà âèäèìóþ àíèì. òåêñòóðó:
 867   if (FCurTexture >= 0) and FTextureIDs[FCurTexture].Anim then
 868   begin
 869     if (FTextureIDs[FCurTexture].AnTex = nil) then
 870     begin
 871       g_FatalError(_lc[I_GAME_ERROR_SWITCH_TEXTURE]);
 872       Exit;
 873     end;
 874
 875     if AnimLoop = 1 then
 876       FTextureIDs[FCurTexture].AnTex.Loop := True
 877     else
 878       if AnimLoop = 2 then
 879         FTextureIDs[FCurTexture].AnTex.Loop := False;
 880
 881     FTextureIDs[FCurTexture].AnTex.Reset();
 882   end;
 883
 884   LastAnimLoop := AnimLoop;
 885 end;
 886
 887   function TPanel.GetTextureID(): DWORD;
 888     var Texture: Integer;
 889   begin
 890     Result := LongWord(TEXTURE_NONE);
 891     if (FCurTexture >= 0) then
 892     begin
 893       Texture := FTextureIDs[FCurTexture].Texture;
 894       case Textures[Texture].TextureName of
 895         TEXTURE_NAME_WATER: Result := DWORD(TEXTURE_SPECIAL_WATER);
 896         TEXTURE_NAME_ACID1: Result := DWORD(TEXTURE_SPECIAL_ACID1);
 897         TEXTURE_NAME_ACID2: Result := DWORD(TEXTURE_SPECIAL_ACID2);
 898       end
 899     end
 900   end;
 901
 902 function TPanel.GetTextureCount(): Integer;
 903 begin
 904   Result := Length(FTextureIDs);
 905   if Enabled and (FCurTexture >= 0) then
 906      if (FTextureIDs[FCurTexture].Anim) and
 907         (FTextureIDs[FCurTexture].AnTex <> nil) and
 908         (Width > 0) and (Height > 0) and (FAlpha < 255) then
 909        Result := Result + 100;
 910 end;
 911
 912 function TPanel.CanChangeTexture(): Boolean;
 913 begin
 914   Result := (GetTextureCount() > 1) or hasTexTrigger;
 915 end;
 916
 917 const
 918   PAN_SAVE_VERSION = 1;
 919
 920 procedure TPanel.SaveState (st: TStream);
 921 var
 922   anim: Boolean;
 923 begin
 924   if (st = nil) then exit;
 925
 926   // Ñèãíàòóðà ïàíåëè
 927   utils.writeSign(st, 'PANL');
 928   utils.writeInt(st, Byte(PAN_SAVE_VERSION));
 929   // Îòêðûòà/çàêðûòà, åñëè äâåðü
 930   utils.writeBool(st, FEnabled);
 931   // Íàïðàâëåíèå ëèôòà, åñëè ëèôò
 932   utils.writeInt(st, Byte(FLiftType));
 933   // Íîìåð òåêóùåé òåêñòóðû
 934   utils.writeInt(st, Integer(FCurTexture));
 935   // Êîîðäèíàòû è ðàçìåð
 936   utils.writeInt(st, Integer(FX));
 937   utils.writeInt(st, Integer(FY));
 938   utils.writeInt(st, Word(FWidth));
 939   utils.writeInt(st, Word(FHeight));
 940   // Àíèìèðîâàíà ëè òåêóùàÿ òåêñòóðà
 941   if (FCurTexture >= 0) and (FTextureIDs[FCurTexture].Anim) then
 942   begin
 943     assert(FTextureIDs[FCurTexture].AnTex <> nil, 'TPanel.SaveState: No animation object');
 944     anim := true;
 945   end
 946   else
 947   begin
 948     anim := false;
 949   end;
 950   utils.writeBool(st, anim);
 951   // Åñëè äà - ñîõðàíÿåì àíèìàöèþ
 952   if anim then FTextureIDs[FCurTexture].AnTex.SaveState(st);
 953
 954   // moving platform state
 955   utils.writeInt(st, Integer(mMovingSpeed.X));
 956   utils.writeInt(st, Integer(mMovingSpeed.Y));
 957   utils.writeInt(st, Integer(mMovingStart.X));
 958   utils.writeInt(st, Integer(mMovingStart.Y));
 959   utils.writeInt(st, Integer(mMovingEnd.X));
 960   utils.writeInt(st, Integer(mMovingEnd.Y));
 961
 962   utils.writeInt(st, Integer(mSizeSpeed.w));
 963   utils.writeInt(st, Integer(mSizeSpeed.h));
 964   utils.writeInt(st, Integer(mSizeEnd.w));
 965   utils.writeInt(st, Integer(mSizeEnd.h));
 966
 967   utils.writeBool(st, mMovingActive);
 968   utils.writeBool(st, mMoveOnce);
 969
 970   utils.writeInt(st, Integer(mEndPosTrig));
 971   utils.writeInt(st, Integer(mEndSizeTrig));
 972 end;
 973
 974
 975 procedure TPanel.LoadState (st: TStream);
 976 begin
 977   if (st = nil) then exit;
 978
 979   // Ñèãíàòóðà ïàíåëè
 980   if not utils.checkSign(st, 'PANL') then raise XStreamError.create('wrong panel signature');
 981   if (utils.readByte(st) <> PAN_SAVE_VERSION) then raise XStreamError.create('wrong panel version');
 982   // Îòêðûòà/çàêðûòà, åñëè äâåðü
 983   FEnabled := utils.readBool(st);
 984   // Íàïðàâëåíèå ëèôòà, åñëè ëèôò
 985   FLiftType := utils.readByte(st);
 986   // Íîìåð òåêóùåé òåêñòóðû
 987   FCurTexture := utils.readLongInt(st);
 988   // Êîîðäèíàòû è ðàçìåð
 989   FX := utils.readLongInt(st);
 990   FY := utils.readLongInt(st);
 991   FWidth := utils.readWord(st);
 992   FHeight := utils.readWord(st);
 993   // Àíèìèðîâàííàÿ ëè òåêóùàÿ òåêñòóðà
 994   if utils.readBool(st) then
 995   begin
 996     // Åñëè äà - çàãðóæàåì àíèìàöèþ
 997     Assert((FCurTexture >= 0) and
 998            (FTextureIDs[FCurTexture].Anim) and
 999            (FTextureIDs[FCurTexture].AnTex <> nil),
1000            'TPanel.LoadState: No animation object');
1001     FTextureIDs[FCurTexture].AnTex.LoadState(st);
1002   end;
1003
1004   // moving platform state
1005   mMovingSpeed.X := utils.readLongInt(st);
1006   mMovingSpeed.Y := utils.readLongInt(st);
1007   mMovingStart.X := utils.readLongInt(st);
1008   mMovingStart.Y := utils.readLongInt(st);
1009   mMovingEnd.X := utils.readLongInt(st);
1010   mMovingEnd.Y := utils.readLongInt(st);
1011
1012   mSizeSpeed.w := utils.readLongInt(st);
1013   mSizeSpeed.h := utils.readLongInt(st);
1014   mSizeEnd.w := utils.readLongInt(st);
1015   mSizeEnd.h := utils.readLongInt(st);
1016
1017   mMovingActive := utils.readBool(st);
1018   mMoveOnce := utils.readBool(st);
1019
1020   mEndPosTrig := utils.readLongInt(st);
1021   mEndSizeTrig := utils.readLongInt(st);
1022
1023   positionChanged();
1024   //mapGrid.proxyEnabled[proxyId] := FEnabled; // done in g_map.pas
1025 end;
1026
1027
1028 end.