src/game/g_console.pas

   1 (* Copyright (C)  Doom 2D: Forever Developers
   2  *
   3  * This program is free software: you can redistribute it and/or modify
   4  * it under the terms of the GNU General Public License as published by
   5  * the Free Software Foundation, version 3 of the License ONLY.
   6  *
   7  * This program is distributed in the hope that it will be useful,
   8  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   9  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  10  * GNU General Public License for more details.
  11  *
  12  * You should have received a copy of the GNU General Public License
  13  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  14  *)
  15 {$INCLUDE ../shared/a_modes.inc}
  16 unit g_console;
  17
  18 interface
  19
  20 uses
  21   utils; // for SSArray
  22
  23   const
  24     ACTION_JUMP = 0;
  25     ACTION_MOVELEFT = 1;
  26     ACTION_MOVERIGHT = 2;
  27     ACTION_LOOKDOWN = 3;
  28     ACTION_LOOKUP = 4;
  29     ACTION_ATTACK = 5;
  30     ACTION_SCORES = 6;
  31     ACTION_ACTIVATE = 7;
  32     ACTION_STRAFE = 8;
  33
  34     FIRST_ACTION = ACTION_JUMP;
  35     LAST_ACTION = ACTION_STRAFE;
  36
  37 procedure g_Console_Init;
  38 procedure g_Console_SysInit;
  39 procedure g_Console_Update;
  40 procedure g_Console_Draw (MessagesOnly: Boolean = False);
  41 procedure g_Console_Char (C: AnsiChar);
  42 procedure g_Console_Control (K: Word);
  43 procedure g_Console_Process (L: AnsiString; quiet: Boolean=false);
  44 procedure g_Console_Add (L: AnsiString; show: Boolean=false);
  45 procedure g_Console_Clear;
  46 function  g_Console_CommandBlacklisted (C: AnsiString): Boolean;
  47 procedure g_Console_ReadConfig (filename: String);
  48 procedure g_Console_WriteConfig (filename: String);
  49 procedure g_Console_WriteGameConfig;
  50
  51 function  g_Console_Interactive: Boolean;
  52 function  g_Console_Action (action: Integer): Boolean;
  53 function  g_Console_MatchBind (key: Integer; down: AnsiString; up: AnsiString = ''): Boolean;
  54 function  g_Console_FindBind (n: Integer; down: AnsiString; up: AnsiString = ''): Integer;
  55 procedure g_Console_BindKey (key: Integer; down: AnsiString; up: AnsiString = ''; rep: Boolean = False);
  56 procedure g_Console_ProcessBind (key: Integer; down: Boolean);
  57 procedure g_Console_ProcessBindRepeat (key: Integer);
  58 procedure g_Console_ResetBinds;
  59
  60 procedure conwriteln (const s: AnsiString; show: Boolean=false);
  61 procedure conwritefln (const s: AnsiString; args: array of const; show: Boolean=false);
  62
  63 procedure conRegVar (const conname: AnsiString; pvar: PBoolean; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
  64 procedure conRegVar (const conname: AnsiString; pvar: PSingle; amin, amax: Single; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
  65 procedure conRegVar (const conname: AnsiString; pvar: PInteger; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
  66 procedure conRegVar (const conname: AnsiString; pvar: PWord; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
  67 procedure conRegVar (const conname: AnsiString; pvar: PCardinal; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
  68 procedure conRegVar (const conname: AnsiString; pvar: PAnsiString; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
  69
  70 // <0: no arg; 0/1: true/false
  71 function conGetBoolArg (p: SSArray; idx: Integer): Integer;
  72
  73 // poor man's floating literal parser; i'm sorry, but `StrToFloat()` sux cocks
  74 function conParseFloat (var res: Single; const s: AnsiString): Boolean;
  75
  76 const
  77   {$IFDEF HEADLESS}
  78     defaultConfigScript = 'dfserver.cfg';
  79   {$ELSE}
  80     defaultConfigScript = 'dfconfig.cfg';
  81   {$ENDIF}
  82
  83 var
  84   gConsoleShow: Boolean = false; // True - êîíñîëü îòêðûòà èëè îòêðûâàåòñÿ
  85   gChatShow: Boolean = false;
  86   gChatTeam: Boolean = false;
  87   gAllowConsoleMessages: Boolean = true;
  88   gJustChatted: Boolean = false; // ÷òîáû àäìèí â èíòåðå ÷àòÿñü íå ïðîìàòûâàë ñòàòèñòèêó
  89   gParsingBinds: Boolean = true; // íå ïåðåñîõðàíÿòü êîíôèã âî âðåìÿ ïàðñèíãà
  90   gPlayerAction: Array [0..1, 0..LAST_ACTION] of Boolean; // [player, action]
  91   gConfigScript: string = defaultConfigScript;
  92
  93 implementation
  94
  95 uses
  96   g_textures, g_main, e_graphics, e_input, g_game, g_gfx, g_player, g_items,
  97   SysUtils, g_basic, g_options, Math, g_touch, e_res,
  98   g_menu, g_gui, g_language, g_net, g_netmsg, e_log, conbuf, g_weapons,
  99   Keyboard;
 100
 101 const
 102   autoexecScript = 'autoexec.cfg';
 103   configComment = 'generated by doom2d, do not modify';
 104
 105 type
 106   PCommand = ^TCommand;
 107
 108   TCmdProc = procedure (p: SSArray);
 109   TCmdProcEx = procedure (me: PCommand; p: SSArray);
 110
 111   TCommand = record
 112     cmd: AnsiString;
 113     proc: TCmdProc;
 114     procEx: TCmdProcEx;
 115     help: AnsiString;
 116     hidden: Boolean;
 117     ptr: Pointer; // various data
 118     msg: AnsiString; // message for var changes
 119     cheat: Boolean;
 120     action: Integer; // >= 0 for action commands
 121     player: Integer; // used for action commands
 122   end;
 123
 124   TAlias = record
 125     name: AnsiString;
 126     commands: SSArray;
 127   end;
 128
 129
 130 const
 131   MsgTime = 144;
 132   MaxScriptRecursion = 16;
 133
 134   DEBUG_STRING = 'DEBUG MODE';
 135
 136 var
 137   ID: DWORD;
 138   RecursionDepth: Word = 0;
 139   RecursionLimitHit: Boolean = False;
 140   Cons_Y: SmallInt;
 141   ConsoleHeight: Single;
 142   Cons_Shown: Boolean; // draw console
 143   InputReady: Boolean; // allow text input in console/chat
 144   Line: AnsiString;
 145   CPos: Word;
 146   //ConsoleHistory: SSArray;
 147   CommandHistory: SSArray;
 148   Whitelist: SSArray;
 149   commands: Array of TCommand = nil;
 150   Aliases: Array of TAlias = nil;
 151   CmdIndex: Word;
 152   conSkipLines: Integer = 0;
 153   MsgArray: Array [0..4] of record
 154                               Msg: AnsiString;
 155                               Time: Word;
 156                             end;
 157
 158   gInputBinds: Array [0..e_MaxInputKeys - 1] of record
 159     rep: Boolean;
 160     down, up: SSArray;
 161   end;
 162   menu_toggled: BOOLEAN; (* hack for menu controls *)
 163   ChatTop: BOOLEAN;
 164   ConsoleStep: Single;
 165   ConsoleTrans: Single;
 166   ConsoleStdIn: Boolean;
 167
 168
 169 procedure g_Console_Switch;
 170 begin
 171   Cons_Y := Min(0, Max(Cons_Y, -Floor(gScreenHeight * ConsoleHeight)));
 172   if Cons_Shown = False then
 173     Cons_Y := -Floor(gScreenHeight * ConsoleHeight);
 174   gChatShow := False;
 175   gConsoleShow := not gConsoleShow;
 176   Cons_Shown := True;
 177   InputReady := False;
 178   g_Touch_ShowKeyboard(gConsoleShow or gChatShow);
 179 end;
 180
 181 procedure g_Console_Chat_Switch (Team: Boolean = False);
 182 begin
 183   if not g_Game_IsNet then Exit;
 184   Cons_Y := Min(0, Max(Cons_Y, -Floor(gScreenHeight * ConsoleHeight)));
 185   if Cons_Shown = False then
 186     Cons_Y := -Floor(gScreenHeight * ConsoleHeight);
 187   gConsoleShow := False;
 188   gChatShow := not gChatShow;
 189   gChatTeam := Team;
 190   Cons_Shown := True;
 191   InputReady := False;
 192   Line := '';
 193   CPos := 1;
 194   g_Touch_ShowKeyboard(gConsoleShow or gChatShow);
 195 end;
 196
 197 // poor man's floating literal parser; i'm sorry, but `StrToFloat()` sux cocks
 198 function conParseFloat (var res: Single; const s: AnsiString): Boolean;
 199 var
 200   pos: Integer = 1;
 201   frac: Single = 1;
 202   slen: Integer;
 203 begin
 204   result := false;
 205   res := 0;
 206   slen := Length(s);
 207   while (slen > 0) and (s[slen] <= ' ') do Dec(slen);
 208   while (pos <= slen) and (s[pos] <= ' ') do Inc(pos);
 209   if (pos > slen) then exit;
 210   if (slen-pos = 1) and (s[pos] = '.') then exit; // single dot
 211   // integral part
 212   while (pos <= slen) do
 213   begin
 214     if (s[pos] < '0') or (s[pos] > '9') then break;
 215     res := res*10+Byte(s[pos])-48;
 216     Inc(pos);
 217   end;
 218   if (pos <= slen) then
 219   begin
 220     // must be a dot
 221     if (s[pos] <> '.') then exit;
 222     Inc(pos);
 223     while (pos <= slen) do
 224     begin
 225       if (s[pos] < '0') or (s[pos] > '9') then break;
 226       frac := frac/10;
 227       res += frac*(Byte(s[pos])-48);
 228       Inc(pos);
 229     end;
 230   end;
 231   if (pos <= slen) then exit; // oops
 232   result := true;
 233 end;
 234
 235
 236 // ////////////////////////////////////////////////////////////////////////// //
 237 // <0: no arg; 0/1: true/false; 666: toggle
 238 function conGetBoolArg (p: SSArray; idx: Integer): Integer;
 239 begin
 240   if (idx < 0) or (idx > High(p)) then begin result := -1; exit; end;
 241   result := 0;
 242   if (p[idx] = '1') or (CompareText(p[idx], 'on') = 0) or (CompareText(p[idx], 'true') = 0) or
 243      (CompareText(p[idx], 'tan') = 0) or (CompareText(p[idx], 'yes') = 0) then result := 1
 244   else if (CompareText(p[idx], 'toggle') = 0) or (CompareText(p[idx], 'switch') = 0) or
 245           (CompareText(p[idx], 't') = 0) then result := 666;
 246 end;
 247
 248
 249 procedure boolVarHandler (me: PCommand; p: SSArray);
 250   procedure binaryFlag (var flag: Boolean; msg: AnsiString);
 251   var
 252     old: Boolean;
 253   begin
 254     if (Length(p) > 2) then
 255     begin
 256       conwritefln('too many arguments to ''%s''', [p[0]]);
 257     end
 258     else
 259     begin
 260       old := flag;
 261       case conGetBoolArg(p, 1) of
 262         -1: begin end;
 263          0: if not me.cheat or conIsCheatsEnabled then flag := false else begin conwriteln('not available'); exit; end;
 264          1: if not me.cheat or conIsCheatsEnabled then flag := true else begin conwriteln('not available'); exit; end;
 265          666: if not me.cheat or conIsCheatsEnabled then flag := not flag else begin conwriteln('not available'); exit; end;
 266       end;
 267       if flag <> old then
 268         g_Console_WriteGameConfig();
 269       if (Length(msg) = 0) then msg := p[0] else msg += ':';
 270       if flag then conwritefln('%s tan', [msg]) else conwritefln('%s ona', [msg]);
 271     end;
 272   end;
 273 begin
 274   binaryFlag(PBoolean(me.ptr)^, me.msg);
 275 end;
 276
 277
 278 procedure intVarHandler (me: PCommand; p: SSArray);
 279 var
 280   old: Integer;
 281 begin
 282   if (Length(p) <> 2) then
 283   begin
 284     conwritefln('%s %d', [me.cmd, PInteger(me.ptr)^]);
 285   end
 286   else
 287   begin
 288     try
 289       old := PInteger(me.ptr)^;
 290       PInteger(me.ptr)^ := StrToInt(p[1]);
 291       if PInteger(me.ptr)^ <> old then
 292         g_Console_WriteGameConfig();
 293     except
 294       conwritefln('invalid integer value: "%s"', [p[1]]);
 295     end;
 296   end;
 297 end;
 298
 299
 300 procedure wordVarHandler (me: PCommand; p: SSArray);
 301 var
 302   old: Integer;
 303 begin
 304   if (Length(p) <> 2) then
 305   begin
 306     conwritefln('%s %d', [me.cmd, PInteger(me.ptr)^]);
 307   end
 308   else
 309   begin
 310     try
 311       old := PWord(me.ptr)^;
 312       PWord(me.ptr)^ := min($FFFF, StrToDWord(p[1]));
 313       if PWord(me.ptr)^ <> old then
 314         g_Console_WriteGameConfig();
 315     except
 316       conwritefln('invalid word value: "%s"', [p[1]]);
 317     end;
 318   end;
 319 end;
 320
 321
 322 procedure dwordVarHandler (me: PCommand; p: SSArray);
 323 var
 324   old: Integer;
 325 begin
 326   if (Length(p) <> 2) then
 327   begin
 328     conwritefln('%s %d', [me.cmd, PInteger(me.ptr)^]);
 329   end
 330   else
 331   begin
 332     try
 333       old := PCardinal(me.ptr)^;
 334       PCardinal(me.ptr)^ := StrToDWord(p[1]);
 335       if PCardinal(me.ptr)^ <> old then
 336         g_Console_WriteGameConfig();
 337     except
 338       conwritefln('invalid dword value: "%s"', [p[1]]);
 339     end;
 340   end;
 341 end;
 342
 343
 344 procedure strVarHandler (me: PCommand; p: SSArray);
 345 var
 346   old: AnsiString;
 347 begin
 348   if (Length(p) <> 2) then
 349   begin
 350     conwritefln('%s %s', [me.cmd, QuoteStr(PAnsiString(me.ptr)^)]);
 351   end
 352   else
 353   begin
 354     old := PAnsiString(me.ptr)^;
 355     PAnsiString(me.ptr)^ := p[1];
 356     if PAnsiString(me.ptr)^ <> old then
 357       g_Console_WriteGameConfig();
 358   end;
 359 end;
 360
 361
 362 procedure conRegVar (const conname: AnsiString; pvar: PBoolean; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
 363 var
 364   f: Integer;
 365   cp: PCommand;
 366 begin
 367   f := Length(commands);
 368   SetLength(commands, f+1);
 369   cp := @commands[f];
 370   cp.cmd := LowerCase(conname);
 371   cp.proc := nil;
 372   cp.procEx := boolVarHandler;
 373   cp.help := ahelp;
 374   cp.hidden := ahidden;
 375   cp.ptr := pvar;
 376   cp.msg := amsg;
 377   cp.cheat := acheat;
 378   cp.action := -1;
 379   cp.player := -1;
 380 end;
 381
 382
 383 procedure conRegVar (const conname: AnsiString; pvar: PInteger; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
 384 var
 385   f: Integer;
 386   cp: PCommand;
 387 begin
 388   f := Length(commands);
 389   SetLength(commands, f+1);
 390   cp := @commands[f];
 391   cp.cmd := LowerCase(conname);
 392   cp.proc := nil;
 393   cp.procEx := intVarHandler;
 394   cp.help := ahelp;
 395   cp.hidden := ahidden;
 396   cp.ptr := pvar;
 397   cp.msg := amsg;
 398   cp.cheat := acheat;
 399   cp.action := -1;
 400   cp.player := -1;
 401 end;
 402
 403
 404 procedure conRegVar (const conname: AnsiString; pvar: PWord; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
 405 var
 406   f: Integer;
 407   cp: PCommand;
 408 begin
 409   f := Length(commands);
 410   SetLength(commands, f+1);
 411   cp := @commands[f];
 412   cp.cmd := LowerCase(conname);
 413   cp.proc := nil;
 414   cp.procEx := wordVarHandler;
 415   cp.help := ahelp;
 416   cp.hidden := ahidden;
 417   cp.ptr := pvar;
 418   cp.msg := amsg;
 419   cp.cheat := acheat;
 420   cp.action := -1;
 421   cp.player := -1;
 422 end;
 423
 424
 425 procedure conRegVar (const conname: AnsiString; pvar: PCardinal; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
 426 var
 427   f: Integer;
 428   cp: PCommand;
 429 begin
 430   f := Length(commands);
 431   SetLength(commands, f+1);
 432   cp := @commands[f];
 433   cp.cmd := LowerCase(conname);
 434   cp.proc := nil;
 435   cp.procEx := dwordVarHandler;
 436   cp.help := ahelp;
 437   cp.hidden := ahidden;
 438   cp.ptr := pvar;
 439   cp.msg := amsg;
 440   cp.cheat := acheat;
 441   cp.action := -1;
 442   cp.player := -1;
 443 end;
 444
 445
 446 procedure conRegVar (const conname: AnsiString; pvar: PAnsiString; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
 447 var
 448   f: Integer;
 449   cp: PCommand;
 450 begin
 451   f := Length(commands);
 452   SetLength(commands, f+1);
 453   cp := @commands[f];
 454   cp.cmd := LowerCase(conname);
 455   cp.proc := nil;
 456   cp.procEx := strVarHandler;
 457   cp.help := ahelp;
 458   cp.hidden := ahidden;
 459   cp.ptr := pvar;
 460   cp.msg := amsg;
 461   cp.cheat := acheat;
 462   cp.action := -1;
 463   cp.player := -1;
 464 end;
 465
 466 // ////////////////////////////////////////////////////////////////////////// //
 467 type
 468   PVarSingle = ^TVarSingle;
 469   TVarSingle = record
 470     val: PSingle;
 471     min, max, def: Single; // default will be starting value
 472   end;
 473
 474
 475 procedure singleVarHandler (me: PCommand; p: SSArray);
 476 var
 477   pv: PVarSingle;
 478   nv, old: Single;
 479   msg: AnsiString;
 480 begin
 481   if (Length(p) > 2) then
 482   begin
 483     conwritefln('too many arguments to ''%s''', [me.cmd]);
 484     exit;
 485   end;
 486   pv := PVarSingle(me.ptr);
 487   old := pv.val^;
 488   if (Length(p) = 2) then
 489   begin
 490     if me.cheat and (not conIsCheatsEnabled) then begin conwriteln('not available'); exit; end;
 491     if (CompareText(p[1], 'default') = 0) or (CompareText(p[1], 'def') = 0) or
 492        (CompareText(p[1], 'd') = 0) or (CompareText(p[1], 'off') = 0) or
 493        (CompareText(p[1], 'ona') = 0) then
 494     begin
 495       pv.val^ := pv.def;
 496     end
 497     else
 498     begin
 499       if not conParseFloat(nv, p[1]) then
 500       begin
 501         conwritefln('%s: ''%s'' doesn''t look like a floating number', [me.cmd, p[1]]);
 502         exit;
 503       end;
 504       if (nv < pv.min) then nv := pv.min;
 505       if (nv > pv.max) then nv := pv.max;
 506       pv.val^ := nv;
 507     end;
 508   end;
 509   if pv.val^ <> old then
 510     g_Console_WriteGameConfig();
 511   msg := me.msg;
 512   if (Length(msg) = 0) then msg := me.cmd else msg += ':';
 513   conwritefln('%s %s', [msg, pv.val^]);
 514 end;
 515
 516
 517 procedure conRegVar (const conname: AnsiString; pvar: PSingle; amin, amax: Single; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
 518 var
 519   f: Integer;
 520   cp: PCommand;
 521   pv: PVarSingle;
 522 begin
 523   GetMem(pv, sizeof(TVarSingle));
 524   pv.val := pvar;
 525   pv.min := amin;
 526   pv.max := amax;
 527   pv.def := pvar^;
 528   f := Length(commands);
 529   SetLength(commands, f+1);
 530   cp := @commands[f];
 531   cp.cmd := LowerCase(conname);
 532   cp.proc := nil;
 533   cp.procEx := singleVarHandler;
 534   cp.help := ahelp;
 535   cp.hidden := ahidden;
 536   cp.ptr := pv;
 537   cp.msg := amsg;
 538   cp.cheat := acheat;
 539   cp.action := -1;
 540   cp.player := -1;
 541 end;
 542
 543
 544 // ////////////////////////////////////////////////////////////////////////// //
 545 function GetStrACmd(var Str: AnsiString): AnsiString;
 546 var
 547   a: Integer;
 548 begin
 549   Result := '';
 550   for a := 1 to Length(Str) do
 551     if (a = Length(Str)) or (Str[a+1] = ';') then
 552     begin
 553       Result := Copy(Str, 1, a);
 554       Delete(Str, 1, a+1);
 555       Str := Trim(Str);
 556       Exit;
 557     end;
 558 end;
 559
 560 function ParseAlias(Str: AnsiString): SSArray;
 561 begin
 562   Result := nil;
 563
 564   Str := Trim(Str);
 565
 566   if Str = '' then
 567     Exit;
 568
 569   while Str <> '' do
 570   begin
 571     SetLength(Result, Length(Result)+1);
 572     Result[High(Result)] := GetStrACmd(Str);
 573   end;
 574 end;
 575
 576 procedure ConsoleCommands(p: SSArray);
 577 var
 578   cmd, s: AnsiString;
 579   a, b: Integer;
 580   (* F: TextFile; *)
 581 begin
 582   cmd := LowerCase(p[0]);
 583   s := '';
 584
 585   if cmd = 'clear' then
 586   begin
 587     //ConsoleHistory := nil;
 588     cbufClear();
 589     conSkipLines := 0;
 590
 591     for a := 0 to High(MsgArray) do
 592       with MsgArray[a] do
 593       begin
 594         Msg := '';
 595         Time := 0;
 596       end;
 597   end;
 598
 599   if cmd = 'clearhistory' then
 600     CommandHistory := nil;
 601
 602   if cmd = 'showhistory' then
 603     if CommandHistory <> nil then
 604     begin
 605       g_Console_Add('');
 606       for a := 0 to High(CommandHistory) do
 607         g_Console_Add('  '+CommandHistory[a]);
 608     end;
 609
 610   if cmd = 'commands' then
 611   begin
 612     g_Console_Add('');
 613     g_Console_Add('commands list:');
 614     for a := High(commands) downto 0 do
 615     begin
 616       if (Length(commands[a].help) > 0) then
 617       begin
 618         g_Console_Add('  '+commands[a].cmd+' -- '+commands[a].help);
 619       end
 620       else
 621       begin
 622         g_Console_Add('  '+commands[a].cmd);
 623       end;
 624     end;
 625   end;
 626
 627   if cmd = 'time' then
 628     g_Console_Add(TimeToStr(Now), True);
 629
 630   if cmd = 'date' then
 631     g_Console_Add(DateToStr(Now), True);
 632
 633   if cmd = 'echo' then
 634     if Length(p) > 1 then
 635       begin
 636         if p[1] = 'ololo' then
 637           gCheats := True
 638         else
 639         begin
 640           s := '';
 641           for a := 1 to High(p) do
 642             s := s + p[a] + ' ';
 643           g_Console_Add(b_Text_Format(s), True);
 644         end;
 645       end
 646     else
 647       g_Console_Add('');
 648
 649   if cmd = 'dump' then
 650   begin
 651     (*
 652     if ConsoleHistory <> nil then
 653     begin
 654       if Length(P) > 1 then
 655         s := P[1]
 656       else
 657         s := GameDir+'/console.txt';
 658
 659       {$I-}
 660       AssignFile(F, s);
 661       Rewrite(F);
 662       if IOResult <> 0 then
 663       begin
 664         g_Console_Add(Format(_lc[I_CONSOLE_ERROR_WRITE], [s]));
 665         CloseFile(F);
 666         Exit;
 667       end;
 668
 669       for a := 0 to High(ConsoleHistory) do
 670         WriteLn(F, ConsoleHistory[a]);
 671
 672       CloseFile(F);
 673       g_Console_Add(Format(_lc[I_CONSOLE_DUMPED], [s]));
 674       {$I+}
 675     end;
 676     *)
 677   end;
 678
 679   if cmd = 'exec' then
 680   begin
 681     // exec <filename>
 682     if Length(p) = 2 then
 683       g_Console_ReadConfig(p[1])
 684     else
 685       g_Console_Add('exec <script file>');
 686   end;
 687
 688   if cmd = 'writeconfig' then
 689   begin
 690     // writeconfig <filename>
 691     if Length(p) = 2 then
 692     begin
 693       s := e_GetWriteableDir(ConfigDirs);
 694       g_Console_WriteConfig(e_CatPath(s, p[1]))
 695     end
 696     else
 697     begin
 698       g_Console_Add('writeconfig <file>')
 699     end
 700   end;
 701
 702   if (cmd = 'ver') or (cmd = 'version') then
 703   begin
 704     conwriteln('Doom 2D: Forever v. ' + GAME_VERSION);
 705     conwritefln('Net protocol v. %d', [NET_PROTOCOL_VER]);
 706     conwritefln('Build date: %s at %s', [GAME_BUILDDATE, GAME_BUILDTIME]);
 707   end;
 708
 709   if cmd = 'alias' then
 710   begin
 711     // alias [alias_name] [commands]
 712     if Length(p) > 1 then
 713     begin
 714       for a := 0 to High(Aliases) do
 715         if Aliases[a].name = p[1] then
 716         begin
 717           if Length(p) > 2 then
 718             Aliases[a].commands := ParseAlias(p[2])
 719           else
 720             for b := 0 to High(Aliases[a].commands) do
 721               g_Console_Add(Aliases[a].commands[b]);
 722           Exit;
 723         end;
 724       SetLength(Aliases, Length(Aliases)+1);
 725       a := High(Aliases);
 726       Aliases[a].name := p[1];
 727       if Length(p) > 2 then
 728         Aliases[a].commands := ParseAlias(p[2])
 729       else
 730         for b := 0 to High(Aliases[a].commands) do
 731           g_Console_Add(Aliases[a].commands[b]);
 732     end else
 733       for a := 0 to High(Aliases) do
 734         if Aliases[a].commands <> nil then
 735           g_Console_Add(Aliases[a].name);
 736   end;
 737
 738   if cmd = 'call' then
 739   begin
 740     // call <alias_name>
 741     if Length(p) > 1 then
 742     begin
 743       if Aliases = nil then
 744         Exit;
 745       for a := 0 to High(Aliases) do
 746         if Aliases[a].name = p[1] then
 747         begin
 748           if Aliases[a].commands <> nil then
 749           begin
 750             // with this system proper endless loop detection seems either impossible
 751             // or very dirty to implement, so let's have this instead
 752             // prevents endless loops
 753             for b := 0 to High(Aliases[a].commands) do
 754             begin
 755               Inc(RecursionDepth);
 756               RecursionLimitHit := (RecursionDepth > MaxScriptRecursion) or RecursionLimitHit;
 757               if not RecursionLimitHit then
 758                 g_Console_Process(Aliases[a].commands[b], True);
 759               Dec(RecursionDepth);
 760             end;
 761             if (RecursionDepth = 0) and RecursionLimitHit then
 762             begin
 763               g_Console_Add(Format(_lc[I_CONSOLE_ERROR_CALL], [s]));
 764               RecursionLimitHit := False;
 765             end;
 766           end;
 767           Exit;
 768         end;
 769     end
 770     else
 771       g_Console_Add('call <alias name>');
 772   end;
 773 end;
 774
 775 procedure WhitelistCommand(cmd: AnsiString);
 776 var
 777   a: Integer;
 778 begin
 779   SetLength(Whitelist, Length(Whitelist)+1);
 780   a := High(Whitelist);
 781   Whitelist[a] := LowerCase(cmd);
 782 end;
 783
 784 procedure segfault (p: SSArray);
 785 var
 786   pp: PByte = nil;
 787 begin
 788   pp^ := 0;
 789 end;
 790
 791 function GetCommandString (p: SSArray): AnsiString;
 792   var i: Integer;
 793 begin
 794   result := '';
 795   if Length(p) >= 1 then
 796   begin
 797     result := p[0];
 798     for i := 1 to High(p) do
 799       result := result + '; ' + p[i]
 800   end
 801 end;
 802
 803 function QuoteStr(str: String): String;
 804 begin
 805   if Pos(' ', str) > 0 then
 806     Result := '"' + str + '"'
 807   else
 808     Result := str;
 809 end;
 810
 811 procedure BindCommands (p: SSArray);
 812   var cmd, key: AnsiString; i: Integer;
 813 begin
 814   cmd := LowerCase(p[0]);
 815   case cmd of
 816   'bind':
 817     // bind <key> [down [up]]
 818     if (Length(p) >= 2) and (Length(p) <= 4) then
 819     begin
 820       i := 0;
 821       key := LowerCase(p[1]);
 822       while (i < e_MaxInputKeys) and (key <> LowerCase(e_KeyNames[i])) do inc(i);
 823       if i < e_MaxInputKeys then
 824       begin
 825         if Length(p) = 2 then
 826           g_Console_Add(QuoteStr(e_KeyNames[i]) + ' = ' + QuoteStr(GetCommandString(gInputBinds[i].down)) + ' ' + QuoteStr(GetCommandString(gInputBinds[i].up)))
 827         else if Length(p) = 3 then
 828           g_Console_BindKey(i, p[2], '')
 829         else (* len = 4 *)
 830           g_Console_BindKey(i, p[2], p[3])
 831       end
 832       else
 833         g_Console_Add('bind: "' + p[1] + '" is not a key')
 834     end
 835     else
 836     begin
 837       g_Console_Add('bind <key> <down action> [up action]')
 838     end;
 839   'bindrep':
 840     // bindrep <key>
 841     if Length(p) = 2 then
 842     begin
 843       key := LowerCase(p[1]);
 844       i := 0;
 845       while (i < e_MaxInputKeys) and (key <> LowerCase(e_KeyNames[i])) do inc(i);
 846       if i < e_MaxInputKeys then
 847         gInputBinds[i].rep := True
 848       else
 849         g_Console_Add('bindrep: "' + p[1] + '" is not a key')
 850     end
 851     else
 852       g_Console_Add('bindrep <key>');
 853   'bindunrep':
 854     // bindunrep <key>
 855     if Length(p) = 2 then
 856     begin
 857       key := LowerCase(p[1]);
 858       i := 0;
 859       while (i < e_MaxInputKeys) and (key <> LowerCase(e_KeyNames[i])) do inc(i);
 860       if i < e_MaxInputKeys then
 861         gInputBinds[i].rep := False
 862       else
 863         g_Console_Add('bindunrep: "' + p[1] + '" is not a key')
 864     end
 865     else
 866       g_Console_Add('bindunrep <key>');
 867   'bindlist':
 868     for i := 0 to e_MaxInputKeys - 1 do
 869       if (gInputBinds[i].down <> nil) or (gInputBinds[i].up <> nil) then
 870         g_Console_Add(e_KeyNames[i] + ' ' + QuoteStr(GetCommandString(gInputBinds[i].down)) + ' ' + QuoteStr(GetCommandString(gInputBinds[i].up)));
 871   'unbind':
 872     // unbind <key>
 873     if Length(p) = 2 then
 874     begin
 875       key := LowerCase(p[1]);
 876       i := 0;
 877       while (i < e_MaxInputKeys) and (key <> LowerCase(e_KeyNames[i])) do inc(i);
 878       if i < e_MaxInputKeys then
 879         g_Console_BindKey(i, '')
 880       else
 881         g_Console_Add('unbind: "' + p[1] + '" is not a key')
 882     end
 883     else
 884       g_Console_Add('unbind <key>');
 885   'unbindall':
 886     for i := 0 to e_MaxInputKeys - 1 do
 887       g_Console_BindKey(i, '');
 888   'showkeyboard':
 889     g_Touch_ShowKeyboard(True);
 890   'hidekeyboard':
 891     g_Touch_ShowKeyboard(False);
 892   'togglemenu':
 893     begin
 894       if gConsoleShow then
 895         g_Console_Switch
 896       else if gChatShow then
 897         g_Console_Chat_Switch
 898       else
 899         KeyPress(VK_ESCAPE);
 900       menu_toggled := True
 901     end;
 902   'toggleconsole':
 903     g_Console_Switch;
 904   'togglechat':
 905     g_Console_Chat_Switch;
 906   'toggleteamchat':
 907     if gGameSettings.GameMode in [GM_TDM, GM_CTF] then
 908       g_Console_Chat_Switch(True);
 909   end
 910 end;
 911
 912 procedure AddCommand(cmd: AnsiString; proc: TCmdProc; ahelp: AnsiString=''; ahidden: Boolean=false; acheat: Boolean=false);
 913 var
 914   a: Integer;
 915   cp: PCommand;
 916 begin
 917   SetLength(commands, Length(commands)+1);
 918   a := High(commands);
 919   cp := @commands[a];
 920   cp.cmd := LowerCase(cmd);
 921   cp.proc := proc;
 922   cp.procEx := nil;
 923   cp.help := ahelp;
 924   cp.hidden := ahidden;
 925   cp.ptr := nil;
 926   cp.msg := '';
 927   cp.cheat := acheat;
 928   cp.action := -1;
 929   cp.player := -1;
 930 end;
 931
 932 procedure AddAction (cmd: AnsiString; action: Integer; help: AnsiString = ''; hidden: Boolean = False; cheat: Boolean = False);
 933   const
 934     PrefixList: array [0..1] of AnsiString = ('+', '-');
 935     PlayerList: array [0..1] of Integer = (1, 2);
 936   var
 937     s: AnsiString;
 938     i: Integer;
 939
 940   procedure NewAction (cmd: AnsiString; player: Integer);
 941     var cp: PCommand;
 942   begin
 943     SetLength(commands, Length(commands) + 1);
 944     cp := @commands[High(commands)];
 945     cp.cmd := LowerCase(cmd);
 946     cp.proc := nil;
 947     cp.procEx := nil;
 948     cp.help := help;
 949     cp.hidden := hidden;
 950     cp.ptr := nil;
 951     cp.msg := '';
 952     cp.cheat := cheat;
 953     cp.action := action;
 954     cp.player := player;
 955   end;
 956
 957 begin
 958   ASSERT(action >= FIRST_ACTION);
 959   ASSERT(action <= LAST_ACTION);
 960   for s in PrefixList do
 961   begin
 962     NewAction(s + cmd, 0);
 963     for i in PlayerList do
 964       NewAction(s + 'p' + IntToStr(i) + '_' + cmd, i - 1)
 965   end
 966 end;
 967
 968 procedure ReadStdIn;
 969 var
 970   K: Char;
 971   KEv: TKeyEvent;
 972 begin
 973   gConsoleShow := True;
 974   InputReady := True;
 975   // one key per frame
 976   KEv := PollKeyEvent();
 977   if KEv <> 0 then
 978   begin
 979     K := GetKeyEventChar(TranslateKeyEvent(GetKeyEvent()));
 980     Write(K);
 981     case K of
 982       #8: g_Console_Control(IK_BACKSPACE);
 983       #10, #13: g_Console_Control(IK_RETURN);
 984       #32..#126: g_Console_Char(K);
 985       // arrow keys and DEL all return 0 for some reason, so fuck em
 986     end;
 987   end;
 988 end;
 989
 990 procedure g_Console_SysInit;
 991   var a: Integer;
 992 begin
 993   Cons_Y := -Floor(gScreenHeight * ConsoleHeight);
 994   gConsoleShow := False;
 995   gChatShow := False;
 996   Cons_Shown := False;
 997   InputReady := False;
 998   CPos := 1;
 999
1000   for a := 0 to High(MsgArray) do
1001     with MsgArray[a] do
1002     begin
1003       Msg := '';
1004       Time := 0;
1005     end;
1006
1007   AddCommand('segfault', segfault, 'make segfault');
1008
1009   AddCommand('quit', SystemCommands);
1010   AddCommand('exit', SystemCommands);
1011   AddCommand('r_reset', SystemCommands);
1012   AddCommand('r_maxfps', SystemCommands);
1013   AddCommand('g_language', SystemCommands);
1014
1015   AddCommand('bind', BindCommands);
1016   AddCommand('bindrep', BindCommands);
1017   AddCommand('bindunrep', BindCommands);
1018   AddCommand('bindlist', BindCommands);
1019   AddCommand('unbind', BindCommands);
1020   AddCommand('unbindall', BindCommands);
1021   AddCommand('showkeyboard', BindCommands);
1022   AddCommand('hidekeyboard', BindCommands);
1023   AddCommand('togglemenu', BindCommands);
1024   AddCommand('toggleconsole', BindCommands);
1025   AddCommand('togglechat', BindCommands);
1026   AddCommand('toggleteamchat', BindCommands);
1027
1028   AddCommand('clear', ConsoleCommands, 'clear console');
1029   AddCommand('clearhistory', ConsoleCommands);
1030   AddCommand('showhistory', ConsoleCommands);
1031   AddCommand('commands', ConsoleCommands);
1032   AddCommand('time', ConsoleCommands);
1033   AddCommand('date', ConsoleCommands);
1034   AddCommand('echo', ConsoleCommands);
1035   AddCommand('dump', ConsoleCommands);
1036   AddCommand('exec', ConsoleCommands);
1037   AddCommand('writeconfig', ConsoleCommands);
1038   AddCommand('alias', ConsoleCommands);
1039   AddCommand('call', ConsoleCommands);
1040   AddCommand('ver', ConsoleCommands);
1041   AddCommand('version', ConsoleCommands);
1042
1043   AddCommand('d_window', DebugCommands);
1044   AddCommand('d_sounds', DebugCommands);
1045   AddCommand('d_frames', DebugCommands);
1046   AddCommand('d_winmsg', DebugCommands);
1047   AddCommand('d_monoff', DebugCommands);
1048   AddCommand('d_botoff', DebugCommands);
1049   AddCommand('d_monster', DebugCommands);
1050   AddCommand('d_health', DebugCommands);
1051   AddCommand('d_player', DebugCommands);
1052   AddCommand('d_joy', DebugCommands);
1053   AddCommand('d_mem', DebugCommands);
1054
1055   AddCommand('p1_name', PlayerSettingsCVars);
1056   AddCommand('p2_name', PlayerSettingsCVars);
1057   AddCommand('p1_color', PlayerSettingsCVars);
1058   AddCommand('p2_color', PlayerSettingsCVars);
1059   AddCommand('p1_model', PlayerSettingsCVars);
1060   AddCommand('p2_model', PlayerSettingsCVars);
1061   AddCommand('p1_team', PlayerSettingsCVars);
1062   AddCommand('p2_team', PlayerSettingsCVars);
1063   AddCommand('p1_autoswitch', PlayerSettingsCVars);
1064   AddCommand('p2_autoswitch', PlayerSettingsCVars);
1065   AddCommand('p1_switch_empty', PlayerSettingsCVars);
1066   AddCommand('p2_switch_empty', PlayerSettingsCVars);
1067   AddCommand('p1_skip_fist', PlayerSettingsCVars);
1068   AddCommand('p2_skip_fist', PlayerSettingsCVars);
1069   AddCommand('p1_priority_kastet', PlayerSettingsCVars);
1070   AddCommand('p2_priority_kastet', PlayerSettingsCVars);
1071   AddCommand('p1_priority_saw', PlayerSettingsCVars);
1072   AddCommand('p2_priority_saw', PlayerSettingsCVars);
1073   AddCommand('p1_priority_pistol', PlayerSettingsCVars);
1074   AddCommand('p2_priority_pistol', PlayerSettingsCVars);
1075   AddCommand('p1_priority_shotgun1', PlayerSettingsCVars);
1076   AddCommand('p2_priority_shotgun1', PlayerSettingsCVars);
1077   AddCommand('p1_priority_shotgun2', PlayerSettingsCVars);
1078   AddCommand('p2_priority_shotgun2', PlayerSettingsCVars);
1079   AddCommand('p1_priority_chaingun', PlayerSettingsCVars);
1080   AddCommand('p2_priority_chaingun', PlayerSettingsCVars);
1081   AddCommand('p1_priority_rocketlauncher', PlayerSettingsCVars);
1082   AddCommand('p2_priority_rocketlauncher', PlayerSettingsCVars);
1083   AddCommand('p1_priority_plasma', PlayerSettingsCVars);
1084   AddCommand('p2_priority_plasma', PlayerSettingsCVars);
1085   AddCommand('p1_priority_bfg', PlayerSettingsCVars);
1086   AddCommand('p2_priority_bfg', PlayerSettingsCVars);
1087   AddCommand('p1_priority_super', PlayerSettingsCVars);
1088   AddCommand('p2_priority_super', PlayerSettingsCVars);
1089   AddCommand('p1_priority_flamethrower', PlayerSettingsCVars);
1090   AddCommand('p2_priority_flamethrower', PlayerSettingsCVars);
1091   AddCommand('p1_priority_berserk', PlayerSettingsCVars);
1092   AddCommand('p2_priority_berserk', PlayerSettingsCVars);
1093
1094   AddCommand('g_max_particles', GameCVars);
1095   AddCommand('g_max_shells', GameCVars);
1096   AddCommand('g_max_gibs', GameCVars);
1097   AddCommand('g_max_corpses', GameCVars);
1098   AddCommand('g_force_model', GameCVars);
1099   AddCommand('g_force_model_name', GameCVars);
1100   AddCommand('g_gamemode', GameCVars);
1101   AddCommand('g_friendlyfire', GameCVars);
1102   AddCommand('g_friendly_hit_trace', GameCVars);
1103   AddCommand('g_friendly_hit_projectile', GameCVars);
1104   AddCommand('g_friendly_absorb_damage', GameCVars);
1105   AddCommand('g_weaponstay', GameCVars);
1106   AddCommand('g_allow_exit', GameCVars);
1107   AddCommand('g_dm_keys', GameCVars);
1108   AddCommand('g_allow_monsters', GameCVars);
1109   AddCommand('g_allow_dropflag', GameCVars);
1110   AddCommand('g_throw_flag', GameCVars);
1111   AddCommand('g_bot_vsmonsters', GameCVars);
1112   AddCommand('g_bot_vsplayers', GameCVars);
1113   AddCommand('g_max_bots', GameCVars); // intentionally not whitelisted
1114   AddCommand('g_scorelimit', GameCVars);
1115   AddCommand('g_timelimit', GameCVars);
1116   AddCommand('g_maxlives', GameCVars);
1117   AddCommand('g_warmup_time', GameCVars);
1118   AddCommand('g_spawn_invul', GameCVars);
1119   AddCommand('g_item_respawn_time', GameCVars);
1120   AddCommand('g_item_time_random', GameCVars);
1121   AddCommand('g_powerup_randomize_respawn', GameCVars);
1122   AddCommand('g_powerup_respawn_time', GameCVars);
1123   AddCommand('g_powerup_time_random', GameCVars);
1124   AddCommand('sv_intertime', GameCVars);
1125
1126   AddCommand('sv_name', NetServerCVars);
1127   AddCommand('sv_passwd', NetServerCVars);
1128   AddCommand('sv_maxplrs', NetServerCVars);
1129   AddCommand('sv_public', NetServerCVars);
1130   AddCommand('sv_port', NetServerCVars);
1131
1132   AddCommand('pause', GameCommands);
1133   AddCommand('endgame', GameCommands);
1134   AddCommand('restart', GameCommands);
1135   AddCommand('addbot', GameCommands);
1136   AddCommand('bot_add', GameCommands);
1137   AddCommand('bot_addlist', GameCommands);
1138   AddCommand('bot_addred', GameCommands);
1139   AddCommand('bot_addblue', GameCommands);
1140   AddCommand('bot_removeall', GameCommands);
1141   AddCommand('chat', GameCommands);
1142   AddCommand('teamchat', GameCommands);
1143   AddCommand('announce', GameCommands);
1144   AddCommand('an', GameCommands);
1145   AddCommand('game', GameCommands);
1146   AddCommand('host', GameCommands);
1147   AddCommand('map', GameCommands);
1148   AddCommand('nextmap', GameCommands);
1149   AddCommand('endmap', GameCommands);
1150   AddCommand('goodbye', GameCommands);
1151   AddCommand('suicide', GameCommands);
1152   AddCommand('spectate', GameCommands);
1153   AddCommand('ready', GameCommands);
1154   AddCommand('kick', GameCommands);
1155   AddCommand('kick_id', GameCommands);
1156   AddCommand('kick_pid', GameCommands);
1157   AddCommand('ban', GameCommands);
1158   AddCommand('ban_id', GameCommands);
1159   AddCommand('ban_pid', GameCommands);
1160   AddCommand('permban', GameCommands);
1161   AddCommand('permban_id', GameCommands);
1162   AddCommand('permban_pid', GameCommands);
1163   AddCommand('permban_ip', GameCommands);
1164   AddCommand('unban', GameCommands);
1165   AddCommand('connect', GameCommands);
1166   AddCommand('disconnect', GameCommands);
1167   AddCommand('reconnect', GameCommands);
1168   AddCommand('say', GameCommands);
1169   AddCommand('tell', GameCommands);
1170   AddCommand('centerprint', GameCommands);
1171   AddCommand('overtime', GameCommands);
1172   AddCommand('rcon_password', GameCommands);
1173   AddCommand('rcon', GameCommands);
1174   AddCommand('callvote', GameCommands);
1175   AddCommand('vote', GameCommands);
1176   AddCommand('clientlist', GameCommands);
1177   AddCommand('event', GameCommands);
1178   AddCommand('screenshot', GameCommands);
1179   AddCommand('weapnext', GameCommands);
1180   AddCommand('weapprev', GameCommands);
1181   AddCommand('weapon', GameCommands);
1182   AddCommand('dropflag', GameCommands);
1183   AddCommand('p1_weapnext', GameCommands);
1184   AddCommand('p1_weapprev', GameCommands);
1185   AddCommand('p1_weapon', GameCommands);
1186   AddCommand('p1_weapbest', GameCommands);
1187   AddCommand('p1_dropflag', GameCommands);
1188   AddCommand('p2_weapnext', GameCommands);
1189   AddCommand('p2_weapprev', GameCommands);
1190   AddCommand('p2_weapon', GameCommands);
1191   AddCommand('p2_weapbest', GameCommands);
1192   AddCommand('p2_dropflag', GameCommands);
1193
1194   AddCommand('god', GameCheats);
1195   AddCommand('notarget', GameCheats);
1196   AddCommand('give', GameCheats); // "exit" too ;-)
1197   AddCommand('open', GameCheats);
1198   AddCommand('fly', GameCheats);
1199   AddCommand('noclip', GameCheats);
1200   AddCommand('speedy', GameCheats);
1201   AddCommand('jumpy', GameCheats);
1202   AddCommand('noreload', GameCheats);
1203   AddCommand('aimline', GameCheats);
1204   AddCommand('automap', GameCheats);
1205
1206   AddAction('jump', ACTION_JUMP);
1207   AddAction('moveleft', ACTION_MOVELEFT);
1208   AddAction('moveright', ACTION_MOVERIGHT);
1209   AddAction('lookup', ACTION_LOOKUP);
1210   AddAction('lookdown', ACTION_LOOKDOWN);
1211   AddAction('attack', ACTION_ATTACK);
1212   AddAction('scores', ACTION_SCORES);
1213   AddAction('activate', ACTION_ACTIVATE);
1214   AddAction('strafe', ACTION_STRAFE);
1215
1216   WhitelistCommand('say');
1217   WhitelistCommand('tell');
1218   WhitelistCommand('overtime');
1219   WhitelistCommand('ready');
1220   WhitelistCommand('map');
1221   WhitelistCommand('nextmap');
1222   WhitelistCommand('endmap');
1223   WhitelistCommand('restart');
1224   WhitelistCommand('kick');
1225   WhitelistCommand('kick_pid');
1226   WhitelistCommand('ban');
1227   WhitelistCommand('ban_pid');
1228   WhitelistCommand('centerprint');
1229
1230   WhitelistCommand('addbot');
1231   WhitelistCommand('bot_add');
1232   WhitelistCommand('bot_addred');
1233   WhitelistCommand('bot_addblue');
1234   WhitelistCommand('bot_removeall');
1235
1236   WhitelistCommand('g_gamemode');
1237   WhitelistCommand('g_friendlyfire');
1238   WhitelistCommand('g_friendly_hit_trace');
1239   WhitelistCommand('g_friendly_hit_projectile');
1240   WhitelistCommand('g_friendly_absorb_damage');
1241   WhitelistCommand('g_weaponstay');
1242   WhitelistCommand('g_allow_exit');
1243   WhitelistCommand('g_dm_keys');
1244   WhitelistCommand('g_allow_monsters');
1245   WhitelistCommand('g_bot_vsmonsters');
1246   WhitelistCommand('g_bot_vsplayers');
1247   WhitelistCommand('g_scorelimit');
1248   WhitelistCommand('g_timelimit');
1249   WhitelistCommand('g_maxlives');
1250   WhitelistCommand('g_warmup_time');
1251   WhitelistCommand('g_spawn_invul');
1252   WhitelistCommand('g_item_respawn_time');
1253   WhitelistCommand('g_item_time_random');
1254   WhitelistCommand('g_powerup_randomize_respawn');
1255   WhitelistCommand('g_powerup_respawn_time');
1256   WhitelistCommand('g_powerup_time_random');
1257
1258   g_Console_ResetBinds;
1259   g_Console_ReadConfig(gConfigScript);
1260   g_Console_ReadConfig(autoexecScript);
1261   gParsingBinds := False;
1262 end;
1263
1264 procedure g_Console_Init;
1265 begin
1266   g_Texture_CreateWAD(ID, GameWAD+':TEXTURES\CONSOLE');
1267   g_Console_Add(Format(_lc[I_CONSOLE_WELCOME], [GAME_VERSION]));
1268   g_Console_Add('');
1269 {$IFDEF HEADLESS}
1270   if ConsoleStdIn then
1271   begin
1272     InitKeyboard();
1273     conbufStdOutRawMode := true;
1274   end;
1275 {$ENDIF}
1276 end;
1277
1278 procedure g_Console_Update;
1279 var
1280   a, b, Step: Integer;
1281 begin
1282 {$IFDEF HEADLESS}
1283   if ConsoleStdIn then
1284     ReadStdIn();
1285 {$ENDIF}
1286
1287   if Cons_Shown then
1288   begin
1289     Step := Max(1, Round(Floor(gScreenHeight * ConsoleHeight) * ConsoleStep));
1290     if gConsoleShow then
1291     begin
1292       (* Open animation *)
1293       Cons_Y := Min(Cons_Y + Step, 0);
1294       InputReady := True
1295     end
1296     else
1297     begin
1298       (* Close animation *)
1299       Cons_Y := Max(Cons_Y - Step, -Floor(gScreenHeight * ConsoleHeight));
1300       Cons_Shown := Cons_Y > -Floor(gScreenHeight * ConsoleHeight);
1301       InputReady := False
1302     end;
1303
1304     if gChatShow then
1305       InputReady := True
1306   end;
1307
1308   a := 0;
1309   while a <= High(MsgArray) do
1310   begin
1311     if MsgArray[a].Time > 0 then
1312     begin
1313       if MsgArray[a].Time = 1 then
1314         begin
1315           if a < High(MsgArray) then
1316           begin
1317             for b := a to High(MsgArray)-1 do
1318               MsgArray[b] := MsgArray[b+1];
1319
1320             MsgArray[High(MsgArray)].Time := 0;
1321
1322             a := a - 1;
1323           end;
1324         end
1325       else
1326         Dec(MsgArray[a].Time);
1327     end;
1328
1329     a := a + 1;
1330   end;
1331 end;
1332
1333
1334 procedure drawConsoleText ();
1335 var
1336   CWidth, CHeight: Byte;
1337   ty: Integer;
1338   sp, ep: LongWord;
1339   skip: Integer;
1340
1341   procedure putLine (sp, ep: LongWord);
1342   var
1343     p: LongWord;
1344     wdt, cw: Integer;
1345   begin
1346     p := sp;
1347     wdt := 0;
1348     while p <> ep do
1349     begin
1350       cw := e_TextureFontCharWidth(cbufAt(p), gStdFont);
1351       if wdt+cw > gScreenWidth-8 then break;
1352       //e_TextureFontPrintChar(X, Y: Integer; Ch: Char; FontID: DWORD; Shadow: Boolean = False);
1353       Inc(wdt, cw);
1354       cbufNext(p);
1355     end;
1356     if p <> ep then putLine(p, ep); // do rest of the line first
1357     // now print our part
1358     if skip = 0 then
1359     begin
1360       ep := p;
1361       p := sp;
1362       wdt := 2;
1363       while p <> ep do
1364       begin
1365         cw := e_TextureFontCharWidth(cbufAt(p), gStdFont);
1366         e_TextureFontPrintCharEx(wdt, ty, cbufAt(p), gStdFont);
1367         Inc(wdt, cw);
1368         cbufNext(p);
1369       end;
1370       Dec(ty, CHeight);
1371     end
1372     else
1373     begin
1374       Dec(skip);
1375     end;
1376   end;
1377
1378 begin
1379   e_TextureFontGetSize(gStdFont, CWidth, CHeight);
1380   ty := Floor(gScreenHeight * ConsoleHeight) - 4 - 2 * CHeight - Abs(Cons_Y);
1381   skip := conSkipLines;
1382   cbufLastLine(sp, ep);
1383   repeat
1384     putLine(sp, ep);
1385     if ty+CHeight <= 0 then break;
1386   until not cbufLineUp(sp, ep);
1387 end;
1388
1389 procedure g_Console_Draw(MessagesOnly: Boolean = False);
1390 var
1391   CWidth, CHeight: Byte;
1392   mfW, mfH: Word;
1393   a, b, offset_y: Integer;
1394 begin
1395   e_TextureFontGetSize(gStdFont, CWidth, CHeight);
1396
1397   if ChatTop and gChatShow then
1398     offset_y := CHeight
1399   else
1400     offset_y := 0;
1401
1402   for a := 0 to High(MsgArray) do
1403     if MsgArray[a].Time > 0 then
1404       e_TextureFontPrintFmt(0, offset_y + CHeight * a, MsgArray[a].Msg, gStdFont, True);
1405
1406   if MessagesOnly then Exit;
1407
1408   if gChatShow then
1409   begin
1410     if ChatTop then
1411       offset_y := 0
1412     else
1413       offset_y := gScreenHeight - CHeight - 1;
1414     if gChatTeam then
1415     begin
1416       e_TextureFontPrintEx(0, offset_y, 'say team> ' + Line, gStdFont, 255, 255, 255, 1, True);
1417       e_TextureFontPrintEx((CPos + 9) * CWidth, offset_y, '_', gStdFont, 255, 255, 255, 1, True);
1418     end
1419     else
1420     begin
1421       e_TextureFontPrintEx(0, offset_y, 'say> ' + Line, gStdFont, 255, 255, 255, 1, True);
1422       e_TextureFontPrintEx((CPos + 4) * CWidth, offset_y, '_', gStdFont, 255, 255, 255, 1, True);
1423     end
1424   end;
1425
1426   if not Cons_Shown then
1427     Exit;
1428
1429   if gDebugMode then
1430   begin
1431     e_CharFont_GetSize(gMenuFont, DEBUG_STRING, mfW, mfH);
1432     a := (gScreenWidth - 2*mfW) div 2;
1433     b := Cons_Y + (Floor(gScreenHeight * ConsoleHeight) - 2 * mfH) div 2;
1434     e_CharFont_PrintEx(gMenuFont, a div 2, b div 2, DEBUG_STRING,
1435                        _RGB(128, 0, 0), 2.0);
1436   end;
1437
1438   e_DrawSize(ID, 0, Cons_Y, Round(ConsoleTrans * 255), False, False, gScreenWidth, Floor(gScreenHeight * ConsoleHeight));
1439   e_TextureFontPrint(0, Cons_Y + Floor(gScreenHeight * ConsoleHeight) - CHeight - 4, '> ' + Line, gStdFont);
1440
1441   drawConsoleText();
1442   (*
1443   if ConsoleHistory <> nil then
1444   begin
1445     b := 0;
1446     if CHeight > 0 then
1447       if Length(ConsoleHistory) > (Floor(gScreenHeight * ConsoleHeight) div CHeight) - 1 then
1448         b := Length(ConsoleHistory) - (Floor(gScreenHeight * ConsoleHeight) div CHeight) + 1;
1449
1450     b := Max(b-Offset, 0);
1451     d := Max(High(ConsoleHistory)-Offset, 0);
1452
1453     c := 2;
1454     for a := d downto b do
1455     begin
1456       e_TextureFontPrintFmt(0, Floor(gScreenHeight * ConsoleHeight) - 4 - c * CHeight - Abs(Cons_Y), ConsoleHistory[a], gStdFont, True);
1457       c := c + 1;
1458     end;
1459   end;
1460   *)
1461
1462   e_TextureFontPrint((CPos + 1) * CWidth, Cons_Y + Floor(gScreenHeight * ConsoleHeight) - 21, '_', gStdFont);
1463 end;
1464
1465 procedure g_Console_Char(C: AnsiChar);
1466 begin
1467   if InputReady and (gConsoleShow or gChatShow) then
1468   begin
1469     Insert(C, Line, CPos);
1470     CPos := CPos + 1;
1471   end
1472 end;
1473
1474
1475 var
1476   tcomplist: array of AnsiString = nil;
1477   tcompidx: array of Integer = nil;
1478
1479 procedure Complete ();
1480 var
1481   i, c: Integer;
1482   tused: Integer;
1483   ll, lpfx, cmd: AnsiString;
1484 begin
1485   if (Length(Line) = 0) then
1486   begin
1487     g_Console_Add('');
1488     for i := 0 to High(commands) do
1489     begin
1490       // hidden commands are hidden when cheats aren't enabled
1491       if commands[i].hidden and not conIsCheatsEnabled then continue;
1492       if (Length(commands[i].help) > 0) then
1493       begin
1494         g_Console_Add('  '+commands[i].cmd+' -- '+commands[i].help);
1495       end
1496       else
1497       begin
1498         g_Console_Add('  '+commands[i].cmd);
1499       end;
1500     end;
1501     exit;
1502   end;
1503
1504   ll := LowerCase(Line);
1505   lpfx := '';
1506
1507   if (Length(ll) > 1) and (ll[Length(ll)] = ' ') then
1508   begin
1509     ll := Copy(ll, 0, Length(ll)-1);
1510     for i := 0 to High(commands) do
1511     begin
1512       // hidden commands are hidden when cheats aren't enabled
1513       if commands[i].hidden and not conIsCheatsEnabled then continue;
1514       if (commands[i].cmd = ll) then
1515       begin
1516         if (Length(commands[i].help) > 0) then
1517         begin
1518           g_Console_Add('  '+commands[i].cmd+' -- '+commands[i].help);
1519         end;
1520       end;
1521     end;
1522     exit;
1523   end;
1524
1525   // build completion list
1526   tused := 0;
1527   for i := 0 to High(commands) do
1528   begin
1529     // hidden commands are hidden when cheats aren't enabled
1530     if commands[i].hidden and not conIsCheatsEnabled then continue;
1531     cmd := commands[i].cmd;
1532     if (Length(cmd) >= Length(ll)) and (ll = Copy(cmd, 0, Length(ll))) then
1533     begin
1534       if (tused = Length(tcomplist)) then
1535       begin
1536         SetLength(tcomplist, Length(tcomplist)+128);
1537         SetLength(tcompidx, Length(tcompidx)+128);
1538       end;
1539       tcomplist[tused] := cmd;
1540       tcompidx[tused] := i;
1541       Inc(tused);
1542       if (Length(cmd) > Length(lpfx)) then lpfx := cmd;
1543     end;
1544   end;
1545
1546   // get longest prefix
1547   for i := 0 to tused-1 do
1548   begin
1549     cmd := tcomplist[i];
1550     for c := 1 to Length(lpfx) do
1551     begin
1552       if (c > Length(cmd)) then break;
1553       if (cmd[c] <> lpfx[c]) then begin lpfx := Copy(lpfx, 0, c-1); break; end;
1554     end;
1555   end;
1556
1557   if (tused = 0) then exit;
1558
1559   if (tused = 1) then
1560   begin
1561     Line := tcomplist[0]+' ';
1562     CPos := Length(Line)+1;
1563   end
1564   else
1565   begin
1566     // has longest prefix?
1567     if (Length(lpfx) > Length(ll)) then
1568     begin
1569       Line := lpfx;
1570       CPos:= Length(Line)+1;
1571     end
1572     else
1573     begin
1574       g_Console_Add('');
1575       for i := 0 to tused-1 do
1576       begin
1577         if (Length(commands[tcompidx[i]].help) > 0) then
1578         begin
1579           g_Console_Add('  '+tcomplist[i]+' -- '+commands[tcompidx[i]].help);
1580         end
1581         else
1582         begin
1583           g_Console_Add('  '+tcomplist[i]);
1584         end;
1585       end;
1586     end;
1587   end;
1588 end;
1589
1590
1591 procedure g_Console_Control(K: Word);
1592 begin
1593   case K of
1594     IK_BACKSPACE:
1595       if (Length(Line) > 0) and (CPos > 1) then
1596       begin
1597         Delete(Line, CPos-1, 1);
1598         CPos := CPos-1;
1599       end;
1600     IK_DELETE:
1601       if (Length(Line) > 0) and (CPos <= Length(Line)) then
1602         Delete(Line, CPos, 1);
1603     IK_LEFT, IK_KPLEFT, VK_LEFT, JOY0_LEFT, JOY1_LEFT, JOY2_LEFT, JOY3_LEFT:
1604       if CPos > 1 then
1605         CPos := CPos - 1;
1606     IK_RIGHT, IK_KPRIGHT, VK_RIGHT, JOY0_RIGHT, JOY1_RIGHT, JOY2_RIGHT, JOY3_RIGHT:
1607       if CPos <= Length(Line) then
1608         CPos := CPos + 1;
1609     IK_RETURN, IK_KPRETURN, VK_OPEN, VK_FIRE, JOY0_ATTACK, JOY1_ATTACK, JOY2_ATTACK, JOY3_ATTACK:
1610     begin
1611       if gConsoleShow then
1612         g_Console_Process(Line)
1613       else
1614         if gChatShow then
1615         begin
1616           if (Length(Line) > 0) and g_Game_IsNet then
1617           begin
1618             if gChatTeam then
1619             begin
1620               if g_Game_IsClient then
1621                 MC_SEND_Chat(b_Text_Format(Line), NET_CHAT_TEAM)
1622               else
1623                 MH_SEND_Chat('[' + gPlayer1Settings.name + ']: ' + b_Text_Format(Line),
1624                   NET_CHAT_TEAM, gPlayer1Settings.Team);
1625             end
1626             else
1627             begin
1628               if g_Game_IsClient then
1629                 MC_SEND_Chat(b_Text_Format(Line), NET_CHAT_PLAYER)
1630               else
1631                 MH_SEND_Chat('[' + gPlayer1Settings.name + ']: ' + b_Text_Format(Line),
1632                 NET_CHAT_PLAYER);
1633             end;
1634           end;
1635
1636           Line := '';
1637           CPos := 1;
1638           gJustChatted := True;
1639           g_Console_Chat_Switch;
1640           InputReady := False;
1641         end;
1642     end;
1643     IK_TAB:
1644       if not gChatShow then
1645         Complete();
1646     IK_DOWN, IK_KPDOWN, VK_DOWN, JOY0_DOWN, JOY1_DOWN, JOY2_DOWN, JOY3_DOWN:
1647       if not gChatShow then
1648         if (CommandHistory <> nil) and
1649            (CmdIndex < Length(CommandHistory)) then
1650         begin
1651           if CmdIndex < Length(CommandHistory)-1 then
1652             CmdIndex := CmdIndex + 1;
1653           Line := CommandHistory[CmdIndex];
1654           CPos := Length(Line) + 1;
1655         end;
1656     IK_UP, IK_KPUP, VK_UP, JOY0_UP, JOY1_UP, JOY2_UP, JOY3_UP:
1657       if not gChatShow then
1658         if (CommandHistory <> nil) and
1659            (CmdIndex <= Length(CommandHistory)) then
1660         begin
1661           if CmdIndex > 0 then
1662             CmdIndex := CmdIndex - 1;
1663           Line := CommandHistory[CmdIndex];
1664           Cpos := Length(Line) + 1;
1665         end;
1666     IK_PAGEUP, IK_KPPAGEUP, VK_PREV, JOY0_PREV, JOY1_PREV, JOY2_PREV, JOY3_PREV: // PgUp
1667       if not gChatShow then Inc(conSkipLines);
1668     IK_PAGEDN, IK_KPPAGEDN, VK_NEXT, JOY0_NEXT, JOY1_NEXT, JOY2_NEXT, JOY3_NEXT: // PgDown
1669       if not gChatShow and (conSkipLines > 0) then Dec(conSkipLines);
1670     IK_HOME, IK_KPHOME:
1671       CPos := 1;
1672     IK_END, IK_KPEND:
1673       CPos := Length(Line) + 1;
1674     IK_A..IK_Z, IK_SPACE, IK_SHIFT, IK_RSHIFT, IK_CAPSLOCK, IK_LBRACKET, IK_RBRACKET,
1675     IK_SEMICOLON, IK_QUOTE, IK_BACKSLASH, IK_SLASH, IK_COMMA, IK_DOT, (*IK_EQUALS,*)
1676     IK_0, IK_1, IK_2, IK_3, IK_4, IK_5, IK_6, IK_7, IK_8, IK_9, IK_MINUS, IK_EQUALS:
1677       (* see TEXTINPUT event *)
1678   end
1679 end;
1680
1681 function GetStr(var Str: AnsiString): AnsiString;
1682 var
1683   a, b: Integer;
1684 begin
1685   Result := '';
1686   if Str[1] = '"' then
1687   begin
1688     for b := 1 to Length(Str) do
1689       if (b = Length(Str)) or (Str[b+1] = '"') then
1690       begin
1691         Result := Copy(Str, 2, b-1);
1692         Delete(Str, 1, b+1);
1693         Str := Trim(Str);
1694         Exit;
1695       end;
1696   end;
1697
1698   for a := 1 to Length(Str) do
1699     if (a = Length(Str)) or (Str[a+1] = ' ') then
1700     begin
1701       Result := Copy(Str, 1, a);
1702       Delete(Str, 1, a+1);
1703       Str := Trim(Str);
1704       Exit;
1705     end;
1706 end;
1707
1708 function ParseString(Str: AnsiString): SSArray;
1709 begin
1710   Result := nil;
1711
1712   Str := Trim(Str);
1713
1714   if Str = '' then
1715     Exit;
1716
1717   while Str <> '' do
1718   begin
1719     SetLength(Result, Length(Result)+1);
1720     Result[High(Result)] := GetStr(Str);
1721   end;
1722 end;
1723
1724 procedure g_Console_Add (L: AnsiString; show: Boolean=false);
1725
1726   procedure conmsg (s: AnsiString);
1727   var
1728     a: Integer;
1729   begin
1730     if length(s) = 0 then exit;
1731     for a := 0 to High(MsgArray) do
1732     begin
1733       with MsgArray[a] do
1734       begin
1735         if Time = 0 then
1736         begin
1737           Msg := s;
1738           Time := MsgTime;
1739           exit;
1740         end;
1741       end;
1742     end;
1743     for a := 0 to High(MsgArray)-1 do MsgArray[a] := MsgArray[a+1];
1744     with MsgArray[High(MsgArray)] do
1745     begin
1746       Msg := L;
1747       Time := MsgTime;
1748     end;
1749   end;
1750
1751 var
1752   f: Integer;
1753 begin
1754   // put it to console
1755   cbufPut(L);
1756   if (length(L) = 0) or ((L[length(L)] <> #10) and (L[length(L)] <> #13)) then cbufPut(#10);
1757
1758   // now show 'em out of console too
1759   show := show and gAllowConsoleMessages;
1760   if show and gShowMessages then
1761   begin
1762     // Âûâîä ñòðîê ñ ïåðåíîñàìè ïî î÷åðåäè
1763     while length(L) > 0 do
1764     begin
1765       f := Pos(#10, L);
1766       if f <= 0 then f := length(L)+1;
1767       conmsg(Copy(L, 1, f-1));
1768       Delete(L, 1, f);
1769     end;
1770   end;
1771
1772   //SetLength(ConsoleHistory, Length(ConsoleHistory)+1);
1773   //ConsoleHistory[High(ConsoleHistory)] := L;
1774
1775   (*
1776 {$IFDEF HEADLESS}
1777   e_WriteLog('CON: ' + L, MSG_NOTIFY);
1778 {$ENDIF}
1779   *)
1780 end;
1781
1782
1783 var
1784   consolewriterLastWasEOL: Boolean = false;
1785
1786 procedure consolewriter (constref buf; len: SizeUInt);
1787 var
1788   b: PByte;
1789 begin
1790   if (len < 1) then exit;
1791   b := PByte(@buf);
1792   consolewriterLastWasEOL := (b[len-1] = 13) or (b[len-1] = 10);
1793   while (len > 0) do
1794   begin
1795     if (b[0] <> 13) and (b[0] <> 10) then
1796     begin
1797       cbufPut(AnsiChar(b[0]));
1798     end
1799     else
1800     begin
1801       if (len > 1) and (b[0] = 13) then begin len -= 1; b += 1; end;
1802       cbufPut(#10);
1803     end;
1804     len -= 1;
1805     b += 1;
1806   end;
1807 end;
1808
1809
1810 // returns formatted string if `writerCB` is `nil`, empty string otherwise
1811 //function formatstrf (const fmt: AnsiString; args: array of const; writerCB: TFormatStrFCallback=nil): AnsiString;
1812 //TFormatStrFCallback = procedure (constref buf; len: SizeUInt);
1813 procedure conwriteln (const s: AnsiString; show: Boolean=false);
1814 begin
1815   g_Console_Add(s, show);
1816 end;
1817
1818
1819 procedure conwritefln (const s: AnsiString; args: array of const; show: Boolean=false);
1820 begin
1821   if show then
1822   begin
1823     g_Console_Add(formatstrf(s, args), true);
1824   end
1825   else
1826   begin
1827     consolewriterLastWasEOL := false;
1828     formatstrf(s, args, consolewriter);
1829     if not consolewriterLastWasEOL then cbufPut(#10);
1830   end;
1831 end;
1832
1833
1834 procedure g_Console_Clear();
1835 begin
1836   //ConsoleHistory := nil;
1837   cbufClear();
1838   conSkipLines := 0;
1839 end;
1840
1841 procedure AddToHistory(L: AnsiString);
1842 var
1843   len: Integer;
1844 begin
1845   len := Length(CommandHistory);
1846
1847   if (len = 0) or
1848      (LowerCase(CommandHistory[len-1]) <> LowerCase(L)) then
1849   begin
1850     SetLength(CommandHistory, len+1);
1851     CommandHistory[len] := L;
1852   end;
1853
1854   CmdIndex := Length(CommandHistory);
1855 end;
1856
1857 function g_Console_CommandBlacklisted(C: AnsiString): Boolean;
1858 var
1859   Arr: SSArray;
1860   i: Integer;
1861 begin
1862   Result := True;
1863
1864   Arr := nil;
1865
1866   if Trim(C) = '' then
1867     Exit;
1868
1869   Arr := ParseString(C);
1870   if Arr = nil then
1871     Exit;
1872
1873   for i := 0 to High(Whitelist) do
1874     if Whitelist[i] = LowerCase(Arr[0]) then
1875       Result := False;
1876 end;
1877
1878 procedure g_Console_Process(L: AnsiString; quiet: Boolean = False);
1879 var
1880   Arr: SSArray;
1881   i: Integer;
1882 begin
1883   Arr := nil;
1884
1885   if Trim(L) = '' then
1886     Exit;
1887
1888   conSkipLines := 0; // "unscroll"
1889
1890   if L = 'goobers' then
1891   begin
1892     Line := '';
1893     CPos := 1;
1894     gCheats := true;
1895     g_Console_Add('Your memory serves you well.');
1896     exit;
1897   end;
1898
1899   if not quiet then
1900   begin
1901     g_Console_Add('> '+L);
1902     Line := '';
1903     CPos := 1;
1904   end;
1905
1906   Arr := ParseString(L);
1907   if Arr = nil then
1908     Exit;
1909
1910   if commands = nil then
1911     Exit;
1912
1913   if not quiet then
1914     AddToHistory(L);
1915
1916   for i := 0 to High(commands) do
1917   begin
1918     if commands[i].cmd = LowerCase(Arr[0]) then
1919     begin
1920       if commands[i].action >= 0 then
1921       begin
1922         gPlayerAction[commands[i].player, commands[i].action] := commands[i].cmd[1] = '+';
1923         exit
1924       end;
1925       if assigned(commands[i].procEx) then
1926       begin
1927         commands[i].procEx(@commands[i], Arr);
1928         exit
1929       end;
1930       if assigned(commands[i].proc) then
1931       begin
1932         commands[i].proc(Arr);
1933         exit
1934       end
1935     end
1936   end;
1937
1938   g_Console_Add(Format(_lc[I_CONSOLE_UNKNOWN], [Arr[0]]));
1939 end;
1940
1941
1942 function g_Console_Interactive: Boolean;
1943 begin
1944   Result := gConsoleShow
1945 end;
1946
1947 procedure g_Console_BindKey (key: Integer; down: AnsiString; up: AnsiString = ''; rep: Boolean = False);
1948 begin
1949   //e_LogWritefln('bind "%s" "%s" <%s>', [LowerCase(e_KeyNames[key]), cmd, key]);
1950   ASSERT(key >= 0);
1951   ASSERT(key < e_MaxInputKeys);
1952   if key > 0 then
1953   begin
1954     gInputBinds[key].rep := rep;
1955     gInputBinds[key].down := ParseAlias(down);
1956     gInputBinds[key].up := ParseAlias(up);
1957   end;
1958   g_Console_WriteGameConfig();
1959 end;
1960
1961 function g_Console_MatchBind (key: Integer; down: AnsiString; up: AnsiString = ''): Boolean;
1962
1963   function EqualsCommandLists (a, b: SSArray): Boolean;
1964     var i, len: Integer;
1965   begin
1966     result := False;
1967     len := Length(a);
1968     if len = Length(b) then
1969     begin
1970       i := 0;
1971       while (i < len) and (a[i] = b[i]) do inc(i);
1972       if i >= len then
1973         result := True
1974     end
1975   end;
1976
1977 begin
1978   ASSERT(key >= 0);
1979   ASSERT(key < e_MaxInputKeys);
1980   result := EqualsCommandLists(ParseAlias(down), gInputBinds[key].down) and EqualsCommandLists(ParseAlias(up), gInputBinds[key].up)
1981 end;
1982
1983 function g_Console_FindBind (n: Integer; down: AnsiString; up: AnsiString = ''): Integer;
1984   var i: Integer;
1985 begin
1986   ASSERT(n >= 1);
1987   result := 0;
1988   if commands = nil then Exit;
1989   i := 0;
1990   while (n >= 1) and (i < e_MaxInputKeys) do
1991   begin
1992     if (i < VK_FIRSTKEY) or (i > VK_LASTKEY) then (* never show virtual keys in gui *)
1993     begin
1994       if g_Console_MatchBind(i, down, up) then
1995       begin
1996         result := i;
1997         dec(n)
1998       end;
1999     end;
2000     inc(i)
2001   end;
2002   if n >= 1 then
2003     result := 0
2004 end;
2005
2006 function g_Console_Action (action: Integer): Boolean;
2007   var i, len: Integer;
2008 begin
2009   ASSERT(action >= FIRST_ACTION);
2010   ASSERT(action <= LAST_ACTION);
2011   i := 0;
2012   len := Length(gPlayerAction);
2013   while (i < len) and (not gPlayerAction[i, action]) do inc(i);
2014   Result := i < len
2015 end;
2016
2017 function BindsAllowed (key: Integer): Boolean;
2018 begin
2019   Result := False;
2020   if (not g_GUIGrabInput) and (key >= 0) and (key < e_MaxInputKeys) and ((gInputBinds[key].down <> nil) or (gInputBinds[key].up <> nil)) then
2021   begin
2022     if gChatShow then
2023       Result := g_Console_MatchBind(key, 'togglemenu') or
2024                 g_Console_MatchBind(key, 'showkeyboard') or
2025                 g_Console_MatchBind(key, 'hidekeyboard')
2026     else if gConsoleShow or (g_ActiveWindow <> nil) or (gGameSettings.GameType = GT_NONE) then
2027       Result := g_Console_MatchBind(key, 'togglemenu') or
2028                 g_Console_MatchBind(key, 'toggleconsole') or
2029                 g_Console_MatchBind(key, 'showkeyboard') or
2030                 g_Console_MatchBind(key, 'hidekeyboard')
2031     else (* in game *)
2032       Result := True
2033   end
2034 end;
2035
2036 procedure g_Console_ProcessBind (key: Integer; down: Boolean);
2037   var i: Integer;
2038 begin
2039   if BindsAllowed(key) then
2040   begin
2041     if down then
2042       for i := 0 to High(gInputBinds[key].down) do
2043         g_Console_Process(gInputBinds[key].down[i], True)
2044     else
2045       for i := 0 to High(gInputBinds[key].up) do
2046         g_Console_Process(gInputBinds[key].up[i], True)
2047   end;
2048   if down and not menu_toggled then
2049     KeyPress(key);
2050   menu_toggled := False
2051 end;
2052
2053 procedure g_Console_ProcessBindRepeat (key: Integer);
2054   var i: Integer;
2055 begin
2056   if gConsoleShow or gChatShow or (g_ActiveWindow <> nil) then
2057   begin
2058     KeyPress(key); // key repeat in menus and shit
2059     Exit;
2060   end;
2061   if BindsAllowed(key) and gInputBinds[key].rep then
2062   begin
2063     for i := 0 to High(gInputBinds[key].down) do
2064       g_Console_Process(gInputBinds[key].down[i], True);
2065   end;
2066 end;
2067
2068 procedure g_Console_ResetBinds;
2069   var i: Integer;
2070 begin
2071   for i := 0 to e_MaxInputKeys - 1 do
2072     g_Console_BindKey(i, '', '');
2073
2074   g_Console_BindKey(IK_GRAVE, 'toggleconsole');
2075   g_Console_BindKey(IK_ESCAPE, 'togglemenu');
2076   g_Console_BindKey(IK_A, '+p1_moveleft', '-p1_moveleft');
2077   g_Console_BindKey(IK_D, '+p1_moveright', '-p1_moveright');
2078   g_Console_BindKey(IK_W, '+p1_lookup', '-p1_lookup');
2079   g_Console_BindKey(IK_S, '+p1_lookdown', '-p1_lookdown');
2080   g_Console_BindKey(IK_SPACE, '+p1_jump', '-p1_jump');
2081   g_Console_BindKey(IK_H, '+p1_attack', '-p1_attack');
2082   g_Console_BindKey(IK_J, '+p1_activate', '-p1_activate');
2083   g_Console_BindKey(IK_ALT, '+p1_strafe', '-p1_strafe');
2084   g_Console_BindKey(IK_E, 'p1_weapnext', '', True);
2085   g_Console_BindKey(IK_Q, 'p1_weapprev', '', True);
2086   g_Console_BindKey(IK_R, 'p1_dropflag', '');
2087   g_Console_BindKey(IK_1, 'p1_weapon 1');
2088   g_Console_BindKey(IK_2, 'p1_weapon 2');
2089   g_Console_BindKey(IK_3, 'p1_weapon 3');
2090   g_Console_BindKey(IK_4, 'p1_weapon 4');
2091   g_Console_BindKey(IK_5, 'p1_weapon 5');
2092   g_Console_BindKey(IK_6, 'p1_weapon 6');
2093   g_Console_BindKey(IK_7, 'p1_weapon 7');
2094   g_Console_BindKey(IK_8, 'p1_weapon 8');
2095   g_Console_BindKey(IK_9, 'p1_weapon 9');
2096   g_Console_BindKey(IK_0, 'p1_weapon 10');
2097   g_Console_BindKey(IK_MINUS, 'p1_weapon 11');
2098   g_Console_BindKey(IK_T, 'togglechat');
2099   g_Console_BindKey(IK_Y, 'toggleteamchat');
2100   g_Console_BindKey(IK_F11, 'screenshot');
2101   g_Console_BindKey(IK_TAB, '+scores', '-scores');
2102   g_Console_BindKey(IK_PAUSE, 'pause');
2103   g_Console_BindKey(IK_F1, 'vote');
2104
2105   (* for i := 0 to e_MaxJoys - 1 do *)
2106   for i := 0 to 1 do
2107   begin
2108     g_Console_BindKey(e_JoyHatToKey(i, 0, HAT_LEFT), '+p' + IntToStr(i mod 2 + 1) + '_moveleft', '-p' + IntToStr(i mod 2 + 1) + '_moveleft');
2109     g_Console_BindKey(e_JoyHatToKey(i, 0, HAT_RIGHT), '+p' + IntToStr(i mod 2 + 1) + '_moveright', '-p' + IntToStr(i mod 2 + 1) + '_moveright');
2110     g_Console_BindKey(e_JoyHatToKey(i, 0, HAT_UP), '+p' + IntToStr(i mod 2 + 1) + '_lookup', '-p' + IntToStr(i mod 2 + 1) + '_lookup');
2111     g_Console_BindKey(e_JoyHatToKey(i, 0, HAT_DOWN), '+p' + IntToStr(i mod 2 + 1) + '_lookdown', '-p' + IntToStr(i mod 2 + 1) + '_lookdown');
2112     g_Console_BindKey(e_JoyButtonToKey(i, 2), '+p' + IntToStr(i mod 2 + 1) + '_jump', '-p' + IntToStr(i mod 2 + 1) + '_jump');
2113     g_Console_BindKey(e_JoyButtonToKey(i, 0), '+p' + IntToStr(i mod 2 + 1) + '_attack', '-p' + IntToStr(i mod 2 + 1) + '_attack');
2114     g_Console_BindKey(e_JoyButtonToKey(i, 3), '+p' + IntToStr(i mod 2 + 1) + '_activate', '-p' + IntToStr(i mod 2 + 1) + '_activate');
2115     g_Console_BindKey(e_JoyButtonToKey(i, 7), '+p' + IntToStr(i mod 2 + 1) + '_strafe', '-p' + IntToStr(i mod 2 + 1) + '_strafe');
2116     g_Console_BindKey(e_JoyButtonToKey(i, 1), 'p' + IntToStr(i mod 2 + 1) + '_weapnext', '', True);
2117     g_Console_BindKey(e_JoyButtonToKey(i, 4), 'p' + IntToStr(i mod 2 + 1) + '_weapprev', '', True);
2118     g_Console_BindKey(e_JoyButtonToKey(i, 10), 'togglemenu');
2119   end;
2120
2121   g_Console_BindKey(VK_ESCAPE, 'togglemenu');
2122   g_Console_BindKey(VK_LSTRAFE, '+moveleft; +strafe', '-moveleft; -strafe');
2123   g_Console_BindKey(VK_RSTRAFE, '+moveright; +strafe', '-moveright; -strafe');
2124   g_Console_BindKey(VK_LEFT, '+moveleft', '-moveleft');
2125   g_Console_BindKey(VK_RIGHT, '+moveright', '-moveright');
2126   g_Console_BindKey(VK_UP, '+lookup', '-lookup');
2127   g_Console_BindKey(VK_DOWN, '+lookdown', '-lookdown');
2128   g_Console_BindKey(VK_JUMP, '+jump', '-jump');
2129   g_Console_BindKey(VK_FIRE, '+attack', '-attack');
2130   g_Console_BindKey(VK_OPEN, '+activate', '-activate');
2131   g_Console_BindKey(VK_STRAFE, '+strafe', '-strafe');
2132   g_Console_BindKey(VK_NEXT, 'weapnext', '', True);
2133   g_Console_BindKey(VK_PREV, 'weapprev', '', True);
2134   g_Console_BindKey(VK_0, 'weapon 1');
2135   g_Console_BindKey(VK_1, 'weapon 2');
2136   g_Console_BindKey(VK_2, 'weapon 3');
2137   g_Console_BindKey(VK_3, 'weapon 4');
2138   g_Console_BindKey(VK_4, 'weapon 5');
2139   g_Console_BindKey(VK_5, 'weapon 6');
2140   g_Console_BindKey(VK_6, 'weapon 7');
2141   g_Console_BindKey(VK_7, 'weapon 8');
2142   g_Console_BindKey(VK_8, 'weapon 9');
2143   g_Console_BindKey(VK_9, 'weapon 10');
2144   g_Console_BindKey(VK_A, 'weapon 11');
2145   g_Console_BindKey(VK_CHAT, 'togglechat');
2146   g_Console_BindKey(VK_TEAM, 'toggleteamchat');
2147   g_Console_BindKey(VK_CONSOLE, 'toggleconsole');
2148   g_Console_BindKey(VK_PRINTSCR, 'screenshot');
2149   g_Console_BindKey(VK_STATUS, '+scores', '-scores');
2150   g_Console_BindKey(VK_SHOWKBD, 'showkeyboard');
2151   g_Console_BindKey(VK_HIDEKBD, 'hidekeyboard');
2152 end;
2153
2154 procedure g_Console_ReadConfig (filename: String);
2155   var f: TextFile; s: AnsiString; i, len: Integer;
2156 begin
2157   e_LogWritefln('g_Console_ReadConfig (1) "%s"', [filename]);
2158   if e_FindResource(ConfigDirs, filename, false) = true then
2159   begin
2160     e_LogWritefln('g_Console_ReadConfig (2) "%s"', [filename]);
2161     AssignFile(f, filename);
2162     Reset(f);
2163     while not EOF(f) do
2164     begin
2165       ReadLn(f, s);
2166       len := Length(s);
2167       if len > 0 then
2168       begin
2169         i := 1;
2170         (* skip spaces *)
2171         while (i <= len) and (s[i] <= ' ') do inc(i);
2172         (* skip comments *)
2173         if (i <= len) and ((s[i] <> '#') and ((i + 1 > len) or (s[i] <> '/') or (s[i + 1] <> '/'))) then
2174           g_Console_Process(s, True);
2175       end
2176     end;
2177     CloseFile(f);
2178   end
2179 end;
2180
2181 procedure g_Console_WriteConfig (filename: String);
2182   var f: TextFile; i, j: Integer;
2183
2184   procedure WriteFlag(name: string; flag: LongWord);
2185   begin
2186     WriteLn(f, name, IfThen(LongBool(gsGameFlags and flag), 1, 0));
2187   end;
2188
2189   function FormatTeam(team: Byte): string;
2190   begin
2191     if team = TEAM_BLUE then
2192       result := 'blue'
2193     else
2194       result := 'red';
2195   end;
2196
2197 begin
2198   AssignFile(f, filename);
2199   Rewrite(f);
2200   WriteLn(f, '// ' + configComment);
2201
2202   // binds
2203   WriteLn(f, 'unbindall');
2204   for i := 0 to e_MaxInputKeys - 1 do
2205     if (Length(gInputBinds[i].down) > 0) or (Length(gInputBinds[i].up) > 0) then
2206     begin
2207       Write(f, 'bind ', e_KeyNames[i], ' ', QuoteStr(GetCommandString(gInputBinds[i].down)));
2208       if Length(gInputBinds[i].down) = 0 then
2209         Write(f, '""');
2210       if Length(gInputBinds[i].up) > 0 then
2211         Write(f, ' ', QuoteStr(GetCommandString(gInputBinds[i].up)));
2212       WriteLn(f, '');
2213       if gInputBinds[i].rep then
2214         WriteLn(f, 'bindrep ', e_KeyNames[i]);
2215     end;
2216
2217   // lang
2218   if gAskLanguage then
2219     WriteLn(f, 'g_language ask')
2220   else
2221     WriteLn(f, 'g_language ', gLanguage);
2222
2223   // net server
2224   WriteLn(f, 'sv_name ', QuoteStr(NetServerName));
2225   WriteLn(f, 'sv_passwd ', QuoteStr(NetPassword));
2226   WriteLn(f, 'sv_maxplrs ', NetMaxClients);
2227   WriteLn(f, 'sv_port ', NetPort);
2228   WriteLn(f, 'sv_public ', IfThen(NetUseMaster, 1, 0));
2229
2230   // game settings
2231   WriteLn(f, 'g_max_particles ', g_GFX_GetMax());
2232   WriteLn(f, 'g_max_shells ', g_Shells_GetMax());
2233   WriteLn(f, 'g_max_gibs ', g_Gibs_GetMax());
2234   WriteLn(f, 'g_max_corpses ', g_Corpses_GetMax());
2235   WriteLn(f, 'g_force_model ', g_Force_Model_Get());
2236   WriteLn(f, 'g_force_model_name ', g_Forced_Model_GetName());
2237   WriteLn(f, 'sv_intertime ', gDefInterTime);
2238
2239   // gameplay settings
2240   WriteLn(f, 'g_gamemode ', gsGameMode);
2241   WriteLn(f, 'g_scorelimit ', gsScoreLimit);
2242   WriteLn(f, 'g_timelimit ', gsTimeLimit);
2243   WriteLn(f, 'g_maxlives ', gsMaxLives);
2244   WriteLn(f, 'g_item_respawn_time ', gsItemRespawnTime);
2245   WriteLn(f, 'g_item_time_random ', gsItemRespawnRandom);
2246   WriteLn(f, 'g_powerup_respawn_time ', gsRulezRespawnTime);
2247   WriteLn(f, 'g_powerup_time_random ', gsRulezRespawnRandom);
2248   WriteLn(f, 'g_spawn_invul ', gsSpawnInvul);
2249   WriteLn(f, 'g_warmup_time ', gsWarmupTime);
2250
2251   WriteFlag('g_friendlyfire ', GAME_OPTION_TEAMDAMAGE);
2252   WriteFlag('g_friendly_hit_trace ', GAME_OPTION_TEAMHITTRACE);
2253   WriteFlag('g_friendly_hit_projectile ', GAME_OPTION_TEAMHITPROJECTILE);
2254   WriteFlag('g_powerup_randomize_respawn ', GAME_OPTION_RULEZRANDOM);
2255   WriteFlag('g_allow_exit ', GAME_OPTION_ALLOWEXIT);
2256   WriteFlag('g_allow_monsters ', GAME_OPTION_MONSTERS);
2257   WriteFlag('g_allow_dropflag ', GAME_OPTION_ALLOWDROPFLAG);
2258   WriteFlag('g_throw_flag ', GAME_OPTION_THROWFLAG);
2259   WriteFlag('g_dm_keys ', GAME_OPTION_DMKEYS);
2260   WriteFlag('g_weaponstay ', GAME_OPTION_WEAPONSTAY);
2261   WriteFlag('g_bot_vsmonsters ', GAME_OPTION_BOTVSMONSTER);
2262   WriteFlag('g_bot_vsplayers ', GAME_OPTION_BOTVSPLAYER);
2263
2264   // players
2265   with gPlayer1Settings do
2266   begin
2267     WriteLn(f, 'p1_name ', QuoteStr(Name));
2268     WriteLn(f, 'p1_color ', Color.R, ' ', Color.G, ' ', Color.B);
2269     WriteLn(f, 'p1_model ', QuoteStr(Model));
2270     WriteLn(f, 'p1_team ', FormatTeam(Team));
2271     WriteLn(f, 'p1_autoswitch ', WeaponSwitch);
2272     WriteLn(f, 'p1_switch_empty ', SwitchToEmpty);
2273     WriteLn(f, 'p1_priority_kastet ', Max(0, WeaponPreferences[WEAPON_KASTET]));
2274     WriteLn(f, 'p1_priority_saw ', Max(0, WeaponPreferences[WEAPON_SAW]));
2275     WriteLn(f, 'p1_priority_pistol ', Max(0, WeaponPreferences[WEAPON_PISTOL]));
2276     WriteLn(f, 'p1_priority_shotgun1 ', Max(0, WeaponPreferences[WEAPON_SHOTGUN1]));
2277     WriteLn(f, 'p1_priority_shotgun2 ', Max(0, WeaponPreferences[WEAPON_SHOTGUN2] ));
2278     WriteLn(f, 'p1_priority_chaingun ', Max(0, WeaponPreferences[WEAPON_CHAINGUN]));
2279     WriteLn(f, 'p1_priority_rocketlauncher ', Max(0, WeaponPreferences[WEAPON_ROCKETLAUNCHER]));
2280     WriteLn(f, 'p1_priority_plasma ', Max(0, WeaponPreferences[WEAPON_PLASMA]));
2281     WriteLn(f, 'p1_priority_bfg ', Max(0, WeaponPreferences[WEAPON_BFG]));
2282     WriteLn(f, 'p1_priority_super ', Max(0, WeaponPreferences[WEAPON_SUPERPULEMET]));
2283     WriteLn(f, 'p1_priority_flamethrower ', Max(0, WeaponPreferences[WEAPON_FLAMETHROWER]));
2284     WriteLn(f, 'p1_priority_berserk ', Max(0, WeaponPreferences[WP_LAST+1]));
2285     //
2286   end;
2287   with gPlayer2Settings do
2288   begin
2289     WriteLn(f, 'p2_name ', QuoteStr(Name));
2290     WriteLn(f, 'p2_color ', Color.R, ' ', Color.G, ' ', Color.B);
2291     WriteLn(f, 'p2_model ', QuoteStr(Model));
2292     WriteLn(f, 'p2_team ', FormatTeam(Team));
2293     WriteLn(f, 'p2_autoswitch ', WeaponSwitch);
2294     WriteLn(f, 'p2_switch_empty ', SwitchToEmpty);
2295     WriteLn(f, 'p2_priority_kastet ', Max(0, WeaponPreferences[WEAPON_KASTET]));
2296     WriteLn(f, 'p2_priority_saw ', Max(0, WeaponPreferences[WEAPON_SAW]));
2297     WriteLn(f, 'p2_priority_pistol ', Max(0, WeaponPreferences[WEAPON_PISTOL]));
2298     WriteLn(f, 'p2_priority_shotgun1 ', Max(0, WeaponPreferences[WEAPON_SHOTGUN1]));
2299     WriteLn(f, 'p2_priority_shotgun2 ', Max(0, WeaponPreferences[WEAPON_SHOTGUN1]));
2300     WriteLn(f, 'p2_priority_chaingun ', Max(0, WeaponPreferences[WEAPON_CHAINGUN]));
2301     WriteLn(f, 'p2_priority_rocketlauncher ', Max(0, WeaponPreferences[WEAPON_ROCKETLAUNCHER]));
2302     WriteLn(f, 'p2_priority_plasma ', Max(0, WeaponPreferences[WEAPON_PLASMA]));
2303     WriteLn(f, 'p2_priority_bfg ', Max(0, WeaponPreferences[WEAPON_BFG]));
2304     WriteLn(f, 'p2_priority_super ', Max(0, WeaponPreferences[WEAPON_SUPERPULEMET]));
2305     WriteLn(f, 'p2_priority_flamethrower ', Max(0, WeaponPreferences[WEAPON_FLAMETHROWER]));
2306     WriteLn(f, 'p2_priority_berserk ', Max(0, WeaponPreferences[WP_LAST+1]));
2307   end;
2308
2309   // all cvars
2310   for i := 0 to High(commands) do
2311   begin
2312     if not commands[i].cheat then
2313     begin
2314       if @commands[i].procEx = @boolVarHandler then
2315       begin
2316         if PBoolean(commands[i].ptr)^ then j := 1 else j := 0;
2317         WriteLn(f, commands[i].cmd, ' ', j)
2318       end
2319       else if @commands[i].procEx = @intVarHandler then
2320       begin
2321         WriteLn(f, commands[i].cmd, ' ', PInteger(commands[i].ptr)^)
2322       end
2323       else if @commands[i].procEx = @wordVarHandler then
2324       begin
2325         WriteLn(f, commands[i].cmd, ' ', PWord(commands[i].ptr)^)
2326       end
2327       else if @commands[i].procEx = @dwordVarHandler then
2328       begin
2329         WriteLn(f, commands[i].cmd, ' ', PCardinal(commands[i].ptr)^)
2330       end
2331       else if @commands[i].procEx = @singleVarHandler then
2332       begin
2333         WriteLn(f, commands[i].cmd, ' ', PVarSingle(commands[i].ptr).val^:0:6)
2334       end
2335       else if @commands[i].procEx = @strVarHandler then
2336       begin
2337         if Length(PAnsiString(commands[i].ptr)^) = 0 then
2338           WriteLn(f, commands[i].cmd, ' ""')
2339         else
2340           WriteLn(f, commands[i].cmd, ' ', QuoteStr(PAnsiString(commands[i].ptr)^))
2341       end
2342     end
2343   end;
2344
2345   WriteLn(f, 'r_maxfps ', gMaxFPS);
2346   WriteLn(f, 'r_reset');
2347   CloseFile(f)
2348 end;
2349
2350 procedure g_Console_WriteGameConfig;
2351   var s: AnsiString;
2352 begin
2353   if gParsingBinds = false then
2354   begin
2355     s := e_GetWriteableDir(ConfigDirs);
2356     g_Console_WriteConfig(e_CatPath(s, gConfigScript))
2357   end
2358 end;
2359
2360 procedure Init;
2361   var i: Integer;
2362 begin
2363   conRegVar('chat_at_top', @ChatTop, 'draw chat at top border', 'draw chat at top border');
2364   conRegVar('console_height', @ConsoleHeight, 0.0, 1.0, 'set console size', 'set console size');
2365   conRegVar('console_trans', @ConsoleTrans, 0.0, 1.0, 'set console transparency', 'set console transparency');
2366   conRegVar('console_step', @ConsoleStep, 0.0, 1.0, 'set console animation speed', 'set console animation speed');
2367   conRegVar('console_stdin', @ConsoleStdIn, 'enable reading commands from stdin', 'enable reading commands from stdin');
2368 {$IFDEF ANDROID}
2369   ChatTop := True;
2370   ConsoleHeight := 0.35;
2371 {$ELSE}
2372   ChatTop := False;
2373   ConsoleHeight := 0.5;
2374 {$ENDIF}
2375   ConsoleTrans := 0.1;
2376   ConsoleStep := 0.07;
2377 {$IFDEF HEADLESS}
2378   ConsoleStdIn := True;
2379 {$ELSE}
2380   ConsoleStdIn := False;
2381 {$ENDIF}
2382   conRegVar('d_eres', @debug_e_res, '', '');
2383   for i := 1 to e_MaxJoys do
2384     conRegVar('joy' + IntToStr(i) + '_deadzone', @e_JoystickDeadzones[i - 1], '', '')
2385 end;
2386
2387 initialization
2388   Init
2389
2390 {$IFDEF HEADLESS}
2391 finalization
2392   DoneKeyboard;
2393   conbufStdOutRawMode := false;
2394 {$ENDIF}
2395
2396 end.