src/game/sdl2/g_system.pas

   1 (* Copyright (C)  Doom 2D: Forever Developers
   2  *
   3  * This program is free software: you can redistribute it and/or modify
   4  * it under the terms of the GNU General Public License as published by
   5  * the Free Software Foundation, version 3 of the License ONLY.
   6  *
   7  * This program is distributed in the hope that it will be useful,
   8  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   9  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  10  * GNU General Public License for more details.
  11  *
  12  * You should have received a copy of the GNU General Public License
  13  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  14  *)
  15 {$INCLUDE ../shared/a_modes.inc}
  16 unit g_system;
  17
  18 interface
  19
  20   uses Utils;
  21
  22   (* --- Utils --- *)
  23   function sys_GetTicks (): Int64;
  24   procedure sys_Delay (ms: Integer);
  25
  26   (* --- Graphics --- *)
  27   function sys_GetDispalyModes (bpp: Integer): SSArray;
  28   function sys_SetDisplayMode (w, h, bpp: Integer; fullscreen: Boolean): Boolean;
  29   procedure sys_EnableVSync (yes: Boolean);
  30   procedure sys_Repaint;
  31
  32   (* --- Input --- *)
  33   function sys_HandleInput (): Boolean;
  34   procedure sys_RequestQuit;
  35
  36   (* --- Init --- *)
  37   procedure sys_Init;
  38   procedure sys_Final;
  39
  40 implementation
  41
  42   uses
  43     SysUtils, SDL2, GL, Math,
  44     e_log, e_graphics, e_input,
  45     g_touch,
  46     g_options, g_window, g_console, g_game, g_menu, g_gui, g_main;
  47
  48   const
  49     GameTitle = 'Doom 2D: Forever (SDL 2)';
  50
  51   var
  52     window: PSDL_Window;
  53     context: TSDL_GLContext;
  54     display: Integer;
  55     JoystickHandle: array [0..e_MaxJoys - 1] of PSDL_Joystick;
  56     JoystickHatState: array [0..e_MaxJoys - 1, 0..e_MaxJoyHats - 1, HAT_LEFT..HAT_DOWN] of Boolean;
  57     JoystickZeroAxes: array [0..e_MaxJoys - 1, 0..e_MaxJoyAxes - 1] of Integer;
  58
  59   (* --------- Utils --------- *)
  60
  61   function sys_GetTicks (): Int64;
  62   begin
  63     result := SDL_GetTicks()
  64   end;
  65
  66   procedure sys_Delay (ms: Integer);
  67   begin
  68     SDL_Delay(ms)
  69   end;
  70
  71   (* --------- Graphics --------- *)
  72
  73   procedure UpdateSize (w, h: Integer);
  74   begin
  75     gWinSizeX := w;
  76     gWinSizeY := h;
  77     gWinRealPosX := 0;
  78     gWinRealPosY := 0;
  79     gScreenWidth := w;
  80     gScreenHeight := h;
  81     {$IFDEF ENABLE_HOLMES}
  82       fuiScrWdt := w;
  83       fuiScrHgt := h;
  84     {$ENDIF}
  85     e_ResizeWindow(w, h);
  86     e_InitGL;
  87     g_Game_SetupScreenSize;
  88     g_Menu_Reset;
  89     g_Game_ClearLoading;
  90   end;
  91
  92   function InitWindow (w, h, bpp: Integer; fullScreen: Boolean): Boolean;
  93     var flags: UInt32;
  94   begin
  95     e_LogWritefln('InitWindow %s %s %s %s', [w, h, bpp, fullScreen]);
  96     result := false;
  97     if window = nil then
  98     begin
  99       {$IFDEF USE_GLES1}
 100         SDL_GL_SetAttribute(SDL_GL_CONTEXT_MAJOR_VERSION, 1);
 101         SDL_GL_SetAttribute(SDL_GL_CONTEXT_MINOR_VERSION, 1);
 102         SDL_GL_SetAttribute(SDL_GL_CONTEXT_PROFILE_MASK, SDL_GL_CONTEXT_PROFILE_ES);
 103       {$ELSE}
 104         SDL_GL_SetAttribute(SDL_GL_CONTEXT_MAJOR_VERSION, 2);
 105         SDL_GL_SetAttribute(SDL_GL_CONTEXT_MINOR_VERSION, 1);
 106         SDL_GL_SetAttribute(SDL_GL_RED_SIZE, 8);
 107         SDL_GL_SetAttribute(SDL_GL_GREEN_SIZE, 8);
 108         SDL_GL_SetAttribute(SDL_GL_BLUE_SIZE, 8);
 109         SDL_GL_SetAttribute(SDL_GL_DEPTH_SIZE, 16);
 110         SDL_GL_SetAttribute(SDL_GL_DOUBLEBUFFER, 1);
 111         SDL_GL_SetAttribute(SDL_GL_STENCIL_SIZE, 8); // lights; it is enough to have 1-bit stencil buffer for lighting, but...
 112       {$ENDIF}
 113       flags := SDL_WINDOW_OPENGL or SDL_WINDOW_RESIZABLE;
 114       if fullScreen then flags := flags or SDL_WINDOW_FULLSCREEN;
 115       window := SDL_CreateWindow(GameTitle, SDL_WINDOWPOS_CENTERED, SDL_WINDOWPOS_CENTERED, w, h, flags);
 116       if window <> nil then
 117       begin
 118         context := SDL_GL_CreateContext(window);
 119         if context <> nil then
 120         begin
 121           UpdateSize(w, h);
 122           result := true
 123         end
 124         else
 125         begin
 126           e_LogWritefln('SDL: unable to create OpenGL context: %s', [SDL_GetError])
 127         end
 128       end
 129       else
 130       begin
 131         e_LogWritefln('SDL: unable to create window: %s', [SDL_GetError])
 132       end
 133     end
 134     else
 135     begin
 136       if fullScreen then flags := SDL_WINDOW_FULLSCREEN else flags := 0;
 137       SDL_SetWindowSize(window, w, h);
 138       SDL_SetWindowFullscreen(window, flags);
 139       UpdateSize(w, h);
 140       result := true
 141     end
 142   end;
 143
 144   procedure sys_Repaint;
 145   begin
 146     SDL_GL_SwapWindow(window)
 147   end;
 148
 149   procedure sys_EnableVSync (yes: Boolean);
 150   begin
 151     if yes then
 152       SDL_GL_SetSwapInterval(1)
 153     else
 154       SDL_GL_SetSwapInterval(0)
 155   end;
 156
 157   function sys_GetDispalyModes (bpp: Integer): SSArray;
 158     var i, count, num, pw, ph: Integer; m: TSDL_DisplayMode;
 159   begin
 160     result := nil;
 161     num := SDL_GetNumDisplayModes(display);
 162     if num < 0 then
 163       e_LogWritefln('SDL: unable to get numer of available display modes: %s', [SDL_GetError]);
 164     if num > 0 then
 165     begin
 166       e_LogWritefln('Video modes for display %s:', [display]);
 167       SetLength(result, num);
 168       i := 0; count := 0; pw := 0; ph := 0;
 169       while i < num do
 170       begin
 171         SDL_GetDisplayMode(display, i, @m);
 172         if ((pw <> m.w) or (ph <> m.h)) then
 173         begin
 174           e_LogWritefln('* %sx%sx%s@%s', [m.w, m.h, SDL_BITSPERPIXEL(m.format), m.refresh_rate]);
 175           pw := m.w; ph := m.h;
 176           result[count] := IntToStr(m.w) + 'x' + IntToStr(m.h);
 177           Inc(count);
 178         end
 179         else
 180         begin
 181           e_LogWritefln('- %sx%sx%s@%s', [m.w, m.h, SDL_BITSPERPIXEL(m.format), m.refresh_rate]);
 182         end;
 183         Inc(i)
 184       end;
 185       SetLength(result, count)
 186     end
 187   end;
 188
 189   function sys_SetDisplayMode (w, h, bpp: Integer; fullScreen: Boolean): Boolean;
 190   begin
 191     result := InitWindow(w, h, bpp, fullScreen)
 192   end;
 193
 194   (* --------- Joystick --------- *)
 195
 196   procedure HandleJoyButton (var ev: TSDL_JoyButtonEvent);
 197     var down: Boolean; key: Integer;
 198   begin
 199     if (ev.which < e_MaxJoys) and (ev.button < e_MaxJoyBtns) then
 200     begin
 201       key := e_JoyButtonToKey(ev.which, ev.button);
 202       down := ev.type_ = SDL_JOYBUTTONDOWN;
 203       if g_dbg_input then
 204         e_LogWritefln('Input Debug: jbutton, joy=%s, button=%s, keycode=%s, press=%s', [ev.which, ev.button, key, down]);
 205       e_KeyUpDown(key, down);
 206       g_Console_ProcessBind(key, down)
 207     end
 208     else
 209     begin
 210       if g_dbg_input then
 211       begin
 212         down := ev.type_ = SDL_JOYBUTTONDOWN;
 213         e_LogWritefln('Input Debug: NOT IN RANGE! jbutton, joy=%s, button=%s, press=%s', [ev.which, ev.button, down])
 214       end
 215     end
 216   end;
 217
 218   procedure HandleJoyAxis (var ev: TSDL_JoyAxisEvent);
 219     var key, minuskey: Integer;
 220   begin
 221     if (ev.which < e_MaxJoys) and (ev.axis < e_MaxJoyAxes) then
 222     begin
 223       key := e_JoyAxisToKey(ev.which, ev.axis, AX_PLUS);
 224       minuskey := e_JoyAxisToKey(ev.which, ev.axis, AX_MINUS);
 225
 226       if g_dbg_input then
 227           e_LogWritefln('Input Debug: jaxis, joy=%s, axis=%s, value=%s, zeroaxes=%s, deadzone=%s', [ev.which, ev.axis, ev.value, JoystickZeroAxes[ev.which, ev.axis], e_JoystickDeadzones[ev.which]]);
 228
 229       if ev.value < JoystickZeroAxes[ev.which, ev.axis] - e_JoystickDeadzones[ev.which] then
 230       begin
 231         if (e_KeyPressed(key)) then
 232         begin
 233           e_KeyUpDown(key, False);
 234           g_Console_ProcessBind(key, False)
 235         end;
 236         e_KeyUpDown(minuskey, True);
 237         g_Console_ProcessBind(minuskey, True)
 238       end
 239       else if ev.value > JoystickZeroAxes[ev.which, ev.axis] + e_JoystickDeadzones[ev.which] then
 240       begin
 241         if (e_KeyPressed(minuskey)) then
 242         begin
 243           e_KeyUpDown(minuskey, False);
 244           g_Console_ProcessBind(minuskey, False)
 245         end;
 246         e_KeyUpDown(key, True);
 247         g_Console_ProcessBind(key, True)
 248       end
 249       else
 250       begin
 251         if (e_KeyPressed(minuskey)) then
 252         begin
 253           e_KeyUpDown(minuskey, False);
 254           g_Console_ProcessBind(minuskey, False)
 255         end;
 256         if (e_KeyPressed(key)) then
 257         begin
 258           e_KeyUpDown(key, False);
 259           g_Console_ProcessBind(key, False)
 260         end
 261       end
 262     end
 263     else
 264     begin
 265       if g_dbg_input then
 266         e_LogWritefln('Input Debug: NOT IN RANGE! jaxis, joy=%s, axis=%s, value=%s, zeroaxes=%s, deadzone=%s', [ev.which, ev.axis, ev.value, JoystickZeroAxes[ev.which, ev.axis], e_JoystickDeadzones[ev.which]])
 267     end
 268   end;
 269
 270   procedure HandleJoyHat (var ev: TSDL_JoyHatEvent);
 271     var
 272       down: Boolean;
 273       i, key: Integer;
 274       hat: array [HAT_LEFT..HAT_DOWN] of Boolean;
 275   begin
 276     if (ev.which < e_MaxJoys) and (ev.hat < e_MaxJoyHats) then
 277     begin
 278       if g_dbg_input then
 279         e_LogWritefln('Input Debug: jhat, joy=%s, hat=%s, value=%s', [ev.which, ev.hat, ev.value]);
 280       hat[HAT_UP] := LongBool(ev.value and SDL_HAT_UP);
 281       hat[HAT_DOWN] := LongBool(ev.value and SDL_HAT_DOWN);
 282       hat[HAT_LEFT] := LongBool(ev.value and SDL_HAT_LEFT);
 283       hat[HAT_RIGHT] := LongBool(ev.value and SDL_HAT_RIGHT);
 284       for i := HAT_LEFT to HAT_DOWN do
 285       begin
 286         if JoystickHatState[ev.which, ev.hat, i] <> hat[i] then
 287         begin
 288           down := hat[i];
 289           key := e_JoyHatToKey(ev.which, ev.hat, i);
 290           e_KeyUpDown(key, down);
 291           g_Console_ProcessBind(key, down)
 292         end
 293       end;
 294       JoystickHatState[ev.which, ev.hat] := hat
 295     end
 296     else
 297     begin
 298       if g_dbg_input then
 299         e_LogWritefln('Input Debug: NOT IN RANGE! jhat, joy=%s, hat=%s, value=%s', [ev.which, ev.hat, ev.value])
 300     end
 301   end;
 302
 303   procedure HandleJoyAdd (var ev: TSDL_JoyDeviceEvent);
 304     var i: Integer;
 305   begin
 306     if (ev.which < e_MaxJoys) then
 307     begin
 308       JoystickHandle[ev.which] := SDL_JoystickOpen(ev.which);
 309       if JoystickHandle[ev.which] <> nil then
 310       begin
 311         e_LogWritefln('Added Joystick %s', [ev.which]);
 312         e_JoystickAvailable[ev.which] := True;
 313         for i := 0 to Min(SDL_JoystickNumAxes(JoystickHandle[ev.which]), e_MaxJoyAxes) - 1 do
 314           JoystickZeroAxes[ev.which, i] := SDL_JoystickGetAxis(JoystickHandle[ev.which], i)
 315       end
 316       else
 317       begin
 318         e_LogWritefln('Warning! Failed to open Joystick %s', [ev.which])
 319       end
 320     end
 321     else
 322     begin
 323       e_LogWritefln('Warning! Added Joystick %s, but we support only <= %s', [ev.which, e_MaxJoys])
 324     end
 325   end;
 326
 327   procedure HandleJoyRemove (var ev: TSDL_JoyDeviceEvent);
 328   begin
 329     e_LogWritefln('Removed Joystick %s', [ev.which]);
 330     if (ev.which < e_MaxJoys) then
 331     begin
 332       e_JoystickAvailable[ev.which] := False;
 333       if JoystickHandle[ev.which] <> nil then
 334         SDL_JoystickClose(JoystickHandle[ev.which]);
 335       JoystickHandle[ev.which] := nil
 336     end
 337   end;
 338
 339   (* --------- Input --------- *)
 340
 341   function HandleWindow (var ev: TSDL_WindowEvent): Boolean;
 342   begin
 343     result := false;
 344     case ev.event of
 345       SDL_WINDOWEVENT_RESIZED: UpdateSize(ev.data1, ev.data2);
 346       SDL_WINDOWEVENT_EXPOSED: sys_Repaint;
 347       SDL_WINDOWEVENT_CLOSE: result := true;
 348     end
 349   end;
 350
 351   procedure HandleKeyboard (var ev: TSDL_KeyboardEvent);
 352     var down: Boolean; key: Integer;
 353   begin
 354     key := ev.keysym.scancode;
 355     down := (ev.type_ = SDL_KEYDOWN);
 356     if key = SDL_SCANCODE_AC_BACK then
 357       key := SDL_SCANCODE_ESCAPE;
 358     if ev._repeat = 0 then
 359     begin
 360       if g_dbg_input then
 361         e_LogWritefln('Input Debug: keysym, press=%s, scancode=%s', [down, key]);
 362       e_KeyUpDown(key, down);
 363       g_Console_ProcessBind(key, down);
 364     end
 365     else if gConsoleShow or gChatShow or (g_ActiveWindow <> nil) then
 366     begin
 367       KeyPress(key) // key repeat in menus and shit
 368     end
 369   end;
 370
 371   procedure HandleTextInput (var ev: TSDL_TextInputEvent);
 372     var ch: UnicodeChar; sch: AnsiChar;
 373   begin
 374     if g_dbg_input then
 375       e_LogWritefln('Input Debug: text, text=%s', [ev.text]);
 376     Utf8ToUnicode(@ch, PChar(ev.text), 1);
 377     if IsValid1251(Word(ch)) then
 378     begin
 379       sch := AnsiChar(wchar2win(ch));
 380       CharPress(sch);
 381     end;
 382   end;
 383
 384   function sys_HandleInput (): Boolean;
 385     var ev: TSDL_Event;
 386   begin
 387     result := false;
 388     while SDL_PollEvent(@ev) <> 0 do
 389     begin
 390       case ev.type_ of
 391         SDL_QUITEV: result := true;
 392         SDL_WINDOWEVENT: result := HandleWindow(ev.window);
 393         SDL_KEYUP, SDL_KEYDOWN: HandleKeyboard(ev.key);
 394         SDL_JOYBUTTONDOWN, SDL_JOYBUTTONUP: HandleJoyButton(ev.jbutton);
 395         SDL_JOYAXISMOTION: HandleJoyAxis(ev.jaxis);
 396         SDL_JOYHATMOTION: HandleJoyHat(ev.jhat);
 397         SDL_JOYDEVICEADDED: HandleJoyAdd(ev.jdevice);
 398         SDL_JOYDEVICEREMOVED: HandleJoyRemove(ev.jdevice);
 399         SDL_TEXTINPUT: HandleTextInput(ev.text);
 400         SDL_FINGERMOTION, SDL_FINGERDOWN, SDL_FINGERUP: g_Touch_HandleEvent(ev.tfinger);
 401       end
 402     end
 403   end;
 404
 405   procedure sys_RequestQuit;
 406     var ev: TSDL_Event;
 407   begin
 408     ev.type_ := SDL_QUITEV;
 409     SDL_PushEvent(@ev)
 410   end;
 411
 412   (* --------- Init --------- *)
 413
 414   procedure sys_Init;
 415     var flags: UInt32; ok: Boolean;
 416   begin
 417     e_WriteLog('Init SDL2', TMsgType.Notify);
 418     {$IFDEF HEADLESS}
 419       {$IFDEF USE_SDLMIXER}
 420         flags := SDL_INIT_TIMER or SDL_INIT_AUDIO or $00004000;
 421       {$ELSE}
 422         flags := SDL_INIT_TIMER or $00004000;
 423       {$ENDIF}
 424     {$ELSE}
 425       flags := SDL_INIT_JOYSTICK or SDL_INIT_TIMER or SDL_INIT_VIDEO;
 426     {$ENDIF}
 427     SDL_SetHint(SDL_HINT_ACCELEROMETER_AS_JOYSTICK, '0');
 428     if SDL_Init(flags) <> 0 then
 429       raise Exception.Create('SDL: Init failed: ' + SDL_GetError);
 430     ok := InitWindow(gScreenWidth, gScreenHeight, gBPP, gFullscreen);
 431     if not ok then
 432       raise Exception.Create('SDL: Failed to set videomode: ' + SDL_GetError);
 433   end;
 434
 435   procedure sys_Final;
 436   begin
 437     e_WriteLog('Releasing SDL2', TMsgType.Notify);
 438     if context <> nil then
 439       SDL_GL_DeleteContext(context);
 440     if window <> nil then
 441       SDL_DestroyWindow(window);
 442     window := nil;
 443     context := nil;
 444     SDL_Quit
 445   end;
 446
 447 initialization
 448   conRegVar('sdl2_display_index', @display, 'use display index as base', '');
 449 end.