DEADSOFTWARE

GIT / REPO / FRED-BOY
Projects / d2df-sdl.git / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
gl: use TAnimInfo for animations calculated by render
[d2df-sdl.git] / src / game / renders / opengl / r_map.pas
1 (* Copyright (C) Doom 2D: Forever Developers
2 *
3 * This program is free software: you can redistribute it and/or modify
4 * it under the terms of the GNU General Public License as published by
5 * the Free Software Foundation, version 3 of the License ONLY.
6 *
7 * This program is distributed in the hope that it will be useful,
8 * but WITHOUT ANY WARRANTY; without even the implied warranty of
9 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
10 * GNU General Public License for more details.
11 *
12 * You should have received a copy of the GNU General Public License
13 * along with this program. If not, see <http://www.gnu.org/licenses/>.
14 *)
15 {$INCLUDE ../../../shared/a_modes.inc}
16 unit r_map;
17
18 interface
19
20 uses g_base, g_player, g_playermodel; // TRectWH, TPlayer, TPlayerModel
21
22 procedure r_Map_Initialize;
23 procedure r_Map_Finalize;
24
25 procedure r_Map_Load;
26 procedure r_Map_Free;
27
28 procedure r_Map_LoadTextures;
29 procedure r_Map_FreeTextures;
30
31 {$IFDEF ENABLE_GFX}
32 procedure r_Map_NewGFX (typ, x, y: Integer);
33 {$ENDIF}
34 {$IFDEF ENABLE_GIBS}
35 function r_Map_GetGibSize (m, i: Integer): TRectWH;
36 {$ENDIF}
37 {$IFDEF ENABLE_MENU}
38 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer; alpha: Byte);
39 {$ENDIF}
40
41 procedure r_Map_Update;
42
43 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer; player: TPlayer);
44
45 implementation
46
47 uses
48 Math,
49 {$IFDEF USE_GLES1}
50 GLES11,
51 {$ELSE}
52 GL, GLEXT,
53 {$ENDIF}
54 e_log,
55 binheap, MAPDEF, utils,
56 g_options, g_animations, g_basic, g_phys,
57 g_game, g_map, g_panel, g_items, g_monsters, g_weapons,
58 {$IFDEF ENABLE_CORPSES}
59 g_corpses,
60 {$ENDIF}
61 {$IFDEF ENABLE_SHELLS}
62 g_shells,
63 {$ENDIF}
64 {$IFDEF ENABLE_GIBS}
65 g_gibs,
66 {$ENDIF}
67 {$IFDEF ENABLE_GFX}
68 g_gfx,
69 {$ENDIF}
70 r_textures, r_draw
71 ;
72
73 const
74 MTABLE: array [0..MONSTER_MAN] of record
75 w, h: Integer;
76 end = (
77 (w: 64; h: 64), // NONE
78 (w: 64; h: 64), // DEMON
79 (w: 64; h: 64), // IMP
80 (w: 64; h: 64), // ZOMBY
81 (w: 64; h: 64), // SERG
82 (w: 128; h: 128), // CYBER
83 (w: 64; h: 64), // CGUN
84 (w: 128; h: 128), // BARON
85 (w: 128; h: 128), // KNIGHT
86 (w: 128; h: 128), // CACO
87 (w: 64; h: 64), // SOUL (DIE is 128x128, see load code)
88 (w: 128; h: 128), // PAIN
89 (w: 256; h: 128), // SPIDER
90 (w: 128; h: 64), // BSP
91 (w: 128; h: 128), // MANCUB
92 (w: 128; h: 128), // SKEL
93 (w: 128; h: 128), // VILE
94 (w: 32; h: 32), // FISH
95 (w: 64; h: 64), // BARREL
96 (w: 128; h: 128), // ROBO
97 (w: 64; h: 64) // MAN
98 );
99 VILEFIRE_DX = 32;
100 VILEFIRE_DY = 128;
101
102 ItemAnim: array [0..ITEM_LAST] of record
103 name: AnsiString;
104 w, h: Integer;
105 anim: TAnimInfo;
106 end = (
107 (name: 'NOTEXTURE'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
108 (name: 'MED1'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
109 (name: 'MED2'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
110 (name: 'BMED'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
111 (name: 'ARMORGREEN'; w: 32; h: 16; anim: (loop: true; delay: 20; frames: 3; back: true)),
112 (name: 'ARMORBLUE'; w: 32; h: 16; anim: (loop: true; delay: 20; frames: 3; back: true)),
113 (name: 'SBLUE'; w: 32; h: 32; anim: (loop: true; delay: 15; frames: 4; back: true)),
114 (name: 'SWHITE'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
115 (name: 'SUIT'; w: 32; h: 64; anim: (loop: true; delay: 1; frames: 1; back: false)),
116 (name: 'OXYGEN'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
117 (name: 'INVUL'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
118 (name: 'SAW'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
119 (name: 'SHOTGUN1'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
120 (name: 'SHOTGUN2'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
121 (name: 'MGUN'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
122 (name: 'RLAUNCHER'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
123 (name: 'PGUN'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
124 (name: 'BFG'; w: 64; h: 64; anim: (loop: true; delay: 1; frames: 1; back: false)),
125 (name: 'SPULEMET'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
126 (name: 'CLIP'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
127 (name: 'AMMO'; w: 32; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
128 (name: 'SHELL1'; w: 16; h: 8; anim: (loop: true; delay: 1; frames: 1; back: false)),
129 (name: 'SHELL2'; w: 32; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
130 (name: 'ROCKET'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
131 (name: 'ROCKETS'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
132 (name: 'CELL'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
133 (name: 'CELL2'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
134 (name: 'BPACK'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
135 (name: 'KEYR'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
136 (name: 'KEYG'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
137 (name: 'KEYB'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
138 (name: 'KASTET'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
139 (name: 'PISTOL'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
140 (name: 'BOTTLE'; w: 16; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
141 (name: 'HELMET'; w: 16; h: 16; anim: (loop: true; delay: 20; frames: 4; back: true)),
142 (name: 'JETPACK'; w: 32; h: 32; anim: (loop: true; delay: 15; frames: 3; back: true)),
143 (name: 'INVIS'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
144 (name: 'FLAMETHROWER'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
145 (name: 'FUELCAN'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false))
146 );
147
148 {$IFDEF ENABLE_GFX}
149 GFXAnim: array [0..R_GFX_LAST] of record
150 name: AnsiString;
151 w, h: Integer;
152 anim: TAnimInfo;
153 rdelay: Integer;
154 alpha: Integer;
155 end = (
156 (name: ''; w: 0; h: 0; anim: (loop: false; delay: 0; frames: 0; back: false); rdelay: 0; alpha: 0),
157 (name: 'TELEPORT'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 10; back: false); rdelay: 0; alpha: 0),
158 (name: 'FLAME'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 11; back: false); rdelay: 0; alpha: 0),
159 (name: 'EROCKET'; w: 128; h: 128; anim: (loop: false; delay: 6; frames: 6; back: false); rdelay: 0; alpha: 0),
160 (name: 'EBFG'; w: 128; h: 128; anim: (loop: false; delay: 6; frames: 6; back: false); rdelay: 0; alpha: 0),
161 (name: 'BFGHIT'; w: 64; h: 64; anim: (loop: false; delay: 4; frames: 4; back: false); rdelay: 0; alpha: 0),
162 (name: 'FIRE'; w: 64; h: 128; anim: (loop: false; delay: 4; frames: 8; back: false); rdelay: 2; alpha: 0),
163 (name: 'ITEMRESPAWN'; w: 32; h: 32; anim: (loop: false; delay: 4; frames: 5; back: true); rdelay: 0; alpha: 0),
164 (name: 'SMOKE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 0),
165 (name: 'ESKELFIRE'; w: 64; h: 64; anim: (loop: false; delay: 8; frames: 3; back: false); rdelay: 0; alpha: 0),
166 (name: 'EPLASMA'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 4; back: true); rdelay: 0; alpha: 0),
167 (name: 'EBSPFIRE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 5; back: false); rdelay: 0; alpha: 0),
168 (name: 'EIMPFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
169 (name: 'ECACOFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
170 (name: 'EBARONFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
171 (name: 'TELEPORT'; w: 64; h: 64; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 0), // fast
172 (name: 'SMOKE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 150), // transparent
173 (name: 'FLAME'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 11; back: false); rdelay: 2; alpha: 0) // random
174 );
175 {$ENDIF}
176
177 ShotAnim: array [0..WEAPON_LAST] of record
178 name: AnsiString;
179 w, h: Integer;
180 count: Integer;
181 end = (
182 (name: ''; w: 0; h: 0; count: 0), // 0 KASTET
183 (name: ''; w: 0; h: 0; count: 0), // 1 SAW
184 (name: ''; w: 0; h: 0; count: 0), // 2 PISTOL
185 (name: ''; w: 0; h: 0; count: 0), // 3 SHOTGUN1
186 (name: ''; w: 0; h: 0; count: 0), // 4 SHOTGUN2
187 (name: ''; w: 0; h: 0; count: 0), // 5 CHAINGUN
188 (name: 'BROCKET'; w: 64; h: 32; count: 1), // 6 ROCKETLAUNCHER
189 (name: 'BPLASMA'; w: 16; h: 16; count: 2), // 7 PLASMA
190 (name: 'BBFG'; w: 64; h: 64; count: 2), // 8 BFG
191 (name: ''; w: 0; h: 0; count: 0), // 9 SUPERPULEMET
192 (name: 'FLAME'; w: 32; h: 32; count: 0{11}), // 10 FLAMETHROWER
193 (name: ''; w: 0; h: 0; count: 0), // 11
194 (name: ''; w: 0; h: 0; count: 0), // 12
195 (name: ''; w: 0; h: 0; count: 0), // 13
196 (name: ''; w: 0; h: 0; count: 0), // 14
197 (name: ''; w: 0; h: 0; count: 0), // 15
198 (name: ''; w: 0; h: 0; count: 0), // 16
199 (name: ''; w: 0; h: 0; count: 0), // 17
200 (name: ''; w: 0; h: 0; count: 0), // 18
201 (name: ''; w: 0; h: 0; count: 0), // 19
202 (name: ''; w: 0; h: 0; count: 0), // 20 ZOMPY_PISTOL
203 (name: 'BIMPFIRE'; w: 16; h: 16; count: 2), // 21 IMP_FIRE
204 (name: 'BBSPFIRE'; w: 16; h: 16; count: 2), // 22 BSP_FIRE
205 (name: 'BCACOFIRE'; w: 16; h: 16; count: 2), // 23 CACO_FIRE
206 (name: 'BBARONFIRE'; w: 64; h: 16; count: 2), // 24 BARON_FIRE
207 (name: 'BMANCUBFIRE'; w: 64; h: 32; count: 2), // 25 MANCUB_FIRE
208 (name: 'BSKELFIRE'; w: 64; h: 64; count: 2) // 26 SKEL_FIRE
209 );
210
211 {$IFDEF ENABLE_SHELLS}
212 ShellAnim: array [0..SHELL_LAST] of record
213 name: AnsiString;
214 dx, dy: Integer;
215 end = (
216 (name: 'EBULLET'; dx: 2; dy: 1), // 0 SHELL_BULLET
217 (name: 'ESHELL'; dx: 4; dy: 2), // 1 SHELL_SHELL
218 (name: 'ESHELL'; dx: 4; dy: 2) // 2 SHELL_DBLSHELL
219 );
220 {$ENDIF}
221
222 FlagAnim: TAnimInfo = (loop: true; delay: 8; frames: 5; back: false);
223
224 type
225 TBinHeapPanelDrawCmp = class
226 public
227 class function less (const a, b: TPanel): Boolean; inline;
228 end;
229
230 TBinHeapPanelDraw = specialize TBinaryHeapBase<TPanel, TBinHeapPanelDrawCmp>;
231
232 TMonsterAnims = array [0..ANIM_LAST, TDirection] of TGLMultiTexture;
233
234 var
235 SkyTexture: TGLTexture;
236 RenTextures: array of record
237 spec: LongInt;
238 tex: TGLMultiTexture;
239 end;
240 Items: array [0..ITEM_LAST] of record
241 tex: TGLMultiTexture;
242 frame: Integer;
243 end;
244 MonTextures: array [0..MONSTER_MAN] of TMonsterAnims;
245 WeapTextures: array [0..WP_LAST, 0..W_POS_LAST, 0..W_ACT_LAST] of TGLTexture;
246 ShotTextures: array [0..WEAPON_LAST] of TGLMultiTexture;
247 FlagTextures: array [0..FLAG_LAST] of TGLMultiTexture;
248 PunchTextures: array [Boolean, 0..2] of TGLMultiTexture; // [berserk, center/up/down]
249 VileFire: TGLMultiTexture;
250 InvulPenta: TGLTexture;
251 Models: array of record
252 anim: array [TDirection, 0..A_LAST] of record
253 base, mask: TGLMultiTexture;
254 end;
255 {$IFDEF ENABLE_GIBS}
256 gibs: record
257 base, mask: TGLTextureArray;
258 rect: TRectArray;
259 end;
260 {$ENDIF}
261 end;
262
263 StubShotAnim: TAnimState; // TODO remove this hack
264 FlagFrame: LongInt;
265
266 {$IFDEF ENABLE_SHELLS}
267 ShellTextures: array [0..SHELL_LAST] of TGLTexture;
268 {$ENDIF}
269 {$IFDEF ENABLE_GFX}
270 GFXTextures: array [0..R_GFX_LAST] of TGLMultiTexture;
271 gfxlist: array of record
272 typ: Byte;
273 x, y: Integer;
274 oldX, oldY: Integer;
275 anim: TAnimInfo;
276 time: LongWord;
277 frame: LongInt;
278 end = nil;
279 {$ENDIF}
280
281 plist: TBinHeapPanelDraw = nil;
282
283 class function TBinHeapPanelDrawCmp.less (const a, b: TPanel): Boolean; inline;
284 begin
285 if a.tag < b.tag then begin result := true; exit; end;
286 if a.tag > b.tag then begin result := false; exit; end;
287 result := a.arrIdx < b.arrIdx;
288 end;
289
290 procedure r_Map_Initialize;
291 begin
292 StubShotAnim := TAnimState.Create(true, 1, 1);
293 FlagFrame := 0;
294 plist := TBinHeapPanelDraw.Create();
295 end;
296
297 procedure r_Map_Finalize;
298 begin
299 plist.Free;
300 FlagFrame := 0;
301 StubShotAnim.Invalidate;
302 end;
303
304 procedure r_Map_FreeModel (i: Integer);
305 var a: Integer; d: TDirection;
306 begin
307 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
308 begin
309 for a := A_STAND to A_LAST do
310 begin
311 if Models[i].anim[d, a].base <> nil then
312 Models[i].anim[d, a].base.Free;
313 if Models[i].anim[d, a].mask <> nil then
314 Models[i].anim[d, a].mask.Free;
315 Models[i].anim[d, a].base := nil;
316 Models[i].anim[d, a].mask := nil;
317 end;
318 end;
319 {$IFDEF ENABLE_GIBS}
320 if Models[i].gibs.base <> nil then
321 for a := 0 to High(Models[i].gibs.base) do
322 Models[i].gibs.base[a].Free;
323 if Models[i].gibs.mask <> nil then
324 for a := 0 to High(Models[i].gibs.mask) do
325 Models[i].gibs.mask[a].Free;
326 Models[i].gibs.base := nil;
327 Models[i].gibs.mask := nil;
328 Models[i].gibs.rect := nil;
329 {$ENDIF}
330 end;
331
332 procedure r_Map_LoadModel (i: Integer);
333 var prefix: AnsiString; a: Integer; d: TDirection; m: ^TPlayerModelInfo;
334 begin
335 ASSERT(i < Length(Models));
336 ASSERT(i < Length(PlayerModelsArray));
337 r_Map_FreeModel(i);
338 m := @PlayerModelsArray[i];
339 prefix := m.FileName + ':TEXTURES/';
340 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
341 begin
342 for a := A_STAND to A_LAST do
343 begin
344 Models[i].anim[d, a].base := nil;
345 Models[i].anim[d, a].mask := nil;
346 if m.anim[d, a].resource <> '' then
347 Models[i].anim[d, a].base := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].resource, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
348 if m.anim[d, a].mask <> '' then
349 Models[i].anim[d, a].mask := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].mask, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
350 end
351 end;
352 {$IFDEF ENABLE_GIBS}
353 Models[i].gibs.base := nil;
354 Models[i].gibs.mask := nil;
355 Models[i].gibs.rect := nil;
356 if m.GibsCount > 0 then
357 begin
358 SetLength(Models[i].gibs.base, m.GibsCount);
359 SetLength(Models[i].gibs.mask, m.GibsCount);
360 SetLength(Models[i].gibs.rect, m.GibsCount);
361 for a := 0 to m.GibsCount - 1 do
362 Models[i].gibs.rect[a] := DefaultGibSize;
363 if r_Textures_LoadStreamFromFile(prefix + m.GibsResource, 32, 32, m.GibsCount, m.GibsCount, Models[i].gibs.base, Models[i].gibs.rect) then
364 begin
365 if r_Textures_LoadStreamFromFile(prefix + m.GibsMask, 32, 32, m.GibsCount, m.GibsCount, Models[i].gibs.mask, nil) then
366 begin
367 // ok
368 end;
369 end;
370 end;
371 {$ENDIF}
372 end;
373
374 procedure r_Map_LoadMonsterAnim (m, a: Integer; d: TDirection);
375 const dir: array [TDirection] of AnsiString = ('_L', '');
376 var w, h, count: Integer;
377 begin
378 count := MONSTER_ANIMTABLE[m].AnimCount[a];
379 if count > 0 then
380 begin
381 w := MTABLE[m].w;
382 h := MTABLE[m].h;
383 if (m = MONSTER_SOUL) and (a = ANIM_DIE) then
384 begin
385 // special case
386 w := 128;
387 h := 128;
388 end;
389 MonTextures[m, a, d] := r_Textures_LoadMultiFromFileAndInfo(
390 GameWAD + ':MTEXTURES/' + MONSTERTABLE[m].name + '_' + ANIMTABLE[a].name + dir[d],
391 w,
392 h,
393 count,
394 False,
395 False
396 );
397 end
398 else
399 MonTextures[m, a, d] := nil;
400 end;
401
402 procedure r_Map_Load;
403 const
404 WeapName: array [0..WP_LAST] of AnsiString = ('', 'CSAW', 'HGUN', 'SG', 'SSG', 'MGUN', 'RKT', 'PLZ', 'BFG', 'SPL', 'FLM');
405 WeapPos: array [0..W_POS_LAST] of AnsiString = ('', '_UP', '_DN');
406 WeapAct: array [0..W_ACT_LAST] of AnsiString = ('', '_FIRE');
407 PunchName: array [Boolean] of AnsiString = ('PUNCH', 'PUNCHB');
408 var
409 i, j, k: Integer; d: TDirection; b: Boolean;
410 begin
411 // --------- items --------- //
412 for i := 0 to ITEM_LAST do
413 begin
414 Items[i].tex := r_Textures_LoadMultiFromFileAndInfo(
415 GameWAD + ':TEXTURES/' + ItemAnim[i].name,
416 ItemAnim[i].w,
417 ItemAnim[i].h,
418 ItemAnim[i].anim.frames,
419 ItemAnim[i].anim.back,
420 false
421 );
422 Items[i].frame := 0;
423 end;
424 // --------- monsters --------- //
425 for i := MONSTER_DEMON to MONSTER_MAN do
426 for j := 0 to ANIM_LAST do
427 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
428 r_Map_LoadMonsterAnim(i, j, d);
429 VileFire := r_Textures_LoadMultiFromFileAndInfo(GameWAD + ':TEXTURES/FIRE', 64, 128, 8, False, False);
430 // --------- player models --------- //
431 if PlayerModelsArray <> nil then
432 begin
433 SetLength(Models, Length(PlayerModelsArray));
434 for i := 0 to High(PlayerModelsArray) do
435 r_Map_LoadModel(i);
436 end;
437 // --------- player weapons --------- //
438 for i := 1 to WP_LAST do
439 for j := 0 to W_POS_LAST do
440 for k := 0 to W_ACT_LAST do
441 WeapTextures[i, j, k] := r_Textures_LoadFromFile(GameWAD + ':WEAPONS\' + WeapName[i] + WeapPos[j] + WeapAct[k]);
442 // --------- gfx animations --------- //
443 {$IFDEF ENABLE_GFX}
444 for i := 1 to R_GFX_LAST do
445 if GFXAnim[i].anim.frames > 0 then
446 GFXTextures[i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/' + GFXAnim[i].name, GFXAnim[i].w, GFXAnim[i].h, GFXAnim[i].anim.frames, GFXAnim[i].anim.back);
447 {$ENDIF}
448 // --------- shots --------- //
449 for i := 0 to WEAPON_LAST do
450 if ShotAnim[i].count > 0 then
451 ShotTextures[i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/' + ShotAnim[i].name, ShotAnim[i].w, ShotAnim[i].h, ShotAnim[i].count, false);
452 // --------- flags --------- //
453 FlagTextures[FLAG_NONE] := nil;
454 FlagTextures[FLAG_RED] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGRED', 64, 64, 5, false);
455 FlagTextures[FLAG_BLUE] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGBLUE', 64, 64, 5, false);
456 // FlagTextures[FLAG_DOM] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGDOM', 64, 64, 8, false);
457 // --------- shells --------- //
458 {$IFDEF ENABLE_SHELLS}
459 for i := 0 to SHELL_LAST do
460 ShellTextures[i] := r_Textures_LoadFromFile(GameWad + ':TEXTURES/' + ShellAnim[i].name);
461 {$ENDIF}
462 // --------- punch --------- //
463 for b := false to true do
464 begin
465 for i := 0 to 2 do
466 PunchTextures[b, i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':WEAPONS/' + PunchName[b] + WeapPos[i], 64, 64, 4, false);
467 end;
468 // --------- other --------- //
469 InvulPenta := r_Textures_LoadFromFile(GameWad + ':TEXTURES/PENTA');
470 end;
471
472 procedure r_Map_Free;
473 var i, j, k: Integer; d: TDirection; b: Boolean;
474 begin
475 if InvulPenta <> nil then
476 InvulPenta.Free;
477 InvulPenta := nil;
478 for b := false to true do
479 begin
480 for i := 0 to 2 do
481 begin
482 if PunchTextures[b, i] <> nil then
483 PunchTextures[b, i].Free;
484 PunchTextures[b, i] := nil;
485 end;
486 end;
487 {$IFDEF ENABLE_SHELLS}
488 for i := 0 to SHELL_LAST do
489 begin
490 if ShellTextures[i] <> nil then
491 ShellTextures[i].Free;
492 ShellTextures[i] := nil;
493 end;
494 {$ENDIF}
495 for i := 0 to FLAG_LAST do
496 begin
497 if FlagTextures[i] <> nil then
498 FlagTextures[i].Free;
499 FlagTextures[i] := nil;
500 end;
501 for i := 0 to WEAPON_LAST do
502 begin
503 if ShotTextures[i] <> nil then
504 ShotTextures[i].Free;
505 ShotTextures[i] := nil;
506 end;
507 {$IFDEF ENABLE_GFX}
508 gfxlist := nil;
509 for i := 0 to R_GFX_LAST do
510 begin
511 if GFXTextures[i] <> nil then
512 GFXTextures[i].Free;
513 GFXTextures[i] := nil;
514 end;
515 {$ENDIF}
516 for i := 1 to WP_LAST do
517 begin
518 for j := 0 to W_POS_LAST do
519 begin
520 for k := 0 to W_ACT_LAST do
521 begin
522 if WeapTextures[i, j, k] <> nil then
523 WeapTextures[i, j, k].Free;
524 WeapTextures[i, j, k] := nil;
525 end;
526 end;
527 end;
528 if Models <> nil then
529 for i := 0 to High(Models) do
530 r_Map_FreeModel(i);
531 for i := MONSTER_DEMON to MONSTER_MAN do
532 begin
533 for j := 0 to ANIM_LAST do
534 begin
535 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
536 begin
537 if MonTextures[i, j, d] <> nil then
538 MonTextures[i, j, d].Free;
539 MonTextures[i, j, d] := nil;
540 end;
541 end;
542 end;
543 for i := 0 to ITEM_LAST do
544 begin
545 if Items[i].tex <> nil then
546 Items[i].tex.Free;
547 Items[i].tex := nil;
548 end;
549 end;
550
551 procedure r_Map_LoadTextures;
552 var i, n: Integer;
553 begin
554 if Textures <> nil then
555 begin
556 n := Length(Textures);
557 SetLength(RenTextures, n);
558 for i := 0 to n - 1 do
559 begin
560 RenTextures[i].tex := nil;
561 case Textures[i].TextureName of
562 TEXTURE_NAME_WATER: RenTextures[i].spec := TEXTURE_SPECIAL_WATER;
563 TEXTURE_NAME_ACID1: RenTextures[i].spec := TEXTURE_SPECIAL_ACID1;
564 TEXTURE_NAME_ACID2: RenTextures[i].spec := TEXTURE_SPECIAL_ACID2;
565 else
566 RenTextures[i].spec := 0;
567 RenTextures[i].tex := r_Textures_LoadMultiFromFile(Textures[i].FullName);
568 if RenTextures[i].tex = nil then
569 e_LogWritefln('r_Map_LoadTextures: failed to load texture: %s', [Textures[i].FullName]);
570 end;
571 end;
572 end;
573 if gMapInfo.SkyFullName <> '' then
574 SkyTexture := r_Textures_LoadFromFile(gMapInfo.SkyFullName);
575 plist.Clear;
576 end;
577
578 procedure r_Map_FreeTextures;
579 var i: Integer;
580 begin
581 plist.Clear;
582 if SkyTexture <> nil then
583 SkyTexture.Free;
584 SkyTexture := nil;
585 if RenTextures <> nil then
586 for i := 0 to High(RenTextures) do
587 if RenTextures[i].tex <> nil then
588 RenTextures[i].tex.Free;
589 RenTextures := nil;
590 end;
591
592 procedure r_Map_DrawPanel (p: TPanel);
593 var Texture: Integer; t: TGLMultiTexture;
594 begin
595 ASSERT(p <> nil);
596 if p.FCurTexture >= 0 then
597 begin
598 Texture := p.TextureIDs[p.FCurTexture].Texture;
599 t := RenTextures[Texture].tex;
600
601 if (RenTextures[Texture].spec = 0) or (t <> nil) then
602 begin
603 if t = nil then
604 r_Draw_TextureRepeat(nil, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
605 else if p.TextureIDs[p.FCurTexture].AnTex.IsValid() then
606 r_Draw_MultiTextureRepeat(t, p.TextureIDs[p.FCurTexture].AnTex, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
607 else
608 r_Draw_TextureRepeat(t.GetTexture(0), p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
609 end;
610
611 if t = nil then
612 begin
613 case RenTextures[Texture].spec of
614 TEXTURE_SPECIAL_WATER: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 0, 255, 255);
615 TEXTURE_SPECIAL_ACID1: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 230, 0, 255);
616 TEXTURE_SPECIAL_ACID2: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 230, 0, 0, 255);
617 end
618 end
619 end
620 end;
621
622 procedure r_Map_DrawPanelType (panelTyp: DWORD);
623 var tagMask, i: Integer; p: TPanel;
624 begin
625 i := 0;
626 tagMask := PanelTypeToTag(panelTyp);
627 while plist.count > 0 do
628 begin
629 p := TPanel(plist.Front());
630 if (p.tag and tagMask) = 0 then
631 break;
632 r_Map_DrawPanel(p);
633 Inc(i);
634 plist.PopFront
635 end;
636 end;
637
638 procedure r_Map_DrawItems (x, y, w, h: Integer; drop: Boolean);
639 var i, fX, fY: Integer; it: PItem; t: TGLMultiTexture; tex: TGLTexture;
640 begin
641 if ggItems <> nil then
642 begin
643 for i := 0 to High(ggItems) do
644 begin
645 it := @ggItems[i];
646 if it.used and it.alive and (it.dropped = drop) and (it.ItemType > ITEM_NONE) and (it.ItemType <= ITEM_LAST) then
647 begin
648 t := Items[it.ItemType].tex;
649 if g_Collide(it.obj.x, it.obj.y, t.width, t.height, x, y, w, h) then
650 begin
651 it.obj.Lerp(gLerpFactor, fX, fY);
652 tex := t.GetTexture(Items[it.ItemType].frame);
653 r_Draw_TextureRepeat(tex, fX, fY, tex.width, tex.height, false, 255, 255, 255, 255, false);
654 end;
655 end;
656 end;
657 end;
658 // TODO draw g_debug_frames
659 end;
660
661 function r_Map_GetMonsterTexture (m, a: Integer; d: TDirection; out t: TGLMultiTexture; out dx, dy: Integer; out flip: Boolean): Boolean;
662 // var c: Integer;
663 begin
664 t := nil; dx := 0; dy := 0; flip := false;
665 result := MonTextures[m, a, d] <> nil;
666 if result = false then
667 begin
668 flip := true;
669 if d = TDirection.D_RIGHT then d := TDirection.D_LEFT else d := TDirection.D_RIGHT;
670 result := MonTextures[m, a, d] <> nil;
671 end;
672 if result = true then
673 begin
674 t := MonTextures[m, a, d];
675 if d = TDirection.D_LEFT then
676 begin
677 dx := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].X;
678 dy := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].Y;
679 end
680 else
681 begin
682 dx := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].X;
683 dy := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].Y;
684 end;
685 if flip then
686 begin
687 // c := (MONSTERTABLE[MonsterType].Rect.X - dx) + MONSTERTABLE[MonsterType].Rect.Width;
688 // dx := MTABLE[m].width - c - MONSTERTABLE[MonsterType].Rect.X;
689 dx := -dx;
690 end;
691 end;
692 end;
693
694 procedure r_Map_DrawMonsterAttack (constref mon: TMonster);
695 var o: TObj;
696 begin
697 if VileFire <> nil then
698 if (mon.MonsterType = MONSTER_VILE) and (mon.MonsterState = MONSTATE_SHOOT) then
699 if mon.VileFireAnim.IsValid() and GetPos(mon.MonsterTargetUID, @o) then
700 r_Draw_MultiTextureRepeat(VileFire, mon.VileFireAnim, o.x + o.rect.x + (o.rect.width div 2) - VILEFIRE_DX, o.y + o.rect.y + o.rect.height - VILEFIRE_DY, VileFire.width, VileFire.height, False, 255, 255, 255, 255, false);
701 end;
702
703 procedure r_Map_DrawMonster (constref mon: TMonster);
704 var m, a, fX, fY, dx, dy: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture;
705 begin
706 m := mon.MonsterType;
707 a := mon.MonsterAnim;
708 d := mon.GameDirection;
709
710 mon.obj.Lerp(gLerpFactor, fX, fY);
711
712 if r_Map_GetMonsterTexture(m, a, d, t, dx, dy, flip) then
713 r_Draw_MultiTextureRepeat(t, mon.DirAnim[a, d], fX + dx, fY + dy, t.width, t.height, flip, 255, 255, 255, 255, false);
714
715 // TODO draw g_debug_frames
716 end;
717
718 procedure r_Map_DrawMonsters (x, y, w, h: Integer);
719 var i: Integer; m: TMonster;
720 begin
721 if gMonsters <> nil then
722 begin
723 for i := 0 to High(gMonsters) do
724 begin
725 m := gMonsters[i];
726 if m <> nil then
727 begin
728 r_Map_DrawMonsterAttack(m);
729 // TODO select from grid
730 if g_Collide(m.obj.x + m.obj.rect.x, m.obj.y + m.obj.rect.y, m.obj.rect.width, m.obj.rect.height, x, y, w, h) then
731 r_Map_DrawMonster(m);
732 end;
733 end;
734 end;
735 end;
736
737 function r_Map_GetPlayerModelTex (i: Integer; var a: Integer; var d: TDirection; out flip: Boolean): Boolean;
738 begin
739 flip := false;
740 result := Models[i].anim[d, a].base <> nil;
741 if result = false then
742 begin
743 flip := true;
744 if d = TDirection.D_LEFT then d := TDirection.D_RIGHT else d := TDirection.D_LEFT;
745 result := Models[i].anim[d, a].base <> nil;
746 end;
747 end;
748
749 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer; alpha: Byte);
750 var a, pos, act, xx, yy, angle: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture; tex: TGLTexture; c: TRGB;
751 begin
752 a := pm.CurrentAnimation;
753 d := pm.Direction;
754
755 (* draw flag*)
756 t := FlagTextures[pm.Flag];
757 if (t <> nil) and not (a in [A_DIE1, A_DIE2]) then
758 begin
759 flip := d = TDirection.D_RIGHT;
760 angle := PlayerModelsArray[pm.id].FlagAngle;
761 xx := PlayerModelsArray[pm.id].FlagPoint.X;
762 yy := PlayerModelsArray[pm.id].FlagPoint.Y;
763 tex := t.GetTexture(FlagFrame);
764 r_Draw_TextureRepeatRotate(
765 tex,
766 x + IfThen(flip, 2 * FLAG_BASEPOINT.X - xx + 1, xx - 1) - FLAG_BASEPOINT.X,
767 y + yy - FLAG_BASEPOINT.Y + 1,
768 tex.width,
769 tex.height,
770 flip,
771 255, 255, 255, 255, false,
772 IfThen(flip, 64 - FLAG_BASEPOINT.X, FLAG_BASEPOINT.X),
773 FLAG_BASEPOINT.Y,
774 IfThen(flip, angle, -angle)
775 );
776 end;
777
778 (* draw weapon *)
779 if PlayerModelsArray[pm.id].HaveWeapon and not (a in [A_DIE1, A_DIE2, A_PAIN]) then
780 begin
781 case a of
782 A_SEEUP, A_ATTACKUP: pos := W_POS_UP;
783 A_SEEDOWN, A_ATTACKDOWN: pos := W_POS_DOWN;
784 else pos := W_POS_NORMAL;
785 end;
786 if (a in [A_ATTACK, A_ATTACKUP, A_ATTACKDOWN]) or pm.GetFire() then
787 act := W_ACT_FIRE
788 else
789 act := W_ACT_NORMAL;
790 tex := WeapTextures[pm.CurrentWeapon, pos, act];
791 if tex <> nil then
792 begin
793 xx := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].X;
794 yy := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].Y;
795 r_Draw_Texture(
796 tex,
797 x + xx,
798 y + yy,
799 tex.width,
800 tex.height,
801 d = TDirection.D_LEFT,
802 255, 255, 255, alpha, false
803 );
804 end;
805 end;
806
807 (* draw body *)
808 if r_Map_GetPlayerModelTex(pm.id, a, d, flip) then
809 begin
810 t := Models[pm.id].anim[d, a].base;
811 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip, 255, 255, 255, alpha, false);
812 t := Models[pm.id].anim[d, a].mask;
813 if t <> nil then
814 begin
815 c := pm.Color;
816 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip, c.r, c.g, c.b, alpha, false);
817 end;
818 end;
819 end;
820
821 procedure r_Map_DrawPlayer (p, drawed: TPlayer);
822 var fX, fY, fSlope, ax, ay, w, h: Integer; b, flip: Boolean; t: TGLMultiTexture; alpha: Byte;
823 begin
824 if p.alive then
825 begin
826 fX := p.obj.x; fY := p.obj.y;
827 // TODO fix lerp
828 //p.obj.Lerp(gLerpFactor, fX, fY);
829 fSlope := nlerp(p.SlopeOld, p.obj.slopeUpLeft, gLerpFactor);
830
831 (* punch effect *)
832 if p.PunchAnim.IsValid() and p.PunchAnim.enabled then
833 begin
834 b := R_BERSERK in p.FRulez;
835 if p.FKeys[KEY_DOWN].pressed then
836 t := PunchTextures[b, 2]
837 else if p.FKeys[KEY_UP].pressed then
838 t := PunchTextures[b, 1]
839 else
840 t := PunchTextures[b, 0];
841 if t <> nil then
842 begin
843 flip := p.Direction = TDirection.D_LEFT;
844 ax := IfThen(flip, 15 - p.Obj.Rect.X, p.Obj.Rect.X - 15); // ???
845 ay := p.Obj.Rect.Y - 11;
846 r_Draw_MultiTextureRepeat(t, p.PunchAnim, fx + ax, fy + fSlope + ay, t.width, t.height, flip, 255, 255, 255, 255, false)
847 end;
848 end;
849
850 (* invulnerability effect *)
851 if (InvulPenta <> nil) and (p.FMegaRulez[MR_INVUL] > gTime) and ((p <> drawed) or (p.SpawnInvul >= gTime)) then
852 begin
853 w := InvulPenta.width;
854 h := InvulPenta.height;
855 ax := p.Obj.Rect.X + (p.Obj.Rect.Width div 2) - (w div 2); // + IfThen(flip, +4, -2) // ???
856 ay := p.Obj.Rect.Y + (p.Obj.Rect.Height div 2) - (h div 2) - 7; // ???
857 r_Draw_Texture(InvulPenta, fx + ax, fy + ay + fSlope, w, h, false, 255, 255, 255, 255, false);
858 end;
859
860 (* invisibility effect *)
861 alpha := 255;
862 if p.FMegaRulez[MR_INVIS] > gTime then
863 begin
864 if (drawed <> nil) and ((p = drawed) or ((p.Team = drawed.Team) and (gGameSettings.GameMode <> GM_DM))) then
865 begin
866 if (p.FMegaRulez[MR_INVIS] - gTime > 2100) or not ODD((p.FMegaRulez[MR_INVIS] - gTime) div 300) then
867 alpha := 55;
868 end
869 else
870 alpha := 1; // ???
871 end;
872
873 r_Map_DrawPlayerModel(p.Model, fX, fY + fSlope, alpha);
874 end;
875 // TODO draw g_debug_frames
876 // TODO draw chat bubble
877 // TODO draw aim
878 end;
879
880 procedure r_Map_DrawPlayers (x, y, w, h: Integer; player: TPlayer);
881 var i: Integer;
882 begin
883 if gPlayers <> nil then
884 for i := 0 to High(gPlayers) do
885 if gPlayers[i] <> nil then
886 r_Map_DrawPlayer(gPlayers[i], player);
887 end;
888
889 {$IFDEF ENABLE_GIBS}
890 function r_Map_GetGibSize (m, i: Integer): TRectWH;
891 begin
892 result := Models[m].gibs.rect[i];
893 end;
894
895 procedure r_Map_DrawGibs (x, y, w, h: Integer);
896 var i, fx, fy, m, id, rx, ry, ra: Integer; p: PObj; t: TGLTexture;
897 begin
898 if gGibs <> nil then
899 begin
900 for i := 0 to High(gGibs) do
901 begin
902 if gGibs[i].alive then
903 begin
904 p := @gGibs[i].Obj;
905 if g_Obj_Collide(x, y, w, h, p) then
906 begin
907 p.Lerp(gLerpFactor, fx, fy);
908 id := gGibs[i].GibID;
909 m := gGibs[i].ModelID;
910 t := Models[m].gibs.base[id];
911 if t <> nil then
912 begin
913 rx := p.Rect.X + p.Rect.Width div 2;
914 ry := p.Rect.Y + p.Rect.Height div 2;
915 ra := gGibs[i].RAngle;
916 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, 255, 255, 255, 255, false, rx, ry, ra);
917 t := Models[m].gibs.mask[id];
918 if t <> nil then
919 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, gGibs[i].Color.R, gGibs[i].Color.G, gGibs[i].Color.B, 255, false, rx, ry, ra);
920 // r_Draw_TextureRepeatRotate(nil, fx + p.Rect.X, fy + p.Rect.Y, p.Rect.Width, p.Rect.Height, false, 255, 255, 255, 255, false, p.Rect.Width div 2, p.Rect.Height div 2, ra);
921 end;
922 end;
923 end;
924 end;
925 end;
926 // TODO draw g_debug_frames
927 end;
928 {$ENDIF}
929
930 {$IFDEF ENABLE_CORPSES}
931 procedure r_Map_DrawCorpses (x, y, w, h: Integer);
932 var i, fX, fY: Integer; p: TCorpse;
933 begin
934 if gCorpses <> nil then
935 begin
936 for i := 0 to High(gCorpses) do
937 begin
938 p := gCorpses[i];
939 if (p <> nil) and (p.state <> CORPSE_STATE_REMOVEME) and (p.model <> nil) then
940 begin
941 p.obj.Lerp(gLerpFactor, fX, fY);
942 r_Map_DrawPlayerModel(p.model, fX, fY, 255);
943 end;
944 end;
945 end;
946 // TODO draw g_debug_frames
947 end;
948 {$ENDIF}
949
950 {$IFDEF ENABLE_GFX}
951 function r_Map_GetGFXID (): Integer;
952 var i: Integer;
953 begin
954 i := 0;
955 if gfxlist <> nil then
956 begin
957 while (i < Length(gfxlist)) and (gfxlist[i].typ > 0) do
958 Inc(i);
959 if i >= Length(gfxlist) then
960 SetLength(gfxlist, Length(gfxlist) + 1)
961 end
962 else
963 SetLength(gfxlist, 1);
964 gfxlist[i].typ := R_GFX_NONE;
965 result := i
966 end;
967
968 procedure r_Map_NewGFX (typ, x, y: Integer);
969 var i: Integer;
970 begin
971 if gpart_dbg_enabled and (typ > 0) and (typ <= R_GFX_LAST) then
972 begin
973 i := r_Map_GetGFXID();
974 if i >= 0 then
975 begin
976 gfxlist[i].typ := typ;
977 gfxlist[i].x := x;
978 gfxlist[i].y := y;
979 gfxlist[i].oldX := x;
980 gfxlist[i].oldY := y;
981 gfxlist[i].anim := GFXAnim[typ].anim;
982 gfxlist[i].time := gTime DIV GAME_TICK;
983 gfxlist[i].frame := 0;
984 INC(gfxlist[i].anim.delay, Random(GFXAnim[typ].rdelay));
985 end;
986 end;
987 end;
988
989 procedure r_Map_UpdateGFX (tick: LongWord);
990 var i: Integer; count: LongInt;
991 begin
992 if gfxlist <> nil then
993 begin
994 for i := 0 to High(gfxlist) do
995 begin
996 if (gfxlist[i].typ > 0) and (tick >= gfxlist[i].time) then
997 begin
998 g_Anim_GetFrameByTime(gfxlist[i].anim, tick - gfxlist[i].time, count, gfxlist[i].frame);
999 if count < 1 then
1000 begin
1001 gfxlist[i].oldX := gfxlist[i].x;
1002 gfxlist[i].oldY := gfxlist[i].y;
1003 case gfxlist[i].typ of
1004 R_GFX_FLAME, R_GFX_SMOKE:
1005 begin
1006 if Random(3) = 0 then
1007 gfxlist[i].x := gfxlist[i].x - 1 + Random(3);
1008 if Random(2) = 0 then
1009 gfxlist[i].y := gfxlist[i].y - Random(2);
1010 end;
1011 end;
1012 end
1013 else
1014 gfxlist[i].typ := R_GFX_NONE;
1015 end;
1016 end;
1017 end;
1018 end;
1019
1020 procedure r_Map_DrawGFX (x, y, w, h: Integer);
1021 var i, fx, fy, typ: Integer; t: TGLMultiTexture; tex: TGLTexture;
1022 begin
1023 if gfxlist <> nil then
1024 begin
1025 for i := 0 to High(gfxlist) do
1026 begin
1027 if gfxlist[i].typ > 0 then
1028 begin
1029 typ := gfxlist[i].typ;
1030 t := GFXTextures[typ];
1031 if t <> nil then
1032 begin
1033 fx := nlerp(gfxlist[i].oldX, gfxlist[i].x, gLerpFactor);
1034 fy := nlerp(gfxlist[i].oldY, gfxlist[i].y, gLerpFactor);
1035 tex := t.GetTexture(gfxlist[i].frame);
1036 r_Draw_TextureRepeat(tex, fx, fy, tex.width, tex.height, false, 255, 255, 255, 255 - GFXAnim[typ].alpha, false);
1037 end;
1038 end;
1039 end;
1040 end;
1041 end;
1042
1043 procedure r_Map_DrawParticles (x, y, w, h: Integer);
1044 var i, fx, fy: Integer;
1045 begin
1046 if gpart_dbg_enabled and (Particles <> nil) then
1047 begin
1048 glDisable(GL_TEXTURE_2D);
1049 if (g_dbg_scale < 0.6) then
1050 glPointSize(1)
1051 else if (g_dbg_scale > 1.3) then
1052 glPointSize(g_dbg_scale + 1)
1053 else
1054 glPointSize(2);
1055 glDisable(GL_POINT_SMOOTH);
1056 glEnable(GL_BLEND);
1057 glBlendFunc(GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA);
1058
1059 glBegin(GL_POINTS);
1060 for i := 0 to High(Particles) do
1061 begin
1062 if Particles[i].alive then
1063 begin
1064 fx := nlerp(Particles[i].oldX, Particles[i].x, gLerpFactor);
1065 fy := nlerp(Particles[i].oldY, Particles[i].y, gLerpFactor);
1066 glColor4ub(Particles[i].red, Particles[i].green, Particles[i].blue, Particles[i].alpha);
1067 glVertex2f(fx, fy);
1068 end;
1069 end;
1070 glEnd;
1071
1072 glDisable(GL_BLEND);
1073 end;
1074 end;
1075 {$ENDIF}
1076
1077 procedure r_Map_DrawShots (x, y, w, h: Integer);
1078 var i, a, fX, fY, pX, pY, typ: Integer; tex: TGLMultiTexture; anim: ^TAnimState;
1079 begin
1080 if Shots <> nil then
1081 begin
1082 for i := 0 to High(Shots) do
1083 begin
1084 typ := Shots[i].ShotType;
1085 if typ <> 0 then
1086 begin
1087 tex := ShotTextures[typ];
1088 if tex <> nil then
1089 begin
1090 a := 0;
1091 case typ of
1092 WEAPON_ROCKETLAUNCHER, WEAPON_BARON_FIRE, WEAPON_MANCUB_FIRE, WEAPON_SKEL_FIRE:
1093 a := -GetAngle2(Shots[i].Obj.Vel.X, Shots[i].Obj.Vel.Y)
1094 end;
1095 Shots[i].Obj.Lerp(gLerpFactor, fX, fY);
1096 pX := Shots[i].Obj.Rect.Width div 2;
1097 pY := Shots[i].Obj.Rect.Height div 2;
1098 // TODO fix this hack
1099 if Shots[i].Animation.IsValid() then anim := @Shots[i].Animation else anim := @StubShotAnim;
1100 r_Draw_MultiTextureRepeatRotate(tex, anim^, fX, fY, tex.width, tex.height, false, 255, 255, 255, 255, false, pX, pY, a);
1101 end;
1102 end;
1103 end;
1104 end;
1105 // TODO draw g_debug_frames
1106 end;
1107
1108 procedure r_Map_DrawFlags (x, y, w, h: Integer);
1109 var i, dx, fx, fy: Integer; flip: Boolean; t: TGLMultiTexture; tex: TGLTexture;
1110 begin
1111 if gGameSettings.GameMode = GM_CTF then
1112 begin
1113 for i := FLAG_RED to FLAG_BLUE do
1114 begin
1115 if not (gFlags[i].state in [FLAG_STATE_NONE, FLAG_STATE_CAPTURED]) then
1116 begin
1117 gFlags[i].Obj.Lerp(gLerpFactor, fx, fy);
1118 flip := gFlags[i].Direction = TDirection.D_LEFT;
1119 if flip then dx := -1 else dx := +1;
1120 t := FlagTextures[i];
1121 tex := t.GetTexture(FlagFrame);
1122 r_Draw_TextureRepeat(tex, fx + dx, fy + 1, tex.width, tex.height, flip, 255, 255, 255, 255, false)
1123 end;
1124 end;
1125 end;
1126 // TODO g_debug_frames
1127 end;
1128
1129 {$IFDEF ENABLE_SHELLS}
1130 procedure r_Map_DrawShells (x, y, w, h: Integer);
1131 var i, fx, fy, typ: Integer; t: TGLTexture; p: PObj;
1132 begin
1133 if gShells <> nil then
1134 begin
1135 for i := 0 to High(gShells) do
1136 begin
1137 if gShells[i].alive then
1138 begin
1139 typ := gShells[i].SType;
1140 if typ <= SHELL_LAST then
1141 begin
1142 p := @gShells[i].Obj;
1143 if g_Obj_Collide(x, y, w, h, p) then
1144 begin
1145 t := ShellTextures[typ];
1146 if t <> nil then
1147 begin
1148 p.Lerp(gLerpFactor, fx, fy);
1149 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, 255, 255, 255, 255, false, ShellAnim[typ].dx, ShellAnim[typ].dy, gShells[i].RAngle);
1150 end;
1151 end;
1152 end;
1153 end;
1154 end;
1155 end;
1156 end;
1157 {$ENDIF}
1158
1159 procedure r_Map_CalcAspect (ow, oh, nw, nh: LongInt; horizontal: Boolean; out ww, hh: LongInt);
1160 begin
1161 if horizontal then
1162 begin
1163 ww := nw;
1164 hh := nw * oh div ow;
1165 end
1166 else
1167 begin
1168 ww := nh * ow div oh;
1169 hh := nh;
1170 end;
1171 end;
1172
1173 procedure r_Map_CalcSkyParallax (cx, cy, vw, vh, sw, sh, mw, mh: LongInt; out x, y, w, h: LongInt);
1174 const
1175 factor = 120; (* size ratio between view and sky (120%) *)
1176 limit = 100; (* max speed for parallax *)
1177 var
1178 msw, msh, mvw, mvh, svw, svh: LongInt;
1179 begin
1180 msw := vw * factor div 100;
1181 msh := vh * factor div 100;
1182 r_Map_CalcAspect(sw, sh, msw, msh, (sw / sh) <= (msw / msh), w, h);
1183
1184 (* calc x parallax or sky center on speed limit *)
1185 mvw := MAX(1, mw - vw);
1186 svw := w - vw;
1187 if 100 * svw div mvw <= limit then
1188 x := -cx * svw div mvw
1189 else
1190 x := -svw div 2;
1191
1192 (* calc y parallax or sky center on speed limit *)
1193 mvh := MAX(1, mh - vh);
1194 svh := h - vh;
1195 if 100 * svh div mvh <= limit then
1196 y := -cy * svh div mvh
1197 else
1198 y := -svh div 2;
1199
1200 (* handle out of map bounds *)
1201 if x > 0 then x := 0;
1202 if y > 0 then y := 0;
1203 if x < -svw then x := -svw;
1204 if y < -svh then y := -svh;
1205 end;
1206
1207 procedure r_Map_DrawScreenEffect (x, y, w, h, level: Integer; r, g, b: Byte);
1208 var i: Integer;
1209 begin
1210 if level > 0 then
1211 begin
1212 case level of
1213 0..14: i := 0;
1214 15..34: i := 1;
1215 35..54: i := 2;
1216 55..74: i := 3;
1217 75..94: i := 4;
1218 else i := 5
1219 end;
1220 r_Draw_FillRect(x, y, x + w, y + h, r, g, b, i * 50)
1221 end;
1222 end;
1223
1224 procedure r_Map_DrawScreenEffects (x, y, w, h: Integer; p: TPlayer);
1225 begin
1226 if p <> nil then
1227 begin
1228 r_Map_DrawScreenEffect(x, y, w, h, p.pain, 255, 0, 0);
1229 r_Map_DrawScreenEffect(x, y, w, h, p.pickup, 150, 200, 150);
1230 if (p.FMegaRulez[MR_INVUL] >= gTime) and (p.SpawnInvul < gTime) then
1231 begin
1232 if ((p.FMegaRulez[MR_INVUL] - gTime) > 2100) or not ODD((p.FMegaRulez[MR_INVUL] - gTime) div 300) then
1233 r_Draw_InvertRect(x, y, x + w, y + h, 191, 191, 191, 255);
1234 end;
1235 if p.FMegaRulez[MR_SUIT] >= gTime then
1236 begin
1237 if ((p.FMegaRulez[MR_SUIT] - gTime) > 2100) or not ODD((p.FMegaRulez[MR_SUIT] - gTime) div 300) then
1238 r_Draw_FillRect(x, y, x + w, y + h, 0, 96, 0, 55);
1239 end;
1240 if (p.Berserk >= 0) and (p.Berserk >= gTime) and (gFlash = 2) then
1241 begin
1242 r_Draw_FillRect(x, y, x + w, y + h, 255, 0, 0, 55);
1243 end;
1244 end;
1245 end;
1246
1247 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer; player: TPlayer);
1248 var iter: TPanelGrid.Iter; p: PPanel; cx, cy, xx, yy, ww, hh: Integer; sx, sy, sw, sh: LongInt;
1249 begin
1250 cx := camx - w div 2;
1251 cy := camy - h div 2;
1252 xx := x + cx;
1253 yy := y + cy;
1254 ww := w;
1255 hh := h;
1256
1257 if g_dbg_ignore_bounds = false then
1258 begin
1259 if xx + ww > gMapInfo.Width then
1260 xx := gMapInfo.Width - ww;
1261 if yy + hh > gMapInfo.Height then
1262 yy := gMapInfo.Height - hh;
1263 if xx < 0 then
1264 xx := 0;
1265 if yy < 0 then
1266 yy := 0;
1267 cx := xx - x;
1268 cy := yy - y;
1269 end;
1270
1271 if SkyTexture <> nil then
1272 begin
1273 r_Map_CalcSkyParallax(cx, cy, ww, hh, SkyTexture.width, SkyTexture.height, gMapInfo.Width, gMapInfo.Height, sx, sy, sw, sh);
1274 r_Draw_Texture(SkyTexture, x + sx, y + sy, sw, sh, false, 255, 255, 255, 255, false);
1275 end;
1276
1277 plist.Clear;
1278 iter := mapGrid.ForEachInAABB(xx, yy, ww, hh, GridDrawableMask);
1279 for p in iter do
1280 if ((p^.tag and GridTagDoor) <> 0) = p^.door then
1281 plist.Insert(p^);
1282 iter.Release;
1283
1284 glPushMatrix;
1285 glTranslatef(-cx, -cy, 0);
1286 r_Map_DrawPanelType(PANEL_BACK);
1287 r_Map_DrawPanelType(PANEL_STEP);
1288 r_Map_DrawItems(xx, yy, ww, hh, false);
1289 r_Map_DrawShots(xx, yy, ww, hh);
1290 {$IFDEF ENABLE_SHELLS}
1291 r_Map_DrawShells(xx, yy, ww, hh);
1292 {$ENDIF}
1293 r_Map_DrawPlayers(xx, yy, ww, hh, player);
1294 {$IFDEF ENABLE_GIBS}
1295 r_Map_DrawGibs(xx, yy, ww, hh);
1296 {$ENDIF}
1297 {$IFDEF ENABLE_CORPSES}
1298 r_Map_DrawCorpses(xx, yy, ww, hh);
1299 {$ENDIF}
1300 r_Map_DrawPanelType(PANEL_WALL);
1301 r_Map_DrawMonsters(xx, yy, ww, hh);
1302 r_Map_DrawItems(xx, yy, ww, hh, true);
1303 r_Map_DrawPanelType(PANEL_CLOSEDOOR);
1304 {$IFDEF ENABLE_GFX}
1305 r_Map_DrawParticles(xx, yy, ww, hh);
1306 r_Map_DrawGFX(xx, yy, ww, hh);
1307 {$ENDIF}
1308 r_Map_DrawFlags(xx, yy, ww, hh);
1309 r_Map_DrawPanelType(PANEL_ACID1);
1310 r_Map_DrawPanelType(PANEL_ACID2);
1311 r_Map_DrawPanelType(PANEL_WATER);
1312 r_Map_DrawPanelType(PANEL_FORE);
1313 // TODO draw monsters health bar
1314 // TODO draw players health bar
1315 // TODO draw players indicators
1316 glPopMatrix;
1317
1318 r_Map_DrawScreenEffects(x, y, w, h, player);
1319
1320 // TODO draw minimap (gShowMap)
1321 // TODO draw g_debug_player
1322 end;
1323
1324 procedure r_Map_Update;
1325 var i, count, tick: LongInt;
1326 begin
1327 tick := gTime div GAME_TICK;
1328 for i := 0 to ITEM_LAST do
1329 g_Anim_GetFrameByTime(ItemAnim[i].anim, tick, count, Items[i].frame);
1330 r_Map_UpdateGFX(tick);
1331 g_Anim_GetFrameByTime(FlagAnim, tick, count, FlagFrame);
1332 end;
1333
1334 end.
[MIRROR] a port of Doom 2D Forever to FPC/SDL
[25/02/2024 19:55:35]
DEADSOFTWARE 2012-2024