src/game/g_items.pas

   1 (* Copyright (C)  Doom 2D: Forever Developers
   2  *
   3  * This program is free software: you can redistribute it and/or modify
   4  * it under the terms of the GNU General Public License as published by
   5  * the Free Software Foundation, version 3 of the License ONLY.
   6  *
   7  * This program is distributed in the hope that it will be useful,
   8  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   9  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  10  * GNU General Public License for more details.
  11  *
  12  * You should have received a copy of the GNU General Public License
  13  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  14  *)
  15 {$INCLUDE ../shared/a_modes.inc}
  16 unit g_items;
  17
  18 interface
  19
  20 uses
  21   SysUtils, Classes,
  22   MAPDEF, g_phys, g_saveload;
  23
  24 const
  25   ITEM_LAST = ITEM_MAX;
  26
  27 Type
  28   PItem = ^TItem;
  29   TItem = record
  30   private
  31     //treeNode: Integer;
  32     slotIsUsed: Boolean;
  33     arrIdx: Integer; // in ggItems
  34
  35   public
  36     ItemType: Byte;
  37     Respawnable: Boolean;
  38     InitX, InitY: Integer;
  39     RespawnTime: Word;
  40     alive: Boolean;
  41     Fall: Boolean;
  42     QuietRespawn: Boolean;
  43     SpawnTrigger: Integer;
  44     Obj: TObj;
  45     dropped: Boolean; // dropped from the monster? drops should be rendered after corpses, so zombie corpse will not obscure ammo container, for example
  46     NeedSend: Boolean;
  47
  48     procedure positionChanged (); //WARNING! call this after monster position was changed, or coldet will not work right!
  49     procedure getMapBox (out x, y, w, h: Integer); inline;
  50     procedure moveBy (dx, dy: Integer); inline;
  51
  52     property used: Boolean read slotIsUsed;
  53     property myid: Integer read arrIdx;
  54   end;
  55
  56 procedure g_Items_LoadData();
  57 procedure g_Items_FreeData();
  58 procedure g_Items_Init();
  59 procedure g_Items_Free();
  60 function g_Items_Create(X, Y: Integer; ItemType: Byte;
  61            Fall, Respawnable: Boolean; AdjCoord: Boolean = False; ForcedID: Integer = -1): DWORD;
  62 procedure g_Items_SetDrop (ID: DWORD);
  63 procedure g_Items_PreUpdate();
  64 procedure g_Items_Update();
  65 procedure g_Items_Pick(ID: DWORD);
  66 procedure g_Items_Remove(ID: DWORD);
  67 procedure g_Items_SaveState (st: TStream);
  68 procedure g_Items_LoadState (st: TStream);
  69
  70 procedure g_Items_RestartRound ();
  71
  72 function g_Items_ValidId (idx: Integer): Boolean; inline;
  73 function g_Items_ByIdx (idx: Integer): PItem;
  74 function g_Items_ObjByIdx (idx: Integer): PObj;
  75
  76 procedure g_Items_EmitPickupSound (idx: Integer); // at item position
  77 procedure g_Items_EmitPickupSoundAt (idx, x, y: Integer);
  78
  79 procedure g_Items_AddDynLights();
  80
  81
  82 type
  83   TItemEachAliveCB = function (it: PItem): Boolean is nested; // return `true` to stop
  84
  85 function g_Items_ForEachAlive (cb: TItemEachAliveCB; backwards: Boolean=false): Boolean;
  86 function g_Items_NextAlive (startIdx: Integer): PItem;
  87
  88   var (* private state *)
  89     ggItems: Array of TItem = nil;
  90
  91 implementation
  92
  93   uses
  94     {$IFDEF ENABLE_GFX}
  95       g_gfx,
  96     {$ENDIF}
  97     Math,
  98     g_basic, g_sound, g_map,
  99     g_game, g_triggers, g_console, g_player, g_net, g_netmsg,
 100     e_log, g_options, g_language, g_window,
 101     g_grid, binheap, idpool, utils, xstreams
 102   ;
 103
 104 // ////////////////////////////////////////////////////////////////////////// //
 105 var
 106   freeIds: TIdPool = nil;
 107
 108
 109 // ////////////////////////////////////////////////////////////////////////// //
 110 function g_Items_ValidId (idx: Integer): Boolean; inline;
 111 begin
 112   result := false;
 113   if (idx < 0) or (idx > High(ggItems)) then exit;
 114   if not ggItems[idx].slotIsUsed then exit;
 115   result := true;
 116 end;
 117
 118
 119 function g_Items_ByIdx (idx: Integer): PItem;
 120 begin
 121   if (idx < 0) or (idx > High(ggItems)) then raise Exception.Create('g_ItemObjByIdx: invalid index');
 122   result := @ggItems[idx];
 123   if not result.slotIsUsed then raise Exception.Create('g_ItemObjByIdx: requested inexistent item');
 124 end;
 125
 126
 127 function g_Items_ObjByIdx (idx: Integer): PObj;
 128 begin
 129   if (idx < 0) or (idx > High(ggItems)) then raise Exception.Create('g_ItemObjByIdx: invalid index');
 130   if not ggItems[idx].slotIsUsed then raise Exception.Create('g_ItemObjByIdx: requested inexistent item');
 131   result := @ggItems[idx].Obj;
 132 end;
 133
 134
 135 // ////////////////////////////////////////////////////////////////////////// //
 136 procedure TItem.positionChanged ();
 137 begin
 138   NeedSend := NeedSend or (Obj.X <> Obj.oldX) or (Obj.Y <> Obj.oldY);
 139 end;
 140
 141 procedure TItem.getMapBox (out x, y, w, h: Integer); inline;
 142 begin
 143   x := Obj.X+Obj.Rect.X;
 144   y := Obj.Y+Obj.Rect.Y;
 145   w := Obj.Rect.Width;
 146   h := Obj.Rect.Height;
 147 end;
 148
 149 procedure TItem.moveBy (dx, dy: Integer); inline;
 150 begin
 151   if (dx <> 0) or (dy <> 0) then
 152   begin
 153     Obj.X += dx;
 154     Obj.Y += dy;
 155     positionChanged();
 156   end;
 157 end;
 158
 159 // ////////////////////////////////////////////////////////////////////////// //
 160 const
 161   ITEM_SIGNATURE = $4D455449; // 'ITEM'
 162
 163   ITEMSIZE: Array [ITEM_MEDKIT_SMALL..ITEM_MAX] of Array [0..1] of Byte =
 164     (((14), (15)), // MEDKIT_SMALL
 165      ((28), (19)), // MEDKIT_LARGE
 166      ((28), (19)), // MEDKIT_BLACK
 167      ((31), (16)), // ARMOR_GREEN
 168      ((31), (16)), // ARMOR_BLUE
 169      ((25), (25)), // SPHERE_BLUE
 170      ((25), (25)), // SPHERE_WHITE
 171      ((24), (47)), // SUIT
 172      ((14), (27)), // OXYGEN
 173      ((25), (25)), // INVUL
 174      ((62), (24)), // WEAPON_SAW
 175      ((63), (12)), // WEAPON_SHOTGUN1
 176      ((54), (13)), // WEAPON_SHOTGUN2
 177      ((54), (16)), // WEAPON_CHAINGUN
 178      ((62), (16)), // WEAPON_ROCKETLAUNCHER
 179      ((54), (16)), // WEAPON_PLASMA
 180      ((61), (36)), // WEAPON_BFG
 181      ((54), (16)), // WEAPON_SUPERPULEMET
 182      (( 9), (11)), // AMMO_BULLETS
 183      ((28), (16)), // AMMO_BULLETS_BOX
 184      ((15), ( 7)), // AMMO_SHELLS
 185      ((32), (12)), // AMMO_SHELLS_BOX
 186      ((12), (27)), // AMMO_ROCKET
 187      ((54), (21)), // AMMO_ROCKET_BOX
 188      ((15), (12)), // AMMO_CELL
 189      ((32), (21)), // AMMO_CELL_BIG
 190      ((22), (29)), // AMMO_BACKPACK
 191      ((16), (16)), // KEY_RED
 192      ((16), (16)), // KEY_GREEN
 193      ((16), (16)), // KEY_BLUE
 194      (( 1), ( 1)), // WEAPON_KASTET
 195      ((43), (16)), // WEAPON_PISTOL
 196      ((14), (18)), // BOTTLE
 197      ((16), (15)), // HELMET
 198      ((32), (24)), // JETPACK
 199      ((25), (25)), // INVIS
 200      ((53), (20)), // WEAPON_FLAMETHROWER
 201      ((13), (20))); // AMMO_FUELCAN
 202
 203 procedure g_Items_LoadData();
 204 begin
 205   e_WriteLog('Loading items data...', TMsgType.Notify);
 206   g_Game_SetLoadingText(_lc[I_LOAD_ITEMS_DATA], 0, False);
 207
 208   g_Sound_CreateWADEx('SOUND_ITEM_RESPAWNITEM', GameWAD+':SOUNDS\RESPAWNITEM');
 209   g_Sound_CreateWADEx('SOUND_ITEM_GETRULEZ', GameWAD+':SOUNDS\GETRULEZ');
 210   g_Sound_CreateWADEx('SOUND_ITEM_GETWEAPON', GameWAD+':SOUNDS\GETWEAPON');
 211   g_Sound_CreateWADEx('SOUND_ITEM_GETITEM', GameWAD+':SOUNDS\GETITEM');
 212
 213   freeIds := TIdPool.Create();
 214 end;
 215
 216
 217 procedure g_Items_FreeData();
 218 begin
 219   e_WriteLog('Releasing items data...', TMsgType.Notify);
 220
 221   g_Sound_Delete('SOUND_ITEM_RESPAWNITEM');
 222   g_Sound_Delete('SOUND_ITEM_GETRULEZ');
 223   g_Sound_Delete('SOUND_ITEM_GETWEAPON');
 224   g_Sound_Delete('SOUND_ITEM_GETITEM');
 225
 226   freeIds.Free();
 227   freeIds := nil;
 228 end;
 229
 230
 231 procedure releaseItem (idx: Integer);
 232 var
 233   it: PItem;
 234 begin
 235   if (idx < 0) or (idx > High(ggItems)) then raise Exception.Create('releaseItem: invalid item id');
 236   if not freeIds.hasAlloced[LongWord(idx)] then raise Exception.Create('releaseItem: trying to release unallocated item (0)');
 237   it := @ggItems[idx];
 238   if not it.slotIsUsed then raise Exception.Create('releaseItem: trying to release unallocated item (1)');
 239   if (it.arrIdx <> idx) then raise Exception.Create('releaseItem: arrIdx inconsistency');
 240   it.slotIsUsed := false;
 241   it.alive := False;
 242   it.SpawnTrigger := -1;
 243   it.ItemType := ITEM_NONE;
 244   it.NeedSend := false;
 245   freeIds.release(LongWord(idx));
 246 end;
 247
 248
 249 procedure growItemArrayTo (newsz: Integer);
 250 var
 251   i, olen: Integer;
 252   it: PItem;
 253 begin
 254   if (newsz < Length(ggItems)) then exit;
 255   // no free slots
 256   olen := Length(ggItems);
 257   SetLength(ggItems, newsz);
 258   for i := olen to High(ggItems) do
 259   begin
 260     it := @ggItems[i];
 261     it.slotIsUsed := false;
 262     it.arrIdx := i;
 263     it.ItemType := ITEM_NONE;
 264     it.alive := false;
 265     it.SpawnTrigger := -1;
 266     it.Respawnable := false;
 267     it.NeedSend := false;
 268     //if not freeIds.hasFree[LongWord(i)] then raise Exception.Create('internal error in item idx manager');
 269   end;
 270 end;
 271
 272
 273 function allocItem (): DWORD;
 274 begin
 275   result := freeIds.alloc();
 276   if (result >= Length(ggItems)) then growItemArrayTo(Integer(result)+64);
 277   if (Integer(result) > High(ggItems)) then raise Exception.Create('allocItem: freeid list corrupted');
 278   if (ggItems[result].arrIdx <> Integer(result)) then raise Exception.Create('allocItem: arrIdx inconsistency');
 279 end;
 280
 281
 282 // it will be slow if the slot is free (we have to rebuild the heap)
 283 function wantItemSlot (slot: Integer): Integer;
 284 var
 285   olen: Integer;
 286   it: PItem;
 287 begin
 288   if (slot < 0) or (slot > $0fffffff) then raise Exception.Create('wantItemSlot: bad item slot request');
 289   // do we need to grow item storate?
 290   olen := Length(ggItems);
 291   if (slot >= olen) then growItemArrayTo(slot+64);
 292
 293   it := @ggItems[slot];
 294   if not it.slotIsUsed then
 295   begin
 296     freeIds.alloc(LongWord(slot));
 297   end
 298   else
 299   begin
 300     if not freeIds.hasAlloced[slot] then raise Exception.Create('wantItemSlot: internal error in item idx manager');
 301   end;
 302   it.slotIsUsed := false;
 303
 304   result := slot;
 305 end;
 306
 307
 308 // ////////////////////////////////////////////////////////////////////////// //
 309 procedure g_Items_Init ();
 310 begin
 311 end;
 312
 313
 314 procedure g_Items_Free ();
 315 begin
 316   if (ggItems <> nil) then
 317     ggItems := nil;
 318   freeIds.clear();
 319 end;
 320
 321
 322 function g_Items_Create (X, Y: Integer; ItemType: Byte;
 323            Fall, Respawnable: Boolean; AdjCoord: Boolean = False; ForcedID: Integer = -1): DWORD;
 324 var
 325   find_id: DWORD;
 326   it: PItem;
 327 begin
 328   if ForcedID < 0 then find_id := allocItem() else find_id := wantItemSlot(ForcedID);
 329
 330   //{$IF DEFINED(D2F_DEBUG)}e_WriteLog(Format('allocated item #%d', [Integer(find_id)]), MSG_NOTIFY);{$ENDIF}
 331
 332   it := @ggItems[find_id];
 333
 334   if (it.arrIdx <> Integer(find_id)) then raise Exception.Create('g_Items_Create: arrIdx inconsistency');
 335   //it.arrIdx := find_id;
 336   it.slotIsUsed := true;
 337
 338   it.ItemType := ItemType;
 339   it.Respawnable := Respawnable;
 340   it.InitX := X;
 341   it.InitY := Y;
 342   it.RespawnTime := 0;
 343   it.Fall := Fall;
 344   it.alive := True;
 345   it.QuietRespawn := False;
 346   it.dropped := false;
 347   it.NeedSend := false;
 348
 349   g_Obj_Init(@it.Obj);
 350   it.Obj.X := X;
 351   it.Obj.Y := Y;
 352   it.Obj.Rect.Width := ITEMSIZE[ItemType][0];
 353   it.Obj.Rect.Height := ITEMSIZE[ItemType][1];
 354
 355   it.SpawnTrigger := -1;
 356
 357   // Êîîðäèíàòû îòíîñèòåëüíî öåíòðà íèæíåãî ðåáðà
 358   if AdjCoord then
 359   begin
 360     with it^ do
 361     begin
 362       Obj.X := X - (Obj.Rect.Width div 2);
 363       Obj.Y := Y - Obj.Rect.Height;
 364       InitX := Obj.X;
 365       InitY := Obj.Y;
 366     end;
 367   end;
 368
 369   it.Obj.oldX := it.Obj.X;
 370   it.Obj.oldY := it.Obj.Y;
 371
 372   it.positionChanged();
 373
 374   result := find_id;
 375 end;
 376
 377 procedure g_Items_PreUpdate ();
 378 var
 379   i: Integer;
 380 begin
 381   if (ggItems = nil) then Exit;
 382   for i := 0 to High(ggItems) do
 383     if (ggItems[i].ItemType <> ITEM_NONE) and ggItems[i].slotIsUsed then
 384     begin
 385       ggItems[i].Obj.oldX := ggItems[i].Obj.X;
 386       ggItems[i].Obj.oldY := ggItems[i].Obj.Y;
 387     end;
 388 end;
 389
 390 procedure g_Items_Update ();
 391 var
 392   i, j, k: Integer;
 393   m, ItemRespawnTime: Word;
 394   r, nxt: Boolean;
 395 begin
 396   if (ggItems = nil) then exit;
 397
 398   // respawn items in 15 seconds regardless of settings during warmup
 399   ItemRespawnTime := IfThen(gLMSRespawn = LMS_RESPAWN_NONE, gGameSettings.ItemRespawnTime, 15);
 400
 401   for i := 0 to High(ggItems) do
 402   begin
 403     if (ggItems[i].ItemType = ITEM_NONE) then continue;
 404     if not ggItems[i].slotIsUsed then continue; // just in case
 405
 406     with ggItems[i] do
 407     begin
 408       nxt := False;
 409
 410       if alive then
 411       begin
 412         if Fall then
 413         begin
 414           m := g_Obj_Move(@Obj, True, True);
 415           positionChanged(); // this updates spatial accelerators
 416
 417           // Ñîïðîòèâëåíèå âîçäóõà
 418           if gTime mod (GAME_TICK*2) = 0 then Obj.Vel.X := z_dec(Obj.Vel.X, 1);
 419
 420           // Åñëè âûïàë çà êàðòó
 421           if WordBool(m and MOVE_FALLOUT) then
 422           begin
 423             if SpawnTrigger = -1 then
 424             begin
 425               g_Items_Pick(i);
 426             end
 427             else
 428             begin
 429               g_Items_Remove(i);
 430               if g_Game_IsServer and g_Game_IsNet then MH_SEND_ItemDestroy(True, i);
 431             end;
 432             continue;
 433           end;
 434         end;
 435
 436         // Åñëè èãðîêè ïîáëèçîñòè
 437         if (gPlayers <> nil) then
 438         begin
 439           j := Random(Length(gPlayers))-1;
 440
 441           for k := 0 to High(gPlayers) do
 442           begin
 443             Inc(j);
 444             if j > High(gPlayers) then j := 0;
 445
 446             if (gPlayers[j] <> nil) and gPlayers[j].alive and g_Obj_Collide(@gPlayers[j].Obj, @Obj) then
 447             begin
 448               if g_Game_IsClient then continue;
 449
 450               if not gPlayers[j].PickItem(ItemType, Respawnable, r) then continue;
 451
 452               if g_Game_IsNet then MH_SEND_PlayerStats(gPlayers[j].UID);
 453
 454               {
 455                 Doom 2D: Original:
 456                 1. I_NONE,I_CLIP,I_SHEL,I_ROCKET,I_CELL,I_AMMO,I_SBOX,I_RBOX,I_CELP,I_BPACK,I_CSAW,I_SGUN,I_SGUN2,I_MGUN,I_LAUN,I_PLAS,I_BFG,I_GUN2
 457                 +2. I_MEGA,I_INVL,I_SUPER
 458                 3. I_STIM,I_MEDI,I_ARM1,I_ARM2,I_AQUA,I_KEYR,I_KEYG,I_KEYB,I_SUIT,I_RTORCH,I_GTORCH,I_BTORCH,I_GOR1,I_FCAN
 459               }
 460               g_Items_EmitPickupSoundAt(i, gPlayers[j].Obj.X, gPlayers[j].Obj.Y);
 461
 462               // Íàäî óáðàòü ñ êàðòû, åñëè ýòî íå êëþ÷, êîòîðûì íóæíî ïîäåëèòüñÿ ñ äðóãèì èãðîêîì
 463               if r then
 464               begin
 465                 if not (Respawnable and (ItemRespawnTime > 0)) then
 466                   g_Items_Remove(i)
 467                 else
 468                   g_Items_Pick(i);
 469                 if g_Game_IsNet then MH_SEND_ItemDestroy(False, i);
 470                 nxt := True;
 471                 break;
 472               end;
 473             end;
 474           end;
 475         end;
 476
 477         if nxt then continue;
 478       end;
 479
 480       if Respawnable and g_Game_IsServer then
 481       begin
 482         DecMin(RespawnTime, 0);
 483         if (RespawnTime = 0) and (not alive) then
 484         begin
 485           if not QuietRespawn then g_Sound_PlayExAt('SOUND_ITEM_RESPAWNITEM', InitX, InitY);
 486           {$IFDEF ENABLE_GFX}
 487             g_GFX_QueueEffect(
 488               R_GFX_ITEM_RESPAWN,
 489               InitX + (Obj.Rect.Width div 2) - 16,
 490               InitY + (Obj.Rect.Height div 2) - 16
 491             );
 492           {$ENDIF}
 493           Obj.oldX := InitX;
 494           Obj.oldY := InitY;
 495           Obj.X := InitX;
 496           Obj.Y := InitY;
 497           Obj.Vel.X := 0;
 498           Obj.Vel.Y := 0;
 499           Obj.Accel.X := 0;
 500           Obj.Accel.Y := 0;
 501           positionChanged(); // this updates spatial accelerators
 502
 503           alive := true;
 504
 505           if g_Game_IsNet then MH_SEND_ItemSpawn(QuietRespawn, i);
 506           QuietRespawn := false;
 507         end;
 508       end;
 509     end;
 510   end;
 511 end;
 512
 513 procedure g_Items_SetDrop (ID: DWORD);
 514 begin
 515   if (ID < Length(ggItems)) then
 516   begin
 517     ggItems[ID].dropped := true;
 518   end;
 519 end;
 520
 521
 522 procedure g_Items_Pick (ID: DWORD);
 523 begin
 524   if (ID < Length(ggItems)) then
 525   begin
 526     ggItems[ID].Obj.oldX := ggItems[ID].Obj.X;
 527     ggItems[ID].Obj.oldY := ggItems[ID].Obj.Y;
 528     ggItems[ID].alive := false;
 529     ggItems[ID].RespawnTime := IfThen(gLMSRespawn = LMS_RESPAWN_NONE, gGameSettings.ItemRespawnTime, 15) * 36;
 530   end;
 531 end;
 532
 533
 534 procedure g_Items_Remove (ID: DWORD);
 535 var
 536   it: PItem;
 537   trig: Integer;
 538 begin
 539   if not g_Items_ValidId(ID) then
 540   begin
 541     //writeln('g_Items_Remove: invalid item id: ', ID);
 542     raise Exception.Create('g_Items_Remove: invalid item id');
 543     //exit;
 544   end;
 545
 546   it := @ggItems[ID];
 547   if (it.arrIdx <> Integer(ID)) then raise Exception.Create('g_Items_Remove: arrIdx desync');
 548
 549   it.Obj.oldX := it.Obj.X;
 550   it.Obj.oldY := it.Obj.Y;
 551   trig := it.SpawnTrigger;
 552
 553   releaseItem(ID);
 554
 555   if (trig > -1) then g_Triggers_DecreaseSpawner(trig);
 556 end;
 557
 558
 559 procedure g_Items_SaveState (st: TStream);
 560 var
 561   count, i: Integer;
 562   tt: Byte;
 563 begin
 564   // Ñ÷èòàåì êîëè÷åñòâî ñóùåñòâóþùèõ ïðåäìåòîâ
 565   count := 0;
 566   for i := 0 to High(ggItems) do if (ggItems[i].ItemType <> ITEM_NONE) and (ggItems[i].slotIsUsed) then Inc(count);
 567
 568   // Êîëè÷åñòâî ïðåäìåòîâ
 569   utils.writeInt(st, LongInt(count));
 570   if (count = 0) then exit;
 571
 572   for i := 0 to High(ggItems) do
 573   begin
 574     if (ggItems[i].ItemType <> ITEM_NONE) and (ggItems[i].slotIsUsed) then
 575     begin
 576       // Ñèãíàòóðà ïðåäìåòà
 577       utils.writeSign(st, 'ITEM');
 578       utils.writeInt(st, Byte(0));
 579       // Òèï ïðåäìåòà
 580       tt := ggItems[i].ItemType;
 581       if ggItems[i].dropped then tt := tt or $80;
 582       utils.writeInt(st, Byte(tt));
 583       // Åñòü ëè ðåñïàóí
 584       utils.writeBool(st, ggItems[i].Respawnable);
 585       // Êîîðäèíàòû ðåñïóíà
 586       utils.writeInt(st, LongInt(ggItems[i].InitX));
 587       utils.writeInt(st, LongInt(ggItems[i].InitY));
 588       // Âðåìÿ äî ðåñïàóíà
 589       utils.writeInt(st, Word(ggItems[i].RespawnTime));
 590       // Ñóùåñòâóåò ëè ýòîò ïðåäìåò
 591       utils.writeBool(st, ggItems[i].alive);
 592       // Ìîæåò ëè îí ïàäàòü
 593       utils.writeBool(st, ggItems[i].Fall);
 594       // Èíäåêñ òðèããåðà, ñîçäàâøåãî ïðåäìåò
 595       utils.writeInt(st, LongInt(ggItems[i].SpawnTrigger));
 596       // Îáúåêò ïðåäìåòà
 597       Obj_SaveState(st, @ggItems[i].Obj);
 598     end;
 599   end;
 600 end;
 601
 602
 603 procedure g_Items_LoadState (st: TStream);
 604 var
 605   count, i, a: Integer;
 606   b: Byte;
 607 begin
 608   assert(st <> nil);
 609
 610   g_Items_Free();
 611
 612   // Êîëè÷åñòâî ïðåäìåòîâ
 613   count := utils.readLongInt(st);
 614   if (count = 0) then exit;
 615   if (count < 0) or (count > 1024*1024) then raise XStreamError.Create('invalid number of items');
 616
 617   for a := 0 to count-1 do
 618   begin
 619     // Ñèãíàòóðà ïðåäìåòà
 620     if not utils.checkSign(st, 'ITEM') then raise XStreamError.Create('invalid item signature');
 621     if (utils.readByte(st) <> 0) then raise XStreamError.Create('invalid item version');
 622     // Òèï ïðåäìåòà
 623     b := utils.readByte(st); // bit7=1: monster drop
 624     // Ñîçäàåì ïðåäìåò
 625     i := g_Items_Create(0, 0, b and $7F, False, False);
 626     if ((b and $80) <> 0) then g_Items_SetDrop(i);
 627     // Åñòü ëè ðåñïàóí
 628     ggItems[i].Respawnable := utils.readBool(st);
 629     // Êîîðäèíàòû ðåñïóíà
 630     ggItems[i].InitX := utils.readLongInt(st);
 631     ggItems[i].InitY := utils.readLongInt(st);
 632     // Âðåìÿ äî ðåñïàóíà
 633     ggItems[i].RespawnTime := utils.readWord(st);
 634     // Ñóùåñòâóåò ëè ýòîò ïðåäìåò
 635     ggItems[i].alive := utils.readBool(st);
 636     // Ìîæåò ëè îí ïàäàòü
 637     ggItems[i].Fall := utils.readBool(st);
 638     // Èíäåêñ òðèããåðà, ñîçäàâøåãî ïðåäìåò
 639     ggItems[i].SpawnTrigger := utils.readLongInt(st);
 640     // Îáúåêò ïðåäìåòà
 641     Obj_LoadState(@ggItems[i].Obj, st);
 642   end;
 643 end;
 644
 645
 646 procedure g_Items_RestartRound ();
 647 var
 648   i: Integer;
 649   it: PItem;
 650 begin
 651   for i := 0 to High(ggItems) do
 652   begin
 653     it := @ggItems[i];
 654     it.Obj.oldX := it.Obj.X;
 655     it.Obj.oldY := it.Obj.Y;
 656     if not it.slotIsUsed then continue;
 657     if it.Respawnable and (it.ItemType <> ITEM_NONE) then
 658     begin
 659       it.QuietRespawn := True;
 660       it.RespawnTime := 0;
 661     end
 662     else
 663     begin
 664       g_Items_Remove(i);
 665       if g_Game_IsNet then MH_SEND_ItemDestroy(True, i);
 666     end;
 667   end;
 668 end;
 669
 670
 671 function g_Items_ForEachAlive (cb: TItemEachAliveCB; backwards: Boolean=false): Boolean;
 672 var
 673   idx: Integer;
 674 begin
 675   result := false;
 676   if (ggItems = nil) or not assigned(cb) then exit;
 677
 678   if backwards then
 679   begin
 680     for idx := High(ggItems) downto 0 do
 681     begin
 682       if ggItems[idx].alive and ggItems[idx].slotIsUsed then
 683       begin
 684         result := cb(@ggItems[idx]);
 685         if result then exit;
 686       end;
 687     end;
 688   end
 689   else
 690   begin
 691     for idx := 0 to High(ggItems) do
 692     begin
 693       if ggItems[idx].alive and ggItems[idx].slotIsUsed then
 694       begin
 695         result := cb(@ggItems[idx]);
 696         if result then exit;
 697       end;
 698     end;
 699   end;
 700 end;
 701
 702 function g_Items_NextAlive (startIdx: Integer): PItem;
 703 var
 704   idx: Integer;
 705 begin
 706   result := nil;
 707   if (ggItems = nil) or (startIdx >= High(ggItems)) then exit;
 708   for idx := startIdx + 1 to High(ggItems) do
 709     if ggItems[idx].alive and ggItems[idx].slotIsUsed then
 710     begin
 711       result := @ggItems[idx];
 712       exit;
 713     end;
 714 end;
 715
 716 // ////////////////////////////////////////////////////////////////////////// //
 717 procedure g_Items_EmitPickupSound (idx: Integer);
 718 var
 719   it: PItem;
 720 begin
 721   if not g_Items_ValidId(idx) then exit;
 722   it := @ggItems[idx];
 723   g_Items_EmitPickupSoundAt(idx, it.Obj.X, it.Obj.Y);
 724 end;
 725
 726 procedure g_Items_EmitPickupSoundAt (idx, x, y: Integer);
 727 var
 728   it: PItem;
 729 begin
 730   if not g_Items_ValidId(idx) then exit;
 731
 732   it := @ggItems[idx];
 733   if gSoundEffectsDF then
 734   begin
 735     if it.ItemType in [ITEM_SPHERE_BLUE, ITEM_SPHERE_WHITE, ITEM_INVUL,
 736                        ITEM_INVIS, ITEM_MEDKIT_BLACK, ITEM_JETPACK] then
 737     begin
 738       g_Sound_PlayExAt('SOUND_ITEM_GETRULEZ', x, y);
 739     end
 740     else if it.ItemType in [ITEM_WEAPON_SAW, ITEM_WEAPON_PISTOL, ITEM_WEAPON_SHOTGUN1, ITEM_WEAPON_SHOTGUN2,
 741                             ITEM_WEAPON_CHAINGUN, ITEM_WEAPON_ROCKETLAUNCHER, ITEM_WEAPON_PLASMA,
 742                             ITEM_WEAPON_BFG, ITEM_WEAPON_SUPERPULEMET, ITEM_WEAPON_FLAMETHROWER,
 743                             ITEM_AMMO_BACKPACK] then
 744     begin
 745       g_Sound_PlayExAt('SOUND_ITEM_GETWEAPON', x, y);
 746     end
 747     else
 748     begin
 749       g_Sound_PlayExAt('SOUND_ITEM_GETITEM', x, y);
 750     end;
 751   end
 752   else
 753   begin
 754     if it.ItemType in [ITEM_SPHERE_BLUE, ITEM_SPHERE_WHITE, ITEM_SUIT,
 755                        ITEM_MEDKIT_BLACK, ITEM_INVUL, ITEM_INVIS, ITEM_JETPACK] then
 756     begin
 757       g_Sound_PlayExAt('SOUND_ITEM_GETRULEZ', x, y);
 758     end
 759     else if it.ItemType in [ITEM_WEAPON_SAW, ITEM_WEAPON_PISTOL, ITEM_WEAPON_SHOTGUN1, ITEM_WEAPON_SHOTGUN2,
 760                             ITEM_WEAPON_CHAINGUN, ITEM_WEAPON_ROCKETLAUNCHER, ITEM_WEAPON_PLASMA,
 761                             ITEM_WEAPON_BFG, ITEM_WEAPON_SUPERPULEMET, ITEM_WEAPON_FLAMETHROWER] then
 762     begin
 763       g_Sound_PlayExAt('SOUND_ITEM_GETWEAPON', x, y);
 764     end
 765     else
 766     begin
 767       g_Sound_PlayExAt('SOUND_ITEM_GETITEM', x, y);
 768     end;
 769   end;
 770 end;
 771
 772
 773 procedure g_Items_AddDynLights();
 774 var
 775   f: Integer;
 776   it: PItem;
 777 begin
 778   for f := 0 to High(ggItems) do
 779   begin
 780     it := @ggItems[f];
 781     if not it.alive then continue;
 782     case it.ItemType of
 783       ITEM_KEY_RED: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 24,  1.0, 0.0, 0.0, 0.6);
 784       ITEM_KEY_GREEN: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 24,  0.0, 1.0, 0.0, 0.6);
 785       ITEM_KEY_BLUE: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 24,  0.0, 0.0, 1.0, 0.6);
 786       ITEM_ARMOR_GREEN: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 42,  0.0, 1.0, 0.0, 0.6);
 787       ITEM_ARMOR_BLUE: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 42,  0.0, 0.0, 1.0, 0.6);
 788       ITEM_JETPACK: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 32,  1.0, 1.0, 1.0, 0.6);
 789       ITEM_SPHERE_BLUE: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 32,  0.0, 1.0, 0.0, 0.6);
 790       ITEM_SPHERE_WHITE: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 32,  1.0, 1.0, 1.0, 0.6);
 791       ITEM_INVUL: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 32,  1.0, 0.0, 0.0, 0.6);
 792       ITEM_INVIS: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 32,  1.0, 1.0, 0.0, 0.6);
 793       ITEM_BOTTLE: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 16,  0.0, 0.0, 0.8, 0.6);
 794       ITEM_HELMET: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 16,  0.0, 0.8, 0.0, 0.6);
 795     end;
 796   end;
 797 end;
 798
 799
 800 end.