DEADSOFTWARE

GIT / REPO / FRED-BOY
Projects / d2df-sdl.git / blob


c008f432def97874c3cce8089a30e1ce109847d5
[d2df-sdl.git] / src / game / renders / opengl / r_map.pas
1 (* Copyright (C) Doom 2D: Forever Developers
2 *
3 * This program is free software: you can redistribute it and/or modify
4 * it under the terms of the GNU General Public License as published by
5 * the Free Software Foundation, version 3 of the License ONLY.
6 *
7 * This program is distributed in the hope that it will be useful,
8 * but WITHOUT ANY WARRANTY; without even the implied warranty of
9 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
10 * GNU General Public License for more details.
11 *
12 * You should have received a copy of the GNU General Public License
13 * along with this program. If not, see <http://www.gnu.org/licenses/>.
14 *)
15 {$INCLUDE ../../../shared/a_modes.inc}
16 unit r_map;
17
18 interface
19
20 uses g_base, g_player, g_playermodel; // TRectWH, TPlayer, TPlayerModel
21
22 procedure r_Map_Initialize;
23 procedure r_Map_Finalize;
24
25 procedure r_Map_Load;
26 procedure r_Map_Free;
27
28 procedure r_Map_LoadTextures;
29 procedure r_Map_FreeTextures;
30
31 {$IFDEF ENABLE_GFX}
32 procedure r_Map_NewGFX (typ, x, y: Integer);
33 {$ENDIF}
34 {$IFDEF ENABLE_GIBS}
35 function r_Map_GetGibSize (m, i: Integer): TRectWH;
36 {$ENDIF}
37 {$IFDEF ENABLE_MENU}
38 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer; alpha: Byte);
39 {$ENDIF}
40
41 procedure r_Map_Update;
42
43 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer; player: TPlayer; out acx, acy: Integer);
44
45 implementation
46
47 uses
48 {$I ../../../nogl/noGLuses.inc}
49 Math, SysUtils,
50 e_log,
51 binheap, MAPDEF, utils,
52 g_options, g_animations, g_basic, g_phys,
53 g_game, g_map, g_panel, g_items, g_monsters, g_weapons,
54 g_console, g_language,
55 {$IFDEF ENABLE_CORPSES}
56 g_corpses,
57 {$ENDIF}
58 {$IFDEF ENABLE_SHELLS}
59 g_shells,
60 {$ENDIF}
61 {$IFDEF ENABLE_GIBS}
62 g_gibs,
63 {$ENDIF}
64 {$IFDEF ENABLE_GFX}
65 g_gfx,
66 {$ENDIF}
67 r_textures, r_draw, r_common
68 ;
69
70 const
71 MTABLE: array [0..MONSTER_MAN] of record
72 w, h: Integer;
73 end = (
74 (w: 64; h: 64), // NONE
75 (w: 64; h: 64), // DEMON
76 (w: 64; h: 64), // IMP
77 (w: 64; h: 64), // ZOMBY
78 (w: 64; h: 64), // SERG
79 (w: 128; h: 128), // CYBER
80 (w: 64; h: 64), // CGUN
81 (w: 128; h: 128), // BARON
82 (w: 128; h: 128), // KNIGHT
83 (w: 128; h: 128), // CACO
84 (w: 64; h: 64), // SOUL (DIE is 128x128, see load code)
85 (w: 128; h: 128), // PAIN
86 (w: 256; h: 128), // SPIDER
87 (w: 128; h: 64), // BSP
88 (w: 128; h: 128), // MANCUB
89 (w: 128; h: 128), // SKEL
90 (w: 128; h: 128), // VILE
91 (w: 32; h: 32), // FISH
92 (w: 64; h: 64), // BARREL
93 (w: 128; h: 128), // ROBO
94 (w: 64; h: 64) // MAN
95 );
96 VILEFIRE_DX = 32;
97 VILEFIRE_DY = 128;
98
99 ItemAnim: array [0..ITEM_LAST] of record
100 name: AnsiString;
101 w, h: Integer;
102 anim: TAnimInfo;
103 end = (
104 (name: 'NOTEXTURE'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
105 (name: 'MED1'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
106 (name: 'MED2'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
107 (name: 'BMED'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
108 (name: 'ARMORGREEN'; w: 32; h: 16; anim: (loop: true; delay: 20; frames: 3; back: true)),
109 (name: 'ARMORBLUE'; w: 32; h: 16; anim: (loop: true; delay: 20; frames: 3; back: true)),
110 (name: 'SBLUE'; w: 32; h: 32; anim: (loop: true; delay: 15; frames: 4; back: true)),
111 (name: 'SWHITE'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
112 (name: 'SUIT'; w: 32; h: 64; anim: (loop: true; delay: 1; frames: 1; back: false)),
113 (name: 'OXYGEN'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
114 (name: 'INVUL'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
115 (name: 'SAW'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
116 (name: 'SHOTGUN1'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
117 (name: 'SHOTGUN2'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
118 (name: 'MGUN'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
119 (name: 'RLAUNCHER'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
120 (name: 'PGUN'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
121 (name: 'BFG'; w: 64; h: 64; anim: (loop: true; delay: 1; frames: 1; back: false)),
122 (name: 'SPULEMET'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
123 (name: 'CLIP'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
124 (name: 'AMMO'; w: 32; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
125 (name: 'SHELL1'; w: 16; h: 8; anim: (loop: true; delay: 1; frames: 1; back: false)),
126 (name: 'SHELL2'; w: 32; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
127 (name: 'ROCKET'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
128 (name: 'ROCKETS'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
129 (name: 'CELL'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
130 (name: 'CELL2'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
131 (name: 'BPACK'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
132 (name: 'KEYR'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
133 (name: 'KEYG'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
134 (name: 'KEYB'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
135 (name: 'KASTET'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
136 (name: 'PISTOL'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
137 (name: 'BOTTLE'; w: 16; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
138 (name: 'HELMET'; w: 16; h: 16; anim: (loop: true; delay: 20; frames: 4; back: true)),
139 (name: 'JETPACK'; w: 32; h: 32; anim: (loop: true; delay: 15; frames: 3; back: true)),
140 (name: 'INVIS'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
141 (name: 'FLAMETHROWER'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
142 (name: 'FUELCAN'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false))
143 );
144
145 {$IFDEF ENABLE_GFX}
146 GFXAnim: array [0..R_GFX_LAST] of record
147 name: AnsiString;
148 w, h: Integer;
149 anim: TAnimInfo;
150 rdelay: Integer;
151 alpha: Integer;
152 end = (
153 (name: ''; w: 0; h: 0; anim: (loop: false; delay: 0; frames: 0; back: false); rdelay: 0; alpha: 0),
154 (name: 'TELEPORT'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 10; back: false); rdelay: 0; alpha: 0),
155 (name: 'FLAME'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 11; back: false); rdelay: 0; alpha: 0),
156 (name: 'EROCKET'; w: 128; h: 128; anim: (loop: false; delay: 6; frames: 6; back: false); rdelay: 0; alpha: 0),
157 (name: 'EBFG'; w: 128; h: 128; anim: (loop: false; delay: 6; frames: 6; back: false); rdelay: 0; alpha: 0),
158 (name: 'BFGHIT'; w: 64; h: 64; anim: (loop: false; delay: 4; frames: 4; back: false); rdelay: 0; alpha: 0),
159 (name: 'FIRE'; w: 64; h: 128; anim: (loop: false; delay: 4; frames: 8; back: false); rdelay: 2; alpha: 0),
160 (name: 'ITEMRESPAWN'; w: 32; h: 32; anim: (loop: false; delay: 4; frames: 5; back: true); rdelay: 0; alpha: 0),
161 (name: 'SMOKE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 0),
162 (name: 'ESKELFIRE'; w: 64; h: 64; anim: (loop: false; delay: 8; frames: 3; back: false); rdelay: 0; alpha: 0),
163 (name: 'EPLASMA'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 4; back: true); rdelay: 0; alpha: 0),
164 (name: 'EBSPFIRE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 5; back: false); rdelay: 0; alpha: 0),
165 (name: 'EIMPFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
166 (name: 'ECACOFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
167 (name: 'EBARONFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
168 (name: 'TELEPORT'; w: 64; h: 64; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 0), // fast
169 (name: 'SMOKE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 150), // transparent
170 (name: 'FLAME'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 11; back: false); rdelay: 2; alpha: 0) // random
171 );
172 {$ENDIF}
173
174 ShotAnim: array [0..WEAPON_LAST] of record
175 name: AnsiString;
176 w, h: Integer;
177 anim: TAnimInfo;
178 end = (
179 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 0 KASTET
180 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 1 SAW
181 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 2 PISTOL
182 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 3 SHOTGUN1
183 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 4 SHOTGUN2
184 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 5 CHAINGUN
185 (name: 'BROCKET'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)), // 6 ROCKETLAUNCHER
186 (name: 'BPLASMA'; w: 16; h: 16; anim: (loop: true; delay: 5; frames: 2; back: false)), // 7 PLASMA
187 (name: 'BBFG'; w: 64; h: 64; anim: (loop: true; delay: 6; frames: 2; back: false)), // 8 BFG
188 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 9 SUPERPULEMET
189 (name: 'FLAME'; w: 32; h: 32; anim: (loop: true; delay: 6; frames: 0{11}; back: false)), // 10 FLAMETHROWER
190 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 11
191 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 12
192 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 13
193 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 14
194 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 15
195 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 16
196 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 17
197 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 18
198 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 19
199 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 20 ZOMPY_PISTOL
200 (name: 'BIMPFIRE'; w: 16; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 21 IMP_FIRE
201 (name: 'BBSPFIRE'; w: 16; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 22 BSP_FIRE
202 (name: 'BCACOFIRE'; w: 16; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 23 CACO_FIRE
203 (name: 'BBARONFIRE'; w: 64; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 24 BARON_FIRE
204 (name: 'BMANCUBFIRE'; w: 64; h: 32; anim: (loop: true; delay: 4; frames: 2; back: false)), // 25 MANCUB_FIRE
205 (name: 'BSKELFIRE'; w: 64; h: 64; anim: (loop: true; delay: 5; frames: 2; back: false)) // 26 SKEL_FIRE
206 );
207
208 {$IFDEF ENABLE_SHELLS}
209 ShellAnim: array [0..SHELL_LAST] of record
210 name: AnsiString;
211 dx, dy: Integer;
212 end = (
213 (name: 'EBULLET'; dx: 2; dy: 1), // 0 SHELL_BULLET
214 (name: 'ESHELL'; dx: 4; dy: 2), // 1 SHELL_SHELL
215 (name: 'ESHELL'; dx: 4; dy: 2) // 2 SHELL_DBLSHELL
216 );
217 {$ENDIF}
218
219 PunchAnim: TAnimInfo = (loop: false; delay: 1; frames: 4; back: false);
220 FlagAnim: TAnimInfo = (loop: true; delay: 8; frames: 5; back: false);
221 VileFireAnim: TAnimInfo = (loop: true; delay: 2; frames: 8; back: false);
222
223 type
224 TBinHeapPanelDrawCmp = class
225 public
226 class function less (const a, b: TPanel): Boolean; inline;
227 end;
228
229 TBinHeapPanelDraw = specialize TBinaryHeapBase<TPanel, TBinHeapPanelDrawCmp>;
230
231 TMonsterAnims = array [0..ANIM_LAST, TDirection] of TGLMultiTexture;
232
233 var
234 DebugCameraScale: Single;
235 FillOutsizeArea: Boolean;
236 SkyTexture: TGLTexture;
237 RenTextures: array of record
238 spec: LongInt;
239 tex: TGLMultiTexture;
240 anim: TAnimInfo;
241 end;
242 Items: array [0..ITEM_LAST] of record
243 tex: TGLMultiTexture;
244 frame: Integer;
245 end;
246 MonTextures: array [0..MONSTER_MAN] of TMonsterAnims;
247 WeapTextures: array [0..WP_LAST, 0..W_POS_LAST, 0..W_ACT_LAST] of TGLTexture;
248 ShotTextures: array [0..WEAPON_LAST] of TGLMultiTexture;
249 FlagTextures: array [0..FLAG_LAST] of TGLMultiTexture;
250 PunchTextures: array [Boolean, 0..2] of TGLMultiTexture; // [berserk, center/up/down]
251 VileFire: TGLMultiTexture;
252 InvulPenta: TGLTexture;
253 IndicatorTexture: TGLTexture;
254 TalkTexture: TGLTexture;
255 Models: array of record
256 anim: array [TDirection, 0..A_LAST] of record
257 base, mask: TGLMultiTexture;
258 end;
259 {$IFDEF ENABLE_GIBS}
260 gibs: record
261 base, mask: TGLTextureArray;
262 rect: TRectArray;
263 end;
264 {$ENDIF}
265 end;
266
267 {$IFDEF ENABLE_SHELLS}
268 ShellTextures: array [0..SHELL_LAST] of TGLTexture;
269 {$ENDIF}
270 {$IFDEF ENABLE_GFX}
271 GFXTextures: array [0..R_GFX_LAST] of TGLMultiTexture;
272 gfxlist: array of record
273 typ: Byte;
274 x, y: Integer;
275 oldX, oldY: Integer;
276 anim: TAnimInfo;
277 time: LongWord;
278 frame: LongInt;
279 end = nil;
280 {$ENDIF}
281
282 FlagFrame: LongInt;
283 plist: TBinHeapPanelDraw = nil;
284
285 class function TBinHeapPanelDrawCmp.less (const a, b: TPanel): Boolean; inline;
286 begin
287 if a.tag < b.tag then begin result := true; exit; end;
288 if a.tag > b.tag then begin result := false; exit; end;
289 result := a.arrIdx < b.arrIdx;
290 end;
291
292 procedure r_Map_Initialize;
293 begin
294 FlagFrame := 0;
295 plist := TBinHeapPanelDraw.Create();
296 end;
297
298 procedure r_Map_Finalize;
299 begin
300 r_Common_FreeAndNil(plist);
301 FlagFrame := 0;
302 end;
303
304 procedure r_Map_FreeModel (i: Integer);
305 var a: Integer; d: TDirection;
306 begin
307 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
308 begin
309 for a := A_STAND to A_LAST do
310 begin
311 r_Common_FreeAndNil(Models[i].anim[d, a].base);
312 r_Common_FreeAndNil(Models[i].anim[d, a].mask);
313 end;
314 end;
315 {$IFDEF ENABLE_GIBS}
316 if Models[i].gibs.base <> nil then
317 for a := 0 to High(Models[i].gibs.base) do
318 r_Common_FreeAndNil(Models[i].gibs.base[a]);
319 if Models[i].gibs.mask <> nil then
320 for a := 0 to High(Models[i].gibs.mask) do
321 r_Common_FreeAndNil(Models[i].gibs.mask[a]);
322 Models[i].gibs.base := nil;
323 Models[i].gibs.mask := nil;
324 Models[i].gibs.rect := nil;
325 {$ENDIF}
326 end;
327
328 procedure r_Map_LoadModel (i: Integer);
329 var prefix: AnsiString; a: Integer; d: TDirection; m: ^TPlayerModelInfo;
330 begin
331 ASSERT(i < Length(Models));
332 ASSERT(i < Length(PlayerModelsArray));
333 r_Map_FreeModel(i);
334 m := @PlayerModelsArray[i];
335 prefix := m.FileName + ':TEXTURES/';
336 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
337 begin
338 for a := A_STAND to A_LAST do
339 begin
340 Models[i].anim[d, a].base := nil;
341 Models[i].anim[d, a].mask := nil;
342 if m.anim[d, a].resource <> '' then
343 Models[i].anim[d, a].base := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].resource, 64, 64, m.anim[d, a].frames, [TGLHints.txNoRepeat], true);
344 if m.anim[d, a].mask <> '' then
345 Models[i].anim[d, a].mask := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].mask, 64, 64, m.anim[d, a].frames, [TGLHints.txNoRepeat], true);
346 end
347 end;
348 {$IFDEF ENABLE_GIBS}
349 Models[i].gibs.base := nil;
350 Models[i].gibs.mask := nil;
351 Models[i].gibs.rect := nil;
352 if m.GibsCount > 0 then
353 begin
354 SetLength(Models[i].gibs.base, m.GibsCount);
355 SetLength(Models[i].gibs.mask, m.GibsCount);
356 SetLength(Models[i].gibs.rect, m.GibsCount);
357 for a := 0 to m.GibsCount - 1 do
358 Models[i].gibs.rect[a] := DefaultGibSize;
359 if r_Textures_LoadStreamFromFile(prefix + m.GibsResource, 32, 32, m.GibsCount, m.GibsCount, Models[i].gibs.base, Models[i].gibs.rect, [TGLHints.txNoRepeat]) then
360 begin
361 if r_Textures_LoadStreamFromFile(prefix + m.GibsMask, 32, 32, m.GibsCount, m.GibsCount, Models[i].gibs.mask, nil, [TGLHints.txNoRepeat]) then
362 begin
363 // ok
364 end;
365 end;
366 end;
367 {$ENDIF}
368 end;
369
370 procedure r_Map_LoadMonsterAnim (m, a: Integer; d: TDirection);
371 const dir: array [TDirection] of AnsiString = ('_L', '');
372 var w, h, count: Integer;
373 begin
374 count := MONSTER_ANIMTABLE[m].AnimCount[a];
375 if count > 0 then
376 begin
377 w := MTABLE[m].w;
378 h := MTABLE[m].h;
379 if (m = MONSTER_SOUL) and (a = ANIM_DIE) then
380 begin
381 // special case
382 w := 128;
383 h := 128;
384 end;
385 MonTextures[m, a, d] := r_Textures_LoadMultiFromFileAndInfo(
386 GameWAD + ':MTEXTURES/' + MONSTERTABLE[m].name + '_' + ANIMTABLE[a].name + dir[d],
387 w,
388 h,
389 count,
390 [TGLHints.txNoRepeat],
391 False
392 );
393 end
394 else
395 MonTextures[m, a, d] := nil;
396 end;
397
398 procedure r_Map_Load;
399 const
400 WeapName: array [0..WP_LAST] of AnsiString = ('', 'CSAW', 'HGUN', 'SG', 'SSG', 'MGUN', 'RKT', 'PLZ', 'BFG', 'SPL', 'FLM');
401 WeapPos: array [0..W_POS_LAST] of AnsiString = ('', '_UP', '_DN');
402 WeapAct: array [0..W_ACT_LAST] of AnsiString = ('', '_FIRE');
403 PunchName: array [Boolean] of AnsiString = ('PUNCH', 'PUNCHB');
404 var
405 i, j, k: Integer; d: TDirection; b: Boolean;
406 begin
407 // --------- items --------- //
408 r_Common_SetLoading(_lc[I_LOAD_ITEMS_DATA], ITEM_LAST + 1);
409 for i := 0 to ITEM_LAST do
410 begin
411 Items[i].tex := r_Common_LoadTextureMultiFromFileAndInfo(
412 GameWAD + ':TEXTURES/' + ItemAnim[i].name,
413 ItemAnim[i].w,
414 ItemAnim[i].h,
415 ItemAnim[i].anim.frames,
416 [TGLHints.txNoRepeat],
417 false
418 );
419 Items[i].frame := 0;
420 end;
421 // --------- monsters --------- //
422 r_Common_SetLoading(_lc[I_LOAD_MONSTER_TEXTURES], MONSTER_MAN - MONSTER_DEMON + 1);
423 for i := MONSTER_DEMON to MONSTER_MAN do
424 begin
425 for j := 0 to ANIM_LAST do
426 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
427 r_Map_LoadMonsterAnim(i, j, d);
428 r_Common_StepLoading(1);
429 end;
430 VileFire := r_Textures_LoadMultiFromFileAndInfo(GameWAD + ':TEXTURES/FIRE', 64, 128, VileFireAnim.frames, [TGLHints.txNoRepeat]);
431 // --------- player models --------- //
432 if PlayerModelsArray <> nil then
433 begin
434 r_Common_SetLoading(_lc[I_LOAD_MODELS], Length(PlayerModelsArray));
435 SetLength(Models, Length(PlayerModelsArray));
436 for i := 0 to High(PlayerModelsArray) do
437 begin
438 r_Map_LoadModel(i);
439 r_Common_StepLoading(1);
440 end;
441 end;
442 // --------- player weapons --------- //
443 r_Common_SetLoading(_lc[I_LOAD_WEAPONS_DATA], WP_LAST);
444 for i := 1 to WP_LAST do
445 begin
446 for j := 0 to W_POS_LAST do
447 for k := 0 to W_ACT_LAST do
448 WeapTextures[i, j, k] := r_Textures_LoadFromFile(GameWAD + ':WEAPONS\' + WeapName[i] + WeapPos[j] + WeapAct[k], [TGLHints.txNoRepeat]);
449 r_Common_StepLoading(1);
450 end;
451 // --------- gfx animations --------- //
452 {$IFDEF ENABLE_GFX}
453 r_Common_SetLoading('GFX Effects', R_GFX_LAST);
454 for i := 1 to R_GFX_LAST do
455 begin
456 if GFXAnim[i].anim.frames > 0 then
457 GFXTextures[i] := r_Common_LoadTextureMultiFromFileAndInfo(GameWad + ':TEXTURES/' + GFXAnim[i].name, GFXAnim[i].w, GFXAnim[i].h, GFXAnim[i].anim.frames, [TGLHints.txNoRepeat]);
458 end;
459 {$ENDIF}
460 // --------- shots --------- //
461 r_Common_SetLoading('Weapon splahses', WEAPON_LAST + 1);
462 for i := 0 to WEAPON_LAST do
463 begin
464 if ShotAnim[i].anim.frames > 0 then
465 ShotTextures[i] := r_Common_LoadTextureMultiFromFileAndInfo(GameWad + ':TEXTURES/' + ShotAnim[i].name, ShotAnim[i].w, ShotAnim[i].h, ShotAnim[i].anim.frames, [TGLHints.txNoRepeat]);
466 end;
467 // --------- flags --------- //
468 r_Common_SetLoading('Flags', 2);
469 FlagTextures[FLAG_NONE] := nil;
470 FlagTextures[FLAG_RED] := r_Common_LoadTextureMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGRED', 64, 64, 5, [TGLHints.txNoRepeat]);
471 FlagTextures[FLAG_BLUE] := r_Common_LoadTextureMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGBLUE', 64, 64, 5, [TGLHints.txNoRepeat]);
472 // FlagTextures[FLAG_DOM] := r_Common_LoadTextureMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGDOM', 64, 64, 8, [TGLHints.txNoRepeat]);
473 // --------- shells --------- //
474 {$IFDEF ENABLE_SHELLS}
475 r_Common_SetLoading('Shells', SHELL_LAST + 1);
476 for i := 0 to SHELL_LAST do
477 ShellTextures[i] := r_Common_LoadTextureFromFile(GameWad + ':TEXTURES/' + ShellAnim[i].name, [TGLHints.txNoRepeat]);
478 {$ENDIF}
479 // --------- other --------- //
480 r_Common_SetLoading('Effects', 3 * 2 + 3);
481 for b := false to true do
482 begin
483 for i := 0 to 2 do
484 PunchTextures[b, i] := r_Common_LoadTextureMultiFromFileAndInfo(GameWad + ':WEAPONS/' + PunchName[b] + WeapPos[i], 64, 64, PunchAnim.frames, [TGLHints.txNoRepeat]);
485 end;
486 InvulPenta := r_Common_LoadTextureFromFile(GameWad + ':TEXTURES/PENTA', [TGLHints.txNoRepeat]);
487 IndicatorTexture := r_Common_LoadTextureFromFile(GameWad + ':TEXTURES/PLRIND', [TGLHints.txNoRepeat]);
488 TalkTexture := r_Common_LoadTextureFromFile(GameWad + ':TEXTURES/TALKBUBBLE', [TGLHints.txNoRepeat]);
489 end;
490
491 procedure r_Map_Free;
492 var i, j, k: Integer; d: TDirection; b: Boolean;
493 begin
494 r_Common_FreeAndNil(TalkTexture);
495 r_Common_FreeAndNil(IndicatorTexture);
496 r_Common_FreeAndNil(InvulPenta);
497 for b := false to true do
498 for i := 0 to 2 do
499 r_Common_FreeAndNil(PunchTextures[b, i]);
500 {$IFDEF ENABLE_SHELLS}
501 for i := 0 to SHELL_LAST do
502 r_Common_FreeAndNil(ShellTextures[i]);
503 {$ENDIF}
504 for i := 0 to FLAG_LAST do
505 r_Common_FreeAndNil(FlagTextures[i]);
506 for i := 0 to WEAPON_LAST do
507 r_Common_FreeAndNil(ShotTextures[i]);
508 {$IFDEF ENABLE_GFX}
509 SetLength(gfxlist, 0);
510 for i := 0 to R_GFX_LAST do
511 r_Common_FreeAndNil(GFXTextures[i]);
512 {$ENDIF}
513 for i := 1 to WP_LAST do
514 for j := 0 to W_POS_LAST do
515 for k := 0 to W_ACT_LAST do
516 r_Common_FreeAndNil(WeapTextures[i, j, k]);
517 if Models <> nil then
518 for i := 0 to High(Models) do
519 r_Map_FreeModel(i);
520 for i := MONSTER_DEMON to MONSTER_MAN do
521 for j := 0 to ANIM_LAST do
522 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
523 r_Common_FreeAndNil(MonTextures[i, j, d]);
524 for i := 0 to ITEM_LAST do
525 r_Common_FreeAndNil(Items[i].tex);
526 end;
527
528 procedure r_Map_FreeTextures;
529 var i: Integer;
530 begin
531 plist.Clear;
532 r_Common_FreeAndNil(SkyTexture);
533 if RenTextures <> nil then
534 for i := 0 to High(RenTextures) do
535 r_Common_FreeAndNil(RenTextures[i].tex);
536 SetLength(RenTextures, 0);
537 end;
538
539 procedure r_Map_LoadTextures;
540 const DefaultAnimInfo: TAnimInfo = (loop: true; delay: 1; frames: 1; back: false);
541 var i, n: Integer; txt: TAnimTextInfo;
542 begin
543 r_Map_FreeTextures;
544 if Textures <> nil then
545 begin
546 n := Length(Textures);
547 SetLength(RenTextures, n);
548 r_Common_SetLoading(_lc[I_LOAD_TEXTURES], n);
549 for i := 0 to n - 1 do
550 begin
551 RenTextures[i].tex := nil;
552 RenTextures[i].anim := DefaultAnimInfo;
553 case Textures[i].TextureName of
554 TEXTURE_NAME_WATER: RenTextures[i].spec := TEXTURE_SPECIAL_WATER;
555 TEXTURE_NAME_ACID1: RenTextures[i].spec := TEXTURE_SPECIAL_ACID1;
556 TEXTURE_NAME_ACID2: RenTextures[i].spec := TEXTURE_SPECIAL_ACID2;
557 else
558 RenTextures[i].spec := 0;
559 RenTextures[i].tex := r_Textures_LoadMultiTextFromFile(Textures[i].FullName, txt, []);
560 if RenTextures[i].tex <> nil then
561 begin
562 RenTextures[i].anim := txt.anim;
563 r_Common_StepLoading(1);
564 end
565 else
566 begin
567 e_LogWritefln('r_Map_LoadTextures: failed to load texture: %s', [Textures[i].FullName]);
568 end;
569 end;
570 ASSERT(RenTextures[i].anim.frames > 0);
571 ASSERT(RenTextures[i].anim.delay > 0);
572 end;
573 end;
574 if gMapInfo.SkyFullName <> '' then
575 begin
576 r_Common_SetLoading(_lc[I_LOAD_SKY], 1);
577 SkyTexture := r_Common_LoadTextureFromFile(gMapInfo.SkyFullName, [TGLHints.txNoRepeat]);
578 end;
579 plist.Clear;
580 end;
581
582 procedure r_Map_DrawPanel (p: TPanel);
583 var Texture: Integer; t: TGLMultiTexture; tex: TGLTexture; count, frame: LongInt; a: TAnimInfo;
584 begin
585 ASSERT(p <> nil);
586 if p.FCurTexture >= 0 then
587 begin
588 ASSERT(p.FCurTexture <= High(p.TextureIDs));
589 Texture := p.TextureIDs[p.FCurTexture].Texture;
590 t := nil;
591 ASSERT(Texture >= -1);
592 ASSERT(Texture <= High(RenTextures));
593 if Texture >= 0 then
594 begin
595 t := RenTextures[Texture].tex;
596 if (RenTextures[Texture].spec = 0) or (t <> nil) then
597 begin
598 count := 0; frame := 0;
599 if p.AnimTime <= gTime then
600 begin
601 a := RenTextures[Texture].anim;
602 a.loop := p.AnimLoop;
603 g_Anim_GetFrameByTime(a, (gTime - p.AnimTime) DIV GAME_TICK, count, frame);
604 end;
605 if t <> nil then
606 begin
607 tex := t.GetTexture(frame);
608 r_Draw_TextureRepeat(tex, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending);
609 end
610 else
611 r_Draw_TextureRepeat(nil, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255, false);
612 end;
613 end;
614
615 if t = nil then
616 begin
617 case RenTextures[Texture].spec of
618 TEXTURE_SPECIAL_WATER: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 0, 255, 255);
619 TEXTURE_SPECIAL_ACID1: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 230, 0, 255);
620 TEXTURE_SPECIAL_ACID2: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 230, 0, 0, 255);
621 end
622 end
623 end
624 end;
625
626 procedure r_Map_DrawPanelType (panelTyp: DWORD);
627 var tagMask, i: Integer; p: TPanel;
628 begin
629 i := 0;
630 tagMask := PanelTypeToTag(panelTyp);
631 while plist.count > 0 do
632 begin
633 p := TPanel(plist.Front());
634 if (p.tag and tagMask) = 0 then
635 break;
636 r_Map_DrawPanel(p);
637 Inc(i);
638 plist.PopFront
639 end;
640 end;
641
642 procedure r_Map_DrawItems (x, y, w, h: Integer; drop: Boolean);
643 var i, xx, yy: Integer; it: PItem; t: TGLMultiTexture; tex: TGLTexture;
644 begin
645 if ggItems <> nil then
646 begin
647 for i := 0 to High(ggItems) do
648 begin
649 it := @ggItems[i];
650 if it.used and it.alive and (it.dropped = drop) and (it.ItemType > ITEM_NONE) and (it.ItemType <= ITEM_LAST) then
651 begin
652 t := Items[it.ItemType].tex;
653 if g_Collide(it.obj.x, it.obj.y, t.width, t.height, x, y, w, h) then
654 begin
655 r_Common_GetObjectPos(it.obj, xx, yy);
656 tex := t.GetTexture(Items[it.ItemType].frame);
657 r_Draw_TextureRepeat(tex, xx, yy, tex.width, tex.height, false, 255, 255, 255, 255, false);
658 end;
659 end;
660 end;
661 end;
662 // TODO draw g_debug_frames
663 end;
664
665 function r_Map_GetMonsterTexture (m, a: Integer; d: TDirection; out t: TGLMultiTexture; out dx, dy: Integer; out flip: Boolean): Boolean;
666 // var c: Integer;
667 begin
668 t := nil; dx := 0; dy := 0; flip := false;
669 result := MonTextures[m, a, d] <> nil;
670 if result = false then
671 begin
672 flip := true;
673 if d = TDirection.D_RIGHT then d := TDirection.D_LEFT else d := TDirection.D_RIGHT;
674 result := MonTextures[m, a, d] <> nil;
675 end;
676 if result = true then
677 begin
678 t := MonTextures[m, a, d];
679 if d = TDirection.D_LEFT then
680 begin
681 dx := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].X;
682 dy := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].Y;
683 end
684 else
685 begin
686 dx := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].X;
687 dy := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].Y;
688 end;
689 if flip then
690 begin
691 // c := (MONSTERTABLE[MonsterType].Rect.X - dx) + MONSTERTABLE[MonsterType].Rect.Width;
692 // dx := MTABLE[m].width - c - MONSTERTABLE[MonsterType].Rect.X;
693 dx := -dx;
694 end;
695 end;
696 end;
697
698 procedure r_Map_DrawMonsterAttack (constref mon: TMonster);
699 var o: TObj; count, frame, xx, yy: LongInt; tex: TGLTexture;
700 begin
701 if VileFire <> nil then
702 begin
703 if (mon.MonsterType = MONSTER_VILE) and (mon.MonsterState = MONSTATE_SHOOT) and (mon.VileFireTime <= gTime) then
704 begin
705 if r_Common_GetPosByUID(mon.MonsterTargetUID, o, xx, yy) then
706 begin
707 g_Anim_GetFrameByTime(VileFireAnim, (gTime - mon.VileFireTime) DIV GAME_TICK, count, frame);
708 tex := VileFire.GetTexture(frame);
709 r_Draw_TextureRepeat(tex, xx + o.rect.x + (o.rect.width div 2) - VILEFIRE_DX, yy + o.rect.y + o.rect.height - VILEFIRE_DY, tex.width, tex.height, False, 255, 255, 255, 255, false);
710 end;
711 end;
712 end;
713 end;
714
715 procedure r_Map_DrawMonster (constref mon: TMonster);
716 var m, a, xx, yy, dx, dy: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture;
717 begin
718 m := mon.MonsterType;
719 a := mon.MonsterAnim;
720 d := mon.GameDirection;
721
722 if r_Map_GetMonsterTexture(m, a, d, t, dx, dy, flip) then
723 begin
724 r_Common_GetObjectPos(mon.obj, xx, yy);
725 r_Draw_MultiTextureRepeat(t, mon.DirAnim[a, d], false, xx + dx, yy + dy, t.width, t.height, flip, 255, 255, 255, 255, false);
726 end;
727
728 // TODO draw g_debug_frames
729 end;
730
731 procedure r_Map_DrawMonsters (x, y, w, h: Integer);
732 var i: Integer; m: TMonster;
733 begin
734 if gMonsters <> nil then
735 begin
736 for i := 0 to High(gMonsters) do
737 begin
738 m := gMonsters[i];
739 if m <> nil then
740 begin
741 r_Map_DrawMonsterAttack(m);
742 // TODO select from grid
743 if g_Collide(m.obj.x + m.obj.rect.x, m.obj.y + m.obj.rect.y, m.obj.rect.width, m.obj.rect.height, x, y, w, h) then
744 r_Map_DrawMonster(m);
745 end;
746 end;
747 end;
748 end;
749
750 function r_Map_GetPlayerModelTex (i: Integer; var a: Integer; var d: TDirection; out flip: Boolean): Boolean;
751 begin
752 flip := false;
753 result := Models[i].anim[d, a].base <> nil;
754 if result = false then
755 begin
756 flip := true;
757 if d = TDirection.D_LEFT then d := TDirection.D_RIGHT else d := TDirection.D_LEFT;
758 result := Models[i].anim[d, a].base <> nil;
759 end;
760 end;
761
762 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer; alpha: Byte);
763 var a, pos, act, xx, yy, angle: Integer; d: TDirection; flip, back: Boolean; t: TGLMultiTexture; tex: TGLTexture; c: TRGB;
764 begin
765 a := pm.CurrentAnimation;
766 d := pm.Direction;
767
768 (* draw flag*)
769 t := FlagTextures[pm.Flag];
770 if (t <> nil) and not (a in [A_DIE1, A_DIE2]) then
771 begin
772 flip := d = TDirection.D_RIGHT;
773 angle := PlayerModelsArray[pm.id].FlagAngle;
774 xx := PlayerModelsArray[pm.id].FlagPoint.X;
775 yy := PlayerModelsArray[pm.id].FlagPoint.Y;
776 tex := t.GetTexture(FlagFrame);
777 r_Draw_TextureRepeatRotate(
778 tex,
779 x + IfThen(flip, 2 * FLAG_BASEPOINT.X - xx + 1, xx - 1) - FLAG_BASEPOINT.X,
780 y + yy - FLAG_BASEPOINT.Y + 1,
781 tex.width,
782 tex.height,
783 flip,
784 255, 255, 255, 255, false,
785 IfThen(flip, 64 - FLAG_BASEPOINT.X, FLAG_BASEPOINT.X),
786 FLAG_BASEPOINT.Y,
787 IfThen(flip, angle, -angle)
788 );
789 end;
790
791 (* draw weapon *)
792 if PlayerModelsArray[pm.id].HaveWeapon and not (a in [A_DIE1, A_DIE2, A_PAIN]) then
793 begin
794 case a of
795 A_SEEUP, A_ATTACKUP: pos := W_POS_UP;
796 A_SEEDOWN, A_ATTACKDOWN: pos := W_POS_DOWN;
797 else pos := W_POS_NORMAL;
798 end;
799 if (a in [A_ATTACK, A_ATTACKUP, A_ATTACKDOWN]) or pm.GetFire() then
800 act := W_ACT_FIRE
801 else
802 act := W_ACT_NORMAL;
803 tex := WeapTextures[pm.CurrentWeapon, pos, act];
804 if tex <> nil then
805 begin
806 xx := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].X;
807 yy := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].Y;
808 r_Draw_Texture(
809 tex,
810 x + xx,
811 y + yy,
812 tex.width,
813 tex.height,
814 d = TDirection.D_LEFT,
815 255, 255, 255, alpha, false
816 );
817 end;
818 end;
819
820 (* draw body *)
821 if r_Map_GetPlayerModelTex(pm.id, a, d, flip) then
822 begin
823 t := Models[pm.id].anim[d, a].base;
824 back := PlayerModelsArray[pm.id].anim[d, a].back;
825 r_Draw_MultiTextureRepeat(t, pm.AnimState, back, x, y, t.width, t.height, flip, 255, 255, 255, alpha, false);
826 t := Models[pm.id].anim[d, a].mask;
827 if t <> nil then
828 begin
829 c := pm.Color;
830 r_Draw_MultiTextureRepeat(t, pm.AnimState, back, x, y, t.width, t.height, flip, c.r, c.g, c.b, alpha, false);
831 end;
832 end;
833 end;
834
835 procedure r_Map_DrawBubble (x, y: Integer; cb, cf: TRGB);
836 const w = 20; h = 14;
837 const dx = 6; dy = 8; dot = 6; size = 2;
838 const tx = 6; ty = h - 1;
839 begin
840 // Outer box (top/down)
841 r_Draw_FillRect(x + 1, y, x + w - 1, y + 1, cb.R, cb.G, cb.B, 255);
842 r_Draw_FillRect(x + 1, y + h - 1, x + w - 1, y + h, cb.R, cb.G, cb.B, 255);
843 // Outer box (left/right)
844 r_Draw_FillRect(x, y + 1, x + 1, y + h - 1, cb.R, cb.G, cb.B, 255);
845 r_Draw_FillRect(x + w - 1, y + 1, x + w, y + h - 1, cb.R, cb.G, cb.B, 255);
846 // Outer tail
847 r_Draw_FillRect(x + tx - 1, y + ty + 0, x + tx + 3 + 1, y + ty + 1, cb.R, cb.G, cb.B, 255);
848 r_Draw_FillRect(x + tx - 1, y + ty + 1, x + tx + 2 + 1, y + ty + 2, cb.R, cb.G, cb.B, 255);
849 r_Draw_FillRect(x + tx - 1, y + ty + 2, x + tx + 1 + 1, y + ty + 3, cb.R, cb.G, cb.B, 255);
850 r_Draw_FillRect(x + tx - 1, y + ty + 3, x + tx + 0 + 1, y + ty + 4, cb.R, cb.G, cb.B, 255);
851 // Inner tail
852 r_Draw_FillRect(x + tx, y + ty + 0, x + tx + 3, y + ty + 1, cf.R, cf.G, cf.B, 255);
853 r_Draw_FillRect(x + tx, y + ty + 1, x + tx + 2, y + ty + 2, cf.R, cf.G, cf.B, 255);
854 r_Draw_FillRect(x + tx, y + ty + 2, x + tx + 1, y + ty + 3, cf.R, cf.G, cf.B, 255);
855 // Inner box
856 r_Draw_FillRect(x + 1, y + 1, x + w - 1, y + h - 1, cf.R, cf.G, cf.B, 255);
857 // Dots
858 r_Draw_FillRect(x + dx + 0*3, y + dy, x + dx + 0*3 + size, y + dy + size, cb.R, cb.G, cb.B, 255);
859 r_Draw_FillRect(x + dx + 1*3, y + dy, x + dx + 1*3 + size, y + dy + size, cb.R, cb.G, cb.B, 255);
860 r_Draw_FillRect(x + dx + 2*3, y + dy, x + dx + 2*3 + size, y + dy + size, cb.R, cb.G, cb.B, 255);
861 end;
862
863 procedure r_Map_DrawTalkBubble (p: TPlayer);
864 var xx, yy, x, y: Integer; cb, cf: TRGB;
865 begin
866 r_Common_GetPlayerPos(p, xx, yy);
867 x := xx + p.obj.rect.x + p.obj.rect.width div 2;
868 y := yy;
869 cb := _RGB(63, 63, 63);
870 cf := _RGB(240, 240, 240);
871 case gChatBubble of
872 1: // simple text
873 begin
874 r_Common_DrawText('[...]', x, y, 255, 255, 255, 255, stdfont, TBasePoint.BP_DOWN);
875 end;
876 2: // adv team color
877 begin
878 case p.Team of
879 TEAM_RED: cb := _RGB(255, 63, 63);
880 TEAM_BLUE: cb := _RGB(63, 63, 255);
881 end;
882 r_Map_DrawBubble(x, y - 18, cb, cf);
883 end;
884 3: // adv player color
885 begin
886 cb := p.Model.Color;
887 cf.R := MIN(cb.R * 2 + 64, 255);
888 cf.G := MIN(cb.G * 2 + 64, 255);
889 cf.B := MIN(cb.B * 2 + 64, 255);
890 if (ABS(cf.R - cb.R) < 32) or (ABS(cf.G - cb.G) < 32) or (ABS(cf.B - cb.B) < 32) then
891 begin
892 cb.R := MAX(cf.R div 2 - 16, 0);
893 cb.G := MAX(cf.G div 2 - 16, 0);
894 cb.B := MAX(cf.B div 2 - 16, 0);
895 end;
896 r_Map_DrawBubble(x, y - 18, cb, cf);
897 end;
898 4: // textured
899 if TalkTexture <> nil then
900 begin
901 r_Common_DrawTexture(TalkTexture, x + 5, y, TalkTexture.width, TalkTexture.height, TBasePoint.BP_DOWN);
902 end;
903 end;
904 end;
905
906 procedure r_Map_DrawPlayer (p, drawed: TPlayer);
907 var x, y, ax, ay, w, h: Integer; b, flip: Boolean; t: TGLMultiTexture; tex: TGLTexture; alpha: Byte; count, frame: LongInt;
908 begin
909 if p.alive then
910 begin
911 r_Common_GetPlayerPos(p, x, y);
912
913 (* punch effect *)
914 if p.PunchTime <= gTime then
915 begin
916 g_Anim_GetFrameByTime(PunchAnim, (gTime - p.PunchTime) DIV GAME_TICK, count, frame);
917 if count < 1 then
918 begin
919 b := R_BERSERK in p.FRulez;
920 if p.FKeys[KEY_DOWN].pressed then
921 t := PunchTextures[b, 2]
922 else if p.FKeys[KEY_UP].pressed then
923 t := PunchTextures[b, 1]
924 else
925 t := PunchTextures[b, 0];
926 if t <> nil then
927 begin
928 flip := p.Direction = TDirection.D_LEFT;
929 ax := IfThen(flip, 15 - p.Obj.Rect.X, p.Obj.Rect.X - 15); // ???
930 ay := p.Obj.Rect.Y - 11;
931 tex := t.GetTexture(frame);
932 r_Draw_TextureRepeat(tex, x + ax, y + ay, tex.width, tex.height, flip, 255, 255, 255, 255, false)
933 end;
934 end;
935 end;
936
937 (* invulnerability effect *)
938 if (InvulPenta <> nil) and (p.FMegaRulez[MR_INVUL] > gTime) and ((p <> drawed) or (p.SpawnInvul >= gTime)) then
939 begin
940 w := InvulPenta.width;
941 h := InvulPenta.height;
942 ax := p.Obj.Rect.X + (p.Obj.Rect.Width div 2) - (w div 2); // + IfThen(flip, +4, -2) // ???
943 ay := p.Obj.Rect.Y + (p.Obj.Rect.Height div 2) - (h div 2) - 7; // ???
944 r_Draw_Texture(InvulPenta, x + ax, y + ay, w, h, false, 255, 255, 255, 255, false);
945 end;
946
947 (* invisibility effect *)
948 alpha := 255;
949 if p.FMegaRulez[MR_INVIS] > gTime then
950 begin
951 if (drawed <> nil) and ((p = drawed) or ((p.Team = drawed.Team) and (gGameSettings.GameMode <> GM_DM))) then
952 begin
953 if (p.FMegaRulez[MR_INVIS] - gTime > 2100) or not ODD((p.FMegaRulez[MR_INVIS] - gTime) div 300) then
954 alpha := 55;
955 end
956 else
957 alpha := 1; // ???
958 end;
959
960 r_Map_DrawPlayerModel(p.Model, x, y, alpha);
961 end;
962 // TODO draw g_debug_frames
963
964 if (gChatBubble > 0) and p.FKeys[KEY_CHAT].Pressed and (p.Ghost = false) then
965 if (p.FMegaRulez[MR_INVIS] <= gTime) or ((drawed <> nil) and ((p = drawed) or (p.Team = drawed.Team) and (gGameSettings.GameMode <> GM_DM))) then
966 r_Map_DrawTalkBubble(p);
967
968 // TODO draw aim
969 end;
970
971 procedure r_Map_DrawPlayers (x, y, w, h: Integer; player: TPlayer);
972 var i: Integer;
973 begin
974 if gPlayers <> nil then
975 for i := 0 to High(gPlayers) do
976 if gPlayers[i] <> nil then
977 r_Map_DrawPlayer(gPlayers[i], player);
978 end;
979
980 {$IFDEF ENABLE_GIBS}
981 function r_Map_GetGibSize (m, i: Integer): TRectWH;
982 begin
983 result := Models[m].gibs.rect[i];
984 end;
985
986 procedure r_Map_DrawGibs (x, y, w, h: Integer);
987 var i, xx, yy, m, id, rx, ry, ra: Integer; p: PObj; t: TGLTexture;
988 begin
989 if gGibs <> nil then
990 begin
991 for i := 0 to High(gGibs) do
992 begin
993 if gGibs[i].alive then
994 begin
995 p := @gGibs[i].Obj;
996 if g_Obj_Collide(x, y, w, h, p) then
997 begin
998 r_Common_GetObjectPos(p^, xx, yy);
999 id := gGibs[i].GibID;
1000 m := gGibs[i].ModelID;
1001 t := Models[m].gibs.base[id];
1002 if t <> nil then
1003 begin
1004 rx := p.Rect.X + p.Rect.Width div 2;
1005 ry := p.Rect.Y + p.Rect.Height div 2;
1006 ra := gGibs[i].RAngle;
1007 r_Draw_TextureRepeatRotate(t, xx, yy, t.width, t.height, false, 255, 255, 255, 255, false, rx, ry, ra);
1008 t := Models[m].gibs.mask[id];
1009 if t <> nil then
1010 r_Draw_TextureRepeatRotate(t, xx, yy, t.width, t.height, false, gGibs[i].Color.R, gGibs[i].Color.G, gGibs[i].Color.B, 255, false, rx, ry, ra);
1011 // r_Draw_TextureRepeatRotate(nil, xx + p.Rect.X, yy + p.Rect.Y, p.Rect.Width, p.Rect.Height, false, 255, 255, 255, 255, false, p.Rect.Width div 2, p.Rect.Height div 2, ra);
1012 end;
1013 end;
1014 end;
1015 end;
1016 end;
1017 // TODO draw g_debug_frames
1018 end;
1019 {$ENDIF}
1020
1021 {$IFDEF ENABLE_CORPSES}
1022 procedure r_Map_DrawCorpses (x, y, w, h: Integer);
1023 var i, xx, yy: Integer; p: TCorpse;
1024 begin
1025 if gCorpses <> nil then
1026 begin
1027 for i := 0 to High(gCorpses) do
1028 begin
1029 p := gCorpses[i];
1030 if (p <> nil) and (p.state <> CORPSE_STATE_REMOVEME) and (p.model <> nil) then
1031 begin
1032 r_Common_GetObjectPos(p.obj, xx, yy);
1033 r_Map_DrawPlayerModel(p.model, xx, yy, 255);
1034 end;
1035 end;
1036 end;
1037 // TODO draw g_debug_frames
1038 end;
1039 {$ENDIF}
1040
1041 {$IFDEF ENABLE_GFX}
1042 function r_Map_GetGFXID (): Integer;
1043 var i: Integer;
1044 begin
1045 i := 0;
1046 if gfxlist <> nil then
1047 begin
1048 while (i < Length(gfxlist)) and (gfxlist[i].typ > 0) do
1049 Inc(i);
1050 if i >= Length(gfxlist) then
1051 SetLength(gfxlist, Length(gfxlist) + 1)
1052 end
1053 else
1054 SetLength(gfxlist, 1);
1055 gfxlist[i].typ := R_GFX_NONE;
1056 result := i
1057 end;
1058
1059 procedure r_Map_NewGFX (typ, x, y: Integer);
1060 var i: Integer;
1061 begin
1062 if gpart_dbg_enabled and (typ > 0) and (typ <= R_GFX_LAST) then
1063 begin
1064 i := r_Map_GetGFXID();
1065 if i >= 0 then
1066 begin
1067 gfxlist[i].typ := typ;
1068 gfxlist[i].x := x;
1069 gfxlist[i].y := y;
1070 gfxlist[i].oldX := x;
1071 gfxlist[i].oldY := y;
1072 gfxlist[i].anim := GFXAnim[typ].anim;
1073 gfxlist[i].time := gTime DIV GAME_TICK;
1074 gfxlist[i].frame := 0;
1075 INC(gfxlist[i].anim.delay, Random(GFXAnim[typ].rdelay));
1076 end;
1077 end;
1078 end;
1079
1080 procedure r_Map_UpdateGFX (tick: LongWord);
1081 var i: Integer; count: LongInt;
1082 begin
1083 if gfxlist <> nil then
1084 begin
1085 for i := 0 to High(gfxlist) do
1086 begin
1087 if (gfxlist[i].typ > 0) and (tick >= gfxlist[i].time) then
1088 begin
1089 g_Anim_GetFrameByTime(gfxlist[i].anim, tick - gfxlist[i].time, count, gfxlist[i].frame);
1090 if count < 1 then
1091 begin
1092 gfxlist[i].oldX := gfxlist[i].x;
1093 gfxlist[i].oldY := gfxlist[i].y;
1094 case gfxlist[i].typ of
1095 R_GFX_FLAME, R_GFX_SMOKE:
1096 begin
1097 if Random(3) = 0 then
1098 gfxlist[i].x := gfxlist[i].x - 1 + Random(3);
1099 if Random(2) = 0 then
1100 gfxlist[i].y := gfxlist[i].y - Random(2);
1101 end;
1102 end;
1103 end
1104 else
1105 gfxlist[i].typ := R_GFX_NONE;
1106 end;
1107 end;
1108 end;
1109 end;
1110
1111 procedure r_Map_DrawGFX (x, y, w, h: Integer);
1112 var i, fx, fy, typ: Integer; t: TGLMultiTexture; tex: TGLTexture;
1113 begin
1114 if gfxlist <> nil then
1115 begin
1116 for i := 0 to High(gfxlist) do
1117 begin
1118 if gfxlist[i].typ > 0 then
1119 begin
1120 typ := gfxlist[i].typ;
1121 t := GFXTextures[typ];
1122 if t <> nil then
1123 begin
1124 fx := nlerp(gfxlist[i].oldX, gfxlist[i].x, gLerpFactor);
1125 fy := nlerp(gfxlist[i].oldY, gfxlist[i].y, gLerpFactor);
1126 tex := t.GetTexture(gfxlist[i].frame);
1127 r_Draw_TextureRepeat(tex, fx, fy, tex.width, tex.height, false, 255, 255, 255, 255 - GFXAnim[typ].alpha, false);
1128 end;
1129 end;
1130 end;
1131 end;
1132 end;
1133
1134 procedure r_Map_DrawParticles (x, y, w, h: Integer);
1135 var i, fx, fy: Integer; factor: Single;
1136 begin
1137 if gpart_dbg_enabled and (Particles <> nil) then
1138 begin
1139 r_Draw_EnableTexture2D(false);
1140 factor := r_pixel_scale * g_dbg_scale;
1141 if factor < 0.6 then
1142 glPointSize(1)
1143 else if factor > 1.3 then
1144 glPointSize(factor + 1)
1145 else
1146 glPointSize(2);
1147 glDisable(GL_POINT_SMOOTH);
1148 glEnable(GL_BLEND);
1149 glBlendFunc(GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA);
1150
1151 r_Draw_SetColor(255, 255, 255, 255);
1152 glBegin(GL_POINTS);
1153 for i := 0 to High(Particles) do
1154 begin
1155 if Particles[i].alive then
1156 begin
1157 fx := nlerp(Particles[i].oldX, Particles[i].x, gLerpFactor);
1158 fy := nlerp(Particles[i].oldY, Particles[i].y, gLerpFactor);
1159 glColor4ub(Particles[i].red, Particles[i].green, Particles[i].blue, Particles[i].alpha);
1160 glVertex2i(fx, fy);
1161 end;
1162 end;
1163 glEnd;
1164 r_Draw_SetColor(0, 0, 0, 255);
1165
1166 glDisable(GL_BLEND);
1167 end;
1168 end;
1169 {$ENDIF}
1170
1171 procedure r_Map_DrawShots (x, y, w, h: Integer);
1172 var i, a, xx, yy, pX, pY, typ: Integer; count, frame: LongInt; t: TGLMultiTexture; tex: TGLTexture;
1173 begin
1174 if Shots <> nil then
1175 begin
1176 for i := 0 to High(Shots) do
1177 begin
1178 typ := Shots[i].ShotType;
1179 if typ <> 0 then
1180 begin
1181 t := ShotTextures[typ];
1182 if t <> nil then
1183 begin
1184 a := 0;
1185 case typ of
1186 WEAPON_ROCKETLAUNCHER, WEAPON_BARON_FIRE, WEAPON_MANCUB_FIRE, WEAPON_SKEL_FIRE:
1187 a := -GetAngle2(Shots[i].Obj.Vel.X, Shots[i].Obj.Vel.Y)
1188 end;
1189 r_Common_GetObjectPos(Shots[i].Obj, xx, yy);
1190 pX := Shots[i].Obj.Rect.Width div 2;
1191 pY := Shots[i].Obj.Rect.Height div 2;
1192 g_Anim_GetFrameByTime(ShotAnim[typ].anim, (gTime - Shots[i].time) DIV GAME_TICK, count, frame);
1193 tex := t.GetTexture(frame);
1194 r_Draw_TextureRepeatRotate(tex, xx, yy, tex.width, tex.height, false, 255, 255, 255, 255, false, pX, pY, a);
1195 end;
1196 end;
1197 end;
1198 end;
1199 // TODO draw g_debug_frames
1200 end;
1201
1202 procedure r_Map_DrawFlags (x, y, w, h: Integer);
1203 var i, dx, xx, yy: Integer; flip: Boolean; t: TGLMultiTexture; tex: TGLTexture;
1204 begin
1205 if gGameSettings.GameMode = GM_CTF then
1206 begin
1207 for i := FLAG_RED to FLAG_BLUE do
1208 begin
1209 if not (gFlags[i].state in [FLAG_STATE_NONE, FLAG_STATE_CAPTURED]) then
1210 begin
1211 r_Common_GetObjectPos(gFlags[i].Obj, xx, yy);
1212 flip := gFlags[i].Direction = TDirection.D_LEFT;
1213 if flip then dx := -1 else dx := +1;
1214 t := FlagTextures[i];
1215 tex := t.GetTexture(FlagFrame);
1216 r_Draw_TextureRepeat(tex, xx + dx, yy + 1, tex.width, tex.height, flip, 255, 255, 255, 255, false)
1217 end;
1218 end;
1219 end;
1220 // TODO g_debug_frames
1221 end;
1222
1223 {$IFDEF ENABLE_SHELLS}
1224 procedure r_Map_DrawShells (x, y, w, h: Integer);
1225 var i, xx, yy, typ: Integer; t: TGLTexture; p: PObj;
1226 begin
1227 if gShells <> nil then
1228 begin
1229 for i := 0 to High(gShells) do
1230 begin
1231 if gShells[i].alive then
1232 begin
1233 typ := gShells[i].SType;
1234 if typ <= SHELL_LAST then
1235 begin
1236 p := @gShells[i].Obj;
1237 if g_Obj_Collide(x, y, w, h, p) then
1238 begin
1239 t := ShellTextures[typ];
1240 if t <> nil then
1241 begin
1242 r_Common_GetObjectPos(p^, xx, yy);
1243 r_Draw_TextureRepeatRotate(t, xx, yy, t.width, t.height, false, 255, 255, 255, 255, false, ShellAnim[typ].dx, ShellAnim[typ].dy, gShells[i].RAngle);
1244 end;
1245 end;
1246 end;
1247 end;
1248 end;
1249 end;
1250 end;
1251 {$ENDIF}
1252
1253 procedure r_Map_CalcSkyParallax (cx, cy, vw, vh, sw, sh, mw, mh: LongInt; out x, y, w, h: LongInt);
1254 const
1255 factor = 120; (* size ratio between view and sky (120%) *)
1256 limit = 100; (* max speed for parallax *)
1257 var
1258 msw, msh, mvw, mvh, svw, svh: LongInt;
1259 begin
1260 msw := vw * factor div 100;
1261 msh := vh * factor div 100;
1262 r_Common_CalcAspect(sw, sh, msw, msh, (sw / sh) <= (msw / msh), w, h);
1263
1264 (* calc x parallax or sky center on speed limit *)
1265 mvw := MAX(1, mw - vw);
1266 svw := w - vw;
1267 if 100 * svw div mvw <= limit then
1268 x := -cx * svw div mvw
1269 else
1270 x := -svw div 2;
1271
1272 (* calc y parallax or sky center on speed limit *)
1273 mvh := MAX(1, mh - vh);
1274 svh := h - vh;
1275 if 100 * svh div mvh <= limit then
1276 y := -cy * svh div mvh
1277 else
1278 y := -svh div 2;
1279
1280 (* handle out of map bounds *)
1281 if x > 0 then x := 0;
1282 if y > 0 then y := 0;
1283 if x < -svw then x := -svw;
1284 if y < -svh then y := -svh;
1285 end;
1286
1287 procedure r_Map_DrawScreenEffect (x, y, w, h, level: Integer; r, g, b: Byte);
1288 var i: Integer;
1289 begin
1290 if level > 0 then
1291 begin
1292 case level of
1293 0..14: i := 0;
1294 15..34: i := 1;
1295 35..54: i := 2;
1296 55..74: i := 3;
1297 75..94: i := 4;
1298 else i := 5
1299 end;
1300 r_Draw_FillRect(x, y, x + w, y + h, r, g, b, i * 50)
1301 end;
1302 end;
1303
1304 procedure r_Map_DrawScreenEffects (x, y, w, h: Integer; p: TPlayer);
1305 begin
1306 if p <> nil then
1307 begin
1308 r_Map_DrawScreenEffect(x, y, w, h, p.pain, 255, 0, 0);
1309 r_Map_DrawScreenEffect(x, y, w, h, p.pickup, 150, 200, 150);
1310 if (p.FMegaRulez[MR_INVUL] >= gTime) and (p.SpawnInvul < gTime) then
1311 begin
1312 if ((p.FMegaRulez[MR_INVUL] - gTime) > 2100) or not ODD((p.FMegaRulez[MR_INVUL] - gTime) div 300) then
1313 r_Draw_InvertRect(x, y, x + w, y + h, 191, 191, 191, 255);
1314 end;
1315 if p.FMegaRulez[MR_SUIT] >= gTime then
1316 begin
1317 if ((p.FMegaRulez[MR_SUIT] - gTime) > 2100) or not ODD((p.FMegaRulez[MR_SUIT] - gTime) div 300) then
1318 r_Draw_FillRect(x, y, x + w, y + h, 0, 96, 0, 55);
1319 end;
1320 if (p.Berserk >= 0) and (p.Berserk >= gTime) and (gFlash = 2) then
1321 begin
1322 r_Draw_FillRect(x, y, x + w, y + h, 255, 0, 0, 55);
1323 end;
1324 end;
1325 end;
1326
1327 procedure r_Map_DrawIndicator (p: TPlayer; color: TRGB; cx, cy, cw, ch: Integer);
1328 var a, ax, ay, fx, fy, xx, yy: Integer;
1329 begin
1330 if (p <> nil) and p.Alive and (p.Spectator = false) then
1331 begin
1332 r_Common_GetPlayerPos(p, fx, fy);
1333 case gPlayerIndicatorStyle of
1334 0:
1335 if IndicatorTexture <> nil then
1336 begin
1337 ax := IndicatorTexture.width div 2;
1338 ay := IndicatorTexture.height div 2;
1339 if (p.obj.x + p.obj.rect.x) < cx then
1340 begin
1341 a := 90;
1342 xx := fx + p.obj.rect.x + p.obj.rect.width;
1343 yy := fy + p.obj.rect.y + (p.obj.rect.height - IndicatorTexture.width) div 2;
1344 end
1345 else if (p.obj.x + p.obj.rect.x + p.obj.rect.width) > (cx + cw) then
1346 begin
1347 a := 270;
1348 xx := fx + p.obj.rect.x - IndicatorTexture.height;
1349 yy := fy + p.obj.rect.y - (p.obj.rect.height - IndicatorTexture.width) div 2;
1350 end
1351 else if (p.obj.y - IndicatorTexture.height) < cy then
1352 begin
1353 a := 180;
1354 xx := fx + p.obj.rect.x + (p.obj.rect.width - IndicatorTexture.width) div 2;
1355 yy := fy + p.obj.rect.y + p.obj.rect.height;
1356 end
1357 else
1358 begin
1359 a := 0;
1360 xx := fx + p.obj.rect.x + (p.obj.rect.width - IndicatorTexture.width) div 2;
1361 yy := fy - IndicatorTexture.height;
1362 end;
1363 xx := MIN(MAX(xx, cx), cx + cw - IndicatorTexture.width);
1364 yy := MIN(MAX(yy, cy), cy + ch - IndicatorTexture.height);
1365 r_Draw_TextureRepeatRotate(IndicatorTexture, xx, yy, IndicatorTexture.width, IndicatorTexture.height, false, color.r, color.g, color.b, 255, false, ax, ay, a);
1366 end;
1367 1:
1368 begin
1369 xx := fx + p.obj.rect.x + p.obj.rect.width div 2;
1370 yy := fy;
1371 r_Common_DrawText(p.Name, xx, yy, color.r, color.g, color.b, 255, stdfont, TBasePoint.BP_DOWN);
1372 end;
1373 end;
1374 end;
1375 end;
1376
1377 procedure r_Map_DrawPlayerIndicators (player: TPlayer; cx, cy, cw, ch: Integer);
1378 var i: Integer; p: TPlayer;
1379 begin
1380 case gPlayerIndicator of
1381 1:
1382 if player <> nil then
1383 begin
1384 r_Map_DrawIndicator(player, _RGB(255, 255, 255), cx, cy, cw, ch);
1385 end;
1386 2:
1387 if gPlayers <> nil then
1388 begin
1389 for i := 0 to HIGH(gPlayers) do
1390 begin
1391 p := gPlayers[i];
1392 if p <> nil then
1393 begin
1394 if (player <> nil) and (p = player) then
1395 begin
1396 r_Map_DrawIndicator(p, _RGB(255, 255, 255), cx, cy, cw, ch);
1397 end
1398 else if (player = nil) or ((p.Team = player.Team) and (p.Team <> TEAM_NONE)) then
1399 begin
1400 case gPlayerIndicatorStyle of
1401 0: r_Map_DrawIndicator(p, p.GetColor(), cx, cy, cw, ch);
1402 1: r_Map_DrawIndicator(p, _RGB(192, 192, 192), cx, cy, cw, ch);
1403 end;
1404 end;
1405 end;
1406 end;
1407 end;
1408 end;
1409 end;
1410
1411 procedure r_Map_DrawGame (xx, yy, ww, hh: Integer; player: TPlayer);
1412 (* xx/yy/ww/hh are in map units *)
1413 var iter: TPanelGrid.Iter; p: PPanel;
1414 begin
1415 plist.Clear;
1416 iter := mapGrid.ForEachInAABB(xx, yy, ww, hh, GridDrawableMask);
1417 for p in iter do
1418 if ((p^.tag and GridTagDoor) <> 0) = p^.door then
1419 plist.Insert(p^);
1420 iter.Release;
1421
1422 r_Map_DrawPanelType(PANEL_BACK);
1423 r_Map_DrawPanelType(PANEL_STEP);
1424 r_Map_DrawItems(xx, yy, ww, hh, false);
1425 r_Map_DrawShots(xx, yy, ww, hh);
1426 {$IFDEF ENABLE_SHELLS}
1427 r_Map_DrawShells(xx, yy, ww, hh);
1428 {$ENDIF}
1429 r_Map_DrawPlayers(xx, yy, ww, hh, player);
1430 {$IFDEF ENABLE_GIBS}
1431 r_Map_DrawGibs(xx, yy, ww, hh);
1432 {$ENDIF}
1433 {$IFDEF ENABLE_CORPSES}
1434 r_Map_DrawCorpses(xx, yy, ww, hh);
1435 {$ENDIF}
1436 r_Map_DrawPanelType(PANEL_WALL);
1437 r_Map_DrawMonsters(xx, yy, ww, hh);
1438 r_Map_DrawItems(xx, yy, ww, hh, true);
1439 r_Map_DrawPanelType(PANEL_CLOSEDOOR);
1440 {$IFDEF ENABLE_GFX}
1441 r_Map_DrawParticles(xx, yy, ww, hh);
1442 r_Map_DrawGFX(xx, yy, ww, hh);
1443 {$ENDIF}
1444 r_Map_DrawFlags(xx, yy, ww, hh);
1445 r_Map_DrawPanelType(PANEL_ACID1);
1446 r_Map_DrawPanelType(PANEL_ACID2);
1447 r_Map_DrawPanelType(PANEL_WATER);
1448 r_Map_DrawPanelType(PANEL_FORE);
1449 // TODO draw monsters health bar
1450 // TODO draw players health bar
1451 end;
1452
1453 procedure r_Map_DrawScaled (w, h, camx, camy: Integer; player: TPlayer; out acx, acy, acw, ach, axx, ayy, aww, ahh: Integer);
1454 (* w/h/camx/camy are in map units (scaled) *)
1455 const limit = 32767;
1456 var cx, cy, cw, ch, xx, yy, ww, hh{, ml, mt, mr, mb}: Integer; sx, sy, sw, sh: LongInt;
1457 begin
1458 (* camera rect *)
1459 cx := camx - w div 2;
1460 cy := camy - h div 2;
1461 cw := w;
1462 ch := h;
1463
1464 (* camera bounds *)
1465 if g_dbg_ignore_bounds = false then
1466 begin
1467 if w > gMapInfo.Width then
1468 cx := gMapInfo.Width div 2 - w div 2
1469 else if cx + cw > gMapInfo.Width then
1470 cx := gMapInfo.Width - cw
1471 else if cx < 0 then
1472 cx := 0;
1473
1474 if h > gMapInfo.Height then
1475 cy := gMapInfo.Height div 2 - h div 2
1476 else if cy + ch > gMapInfo.Height then
1477 cy := gMapInfo.Height - ch
1478 else if cy < 0 then
1479 cy := 0;
1480 end;
1481
1482 acx := cx;
1483 acy := cy;
1484 acw := cw;
1485 ach := ch;
1486
1487 (* map bounds *)
1488 xx := cx;
1489 yy := cy;
1490 ww := cw;
1491 hh := ch;
1492 if xx + ww > gMapInfo.Width then
1493 xx := gMapInfo.Width - ww;
1494 if yy + hh > gMapInfo.Height then
1495 yy := gMapInfo.Height - hh;
1496 if xx < 0 then
1497 xx := 0;
1498 if yy < 0 then
1499 yy := 0;
1500 axx := xx;
1501 ayy := yy;
1502 aww := ww;
1503 ahh := hh;
1504
1505 {
1506 (* view bounds *)
1507 ml := x; mt := y; mr := x + w; mb := y + h;
1508 if FillOutsizeArea and (DebugCameraScale = 1.0) then
1509 begin
1510 ml := MAX(cx + ml, 0) - cx;
1511 mt := MAX(cy + mt, 0) - cy;
1512 mr := MIN(cx + mr, gMapInfo.Width - 1) - cx;
1513 mb := MIN(cy + mb, gMapInfo.Height - 1) - cy;
1514 end;
1515 r_Draw_SetRect(ml, mt, mr, mb);
1516 }
1517
1518 if DebugCameraScale <> 1.0 then
1519 begin
1520 glTranslatef(cw div 2, ch div 2, 0);
1521 glScalef(DebugCameraScale, DebugCameraScale, 1);
1522 glTranslatef(-w div 2, -h div 2, 0);
1523 end;
1524
1525 if SkyTexture <> nil then
1526 begin
1527 r_Map_CalcSkyParallax(cx, cy, w, h, SkyTexture.width, SkyTexture.height, gMapInfo.Width, gMapInfo.Height, sx, sy, sw, sh);
1528 r_Draw_Texture(SkyTexture, sx, sy, sw, sh, false, 255, 255, 255, 255, false);
1529 end;
1530
1531 glTranslatef(-cx, -cy, 0);
1532 r_Map_DrawGame(xx, yy, ww, hh, player);
1533 if FillOutsizeArea and (DebugCameraScale = 1.0) then
1534 begin
1535 (* top *) r_Draw_FillRect(0 - limit, 0 - limit, gMapInfo.Width + limit, 0, 0, 0, 0, 255);
1536 (* left *) r_Draw_FillRect(0 - limit, 0, 0, gMapInfo.Height + limit, 0, 0, 0, 255);
1537 (* right *) r_Draw_FillRect(gMapInfo.Width, 0, gMapInfo.Width + limit, gMapInfo.Height + limit, 0, 0, 0, 255);
1538 (* bottom *) r_Draw_FillRect(0 - limit, gMapInfo.Height, gMapInfo.Width + limit, gMapInfo.Height + limit, 0, 0, 0, 255);
1539 end;
1540 glTranslatef(cx, cy, 0);
1541 end;
1542
1543 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer; player: TPlayer; out acx, acy: Integer);
1544 var cx, cy, cw, ch, xx, yy, ww, hh, ml, mt, mr, mb, mcx, mcy: Integer; l, t, r, b: Integer;
1545 begin
1546 glPushMatrix;
1547 r_Draw_GetRect(l, t, r, b);
1548 glTranslatef(x, y, 0);
1549 glScalef(g_dbg_scale, g_dbg_scale, 0);
1550
1551 r_Draw_SetRect(x, y, x + w, y + h);
1552 r_Map_DrawScaled(Round(w / g_dbg_scale), Round(h / g_dbg_scale), camx, camy, player, cx, cy, cw, ch, xx, yy, ww, hh);
1553 acx := cx;
1554 acy := cy;
1555 r_Draw_SetRect(x, y, x + w, y + h);
1556
1557 if DebugCameraScale <> 1.0 then
1558 begin
1559 r_Draw_Rect(0, 0, cw, ch, 0, 255, 0, 255);
1560 r_Draw_Rect(-cx + xx, -cy + yy, -cx + xx + ww, -cy + yy + hh, 255, 0, 0, 255);
1561 end;
1562
1563 if gGameSettings.GameMode <> GM_SINGLE then
1564 begin
1565 glTranslatef(-cx, -cy, 0);
1566 r_Map_DrawPlayerIndicators(player, cx, cy, cw, ch);
1567 end;
1568
1569 // TODO draw g_debug_player
1570
1571 //glTranslatef(-x, -y, 0);
1572 r_Draw_SetRect(l, t, r, b);
1573 glPopMatrix;
1574
1575 r_Map_DrawScreenEffects(x, y, w, h, player);
1576 end;
1577
1578 procedure r_Map_Update;
1579 var i, count, tick: LongInt;
1580 begin
1581 tick := gTime div GAME_TICK;
1582 for i := 0 to ITEM_LAST do
1583 g_Anim_GetFrameByTime(ItemAnim[i].anim, tick, count, Items[i].frame);
1584 r_Map_UpdateGFX(tick);
1585 g_Anim_GetFrameByTime(FlagAnim, tick, count, FlagFrame);
1586 end;
1587
1588 initialization
1589 conRegVar('r_debug_camera_scale', @DebugCameraScale, 0.0001, 1000.0, '', '');
1590 conRegVar('r_gl_fill_outside', @FillOutsizeArea, '', '');
1591 DebugCameraScale := 1.0;
1592 FillOutsizeArea := true;
1593 end.
[MIRROR] a port of Doom 2D Forever to FPC/SDL
[25/02/2024 19:55:35]
DEADSOFTWARE 2012-2024