DEADSOFTWARE

GIT / REPO / FRED-BOY
Projects / d2df-sdl.git / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
more code for tracing and other shit; NOTHING IS WORKING YET
[d2df-sdl.git] / src / game / g_console.pas
1 (* Copyright (C) DooM 2D:Forever Developers
2 *
3 * This program is free software: you can redistribute it and/or modify
4 * it under the terms of the GNU General Public License as published by
5 * the Free Software Foundation, either version 3 of the License, or
6 * (at your option) any later version.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 *)
16 {$INCLUDE ../shared/a_modes.inc}
17 unit g_console;
18
19 interface
20
21 procedure g_Console_Init();
22 procedure g_Console_Update();
23 procedure g_Console_Draw();
24 procedure g_Console_Switch();
25 procedure g_Console_Char(C: Char);
26 procedure g_Console_Control(K: Word);
27 procedure g_Console_Process(L: String; Quiet: Boolean = False);
28 procedure g_Console_Add(L: String; Show: Boolean = False);
29 procedure g_Console_Clear();
30 function g_Console_CommandBlacklisted(C: String): Boolean;
31
32 procedure g_Console_Chat_Switch(Team: Boolean = False);
33
34 var
35 gConsoleShow: Boolean; // True - êîíñîëü îòêðûòà èëè îòêðûâàåòñÿ
36 gChatShow: Boolean;
37 gChatTeam: Boolean = False;
38 gAllowConsoleMessages: Boolean = True;
39 gChatEnter: Boolean = True;
40 gJustChatted: Boolean = False; // ÷òîáû àäìèí â èíòåðå ÷àòÿñü íå ïðîìàòûâàë ñòàòèñòèêó
41
42 implementation
43
44 uses
45 g_textures, g_main, e_graphics, e_input, g_game,
46 SysUtils, g_basic, g_options, wadreader, Math,
47 g_menu, g_language, g_net, g_netmsg, e_log, conbuf;
48
49 type
50 TCmdProc = procedure (P: SArray);
51
52 TCommand = record
53 Cmd: String;
54 Proc: TCmdProc;
55 help: String;
56 hidden: Boolean;
57 end;
58
59 TAlias = record
60 Name: String;
61 Commands: SArray;
62 end;
63
64 const
65 Step = 32;
66 Alpha = 25;
67 MsgTime = 144;
68 MaxScriptRecursion = 16;
69
70 DEBUG_STRING = 'DEBUG MODE';
71
72 var
73 ID: DWORD;
74 RecursionDepth: Word = 0;
75 RecursionLimitHit: Boolean = False;
76 Cons_Y: SmallInt;
77 Cons_Shown: Boolean; // Ðèñîâàòü ëè êîíñîëü?
78 Line: String;
79 CPos: Word;
80 //ConsoleHistory: SArray;
81 CommandHistory: SArray;
82 Whitelist: SArray;
83 Commands: Array of TCommand;
84 Aliases: Array of TAlias;
85 CmdIndex: Word;
86 conSkipLines: Integer = 0;
87 MsgArray: Array [0..4] of record
88 Msg: String;
89 Time: Word;
90 end;
91
92 function GetStrACmd(var Str: String): String;
93 var
94 a: Integer;
95 begin
96 Result := '';
97 for a := 1 to Length(Str) do
98 if (a = Length(Str)) or (Str[a+1] = ';') then
99 begin
100 Result := Copy(Str, 1, a);
101 Delete(Str, 1, a+1);
102 Str := Trim(Str);
103 Exit;
104 end;
105 end;
106
107 function ParseAlias(Str: String): SArray;
108 begin
109 Result := nil;
110
111 Str := Trim(Str);
112
113 if Str = '' then
114 Exit;
115
116 while Str <> '' do
117 begin
118 SetLength(Result, Length(Result)+1);
119 Result[High(Result)] := GetStrACmd(Str);
120 end;
121 end;
122
123 procedure ConsoleCommands(P: SArray);
124 var
125 Cmd, s: String;
126 a, b: Integer;
127 F: TextFile;
128 begin
129 Cmd := LowerCase(P[0]);
130 s := '';
131
132 if Cmd = 'clear' then
133 begin
134 //ConsoleHistory := nil;
135 cbufClear();
136 conSkipLines := 0;
137
138 for a := 0 to High(MsgArray) do
139 with MsgArray[a] do
140 begin
141 Msg := '';
142 Time := 0;
143 end;
144 end;
145
146 if Cmd = 'clearhistory' then
147 CommandHistory := nil;
148
149 if Cmd = 'showhistory' then
150 if CommandHistory <> nil then
151 begin
152 g_Console_Add('');
153 for a := 0 to High(CommandHistory) do
154 g_Console_Add(' '+CommandHistory[a]);
155 end;
156
157 if Cmd = 'commands' then
158 begin
159 g_Console_Add('');
160 g_Console_Add('Commands list:');
161 for a := High(Commands) downto 0 do
162 begin
163 if (Length(Commands[a].help) > 0) then
164 begin
165 g_Console_Add(' '+Commands[a].Cmd+' -- '+Commands[a].help);
166 end
167 else
168 begin
169 g_Console_Add(' '+Commands[a].Cmd);
170 end;
171 end;
172 end;
173
174 if Cmd = 'time' then
175 g_Console_Add(TimeToStr(Now), True);
176
177 if Cmd = 'date' then
178 g_Console_Add(DateToStr(Now), True);
179
180 if Cmd = 'echo' then
181 if Length(P) > 1 then
182 begin
183 if P[1] = 'ololo' then
184 gCheats := True
185 else
186 begin
187 s := '';
188 for a := 1 to High(P) do
189 s := s + P[a] + ' ';
190 g_Console_Add(b_Text_Format(s), True);
191 end;
192 end
193 else
194 g_Console_Add('');
195
196 if Cmd = 'dump' then
197 begin
198 (*
199 if ConsoleHistory <> nil then
200 begin
201 if Length(P) > 1 then
202 s := P[1]
203 else
204 s := GameDir+'/console.txt';
205
206 {$I-}
207 AssignFile(F, s);
208 Rewrite(F);
209 if IOResult <> 0 then
210 begin
211 g_Console_Add(Format(_lc[I_CONSOLE_ERROR_WRITE], [s]));
212 CloseFile(F);
213 Exit;
214 end;
215
216 for a := 0 to High(ConsoleHistory) do
217 WriteLn(F, ConsoleHistory[a]);
218
219 CloseFile(F);
220 g_Console_Add(Format(_lc[I_CONSOLE_DUMPED], [s]));
221 {$I+}
222 end;
223 *)
224 end;
225
226 if Cmd = 'exec' then
227 begin
228 // exec <filename>
229 if Length(P) > 1 then
230 begin
231 s := GameDir+'/'+P[1];
232
233 {$I-}
234 AssignFile(F, s);
235 Reset(F);
236 if IOResult <> 0 then
237 begin
238 g_Console_Add(Format(_lc[I_CONSOLE_ERROR_READ], [s]));
239 CloseFile(F);
240 Exit;
241 end;
242 g_Console_Add(Format(_lc[I_CONSOLE_EXEC], [s]));
243
244 while not EOF(F) do
245 begin
246 ReadLn(F, s);
247 if IOResult <> 0 then
248 begin
249 g_Console_Add(Format(_lc[I_CONSOLE_ERROR_READ], [s]));
250 CloseFile(F);
251 Exit;
252 end;
253 if Pos('#', s) <> 1 then // script comment
254 begin
255 // prevents endless loops
256 Inc(RecursionDepth);
257 RecursionLimitHit := (RecursionDepth > MaxScriptRecursion) or RecursionLimitHit;
258 if not RecursionLimitHit then
259 g_Console_Process(s, True);
260 Dec(RecursionDepth);
261 end;
262 end;
263 if (RecursionDepth = 0) and RecursionLimitHit then
264 begin
265 g_Console_Add(Format(_lc[I_CONSOLE_ERROR_CALL], [s]));
266 RecursionLimitHit := False;
267 end;
268
269 CloseFile(F);
270 {$I+}
271 end
272 else
273 g_Console_Add('exec <script file>');
274 end;
275
276 if Cmd = 'alias' then
277 begin
278 // alias [alias_name] [commands]
279 if Length(P) > 1 then
280 begin
281 for a := 0 to High(Aliases) do
282 if Aliases[a].Name = P[1] then
283 begin
284 if Length(P) > 2 then
285 Aliases[a].Commands := ParseAlias(P[2])
286 else
287 for b := 0 to High(Aliases[a].Commands) do
288 g_Console_Add(Aliases[a].Commands[b]);
289 Exit;
290 end;
291 SetLength(Aliases, Length(Aliases)+1);
292 a := High(Aliases);
293 Aliases[a].Name := P[1];
294 if Length(P) > 2 then
295 Aliases[a].Commands := ParseAlias(P[2])
296 else
297 for b := 0 to High(Aliases[a].Commands) do
298 g_Console_Add(Aliases[a].Commands[b]);
299 end else
300 for a := 0 to High(Aliases) do
301 if Aliases[a].Commands <> nil then
302 g_Console_Add(Aliases[a].Name);
303 end;
304
305 if Cmd = 'call' then
306 begin
307 // call <alias_name>
308 if Length(P) > 1 then
309 begin
310 if Aliases = nil then
311 Exit;
312 for a := 0 to High(Aliases) do
313 if Aliases[a].Name = P[1] then
314 begin
315 if Aliases[a].Commands <> nil then
316 begin
317 // with this system proper endless loop detection seems either impossible
318 // or very dirty to implement, so let's have this instead
319 // prevents endless loops
320 for b := 0 to High(Aliases[a].Commands) do
321 begin
322 Inc(RecursionDepth);
323 RecursionLimitHit := (RecursionDepth > MaxScriptRecursion) or RecursionLimitHit;
324 if not RecursionLimitHit then
325 g_Console_Process(Aliases[a].Commands[b], True);
326 Dec(RecursionDepth);
327 end;
328 if (RecursionDepth = 0) and RecursionLimitHit then
329 begin
330 g_Console_Add(Format(_lc[I_CONSOLE_ERROR_CALL], [s]));
331 RecursionLimitHit := False;
332 end;
333 end;
334 Exit;
335 end;
336 end
337 else
338 g_Console_Add('call <alias name>');
339 end;
340 end;
341
342 procedure WhitelistCommand(Cmd: string);
343 var
344 a: Integer;
345 begin
346 SetLength(Whitelist, Length(Whitelist)+1);
347 a := High(Whitelist);
348 Whitelist[a] := LowerCase(Cmd);
349 end;
350
351 procedure AddCommand(Cmd: String; Proc: TCmdProc; ahelp: String=''; ahidden: Boolean=false);
352 var
353 a: Integer;
354 begin
355 SetLength(Commands, Length(Commands)+1);
356 a := High(Commands);
357 Commands[a].Cmd := LowerCase(Cmd);
358 Commands[a].Proc := Proc;
359 Commands[a].hidden := ahidden;
360 Commands[a].help := ahelp;
361 end;
362
363 procedure g_Console_Init();
364 var
365 a: Integer;
366 begin
367 g_Texture_CreateWAD(ID, GameWAD+':TEXTURES\CONSOLE');
368 Cons_Y := -(gScreenHeight div 2);
369 gConsoleShow := False;
370 gChatShow := False;
371 Cons_Shown := False;
372 CPos := 1;
373
374 for a := 0 to High(MsgArray) do
375 with MsgArray[a] do
376 begin
377 Msg := '';
378 Time := 0;
379 end;
380
381 AddCommand('clear', ConsoleCommands, 'clear console');
382 AddCommand('clearhistory', ConsoleCommands);
383 AddCommand('showhistory', ConsoleCommands);
384 AddCommand('commands', ConsoleCommands);
385 AddCommand('time', ConsoleCommands);
386 AddCommand('date', ConsoleCommands);
387 AddCommand('echo', ConsoleCommands);
388 AddCommand('dump', ConsoleCommands);
389 AddCommand('exec', ConsoleCommands);
390 AddCommand('alias', ConsoleCommands);
391 AddCommand('call', ConsoleCommands);
392
393 AddCommand('d_window', DebugCommands);
394 AddCommand('d_sounds', DebugCommands);
395 AddCommand('d_frames', DebugCommands);
396 AddCommand('d_winmsg', DebugCommands);
397 AddCommand('d_monoff', DebugCommands);
398 AddCommand('d_botoff', DebugCommands);
399 AddCommand('d_monster', DebugCommands);
400 AddCommand('d_health', DebugCommands);
401 AddCommand('d_player', DebugCommands);
402 AddCommand('d_joy', DebugCommands);
403
404 AddCommand('pf_draw_frame', ProfilerCommands, 'draw frame rendering profiles');
405 //AddCommand('pf_update_frame', ProfilerCommands);
406 AddCommand('pf_coldet', ProfilerCommands, 'draw collision detection profiles');
407 AddCommand('pf_los', ProfilerCommands, 'draw monster LOS profiles');
408 AddCommand('r_sq_draw', ProfilerCommands, 'accelerated spatial queries in rendering');
409 AddCommand('cd_sq_enabled', ProfilerCommands, 'accelerated spatial queries in map coldet');
410 AddCommand('mon_sq_enabled', ProfilerCommands, 'use accelerated spatial queries for monsters');
411 AddCommand('wtrace_sq_enabled', ProfilerCommands, 'use accelerated weapon hitscan trace');
412
413 AddCommand('pr_enabled', ProfilerCommands, 'enable/disable particles');
414 AddCommand('pr_phys_enabled', ProfilerCommands, 'enable/disable particle physics');
415 AddCommand('los_enabled', ProfilerCommands, 'enable/disable LOS calculations');
416
417 AddCommand('p1_name', GameCVars);
418 AddCommand('p2_name', GameCVars);
419 AddCommand('p1_color', GameCVars);
420 AddCommand('p2_color', GameCVars);
421 AddCommand('r_showfps', GameCVars);
422 AddCommand('r_showtime', GameCVars);
423 AddCommand('r_showscore', GameCVars);
424 AddCommand('r_showlives', GameCVars);
425 AddCommand('r_showstat', GameCVars);
426 AddCommand('r_showkillmsg', GameCVars);
427 AddCommand('r_showspect', GameCVars);
428 AddCommand('r_showping', GameCVars);
429 AddCommand('g_gamemode', GameCVars);
430 AddCommand('g_friendlyfire', GameCVars);
431 AddCommand('g_weaponstay', GameCVars);
432 AddCommand('g_allow_exit', GameCVars);
433 AddCommand('g_allow_monsters', GameCVars);
434 AddCommand('g_bot_vsmonsters', GameCVars);
435 AddCommand('g_bot_vsplayers', GameCVars);
436 AddCommand('g_scorelimit', GameCVars);
437 AddCommand('g_timelimit', GameCVars);
438 AddCommand('g_maxlives', GameCVars);
439 AddCommand('g_warmuptime', GameCVars);
440 AddCommand('net_interp', GameCVars);
441 AddCommand('net_forceplayerupdate', GameCVars);
442 AddCommand('net_predictself', GameCVars);
443 AddCommand('sv_name', GameCVars);
444 AddCommand('sv_passwd', GameCVars);
445 AddCommand('sv_maxplrs', GameCVars);
446 AddCommand('sv_public', GameCVars);
447 AddCommand('sv_intertime', GameCVars);
448
449 AddCommand('quit', GameCommands);
450 AddCommand('exit', GameCommands);
451 AddCommand('pause', GameCommands);
452 AddCommand('endgame', GameCommands);
453 AddCommand('restart', GameCommands);
454 AddCommand('addbot', GameCommands);
455 AddCommand('bot_add', GameCommands);
456 AddCommand('bot_addlist', GameCommands);
457 AddCommand('bot_addred', GameCommands);
458 AddCommand('bot_addblue', GameCommands);
459 AddCommand('bot_removeall', GameCommands);
460 AddCommand('chat', GameCommands);
461 AddCommand('teamchat', GameCommands);
462 AddCommand('game', GameCommands);
463 AddCommand('host', GameCommands);
464 AddCommand('map', GameCommands);
465 AddCommand('nextmap', GameCommands);
466 AddCommand('endmap', GameCommands);
467 AddCommand('goodbye', GameCommands);
468 AddCommand('suicide', GameCommands);
469 AddCommand('spectate', GameCommands);
470 AddCommand('ready', GameCommands);
471 AddCommand('kick', GameCommands);
472 AddCommand('kick_id', GameCommands);
473 AddCommand('ban', GameCommands);
474 AddCommand('permban', GameCommands);
475 AddCommand('ban_id', GameCommands);
476 AddCommand('permban_id', GameCommands);
477 AddCommand('unban', GameCommands);
478 AddCommand('connect', GameCommands);
479 AddCommand('disconnect', GameCommands);
480 AddCommand('reconnect', GameCommands);
481 AddCommand('say', GameCommands);
482 AddCommand('tell', GameCommands);
483 AddCommand('overtime', GameCommands);
484 AddCommand('rcon_password', GameCommands);
485 AddCommand('rcon', GameCommands);
486 AddCommand('callvote', GameCommands);
487 AddCommand('vote', GameCommands);
488 AddCommand('clientlist', GameCommands);
489 AddCommand('event', GameCommands);
490
491 AddCommand('god', GameCheats);
492 AddCommand('notarget', GameCheats);
493 AddCommand('give', GameCheats); // "exit" too ;-)
494 AddCommand('open', GameCheats);
495 AddCommand('fly', GameCheats);
496 AddCommand('noclip', GameCheats);
497 AddCommand('speedy', GameCheats);
498 AddCommand('jumpy', GameCheats);
499 AddCommand('noreload', GameCheats);
500 AddCommand('aimline', GameCheats);
501 AddCommand('automap', GameCheats);
502
503 WhitelistCommand('say');
504 WhitelistCommand('tell');
505 WhitelistCommand('overtime');
506 WhitelistCommand('ready');
507 WhitelistCommand('map');
508 WhitelistCommand('nextmap');
509 WhitelistCommand('endmap');
510 WhitelistCommand('restart');
511 WhitelistCommand('kick');
512 WhitelistCommand('ban');
513
514 WhitelistCommand('addbot');
515 WhitelistCommand('bot_add');
516 WhitelistCommand('bot_addred');
517 WhitelistCommand('bot_addblue');
518 WhitelistCommand('bot_removeall');
519
520 WhitelistCommand('g_gamemode');
521 WhitelistCommand('g_friendlyfire');
522 WhitelistCommand('g_weaponstay');
523 WhitelistCommand('g_allow_exit');
524 WhitelistCommand('g_allow_monsters');
525 WhitelistCommand('g_scorelimit');
526 WhitelistCommand('g_timelimit');
527
528 g_Console_Add(Format(_lc[I_CONSOLE_WELCOME], [GAME_VERSION]));
529 g_Console_Add('');
530 end;
531
532 procedure g_Console_Update();
533 var
534 a, b: Integer;
535 begin
536 if Cons_Shown then
537 begin
538 // Â ïðîöåññå îòêðûòèÿ:
539 if gConsoleShow and (Cons_Y < 0) then
540 begin
541 Cons_Y := Cons_Y+Step;
542 end;
543
544 // Â ïðîöåññå çàêðûòèÿ:
545 if (not gConsoleShow) and
546 (Cons_Y > -(gScreenHeight div 2)) then
547 Cons_Y := Cons_Y-Step;
548
549 // Îêîí÷àòåëüíî îòêðûëàñü:
550 if Cons_Y > 0 then
551 Cons_Y := 0;
552
553 // Îêîí÷àòåëüíî çàêðûëàñü:
554 if Cons_Y <= (-(gScreenHeight div 2)) then
555 begin
556 Cons_Y := -(gScreenHeight div 2);
557 Cons_Shown := False;
558 end;
559 end;
560
561 a := 0;
562 while a <= High(MsgArray) do
563 begin
564 if MsgArray[a].Time > 0 then
565 begin
566 if MsgArray[a].Time = 1 then
567 begin
568 if a < High(MsgArray) then
569 begin
570 for b := a to High(MsgArray)-1 do
571 MsgArray[b] := MsgArray[b+1];
572
573 MsgArray[High(MsgArray)].Time := 0;
574
575 a := a - 1;
576 end;
577 end
578 else
579 Dec(MsgArray[a].Time);
580 end;
581
582 a := a + 1;
583 end;
584 end;
585
586
587 procedure drawConsoleText ();
588 var
589 CWidth, CHeight: Byte;
590 ty: Integer;
591 sp, ep: LongWord;
592 skip: Integer;
593
594 procedure putLine (sp, ep: LongWord);
595 var
596 p: LongWord;
597 wdt, cw: Integer;
598 begin
599 p := sp;
600 wdt := 0;
601 while p <> ep do
602 begin
603 cw := e_TextureFontCharWidth(cbufAt(p), gStdFont);
604 if wdt+cw > gScreenWidth-8 then break;
605 //e_TextureFontPrintChar(X, Y: Integer; Ch: Char; FontID: DWORD; Shadow: Boolean = False);
606 Inc(wdt, cw);
607 cbufNext(p);
608 end;
609 if p <> ep then putLine(p, ep); // do rest of the line first
610 // now print our part
611 if skip = 0 then
612 begin
613 ep := p;
614 p := sp;
615 wdt := 2;
616 while p <> ep do
617 begin
618 cw := e_TextureFontCharWidth(cbufAt(p), gStdFont);
619 e_TextureFontPrintCharEx(wdt, ty, cbufAt(p), gStdFont);
620 Inc(wdt, cw);
621 cbufNext(p);
622 end;
623 Dec(ty, CHeight);
624 end
625 else
626 begin
627 Dec(skip);
628 end;
629 end;
630
631 begin
632 e_TextureFontGetSize(gStdFont, CWidth, CHeight);
633 ty := (gScreenHeight div 2)-4-2*CHeight-Abs(Cons_Y);
634 skip := conSkipLines;
635 cbufLastLine(sp, ep);
636 repeat
637 putLine(sp, ep);
638 if ty+CHeight <= 0 then break;
639 until not cbufLineUp(sp, ep);
640 end;
641
642 procedure g_Console_Draw();
643 var
644 CWidth, CHeight: Byte;
645 mfW, mfH: Word;
646 a, b: Integer;
647 begin
648 e_TextureFontGetSize(gStdFont, CWidth, CHeight);
649
650 for a := 0 to High(MsgArray) do
651 if MsgArray[a].Time > 0 then
652 e_TextureFontPrintFmt(0, CHeight*a, MsgArray[a].Msg,
653 gStdFont, True);
654
655 if not Cons_Shown then
656 begin
657 if gChatShow then
658 begin
659 if gChatTeam then
660 begin
661 e_TextureFontPrintEx(0, gScreenHeight - CHeight - 1, 'say team> ' + Line,
662 gStdFont, 255, 255, 255, 1, True);
663 e_TextureFontPrintEx((CPos + 9)*CWidth, gScreenHeight - CHeight - 1, '_',
664 gStdFont, 255, 255, 255, 1, True);
665 end
666 else
667 begin
668 e_TextureFontPrintEx(0, gScreenHeight - CHeight - 1, 'say> ' + Line,
669 gStdFont, 255, 255, 255, 1, True);
670 e_TextureFontPrintEx((CPos + 4)*CWidth, gScreenHeight - CHeight - 1, '_',
671 gStdFont, 255, 255, 255, 1, True);
672 end;
673 end;
674 Exit;
675 end;
676
677 if gDebugMode then
678 begin
679 e_CharFont_GetSize(gMenuFont, DEBUG_STRING, mfW, mfH);
680 a := (gScreenWidth - 2*mfW) div 2;
681 b := Cons_Y + ((gScreenHeight div 2) - 2*mfH) div 2;
682 e_CharFont_PrintEx(gMenuFont, a div 2, b div 2, DEBUG_STRING,
683 _RGB(128, 0, 0), 2.0);
684 end;
685
686 e_DrawSize(ID, 0, Cons_Y, Alpha, False, False, gScreenWidth, gScreenHeight div 2);
687 e_TextureFontPrint(0, Cons_Y+(gScreenHeight div 2)-CHeight-4, '> '+Line, gStdFont);
688
689 drawConsoleText();
690 (*
691 if ConsoleHistory <> nil then
692 begin
693 b := 0;
694 if CHeight > 0 then
695 if Length(ConsoleHistory) > ((gScreenHeight div 2) div CHeight)-1 then
696 b := Length(ConsoleHistory)-((gScreenHeight div 2) div CHeight)+1;
697
698 b := Max(b-Offset, 0);
699 d := Max(High(ConsoleHistory)-Offset, 0);
700
701 c := 2;
702 for a := d downto b do
703 begin
704 e_TextureFontPrintFmt(0, (gScreenHeight div 2)-4-c*CHeight-Abs(Cons_Y), ConsoleHistory[a],
705 gStdFont, True);
706 c := c + 1;
707 end;
708 end;
709 *)
710
711 e_TextureFontPrint((CPos+1)*CWidth, Cons_Y+(gScreenHeight div 2)-21, '_', gStdFont);
712 end;
713
714 procedure g_Console_Switch();
715 begin
716 if gChatShow then Exit;
717 gConsoleShow := not gConsoleShow;
718 Cons_Shown := True;
719 end;
720
721 procedure g_Console_Chat_Switch(Team: Boolean = False);
722 begin
723 if gConsoleShow then Exit;
724 if not g_Game_IsNet then Exit;
725 gChatShow := not gChatShow;
726 gChatTeam := Team;
727 if gChatShow then
728 gChatEnter := False;
729 Line := '';
730 CPos := 1;
731 end;
732
733 procedure g_Console_Char(C: Char);
734 begin
735 if gChatShow and (not gChatEnter) then
736 Exit;
737 Insert(C, Line, CPos);
738 CPos := CPos + 1;
739 end;
740
741
742 var
743 tcomplist: array of string = nil;
744 tcompidx: array of Integer = nil;
745
746 procedure Complete ();
747 var
748 i, c: Integer;
749 tused: Integer;
750 ll, lpfx, cmd: string;
751 begin
752 if (Length(Line) = 0) then
753 begin
754 g_Console_Add('');
755 for i := 0 to High(Commands) do
756 begin
757 if not Commands[i].hidden then
758 begin
759 if (Length(Commands[i].help) > 0) then
760 begin
761 g_Console_Add(' '+Commands[i].Cmd+' -- '+Commands[i].help);
762 end
763 else
764 begin
765 g_Console_Add(' '+Commands[i].Cmd);
766 end;
767 end;
768 end;
769 exit;
770 end;
771
772 ll := LowerCase(Line);
773 lpfx := '';
774
775 if (Length(ll) > 1) and (ll[Length(ll)] = ' ') then
776 begin
777 ll := Copy(ll, 0, Length(ll)-1);
778 for i := 0 to High(Commands) do
779 begin
780 if Commands[i].hidden then continue;
781 if (Commands[i].Cmd = ll) then
782 begin
783 if (Length(Commands[i].help) > 0) then
784 begin
785 g_Console_Add(' '+Commands[i].Cmd+' -- '+Commands[i].help);
786 end;
787 end;
788 end;
789 exit;
790 end;
791
792 // build completion list
793 tused := 0;
794 for i := 0 to High(Commands) do
795 begin
796 if Commands[i].hidden then continue;
797 cmd := Commands[i].Cmd;
798 if (Length(cmd) >= Length(ll)) and (ll = Copy(cmd, 0, Length(ll))) then
799 begin
800 if (tused = Length(tcomplist)) then
801 begin
802 SetLength(tcomplist, Length(tcomplist)+128);
803 SetLength(tcompidx, Length(tcompidx)+128);
804 end;
805 tcomplist[tused] := cmd;
806 tcompidx[tused] := i;
807 Inc(tused);
808 if (Length(cmd) > Length(lpfx)) then lpfx := cmd;
809 end;
810 end;
811
812 // get longest prefix
813 for i := 0 to tused-1 do
814 begin
815 cmd := tcomplist[i];
816 for c := 1 to Length(lpfx) do
817 begin
818 if (c > Length(cmd)) then break;
819 if (cmd[c] <> lpfx[c]) then begin lpfx := Copy(lpfx, 0, c-1); break; end;
820 end;
821 end;
822
823 if (tused = 0) then exit;
824
825 if (tused = 1) then
826 begin
827 Line := tcomplist[0]+' ';
828 CPos := Length(Line)+1;
829 end
830 else
831 begin
832 // has longest prefix?
833 if (Length(lpfx) > Length(ll)) then
834 begin
835 Line := lpfx;
836 CPos:= Length(Line)+1;
837 end
838 else
839 begin
840 g_Console_Add('');
841 for i := 0 to tused-1 do
842 begin
843 if (Length(Commands[tcompidx[i]].help) > 0) then
844 begin
845 g_Console_Add(' '+tcomplist[i]+' -- '+Commands[tcompidx[i]].help);
846 end
847 else
848 begin
849 g_Console_Add(' '+tcomplist[i]);
850 end;
851 end;
852 end;
853 end;
854 end;
855
856
857 procedure g_Console_Control(K: Word);
858 begin
859 case K of
860 IK_BACKSPACE:
861 if (Length(Line) > 0) and (CPos > 1) then
862 begin
863 Delete(Line, CPos-1, 1);
864 CPos := CPos-1;
865 end;
866 IK_DELETE:
867 if (Length(Line) > 0) and (CPos <= Length(Line)) then
868 Delete(Line, CPos, 1);
869 IK_LEFT, IK_KPLEFT:
870 if CPos > 1 then
871 CPos := CPos - 1;
872 IK_RIGHT, IK_KPRIGHT:
873 if CPos <= Length(Line) then
874 CPos := CPos + 1;
875 IK_RETURN, IK_KPRETURN:
876 begin
877 if Cons_Shown then
878 g_Console_Process(Line)
879 else
880 if gChatShow then
881 begin
882 if (Length(Line) > 0) and g_Game_IsNet then
883 begin
884 if gChatTeam then
885 begin
886 if g_Game_IsClient then
887 MC_SEND_Chat(b_Text_Format(Line), NET_CHAT_TEAM)
888 else
889 MH_SEND_Chat('[' + gPlayer1Settings.Name + ']: ' + b_Text_Format(Line),
890 NET_CHAT_TEAM, gPlayer1Settings.Team);
891 end
892 else
893 begin
894 if g_Game_IsClient then
895 MC_SEND_Chat(b_Text_Format(Line), NET_CHAT_PLAYER)
896 else
897 MH_SEND_Chat('[' + gPlayer1Settings.Name + ']: ' + b_Text_Format(Line),
898 NET_CHAT_PLAYER);
899 end;
900 end;
901
902 Line := '';
903 CPos := 1;
904 gChatShow := False;
905 gJustChatted := True;
906 end;
907 end;
908 IK_TAB:
909 if not gChatShow then
910 Complete();
911 IK_DOWN, IK_KPDOWN:
912 if not gChatShow then
913 if (CommandHistory <> nil) and
914 (CmdIndex < Length(CommandHistory)) then
915 begin
916 if CmdIndex < Length(CommandHistory)-1 then
917 CmdIndex := CmdIndex + 1;
918 Line := CommandHistory[CmdIndex];
919 CPos := Length(Line) + 1;
920 end;
921 IK_UP, IK_KPUP:
922 if not gChatShow then
923 if (CommandHistory <> nil) and
924 (CmdIndex <= Length(CommandHistory)) then
925 begin
926 if CmdIndex > 0 then
927 CmdIndex := CmdIndex - 1;
928 Line := CommandHistory[CmdIndex];
929 Cpos := Length(Line) + 1;
930 end;
931 IK_PAGEUP, IK_KPPAGEUP: // PgUp
932 if not gChatShow then Inc(conSkipLines);
933 IK_PAGEDN, IK_KPPAGEDN: // PgDown
934 if not gChatShow and (conSkipLines > 0) then Dec(conSkipLines);
935 IK_HOME, IK_KPHOME:
936 CPos := 1;
937 IK_END, IK_KPEND:
938 CPos := Length(Line) + 1;
939 end;
940 end;
941
942 function GetStr(var Str: String): String;
943 var
944 a, b: Integer;
945 begin
946 Result := '';
947 if Str[1] = '"' then
948 begin
949 for b := 1 to Length(Str) do
950 if (b = Length(Str)) or (Str[b+1] = '"') then
951 begin
952 Result := Copy(Str, 2, b-1);
953 Delete(Str, 1, b+1);
954 Str := Trim(Str);
955 Exit;
956 end;
957 end;
958
959 for a := 1 to Length(Str) do
960 if (a = Length(Str)) or (Str[a+1] = ' ') then
961 begin
962 Result := Copy(Str, 1, a);
963 Delete(Str, 1, a+1);
964 Str := Trim(Str);
965 Exit;
966 end;
967 end;
968
969 function ParseString(Str: String): SArray;
970 begin
971 Result := nil;
972
973 Str := Trim(Str);
974
975 if Str = '' then
976 Exit;
977
978 while Str <> '' do
979 begin
980 SetLength(Result, Length(Result)+1);
981 Result[High(Result)] := GetStr(Str);
982 end;
983 end;
984
985 procedure g_Console_Add (L: string; Show: Boolean=false);
986
987 procedure conmsg (s: AnsiString);
988 var
989 a: Integer;
990 begin
991 if length(s) = 0 then exit;
992 for a := 0 to High(MsgArray) do
993 begin
994 with MsgArray[a] do
995 begin
996 if Time = 0 then
997 begin
998 Msg := s;
999 Time := MsgTime;
1000 exit;
1001 end;
1002 end;
1003 end;
1004 for a := 0 to High(MsgArray)-1 do MsgArray[a] := MsgArray[a+1];
1005 with MsgArray[High(MsgArray)] do
1006 begin
1007 Msg := L;
1008 Time := MsgTime;
1009 end;
1010 end;
1011
1012 var
1013 f: Integer;
1014 begin
1015 // put it to console
1016 cbufPut(L);
1017 if (length(L) = 0) or ((L[length(L)] <> #10) and (L[length(L)] <> #13)) then cbufPut(#10);
1018
1019 // now show 'em out of console too
1020 Show := Show and gAllowConsoleMessages;
1021 if Show and gShowMessages then
1022 begin
1023 // Âûâîä ñòðîê ñ ïåðåíîñàìè ïî î÷åðåäè
1024 while length(L) > 0 do
1025 begin
1026 f := Pos(#10, L);
1027 if f <= 0 then f := length(L)+1;
1028 conmsg(Copy(L, 1, f-1));
1029 Delete(L, 1, f);
1030 end;
1031 end;
1032
1033 //SetLength(ConsoleHistory, Length(ConsoleHistory)+1);
1034 //ConsoleHistory[High(ConsoleHistory)] := L;
1035
1036 (*
1037 {$IFDEF HEADLESS}
1038 e_WriteLog('CON: ' + L, MSG_NOTIFY);
1039 {$ENDIF}
1040 *)
1041 end;
1042
1043 procedure g_Console_Clear();
1044 begin
1045 //ConsoleHistory := nil;
1046 cbufClear();
1047 conSkipLines := 0;
1048 end;
1049
1050 procedure AddToHistory(L: String);
1051 var
1052 len: Integer;
1053 begin
1054 len := Length(CommandHistory);
1055
1056 if (len = 0) or
1057 (LowerCase(CommandHistory[len-1]) <> LowerCase(L)) then
1058 begin
1059 SetLength(CommandHistory, len+1);
1060 CommandHistory[len] := L;
1061 end;
1062
1063 CmdIndex := Length(CommandHistory);
1064 end;
1065
1066 function g_Console_CommandBlacklisted(C: String): Boolean;
1067 var
1068 Arr: SArray;
1069 i: Integer;
1070 begin
1071 Result := True;
1072
1073 Arr := nil;
1074
1075 if Trim(C) = '' then
1076 Exit;
1077
1078 Arr := ParseString(C);
1079 if Arr = nil then
1080 Exit;
1081
1082 for i := 0 to High(Whitelist) do
1083 if Whitelist[i] = LowerCase(Arr[0]) then
1084 Result := False;
1085 end;
1086
1087 procedure g_Console_Process(L: String; Quiet: Boolean = False);
1088 var
1089 Arr: SArray;
1090 i: Integer;
1091 begin
1092 Arr := nil;
1093
1094 if Trim(L) = '' then
1095 Exit;
1096
1097 conSkipLines := 0; // "unscroll"
1098
1099 if L = 'goobers' then
1100 begin
1101 Line := '';
1102 CPos := 1;
1103 gCheats := true;
1104 g_Console_Add('Your memory serves you well.');
1105 exit;
1106 end;
1107
1108 if not Quiet then
1109 begin
1110 g_Console_Add('> '+L);
1111 Line := '';
1112 CPos := 1;
1113 end;
1114
1115 Arr := ParseString(L);
1116 if Arr = nil then
1117 Exit;
1118
1119 if Commands = nil then
1120 Exit;
1121
1122 if not Quiet then
1123 AddToHistory(L);
1124
1125 for i := 0 to High(Commands) do
1126 if Commands[i].Cmd = LowerCase(Arr[0]) then
1127 if @Commands[i].Proc <> nil then
1128 begin
1129 Commands[i].Proc(Arr);
1130 Exit;
1131 end;
1132
1133 g_Console_Add(Format(_lc[I_CONSOLE_UNKNOWN], [Arr[0]]));
1134 end;
1135
1136 end.
[MIRROR] a port of Doom 2D Forever to FPC/SDL
[25/02/2024 19:55:35]
DEADSOFTWARE 2012-2024