src/game/g_console.pas

   1 (* Copyright (C)  Doom 2D: Forever Developers
   2  *
   3  * This program is free software: you can redistribute it and/or modify
   4  * it under the terms of the GNU General Public License as published by
   5  * the Free Software Foundation, either version 3 of the License, or
   6  * (at your option) any later version.
   7  *
   8  * This program is distributed in the hope that it will be useful,
   9  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11  * GNU General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License
  14  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15  *)
  16 {$INCLUDE ../shared/a_modes.inc}
  17 unit g_console;
  18
  19 interface
  20
  21 uses
  22   utils; // for SSArray
  23
  24   const
  25     ACTION_JUMP = 0;
  26     ACTION_MOVELEFT = 1;
  27     ACTION_MOVERIGHT = 2;
  28     ACTION_LOOKDOWN = 3;
  29     ACTION_LOOKUP = 4;
  30     ACTION_ATTACK = 5;
  31     ACTION_SCORES = 6;
  32     ACTION_ACTIVATE = 7;
  33     ACTION_STRAFE = 8;
  34     ACTION_WEAPNEXT = 9;
  35     ACTION_WEAPPREV = 10;
  36
  37     FIRST_ACTION = ACTION_JUMP;
  38     LAST_ACTION = ACTION_WEAPPREV;
  39
  40 procedure g_Console_Init;
  41 procedure g_Console_Update;
  42 procedure g_Console_Draw;
  43 procedure g_Console_Char (C: AnsiChar);
  44 procedure g_Console_Control (K: Word);
  45 procedure g_Console_Process (L: AnsiString; quiet: Boolean=false);
  46 procedure g_Console_Add (L: AnsiString; show: Boolean=false);
  47 procedure g_Console_Clear;
  48 function  g_Console_CommandBlacklisted (C: AnsiString): Boolean;
  49 procedure g_Console_ReadConfig (filename: String);
  50 procedure g_Console_WriteConfig (filename: String);
  51
  52 function  g_Console_Interactive: Boolean;
  53 function  g_Console_Action (action: Integer): Boolean;
  54 function  g_Console_MatchBind (key: Integer; down: AnsiString; up: AnsiString = ''): Boolean;
  55 function  g_Console_FindBind (n: Integer; down: AnsiString; up: AnsiString = ''): Integer;
  56 procedure g_Console_BindKey (key: Integer; down: AnsiString; up: AnsiString = '');
  57 procedure g_Console_ProcessBind (key: Integer; down: Boolean);
  58 procedure g_Console_ResetBinds;
  59
  60 procedure conwriteln (const s: AnsiString; show: Boolean=false);
  61 procedure conwritefln (const s: AnsiString; args: array of const; show: Boolean=false);
  62
  63 procedure conRegVar (const conname: AnsiString; pvar: PBoolean; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
  64 procedure conRegVar (const conname: AnsiString; pvar: PSingle; amin, amax: Single; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
  65 procedure conRegVar (const conname: AnsiString; pvar: PInteger; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
  66
  67 // <0: no arg; 0/1: true/false
  68 function conGetBoolArg (p: SSArray; idx: Integer): Integer;
  69
  70 // poor man's floating literal parser; i'm sorry, but `StrToFloat()` sux cocks
  71 function conParseFloat (var res: Single; const s: AnsiString): Boolean;
  72
  73
  74 var
  75   gConsoleShow: Boolean = false; // True - êîíñîëü îòêðûòà èëè îòêðûâàåòñÿ
  76   gChatShow: Boolean = false;
  77   gChatTeam: Boolean = false;
  78   gAllowConsoleMessages: Boolean = true;
  79   gJustChatted: Boolean = false; // ÷òîáû àäìèí â èíòåðå ÷àòÿñü íå ïðîìàòûâàë ñòàòèñòèêó
  80   gPlayerAction: Array [0..1, 0..LAST_ACTION] of Boolean; // [player, action]
  81
  82 implementation
  83
  84 uses
  85   g_textures, g_main, e_graphics, e_input, g_game,
  86   SysUtils, g_basic, g_options, Math, g_touch,
  87   g_menu, g_gui, g_language, g_net, g_netmsg, e_log, conbuf;
  88
  89
  90 type
  91   PCommand = ^TCommand;
  92
  93   TCmdProc = procedure (p: SSArray);
  94   TCmdProcEx = procedure (me: PCommand; p: SSArray);
  95
  96   TCommand = record
  97     cmd: AnsiString;
  98     proc: TCmdProc;
  99     procEx: TCmdProcEx;
 100     help: AnsiString;
 101     hidden: Boolean;
 102     ptr: Pointer; // various data
 103     msg: AnsiString; // message for var changes
 104     cheat: Boolean;
 105     action: Integer; // >= 0 for action commands
 106     player: Integer; // used for action commands
 107   end;
 108
 109   TAlias = record
 110     name: AnsiString;
 111     commands: SSArray;
 112   end;
 113
 114
 115 const
 116   Step = 32;
 117   Alpha = 25;
 118   MsgTime = 144;
 119   MaxScriptRecursion = 16;
 120
 121   DEBUG_STRING = 'DEBUG MODE';
 122
 123 var
 124   ID: DWORD;
 125   RecursionDepth: Word = 0;
 126   RecursionLimitHit: Boolean = False;
 127   Cons_Y: SmallInt;
 128   Cons_Shown: Boolean; // Ðèñîâàòü ëè êîíñîëü?
 129   Line: AnsiString;
 130   CPos: Word;
 131   //ConsoleHistory: SSArray;
 132   CommandHistory: SSArray;
 133   Whitelist: SSArray;
 134   commands: Array of TCommand = nil;
 135   Aliases: Array of TAlias = nil;
 136   CmdIndex: Word;
 137   conSkipLines: Integer = 0;
 138   MsgArray: Array [0..4] of record
 139                               Msg: AnsiString;
 140                               Time: Word;
 141                             end;
 142
 143   gInputBinds: Array [0..e_MaxInputKeys - 1] of record
 144     down, up: SSArray;
 145   end;
 146   menu_toggled: BOOLEAN; (* hack for menu controls *)
 147   gSkipFirstChar: Boolean; (* hack for console/chat input *)
 148
 149
 150 procedure g_Console_Switch;
 151 begin
 152   gChatShow := False;
 153   gConsoleShow := not gConsoleShow;
 154   Cons_Shown := True;
 155   g_Touch_ShowKeyboard(gConsoleShow or gChatShow);
 156 end;
 157
 158 procedure g_Console_Chat_Switch (Team: Boolean = False);
 159 begin
 160   if not g_Game_IsNet then Exit;
 161   gConsoleShow := False;
 162   gChatShow := not gChatShow;
 163   gChatTeam := Team;
 164   Line := '';
 165   CPos := 1;
 166   g_Touch_ShowKeyboard(gConsoleShow or gChatShow);
 167 end;
 168
 169 // poor man's floating literal parser; i'm sorry, but `StrToFloat()` sux cocks
 170 function conParseFloat (var res: Single; const s: AnsiString): Boolean;
 171 var
 172   pos: Integer = 1;
 173   frac: Single = 1;
 174   slen: Integer;
 175 begin
 176   result := false;
 177   res := 0;
 178   slen := Length(s);
 179   while (slen > 0) and (s[slen] <= ' ') do Dec(slen);
 180   while (pos <= slen) and (s[pos] <= ' ') do Inc(pos);
 181   if (pos > slen) then exit;
 182   if (slen-pos = 1) and (s[pos] = '.') then exit; // single dot
 183   // integral part
 184   while (pos <= slen) do
 185   begin
 186     if (s[pos] < '0') or (s[pos] > '9') then break;
 187     res := res*10+Byte(s[pos])-48;
 188     Inc(pos);
 189   end;
 190   if (pos <= slen) then
 191   begin
 192     // must be a dot
 193     if (s[pos] <> '.') then exit;
 194     Inc(pos);
 195     while (pos <= slen) do
 196     begin
 197       if (s[pos] < '0') or (s[pos] > '9') then break;
 198       frac := frac/10;
 199       res += frac*(Byte(s[pos])-48);
 200       Inc(pos);
 201     end;
 202   end;
 203   if (pos <= slen) then exit; // oops
 204   result := true;
 205 end;
 206
 207
 208 // ////////////////////////////////////////////////////////////////////////// //
 209 // <0: no arg; 0/1: true/false; 666: toggle
 210 function conGetBoolArg (p: SSArray; idx: Integer): Integer;
 211 begin
 212   if (idx < 0) or (idx > High(p)) then begin result := -1; exit; end;
 213   result := 0;
 214   if (p[idx] = '1') or (CompareText(p[idx], 'on') = 0) or (CompareText(p[idx], 'true') = 0) or
 215      (CompareText(p[idx], 'tan') = 0) or (CompareText(p[idx], 'yes') = 0) then result := 1
 216   else if (CompareText(p[idx], 'toggle') = 0) or (CompareText(p[idx], 'switch') = 0) or
 217           (CompareText(p[idx], 't') = 0) then result := 666;
 218 end;
 219
 220
 221 procedure boolVarHandler (me: PCommand; p: SSArray);
 222   procedure binaryFlag (var flag: Boolean; msg: AnsiString);
 223   begin
 224     if (Length(p) > 2) then
 225     begin
 226       conwritefln('too many arguments to ''%s''', [p[0]]);
 227     end
 228     else
 229     begin
 230       case conGetBoolArg(p, 1) of
 231         -1: begin end;
 232          0: if not me.cheat or conIsCheatsEnabled then flag := false else begin conwriteln('not available'); exit; end;
 233          1: if not me.cheat or conIsCheatsEnabled then flag := true else begin conwriteln('not available'); exit; end;
 234          666: if not me.cheat or conIsCheatsEnabled then flag := not flag else begin conwriteln('not available'); exit; end;
 235       end;
 236       if (Length(msg) = 0) then msg := p[0] else msg += ':';
 237       if flag then conwritefln('%s tan', [msg]) else conwritefln('%s ona', [msg]);
 238     end;
 239   end;
 240 begin
 241   binaryFlag(PBoolean(me.ptr)^, me.msg);
 242 end;
 243
 244
 245 procedure intVarHandler (me: PCommand; p: SSArray);
 246   procedure binaryFlag (var flag: Boolean; msg: AnsiString);
 247   begin
 248     if (Length(p) > 2) then
 249     begin
 250       conwritefln('too many arguments to ''%s''', [p[0]]);
 251     end
 252     else
 253     begin
 254       case conGetBoolArg(p, 1) of
 255         -1: begin end;
 256          0: if not me.cheat or conIsCheatsEnabled then flag := false else begin conwriteln('not available'); exit; end;
 257          1: if not me.cheat or conIsCheatsEnabled then flag := true else begin conwriteln('not available'); exit; end;
 258          666: if not me.cheat or conIsCheatsEnabled then flag := not flag else begin conwriteln('not available'); exit; end;
 259       end;
 260       if (Length(msg) = 0) then msg := p[0] else msg += ':';
 261       if flag then conwritefln('%s tan', [msg]) else conwritefln('%s ona', [msg]);
 262     end;
 263   end;
 264 begin
 265   if (Length(p) <> 2) then
 266   begin
 267     conwritefln('%s %d', [me.cmd, PInteger(me.ptr)^]);
 268   end
 269   else
 270   begin
 271     try
 272       PInteger(me.ptr)^ := StrToInt(p[1]);
 273     except
 274       conwritefln('invalid integer value: "%s"', [p[1]]);
 275     end;
 276   end;
 277 end;
 278
 279
 280 procedure conRegVar (const conname: AnsiString; pvar: PBoolean; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
 281 var
 282   f: Integer;
 283   cp: PCommand;
 284 begin
 285   f := Length(commands);
 286   SetLength(commands, f+1);
 287   cp := @commands[f];
 288   cp.cmd := LowerCase(conname);
 289   cp.proc := nil;
 290   cp.procEx := boolVarHandler;
 291   cp.help := ahelp;
 292   cp.hidden := ahidden;
 293   cp.ptr := pvar;
 294   cp.msg := amsg;
 295   cp.cheat := acheat;
 296   cp.action := -1;
 297   cp.player := -1;
 298 end;
 299
 300
 301 procedure conRegVar (const conname: AnsiString; pvar: PInteger; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
 302 var
 303   f: Integer;
 304   cp: PCommand;
 305 begin
 306   f := Length(commands);
 307   SetLength(commands, f+1);
 308   cp := @commands[f];
 309   cp.cmd := LowerCase(conname);
 310   cp.proc := nil;
 311   cp.procEx := intVarHandler;
 312   cp.help := ahelp;
 313   cp.hidden := ahidden;
 314   cp.ptr := pvar;
 315   cp.msg := amsg;
 316   cp.cheat := acheat;
 317   cp.action := -1;
 318   cp.player := -1;
 319 end;
 320
 321
 322 // ////////////////////////////////////////////////////////////////////////// //
 323 type
 324   PVarSingle = ^TVarSingle;
 325   TVarSingle = record
 326     val: PSingle;
 327     min, max, def: Single; // default will be starting value
 328   end;
 329
 330
 331 procedure singleVarHandler (me: PCommand; p: SSArray);
 332 var
 333   pv: PVarSingle;
 334   nv: Single;
 335   msg: AnsiString;
 336 begin
 337   if (Length(p) > 2) then
 338   begin
 339     conwritefln('too many arguments to ''%s''', [me.cmd]);
 340     exit;
 341   end;
 342   pv := PVarSingle(me.ptr);
 343   if (Length(p) = 2) then
 344   begin
 345     if me.cheat and (not conIsCheatsEnabled) then begin conwriteln('not available'); exit; end;
 346     if (CompareText(p[1], 'default') = 0) or (CompareText(p[1], 'def') = 0) or
 347        (CompareText(p[1], 'd') = 0) or (CompareText(p[1], 'off') = 0) or
 348        (CompareText(p[1], 'ona') = 0) then
 349     begin
 350       pv.val^ := pv.def;
 351     end
 352     else
 353     begin
 354       if not conParseFloat(nv, p[1]) then
 355       begin
 356         conwritefln('%s: ''%s'' doesn''t look like a floating number', [me.cmd, p[1]]);
 357         exit;
 358       end;
 359       if (nv < pv.min) then nv := pv.min;
 360       if (nv > pv.max) then nv := pv.max;
 361       pv.val^ := nv;
 362     end;
 363   end;
 364   msg := me.msg;
 365   if (Length(msg) = 0) then msg := me.cmd else msg += ':';
 366   conwritefln('%s %s', [msg, pv.val^]);
 367 end;
 368
 369
 370 procedure conRegVar (const conname: AnsiString; pvar: PSingle; amin, amax: Single; const ahelp: AnsiString; const amsg: AnsiString; acheat: Boolean=false; ahidden: Boolean=false); overload;
 371 var
 372   f: Integer;
 373   cp: PCommand;
 374   pv: PVarSingle;
 375 begin
 376   GetMem(pv, sizeof(TVarSingle));
 377   pv.val := pvar;
 378   pv.min := amin;
 379   pv.max := amax;
 380   pv.def := pvar^;
 381   f := Length(commands);
 382   SetLength(commands, f+1);
 383   cp := @commands[f];
 384   cp.cmd := LowerCase(conname);
 385   cp.proc := nil;
 386   cp.procEx := singleVarHandler;
 387   cp.help := ahelp;
 388   cp.hidden := ahidden;
 389   cp.ptr := pv;
 390   cp.msg := amsg;
 391   cp.cheat := acheat;
 392   cp.action := -1;
 393   cp.player := -1;
 394 end;
 395
 396
 397 // ////////////////////////////////////////////////////////////////////////// //
 398 function GetStrACmd(var Str: AnsiString): AnsiString;
 399 var
 400   a: Integer;
 401 begin
 402   Result := '';
 403   for a := 1 to Length(Str) do
 404     if (a = Length(Str)) or (Str[a+1] = ';') then
 405     begin
 406       Result := Copy(Str, 1, a);
 407       Delete(Str, 1, a+1);
 408       Str := Trim(Str);
 409       Exit;
 410     end;
 411 end;
 412
 413 function ParseAlias(Str: AnsiString): SSArray;
 414 begin
 415   Result := nil;
 416
 417   Str := Trim(Str);
 418
 419   if Str = '' then
 420     Exit;
 421
 422   while Str <> '' do
 423   begin
 424     SetLength(Result, Length(Result)+1);
 425     Result[High(Result)] := GetStrACmd(Str);
 426   end;
 427 end;
 428
 429 procedure ConsoleCommands(p: SSArray);
 430 var
 431   cmd, s: AnsiString;
 432   a, b: Integer;
 433   (* F: TextFile; *)
 434 begin
 435   cmd := LowerCase(p[0]);
 436   s := '';
 437
 438   if cmd = 'clear' then
 439   begin
 440     //ConsoleHistory := nil;
 441     cbufClear();
 442     conSkipLines := 0;
 443
 444     for a := 0 to High(MsgArray) do
 445       with MsgArray[a] do
 446       begin
 447         Msg := '';
 448         Time := 0;
 449       end;
 450   end;
 451
 452   if cmd = 'clearhistory' then
 453     CommandHistory := nil;
 454
 455   if cmd = 'showhistory' then
 456     if CommandHistory <> nil then
 457     begin
 458       g_Console_Add('');
 459       for a := 0 to High(CommandHistory) do
 460         g_Console_Add('  '+CommandHistory[a]);
 461     end;
 462
 463   if cmd = 'commands' then
 464   begin
 465     g_Console_Add('');
 466     g_Console_Add('commands list:');
 467     for a := High(commands) downto 0 do
 468     begin
 469       if (Length(commands[a].help) > 0) then
 470       begin
 471         g_Console_Add('  '+commands[a].cmd+' -- '+commands[a].help);
 472       end
 473       else
 474       begin
 475         g_Console_Add('  '+commands[a].cmd);
 476       end;
 477     end;
 478   end;
 479
 480   if cmd = 'time' then
 481     g_Console_Add(TimeToStr(Now), True);
 482
 483   if cmd = 'date' then
 484     g_Console_Add(DateToStr(Now), True);
 485
 486   if cmd = 'echo' then
 487     if Length(p) > 1 then
 488       begin
 489         if p[1] = 'ololo' then
 490           gCheats := True
 491         else
 492         begin
 493           s := '';
 494           for a := 1 to High(p) do
 495             s := s + p[a] + ' ';
 496           g_Console_Add(b_Text_Format(s), True);
 497         end;
 498       end
 499     else
 500       g_Console_Add('');
 501
 502   if cmd = 'dump' then
 503   begin
 504     (*
 505     if ConsoleHistory <> nil then
 506     begin
 507       if Length(P) > 1 then
 508         s := P[1]
 509       else
 510         s := GameDir+'/console.txt';
 511
 512       {$I-}
 513       AssignFile(F, s);
 514       Rewrite(F);
 515       if IOResult <> 0 then
 516       begin
 517         g_Console_Add(Format(_lc[I_CONSOLE_ERROR_WRITE], [s]));
 518         CloseFile(F);
 519         Exit;
 520       end;
 521
 522       for a := 0 to High(ConsoleHistory) do
 523         WriteLn(F, ConsoleHistory[a]);
 524
 525       CloseFile(F);
 526       g_Console_Add(Format(_lc[I_CONSOLE_DUMPED], [s]));
 527       {$I+}
 528     end;
 529     *)
 530   end;
 531
 532   if cmd = 'exec' then
 533   begin
 534     // exec <filename>
 535     if Length(p) = 2 then
 536       g_Console_ReadConfig(GameDir + '/' + p[1])
 537     else
 538       g_Console_Add('exec <script file>');
 539   end;
 540
 541   if cmd = 'writeconfig' then
 542   begin
 543     // writeconfig <filename>
 544     if Length(p) = 2 then
 545       g_Console_WriteConfig(GameDir + '/' + p[1])
 546     else
 547       g_Console_Add('writeconfig <file>');
 548   end;
 549
 550   if (cmd = 'ver') or (cmd = 'version') then
 551   begin
 552     conwriteln('Doom 2D: Forever v. ' + GAME_VERSION);
 553     conwritefln('Net protocol v. %d', [NET_PROTOCOL_VER]);
 554     conwritefln('Build date: %s at %s', [GAME_BUILDDATE, GAME_BUILDTIME]);
 555   end;
 556
 557   if cmd = 'alias' then
 558   begin
 559     // alias [alias_name] [commands]
 560     if Length(p) > 1 then
 561     begin
 562       for a := 0 to High(Aliases) do
 563         if Aliases[a].name = p[1] then
 564         begin
 565           if Length(p) > 2 then
 566             Aliases[a].commands := ParseAlias(p[2])
 567           else
 568             for b := 0 to High(Aliases[a].commands) do
 569               g_Console_Add(Aliases[a].commands[b]);
 570           Exit;
 571         end;
 572       SetLength(Aliases, Length(Aliases)+1);
 573       a := High(Aliases);
 574       Aliases[a].name := p[1];
 575       if Length(p) > 2 then
 576         Aliases[a].commands := ParseAlias(p[2])
 577       else
 578         for b := 0 to High(Aliases[a].commands) do
 579           g_Console_Add(Aliases[a].commands[b]);
 580     end else
 581       for a := 0 to High(Aliases) do
 582         if Aliases[a].commands <> nil then
 583           g_Console_Add(Aliases[a].name);
 584   end;
 585
 586   if cmd = 'call' then
 587   begin
 588     // call <alias_name>
 589     if Length(p) > 1 then
 590     begin
 591       if Aliases = nil then
 592         Exit;
 593       for a := 0 to High(Aliases) do
 594         if Aliases[a].name = p[1] then
 595         begin
 596           if Aliases[a].commands <> nil then
 597           begin
 598             // with this system proper endless loop detection seems either impossible
 599             // or very dirty to implement, so let's have this instead
 600             // prevents endless loops
 601             for b := 0 to High(Aliases[a].commands) do
 602             begin
 603               Inc(RecursionDepth);
 604               RecursionLimitHit := (RecursionDepth > MaxScriptRecursion) or RecursionLimitHit;
 605               if not RecursionLimitHit then
 606                 g_Console_Process(Aliases[a].commands[b], True);
 607               Dec(RecursionDepth);
 608             end;
 609             if (RecursionDepth = 0) and RecursionLimitHit then
 610             begin
 611               g_Console_Add(Format(_lc[I_CONSOLE_ERROR_CALL], [s]));
 612               RecursionLimitHit := False;
 613             end;
 614           end;
 615           Exit;
 616         end;
 617     end
 618     else
 619       g_Console_Add('call <alias name>');
 620   end;
 621 end;
 622
 623 procedure WhitelistCommand(cmd: AnsiString);
 624 var
 625   a: Integer;
 626 begin
 627   SetLength(Whitelist, Length(Whitelist)+1);
 628   a := High(Whitelist);
 629   Whitelist[a] := LowerCase(cmd);
 630 end;
 631
 632 procedure segfault (p: SSArray);
 633 var
 634   pp: PByte = nil;
 635 begin
 636   pp^ := 0;
 637 end;
 638
 639 function GetCommandString (p: SSArray): AnsiString;
 640   var i: Integer;
 641 begin
 642   result := '';
 643   if Length(p) >= 1 then
 644   begin
 645     result := p[0];
 646     for i := 1 to High(p) do
 647       result := result + '; ' + p[i]
 648   end
 649 end;
 650
 651 procedure BindCommands (p: SSArray);
 652   var cmd, key: AnsiString; i: Integer;
 653 begin
 654   cmd := LowerCase(p[0]);
 655   case cmd of
 656   'bind':
 657     // bind <key> [down [up]]
 658     if (Length(p) >= 2) and (Length(p) <= 4) then
 659     begin
 660       i := 0;
 661       key := LowerCase(p[1]);
 662       while (i < e_MaxInputKeys) and (key <> LowerCase(e_KeyNames[i])) do inc(i);
 663       if i < e_MaxInputKeys then
 664       begin
 665         if Length(p) = 2 then
 666           g_Console_Add('"' + e_KeyNames[i] + '" = "' + GetCommandString(gInputBinds[i].down) + '" "' + GetCommandString(gInputBinds[i].up) + '"')
 667         else if Length(p) = 3 then
 668           g_Console_BindKey(i, p[2], '')
 669         else (* len = 4 *)
 670           g_Console_BindKey(i, p[2], p[3])
 671       end
 672       else
 673         g_Console_Add('bind: "' + p[1] + '" is not a key')
 674     end
 675     else
 676     begin
 677       g_Console_Add('bind <key> <down action> [up action]')
 678     end;
 679   'bindlist':
 680     for i := 0 to e_MaxInputKeys - 1 do
 681       if (gInputBinds[i].down <> nil) or (gInputBinds[i].up <> nil) then
 682         g_Console_Add(e_KeyNames[i] + ' "' + GetCommandString(gInputBinds[i].down) + '" "' + GetCommandString(gInputBinds[i].up) + '"');
 683   'unbind':
 684     // unbind <key>
 685     if Length(p) = 2 then
 686     begin
 687       key := LowerCase(p[1]);
 688       i := 0;
 689       while (i < e_MaxInputKeys) and (key <> LowerCase(e_KeyNames[i])) do inc(i);
 690       if i < e_MaxInputKeys then
 691         g_Console_BindKey(i, '')
 692       else
 693         g_Console_Add('unbind: "' + p[1] + '" is not a key')
 694     end
 695     else
 696       g_Console_Add('unbind <key>');
 697   'unbindall':
 698     for i := 0 to e_MaxInputKeys - 1 do
 699       g_Console_BindKey(i, '');
 700   'showkeyboard':
 701     g_Touch_ShowKeyboard(True);
 702   'hidekeyboard':
 703     g_Touch_ShowKeyboard(False);
 704   'togglemenu':
 705     if gConsoleShow then
 706     begin
 707       g_Console_Switch;
 708       menu_toggled := True
 709     end
 710     else
 711     begin
 712       KeyPress(VK_ESCAPE);
 713       menu_toggled := True
 714     end;
 715   'toggleconsole':
 716     begin
 717       g_Console_Switch;
 718       gSkipFirstChar := g_Console_Interactive();
 719     end;
 720   'togglechat':
 721     begin
 722       g_Console_Chat_Switch;
 723       gSkipFirstChar := not g_Console_Interactive()
 724     end;
 725   'toggleteamchat':
 726     if gGameSettings.GameMode in [GM_TDM, GM_CTF] then
 727     begin
 728       g_Console_Chat_Switch(True);
 729       gSkipFirstChar := not g_Console_Interactive()
 730     end;
 731   end
 732 end;
 733
 734 procedure AddCommand(cmd: AnsiString; proc: TCmdProc; ahelp: AnsiString=''; ahidden: Boolean=false; acheat: Boolean=false);
 735 var
 736   a: Integer;
 737   cp: PCommand;
 738 begin
 739   SetLength(commands, Length(commands)+1);
 740   a := High(commands);
 741   cp := @commands[a];
 742   cp.cmd := LowerCase(cmd);
 743   cp.proc := proc;
 744   cp.procEx := nil;
 745   cp.help := ahelp;
 746   cp.hidden := ahidden;
 747   cp.ptr := nil;
 748   cp.msg := '';
 749   cp.cheat := acheat;
 750   cp.action := -1;
 751   cp.player := -1;
 752 end;
 753
 754 procedure AddAction (cmd: AnsiString; action: Integer; help: AnsiString = ''; hidden: Boolean = False; cheat: Boolean = False);
 755   const
 756     PrefixList: array [0..1] of AnsiString = ('+', '-');
 757     PlayerList: array [0..1] of Integer = (1, 2);
 758   var
 759     s: AnsiString;
 760     i: Integer;
 761
 762   procedure NewAction (cmd: AnsiString; player: Integer);
 763     var cp: PCommand;
 764   begin
 765     SetLength(commands, Length(commands) + 1);
 766     cp := @commands[High(commands)];
 767     cp.cmd := LowerCase(cmd);
 768     cp.proc := nil;
 769     cp.procEx := nil;
 770     cp.help := help;
 771     cp.hidden := hidden;
 772     cp.ptr := nil;
 773     cp.msg := '';
 774     cp.cheat := cheat;
 775     cp.action := action;
 776     cp.player := player;
 777   end;
 778
 779 begin
 780   ASSERT(action >= FIRST_ACTION);
 781   ASSERT(action <= LAST_ACTION);
 782   for s in PrefixList do
 783   begin
 784     NewAction(s + cmd, 0);
 785     for i in PlayerList do
 786       NewAction(s + 'p' + IntToStr(i) + '_' + cmd, i - 1)
 787   end
 788 end;
 789
 790 procedure g_Console_Init();
 791   var
 792     a: Integer;
 793 begin
 794   g_Texture_CreateWAD(ID, GameWAD+':TEXTURES\CONSOLE');
 795   Cons_Y := -(gScreenHeight div 2);
 796   gConsoleShow := False;
 797   gChatShow := False;
 798   Cons_Shown := False;
 799   CPos := 1;
 800
 801   for a := 0 to High(MsgArray) do
 802     with MsgArray[a] do
 803     begin
 804       Msg := '';
 805       Time := 0;
 806     end;
 807
 808   AddCommand('segfault', segfault, 'make segfault');
 809
 810   AddCommand('bind', BindCommands);
 811   AddCommand('bindlist', BindCommands);
 812   AddCommand('unbind', BindCommands);
 813   AddCommand('unbindall', BindCommands);
 814   AddCommand('showkeyboard', BindCommands);
 815   AddCommand('hidekeyboard', BindCommands);
 816   AddCommand('togglemenu', BindCommands);
 817   AddCommand('toggleconsole', BindCommands);
 818   AddCommand('togglechat', BindCommands);
 819   AddCommand('toggleteamchat', BindCommands);
 820
 821   AddCommand('clear', ConsoleCommands, 'clear console');
 822   AddCommand('clearhistory', ConsoleCommands);
 823   AddCommand('showhistory', ConsoleCommands);
 824   AddCommand('commands', ConsoleCommands);
 825   AddCommand('time', ConsoleCommands);
 826   AddCommand('date', ConsoleCommands);
 827   AddCommand('echo', ConsoleCommands);
 828   AddCommand('dump', ConsoleCommands);
 829   AddCommand('exec', ConsoleCommands);
 830   AddCommand('writeconfig', ConsoleCommands);
 831   AddCommand('alias', ConsoleCommands);
 832   AddCommand('call', ConsoleCommands);
 833   AddCommand('ver', ConsoleCommands);
 834   AddCommand('version', ConsoleCommands);
 835
 836   AddCommand('d_window', DebugCommands);
 837   AddCommand('d_sounds', DebugCommands);
 838   AddCommand('d_frames', DebugCommands);
 839   AddCommand('d_winmsg', DebugCommands);
 840   AddCommand('d_monoff', DebugCommands);
 841   AddCommand('d_botoff', DebugCommands);
 842   AddCommand('d_monster', DebugCommands);
 843   AddCommand('d_health', DebugCommands);
 844   AddCommand('d_player', DebugCommands);
 845   AddCommand('d_joy', DebugCommands);
 846   AddCommand('d_mem', DebugCommands);
 847
 848   AddCommand('p1_name', GameCVars);
 849   AddCommand('p2_name', GameCVars);
 850   AddCommand('p1_color', GameCVars);
 851   AddCommand('p2_color', GameCVars);
 852   AddCommand('r_showtime', GameCVars);
 853   AddCommand('r_showscore', GameCVars);
 854   AddCommand('r_showlives', GameCVars);
 855   AddCommand('r_showstat', GameCVars);
 856   AddCommand('r_showkillmsg', GameCVars);
 857   AddCommand('r_showspect', GameCVars);
 858   AddCommand('r_showping', GameCVars);
 859   AddCommand('g_gamemode', GameCVars);
 860   AddCommand('g_friendlyfire', GameCVars);
 861   AddCommand('g_weaponstay', GameCVars);
 862   AddCommand('g_allow_exit', GameCVars);
 863   AddCommand('g_allow_monsters', GameCVars);
 864   AddCommand('g_bot_vsmonsters', GameCVars);
 865   AddCommand('g_bot_vsplayers', GameCVars);
 866   AddCommand('g_scorelimit', GameCVars);
 867   AddCommand('g_timelimit', GameCVars);
 868   AddCommand('g_maxlives', GameCVars);
 869   AddCommand('g_warmuptime', GameCVars);
 870   AddCommand('net_interp', GameCVars);
 871   AddCommand('net_forceplayerupdate', GameCVars);
 872   AddCommand('net_predictself', GameCVars);
 873   AddCommand('sv_name', GameCVars);
 874   AddCommand('sv_passwd', GameCVars);
 875   AddCommand('sv_maxplrs', GameCVars);
 876   AddCommand('sv_public', GameCVars);
 877   AddCommand('sv_intertime', GameCVars);
 878
 879   AddCommand('quit', GameCommands);
 880   AddCommand('exit', GameCommands);
 881   AddCommand('pause', GameCommands);
 882   AddCommand('endgame', GameCommands);
 883   AddCommand('restart', GameCommands);
 884   AddCommand('addbot', GameCommands);
 885   AddCommand('bot_add', GameCommands);
 886   AddCommand('bot_addlist', GameCommands);
 887   AddCommand('bot_addred', GameCommands);
 888   AddCommand('bot_addblue', GameCommands);
 889   AddCommand('bot_removeall', GameCommands);
 890   AddCommand('chat', GameCommands);
 891   AddCommand('teamchat', GameCommands);
 892   AddCommand('game', GameCommands);
 893   AddCommand('host', GameCommands);
 894   AddCommand('map', GameCommands);
 895   AddCommand('nextmap', GameCommands);
 896   AddCommand('endmap', GameCommands);
 897   AddCommand('goodbye', GameCommands);
 898   AddCommand('suicide', GameCommands);
 899   AddCommand('spectate', GameCommands);
 900   AddCommand('ready', GameCommands);
 901   AddCommand('kick', GameCommands);
 902   AddCommand('kick_id', GameCommands);
 903   AddCommand('ban', GameCommands);
 904   AddCommand('permban', GameCommands);
 905   AddCommand('ban_id', GameCommands);
 906   AddCommand('permban_id', GameCommands);
 907   AddCommand('unban', GameCommands);
 908   AddCommand('connect', GameCommands);
 909   AddCommand('disconnect', GameCommands);
 910   AddCommand('reconnect', GameCommands);
 911   AddCommand('say', GameCommands);
 912   AddCommand('tell', GameCommands);
 913   AddCommand('overtime', GameCommands);
 914   AddCommand('rcon_password', GameCommands);
 915   AddCommand('rcon', GameCommands);
 916   AddCommand('callvote', GameCommands);
 917   AddCommand('vote', GameCommands);
 918   AddCommand('clientlist', GameCommands);
 919   AddCommand('event', GameCommands);
 920   AddCommand('screenshot', GameCommands);
 921   AddCommand('weapon', GameCommands);
 922   AddCommand('p1_weapon', GameCommands);
 923   AddCommand('p2_weapon', GameCommands);
 924
 925   AddCommand('god', GameCheats);
 926   AddCommand('notarget', GameCheats);
 927   AddCommand('give', GameCheats); // "exit" too ;-)
 928   AddCommand('open', GameCheats);
 929   AddCommand('fly', GameCheats);
 930   AddCommand('noclip', GameCheats);
 931   AddCommand('speedy', GameCheats);
 932   AddCommand('jumpy', GameCheats);
 933   AddCommand('noreload', GameCheats);
 934   AddCommand('aimline', GameCheats);
 935   AddCommand('automap', GameCheats);
 936
 937   AddAction('jump', ACTION_JUMP);
 938   AddAction('moveleft', ACTION_MOVELEFT);
 939   AddAction('moveright', ACTION_MOVERIGHT);
 940   AddAction('lookup', ACTION_LOOKUP);
 941   AddAction('lookdown', ACTION_LOOKDOWN);
 942   AddAction('attack', ACTION_ATTACK);
 943   AddAction('scores', ACTION_SCORES);
 944   AddAction('activate', ACTION_ACTIVATE);
 945   AddAction('strafe', ACTION_STRAFE);
 946   AddAction('weapnext', ACTION_WEAPNEXT);
 947   AddAction('weapprev', ACTION_WEAPPREV);
 948
 949   WhitelistCommand('say');
 950   WhitelistCommand('tell');
 951   WhitelistCommand('overtime');
 952   WhitelistCommand('ready');
 953   WhitelistCommand('map');
 954   WhitelistCommand('nextmap');
 955   WhitelistCommand('endmap');
 956   WhitelistCommand('restart');
 957   WhitelistCommand('kick');
 958   WhitelistCommand('ban');
 959
 960   WhitelistCommand('addbot');
 961   WhitelistCommand('bot_add');
 962   WhitelistCommand('bot_addred');
 963   WhitelistCommand('bot_addblue');
 964   WhitelistCommand('bot_removeall');
 965
 966   WhitelistCommand('g_gamemode');
 967   WhitelistCommand('g_friendlyfire');
 968   WhitelistCommand('g_weaponstay');
 969   WhitelistCommand('g_allow_exit');
 970   WhitelistCommand('g_allow_monsters');
 971   WhitelistCommand('g_scorelimit');
 972   WhitelistCommand('g_timelimit');
 973
 974   g_Console_ResetBinds;
 975   g_Console_ReadConfig(GameDir + '/dfconfig.cfg');
 976   g_Console_ReadConfig(GameDir + '/autoexec.cfg');
 977
 978   g_Console_Add(Format(_lc[I_CONSOLE_WELCOME], [GAME_VERSION]));
 979   g_Console_Add('');
 980 end;
 981
 982 procedure g_Console_Update();
 983 var
 984   a, b: Integer;
 985 begin
 986   if Cons_Shown then
 987   begin
 988   // Â ïðîöåññå îòêðûòèÿ:
 989     if gConsoleShow and (Cons_Y < 0) then
 990     begin
 991       Cons_Y := Cons_Y+Step;
 992     end;
 993
 994   // Â ïðîöåññå çàêðûòèÿ:
 995     if (not gConsoleShow) and
 996        (Cons_Y > -(gScreenHeight div 2)) then
 997       Cons_Y := Cons_Y-Step;
 998
 999   // Îêîí÷àòåëüíî îòêðûëàñü:
1000     if Cons_Y > 0 then
1001       Cons_Y := 0;
1002
1003   // Îêîí÷àòåëüíî çàêðûëàñü:
1004     if Cons_Y <= (-(gScreenHeight div 2)) then
1005     begin
1006       Cons_Y := -(gScreenHeight div 2);
1007       Cons_Shown := False;
1008     end;
1009   end;
1010
1011   a := 0;
1012   while a <= High(MsgArray) do
1013   begin
1014     if MsgArray[a].Time > 0 then
1015     begin
1016       if MsgArray[a].Time = 1 then
1017         begin
1018           if a < High(MsgArray) then
1019           begin
1020             for b := a to High(MsgArray)-1 do
1021               MsgArray[b] := MsgArray[b+1];
1022
1023             MsgArray[High(MsgArray)].Time := 0;
1024
1025             a := a - 1;
1026           end;
1027         end
1028       else
1029         Dec(MsgArray[a].Time);
1030     end;
1031
1032     a := a + 1;
1033   end;
1034 end;
1035
1036
1037 procedure drawConsoleText ();
1038 var
1039   CWidth, CHeight: Byte;
1040   ty: Integer;
1041   sp, ep: LongWord;
1042   skip: Integer;
1043
1044   procedure putLine (sp, ep: LongWord);
1045   var
1046     p: LongWord;
1047     wdt, cw: Integer;
1048   begin
1049     p := sp;
1050     wdt := 0;
1051     while p <> ep do
1052     begin
1053       cw := e_TextureFontCharWidth(cbufAt(p), gStdFont);
1054       if wdt+cw > gScreenWidth-8 then break;
1055       //e_TextureFontPrintChar(X, Y: Integer; Ch: Char; FontID: DWORD; Shadow: Boolean = False);
1056       Inc(wdt, cw);
1057       cbufNext(p);
1058     end;
1059     if p <> ep then putLine(p, ep); // do rest of the line first
1060     // now print our part
1061     if skip = 0 then
1062     begin
1063       ep := p;
1064       p := sp;
1065       wdt := 2;
1066       while p <> ep do
1067       begin
1068         cw := e_TextureFontCharWidth(cbufAt(p), gStdFont);
1069         e_TextureFontPrintCharEx(wdt, ty, cbufAt(p), gStdFont);
1070         Inc(wdt, cw);
1071         cbufNext(p);
1072       end;
1073       Dec(ty, CHeight);
1074     end
1075     else
1076     begin
1077       Dec(skip);
1078     end;
1079   end;
1080
1081 begin
1082   e_TextureFontGetSize(gStdFont, CWidth, CHeight);
1083   ty := (gScreenHeight div 2)-4-2*CHeight-Abs(Cons_Y);
1084   skip := conSkipLines;
1085   cbufLastLine(sp, ep);
1086   repeat
1087     putLine(sp, ep);
1088     if ty+CHeight <= 0 then break;
1089   until not cbufLineUp(sp, ep);
1090 end;
1091
1092 procedure g_Console_Draw();
1093 var
1094   CWidth, CHeight: Byte;
1095   mfW, mfH: Word;
1096   a, b: Integer;
1097 begin
1098   e_TextureFontGetSize(gStdFont, CWidth, CHeight);
1099
1100   for a := 0 to High(MsgArray) do
1101     if MsgArray[a].Time > 0 then
1102       e_TextureFontPrintFmt(0, CHeight*a, MsgArray[a].Msg,
1103         gStdFont, True);
1104
1105   if not Cons_Shown then
1106   begin
1107     if gChatShow then
1108     begin
1109       if gChatTeam then
1110       begin
1111         e_TextureFontPrintEx(0, gScreenHeight - CHeight - 1, 'say team> ' + Line,
1112           gStdFont, 255, 255, 255, 1, True);
1113         e_TextureFontPrintEx((CPos + 9)*CWidth, gScreenHeight - CHeight - 1, '_',
1114           gStdFont, 255, 255, 255, 1, True);
1115       end
1116       else
1117       begin
1118         e_TextureFontPrintEx(0, gScreenHeight - CHeight - 1, 'say> ' + Line,
1119           gStdFont, 255, 255, 255, 1, True);
1120         e_TextureFontPrintEx((CPos + 4)*CWidth, gScreenHeight - CHeight - 1, '_',
1121           gStdFont, 255, 255, 255, 1, True);
1122       end;
1123     end;
1124     Exit;
1125   end;
1126
1127   if gDebugMode then
1128   begin
1129     e_CharFont_GetSize(gMenuFont, DEBUG_STRING, mfW, mfH);
1130     a := (gScreenWidth - 2*mfW) div 2;
1131     b := Cons_Y + ((gScreenHeight div 2) - 2*mfH) div 2;
1132     e_CharFont_PrintEx(gMenuFont, a div 2, b div 2, DEBUG_STRING,
1133                        _RGB(128, 0, 0), 2.0);
1134   end;
1135
1136   e_DrawSize(ID, 0, Cons_Y, Alpha, False, False, gScreenWidth, gScreenHeight div 2);
1137   e_TextureFontPrint(0, Cons_Y+(gScreenHeight div 2)-CHeight-4, '> '+Line, gStdFont);
1138
1139   drawConsoleText();
1140   (*
1141   if ConsoleHistory <> nil then
1142   begin
1143     b := 0;
1144     if CHeight > 0 then
1145       if Length(ConsoleHistory) > ((gScreenHeight div 2) div CHeight)-1 then
1146         b := Length(ConsoleHistory)-((gScreenHeight div 2) div CHeight)+1;
1147
1148     b := Max(b-Offset, 0);
1149     d := Max(High(ConsoleHistory)-Offset, 0);
1150
1151     c := 2;
1152     for a := d downto b do
1153     begin
1154       e_TextureFontPrintFmt(0, (gScreenHeight div 2)-4-c*CHeight-Abs(Cons_Y), ConsoleHistory[a],
1155                            gStdFont, True);
1156       c := c + 1;
1157     end;
1158   end;
1159   *)
1160
1161   e_TextureFontPrint((CPos+1)*CWidth, Cons_Y+(gScreenHeight div 2)-21, '_', gStdFont);
1162 end;
1163
1164 procedure g_Console_Char(C: AnsiChar);
1165 begin
1166   if not gSkipFirstChar then
1167   begin
1168     Insert(C, Line, CPos);
1169     CPos := CPos + 1;
1170   end;
1171   gSkipFirstChar := False
1172 end;
1173
1174
1175 var
1176   tcomplist: array of AnsiString = nil;
1177   tcompidx: array of Integer = nil;
1178
1179 procedure Complete ();
1180 var
1181   i, c: Integer;
1182   tused: Integer;
1183   ll, lpfx, cmd: AnsiString;
1184 begin
1185   if (Length(Line) = 0) then
1186   begin
1187     g_Console_Add('');
1188     for i := 0 to High(commands) do
1189     begin
1190       // hidden commands are hidden when cheats aren't enabled
1191       if commands[i].hidden and not conIsCheatsEnabled then continue;
1192       if (Length(commands[i].help) > 0) then
1193       begin
1194         g_Console_Add('  '+commands[i].cmd+' -- '+commands[i].help);
1195       end
1196       else
1197       begin
1198         g_Console_Add('  '+commands[i].cmd);
1199       end;
1200     end;
1201     exit;
1202   end;
1203
1204   ll := LowerCase(Line);
1205   lpfx := '';
1206
1207   if (Length(ll) > 1) and (ll[Length(ll)] = ' ') then
1208   begin
1209     ll := Copy(ll, 0, Length(ll)-1);
1210     for i := 0 to High(commands) do
1211     begin
1212       // hidden commands are hidden when cheats aren't enabled
1213       if commands[i].hidden and not conIsCheatsEnabled then continue;
1214       if (commands[i].cmd = ll) then
1215       begin
1216         if (Length(commands[i].help) > 0) then
1217         begin
1218           g_Console_Add('  '+commands[i].cmd+' -- '+commands[i].help);
1219         end;
1220       end;
1221     end;
1222     exit;
1223   end;
1224
1225   // build completion list
1226   tused := 0;
1227   for i := 0 to High(commands) do
1228   begin
1229     // hidden commands are hidden when cheats aren't enabled
1230     if commands[i].hidden and not conIsCheatsEnabled then continue;
1231     cmd := commands[i].cmd;
1232     if (Length(cmd) >= Length(ll)) and (ll = Copy(cmd, 0, Length(ll))) then
1233     begin
1234       if (tused = Length(tcomplist)) then
1235       begin
1236         SetLength(tcomplist, Length(tcomplist)+128);
1237         SetLength(tcompidx, Length(tcompidx)+128);
1238       end;
1239       tcomplist[tused] := cmd;
1240       tcompidx[tused] := i;
1241       Inc(tused);
1242       if (Length(cmd) > Length(lpfx)) then lpfx := cmd;
1243     end;
1244   end;
1245
1246   // get longest prefix
1247   for i := 0 to tused-1 do
1248   begin
1249     cmd := tcomplist[i];
1250     for c := 1 to Length(lpfx) do
1251     begin
1252       if (c > Length(cmd)) then break;
1253       if (cmd[c] <> lpfx[c]) then begin lpfx := Copy(lpfx, 0, c-1); break; end;
1254     end;
1255   end;
1256
1257   if (tused = 0) then exit;
1258
1259   if (tused = 1) then
1260   begin
1261     Line := tcomplist[0]+' ';
1262     CPos := Length(Line)+1;
1263   end
1264   else
1265   begin
1266     // has longest prefix?
1267     if (Length(lpfx) > Length(ll)) then
1268     begin
1269       Line := lpfx;
1270       CPos:= Length(Line)+1;
1271     end
1272     else
1273     begin
1274       g_Console_Add('');
1275       for i := 0 to tused-1 do
1276       begin
1277         if (Length(commands[tcompidx[i]].help) > 0) then
1278         begin
1279           g_Console_Add('  '+tcomplist[i]+' -- '+commands[tcompidx[i]].help);
1280         end
1281         else
1282         begin
1283           g_Console_Add('  '+tcomplist[i]);
1284         end;
1285       end;
1286     end;
1287   end;
1288 end;
1289
1290
1291 procedure g_Console_Control(K: Word);
1292 begin
1293   case K of
1294     IK_BACKSPACE:
1295       if (Length(Line) > 0) and (CPos > 1) then
1296       begin
1297         Delete(Line, CPos-1, 1);
1298         CPos := CPos-1;
1299       end;
1300     IK_DELETE:
1301       if (Length(Line) > 0) and (CPos <= Length(Line)) then
1302         Delete(Line, CPos, 1);
1303     IK_LEFT, IK_KPLEFT, VK_LEFT, JOY0_LEFT, JOY1_LEFT, JOY2_LEFT, JOY3_LEFT:
1304       if CPos > 1 then
1305         CPos := CPos - 1;
1306     IK_RIGHT, IK_KPRIGHT, VK_RIGHT, JOY0_RIGHT, JOY1_RIGHT, JOY2_RIGHT, JOY3_RIGHT:
1307       if CPos <= Length(Line) then
1308         CPos := CPos + 1;
1309     IK_RETURN, IK_KPRETURN, VK_OPEN, VK_FIRE, JOY0_ATTACK, JOY1_ATTACK, JOY2_ATTACK, JOY3_ATTACK:
1310     begin
1311       if Cons_Shown then
1312         g_Console_Process(Line)
1313       else
1314         if gChatShow then
1315         begin
1316           if (Length(Line) > 0) and g_Game_IsNet then
1317           begin
1318             if gChatTeam then
1319             begin
1320               if g_Game_IsClient then
1321                 MC_SEND_Chat(b_Text_Format(Line), NET_CHAT_TEAM)
1322               else
1323                 MH_SEND_Chat('[' + gPlayer1Settings.name + ']: ' + b_Text_Format(Line),
1324                   NET_CHAT_TEAM, gPlayer1Settings.Team);
1325             end
1326             else
1327             begin
1328               if g_Game_IsClient then
1329                 MC_SEND_Chat(b_Text_Format(Line), NET_CHAT_PLAYER)
1330               else
1331                 MH_SEND_Chat('[' + gPlayer1Settings.name + ']: ' + b_Text_Format(Line),
1332                 NET_CHAT_PLAYER);
1333             end;
1334           end;
1335
1336           Line := '';
1337           CPos := 1;
1338           gChatShow := False;
1339           gJustChatted := True;
1340           g_Touch_ShowKeyboard(gConsoleShow or gChatShow);
1341         end;
1342     end;
1343     IK_TAB:
1344       if not gChatShow then
1345         Complete();
1346     IK_DOWN, IK_KPDOWN, VK_DOWN, JOY0_DOWN, JOY1_DOWN, JOY2_DOWN, JOY3_DOWN:
1347       if not gChatShow then
1348         if (CommandHistory <> nil) and
1349            (CmdIndex < Length(CommandHistory)) then
1350         begin
1351           if CmdIndex < Length(CommandHistory)-1 then
1352             CmdIndex := CmdIndex + 1;
1353           Line := CommandHistory[CmdIndex];
1354           CPos := Length(Line) + 1;
1355         end;
1356     IK_UP, IK_KPUP, VK_UP, JOY0_UP, JOY1_UP, JOY2_UP, JOY3_UP:
1357       if not gChatShow then
1358         if (CommandHistory <> nil) and
1359            (CmdIndex <= Length(CommandHistory)) then
1360         begin
1361           if CmdIndex > 0 then
1362             CmdIndex := CmdIndex - 1;
1363           Line := CommandHistory[CmdIndex];
1364           Cpos := Length(Line) + 1;
1365         end;
1366     IK_PAGEUP, IK_KPPAGEUP, VK_PREV, JOY0_PREV, JOY1_PREV, JOY2_PREV, JOY3_PREV: // PgUp
1367       if not gChatShow then Inc(conSkipLines);
1368     IK_PAGEDN, IK_KPPAGEDN, VK_NEXT, JOY0_NEXT, JOY1_NEXT, JOY2_NEXT, JOY3_NEXT: // PgDown
1369       if not gChatShow and (conSkipLines > 0) then Dec(conSkipLines);
1370     IK_HOME, IK_KPHOME:
1371       CPos := 1;
1372     IK_END, IK_KPEND:
1373       CPos := Length(Line) + 1;
1374     IK_A..IK_Z, IK_SPACE, IK_SHIFT, IK_RSHIFT, IK_CAPSLOCK, IK_LBRACKET, IK_RBRACKET,
1375     IK_SEMICOLON, IK_QUOTE, IK_BACKSLASH, IK_SLASH, IK_COMMA, IK_DOT, IK_EQUALS,
1376     IK_0, IK_1, IK_2, IK_3, IK_4, IK_5, IK_6, IK_7, IK_8, IK_9, IK_MINUS, IK_EQUALS:
1377       (* see TEXTINPUT event *)
1378   else
1379     if not gSkipFirstChar then
1380     begin
1381       if gConsoleShow and g_Console_MatchBind(K, 'toggleconsole') then
1382         g_Console_Switch;
1383
1384       if g_Console_MatchBind(K, 'togglemenu') then
1385       begin
1386         menu_toggled := True;
1387         if gChatShow then
1388           g_Console_Chat_Switch
1389         else if gConsoleShow then
1390           g_Console_Switch
1391       end
1392     end
1393   end
1394 end;
1395
1396 function GetStr(var Str: AnsiString): AnsiString;
1397 var
1398   a, b: Integer;
1399 begin
1400   Result := '';
1401   if Str[1] = '"' then
1402   begin
1403     for b := 1 to Length(Str) do
1404       if (b = Length(Str)) or (Str[b+1] = '"') then
1405       begin
1406         Result := Copy(Str, 2, b-1);
1407         Delete(Str, 1, b+1);
1408         Str := Trim(Str);
1409         Exit;
1410       end;
1411   end;
1412
1413   for a := 1 to Length(Str) do
1414     if (a = Length(Str)) or (Str[a+1] = ' ') then
1415     begin
1416       Result := Copy(Str, 1, a);
1417       Delete(Str, 1, a+1);
1418       Str := Trim(Str);
1419       Exit;
1420     end;
1421 end;
1422
1423 function ParseString(Str: AnsiString): SSArray;
1424 begin
1425   Result := nil;
1426
1427   Str := Trim(Str);
1428
1429   if Str = '' then
1430     Exit;
1431
1432   while Str <> '' do
1433   begin
1434     SetLength(Result, Length(Result)+1);
1435     Result[High(Result)] := GetStr(Str);
1436   end;
1437 end;
1438
1439 procedure g_Console_Add (L: AnsiString; show: Boolean=false);
1440
1441   procedure conmsg (s: AnsiString);
1442   var
1443     a: Integer;
1444   begin
1445     if length(s) = 0 then exit;
1446     for a := 0 to High(MsgArray) do
1447     begin
1448       with MsgArray[a] do
1449       begin
1450         if Time = 0 then
1451         begin
1452           Msg := s;
1453           Time := MsgTime;
1454           exit;
1455         end;
1456       end;
1457     end;
1458     for a := 0 to High(MsgArray)-1 do MsgArray[a] := MsgArray[a+1];
1459     with MsgArray[High(MsgArray)] do
1460     begin
1461       Msg := L;
1462       Time := MsgTime;
1463     end;
1464   end;
1465
1466 var
1467   f: Integer;
1468 begin
1469   // put it to console
1470   cbufPut(L);
1471   if (length(L) = 0) or ((L[length(L)] <> #10) and (L[length(L)] <> #13)) then cbufPut(#10);
1472
1473   // now show 'em out of console too
1474   show := show and gAllowConsoleMessages;
1475   if show and gShowMessages then
1476   begin
1477     // Âûâîä ñòðîê ñ ïåðåíîñàìè ïî î÷åðåäè
1478     while length(L) > 0 do
1479     begin
1480       f := Pos(#10, L);
1481       if f <= 0 then f := length(L)+1;
1482       conmsg(Copy(L, 1, f-1));
1483       Delete(L, 1, f);
1484     end;
1485   end;
1486
1487   //SetLength(ConsoleHistory, Length(ConsoleHistory)+1);
1488   //ConsoleHistory[High(ConsoleHistory)] := L;
1489
1490   (*
1491 {$IFDEF HEADLESS}
1492   e_WriteLog('CON: ' + L, MSG_NOTIFY);
1493 {$ENDIF}
1494   *)
1495 end;
1496
1497
1498 var
1499   consolewriterLastWasEOL: Boolean = false;
1500
1501 procedure consolewriter (constref buf; len: SizeUInt);
1502 var
1503   b: PByte;
1504 begin
1505   if (len < 1) then exit;
1506   b := PByte(@buf);
1507   consolewriterLastWasEOL := (b[len-1] = 13) or (b[len-1] = 10);
1508   while (len > 0) do
1509   begin
1510     if (b[0] <> 13) and (b[0] <> 10) then
1511     begin
1512       cbufPut(AnsiChar(b[0]));
1513     end
1514     else
1515     begin
1516       if (len > 1) and (b[0] = 13) then begin len -= 1; b += 1; end;
1517       cbufPut(#10);
1518     end;
1519     len -= 1;
1520     b += 1;
1521   end;
1522 end;
1523
1524
1525 // returns formatted string if `writerCB` is `nil`, empty string otherwise
1526 //function formatstrf (const fmt: AnsiString; args: array of const; writerCB: TFormatStrFCallback=nil): AnsiString;
1527 //TFormatStrFCallback = procedure (constref buf; len: SizeUInt);
1528 procedure conwriteln (const s: AnsiString; show: Boolean=false);
1529 begin
1530   g_Console_Add(s, show);
1531 end;
1532
1533
1534 procedure conwritefln (const s: AnsiString; args: array of const; show: Boolean=false);
1535 begin
1536   if show then
1537   begin
1538     g_Console_Add(formatstrf(s, args), true);
1539   end
1540   else
1541   begin
1542     consolewriterLastWasEOL := false;
1543     formatstrf(s, args, consolewriter);
1544     if not consolewriterLastWasEOL then cbufPut(#10);
1545   end;
1546 end;
1547
1548
1549 procedure g_Console_Clear();
1550 begin
1551   //ConsoleHistory := nil;
1552   cbufClear();
1553   conSkipLines := 0;
1554 end;
1555
1556 procedure AddToHistory(L: AnsiString);
1557 var
1558   len: Integer;
1559 begin
1560   len := Length(CommandHistory);
1561
1562   if (len = 0) or
1563      (LowerCase(CommandHistory[len-1]) <> LowerCase(L)) then
1564   begin
1565     SetLength(CommandHistory, len+1);
1566     CommandHistory[len] := L;
1567   end;
1568
1569   CmdIndex := Length(CommandHistory);
1570 end;
1571
1572 function g_Console_CommandBlacklisted(C: AnsiString): Boolean;
1573 var
1574   Arr: SSArray;
1575   i: Integer;
1576 begin
1577   Result := True;
1578
1579   Arr := nil;
1580
1581   if Trim(C) = '' then
1582     Exit;
1583
1584   Arr := ParseString(C);
1585   if Arr = nil then
1586     Exit;
1587
1588   for i := 0 to High(Whitelist) do
1589     if Whitelist[i] = LowerCase(Arr[0]) then
1590       Result := False;
1591 end;
1592
1593 procedure g_Console_Process(L: AnsiString; quiet: Boolean = False);
1594 var
1595   Arr: SSArray;
1596   i: Integer;
1597 begin
1598   Arr := nil;
1599
1600   if Trim(L) = '' then
1601     Exit;
1602
1603   conSkipLines := 0; // "unscroll"
1604
1605   if L = 'goobers' then
1606   begin
1607     Line := '';
1608     CPos := 1;
1609     gCheats := true;
1610     g_Console_Add('Your memory serves you well.');
1611     exit;
1612   end;
1613
1614   if not quiet then
1615   begin
1616     g_Console_Add('> '+L);
1617     Line := '';
1618     CPos := 1;
1619   end;
1620
1621   Arr := ParseString(L);
1622   if Arr = nil then
1623     Exit;
1624
1625   if commands = nil then
1626     Exit;
1627
1628   if not quiet then
1629     AddToHistory(L);
1630
1631   for i := 0 to High(commands) do
1632   begin
1633     if commands[i].cmd = LowerCase(Arr[0]) then
1634     begin
1635       if commands[i].action >= 0 then
1636       begin
1637         gPlayerAction[commands[i].player, commands[i].action] := commands[i].cmd[1] = '+';
1638         exit
1639       end;
1640       if assigned(commands[i].procEx) then
1641       begin
1642         commands[i].procEx(@commands[i], Arr);
1643         exit
1644       end;
1645       if assigned(commands[i].proc) then
1646       begin
1647         commands[i].proc(Arr);
1648         exit
1649       end
1650     end
1651   end;
1652
1653   g_Console_Add(Format(_lc[I_CONSOLE_UNKNOWN], [Arr[0]]));
1654 end;
1655
1656
1657 function g_Console_Interactive: Boolean;
1658 begin
1659   Result := gConsoleShow
1660 end;
1661
1662 procedure g_Console_BindKey (key: Integer; down: AnsiString; up: AnsiString = '');
1663 begin
1664   //e_LogWritefln('bind "%s" "%s" <%s>', [LowerCase(e_KeyNames[key]), cmd, key]);
1665   ASSERT(key >= 0);
1666   ASSERT(key < e_MaxInputKeys);
1667   if key > 0 then
1668   begin
1669     gInputBinds[key].down := ParseAlias(down);
1670     gInputBinds[key].up := ParseAlias(up)
1671   end
1672 end;
1673
1674 function g_Console_MatchBind (key: Integer; down: AnsiString; up: AnsiString = ''): Boolean;
1675
1676   function EqualsCommandLists (a, b: SSArray): Boolean;
1677     var i, len: Integer;
1678   begin
1679     result := False;
1680     len := Length(a);
1681     if len = Length(b) then
1682     begin
1683       i := 0;
1684       while (i < len) and (a[i] = b[i]) do inc(i);
1685       if i >= len then
1686         result := True
1687     end
1688   end;
1689
1690 begin
1691   ASSERT(key >= 0);
1692   ASSERT(key < e_MaxInputKeys);
1693   result := EqualsCommandLists(ParseAlias(down), gInputBinds[key].down) and EqualsCommandLists(ParseAlias(up), gInputBinds[key].up)
1694 end;
1695
1696 function g_Console_FindBind (n: Integer; down: AnsiString; up: AnsiString = ''): Integer;
1697   var i: Integer;
1698 begin
1699   ASSERT(n >= 1);
1700   result := 0;
1701   if commands = nil then Exit;
1702   i := 0;
1703   while (n >= 1) and (i < e_MaxInputKeys) do
1704   begin
1705     if g_Console_MatchBind(i, down, up) then
1706     begin
1707       result := i;
1708       dec(n)
1709     end;
1710     inc(i)
1711   end;
1712   if n >= 1 then
1713     result := 0
1714 end;
1715
1716 function g_Console_Action (action: Integer): Boolean;
1717   var i, len: Integer;
1718 begin
1719   ASSERT(action >= FIRST_ACTION);
1720   ASSERT(action <= LAST_ACTION);
1721   i := 0;
1722   len := Length(gPlayerAction);
1723   while (i < len) and (not gPlayerAction[i, action]) do inc(i);
1724   Result := i < len
1725 end;
1726
1727 procedure g_Console_ProcessBind (key: Integer; down: Boolean);
1728   var i: Integer;
1729 begin
1730   if (key >= 0) and (key < e_MaxInputKeys) and ((gInputBinds[key].down <> nil) or (gInputBinds[key].up <> nil)) then
1731   begin
1732     // down binds shouldn't be processed when there's no input focus
1733     // however when the user releases a button the bind should still be processed
1734     // to avoid "sticky" buttons
1735     if down then
1736     begin
1737       if (not g_GUIGrabInput) and (not gChatShow) and (not gConsoleShow) then
1738         for i := 0 to High(gInputBinds[key].down) do
1739           g_Console_Process(gInputBinds[key].down[i], True);
1740     end
1741     else
1742       for i := 0 to High(gInputBinds[key].up) do
1743         g_Console_Process(gInputBinds[key].up[i], True)
1744   end;
1745   if down and not menu_toggled then
1746     KeyPress(key);
1747   menu_toggled := False
1748 end;
1749
1750 procedure g_Console_ResetBinds;
1751   var i: Integer;
1752 begin
1753   for i := 0 to e_MaxInputKeys - 1 do
1754     g_Console_BindKey(i, '', '');
1755
1756   g_Console_BindKey(IK_GRAVE, 'toggleconsole');
1757   g_Console_BindKey(IK_ESCAPE, 'togglemenu');
1758   g_Console_BindKey(IK_A, '+p1_moveleft', '-p1_moveleft');
1759   g_Console_BindKey(IK_D, '+p1_moveright', '-p1_moveright');
1760   g_Console_BindKey(IK_W, '+p1_lookup', '-p1_lookup');
1761   g_Console_BindKey(IK_S, '+p1_lookdown', '-p1_lookdown');
1762   g_Console_BindKey(IK_SPACE, '+p1_jump', '-p1_jump');
1763   g_Console_BindKey(IK_H, '+p1_attack', '-p1_attack');
1764   g_Console_BindKey(IK_J, '+p1_activate', '-p1_activate');
1765   g_Console_BindKey(IK_E, '+p1_weapnext', '-p1_weapnext');
1766   g_Console_BindKey(IK_Q, '+p1_weapprev', '-p1_weapprev');
1767   g_Console_BindKey(IK_ALT, '+p1_strafe', '-p1_strafe');
1768   g_Console_BindKey(IK_1, 'p1_weapon 1');
1769   g_Console_BindKey(IK_2, 'p1_weapon 2');
1770   g_Console_BindKey(IK_3, 'p1_weapon 3');
1771   g_Console_BindKey(IK_4, 'p1_weapon 4');
1772   g_Console_BindKey(IK_5, 'p1_weapon 5');
1773   g_Console_BindKey(IK_6, 'p1_weapon 6');
1774   g_Console_BindKey(IK_7, 'p1_weapon 7');
1775   g_Console_BindKey(IK_8, 'p1_weapon 8');
1776   g_Console_BindKey(IK_9, 'p1_weapon 9');
1777   g_Console_BindKey(IK_0, 'p1_weapon 10');
1778   g_Console_BindKey(IK_MINUS, 'p1_weapon 11');
1779   g_Console_BindKey(IK_T, 'togglechat');
1780   g_Console_BindKey(IK_Y, 'toggleteamchat');
1781   g_Console_BindKey(IK_F11, 'screenshot');
1782   g_Console_BindKey(IK_TAB, '+p1_scores', '-p1_scores');
1783   g_Console_BindKey(IK_PAUSE, 'pause');
1784   g_Console_BindKey(IK_F1, 'vote');
1785
1786   (* for i := 0 to e_MaxJoys - 1 do *)
1787   for i := 0 to 1 do
1788   begin
1789     g_Console_BindKey(e_JoyHatToKey(i, 0, HAT_LEFT), '+p' + IntToStr(i mod 2 + 1) + '_moveleft', '-p' + IntToStr(i mod 2 + 1) + '_moveleft');
1790     g_Console_BindKey(e_JoyHatToKey(i, 0, HAT_RIGHT), '+p' + IntToStr(i mod 2 + 1) + '_moveright', '-p' + IntToStr(i mod 2 + 1) + '_moveright');
1791     g_Console_BindKey(e_JoyHatToKey(i, 0, HAT_UP), '+p' + IntToStr(i mod 2 + 1) + '_lookup', '-p' + IntToStr(i mod 2 + 1) + '_lookup');
1792     g_Console_BindKey(e_JoyHatToKey(i, 0, HAT_DOWN), '+p' + IntToStr(i mod 2 + 1) + '_lookdown', '-p' + IntToStr(i mod 2 + 1) + '_lookdown');
1793     g_Console_BindKey(e_JoyButtonToKey(i, 2), '+p' + IntToStr(i mod 2 + 1) + '_jump', '-p' + IntToStr(i mod 2 + 1) + '_jump');
1794     g_Console_BindKey(e_JoyButtonToKey(i, 0), '+p' + IntToStr(i mod 2 + 1) + '_attack', '-p' + IntToStr(i mod 2 + 1) + '_attack');
1795     g_Console_BindKey(e_JoyButtonToKey(i, 3), '+p' + IntToStr(i mod 2 + 1) + '_activate', '-p' + IntToStr(i mod 2 + 1) + '_activate');
1796     g_Console_BindKey(e_JoyButtonToKey(i, 1), '+p' + IntToStr(i mod 2 + 1) + '_weapnext', '-p' + IntToStr(i mod 2 + 1) + '_weapnext');
1797     g_Console_BindKey(e_JoyButtonToKey(i, 4), '+p' + IntToStr(i mod 2 + 1) + '_weapprev', '-p' + IntToStr(i mod 2 + 1) + '_weapprev');
1798     g_Console_BindKey(e_JoyButtonToKey(i, 7), '+p' + IntToStr(i mod 2 + 1) + '_strafe', '-p' + IntToStr(i mod 2 + 1) + '_strafe');
1799     g_Console_BindKey(e_JoyButtonToKey(i, 10), 'togglemenu');
1800   end;
1801
1802   g_Console_BindKey(VK_ESCAPE, 'togglemenu');
1803   g_Console_BindKey(VK_LSTRAFE, '+moveleft; +strafe', '-moveleft; -strafe');
1804   g_Console_BindKey(VK_RSTRAFE, '+moveright; +strafe', '-moveright; -strafe');
1805   g_Console_BindKey(VK_LEFT, '+moveleft', '-moveleft');
1806   g_Console_BindKey(VK_RIGHT, '+moveright', '-moveright');
1807   g_Console_BindKey(VK_UP, '+lookup', '-lookup');
1808   g_Console_BindKey(VK_DOWN, '+lookdown', '-lookdown');
1809   g_Console_BindKey(VK_JUMP, '+jump', '-jump');
1810   g_Console_BindKey(VK_FIRE, '+attack', '-attack');
1811   g_Console_BindKey(VK_OPEN, '+activate', '-activate');
1812   g_Console_BindKey(VK_NEXT, '+weapnext', '-weapnext');
1813   g_Console_BindKey(VK_PREV, '+weapprev', '-weapprev');
1814   g_Console_BindKey(VK_STRAFE, '+strafe', '-strafe');
1815   g_Console_BindKey(VK_0, 'weapon 1');
1816   g_Console_BindKey(VK_1, 'weapon 2');
1817   g_Console_BindKey(VK_2, 'weapon 3');
1818   g_Console_BindKey(VK_3, 'weapon 4');
1819   g_Console_BindKey(VK_4, 'weapon 5');
1820   g_Console_BindKey(VK_5, 'weapon 6');
1821   g_Console_BindKey(VK_6, 'weapon 7');
1822   g_Console_BindKey(VK_7, 'weapon 8');
1823   g_Console_BindKey(VK_8, 'weapon 9');
1824   g_Console_BindKey(VK_9, 'weapon 10');
1825   g_Console_BindKey(VK_A, 'weapon 11');
1826   g_Console_BindKey(VK_CHAT, 'togglechat');
1827   g_Console_BindKey(VK_TEAM, 'toggleteamchat');
1828   g_Console_BindKey(VK_CONSOLE, 'toggleconsole');
1829   g_Console_BindKey(VK_PRINTSCR, 'screenshot');
1830   g_Console_BindKey(VK_STATUS, '+scores', '-scores');
1831   g_Console_BindKey(VK_SHOWKBD, 'showkeyboard');
1832   g_Console_BindKey(VK_HIDEKBD, 'hidekeyboard');
1833 end;
1834
1835 procedure g_Console_ReadConfig (filename: String);
1836   var f: TextFile; s: AnsiString; i, len: Integer;
1837 begin
1838   if FileExists(filename) then
1839   begin
1840     AssignFile(f, filename);
1841     Reset(f);
1842     while not EOF(f) do
1843     begin
1844       ReadLn(f, s);
1845       len := Length(s);
1846       if len > 0 then
1847       begin
1848         i := 1;
1849         (* skip spaces *)
1850         while (i <= len) and (s[i] <= ' ') do inc(i);
1851         (* skip comments *)
1852         if (i <= len) and ((s[i] <> '#') and ((i + 1 > len) or (s[i] <> '/') or (s[i + 1] <> '/'))) then
1853           g_Console_Process(s, True)
1854       end
1855     end;
1856     CloseFile(f)
1857   end
1858 end;
1859
1860 procedure g_Console_WriteConfig (filename: String);
1861   var f: TextFile; i, j: Integer;
1862 begin
1863   AssignFile(f, filename);
1864   Rewrite(f);
1865   WriteLn(f, '// generated by doom2d, do not modify');
1866   WriteLn(f, 'unbindall');
1867   for i := 0 to e_MaxInputKeys - 1 do
1868     if (Length(gInputBinds[i].down) > 0) or (Length(gInputBinds[i].up) > 0) then
1869       WriteLn(f, 'bind ', e_KeyNames[i], ' "', GetCommandString(gInputBinds[i].down), '" "', GetCommandString(gInputBinds[i].up), '"');
1870   for i := 0 to High(commands) do
1871   begin
1872     if not commands[i].cheat then
1873     begin
1874       if @commands[i].procEx = @boolVarHandler then
1875       begin
1876         if PBoolean(commands[i].ptr)^ then j := 1 else j := 0;
1877         WriteLn(f, commands[i].cmd, ' "', j, '"')
1878       end
1879       else if @commands[i].procEx = @intVarHandler then
1880       begin
1881         WriteLn(f, commands[i].cmd, ' "', PInteger(commands[i].ptr)^, '"')
1882       end
1883       else if @commands[i].procEx = @singleVarHandler then
1884       begin
1885         WriteLn(f, commands[i].cmd, ' "', PVarSingle(commands[i].ptr).val^:0:6, '"')
1886       end
1887     end
1888   end;
1889   CloseFile(f)
1890 end;
1891
1892
1893 end.