src/game/g_console.pas

   1 (* Copyright (C)  Doom 2D: Forever Developers
   2  *
   3  * This program is free software: you can redistribute it and/or modify
   4  * it under the terms of the GNU General Public License as published by
   5  * the Free Software Foundation, either version 3 of the License, or
   6  * (at your option) any later version.
   7  *
   8  * This program is distributed in the hope that it will be useful,
   9  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11  * GNU General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License
  14  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15  *)
  16 {$INCLUDE ../shared/a_modes.inc}
  17 unit g_console;
  18
  19 interface
  20
  21 uses
  22   utils; // for SSArray
  23
  24   const
  25     ACTION_JUMP = 0;
  26     ACTION_MOVELEFT = 1;
  27     ACTION_MOVERIGHT = 2;
  28     ACTION_LOOKDOWN = 3;
  29     ACTION_LOOKUP = 4;
  30     ACTION_ATTACK = 5;
  31     ACTION_SCORES = 6;
  32     ACTION_ACTIVATE = 7;
  33     ACTION_STRAFE = 8;
  34     ACTION_WEAPNEXT = 9;
  35     ACTION_WEAPPREV = 10;
  36
  37     FIRST_ACTION = ACTION_JUMP;
  38     LAST_ACTION = ACTION_WEAPPREV;
  39
  40 procedure g_Console_Init;
  41 procedure g_Console_Update;
  42 procedure g_Console_Draw;
  43 procedure g_Console_Char (C: AnsiChar);
  44 procedure g_Console_Control (K: Word);
  45 procedure g_Console_Process (L: AnsiString; quiet: Boolean=false);
  46 procedure g_Console_Add (L: AnsiString; show: Boolean=false);
  47 procedure g_Console_Clear;
  48 function  g_Console_CommandBlacklisted (C: AnsiString): Boolean;
  49 procedure g_Console_ReadConfig (filename: String);
  50 procedure g_Console_WriteConfig (filename: String);
  51
  52 function  g_Console_Interactive: Boolean;
  53 function  g_Console_Action (action: Integer): Boolean;
  54 function  g_Console_MatchBind (key: Integer; down: AnsiString; up: AnsiString = ''): Boolean;
  55 function  g_Console_FindBind (n: Integer; down: AnsiString; up: AnsiString = ''): Integer;
  56 procedure g_Console_BindKey (key: Integer; down: AnsiString; up: AnsiString = '');
  57 procedure g_Console_ProcessBind (key: Integer; down: Boolean);
  58 procedure g_Console_ResetBinds;
  59
  60 procedure conwriteln (const s: AnsiString; show: Boolean=false);
  61 procedure conwritefln (const s: AnsiString; args: array of const; show: Boolean=false);
  62
  63 procedure conRegVar (const conname: AnsiString; pvar: PBoolean; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
  64 procedure conRegVar (const conname: AnsiString; pvar: PSingle; amin, amax: Single; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
  65 procedure conRegVar (const conname: AnsiString; pvar: PInteger; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
  66
  67 // <0: no arg; 0/1: true/false
  68 function conGetBoolArg (p: SSArray; idx: Integer): Integer;
  69
  70 // poor man's floating literal parser; i'm sorry, but `StrToFloat()` sux cocks
  71 function conParseFloat (var res: Single; const s: AnsiString): Boolean;
  72
  73
  74 var
  75   gConsoleShow: Boolean = false; // True - êîíñîëü îòêðûòà èëè îòêðûâàåòñÿ
  76   gChatShow: Boolean = false;
  77   gChatTeam: Boolean = false;
  78   gAllowConsoleMessages: Boolean = true;
  79   gJustChatted: Boolean = false; // ÷òîáû àäìèí â èíòåðå ÷àòÿñü íå ïðîìàòûâàë ñòàòèñòèêó
  80   gPlayerAction: Array [0..1, 0..LAST_ACTION] of Boolean; // [player, action]
  81
  82 implementation
  83
  84 uses
  85   g_textures, g_main, e_graphics, e_input, g_game,
  86   SysUtils, g_basic, g_options, Math, g_touch,
  87   g_menu, g_gui, g_language, g_net, g_netmsg, e_log, conbuf;
  88
  89
  90 type
  91   PCommand = ^TCommand;
  92
  93   TCmdProc = procedure (p: SSArray);
  94   TCmdProcEx = procedure (me: PCommand; p: SSArray);
  95
  96   TCommand = record
  97     cmd: AnsiString;
  98     proc: TCmdProc;
  99     procEx: TCmdProcEx;
 100     help: AnsiString;
 101     hidden: Boolean;
 102     ptr: Pointer; // various data
 103     msg: AnsiString; // message for var changes
 104     cheat: Boolean;
 105     action: Integer; // >= 0 for action commands
 106     player: Integer; // used for action commands
 107   end;
 108
 109   TAlias = record
 110     name: AnsiString;
 111     commands: SSArray;
 112   end;
 113
 114
 115 const
 116   Step = 32;
 117   Alpha = 25;
 118   MsgTime = 144;
 119   MaxScriptRecursion = 16;
 120
 121   DEBUG_STRING = 'DEBUG MODE';
 122
 123 var
 124   ID: DWORD;
 125   RecursionDepth: Word = 0;
 126   RecursionLimitHit: Boolean = False;
 127   Cons_Y: SmallInt;
 128   Cons_Shown: Boolean; // Ðèñîâàòü ëè êîíñîëü?
 129   Line: AnsiString;
 130   CPos: Word;
 131   //ConsoleHistory: SSArray;
 132   CommandHistory: SSArray;
 133   Whitelist: SSArray;
 134   commands: Array of TCommand = nil;
 135   Aliases: Array of TAlias = nil;
 136   CmdIndex: Word;
 137   conSkipLines: Integer = 0;
 138   MsgArray: Array [0..4] of record
 139                               Msg: AnsiString;
 140                               Time: Word;
 141                             end;
 142
 143   gInputBinds: Array [0..e_MaxInputKeys - 1] of record
 144     down, up: SSArray;
 145   end;
 146   menu_toggled: BOOLEAN; (* hack for menu controls *)
 147   gSkipFirstChar: Boolean; (* hack for console/chat input *)
 148
 149
 150 procedure g_Console_Switch;
 151 begin
 152   gChatShow := False;
 153   gConsoleShow := not gConsoleShow;
 154   Cons_Shown := True;
 155   g_Touch_ShowKeyboard(gConsoleShow or gChatShow);
 156 end;
 157
 158 procedure g_Console_Chat_Switch (Team: Boolean = False);
 159 begin
 160   if not g_Game_IsNet then Exit;
 161   gConsoleShow := False;
 162   gChatShow := not gChatShow;
 163   gChatTeam := Team;
 164   Line := '';
 165   CPos := 1;
 166   g_Touch_ShowKeyboard(gConsoleShow or gChatShow);
 167 end;
 168
 169 // poor man's floating literal parser; i'm sorry, but `StrToFloat()` sux cocks
 170 function conParseFloat (var res: Single; const s: AnsiString): Boolean;
 171 var
 172   pos: Integer = 1;
 173   frac: Single = 1;
 174   slen: Integer;
 175 begin
 176   result := false;
 177   res := 0;
 178   slen := Length(s);
 179   while (slen > 0) and (s[slen] <= ' ') do Dec(slen);
 180   while (pos <= slen) and (s[pos] <= ' ') do Inc(pos);
 181   if (pos > slen) then exit;
 182   if (slen-pos = 1) and (s[pos] = '.') then exit; // single dot
 183   // integral part
 184   while (pos <= slen) do
 185   begin
 186     if (s[pos] < '0') or (s[pos] > '9') then break;
 187     res := res*10+Byte(s[pos])-48;
 188     Inc(pos);
 189   end;
 190   if (pos <= slen) then
 191   begin
 192     // must be a dot
 193     if (s[pos] <> '.') then exit;
 194     Inc(pos);
 195     while (pos <= slen) do
 196     begin
 197       if (s[pos] < '0') or (s[pos] > '9') then break;
 198       frac := frac/10;
 199       res += frac*(Byte(s[pos])-48);
 200       Inc(pos);
 201     end;
 202   end;
 203   if (pos <= slen) then exit; // oops
 204   result := true;
 205 end;
 206
 207
 208 // ////////////////////////////////////////////////////////////////////////// //
 209 // <0: no arg; 0/1: true/false; 666: toggle
 210 function conGetBoolArg (p: SSArray; idx: Integer): Integer;
 211 begin
 212   if (idx < 0) or (idx > High(p)) then begin result := -1; exit; end;
 213   result := 0;
 214   if (p[idx] = '1') or (CompareText(p[idx], 'on') = 0) or (CompareText(p[idx], 'true') = 0) or
 215      (CompareText(p[idx], 'tan') = 0) or (CompareText(p[idx], 'yes') = 0) then result := 1
 216   else if (CompareText(p[idx], 'toggle') = 0) or (CompareText(p[idx], 'switch') = 0) or
 217           (CompareText(p[idx], 't') = 0) then result := 666;
 218 end;
 219
 220
 221 procedure boolVarHandler (me: PCommand; p: SSArray);
 222   procedure binaryFlag (var flag: Boolean; msg: AnsiString);
 223   begin
 224     if (Length(p) > 2) then
 225     begin
 226       conwritefln('too many arguments to ''%s''', [p[0]]);
 227     end
 228     else
 229     begin
 230       case conGetBoolArg(p, 1) of
 231         -1: begin end;
 232          0: if not me.cheat or conIsCheatsEnabled then flag := false else begin conwriteln('not available'); exit; end;
 233          1: if not me.cheat or conIsCheatsEnabled then flag := true else begin conwriteln('not available'); exit; end;
 234          666: if not me.cheat or conIsCheatsEnabled then flag := not flag else begin conwriteln('not available'); exit; end;
 235       end;
 236       if (Length(msg) = 0) then msg := p[0] else msg += ':';
 237       if flag then conwritefln('%s tan', [msg]) else conwritefln('%s ona', [msg]);
 238     end;
 239   end;
 240 begin
 241   binaryFlag(PBoolean(me.ptr)^, me.msg);
 242 end;
 243
 244
 245 procedure intVarHandler (me: PCommand; p: SSArray);
 246   procedure binaryFlag (var flag: Boolean; msg: AnsiString);
 247   begin
 248     if (Length(p) > 2) then
 249     begin
 250       conwritefln('too many arguments to ''%s''', [p[0]]);
 251     end
 252     else
 253     begin
 254       case conGetBoolArg(p, 1) of
 255         -1: begin end;
 256          0: if not me.cheat or conIsCheatsEnabled then flag := false else begin conwriteln('not available'); exit; end;
 257          1: if not me.cheat or conIsCheatsEnabled then flag := true else begin conwriteln('not available'); exit; end;
 258          666: if not me.cheat or conIsCheatsEnabled then flag := not flag else begin conwriteln('not available'); exit; end;
 259       end;
 260       if (Length(msg) = 0) then msg := p[0] else msg += ':';
 261       if flag then conwritefln('%s tan', [msg]) else conwritefln('%s ona', [msg]);
 262     end;
 263   end;
 264 begin
 265   if (Length(p) <> 2) then
 266   begin
 267     conwritefln('%s %d', [me.cmd, PInteger(me.ptr)^]);
 268   end
 269   else
 270   begin
 271     try
 272       PInteger(me.ptr)^ := StrToInt(p[1]);
 273     except
 274       conwritefln('invalid integer value: "%s"', [p[1]]);
 275     end;
 276   end;
 277 end;
 278
 279
 280 procedure conRegVar (const conname: AnsiString; pvar: PBoolean; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
 281 var
 282   f: Integer;
 283   cp: PCommand;
 284 begin
 285   f := Length(commands);
 286   SetLength(commands, f+1);
 287   cp := @commands[f];
 288   cp.cmd := LowerCase(conname);
 289   cp.proc := nil;
 290   cp.procEx := boolVarHandler;
 291   cp.help := ahelp;
 292   cp.hidden := ahidden;
 293   cp.ptr := pvar;
 294   cp.msg := amsg;
 295   cp.cheat := acheat;
 296   cp.action := -1;
 297   cp.player := -1;
 298 end;
 299
 300
 301 procedure conRegVar (const conname: AnsiString; pvar: PInteger; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
 302 var
 303   f: Integer;
 304   cp: PCommand;
 305 begin
 306   f := Length(commands);
 307   SetLength(commands, f+1);
 308   cp := @commands[f];
 309   cp.cmd := LowerCase(conname);
 310   cp.proc := nil;
 311   cp.procEx := intVarHandler;
 312   cp.help := ahelp;
 313   cp.hidden := ahidden;
 314   cp.ptr := pvar;
 315   cp.msg := amsg;
 316   cp.cheat := acheat;
 317   cp.action := -1;
 318   cp.player := -1;
 319 end;
 320
 321
 322 // ////////////////////////////////////////////////////////////////////////// //
 323 type
 324   PVarSingle = ^TVarSingle;
 325   TVarSingle = record
 326     val: PSingle;
 327     min, max, def: Single; // default will be starting value
 328   end;
 329
 330
 331 procedure singleVarHandler (me: PCommand; p: SSArray);
 332 var
 333   pv: PVarSingle;
 334   nv: Single;
 335   msg: AnsiString;
 336 begin
 337   if (Length(p) > 2) then
 338   begin
 339     conwritefln('too many arguments to ''%s''', [me.cmd]);
 340     exit;
 341   end;
 342   pv := PVarSingle(me.ptr);
 343   if (Length(p) = 2) then
 344   begin
 345     if me.cheat and (not conIsCheatsEnabled) then begin conwriteln('not available'); exit; end;
 346     if (CompareText(p[1], 'default') = 0) or (CompareText(p[1], 'def') = 0) or
 347        (CompareText(p[1], 'd') = 0) or (CompareText(p[1], 'off') = 0) or
 348        (CompareText(p[1], 'ona') = 0) then
 349     begin
 350       pv.val^ := pv.def;
 351     end
 352     else
 353     begin
 354       if not conParseFloat(nv, p[1]) then
 355       begin
 356         conwritefln('%s: ''%s'' doesn''t look like a floating number', [me.cmd, p[1]]);
 357         exit;
 358       end;
 359       if (nv < pv.min) then nv := pv.min;
 360       if (nv > pv.max) then nv := pv.max;
 361       pv.val^ := nv;
 362     end;
 363   end;
 364   msg := me.msg;
 365   if (Length(msg) = 0) then msg := me.cmd else msg += ':';
 366   conwritefln('%s %s', [msg, pv.val^]);
 367 end;
 368
 369
 370 procedure conRegVar (const conname: AnsiString; pvar: PSingle; amin, amax: Single; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
 371 var
 372   f: Integer;
 373   cp: PCommand;
 374   pv: PVarSingle;
 375 begin
 376   GetMem(pv, sizeof(TVarSingle));
 377   pv.val := pvar;
 378   pv.min := amin;
 379   pv.max := amax;
 380   pv.def := pvar^;
 381   f := Length(commands);
 382   SetLength(commands, f+1);
 383   cp := @commands[f];
 384   cp.cmd := LowerCase(conname);
 385   cp.proc := nil;
 386   cp.procEx := singleVarHandler;
 387   cp.help := ahelp;
 388   cp.hidden := ahidden;
 389   cp.ptr := pv;
 390   cp.msg := amsg;
 391   cp.cheat := acheat;
 392   cp.action := -1;
 393   cp.player := -1;
 394 end;
 395
 396
 397 // ////////////////////////////////////////////////////////////////////////// //
 398 function GetStrACmd(var Str: AnsiString): AnsiString;
 399 var
 400   a: Integer;
 401 begin
 402   Result := '';
 403   for a := 1 to Length(Str) do
 404     if (a = Length(Str)) or (Str[a+1] = ';') then
 405     begin
 406       Result := Copy(Str, 1, a);
 407       Delete(Str, 1, a+1);
 408       Str := Trim(Str);
 409       Exit;
 410     end;
 411 end;
 412
 413 function ParseAlias(Str: AnsiString): SSArray;
 414 begin
 415   Result := nil;
 416
 417   Str := Trim(Str);
 418
 419   if Str = '' then
 420     Exit;
 421
 422   while Str <> '' do
 423   begin
 424     SetLength(Result, Length(Result)+1);
 425     Result[High(Result)] := GetStrACmd(Str);
 426   end;
 427 end;
 428
 429 procedure ConsoleCommands(p: SSArray);
 430 var
 431   cmd, s: AnsiString;
 432   a, b: Integer;
 433   (* F: TextFile; *)
 434 begin
 435   cmd := LowerCase(p[0]);
 436   s := '';
 437
 438   if cmd = 'clear' then
 439   begin
 440     //ConsoleHistory := nil;
 441     cbufClear();
 442     conSkipLines := 0;
 443
 444     for a := 0 to High(MsgArray) do
 445       with MsgArray[a] do
 446       begin
 447         Msg := '';
 448         Time := 0;
 449       end;
 450   end;
 451
 452   if cmd = 'clearhistory' then
 453     CommandHistory := nil;
 454
 455   if cmd = 'showhistory' then
 456     if CommandHistory <> nil then
 457     begin
 458       g_Console_Add('');
 459       for a := 0 to High(CommandHistory) do
 460         g_Console_Add('  '+CommandHistory[a]);
 461     end;
 462
 463   if cmd = 'commands' then
 464   begin
 465     g_Console_Add('');
 466     g_Console_Add('commands list:');
 467     for a := High(commands) downto 0 do
 468     begin
 469       if (Length(commands[a].help) > 0) then
 470       begin
 471         g_Console_Add('  '+commands[a].cmd+' -- '+commands[a].help);
 472       end
 473       else
 474       begin
 475         g_Console_Add('  '+commands[a].cmd);
 476       end;
 477     end;
 478   end;
 479
 480   if cmd = 'time' then
 481     g_Console_Add(TimeToStr(Now), True);
 482
 483   if cmd = 'date' then
 484     g_Console_Add(DateToStr(Now), True);
 485
 486   if cmd = 'echo' then
 487     if Length(p) > 1 then
 488       begin
 489         if p[1] = 'ololo' then
 490           gCheats := True
 491         else
 492         begin
 493           s := '';
 494           for a := 1 to High(p) do
 495             s := s + p[a] + ' ';
 496           g_Console_Add(b_Text_Format(s), True);
 497         end;
 498       end
 499     else
 500       g_Console_Add('');
 501
 502   if cmd = 'dump' then
 503   begin
 504     (*
 505     if ConsoleHistory <> nil then
 506     begin
 507       if Length(P) > 1 then
 508         s := P[1]
 509       else
 510         s := GameDir+'/console.txt';
 511
 512       {$I-}
 513       AssignFile(F, s);
 514       Rewrite(F);
 515       if IOResult <> 0 then
 516       begin
 517         g_Console_Add(Format(_lc[I_CONSOLE_ERROR_WRITE], [s]));
 518         CloseFile(F);
 519         Exit;
 520       end;
 521
 522       for a := 0 to High(ConsoleHistory) do
 523         WriteLn(F, ConsoleHistory[a]);
 524
 525       CloseFile(F);
 526       g_Console_Add(Format(_lc[I_CONSOLE_DUMPED], [s]));
 527       {$I+}
 528     end;
 529     *)
 530   end;
 531
 532   if cmd = 'exec' then
 533   begin
 534     // exec <filename>
 535     if Length(p) = 2 then
 536       g_Console_ReadConfig(GameDir + '/' + p[1])
 537     else
 538       g_Console_Add('exec <script file>');
 539   end;
 540
 541   if cmd = 'writeconfig' then
 542   begin
 543     // writeconfig <filename>
 544     if Length(p) = 2 then
 545       g_Console_WriteConfig(GameDir + '/' + p[1])
 546     else
 547       g_Console_Add('writeconfig <file>');
 548   end;
 549
 550   if (cmd = 'ver') or (cmd = 'version') then
 551   begin
 552     conwriteln('Doom 2D: Forever v. ' + GAME_VERSION);
 553     conwritefln('Net protocol v. %d', [NET_PROTOCOL_VER]);
 554     conwritefln('Build date: %s at %s', [GAME_BUILDDATE, GAME_BUILDTIME]);
 555   end;
 556
 557   if cmd = 'alias' then
 558   begin
 559     // alias [alias_name] [commands]
 560     if Length(p) > 1 then
 561     begin
 562       for a := 0 to High(Aliases) do
 563         if Aliases[a].name = p[1] then
 564         begin
 565           if Length(p) > 2 then
 566             Aliases[a].commands := ParseAlias(p[2])
 567           else
 568             for b := 0 to High(Aliases[a].commands) do
 569               g_Console_Add(Aliases[a].commands[b]);
 570           Exit;
 571         end;
 572       SetLength(Aliases, Length(Aliases)+1);
 573       a := High(Aliases);
 574       Aliases[a].name := p[1];
 575       if Length(p) > 2 then
 576         Aliases[a].commands := ParseAlias(p[2])
 577       else
 578         for b := 0 to High(Aliases[a].commands) do
 579           g_Console_Add(Aliases[a].commands[b]);
 580     end else
 581       for a := 0 to High(Aliases) do
 582         if Aliases[a].commands <> nil then
 583           g_Console_Add(Aliases[a].name);
 584   end;
 585
 586   if cmd = 'call' then
 587   begin
 588     // call <alias_name>
 589     if Length(p) > 1 then
 590     begin
 591       if Aliases = nil then
 592         Exit;
 593       for a := 0 to High(Aliases) do
 594         if Aliases[a].name = p[1] then
 595         begin
 596           if Aliases[a].commands <> nil then
 597           begin
 598             // with this system proper endless loop detection seems either impossible
 599             // or very dirty to implement, so let's have this instead
 600             // prevents endless loops
 601             for b := 0 to High(Aliases[a].commands) do
 602             begin
 603               Inc(RecursionDepth);
 604               RecursionLimitHit := (RecursionDepth > MaxScriptRecursion) or RecursionLimitHit;
 605               if not RecursionLimitHit then
 606                 g_Console_Process(Aliases[a].commands[b], True);
 607               Dec(RecursionDepth);
 608             end;
 609             if (RecursionDepth = 0) and RecursionLimitHit then
 610             begin
 611               g_Console_Add(Format(_lc[I_CONSOLE_ERROR_CALL], [s]));
 612               RecursionLimitHit := False;
 613             end;
 614           end;
 615           Exit;
 616         end;
 617     end
 618     else
 619       g_Console_Add('call <alias name>');
 620   end;
 621 end;
 622
 623 procedure WhitelistCommand(cmd: AnsiString);
 624 var
 625   a: Integer;
 626 begin
 627   SetLength(Whitelist, Length(Whitelist)+1);
 628   a := High(Whitelist);
 629   Whitelist[a] := LowerCase(cmd);
 630 end;
 631
 632 procedure segfault (p: SSArray);
 633 var
 634   pp: PByte = nil;
 635 begin
 636   pp^ := 0;
 637 end;
 638
 639 function GetCommandString (p: SSArray): AnsiString;
 640   var i: Integer;
 641 begin
 642   result := '';
 643   if Length(p) >= 1 then
 644   begin
 645     result := p[0];
 646     for i := 1 to High(p) do
 647       result := result + '; ' + p[i]
 648   end
 649 end;
 650
 651 procedure BindCommands (p: SSArray);
 652   var cmd, key: AnsiString; i: Integer;
 653 begin
 654   cmd := LowerCase(p[0]);
 655   case cmd of
 656   'bind':
 657     // bind <key> [down [up]]
 658     if (Length(p) >= 2) and (Length(p) <= 4) then
 659     begin
 660       i := 0;
 661       key := LowerCase(p[1]);
 662       while (i < e_MaxInputKeys) and (key <> LowerCase(e_KeyNames[i])) do inc(i);
 663       if i < e_MaxInputKeys then
 664       begin
 665         if Length(p) = 2 then
 666           g_Console_Add('"' + e_KeyNames[i] + '" = "' + GetCommandString(gInputBinds[i].down) + '" "' + GetCommandString(gInputBinds[i].up) + '"')
 667         else if Length(p) = 3 then
 668           g_Console_BindKey(i, p[2], '')
 669         else (* len = 4 *)
 670           g_Console_BindKey(i, p[2], p[3])
 671       end
 672       else
 673         g_Console_Add('bind: "' + p[1] + '" is not a key')
 674     end
 675     else
 676     begin
 677       g_Console_Add('bind <key> <down action> [up action]')
 678     end;
 679   'bindlist':
 680     for i := 0 to e_MaxInputKeys - 1 do
 681       if (gInputBinds[i].down <> nil) or (gInputBinds[i].up <> nil) then
 682         g_Console_Add(e_KeyNames[i] + ' "' + GetCommandString(gInputBinds[i].down) + '" "' + GetCommandString(gInputBinds[i].up) + '"');
 683   'unbind':
 684     // unbind <key>
 685     if Length(p) = 2 then
 686     begin
 687       key := LowerCase(p[1]);
 688       i := 0;
 689       while (i < e_MaxInputKeys) and (key <> LowerCase(e_KeyNames[i])) do inc(i);
 690       if i < e_MaxInputKeys then
 691         g_Console_BindKey(i, '')
 692       else
 693         g_Console_Add('unbind: "' + p[1] + '" is not a key')
 694     end
 695     else
 696       g_Console_Add('unbind <key>');
 697   'unbindall':
 698     for i := 0 to e_MaxInputKeys - 1 do
 699       g_Console_BindKey(i, '');
 700   'showkeyboard':
 701     g_Touch_ShowKeyboard(True);
 702   'hidekeyboard':
 703     g_Touch_ShowKeyboard(False);
 704   'togglemenu':
 705     if gConsoleShow then
 706     begin
 707       g_Console_Switch;
 708       menu_toggled := True
 709     end
 710     else
 711     begin
 712       KeyPress(VK_ESCAPE);
 713       menu_toggled := True
 714     end;
 715   'toggleconsole':
 716     begin
 717       g_Console_Switch;
 718       gSkipFirstChar := g_Console_Interactive();
 719     end;
 720   'togglechat':
 721     begin
 722       if not gConsoleShow and (g_ActiveWindow = nil) then
 723         g_Console_Chat_Switch;
 724       gSkipFirstChar := not g_Console_Interactive()
 725     end;
 726   'toggleteamchat':
 727     if gGameSettings.GameMode in [GM_TDM, GM_CTF] then
 728     begin
 729       if not gConsoleShow and (g_ActiveWindow = nil) then
 730         g_Console_Chat_Switch(True);
 731       gSkipFirstChar := not g_Console_Interactive()
 732     end;
 733   end
 734 end;
 735
 736 procedure AddCommand(cmd: AnsiString; proc: TCmdProc; ahelp: AnsiString=''; ahidden: Boolean=false; acheat: Boolean=false);
 737 var
 738   a: Integer;
 739   cp: PCommand;
 740 begin
 741   SetLength(commands, Length(commands)+1);
 742   a := High(commands);
 743   cp := @commands[a];
 744   cp.cmd := LowerCase(cmd);
 745   cp.proc := proc;
 746   cp.procEx := nil;
 747   cp.help := ahelp;
 748   cp.hidden := ahidden;
 749   cp.ptr := nil;
 750   cp.msg := '';
 751   cp.cheat := acheat;
 752   cp.action := -1;
 753   cp.player := -1;
 754 end;
 755
 756 procedure AddAction (cmd: AnsiString; action: Integer; help: AnsiString = ''; hidden: Boolean = False; cheat: Boolean = False);
 757   const
 758     PrefixList: array [0..1] of AnsiString = ('+', '-');
 759     PlayerList: array [0..1] of Integer = (1, 2);
 760   var
 761     s: AnsiString;
 762     i: Integer;
 763
 764   procedure NewAction (cmd: AnsiString; player: Integer);
 765     var cp: PCommand;
 766   begin
 767     SetLength(commands, Length(commands) + 1);
 768     cp := @commands[High(commands)];
 769     cp.cmd := LowerCase(cmd);
 770     cp.proc := nil;
 771     cp.procEx := nil;
 772     cp.help := help;
 773     cp.hidden := hidden;
 774     cp.ptr := nil;
 775     cp.msg := '';
 776     cp.cheat := cheat;
 777     cp.action := action;
 778     cp.player := player;
 779   end;
 780
 781 begin
 782   ASSERT(action >= FIRST_ACTION);
 783   ASSERT(action <= LAST_ACTION);
 784   for s in PrefixList do
 785   begin
 786     NewAction(s + cmd, 0);
 787     for i in PlayerList do
 788       NewAction(s + 'p' + IntToStr(i) + '_' + cmd, i - 1)
 789   end
 790 end;
 791
 792 procedure g_Console_Init();
 793   var
 794     a: Integer;
 795 begin
 796   g_Texture_CreateWAD(ID, GameWAD+':TEXTURES\CONSOLE');
 797   Cons_Y := -(gScreenHeight div 2);
 798   gConsoleShow := False;
 799   gChatShow := False;
 800   Cons_Shown := False;
 801   CPos := 1;
 802
 803   for a := 0 to High(MsgArray) do
 804     with MsgArray[a] do
 805     begin
 806       Msg := '';
 807       Time := 0;
 808     end;
 809
 810   AddCommand('segfault', segfault, 'make segfault');
 811
 812   AddCommand('bind', BindCommands);
 813   AddCommand('bindlist', BindCommands);
 814   AddCommand('unbind', BindCommands);
 815   AddCommand('unbindall', BindCommands);
 816   AddCommand('showkeyboard', BindCommands);
 817   AddCommand('hidekeyboard', BindCommands);
 818   AddCommand('togglemenu', BindCommands);
 819   AddCommand('toggleconsole', BindCommands);
 820   AddCommand('togglechat', BindCommands);
 821   AddCommand('toggleteamchat', BindCommands);
 822
 823   AddCommand('clear', ConsoleCommands, 'clear console');
 824   AddCommand('clearhistory', ConsoleCommands);
 825   AddCommand('showhistory', ConsoleCommands);
 826   AddCommand('commands', ConsoleCommands);
 827   AddCommand('time', ConsoleCommands);
 828   AddCommand('date', ConsoleCommands);
 829   AddCommand('echo', ConsoleCommands);
 830   AddCommand('dump', ConsoleCommands);
 831   AddCommand('exec', ConsoleCommands);
 832   AddCommand('writeconfig', ConsoleCommands);
 833   AddCommand('alias', ConsoleCommands);
 834   AddCommand('call', ConsoleCommands);
 835   AddCommand('ver', ConsoleCommands);
 836   AddCommand('version', ConsoleCommands);
 837
 838   AddCommand('d_window', DebugCommands);
 839   AddCommand('d_sounds', DebugCommands);
 840   AddCommand('d_frames', DebugCommands);
 841   AddCommand('d_winmsg', DebugCommands);
 842   AddCommand('d_monoff', DebugCommands);
 843   AddCommand('d_botoff', DebugCommands);
 844   AddCommand('d_monster', DebugCommands);
 845   AddCommand('d_health', DebugCommands);
 846   AddCommand('d_player', DebugCommands);
 847   AddCommand('d_joy', DebugCommands);
 848   AddCommand('d_mem', DebugCommands);
 849
 850   AddCommand('p1_name', GameCVars);
 851   AddCommand('p2_name', GameCVars);
 852   AddCommand('p1_color', GameCVars);
 853   AddCommand('p2_color', GameCVars);
 854   AddCommand('r_showscore', GameCVars);
 855   AddCommand('r_showlives', GameCVars);
 856   AddCommand('r_showstat', GameCVars);
 857   AddCommand('r_showkillmsg', GameCVars);
 858   AddCommand('r_showspect', GameCVars);
 859   AddCommand('r_showping', GameCVars);
 860   AddCommand('g_gamemode', GameCVars);
 861   AddCommand('g_friendlyfire', GameCVars);
 862   AddCommand('g_weaponstay', GameCVars);
 863   AddCommand('g_allow_exit', GameCVars);
 864   AddCommand('g_allow_monsters', GameCVars);
 865   AddCommand('g_bot_vsmonsters', GameCVars);
 866   AddCommand('g_bot_vsplayers', GameCVars);
 867   AddCommand('g_scorelimit', GameCVars);
 868   AddCommand('g_timelimit', GameCVars);
 869   AddCommand('g_maxlives', GameCVars);
 870   AddCommand('g_warmuptime', GameCVars);
 871   AddCommand('net_interp', GameCVars);
 872   AddCommand('net_forceplayerupdate', GameCVars);
 873   AddCommand('net_predictself', GameCVars);
 874   AddCommand('sv_name', GameCVars);
 875   AddCommand('sv_passwd', GameCVars);
 876   AddCommand('sv_maxplrs', GameCVars);
 877   AddCommand('sv_public', GameCVars);
 878   AddCommand('sv_intertime', GameCVars);
 879
 880   AddCommand('quit', GameCommands);
 881   AddCommand('exit', GameCommands);
 882   AddCommand('pause', GameCommands);
 883   AddCommand('endgame', GameCommands);
 884   AddCommand('restart', GameCommands);
 885   AddCommand('addbot', GameCommands);
 886   AddCommand('bot_add', GameCommands);
 887   AddCommand('bot_addlist', GameCommands);
 888   AddCommand('bot_addred', GameCommands);
 889   AddCommand('bot_addblue', GameCommands);
 890   AddCommand('bot_removeall', GameCommands);
 891   AddCommand('chat', GameCommands);
 892   AddCommand('teamchat', GameCommands);
 893   AddCommand('game', GameCommands);
 894   AddCommand('host', GameCommands);
 895   AddCommand('map', GameCommands);
 896   AddCommand('nextmap', GameCommands);
 897   AddCommand('endmap', GameCommands);
 898   AddCommand('goodbye', GameCommands);
 899   AddCommand('suicide', GameCommands);
 900   AddCommand('spectate', GameCommands);
 901   AddCommand('ready', GameCommands);
 902   AddCommand('kick', GameCommands);
 903   AddCommand('kick_id', GameCommands);
 904   AddCommand('ban', GameCommands);
 905   AddCommand('permban', GameCommands);
 906   AddCommand('ban_id', GameCommands);
 907   AddCommand('permban_id', GameCommands);
 908   AddCommand('unban', GameCommands);
 909   AddCommand('connect', GameCommands);
 910   AddCommand('disconnect', GameCommands);
 911   AddCommand('reconnect', GameCommands);
 912   AddCommand('say', GameCommands);
 913   AddCommand('tell', GameCommands);
 914   AddCommand('overtime', GameCommands);
 915   AddCommand('rcon_password', GameCommands);
 916   AddCommand('rcon', GameCommands);
 917   AddCommand('callvote', GameCommands);
 918   AddCommand('vote', GameCommands);
 919   AddCommand('clientlist', GameCommands);
 920   AddCommand('event', GameCommands);
 921   AddCommand('screenshot', GameCommands);
 922   AddCommand('weapon', GameCommands);
 923   AddCommand('p1_weapon', GameCommands);
 924   AddCommand('p2_weapon', GameCommands);
 925
 926   AddCommand('god', GameCheats);
 927   AddCommand('notarget', GameCheats);
 928   AddCommand('give', GameCheats); // "exit" too ;-)
 929   AddCommand('open', GameCheats);
 930   AddCommand('fly', GameCheats);
 931   AddCommand('noclip', GameCheats);
 932   AddCommand('speedy', GameCheats);
 933   AddCommand('jumpy', GameCheats);
 934   AddCommand('noreload', GameCheats);
 935   AddCommand('aimline', GameCheats);
 936   AddCommand('automap', GameCheats);
 937
 938   AddAction('jump', ACTION_JUMP);
 939   AddAction('moveleft', ACTION_MOVELEFT);
 940   AddAction('moveright', ACTION_MOVERIGHT);
 941   AddAction('lookup', ACTION_LOOKUP);
 942   AddAction('lookdown', ACTION_LOOKDOWN);
 943   AddAction('attack', ACTION_ATTACK);
 944   AddAction('scores', ACTION_SCORES);
 945   AddAction('activate', ACTION_ACTIVATE);
 946   AddAction('strafe', ACTION_STRAFE);
 947   AddAction('weapnext', ACTION_WEAPNEXT);
 948   AddAction('weapprev', ACTION_WEAPPREV);
 949
 950   WhitelistCommand('say');
 951   WhitelistCommand('tell');
 952   WhitelistCommand('overtime');
 953   WhitelistCommand('ready');
 954   WhitelistCommand('map');
 955   WhitelistCommand('nextmap');
 956   WhitelistCommand('endmap');
 957   WhitelistCommand('restart');
 958   WhitelistCommand('kick');
 959   WhitelistCommand('ban');
 960
 961   WhitelistCommand('addbot');
 962   WhitelistCommand('bot_add');
 963   WhitelistCommand('bot_addred');
 964   WhitelistCommand('bot_addblue');
 965   WhitelistCommand('bot_removeall');
 966
 967   WhitelistCommand('g_gamemode');
 968   WhitelistCommand('g_friendlyfire');
 969   WhitelistCommand('g_weaponstay');
 970   WhitelistCommand('g_allow_exit');
 971   WhitelistCommand('g_allow_monsters');
 972   WhitelistCommand('g_scorelimit');
 973   WhitelistCommand('g_timelimit');
 974
 975   g_Console_ResetBinds;
 976   g_Console_ReadConfig(GameDir + '/dfconfig.cfg');
 977   g_Console_ReadConfig(GameDir + '/autoexec.cfg');
 978
 979   g_Console_Add(Format(_lc[I_CONSOLE_WELCOME], [GAME_VERSION]));
 980   g_Console_Add('');
 981 end;
 982
 983 procedure g_Console_Update();
 984 var
 985   a, b: Integer;
 986 begin
 987   if Cons_Shown then
 988   begin
 989   // Â ïðîöåññå îòêðûòèÿ:
 990     if gConsoleShow and (Cons_Y < 0) then
 991     begin
 992       Cons_Y := Cons_Y+Step;
 993     end;
 994
 995   // Â ïðîöåññå çàêðûòèÿ:
 996     if (not gConsoleShow) and
 997        (Cons_Y > -(gScreenHeight div 2)) then
 998       Cons_Y := Cons_Y-Step;
 999
1000   // Îêîí÷àòåëüíî îòêðûëàñü:
1001     if Cons_Y > 0 then
1002       Cons_Y := 0;
1003
1004   // Îêîí÷àòåëüíî çàêðûëàñü:
1005     if Cons_Y <= (-(gScreenHeight div 2)) then
1006     begin
1007       Cons_Y := -(gScreenHeight div 2);
1008       Cons_Shown := False;
1009     end;
1010   end;
1011
1012   a := 0;
1013   while a <= High(MsgArray) do
1014   begin
1015     if MsgArray[a].Time > 0 then
1016     begin
1017       if MsgArray[a].Time = 1 then
1018         begin
1019           if a < High(MsgArray) then
1020           begin
1021             for b := a to High(MsgArray)-1 do
1022               MsgArray[b] := MsgArray[b+1];
1023
1024             MsgArray[High(MsgArray)].Time := 0;
1025
1026             a := a - 1;
1027           end;
1028         end
1029       else
1030         Dec(MsgArray[a].Time);
1031     end;
1032
1033     a := a + 1;
1034   end;
1035 end;
1036
1037
1038 procedure drawConsoleText ();
1039 var
1040   CWidth, CHeight: Byte;
1041   ty: Integer;
1042   sp, ep: LongWord;
1043   skip: Integer;
1044
1045   procedure putLine (sp, ep: LongWord);
1046   var
1047     p: LongWord;
1048     wdt, cw: Integer;
1049   begin
1050     p := sp;
1051     wdt := 0;
1052     while p <> ep do
1053     begin
1054       cw := e_TextureFontCharWidth(cbufAt(p), gStdFont);
1055       if wdt+cw > gScreenWidth-8 then break;
1056       //e_TextureFontPrintChar(X, Y: Integer; Ch: Char; FontID: DWORD; Shadow: Boolean = False);
1057       Inc(wdt, cw);
1058       cbufNext(p);
1059     end;
1060     if p <> ep then putLine(p, ep); // do rest of the line first
1061     // now print our part
1062     if skip = 0 then
1063     begin
1064       ep := p;
1065       p := sp;
1066       wdt := 2;
1067       while p <> ep do
1068       begin
1069         cw := e_TextureFontCharWidth(cbufAt(p), gStdFont);
1070         e_TextureFontPrintCharEx(wdt, ty, cbufAt(p), gStdFont);
1071         Inc(wdt, cw);
1072         cbufNext(p);
1073       end;
1074       Dec(ty, CHeight);
1075     end
1076     else
1077     begin
1078       Dec(skip);
1079     end;
1080   end;
1081
1082 begin
1083   e_TextureFontGetSize(gStdFont, CWidth, CHeight);
1084   ty := (gScreenHeight div 2)-4-2*CHeight-Abs(Cons_Y);
1085   skip := conSkipLines;
1086   cbufLastLine(sp, ep);
1087   repeat
1088     putLine(sp, ep);
1089     if ty+CHeight <= 0 then break;
1090   until not cbufLineUp(sp, ep);
1091 end;
1092
1093 procedure g_Console_Draw();
1094 var
1095   CWidth, CHeight: Byte;
1096   mfW, mfH: Word;
1097   a, b: Integer;
1098 begin
1099   e_TextureFontGetSize(gStdFont, CWidth, CHeight);
1100
1101   for a := 0 to High(MsgArray) do
1102     if MsgArray[a].Time > 0 then
1103       e_TextureFontPrintFmt(0, CHeight*a, MsgArray[a].Msg,
1104         gStdFont, True);
1105
1106   if not Cons_Shown then
1107   begin
1108     if gChatShow then
1109     begin
1110       if gChatTeam then
1111       begin
1112         e_TextureFontPrintEx(0, gScreenHeight - CHeight - 1, 'say team> ' + Line,
1113           gStdFont, 255, 255, 255, 1, True);
1114         e_TextureFontPrintEx((CPos + 9)*CWidth, gScreenHeight - CHeight - 1, '_',
1115           gStdFont, 255, 255, 255, 1, True);
1116       end
1117       else
1118       begin
1119         e_TextureFontPrintEx(0, gScreenHeight - CHeight - 1, 'say> ' + Line,
1120           gStdFont, 255, 255, 255, 1, True);
1121         e_TextureFontPrintEx((CPos + 4)*CWidth, gScreenHeight - CHeight - 1, '_',
1122           gStdFont, 255, 255, 255, 1, True);
1123       end;
1124     end;
1125     Exit;
1126   end;
1127
1128   if gDebugMode then
1129   begin
1130     e_CharFont_GetSize(gMenuFont, DEBUG_STRING, mfW, mfH);
1131     a := (gScreenWidth - 2*mfW) div 2;
1132     b := Cons_Y + ((gScreenHeight div 2) - 2*mfH) div 2;
1133     e_CharFont_PrintEx(gMenuFont, a div 2, b div 2, DEBUG_STRING,
1134                        _RGB(128, 0, 0), 2.0);
1135   end;
1136
1137   e_DrawSize(ID, 0, Cons_Y, Alpha, False, False, gScreenWidth, gScreenHeight div 2);
1138   e_TextureFontPrint(0, Cons_Y+(gScreenHeight div 2)-CHeight-4, '> '+Line, gStdFont);
1139
1140   drawConsoleText();
1141   (*
1142   if ConsoleHistory <> nil then
1143   begin
1144     b := 0;
1145     if CHeight > 0 then
1146       if Length(ConsoleHistory) > ((gScreenHeight div 2) div CHeight)-1 then
1147         b := Length(ConsoleHistory)-((gScreenHeight div 2) div CHeight)+1;
1148
1149     b := Max(b-Offset, 0);
1150     d := Max(High(ConsoleHistory)-Offset, 0);
1151
1152     c := 2;
1153     for a := d downto b do
1154     begin
1155       e_TextureFontPrintFmt(0, (gScreenHeight div 2)-4-c*CHeight-Abs(Cons_Y), ConsoleHistory[a],
1156                            gStdFont, True);
1157       c := c + 1;
1158     end;
1159   end;
1160   *)
1161
1162   e_TextureFontPrint((CPos+1)*CWidth, Cons_Y+(gScreenHeight div 2)-21, '_', gStdFont);
1163 end;
1164
1165 procedure g_Console_Char(C: AnsiChar);
1166 begin
1167   if not gSkipFirstChar then
1168   begin
1169     Insert(C, Line, CPos);
1170     CPos := CPos + 1;
1171   end;
1172   gSkipFirstChar := False
1173 end;
1174
1175
1176 var
1177   tcomplist: array of AnsiString = nil;
1178   tcompidx: array of Integer = nil;
1179
1180 procedure Complete ();
1181 var
1182   i, c: Integer;
1183   tused: Integer;
1184   ll, lpfx, cmd: AnsiString;
1185 begin
1186   if (Length(Line) = 0) then
1187   begin
1188     g_Console_Add('');
1189     for i := 0 to High(commands) do
1190     begin
1191       // hidden commands are hidden when cheats aren't enabled
1192       if commands[i].hidden and not conIsCheatsEnabled then continue;
1193       if (Length(commands[i].help) > 0) then
1194       begin
1195         g_Console_Add('  '+commands[i].cmd+' -- '+commands[i].help);
1196       end
1197       else
1198       begin
1199         g_Console_Add('  '+commands[i].cmd);
1200       end;
1201     end;
1202     exit;
1203   end;
1204
1205   ll := LowerCase(Line);
1206   lpfx := '';
1207
1208   if (Length(ll) > 1) and (ll[Length(ll)] = ' ') then
1209   begin
1210     ll := Copy(ll, 0, Length(ll)-1);
1211     for i := 0 to High(commands) do
1212     begin
1213       // hidden commands are hidden when cheats aren't enabled
1214       if commands[i].hidden and not conIsCheatsEnabled then continue;
1215       if (commands[i].cmd = ll) then
1216       begin
1217         if (Length(commands[i].help) > 0) then
1218         begin
1219           g_Console_Add('  '+commands[i].cmd+' -- '+commands[i].help);
1220         end;
1221       end;
1222     end;
1223     exit;
1224   end;
1225
1226   // build completion list
1227   tused := 0;
1228   for i := 0 to High(commands) do
1229   begin
1230     // hidden commands are hidden when cheats aren't enabled
1231     if commands[i].hidden and not conIsCheatsEnabled then continue;
1232     cmd := commands[i].cmd;
1233     if (Length(cmd) >= Length(ll)) and (ll = Copy(cmd, 0, Length(ll))) then
1234     begin
1235       if (tused = Length(tcomplist)) then
1236       begin
1237         SetLength(tcomplist, Length(tcomplist)+128);
1238         SetLength(tcompidx, Length(tcompidx)+128);
1239       end;
1240       tcomplist[tused] := cmd;
1241       tcompidx[tused] := i;
1242       Inc(tused);
1243       if (Length(cmd) > Length(lpfx)) then lpfx := cmd;
1244     end;
1245   end;
1246
1247   // get longest prefix
1248   for i := 0 to tused-1 do
1249   begin
1250     cmd := tcomplist[i];
1251     for c := 1 to Length(lpfx) do
1252     begin
1253       if (c > Length(cmd)) then break;
1254       if (cmd[c] <> lpfx[c]) then begin lpfx := Copy(lpfx, 0, c-1); break; end;
1255     end;
1256   end;
1257
1258   if (tused = 0) then exit;
1259
1260   if (tused = 1) then
1261   begin
1262     Line := tcomplist[0]+' ';
1263     CPos := Length(Line)+1;
1264   end
1265   else
1266   begin
1267     // has longest prefix?
1268     if (Length(lpfx) > Length(ll)) then
1269     begin
1270       Line := lpfx;
1271       CPos:= Length(Line)+1;
1272     end
1273     else
1274     begin
1275       g_Console_Add('');
1276       for i := 0 to tused-1 do
1277       begin
1278         if (Length(commands[tcompidx[i]].help) > 0) then
1279         begin
1280           g_Console_Add('  '+tcomplist[i]+' -- '+commands[tcompidx[i]].help);
1281         end
1282         else
1283         begin
1284           g_Console_Add('  '+tcomplist[i]);
1285         end;
1286       end;
1287     end;
1288   end;
1289 end;
1290
1291
1292 procedure g_Console_Control(K: Word);
1293 begin
1294   case K of
1295     IK_BACKSPACE:
1296       if (Length(Line) > 0) and (CPos > 1) then
1297       begin
1298         Delete(Line, CPos-1, 1);
1299         CPos := CPos-1;
1300       end;
1301     IK_DELETE:
1302       if (Length(Line) > 0) and (CPos <= Length(Line)) then
1303         Delete(Line, CPos, 1);
1304     IK_LEFT, IK_KPLEFT, VK_LEFT, JOY0_LEFT, JOY1_LEFT, JOY2_LEFT, JOY3_LEFT:
1305       if CPos > 1 then
1306         CPos := CPos - 1;
1307     IK_RIGHT, IK_KPRIGHT, VK_RIGHT, JOY0_RIGHT, JOY1_RIGHT, JOY2_RIGHT, JOY3_RIGHT:
1308       if CPos <= Length(Line) then
1309         CPos := CPos + 1;
1310     IK_RETURN, IK_KPRETURN, VK_OPEN, VK_FIRE, JOY0_ATTACK, JOY1_ATTACK, JOY2_ATTACK, JOY3_ATTACK:
1311     begin
1312       if Cons_Shown then
1313         g_Console_Process(Line)
1314       else
1315         if gChatShow then
1316         begin
1317           if (Length(Line) > 0) and g_Game_IsNet then
1318           begin
1319             if gChatTeam then
1320             begin
1321               if g_Game_IsClient then
1322                 MC_SEND_Chat(b_Text_Format(Line), NET_CHAT_TEAM)
1323               else
1324                 MH_SEND_Chat('[' + gPlayer1Settings.name + ']: ' + b_Text_Format(Line),
1325                   NET_CHAT_TEAM, gPlayer1Settings.Team);
1326             end
1327             else
1328             begin
1329               if g_Game_IsClient then
1330                 MC_SEND_Chat(b_Text_Format(Line), NET_CHAT_PLAYER)
1331               else
1332                 MH_SEND_Chat('[' + gPlayer1Settings.name + ']: ' + b_Text_Format(Line),
1333                 NET_CHAT_PLAYER);
1334             end;
1335           end;
1336
1337           Line := '';
1338           CPos := 1;
1339           gChatShow := False;
1340           gJustChatted := True;
1341           g_Touch_ShowKeyboard(gConsoleShow or gChatShow);
1342         end;
1343     end;
1344     IK_TAB:
1345       if not gChatShow then
1346         Complete();
1347     IK_DOWN, IK_KPDOWN, VK_DOWN, JOY0_DOWN, JOY1_DOWN, JOY2_DOWN, JOY3_DOWN:
1348       if not gChatShow then
1349         if (CommandHistory <> nil) and
1350            (CmdIndex < Length(CommandHistory)) then
1351         begin
1352           if CmdIndex < Length(CommandHistory)-1 then
1353             CmdIndex := CmdIndex + 1;
1354           Line := CommandHistory[CmdIndex];
1355           CPos := Length(Line) + 1;
1356         end;
1357     IK_UP, IK_KPUP, VK_UP, JOY0_UP, JOY1_UP, JOY2_UP, JOY3_UP:
1358       if not gChatShow then
1359         if (CommandHistory <> nil) and
1360            (CmdIndex <= Length(CommandHistory)) then
1361         begin
1362           if CmdIndex > 0 then
1363             CmdIndex := CmdIndex - 1;
1364           Line := CommandHistory[CmdIndex];
1365           Cpos := Length(Line) + 1;
1366         end;
1367     IK_PAGEUP, IK_KPPAGEUP, VK_PREV, JOY0_PREV, JOY1_PREV, JOY2_PREV, JOY3_PREV: // PgUp
1368       if not gChatShow then Inc(conSkipLines);
1369     IK_PAGEDN, IK_KPPAGEDN, VK_NEXT, JOY0_NEXT, JOY1_NEXT, JOY2_NEXT, JOY3_NEXT: // PgDown
1370       if not gChatShow and (conSkipLines > 0) then Dec(conSkipLines);
1371     IK_HOME, IK_KPHOME:
1372       CPos := 1;
1373     IK_END, IK_KPEND:
1374       CPos := Length(Line) + 1;
1375     IK_A..IK_Z, IK_SPACE, IK_SHIFT, IK_RSHIFT, IK_CAPSLOCK, IK_LBRACKET, IK_RBRACKET,
1376     IK_SEMICOLON, IK_QUOTE, IK_BACKSLASH, IK_SLASH, IK_COMMA, IK_DOT, IK_EQUALS,
1377     IK_0, IK_1, IK_2, IK_3, IK_4, IK_5, IK_6, IK_7, IK_8, IK_9, IK_MINUS, IK_EQUALS:
1378       (* see TEXTINPUT event *)
1379   else
1380     if not gSkipFirstChar then
1381     begin
1382       if gConsoleShow and g_Console_MatchBind(K, 'toggleconsole') then
1383         g_Console_Switch;
1384
1385       if g_Console_MatchBind(K, 'togglemenu') then
1386       begin
1387         menu_toggled := True;
1388         if gChatShow then
1389           g_Console_Chat_Switch
1390         else if gConsoleShow then
1391           g_Console_Switch
1392       end
1393     end
1394   end
1395 end;
1396
1397 function GetStr(var Str: AnsiString): AnsiString;
1398 var
1399   a, b: Integer;
1400 begin
1401   Result := '';
1402   if Str[1] = '"' then
1403   begin
1404     for b := 1 to Length(Str) do
1405       if (b = Length(Str)) or (Str[b+1] = '"') then
1406       begin
1407         Result := Copy(Str, 2, b-1);
1408         Delete(Str, 1, b+1);
1409         Str := Trim(Str);
1410         Exit;
1411       end;
1412   end;
1413
1414   for a := 1 to Length(Str) do
1415     if (a = Length(Str)) or (Str[a+1] = ' ') then
1416     begin
1417       Result := Copy(Str, 1, a);
1418       Delete(Str, 1, a+1);
1419       Str := Trim(Str);
1420       Exit;
1421     end;
1422 end;
1423
1424 function ParseString(Str: AnsiString): SSArray;
1425 begin
1426   Result := nil;
1427
1428   Str := Trim(Str);
1429
1430   if Str = '' then
1431     Exit;
1432
1433   while Str <> '' do
1434   begin
1435     SetLength(Result, Length(Result)+1);
1436     Result[High(Result)] := GetStr(Str);
1437   end;
1438 end;
1439
1440 procedure g_Console_Add (L: AnsiString; show: Boolean=false);
1441
1442   procedure conmsg (s: AnsiString);
1443   var
1444     a: Integer;
1445   begin
1446     if length(s) = 0 then exit;
1447     for a := 0 to High(MsgArray) do
1448     begin
1449       with MsgArray[a] do
1450       begin
1451         if Time = 0 then
1452         begin
1453           Msg := s;
1454           Time := MsgTime;
1455           exit;
1456         end;
1457       end;
1458     end;
1459     for a := 0 to High(MsgArray)-1 do MsgArray[a] := MsgArray[a+1];
1460     with MsgArray[High(MsgArray)] do
1461     begin
1462       Msg := L;
1463       Time := MsgTime;
1464     end;
1465   end;
1466
1467 var
1468   f: Integer;
1469 begin
1470   // put it to console
1471   cbufPut(L);
1472   if (length(L) = 0) or ((L[length(L)] <> #10) and (L[length(L)] <> #13)) then cbufPut(#10);
1473
1474   // now show 'em out of console too
1475   show := show and gAllowConsoleMessages;
1476   if show and gShowMessages then
1477   begin
1478     // Âûâîä ñòðîê ñ ïåðåíîñàìè ïî î÷åðåäè
1479     while length(L) > 0 do
1480     begin
1481       f := Pos(#10, L);
1482       if f <= 0 then f := length(L)+1;
1483       conmsg(Copy(L, 1, f-1));
1484       Delete(L, 1, f);
1485     end;
1486   end;
1487
1488   //SetLength(ConsoleHistory, Length(ConsoleHistory)+1);
1489   //ConsoleHistory[High(ConsoleHistory)] := L;
1490
1491   (*
1492 {$IFDEF HEADLESS}
1493   e_WriteLog('CON: ' + L, MSG_NOTIFY);
1494 {$ENDIF}
1495   *)
1496 end;
1497
1498
1499 var
1500   consolewriterLastWasEOL: Boolean = false;
1501
1502 procedure consolewriter (constref buf; len: SizeUInt);
1503 var
1504   b: PByte;
1505 begin
1506   if (len < 1) then exit;
1507   b := PByte(@buf);
1508   consolewriterLastWasEOL := (b[len-1] = 13) or (b[len-1] = 10);
1509   while (len > 0) do
1510   begin
1511     if (b[0] <> 13) and (b[0] <> 10) then
1512     begin
1513       cbufPut(AnsiChar(b[0]));
1514     end
1515     else
1516     begin
1517       if (len > 1) and (b[0] = 13) then begin len -= 1; b += 1; end;
1518       cbufPut(#10);
1519     end;
1520     len -= 1;
1521     b += 1;
1522   end;
1523 end;
1524
1525
1526 // returns formatted string if `writerCB` is `nil`, empty string otherwise
1527 //function formatstrf (const fmt: AnsiString; args: array of const; writerCB: TFormatStrFCallback=nil): AnsiString;
1528 //TFormatStrFCallback = procedure (constref buf; len: SizeUInt);
1529 procedure conwriteln (const s: AnsiString; show: Boolean=false);
1530 begin
1531   g_Console_Add(s, show);
1532 end;
1533
1534
1535 procedure conwritefln (const s: AnsiString; args: array of const; show: Boolean=false);
1536 begin
1537   if show then
1538   begin
1539     g_Console_Add(formatstrf(s, args), true);
1540   end
1541   else
1542   begin
1543     consolewriterLastWasEOL := false;
1544     formatstrf(s, args, consolewriter);
1545     if not consolewriterLastWasEOL then cbufPut(#10);
1546   end;
1547 end;
1548
1549
1550 procedure g_Console_Clear();
1551 begin
1552   //ConsoleHistory := nil;
1553   cbufClear();
1554   conSkipLines := 0;
1555 end;
1556
1557 procedure AddToHistory(L: AnsiString);
1558 var
1559   len: Integer;
1560 begin
1561   len := Length(CommandHistory);
1562
1563   if (len = 0) or
1564      (LowerCase(CommandHistory[len-1]) <> LowerCase(L)) then
1565   begin
1566     SetLength(CommandHistory, len+1);
1567     CommandHistory[len] := L;
1568   end;
1569
1570   CmdIndex := Length(CommandHistory);
1571 end;
1572
1573 function g_Console_CommandBlacklisted(C: AnsiString): Boolean;
1574 var
1575   Arr: SSArray;
1576   i: Integer;
1577 begin
1578   Result := True;
1579
1580   Arr := nil;
1581
1582   if Trim(C) = '' then
1583     Exit;
1584
1585   Arr := ParseString(C);
1586   if Arr = nil then
1587     Exit;
1588
1589   for i := 0 to High(Whitelist) do
1590     if Whitelist[i] = LowerCase(Arr[0]) then
1591       Result := False;
1592 end;
1593
1594 procedure g_Console_Process(L: AnsiString; quiet: Boolean = False);
1595 var
1596   Arr: SSArray;
1597   i: Integer;
1598 begin
1599   Arr := nil;
1600
1601   if Trim(L) = '' then
1602     Exit;
1603
1604   conSkipLines := 0; // "unscroll"
1605
1606   if L = 'goobers' then
1607   begin
1608     Line := '';
1609     CPos := 1;
1610     gCheats := true;
1611     g_Console_Add('Your memory serves you well.');
1612     exit;
1613   end;
1614
1615   if not quiet then
1616   begin
1617     g_Console_Add('> '+L);
1618     Line := '';
1619     CPos := 1;
1620   end;
1621
1622   Arr := ParseString(L);
1623   if Arr = nil then
1624     Exit;
1625
1626   if commands = nil then
1627     Exit;
1628
1629   if not quiet then
1630     AddToHistory(L);
1631
1632   for i := 0 to High(commands) do
1633   begin
1634     if commands[i].cmd = LowerCase(Arr[0]) then
1635     begin
1636       if commands[i].action >= 0 then
1637       begin
1638         gPlayerAction[commands[i].player, commands[i].action] := commands[i].cmd[1] = '+';
1639         exit
1640       end;
1641       if assigned(commands[i].procEx) then
1642       begin
1643         commands[i].procEx(@commands[i], Arr);
1644         exit
1645       end;
1646       if assigned(commands[i].proc) then
1647       begin
1648         commands[i].proc(Arr);
1649         exit
1650       end
1651     end
1652   end;
1653
1654   g_Console_Add(Format(_lc[I_CONSOLE_UNKNOWN], [Arr[0]]));
1655 end;
1656
1657
1658 function g_Console_Interactive: Boolean;
1659 begin
1660   Result := gConsoleShow
1661 end;
1662
1663 procedure g_Console_BindKey (key: Integer; down: AnsiString; up: AnsiString = '');
1664 begin
1665   //e_LogWritefln('bind "%s" "%s" <%s>', [LowerCase(e_KeyNames[key]), cmd, key]);
1666   ASSERT(key >= 0);
1667   ASSERT(key < e_MaxInputKeys);
1668   if key > 0 then
1669   begin
1670     gInputBinds[key].down := ParseAlias(down);
1671     gInputBinds[key].up := ParseAlias(up)
1672   end
1673 end;
1674
1675 function g_Console_MatchBind (key: Integer; down: AnsiString; up: AnsiString = ''): Boolean;
1676
1677   function EqualsCommandLists (a, b: SSArray): Boolean;
1678     var i, len: Integer;
1679   begin
1680     result := False;
1681     len := Length(a);
1682     if len = Length(b) then
1683     begin
1684       i := 0;
1685       while (i < len) and (a[i] = b[i]) do inc(i);
1686       if i >= len then
1687         result := True
1688     end
1689   end;
1690
1691 begin
1692   ASSERT(key >= 0);
1693   ASSERT(key < e_MaxInputKeys);
1694   result := EqualsCommandLists(ParseAlias(down), gInputBinds[key].down) and EqualsCommandLists(ParseAlias(up), gInputBinds[key].up)
1695 end;
1696
1697 function g_Console_FindBind (n: Integer; down: AnsiString; up: AnsiString = ''): Integer;
1698   var i: Integer;
1699 begin
1700   ASSERT(n >= 1);
1701   result := 0;
1702   if commands = nil then Exit;
1703   i := 0;
1704   while (n >= 1) and (i < e_MaxInputKeys) do
1705   begin
1706     if g_Console_MatchBind(i, down, up) then
1707     begin
1708       result := i;
1709       dec(n)
1710     end;
1711     inc(i)
1712   end;
1713   if n >= 1 then
1714     result := 0
1715 end;
1716
1717 function g_Console_Action (action: Integer): Boolean;
1718   var i, len: Integer;
1719 begin
1720   ASSERT(action >= FIRST_ACTION);
1721   ASSERT(action <= LAST_ACTION);
1722   i := 0;
1723   len := Length(gPlayerAction);
1724   while (i < len) and (not gPlayerAction[i, action]) do inc(i);
1725   Result := i < len
1726 end;
1727
1728 procedure g_Console_ProcessBind (key: Integer; down: Boolean);
1729   var i: Integer;
1730 begin
1731   if (not g_GUIGrabInput) and (key >= 0) and (key < e_MaxInputKeys) and ((gInputBinds[key].down <> nil) or (gInputBinds[key].up <> nil)) then
1732   begin
1733     if down then
1734     begin
1735       if not gChatShow then
1736         for i := 0 to High(gInputBinds[key].down) do
1737           g_Console_Process(gInputBinds[key].down[i], True);
1738     end
1739     else
1740       for i := 0 to High(gInputBinds[key].up) do
1741         g_Console_Process(gInputBinds[key].up[i], True)
1742   end;
1743   if down and not menu_toggled then
1744     KeyPress(key);
1745   menu_toggled := False
1746 end;
1747
1748 procedure g_Console_ResetBinds;
1749   var i: Integer;
1750 begin
1751   for i := 0 to e_MaxInputKeys - 1 do
1752     g_Console_BindKey(i, '', '');
1753
1754   g_Console_BindKey(IK_GRAVE, 'toggleconsole');
1755   g_Console_BindKey(IK_ESCAPE, 'togglemenu');
1756   g_Console_BindKey(IK_A, '+p1_moveleft', '-p1_moveleft');
1757   g_Console_BindKey(IK_D, '+p1_moveright', '-p1_moveright');
1758   g_Console_BindKey(IK_W, '+p1_lookup', '-p1_lookup');
1759   g_Console_BindKey(IK_S, '+p1_lookdown', '-p1_lookdown');
1760   g_Console_BindKey(IK_SPACE, '+p1_jump', '-p1_jump');
1761   g_Console_BindKey(IK_H, '+p1_attack', '-p1_attack');
1762   g_Console_BindKey(IK_J, '+p1_activate', '-p1_activate');
1763   g_Console_BindKey(IK_E, '+p1_weapnext', '-p1_weapnext');
1764   g_Console_BindKey(IK_Q, '+p1_weapprev', '-p1_weapprev');
1765   g_Console_BindKey(IK_ALT, '+p1_strafe', '-p1_strafe');
1766   g_Console_BindKey(IK_1, 'p1_weapon 1');
1767   g_Console_BindKey(IK_2, 'p1_weapon 2');
1768   g_Console_BindKey(IK_3, 'p1_weapon 3');
1769   g_Console_BindKey(IK_4, 'p1_weapon 4');
1770   g_Console_BindKey(IK_5, 'p1_weapon 5');
1771   g_Console_BindKey(IK_6, 'p1_weapon 6');
1772   g_Console_BindKey(IK_7, 'p1_weapon 7');
1773   g_Console_BindKey(IK_8, 'p1_weapon 8');
1774   g_Console_BindKey(IK_9, 'p1_weapon 9');
1775   g_Console_BindKey(IK_0, 'p1_weapon 10');
1776   g_Console_BindKey(IK_MINUS, 'p1_weapon 11');
1777   g_Console_BindKey(IK_T, 'togglechat');
1778   g_Console_BindKey(IK_Y, 'toggleteamchat');
1779   g_Console_BindKey(IK_F11, 'screenshot');
1780   g_Console_BindKey(IK_TAB, '+p1_scores', '-p1_scores');
1781   g_Console_BindKey(IK_PAUSE, 'pause');
1782   g_Console_BindKey(IK_F1, 'vote');
1783
1784   (* for i := 0 to e_MaxJoys - 1 do *)
1785   for i := 0 to 1 do
1786   begin
1787     g_Console_BindKey(e_JoyHatToKey(i, 0, HAT_LEFT), '+p' + IntToStr(i mod 2 + 1) + '_moveleft', '-p' + IntToStr(i mod 2 + 1) + '_moveleft');
1788     g_Console_BindKey(e_JoyHatToKey(i, 0, HAT_RIGHT), '+p' + IntToStr(i mod 2 + 1) + '_moveright', '-p' + IntToStr(i mod 2 + 1) + '_moveright');
1789     g_Console_BindKey(e_JoyHatToKey(i, 0, HAT_UP), '+p' + IntToStr(i mod 2 + 1) + '_lookup', '-p' + IntToStr(i mod 2 + 1) + '_lookup');
1790     g_Console_BindKey(e_JoyHatToKey(i, 0, HAT_DOWN), '+p' + IntToStr(i mod 2 + 1) + '_lookdown', '-p' + IntToStr(i mod 2 + 1) + '_lookdown');
1791     g_Console_BindKey(e_JoyButtonToKey(i, 2), '+p' + IntToStr(i mod 2 + 1) + '_jump', '-p' + IntToStr(i mod 2 + 1) + '_jump');
1792     g_Console_BindKey(e_JoyButtonToKey(i, 0), '+p' + IntToStr(i mod 2 + 1) + '_attack', '-p' + IntToStr(i mod 2 + 1) + '_attack');
1793     g_Console_BindKey(e_JoyButtonToKey(i, 3), '+p' + IntToStr(i mod 2 + 1) + '_activate', '-p' + IntToStr(i mod 2 + 1) + '_activate');
1794     g_Console_BindKey(e_JoyButtonToKey(i, 1), '+p' + IntToStr(i mod 2 + 1) + '_weapnext', '-p' + IntToStr(i mod 2 + 1) + '_weapnext');
1795     g_Console_BindKey(e_JoyButtonToKey(i, 4), '+p' + IntToStr(i mod 2 + 1) + '_weapprev', '-p' + IntToStr(i mod 2 + 1) + '_weapprev');
1796     g_Console_BindKey(e_JoyButtonToKey(i, 7), '+p' + IntToStr(i mod 2 + 1) + '_strafe', '-p' + IntToStr(i mod 2 + 1) + '_strafe');
1797     g_Console_BindKey(e_JoyButtonToKey(i, 10), 'togglemenu');
1798   end;
1799
1800   g_Console_BindKey(VK_ESCAPE, 'togglemenu');
1801   g_Console_BindKey(VK_LSTRAFE, '+moveleft; +strafe', '-moveleft; -strafe');
1802   g_Console_BindKey(VK_RSTRAFE, '+moveright; +strafe', '-moveright; -strafe');
1803   g_Console_BindKey(VK_LEFT, '+moveleft', '-moveleft');
1804   g_Console_BindKey(VK_RIGHT, '+moveright', '-moveright');
1805   g_Console_BindKey(VK_UP, '+lookup', '-lookup');
1806   g_Console_BindKey(VK_DOWN, '+lookdown', '-lookdown');
1807   g_Console_BindKey(VK_JUMP, '+jump', '-jump');
1808   g_Console_BindKey(VK_FIRE, '+attack', '-attack');
1809   g_Console_BindKey(VK_OPEN, '+activate', '-activate');
1810   g_Console_BindKey(VK_NEXT, '+weapnext', '-weapnext');
1811   g_Console_BindKey(VK_PREV, '+weapprev', '-weapprev');
1812   g_Console_BindKey(VK_STRAFE, '+strafe', '-strafe');
1813   g_Console_BindKey(VK_0, 'weapon 1');
1814   g_Console_BindKey(VK_1, 'weapon 2');
1815   g_Console_BindKey(VK_2, 'weapon 3');
1816   g_Console_BindKey(VK_3, 'weapon 4');
1817   g_Console_BindKey(VK_4, 'weapon 5');
1818   g_Console_BindKey(VK_5, 'weapon 6');
1819   g_Console_BindKey(VK_6, 'weapon 7');
1820   g_Console_BindKey(VK_7, 'weapon 8');
1821   g_Console_BindKey(VK_8, 'weapon 9');
1822   g_Console_BindKey(VK_9, 'weapon 10');
1823   g_Console_BindKey(VK_A, 'weapon 11');
1824   g_Console_BindKey(VK_CHAT, 'togglechat');
1825   g_Console_BindKey(VK_TEAM, 'toggleteamchat');
1826   g_Console_BindKey(VK_CONSOLE, 'toggleconsole');
1827   g_Console_BindKey(VK_PRINTSCR, 'screenshot');
1828   g_Console_BindKey(VK_STATUS, '+scores', '-scores');
1829   g_Console_BindKey(VK_SHOWKBD, 'showkeyboard');
1830   g_Console_BindKey(VK_HIDEKBD, 'hidekeyboard');
1831 end;
1832
1833 procedure g_Console_ReadConfig (filename: String);
1834   var f: TextFile; s: AnsiString; i, len: Integer;
1835 begin
1836   if FileExists(filename) then
1837   begin
1838     AssignFile(f, filename);
1839     Reset(f);
1840     while not EOF(f) do
1841     begin
1842       ReadLn(f, s);
1843       len := Length(s);
1844       if len > 0 then
1845       begin
1846         i := 1;
1847         (* skip spaces *)
1848         while (i <= len) and (s[i] <= ' ') do inc(i);
1849         (* skip comments *)
1850         if (i <= len) and ((s[i] <> '#') and ((i + 1 > len) or (s[i] <> '/') or (s[i + 1] <> '/'))) then
1851           g_Console_Process(s, True)
1852       end
1853     end;
1854     CloseFile(f)
1855   end
1856 end;
1857
1858 procedure g_Console_WriteConfig (filename: String);
1859   var f: TextFile; i, j: Integer;
1860 begin
1861   AssignFile(f, filename);
1862   Rewrite(f);
1863   WriteLn(f, '// generated by doom2d, do not modify');
1864   WriteLn(f, 'unbindall');
1865   for i := 0 to e_MaxInputKeys - 1 do
1866     if (Length(gInputBinds[i].down) > 0) or (Length(gInputBinds[i].up) > 0) then
1867       WriteLn(f, 'bind ', e_KeyNames[i], ' "', GetCommandString(gInputBinds[i].down), '" "', GetCommandString(gInputBinds[i].up), '"');
1868   for i := 0 to High(commands) do
1869   begin
1870     if not commands[i].cheat then
1871     begin
1872       if @commands[i].procEx = @boolVarHandler then
1873       begin
1874         if PBoolean(commands[i].ptr)^ then j := 1 else j := 0;
1875         WriteLn(f, commands[i].cmd, ' "', j, '"')
1876       end
1877       else if @commands[i].procEx = @intVarHandler then
1878       begin
1879         WriteLn(f, commands[i].cmd, ' "', PInteger(commands[i].ptr)^, '"')
1880       end
1881       else if @commands[i].procEx = @singleVarHandler then
1882       begin
1883         WriteLn(f, commands[i].cmd, ' "', PVarSingle(commands[i].ptr).val^:0:6, '"')
1884       end
1885     end
1886   end;
1887   CloseFile(f)
1888 end;
1889
1890
1891 end.