src/game/sdl/g_system.pas

   1 (* Copyright (C)  Doom 2D: Forever Developers
   2  *
   3  * This program is free software: you can redistribute it and/or modify
   4  * it under the terms of the GNU General Public License as published by
   5  * the Free Software Foundation, version 3 of the License ONLY.
   6  *
   7  * This program is distributed in the hope that it will be useful,
   8  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   9  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  10  * GNU General Public License for more details.
  11  *
  12  * You should have received a copy of the GNU General Public License
  13  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  14  *)
  15 {$INCLUDE ../shared/a_modes.inc}
  16 unit g_system;
  17
  18 interface
  19
  20   uses Utils;
  21
  22   (* --- Utils --- *)
  23   function sys_GetTicks (): Int64;
  24   procedure sys_Delay (ms: Integer);
  25
  26   (* --- Graphics --- *)
  27   function sys_GetDisplayModes (bpp: Integer): SSArray;
  28   function sys_SetDisplayMode (w, h, bpp: Integer; fullscreen, maximized: Boolean): Boolean;
  29   procedure sys_EnableVSync (yes: Boolean);
  30   procedure sys_Repaint;
  31
  32   (* --- Input --- *)
  33   function sys_HandleInput (): Boolean;
  34   procedure sys_RequestQuit;
  35
  36   (* --- Init --- *)
  37   procedure sys_Init;
  38   procedure sys_Final;
  39
  40 implementation
  41
  42   uses
  43     SysUtils, SDL, Math,
  44     {$INCLUDE ../nogl/noGLuses.inc}
  45     e_log, e_graphics, e_input, e_sound,
  46     g_options, g_window, g_console, g_game, g_menu, g_gui, g_main, g_basic;
  47
  48   const
  49     GameTitle = 'Doom 2D: Forever (SDL 1.2, %s)';
  50
  51   var
  52     userResize: Boolean;
  53     modeResize: Integer;
  54     screen: PSDL_Surface;
  55     JoystickHandle: array [0..e_MaxJoys - 1] of PSDL_Joystick;
  56     JoystickHatState: array [0..e_MaxJoys - 1, 0..e_MaxJoyHats - 1, HAT_LEFT..HAT_DOWN] of Boolean;
  57     JoystickZeroAxes: array [0..e_MaxJoys - 1, 0..e_MaxJoyAxes - 1] of Integer;
  58
  59   (* --------- Utils --------- *)
  60
  61   function sys_GetTicks (): Int64;
  62   begin
  63     result := SDL_GetTicks()
  64   end;
  65
  66   procedure sys_Delay (ms: Integer);
  67   begin
  68     SDL_Delay(ms)
  69   end;
  70
  71   (* --------- Graphics --------- *)
  72
  73   function LoadGL: Boolean;
  74   begin
  75     result := true;
  76     {$IFDEF NOGL_INIT}
  77     nogl_Init;
  78     if glRenderToFBO and (not nogl_ExtensionSupported('GL_OES_framebuffer_object')) then
  79     {$ELSE}
  80     if glRenderToFBO and (not Load_GL_ARB_framebuffer_object) then
  81     {$ENDIF}
  82     begin
  83       e_LogWriteln('GL: framebuffer objects not supported; disabling FBO rendering');
  84       glRenderToFBO := false;
  85     end;
  86   end;
  87
  88   procedure FreeGL;
  89   begin
  90     {$IFDEF NOGL_INIT}
  91     nogl_Quit();
  92     {$ENDIF}
  93   end;
  94
  95   procedure UpdateSize (w, h: Integer);
  96   begin
  97     gWinSizeX := w;
  98     gWinSizeY := h;
  99     gRC_Width := w;
 100     gRC_Height := h;
 101     if glRenderToFBO then
 102     begin
 103       // store real window size in gWinSize, downscale resolution now
 104       w := round(w / r_pixel_scale);
 105       h := round(h / r_pixel_scale);
 106       if not e_ResizeFramebuffer(w, h) then
 107       begin
 108         e_LogWriteln('GL: could not create framebuffer, falling back to --no-fbo');
 109         glRenderToFBO := False;
 110         w := gWinSizeX;
 111         h := gWinSizeY;
 112       end;
 113     end;
 114     gScreenWidth := w;
 115     gScreenHeight := h;
 116     {$IFDEF ENABLE_HOLMES}
 117       fuiScrWdt := w;
 118       fuiScrHgt := h;
 119     {$ENDIF}
 120     e_ResizeWindow(w, h);
 121     e_InitGL;
 122     g_Game_SetupScreenSize;
 123     g_Menu_Reset;
 124     g_Game_ClearLoading;
 125   end;
 126
 127   function GetTitle (): PChar;
 128     var info: AnsiString;
 129   begin
 130     info := g_GetBuildHash(false);
 131     if info = 'custom build' then
 132       info := info + ' by ' + g_GetBuilderName() + ' ' + GAME_BUILDDATE + ' ' + GAME_BUILDTIME;
 133     result := PChar(Format(GameTitle, [info]))
 134   end;
 135
 136   function InitWindow (w, h, bpp: Integer; fullScreen: Boolean): Boolean;
 137     var flags: Uint32;
 138   begin
 139     e_LogWritefln('InitWindow %s %s %s %s', [w, h, bpp, fullScreen]);
 140     result := false;
 141     SDL_GL_SetAttribute(SDL_GL_RED_SIZE, 8);
 142     SDL_GL_SetAttribute(SDL_GL_GREEN_SIZE, 8);
 143     SDL_GL_SetAttribute(SDL_GL_BLUE_SIZE, 8);
 144     SDL_GL_SetAttribute(SDL_GL_DEPTH_SIZE, 16);
 145     SDL_GL_SetAttribute(SDL_GL_DOUBLEBUFFER, 1);
 146     SDL_GL_SetAttribute(SDL_GL_STENCIL_SIZE, 8); // lights; it is enough to have 1-bit stencil buffer for lighting, but...
 147     flags := SDL_OPENGL;
 148     if fullScreen then flags := flags or SDL_FULLSCREEN;
 149     if userResize then flags := flags or SDL_VIDEORESIZE;
 150     if (screen = nil) or (SDL_VideoModeOk(w, h, bpp, flags) <> 0) then
 151     begin
 152       SDL_FreeSurface(screen);
 153       screen := SDL_SetVideoMode(w, h, bpp, flags);
 154       if screen <> nil then
 155       begin
 156         if not LoadGL then
 157         begin
 158           e_LogWriteln('GL: unable to load OpenGL functions', TMsgType.Fatal);
 159           exit;
 160         end;
 161         SDL_WM_SetCaption(GetTitle(), nil);
 162         gFullScreen := fullscreen;
 163         gRC_FullScreen := fullscreen;
 164         UpdateSize(w, h);
 165         result := True
 166       end
 167     end
 168     else
 169     begin
 170       e_LogWritefln('SDL: video mode not supported', [])
 171     end
 172   end;
 173
 174   procedure sys_Repaint;
 175   begin
 176     SDL_GL_SwapBuffers
 177   end;
 178
 179   procedure sys_EnableVSync (yes: Boolean);
 180   begin
 181     (* ??? *)
 182   end;
 183
 184   function sys_GetDisplayModes (bpp: Integer): SSArray;
 185     var m: PPSDL_Rect; f: TSDL_PixelFormat; i, count: Integer;
 186   begin
 187     SetLength(result, 0);
 188     FillChar(f, sizeof(f), 0);
 189     f.palette := nil;
 190     f.BitsPerPixel := bpp;
 191     f.BytesPerPixel := (bpp + 7) div 8;
 192     m := SDL_ListModes(@f, SDL_OPENGL or SDL_FULLSCREEN);
 193     if (m <> NIL) and (UIntPtr(m) <> UIntPtr(-1)) then
 194     begin
 195       count := 0;
 196       while m[count] <> nil do inc(count);
 197       SetLength(result, count);
 198       for i := 0 to count - 1 do
 199         result[i] := IntToStr(m[i].w) + 'x' + IntToStr(m[i].h);
 200     end
 201   end;
 202
 203   function sys_SetDisplayMode (w, h, bpp: Integer; fullscreen, maximized: Boolean): Boolean;
 204   begin
 205     result := InitWindow(w, h, bpp, fullscreen)
 206   end;
 207
 208   (* --------- Joystick --------- *)
 209
 210   procedure HandleJoyButton (var ev: TSDL_JoyButtonEvent);
 211     var down: Boolean; key: Integer;
 212   begin
 213     if (ev.which < e_MaxJoys) and (ev.button < e_MaxJoyBtns) then
 214     begin
 215       key := e_JoyButtonToKey(ev.which, ev.button);
 216       down := ev.type_ = SDL_JOYBUTTONDOWN;
 217       if g_dbg_input then
 218         e_LogWritefln('Input Debug: jbutton, joy=%s, button=%s, keycode=%s, press=%s', [ev.which, ev.button, key, down]);
 219       e_KeyUpDown(key, down);
 220       g_Console_ProcessBind(key, down)
 221     end
 222     else
 223     begin
 224       if g_dbg_input then
 225       begin
 226         down := ev.type_ = SDL_JOYBUTTONDOWN;
 227         e_LogWritefln('Input Debug: NOT IN RANGE! jbutton, joy=%s, button=%s, press=%s', [ev.which, ev.button, down])
 228       end
 229     end
 230   end;
 231
 232   procedure HandleJoyAxis (var ev: TSDL_JoyAxisEvent);
 233     var key, minuskey: Integer;
 234   begin
 235     if (ev.which < e_MaxJoys) and (ev.axis < e_MaxJoyAxes) then
 236     begin
 237       key := e_JoyAxisToKey(ev.which, ev.axis, AX_PLUS);
 238       minuskey := e_JoyAxisToKey(ev.which, ev.axis, AX_MINUS);
 239
 240       if g_dbg_input then
 241           e_LogWritefln('Input Debug: jaxis, joy=%s, axis=%s, value=%s, zeroaxes=%s, deadzone=%s', [ev.which, ev.axis, ev.value, JoystickZeroAxes[ev.which, ev.axis], e_JoystickDeadzones[ev.which]]);
 242
 243       if ev.value < JoystickZeroAxes[ev.which, ev.axis] - e_JoystickDeadzones[ev.which] then
 244       begin
 245         if (e_KeyPressed(key)) then
 246         begin
 247           e_KeyUpDown(key, False);
 248           g_Console_ProcessBind(key, False)
 249         end;
 250         e_KeyUpDown(minuskey, True);
 251         g_Console_ProcessBind(minuskey, True)
 252       end
 253       else if ev.value > JoystickZeroAxes[ev.which, ev.axis] + e_JoystickDeadzones[ev.which] then
 254       begin
 255         if (e_KeyPressed(minuskey)) then
 256         begin
 257           e_KeyUpDown(minuskey, False);
 258           g_Console_ProcessBind(minuskey, False)
 259         end;
 260         e_KeyUpDown(key, True);
 261         g_Console_ProcessBind(key, True)
 262       end
 263       else
 264       begin
 265         if (e_KeyPressed(minuskey)) then
 266         begin
 267           e_KeyUpDown(minuskey, False);
 268           g_Console_ProcessBind(minuskey, False)
 269         end;
 270         if (e_KeyPressed(key)) then
 271         begin
 272           e_KeyUpDown(key, False);
 273           g_Console_ProcessBind(key, False)
 274         end
 275       end
 276     end
 277     else
 278     begin
 279       if g_dbg_input then
 280         e_LogWritefln('Input Debug: NOT IN RANGE! jaxis, joy=%s, axis=%s, value=%s, zeroaxes=%s, deadzone=%s', [ev.which, ev.axis, ev.value, JoystickZeroAxes[ev.which, ev.axis], e_JoystickDeadzones[ev.which]])
 281     end
 282   end;
 283
 284   procedure HandleJoyHat (var ev: TSDL_JoyHatEvent);
 285     var
 286       down: Boolean;
 287       i, key: Integer;
 288       hat: array [HAT_LEFT..HAT_DOWN] of Boolean;
 289   begin
 290     if (ev.which < e_MaxJoys) and (ev.hat < e_MaxJoyHats) then
 291     begin
 292       if g_dbg_input then
 293         e_LogWritefln('Input Debug: jhat, joy=%s, hat=%s, value=%s', [ev.which, ev.hat, ev.value]);
 294       hat[HAT_UP] := LongBool(ev.value and SDL_HAT_UP);
 295       hat[HAT_DOWN] := LongBool(ev.value and SDL_HAT_DOWN);
 296       hat[HAT_LEFT] := LongBool(ev.value and SDL_HAT_LEFT);
 297       hat[HAT_RIGHT] := LongBool(ev.value and SDL_HAT_RIGHT);
 298       for i := HAT_LEFT to HAT_DOWN do
 299       begin
 300         if JoystickHatState[ev.which, ev.hat, i] <> hat[i] then
 301         begin
 302           down := hat[i];
 303           key := e_JoyHatToKey(ev.which, ev.hat, i);
 304           e_KeyUpDown(key, down);
 305           g_Console_ProcessBind(key, down)
 306         end
 307       end;
 308       JoystickHatState[ev.which, ev.hat] := hat
 309     end
 310     else
 311     begin
 312       if g_dbg_input then
 313         e_LogWritefln('Input Debug: NOT IN RANGE! jhat, joy=%s, hat=%s, value=%s', [ev.which, ev.hat, ev.value])
 314     end
 315   end;
 316
 317   procedure AddJoystick (which: Integer);
 318     var i: Integer;
 319   begin
 320     assert(which < e_MaxJoys);
 321     JoystickHandle[which] := SDL_JoystickOpen(which);
 322     if JoystickHandle[which] <> nil then
 323     begin
 324       e_LogWritefln('Added Joystick %s', [which]);
 325       e_JoystickAvailable[which] := True;
 326       for i := 0 to Min(SDL_JoystickNumAxes(JoystickHandle[which]), e_MaxJoyAxes) - 1 do
 327         JoystickZeroAxes[which, i] := SDL_JoystickGetAxis(JoystickHandle[which], i)
 328     end
 329     else
 330     begin
 331       e_LogWritefln('Failed to open Joystick %s', [which])
 332     end
 333   end;
 334
 335   procedure RemoveJoystick (which: Integer);
 336   begin
 337     assert(which < e_MaxJoys);
 338     e_LogWritefln('Remove Joystick %s', [which]);
 339     e_JoystickAvailable[which] := False;
 340     if JoystickHandle[which] <> nil then
 341       SDL_JoystickClose(JoystickHandle[which]);
 342     JoystickHandle[which] := nil
 343   end;
 344
 345   (* --------- Input --------- *)
 346
 347   function Key2Stub (key: Integer): Integer;
 348     var x: Integer;
 349   begin
 350     case key of
 351       SDLK_ESCAPE: x := IK_ESCAPE;
 352       SDLK_RETURN: x := IK_RETURN;
 353       SDLK_KP_ENTER: x := IK_KPRETURN;
 354       SDLK_KP0: x := IK_KPINSERT;
 355       SDLK_UP: x := IK_UP;
 356       SDLK_KP8: x := IK_KPUP;
 357       SDLK_DOWN: x := IK_DOWN;
 358       SDLK_KP2: x := IK_KPDOWN;
 359       SDLK_LEFT: x := IK_LEFT;
 360       SDLK_KP4: x := IK_KPLEFT;
 361       SDLK_RIGHT: x := IK_RIGHT;
 362       SDLK_KP6: x := IK_KPRIGHT;
 363       SDLK_DELETE: x := IK_DELETE;
 364       SDLK_HOME: x := IK_HOME;
 365       SDLK_KP7: x := IK_KPHOME;
 366       SDLK_INSERT: x := IK_INSERT;
 367       SDLK_SPACE: x := IK_SPACE;
 368       SDLK_LSHIFT: x := IK_SHIFT;
 369       SDLK_LALT: x := IK_ALT;
 370       SDLK_TAB: x := IK_TAB;
 371       SDLK_PAGEUP: x := IK_PAGEUP;
 372       SDLK_KP9: x := IK_KPPAGEUP;
 373       SDLK_PAGEDOWN: x := IK_PAGEDN;
 374       SDLK_KP3: x := IK_KPPAGEDN;
 375       SDLK_KP5: x := IK_KP5;
 376       SDLK_NUMLOCK: x := IK_NUMLOCK;
 377       SDLK_KP_DIVIDE: x := IK_KPDIVIDE;
 378       SDLK_KP_MULTIPLY: x := IK_KPMULTIPLE;
 379       SDLK_KP_MINUS: x := IK_KPMINUS;
 380       SDLK_KP_PLUS: x := IK_KPPLUS;
 381       SDLK_KP_PERIOD: x := IK_KPDOT;
 382       SDLK_CAPSLOCK: x := IK_CAPSLOCK;
 383       SDLK_RSHIFT: x := IK_RSHIFT;
 384       SDLK_LCTRL: x := IK_CTRL;
 385       SDLK_RCTRL: x := IK_RCTRL;
 386       SDLK_RALT: x := IK_RALT;
 387       SDLK_LSUPER: x := IK_WIN;
 388       SDLK_RSUPER: x := IK_RWIN;
 389       SDLK_MENU: x := IK_MENU;
 390       SDLK_PRINT: x := IK_PRINTSCR;
 391       SDLK_SCROLLOCK: x := IK_SCROLLLOCK;
 392       SDLK_LEFTBRACKET: x := IK_LBRACKET;
 393       SDLK_RIGHTBRACKET: x := IK_RBRACKET;
 394       SDLK_SEMICOLON: x := IK_SEMICOLON;
 395       SDLK_QUOTE: x := IK_QUOTE;
 396       SDLK_BACKSLASH: x := IK_BACKSLASH;
 397       SDLK_SLASH: x := IK_SLASH;
 398       SDLK_COMMA: x := IK_COMMA;
 399       SDLK_PERIOD: x := IK_DOT;
 400       SDLK_EQUALS: x := IK_EQUALS;
 401       SDLK_0: x := IK_0;
 402       SDLK_1: x := IK_1;
 403       SDLK_2: x := IK_2;
 404       SDLK_3: x := IK_3;
 405       SDLK_4: x := IK_4;
 406       SDLK_5: x := IK_5;
 407       SDLK_6: x := IK_6;
 408       SDLK_7: x := IK_7;
 409       SDLK_8: x := IK_8;
 410       SDLK_9: x := IK_9;
 411       SDLK_F1: x := IK_F1;
 412       SDLK_F2: x := IK_F2;
 413       SDLK_F3: x := IK_F3;
 414       SDLK_F4: x := IK_F4;
 415       SDLK_F5: x := IK_F5;
 416       SDLK_F6: x := IK_F6;
 417       SDLK_F7: x := IK_F7;
 418       SDLK_F8: x := IK_F8;
 419       SDLK_F9: x := IK_F9;
 420       SDLK_F10: x := IK_F10;
 421       SDLK_F11: x := IK_F11;
 422       SDLK_F12: x := IK_F12;
 423       SDLK_END: x := IK_END;
 424       SDLK_KP1: x := IK_KPEND;
 425       SDLK_BACKSPACE: x := IK_BACKSPACE;
 426       SDLK_BACKQUOTE: x := IK_BACKQUOTE;
 427       SDLK_PAUSE: x := IK_PAUSE;
 428       SDLK_A..SDLK_Z: x := IK_A + (key - SDLK_A);
 429       SDLK_MINUS: x := IK_MINUS;
 430       SDLK_RMETA: x := IK_RMETA;
 431       SDLK_LMETA: x := IK_LMETA;
 432     else
 433       x := IK_INVALID
 434     end;
 435     result := x
 436   end;
 437
 438   procedure HandleKeyboard (var ev: TSDL_KeyboardEvent);
 439     var down, repeated: Boolean; key: Integer; ch: Char;
 440   begin
 441     key := Key2Stub(ev.keysym.sym);
 442     down := (ev.type_ = SDL_KEYDOWN);
 443     repeated := down and e_KeyPressed(key);
 444     ch := wchar2win(WideChar(ev.keysym.unicode));
 445     if g_dbg_input then
 446       e_LogWritefln('Input Debug: keysym, down=%s, sym=%s, state=%s, unicode=%s, stubsym=%s, cp1251=%s', [down, ev.keysym.sym, ev.state, ev.keysym.unicode, key, Ord(ch)]);
 447     if not repeated then
 448     begin
 449       e_KeyUpDown(key, down);
 450       g_Console_ProcessBind(key, down);
 451     end
 452     else
 453     begin
 454       g_Console_ProcessBindRepeat(key)
 455     end;
 456     if down and IsValid1251(ev.keysym.unicode) and IsPrintable1251(ch) then
 457       CharPress(ch)
 458   end;
 459
 460   procedure HandleResize (var ev: TSDL_ResizeEvent);
 461   begin
 462     if g_dbg_input then
 463       e_LogWritefln('Input Debug: SDL_VIDEORESIZE %s %s', [ev.w, ev.h]);
 464     if modeResize = 1 then
 465       UpdateSize(ev.w, ev.h)
 466     else if modeResize > 1 then
 467       InitWindow(ev.w, ev.h, gBPP, gFullscreen)
 468   end;
 469
 470   function sys_HandleInput (): Boolean;
 471     var ev: TSDL_Event;
 472   begin
 473     result := false;
 474     while SDL_PollEvent(@ev) <> 0 do
 475     begin
 476       case ev.type_ of
 477         SDL_QUITEV: result := true;
 478         SDL_VIDEORESIZE: HandleResize(ev.resize);
 479         SDL_KEYUP, SDL_KEYDOWN: HandleKeyboard(ev.key);
 480         SDL_JOYBUTTONDOWN, SDL_JOYBUTTONUP: HandleJoyButton(ev.jbutton);
 481         SDL_JOYAXISMOTION: HandleJoyAxis(ev.jaxis);
 482         SDL_JOYHATMOTION: HandleJoyHat(ev.jhat);
 483         SDL_VIDEOEXPOSE: sys_Repaint;
 484         SDL_ACTIVEEVENT: e_MuteChannels((ev.active.gain = 0) and gMuteWhenInactive);
 485       end
 486     end
 487   end;
 488
 489   procedure sys_RequestQuit;
 490     var ev: TSDL_Event;
 491   begin
 492     ev.quit.type_ := SDL_QUITEV;
 493     SDL_PushEvent(@ev)
 494   end;
 495
 496   (* --------- Init --------- *)
 497
 498   procedure sys_Init;
 499     var flags: Uint32; i: Integer;
 500   begin
 501     e_WriteLog('Init SDL', TMsgType.Notify);
 502     flags := SDL_INIT_VIDEO or SDL_INIT_AUDIO or
 503              SDL_INIT_TIMER or SDL_INIT_JOYSTICK
 504              (*or SDL_INIT_NOPARACHUTE*);
 505     if SDL_Init(flags) <> 0 then
 506       raise Exception.Create('SDL: Init failed: ' + SDL_GetError);
 507     SDL_EnableUNICODE(1);
 508     SDL_EnableKeyRepeat(SDL_DEFAULT_REPEAT_DELAY, SDL_DEFAULT_REPEAT_INTERVAL);
 509     for i := 0 to e_MaxJoys - 1 do
 510       AddJoystick(i)
 511   end;
 512
 513   procedure sys_Final;
 514     var i: Integer;
 515   begin
 516     e_WriteLog('Releasing SDL', TMsgType.Notify);
 517     for i := 0 to e_MaxJoys - 1 do
 518       RemoveJoystick(i);
 519     if screen <> nil then
 520     begin
 521       FreeGL;
 522       SDL_FreeSurface(screen)
 523     end;
 524     SDL_Quit
 525   end;
 526
 527 initialization
 528   (* window resize are broken both on linux and osx, so disabled by default *)
 529   conRegVar('sdl_allow_resize', @userResize, 'allow to resize window by user', 'allow to resize window by user');
 530   conRegVar('sdl_resize_action', @modeResize, 'set window resize mode (0: ignore, 1: change, 2: reset)', '');
 531   userResize := false;
 532   modeResize := 0;
 533 end.