src/game/g_items.pas

   1 (* Copyright (C)  Doom 2D: Forever Developers
   2  *
   3  * This program is free software: you can redistribute it and/or modify
   4  * it under the terms of the GNU General Public License as published by
   5  * the Free Software Foundation, version 3 of the License ONLY.
   6  *
   7  * This program is distributed in the hope that it will be useful,
   8  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   9  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  10  * GNU General Public License for more details.
  11  *
  12  * You should have received a copy of the GNU General Public License
  13  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  14  *)
  15 {$INCLUDE ../shared/a_modes.inc}
  16 unit g_items;
  17
  18 interface
  19
  20 uses
  21   SysUtils, Classes,
  22   MAPDEF, g_phys, g_saveload;
  23
  24 const
  25   ITEM_LAST = ITEM_MAX;
  26
  27 Type
  28   PItem = ^TItem;
  29   TItem = record
  30   private
  31     //treeNode: Integer;
  32     slotIsUsed: Boolean;
  33     arrIdx: Integer; // in ggItems
  34
  35   public
  36     ItemType: Byte;
  37     Respawnable: Boolean;
  38     InitX, InitY: Integer;
  39     RespawnTime: Word;
  40     alive: Boolean;
  41     Fall: Boolean;
  42     QuietRespawn: Boolean;
  43     SpawnTrigger: Integer;
  44     Obj: TObj;
  45     dropped: Boolean; // dropped from the monster? drops should be rendered after corpses, so zombie corpse will not obscure ammo container, for example
  46     NeedSend: Boolean;
  47
  48     procedure positionChanged (); //WARNING! call this after monster position was changed, or coldet will not work right!
  49     procedure getMapBox (out x, y, w, h: Integer); inline;
  50     procedure moveBy (dx, dy: Integer); inline;
  51
  52     property used: Boolean read slotIsUsed;
  53     property myid: Integer read arrIdx;
  54   end;
  55
  56 procedure g_Items_LoadData();
  57 procedure g_Items_FreeData();
  58 procedure g_Items_Init();
  59 procedure g_Items_Free();
  60 function g_Items_Create(X, Y: Integer; ItemType: Byte;
  61            Fall, Respawnable: Boolean; AdjCoord: Boolean = False; ForcedID: Integer = -1): DWORD;
  62 procedure g_Items_SetDrop (ID: DWORD);
  63 procedure g_Items_PreUpdate();
  64 procedure g_Items_Update();
  65 procedure g_Items_Pick(ID: DWORD);
  66 procedure g_Items_Remove(ID: DWORD);
  67 procedure g_Items_SaveState (st: TStream);
  68 procedure g_Items_LoadState (st: TStream);
  69
  70 procedure g_Items_RestartRound ();
  71
  72 function g_Items_ValidId (idx: Integer): Boolean; inline;
  73 function g_Items_ByIdx (idx: Integer): PItem;
  74 function g_Items_ObjByIdx (idx: Integer): PObj;
  75
  76 procedure g_Items_EmitPickupSound (idx: Integer); // at item position
  77 procedure g_Items_EmitPickupSoundAt (idx, x, y: Integer);
  78
  79 procedure g_Items_AddDynLights();
  80
  81
  82 type
  83   TItemEachAliveCB = function (it: PItem): Boolean is nested; // return `true` to stop
  84
  85 function g_Items_ForEachAlive (cb: TItemEachAliveCB; backwards: Boolean=false): Boolean;
  86 function g_Items_NextAlive (startIdx: Integer): PItem;
  87
  88   var (* private state *)
  89     ggItems: Array of TItem = nil;
  90
  91 implementation
  92
  93   uses
  94     {$IFDEF ENABLE_GFX}
  95       g_gfx,
  96     {$ENDIF}
  97     Math,
  98     g_basic, g_sound, g_map,
  99     g_game, g_triggers, g_console, g_player, g_net, g_netmsg,
 100     e_log, g_options,
 101     g_grid, binheap, idpool, utils, xstreams
 102   ;
 103
 104 // ////////////////////////////////////////////////////////////////////////// //
 105 var
 106   freeIds: TIdPool = nil;
 107
 108
 109 // ////////////////////////////////////////////////////////////////////////// //
 110 function g_Items_ValidId (idx: Integer): Boolean; inline;
 111 begin
 112   result := false;
 113   if (idx < 0) or (idx > High(ggItems)) then exit;
 114   if not ggItems[idx].slotIsUsed then exit;
 115   result := true;
 116 end;
 117
 118
 119 function g_Items_ByIdx (idx: Integer): PItem;
 120 begin
 121   if (idx < 0) or (idx > High(ggItems)) then raise Exception.Create('g_ItemObjByIdx: invalid index');
 122   result := @ggItems[idx];
 123   if not result.slotIsUsed then raise Exception.Create('g_ItemObjByIdx: requested inexistent item');
 124 end;
 125
 126
 127 function g_Items_ObjByIdx (idx: Integer): PObj;
 128 begin
 129   if (idx < 0) or (idx > High(ggItems)) then raise Exception.Create('g_ItemObjByIdx: invalid index');
 130   if not ggItems[idx].slotIsUsed then raise Exception.Create('g_ItemObjByIdx: requested inexistent item');
 131   result := @ggItems[idx].Obj;
 132 end;
 133
 134
 135 // ////////////////////////////////////////////////////////////////////////// //
 136 procedure TItem.positionChanged ();
 137 begin
 138   NeedSend := NeedSend or (Obj.X <> Obj.oldX) or (Obj.Y <> Obj.oldY);
 139 end;
 140
 141 procedure TItem.getMapBox (out x, y, w, h: Integer); inline;
 142 begin
 143   x := Obj.X+Obj.Rect.X;
 144   y := Obj.Y+Obj.Rect.Y;
 145   w := Obj.Rect.Width;
 146   h := Obj.Rect.Height;
 147 end;
 148
 149 procedure TItem.moveBy (dx, dy: Integer); inline;
 150 begin
 151   if (dx <> 0) or (dy <> 0) then
 152   begin
 153     Obj.X += dx;
 154     Obj.Y += dy;
 155     positionChanged();
 156   end;
 157 end;
 158
 159 // ////////////////////////////////////////////////////////////////////////// //
 160 const
 161   ITEM_SIGNATURE = $4D455449; // 'ITEM'
 162
 163   ITEMSIZE: Array [ITEM_MEDKIT_SMALL..ITEM_MAX] of Array [0..1] of Byte =
 164     (((14), (15)), // MEDKIT_SMALL
 165      ((28), (19)), // MEDKIT_LARGE
 166      ((28), (19)), // MEDKIT_BLACK
 167      ((31), (16)), // ARMOR_GREEN
 168      ((31), (16)), // ARMOR_BLUE
 169      ((25), (25)), // SPHERE_BLUE
 170      ((25), (25)), // SPHERE_WHITE
 171      ((24), (47)), // SUIT
 172      ((14), (27)), // OXYGEN
 173      ((25), (25)), // INVUL
 174      ((62), (24)), // WEAPON_SAW
 175      ((63), (12)), // WEAPON_SHOTGUN1
 176      ((54), (13)), // WEAPON_SHOTGUN2
 177      ((54), (16)), // WEAPON_CHAINGUN
 178      ((62), (16)), // WEAPON_ROCKETLAUNCHER
 179      ((54), (16)), // WEAPON_PLASMA
 180      ((61), (36)), // WEAPON_BFG
 181      ((54), (16)), // WEAPON_SUPERPULEMET
 182      (( 9), (11)), // AMMO_BULLETS
 183      ((28), (16)), // AMMO_BULLETS_BOX
 184      ((15), ( 7)), // AMMO_SHELLS
 185      ((32), (12)), // AMMO_SHELLS_BOX
 186      ((12), (27)), // AMMO_ROCKET
 187      ((54), (21)), // AMMO_ROCKET_BOX
 188      ((15), (12)), // AMMO_CELL
 189      ((32), (21)), // AMMO_CELL_BIG
 190      ((22), (29)), // AMMO_BACKPACK
 191      ((16), (16)), // KEY_RED
 192      ((16), (16)), // KEY_GREEN
 193      ((16), (16)), // KEY_BLUE
 194      (( 1), ( 1)), // WEAPON_KASTET
 195      ((43), (16)), // WEAPON_PISTOL
 196      ((14), (18)), // BOTTLE
 197      ((16), (15)), // HELMET
 198      ((32), (24)), // JETPACK
 199      ((25), (25)), // INVIS
 200      ((53), (20)), // WEAPON_FLAMETHROWER
 201      ((13), (20))); // AMMO_FUELCAN
 202
 203 procedure g_Items_LoadData();
 204 begin
 205   e_WriteLog('Loading items data...', TMsgType.Notify);
 206
 207   g_Sound_CreateWADEx('SOUND_ITEM_RESPAWNITEM', GameWAD+':SOUNDS\RESPAWNITEM');
 208   g_Sound_CreateWADEx('SOUND_ITEM_GETRULEZ', GameWAD+':SOUNDS\GETRULEZ');
 209   g_Sound_CreateWADEx('SOUND_ITEM_GETWEAPON', GameWAD+':SOUNDS\GETWEAPON');
 210   g_Sound_CreateWADEx('SOUND_ITEM_GETITEM', GameWAD+':SOUNDS\GETITEM');
 211
 212   freeIds := TIdPool.Create();
 213 end;
 214
 215
 216 procedure g_Items_FreeData();
 217 begin
 218   e_WriteLog('Releasing items data...', TMsgType.Notify);
 219
 220   g_Sound_Delete('SOUND_ITEM_RESPAWNITEM');
 221   g_Sound_Delete('SOUND_ITEM_GETRULEZ');
 222   g_Sound_Delete('SOUND_ITEM_GETWEAPON');
 223   g_Sound_Delete('SOUND_ITEM_GETITEM');
 224
 225   freeIds.Free();
 226   freeIds := nil;
 227 end;
 228
 229
 230 procedure releaseItem (idx: Integer);
 231 var
 232   it: PItem;
 233 begin
 234   if (idx < 0) or (idx > High(ggItems)) then raise Exception.Create('releaseItem: invalid item id');
 235   if not freeIds.hasAlloced[LongWord(idx)] then raise Exception.Create('releaseItem: trying to release unallocated item (0)');
 236   it := @ggItems[idx];
 237   if not it.slotIsUsed then raise Exception.Create('releaseItem: trying to release unallocated item (1)');
 238   if (it.arrIdx <> idx) then raise Exception.Create('releaseItem: arrIdx inconsistency');
 239   it.slotIsUsed := false;
 240   it.alive := False;
 241   it.SpawnTrigger := -1;
 242   it.ItemType := ITEM_NONE;
 243   it.NeedSend := false;
 244   freeIds.release(LongWord(idx));
 245 end;
 246
 247
 248 procedure growItemArrayTo (newsz: Integer);
 249 var
 250   i, olen: Integer;
 251   it: PItem;
 252 begin
 253   if (newsz < Length(ggItems)) then exit;
 254   // no free slots
 255   olen := Length(ggItems);
 256   SetLength(ggItems, newsz);
 257   for i := olen to High(ggItems) do
 258   begin
 259     it := @ggItems[i];
 260     it.slotIsUsed := false;
 261     it.arrIdx := i;
 262     it.ItemType := ITEM_NONE;
 263     it.alive := false;
 264     it.SpawnTrigger := -1;
 265     it.Respawnable := false;
 266     it.NeedSend := false;
 267     //if not freeIds.hasFree[LongWord(i)] then raise Exception.Create('internal error in item idx manager');
 268   end;
 269 end;
 270
 271
 272 function allocItem (): DWORD;
 273 begin
 274   result := freeIds.alloc();
 275   if (result >= Length(ggItems)) then growItemArrayTo(Integer(result)+64);
 276   if (Integer(result) > High(ggItems)) then raise Exception.Create('allocItem: freeid list corrupted');
 277   if (ggItems[result].arrIdx <> Integer(result)) then raise Exception.Create('allocItem: arrIdx inconsistency');
 278 end;
 279
 280
 281 // it will be slow if the slot is free (we have to rebuild the heap)
 282 function wantItemSlot (slot: Integer): Integer;
 283 var
 284   olen: Integer;
 285   it: PItem;
 286 begin
 287   if (slot < 0) or (slot > $0fffffff) then raise Exception.Create('wantItemSlot: bad item slot request');
 288   // do we need to grow item storate?
 289   olen := Length(ggItems);
 290   if (slot >= olen) then growItemArrayTo(slot+64);
 291
 292   it := @ggItems[slot];
 293   if not it.slotIsUsed then
 294   begin
 295     freeIds.alloc(LongWord(slot));
 296   end
 297   else
 298   begin
 299     if not freeIds.hasAlloced[slot] then raise Exception.Create('wantItemSlot: internal error in item idx manager');
 300   end;
 301   it.slotIsUsed := false;
 302
 303   result := slot;
 304 end;
 305
 306
 307 // ////////////////////////////////////////////////////////////////////////// //
 308 procedure g_Items_Init ();
 309 begin
 310 end;
 311
 312
 313 procedure g_Items_Free ();
 314 begin
 315   if (ggItems <> nil) then
 316     ggItems := nil;
 317   freeIds.clear();
 318 end;
 319
 320
 321 function g_Items_Create (X, Y: Integer; ItemType: Byte;
 322            Fall, Respawnable: Boolean; AdjCoord: Boolean = False; ForcedID: Integer = -1): DWORD;
 323 var
 324   find_id: DWORD;
 325   it: PItem;
 326 begin
 327   if ForcedID < 0 then find_id := allocItem() else find_id := wantItemSlot(ForcedID);
 328
 329   //{$IF DEFINED(D2F_DEBUG)}e_WriteLog(Format('allocated item #%d', [Integer(find_id)]), MSG_NOTIFY);{$ENDIF}
 330
 331   it := @ggItems[find_id];
 332
 333   if (it.arrIdx <> Integer(find_id)) then raise Exception.Create('g_Items_Create: arrIdx inconsistency');
 334   //it.arrIdx := find_id;
 335   it.slotIsUsed := true;
 336
 337   it.ItemType := ItemType;
 338   it.Respawnable := Respawnable;
 339   it.InitX := X;
 340   it.InitY := Y;
 341   it.RespawnTime := 0;
 342   it.Fall := Fall;
 343   it.alive := True;
 344   it.QuietRespawn := False;
 345   it.dropped := false;
 346   it.NeedSend := false;
 347
 348   g_Obj_Init(@it.Obj);
 349   it.Obj.X := X;
 350   it.Obj.Y := Y;
 351   it.Obj.Rect.Width := ITEMSIZE[ItemType][0];
 352   it.Obj.Rect.Height := ITEMSIZE[ItemType][1];
 353
 354   it.SpawnTrigger := -1;
 355
 356   // Êîîðäèíàòû îòíîñèòåëüíî öåíòðà íèæíåãî ðåáðà
 357   if AdjCoord then
 358   begin
 359     with it^ do
 360     begin
 361       Obj.X := X - (Obj.Rect.Width div 2);
 362       Obj.Y := Y - Obj.Rect.Height;
 363       InitX := Obj.X;
 364       InitY := Obj.Y;
 365     end;
 366   end;
 367
 368   it.Obj.oldX := it.Obj.X;
 369   it.Obj.oldY := it.Obj.Y;
 370
 371   it.positionChanged();
 372
 373   result := find_id;
 374 end;
 375
 376 procedure g_Items_PreUpdate ();
 377 var
 378   i: Integer;
 379 begin
 380   if (ggItems = nil) then Exit;
 381   for i := 0 to High(ggItems) do
 382     if (ggItems[i].ItemType <> ITEM_NONE) and ggItems[i].slotIsUsed then
 383     begin
 384       ggItems[i].Obj.oldX := ggItems[i].Obj.X;
 385       ggItems[i].Obj.oldY := ggItems[i].Obj.Y;
 386     end;
 387 end;
 388
 389 procedure g_Items_Update ();
 390 var
 391   i, j, k: Integer;
 392   m, ItemRespawnTime: Word;
 393   r, nxt: Boolean;
 394 begin
 395   if (ggItems = nil) then exit;
 396
 397   // respawn items in 15 seconds regardless of settings during warmup
 398   ItemRespawnTime := IfThen(gLMSRespawn = LMS_RESPAWN_NONE, gGameSettings.ItemRespawnTime, 15);
 399
 400   for i := 0 to High(ggItems) do
 401   begin
 402     if (ggItems[i].ItemType = ITEM_NONE) then continue;
 403     if not ggItems[i].slotIsUsed then continue; // just in case
 404
 405     with ggItems[i] do
 406     begin
 407       nxt := False;
 408
 409       if alive then
 410       begin
 411         if Fall then
 412         begin
 413           m := g_Obj_Move(@Obj, True, True);
 414           positionChanged(); // this updates spatial accelerators
 415
 416           // Ñîïðîòèâëåíèå âîçäóõà
 417           if gTime mod (GAME_TICK*2) = 0 then Obj.Vel.X := z_dec(Obj.Vel.X, 1);
 418
 419           // Åñëè âûïàë çà êàðòó
 420           if WordBool(m and MOVE_FALLOUT) then
 421           begin
 422             if SpawnTrigger = -1 then
 423             begin
 424               g_Items_Pick(i);
 425             end
 426             else
 427             begin
 428               g_Items_Remove(i);
 429               if g_Game_IsServer and g_Game_IsNet then MH_SEND_ItemDestroy(True, i);
 430             end;
 431             continue;
 432           end;
 433         end;
 434
 435         // Åñëè èãðîêè ïîáëèçîñòè
 436         if (gPlayers <> nil) then
 437         begin
 438           j := Random(Length(gPlayers))-1;
 439
 440           for k := 0 to High(gPlayers) do
 441           begin
 442             Inc(j);
 443             if j > High(gPlayers) then j := 0;
 444
 445             if (gPlayers[j] <> nil) and gPlayers[j].alive and g_Obj_Collide(@gPlayers[j].Obj, @Obj) then
 446             begin
 447               if g_Game_IsClient then continue;
 448
 449               if not gPlayers[j].PickItem(ItemType, Respawnable, r) then continue;
 450
 451               if g_Game_IsNet then MH_SEND_PlayerStats(gPlayers[j].UID);
 452
 453               {
 454                 Doom 2D: Original:
 455                 1. I_NONE,I_CLIP,I_SHEL,I_ROCKET,I_CELL,I_AMMO,I_SBOX,I_RBOX,I_CELP,I_BPACK,I_CSAW,I_SGUN,I_SGUN2,I_MGUN,I_LAUN,I_PLAS,I_BFG,I_GUN2
 456                 +2. I_MEGA,I_INVL,I_SUPER
 457                 3. I_STIM,I_MEDI,I_ARM1,I_ARM2,I_AQUA,I_KEYR,I_KEYG,I_KEYB,I_SUIT,I_RTORCH,I_GTORCH,I_BTORCH,I_GOR1,I_FCAN
 458               }
 459               g_Items_EmitPickupSoundAt(i, gPlayers[j].Obj.X, gPlayers[j].Obj.Y);
 460
 461               // Íàäî óáðàòü ñ êàðòû, åñëè ýòî íå êëþ÷, êîòîðûì íóæíî ïîäåëèòüñÿ ñ äðóãèì èãðîêîì
 462               if r then
 463               begin
 464                 if not (Respawnable and (ItemRespawnTime > 0)) then
 465                   g_Items_Remove(i)
 466                 else
 467                   g_Items_Pick(i);
 468                 if g_Game_IsNet then MH_SEND_ItemDestroy(False, i);
 469                 nxt := True;
 470                 break;
 471               end;
 472             end;
 473           end;
 474         end;
 475
 476         if nxt then continue;
 477       end;
 478
 479       if Respawnable and g_Game_IsServer then
 480       begin
 481         DecMin(RespawnTime, 0);
 482         if (RespawnTime = 0) and (not alive) then
 483         begin
 484           if not QuietRespawn then g_Sound_PlayExAt('SOUND_ITEM_RESPAWNITEM', InitX, InitY);
 485           {$IFDEF ENABLE_GFX}
 486             g_GFX_QueueEffect(
 487               R_GFX_ITEM_RESPAWN,
 488               InitX + (Obj.Rect.Width div 2) - 16,
 489               InitY + (Obj.Rect.Height div 2) - 16
 490             );
 491           {$ENDIF}
 492           Obj.oldX := InitX;
 493           Obj.oldY := InitY;
 494           Obj.X := InitX;
 495           Obj.Y := InitY;
 496           Obj.Vel.X := 0;
 497           Obj.Vel.Y := 0;
 498           Obj.Accel.X := 0;
 499           Obj.Accel.Y := 0;
 500           positionChanged(); // this updates spatial accelerators
 501
 502           alive := true;
 503
 504           if g_Game_IsNet then MH_SEND_ItemSpawn(QuietRespawn, i);
 505           QuietRespawn := false;
 506         end;
 507       end;
 508     end;
 509   end;
 510 end;
 511
 512 procedure g_Items_SetDrop (ID: DWORD);
 513 begin
 514   if (ID < Length(ggItems)) then
 515   begin
 516     ggItems[ID].dropped := true;
 517   end;
 518 end;
 519
 520
 521 procedure g_Items_Pick (ID: DWORD);
 522 begin
 523   if (ID < Length(ggItems)) then
 524   begin
 525     ggItems[ID].Obj.oldX := ggItems[ID].Obj.X;
 526     ggItems[ID].Obj.oldY := ggItems[ID].Obj.Y;
 527     ggItems[ID].alive := false;
 528     ggItems[ID].RespawnTime := IfThen(gLMSRespawn = LMS_RESPAWN_NONE, gGameSettings.ItemRespawnTime, 15) * 36;
 529   end;
 530 end;
 531
 532
 533 procedure g_Items_Remove (ID: DWORD);
 534 var
 535   it: PItem;
 536   trig: Integer;
 537 begin
 538   if not g_Items_ValidId(ID) then
 539   begin
 540     //writeln('g_Items_Remove: invalid item id: ', ID);
 541     raise Exception.Create('g_Items_Remove: invalid item id');
 542     //exit;
 543   end;
 544
 545   it := @ggItems[ID];
 546   if (it.arrIdx <> Integer(ID)) then raise Exception.Create('g_Items_Remove: arrIdx desync');
 547
 548   it.Obj.oldX := it.Obj.X;
 549   it.Obj.oldY := it.Obj.Y;
 550   trig := it.SpawnTrigger;
 551
 552   releaseItem(ID);
 553
 554   if (trig > -1) then g_Triggers_DecreaseSpawner(trig);
 555 end;
 556
 557
 558 procedure g_Items_SaveState (st: TStream);
 559 var
 560   count, i: Integer;
 561   tt: Byte;
 562 begin
 563   // Ñ÷èòàåì êîëè÷åñòâî ñóùåñòâóþùèõ ïðåäìåòîâ
 564   count := 0;
 565   for i := 0 to High(ggItems) do if (ggItems[i].ItemType <> ITEM_NONE) and (ggItems[i].slotIsUsed) then Inc(count);
 566
 567   // Êîëè÷åñòâî ïðåäìåòîâ
 568   utils.writeInt(st, LongInt(count));
 569   if (count = 0) then exit;
 570
 571   for i := 0 to High(ggItems) do
 572   begin
 573     if (ggItems[i].ItemType <> ITEM_NONE) and (ggItems[i].slotIsUsed) then
 574     begin
 575       // Ñèãíàòóðà ïðåäìåòà
 576       utils.writeSign(st, 'ITEM');
 577       utils.writeInt(st, Byte(0));
 578       // Òèï ïðåäìåòà
 579       tt := ggItems[i].ItemType;
 580       if ggItems[i].dropped then tt := tt or $80;
 581       utils.writeInt(st, Byte(tt));
 582       // Åñòü ëè ðåñïàóí
 583       utils.writeBool(st, ggItems[i].Respawnable);
 584       // Êîîðäèíàòû ðåñïóíà
 585       utils.writeInt(st, LongInt(ggItems[i].InitX));
 586       utils.writeInt(st, LongInt(ggItems[i].InitY));
 587       // Âðåìÿ äî ðåñïàóíà
 588       utils.writeInt(st, Word(ggItems[i].RespawnTime));
 589       // Ñóùåñòâóåò ëè ýòîò ïðåäìåò
 590       utils.writeBool(st, ggItems[i].alive);
 591       // Ìîæåò ëè îí ïàäàòü
 592       utils.writeBool(st, ggItems[i].Fall);
 593       // Èíäåêñ òðèããåðà, ñîçäàâøåãî ïðåäìåò
 594       utils.writeInt(st, LongInt(ggItems[i].SpawnTrigger));
 595       // Îáúåêò ïðåäìåòà
 596       Obj_SaveState(st, @ggItems[i].Obj);
 597     end;
 598   end;
 599 end;
 600
 601
 602 procedure g_Items_LoadState (st: TStream);
 603 var
 604   count, i, a: Integer;
 605   b: Byte;
 606 begin
 607   assert(st <> nil);
 608
 609   g_Items_Free();
 610
 611   // Êîëè÷åñòâî ïðåäìåòîâ
 612   count := utils.readLongInt(st);
 613   if (count = 0) then exit;
 614   if (count < 0) or (count > 1024*1024) then raise XStreamError.Create('invalid number of items');
 615
 616   for a := 0 to count-1 do
 617   begin
 618     // Ñèãíàòóðà ïðåäìåòà
 619     if not utils.checkSign(st, 'ITEM') then raise XStreamError.Create('invalid item signature');
 620     if (utils.readByte(st) <> 0) then raise XStreamError.Create('invalid item version');
 621     // Òèï ïðåäìåòà
 622     b := utils.readByte(st); // bit7=1: monster drop
 623     // Ñîçäàåì ïðåäìåò
 624     i := g_Items_Create(0, 0, b and $7F, False, False);
 625     if ((b and $80) <> 0) then g_Items_SetDrop(i);
 626     // Åñòü ëè ðåñïàóí
 627     ggItems[i].Respawnable := utils.readBool(st);
 628     // Êîîðäèíàòû ðåñïóíà
 629     ggItems[i].InitX := utils.readLongInt(st);
 630     ggItems[i].InitY := utils.readLongInt(st);
 631     // Âðåìÿ äî ðåñïàóíà
 632     ggItems[i].RespawnTime := utils.readWord(st);
 633     // Ñóùåñòâóåò ëè ýòîò ïðåäìåò
 634     ggItems[i].alive := utils.readBool(st);
 635     // Ìîæåò ëè îí ïàäàòü
 636     ggItems[i].Fall := utils.readBool(st);
 637     // Èíäåêñ òðèããåðà, ñîçäàâøåãî ïðåäìåò
 638     ggItems[i].SpawnTrigger := utils.readLongInt(st);
 639     // Îáúåêò ïðåäìåòà
 640     Obj_LoadState(@ggItems[i].Obj, st);
 641   end;
 642 end;
 643
 644
 645 procedure g_Items_RestartRound ();
 646 var
 647   i: Integer;
 648   it: PItem;
 649 begin
 650   for i := 0 to High(ggItems) do
 651   begin
 652     it := @ggItems[i];
 653     it.Obj.oldX := it.Obj.X;
 654     it.Obj.oldY := it.Obj.Y;
 655     if not it.slotIsUsed then continue;
 656     if it.Respawnable and (it.ItemType <> ITEM_NONE) then
 657     begin
 658       it.QuietRespawn := True;
 659       it.RespawnTime := 0;
 660     end
 661     else
 662     begin
 663       g_Items_Remove(i);
 664       if g_Game_IsNet then MH_SEND_ItemDestroy(True, i);
 665     end;
 666   end;
 667 end;
 668
 669
 670 function g_Items_ForEachAlive (cb: TItemEachAliveCB; backwards: Boolean=false): Boolean;
 671 var
 672   idx: Integer;
 673 begin
 674   result := false;
 675   if (ggItems = nil) or not assigned(cb) then exit;
 676
 677   if backwards then
 678   begin
 679     for idx := High(ggItems) downto 0 do
 680     begin
 681       if ggItems[idx].alive and ggItems[idx].slotIsUsed then
 682       begin
 683         result := cb(@ggItems[idx]);
 684         if result then exit;
 685       end;
 686     end;
 687   end
 688   else
 689   begin
 690     for idx := 0 to High(ggItems) do
 691     begin
 692       if ggItems[idx].alive and ggItems[idx].slotIsUsed then
 693       begin
 694         result := cb(@ggItems[idx]);
 695         if result then exit;
 696       end;
 697     end;
 698   end;
 699 end;
 700
 701 function g_Items_NextAlive (startIdx: Integer): PItem;
 702 var
 703   idx: Integer;
 704 begin
 705   result := nil;
 706   if (ggItems = nil) or (startIdx >= High(ggItems)) then exit;
 707   for idx := startIdx + 1 to High(ggItems) do
 708     if ggItems[idx].alive and ggItems[idx].slotIsUsed then
 709     begin
 710       result := @ggItems[idx];
 711       exit;
 712     end;
 713 end;
 714
 715 // ////////////////////////////////////////////////////////////////////////// //
 716 procedure g_Items_EmitPickupSound (idx: Integer);
 717 var
 718   it: PItem;
 719 begin
 720   if not g_Items_ValidId(idx) then exit;
 721   it := @ggItems[idx];
 722   g_Items_EmitPickupSoundAt(idx, it.Obj.X, it.Obj.Y);
 723 end;
 724
 725 procedure g_Items_EmitPickupSoundAt (idx, x, y: Integer);
 726 var
 727   it: PItem;
 728 begin
 729   if not g_Items_ValidId(idx) then exit;
 730
 731   it := @ggItems[idx];
 732   if gSoundEffectsDF then
 733   begin
 734     if it.ItemType in [ITEM_SPHERE_BLUE, ITEM_SPHERE_WHITE, ITEM_INVUL,
 735                        ITEM_INVIS, ITEM_MEDKIT_BLACK, ITEM_JETPACK] then
 736     begin
 737       g_Sound_PlayExAt('SOUND_ITEM_GETRULEZ', x, y);
 738     end
 739     else if it.ItemType in [ITEM_WEAPON_SAW, ITEM_WEAPON_PISTOL, ITEM_WEAPON_SHOTGUN1, ITEM_WEAPON_SHOTGUN2,
 740                             ITEM_WEAPON_CHAINGUN, ITEM_WEAPON_ROCKETLAUNCHER, ITEM_WEAPON_PLASMA,
 741                             ITEM_WEAPON_BFG, ITEM_WEAPON_SUPERPULEMET, ITEM_WEAPON_FLAMETHROWER,
 742                             ITEM_AMMO_BACKPACK] then
 743     begin
 744       g_Sound_PlayExAt('SOUND_ITEM_GETWEAPON', x, y);
 745     end
 746     else
 747     begin
 748       g_Sound_PlayExAt('SOUND_ITEM_GETITEM', x, y);
 749     end;
 750   end
 751   else
 752   begin
 753     if it.ItemType in [ITEM_SPHERE_BLUE, ITEM_SPHERE_WHITE, ITEM_SUIT,
 754                        ITEM_MEDKIT_BLACK, ITEM_INVUL, ITEM_INVIS, ITEM_JETPACK] then
 755     begin
 756       g_Sound_PlayExAt('SOUND_ITEM_GETRULEZ', x, y);
 757     end
 758     else if it.ItemType in [ITEM_WEAPON_SAW, ITEM_WEAPON_PISTOL, ITEM_WEAPON_SHOTGUN1, ITEM_WEAPON_SHOTGUN2,
 759                             ITEM_WEAPON_CHAINGUN, ITEM_WEAPON_ROCKETLAUNCHER, ITEM_WEAPON_PLASMA,
 760                             ITEM_WEAPON_BFG, ITEM_WEAPON_SUPERPULEMET, ITEM_WEAPON_FLAMETHROWER] then
 761     begin
 762       g_Sound_PlayExAt('SOUND_ITEM_GETWEAPON', x, y);
 763     end
 764     else
 765     begin
 766       g_Sound_PlayExAt('SOUND_ITEM_GETITEM', x, y);
 767     end;
 768   end;
 769 end;
 770
 771
 772 procedure g_Items_AddDynLights();
 773 var
 774   f: Integer;
 775   it: PItem;
 776 begin
 777   for f := 0 to High(ggItems) do
 778   begin
 779     it := @ggItems[f];
 780     if not it.alive then continue;
 781     case it.ItemType of
 782       ITEM_KEY_RED: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 24,  1.0, 0.0, 0.0, 0.6);
 783       ITEM_KEY_GREEN: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 24,  0.0, 1.0, 0.0, 0.6);
 784       ITEM_KEY_BLUE: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 24,  0.0, 0.0, 1.0, 0.6);
 785       ITEM_ARMOR_GREEN: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 42,  0.0, 1.0, 0.0, 0.6);
 786       ITEM_ARMOR_BLUE: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 42,  0.0, 0.0, 1.0, 0.6);
 787       ITEM_JETPACK: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 32,  1.0, 1.0, 1.0, 0.6);
 788       ITEM_SPHERE_BLUE: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 32,  0.0, 1.0, 0.0, 0.6);
 789       ITEM_SPHERE_WHITE: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 32,  1.0, 1.0, 1.0, 0.6);
 790       ITEM_INVUL: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 32,  1.0, 0.0, 0.0, 0.6);
 791       ITEM_INVIS: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 32,  1.0, 1.0, 0.0, 0.6);
 792       ITEM_BOTTLE: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 16,  0.0, 0.0, 0.8, 0.6);
 793       ITEM_HELMET: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 16,  0.0, 0.8, 0.0, 0.6);
 794     end;
 795   end;
 796 end;
 797
 798
 799 end.