DEADSOFTWARE

GIT / REPO / FRED-BOY
Projects / d2df-sdl.git / blob


36bb85fce93a77a36c9fb4f3b0d989d0cfb02260
[d2df-sdl.git] / src / game / renders / opengl / r_map.pas
1 (* Copyright (C) Doom 2D: Forever Developers
2 *
3 * This program is free software: you can redistribute it and/or modify
4 * it under the terms of the GNU General Public License as published by
5 * the Free Software Foundation, version 3 of the License ONLY.
6 *
7 * This program is distributed in the hope that it will be useful,
8 * but WITHOUT ANY WARRANTY; without even the implied warranty of
9 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
10 * GNU General Public License for more details.
11 *
12 * You should have received a copy of the GNU General Public License
13 * along with this program. If not, see <http://www.gnu.org/licenses/>.
14 *)
15 {$INCLUDE ../../../shared/a_modes.inc}
16 unit r_map;
17
18 interface
19
20 uses g_base, g_player, g_playermodel; // TRectWH, TPlayer, TPlayerModel
21
22 procedure r_Map_Initialize;
23 procedure r_Map_Finalize;
24
25 procedure r_Map_Load;
26 procedure r_Map_Free;
27
28 procedure r_Map_LoadTextures;
29 procedure r_Map_FreeTextures;
30
31 {$IFDEF ENABLE_GFX}
32 procedure r_Map_NewGFX (typ, x, y: Integer);
33 {$ENDIF}
34 {$IFDEF ENABLE_GIBS}
35 function r_Map_GetGibSize (m, i: Integer): TRectWH;
36 {$ENDIF}
37 {$IFDEF ENABLE_MENU}
38 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer; alpha: Byte);
39 {$ENDIF}
40
41 procedure r_Map_Update;
42
43 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer; player: TPlayer);
44
45 implementation
46
47 uses
48 Math, SysUtils,
49 {$IFDEF USE_GLES1}
50 GLES11,
51 {$ELSE}
52 GL, GLEXT,
53 {$ENDIF}
54 e_log,
55 binheap, MAPDEF, utils,
56 g_options, g_animations, g_basic, g_phys,
57 g_game, g_map, g_panel, g_items, g_monsters, g_weapons,
58 g_console,
59 {$IFDEF ENABLE_CORPSES}
60 g_corpses,
61 {$ENDIF}
62 {$IFDEF ENABLE_SHELLS}
63 g_shells,
64 {$ENDIF}
65 {$IFDEF ENABLE_GIBS}
66 g_gibs,
67 {$ENDIF}
68 {$IFDEF ENABLE_GFX}
69 g_gfx,
70 {$ENDIF}
71 r_textures, r_draw, r_common
72 ;
73
74 const
75 MTABLE: array [0..MONSTER_MAN] of record
76 w, h: Integer;
77 end = (
78 (w: 64; h: 64), // NONE
79 (w: 64; h: 64), // DEMON
80 (w: 64; h: 64), // IMP
81 (w: 64; h: 64), // ZOMBY
82 (w: 64; h: 64), // SERG
83 (w: 128; h: 128), // CYBER
84 (w: 64; h: 64), // CGUN
85 (w: 128; h: 128), // BARON
86 (w: 128; h: 128), // KNIGHT
87 (w: 128; h: 128), // CACO
88 (w: 64; h: 64), // SOUL (DIE is 128x128, see load code)
89 (w: 128; h: 128), // PAIN
90 (w: 256; h: 128), // SPIDER
91 (w: 128; h: 64), // BSP
92 (w: 128; h: 128), // MANCUB
93 (w: 128; h: 128), // SKEL
94 (w: 128; h: 128), // VILE
95 (w: 32; h: 32), // FISH
96 (w: 64; h: 64), // BARREL
97 (w: 128; h: 128), // ROBO
98 (w: 64; h: 64) // MAN
99 );
100 VILEFIRE_DX = 32;
101 VILEFIRE_DY = 128;
102
103 ItemAnim: array [0..ITEM_LAST] of record
104 name: AnsiString;
105 w, h: Integer;
106 anim: TAnimInfo;
107 end = (
108 (name: 'NOTEXTURE'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
109 (name: 'MED1'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
110 (name: 'MED2'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
111 (name: 'BMED'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
112 (name: 'ARMORGREEN'; w: 32; h: 16; anim: (loop: true; delay: 20; frames: 3; back: true)),
113 (name: 'ARMORBLUE'; w: 32; h: 16; anim: (loop: true; delay: 20; frames: 3; back: true)),
114 (name: 'SBLUE'; w: 32; h: 32; anim: (loop: true; delay: 15; frames: 4; back: true)),
115 (name: 'SWHITE'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
116 (name: 'SUIT'; w: 32; h: 64; anim: (loop: true; delay: 1; frames: 1; back: false)),
117 (name: 'OXYGEN'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
118 (name: 'INVUL'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
119 (name: 'SAW'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
120 (name: 'SHOTGUN1'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
121 (name: 'SHOTGUN2'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
122 (name: 'MGUN'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
123 (name: 'RLAUNCHER'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
124 (name: 'PGUN'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
125 (name: 'BFG'; w: 64; h: 64; anim: (loop: true; delay: 1; frames: 1; back: false)),
126 (name: 'SPULEMET'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
127 (name: 'CLIP'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
128 (name: 'AMMO'; w: 32; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
129 (name: 'SHELL1'; w: 16; h: 8; anim: (loop: true; delay: 1; frames: 1; back: false)),
130 (name: 'SHELL2'; w: 32; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
131 (name: 'ROCKET'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
132 (name: 'ROCKETS'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
133 (name: 'CELL'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
134 (name: 'CELL2'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
135 (name: 'BPACK'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
136 (name: 'KEYR'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
137 (name: 'KEYG'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
138 (name: 'KEYB'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
139 (name: 'KASTET'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
140 (name: 'PISTOL'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
141 (name: 'BOTTLE'; w: 16; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
142 (name: 'HELMET'; w: 16; h: 16; anim: (loop: true; delay: 20; frames: 4; back: true)),
143 (name: 'JETPACK'; w: 32; h: 32; anim: (loop: true; delay: 15; frames: 3; back: true)),
144 (name: 'INVIS'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
145 (name: 'FLAMETHROWER'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
146 (name: 'FUELCAN'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false))
147 );
148
149 {$IFDEF ENABLE_GFX}
150 GFXAnim: array [0..R_GFX_LAST] of record
151 name: AnsiString;
152 w, h: Integer;
153 anim: TAnimInfo;
154 rdelay: Integer;
155 alpha: Integer;
156 end = (
157 (name: ''; w: 0; h: 0; anim: (loop: false; delay: 0; frames: 0; back: false); rdelay: 0; alpha: 0),
158 (name: 'TELEPORT'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 10; back: false); rdelay: 0; alpha: 0),
159 (name: 'FLAME'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 11; back: false); rdelay: 0; alpha: 0),
160 (name: 'EROCKET'; w: 128; h: 128; anim: (loop: false; delay: 6; frames: 6; back: false); rdelay: 0; alpha: 0),
161 (name: 'EBFG'; w: 128; h: 128; anim: (loop: false; delay: 6; frames: 6; back: false); rdelay: 0; alpha: 0),
162 (name: 'BFGHIT'; w: 64; h: 64; anim: (loop: false; delay: 4; frames: 4; back: false); rdelay: 0; alpha: 0),
163 (name: 'FIRE'; w: 64; h: 128; anim: (loop: false; delay: 4; frames: 8; back: false); rdelay: 2; alpha: 0),
164 (name: 'ITEMRESPAWN'; w: 32; h: 32; anim: (loop: false; delay: 4; frames: 5; back: true); rdelay: 0; alpha: 0),
165 (name: 'SMOKE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 0),
166 (name: 'ESKELFIRE'; w: 64; h: 64; anim: (loop: false; delay: 8; frames: 3; back: false); rdelay: 0; alpha: 0),
167 (name: 'EPLASMA'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 4; back: true); rdelay: 0; alpha: 0),
168 (name: 'EBSPFIRE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 5; back: false); rdelay: 0; alpha: 0),
169 (name: 'EIMPFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
170 (name: 'ECACOFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
171 (name: 'EBARONFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
172 (name: 'TELEPORT'; w: 64; h: 64; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 0), // fast
173 (name: 'SMOKE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 150), // transparent
174 (name: 'FLAME'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 11; back: false); rdelay: 2; alpha: 0) // random
175 );
176 {$ENDIF}
177
178 ShotAnim: array [0..WEAPON_LAST] of record
179 name: AnsiString;
180 w, h: Integer;
181 anim: TAnimInfo;
182 end = (
183 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 0 KASTET
184 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 1 SAW
185 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 2 PISTOL
186 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 3 SHOTGUN1
187 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 4 SHOTGUN2
188 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 5 CHAINGUN
189 (name: 'BROCKET'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)), // 6 ROCKETLAUNCHER
190 (name: 'BPLASMA'; w: 16; h: 16; anim: (loop: true; delay: 5; frames: 2; back: false)), // 7 PLASMA
191 (name: 'BBFG'; w: 64; h: 64; anim: (loop: true; delay: 6; frames: 2; back: false)), // 8 BFG
192 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 9 SUPERPULEMET
193 (name: 'FLAME'; w: 32; h: 32; anim: (loop: true; delay: 6; frames: 0{11}; back: false)), // 10 FLAMETHROWER
194 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 11
195 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 12
196 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 13
197 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 14
198 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 15
199 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 16
200 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 17
201 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 18
202 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 19
203 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 20 ZOMPY_PISTOL
204 (name: 'BIMPFIRE'; w: 16; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 21 IMP_FIRE
205 (name: 'BBSPFIRE'; w: 16; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 22 BSP_FIRE
206 (name: 'BCACOFIRE'; w: 16; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 23 CACO_FIRE
207 (name: 'BBARONFIRE'; w: 64; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 24 BARON_FIRE
208 (name: 'BMANCUBFIRE'; w: 64; h: 32; anim: (loop: true; delay: 4; frames: 2; back: false)), // 25 MANCUB_FIRE
209 (name: 'BSKELFIRE'; w: 64; h: 64; anim: (loop: true; delay: 5; frames: 2; back: false)) // 26 SKEL_FIRE
210 );
211
212 {$IFDEF ENABLE_SHELLS}
213 ShellAnim: array [0..SHELL_LAST] of record
214 name: AnsiString;
215 dx, dy: Integer;
216 end = (
217 (name: 'EBULLET'; dx: 2; dy: 1), // 0 SHELL_BULLET
218 (name: 'ESHELL'; dx: 4; dy: 2), // 1 SHELL_SHELL
219 (name: 'ESHELL'; dx: 4; dy: 2) // 2 SHELL_DBLSHELL
220 );
221 {$ENDIF}
222
223 PunchAnim: TAnimInfo = (loop: false; delay: 1; frames: 4; back: false);
224 FlagAnim: TAnimInfo = (loop: true; delay: 8; frames: 5; back: false);
225 VileFireAnim: TAnimInfo = (loop: true; delay: 2; frames: 8; back: false);
226
227 type
228 TBinHeapPanelDrawCmp = class
229 public
230 class function less (const a, b: TPanel): Boolean; inline;
231 end;
232
233 TBinHeapPanelDraw = specialize TBinaryHeapBase<TPanel, TBinHeapPanelDrawCmp>;
234
235 TMonsterAnims = array [0..ANIM_LAST, TDirection] of TGLMultiTexture;
236
237 var
238 DebugCameraScale: Single;
239 SkyTexture: TGLTexture;
240 RenTextures: array of record
241 spec: LongInt;
242 tex: TGLMultiTexture;
243 anim: TAnimInfo;
244 end;
245 Items: array [0..ITEM_LAST] of record
246 tex: TGLMultiTexture;
247 frame: Integer;
248 end;
249 MonTextures: array [0..MONSTER_MAN] of TMonsterAnims;
250 WeapTextures: array [0..WP_LAST, 0..W_POS_LAST, 0..W_ACT_LAST] of TGLTexture;
251 ShotTextures: array [0..WEAPON_LAST] of TGLMultiTexture;
252 FlagTextures: array [0..FLAG_LAST] of TGLMultiTexture;
253 PunchTextures: array [Boolean, 0..2] of TGLMultiTexture; // [berserk, center/up/down]
254 VileFire: TGLMultiTexture;
255 InvulPenta: TGLTexture;
256 IndicatorTexture: TGLTexture;
257 TalkTexture: TGLTexture;
258 Models: array of record
259 anim: array [TDirection, 0..A_LAST] of record
260 base, mask: TGLMultiTexture;
261 end;
262 {$IFDEF ENABLE_GIBS}
263 gibs: record
264 base, mask: TGLTextureArray;
265 rect: TRectArray;
266 end;
267 {$ENDIF}
268 end;
269
270 {$IFDEF ENABLE_SHELLS}
271 ShellTextures: array [0..SHELL_LAST] of TGLTexture;
272 {$ENDIF}
273 {$IFDEF ENABLE_GFX}
274 GFXTextures: array [0..R_GFX_LAST] of TGLMultiTexture;
275 gfxlist: array of record
276 typ: Byte;
277 x, y: Integer;
278 oldX, oldY: Integer;
279 anim: TAnimInfo;
280 time: LongWord;
281 frame: LongInt;
282 end = nil;
283 {$ENDIF}
284
285 FlagFrame: LongInt;
286 plist: TBinHeapPanelDraw = nil;
287
288 class function TBinHeapPanelDrawCmp.less (const a, b: TPanel): Boolean; inline;
289 begin
290 if a.tag < b.tag then begin result := true; exit; end;
291 if a.tag > b.tag then begin result := false; exit; end;
292 result := a.arrIdx < b.arrIdx;
293 end;
294
295 procedure r_Map_Initialize;
296 begin
297 FlagFrame := 0;
298 plist := TBinHeapPanelDraw.Create();
299 end;
300
301 procedure r_Map_Finalize;
302 begin
303 plist.Free;
304 FlagFrame := 0;
305 end;
306
307 procedure r_Map_FreeModel (i: Integer);
308 var a: Integer; d: TDirection;
309 begin
310 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
311 begin
312 for a := A_STAND to A_LAST do
313 begin
314 if Models[i].anim[d, a].base <> nil then
315 Models[i].anim[d, a].base.Free;
316 if Models[i].anim[d, a].mask <> nil then
317 Models[i].anim[d, a].mask.Free;
318 Models[i].anim[d, a].base := nil;
319 Models[i].anim[d, a].mask := nil;
320 end;
321 end;
322 {$IFDEF ENABLE_GIBS}
323 if Models[i].gibs.base <> nil then
324 for a := 0 to High(Models[i].gibs.base) do
325 Models[i].gibs.base[a].Free;
326 if Models[i].gibs.mask <> nil then
327 for a := 0 to High(Models[i].gibs.mask) do
328 Models[i].gibs.mask[a].Free;
329 Models[i].gibs.base := nil;
330 Models[i].gibs.mask := nil;
331 Models[i].gibs.rect := nil;
332 {$ENDIF}
333 end;
334
335 procedure r_Map_LoadModel (i: Integer);
336 var prefix: AnsiString; a: Integer; d: TDirection; m: ^TPlayerModelInfo;
337 begin
338 ASSERT(i < Length(Models));
339 ASSERT(i < Length(PlayerModelsArray));
340 r_Map_FreeModel(i);
341 m := @PlayerModelsArray[i];
342 prefix := m.FileName + ':TEXTURES/';
343 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
344 begin
345 for a := A_STAND to A_LAST do
346 begin
347 Models[i].anim[d, a].base := nil;
348 Models[i].anim[d, a].mask := nil;
349 if m.anim[d, a].resource <> '' then
350 Models[i].anim[d, a].base := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].resource, 64, 64, m.anim[d, a].frames, true);
351 if m.anim[d, a].mask <> '' then
352 Models[i].anim[d, a].mask := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].mask, 64, 64, m.anim[d, a].frames, true);
353 end
354 end;
355 {$IFDEF ENABLE_GIBS}
356 Models[i].gibs.base := nil;
357 Models[i].gibs.mask := nil;
358 Models[i].gibs.rect := nil;
359 if m.GibsCount > 0 then
360 begin
361 SetLength(Models[i].gibs.base, m.GibsCount);
362 SetLength(Models[i].gibs.mask, m.GibsCount);
363 SetLength(Models[i].gibs.rect, m.GibsCount);
364 for a := 0 to m.GibsCount - 1 do
365 Models[i].gibs.rect[a] := DefaultGibSize;
366 if r_Textures_LoadStreamFromFile(prefix + m.GibsResource, 32, 32, m.GibsCount, m.GibsCount, Models[i].gibs.base, Models[i].gibs.rect) then
367 begin
368 if r_Textures_LoadStreamFromFile(prefix + m.GibsMask, 32, 32, m.GibsCount, m.GibsCount, Models[i].gibs.mask, nil) then
369 begin
370 // ok
371 end;
372 end;
373 end;
374 {$ENDIF}
375 end;
376
377 procedure r_Map_LoadMonsterAnim (m, a: Integer; d: TDirection);
378 const dir: array [TDirection] of AnsiString = ('_L', '');
379 var w, h, count: Integer;
380 begin
381 count := MONSTER_ANIMTABLE[m].AnimCount[a];
382 if count > 0 then
383 begin
384 w := MTABLE[m].w;
385 h := MTABLE[m].h;
386 if (m = MONSTER_SOUL) and (a = ANIM_DIE) then
387 begin
388 // special case
389 w := 128;
390 h := 128;
391 end;
392 MonTextures[m, a, d] := r_Textures_LoadMultiFromFileAndInfo(
393 GameWAD + ':MTEXTURES/' + MONSTERTABLE[m].name + '_' + ANIMTABLE[a].name + dir[d],
394 w,
395 h,
396 count,
397 False
398 );
399 end
400 else
401 MonTextures[m, a, d] := nil;
402 end;
403
404 procedure r_Map_Load;
405 const
406 WeapName: array [0..WP_LAST] of AnsiString = ('', 'CSAW', 'HGUN', 'SG', 'SSG', 'MGUN', 'RKT', 'PLZ', 'BFG', 'SPL', 'FLM');
407 WeapPos: array [0..W_POS_LAST] of AnsiString = ('', '_UP', '_DN');
408 WeapAct: array [0..W_ACT_LAST] of AnsiString = ('', '_FIRE');
409 PunchName: array [Boolean] of AnsiString = ('PUNCH', 'PUNCHB');
410 var
411 i, j, k: Integer; d: TDirection; b: Boolean;
412 begin
413 // --------- items --------- //
414 for i := 0 to ITEM_LAST do
415 begin
416 Items[i].tex := r_Textures_LoadMultiFromFileAndInfo(
417 GameWAD + ':TEXTURES/' + ItemAnim[i].name,
418 ItemAnim[i].w,
419 ItemAnim[i].h,
420 ItemAnim[i].anim.frames,
421 false
422 );
423 Items[i].frame := 0;
424 end;
425 // --------- monsters --------- //
426 for i := MONSTER_DEMON to MONSTER_MAN do
427 for j := 0 to ANIM_LAST do
428 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
429 r_Map_LoadMonsterAnim(i, j, d);
430 VileFire := r_Textures_LoadMultiFromFileAndInfo(GameWAD + ':TEXTURES/FIRE', 64, 128, VileFireAnim.frames);
431 // --------- player models --------- //
432 if PlayerModelsArray <> nil then
433 begin
434 SetLength(Models, Length(PlayerModelsArray));
435 for i := 0 to High(PlayerModelsArray) do
436 r_Map_LoadModel(i);
437 end;
438 // --------- player weapons --------- //
439 for i := 1 to WP_LAST do
440 for j := 0 to W_POS_LAST do
441 for k := 0 to W_ACT_LAST do
442 WeapTextures[i, j, k] := r_Textures_LoadFromFile(GameWAD + ':WEAPONS\' + WeapName[i] + WeapPos[j] + WeapAct[k]);
443 // --------- gfx animations --------- //
444 {$IFDEF ENABLE_GFX}
445 for i := 1 to R_GFX_LAST do
446 if GFXAnim[i].anim.frames > 0 then
447 GFXTextures[i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/' + GFXAnim[i].name, GFXAnim[i].w, GFXAnim[i].h, GFXAnim[i].anim.frames);
448 {$ENDIF}
449 // --------- shots --------- //
450 for i := 0 to WEAPON_LAST do
451 if ShotAnim[i].anim.frames > 0 then
452 ShotTextures[i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/' + ShotAnim[i].name, ShotAnim[i].w, ShotAnim[i].h, ShotAnim[i].anim.frames);
453 // --------- flags --------- //
454 FlagTextures[FLAG_NONE] := nil;
455 FlagTextures[FLAG_RED] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGRED', 64, 64, 5);
456 FlagTextures[FLAG_BLUE] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGBLUE', 64, 64, 5);
457 // FlagTextures[FLAG_DOM] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGDOM', 64, 64, 8);
458 // --------- shells --------- //
459 {$IFDEF ENABLE_SHELLS}
460 for i := 0 to SHELL_LAST do
461 ShellTextures[i] := r_Textures_LoadFromFile(GameWad + ':TEXTURES/' + ShellAnim[i].name);
462 {$ENDIF}
463 // --------- punch --------- //
464 for b := false to true do
465 begin
466 for i := 0 to 2 do
467 PunchTextures[b, i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':WEAPONS/' + PunchName[b] + WeapPos[i], 64, 64, PunchAnim.frames);
468 end;
469 // --------- other --------- //
470 InvulPenta := r_Textures_LoadFromFile(GameWad + ':TEXTURES/PENTA');
471 IndicatorTexture := r_Textures_LoadFromFile(GameWad + ':TEXTURES/PLRIND');
472 TalkTexture := r_Textures_LoadFromFile(GameWad + ':TEXTURES/TALKBUBBLE');
473 end;
474
475 procedure r_Map_Free;
476 var i, j, k: Integer; d: TDirection; b: Boolean;
477 begin
478 if TalkTexture <> nil then
479 TalkTexture.Free;
480 if IndicatorTexture <> nil then
481 IndicatorTexture.Free;
482 if InvulPenta <> nil then
483 InvulPenta.Free;
484 InvulPenta := nil;
485 for b := false to true do
486 begin
487 for i := 0 to 2 do
488 begin
489 if PunchTextures[b, i] <> nil then
490 PunchTextures[b, i].Free;
491 PunchTextures[b, i] := nil;
492 end;
493 end;
494 {$IFDEF ENABLE_SHELLS}
495 for i := 0 to SHELL_LAST do
496 begin
497 if ShellTextures[i] <> nil then
498 ShellTextures[i].Free;
499 ShellTextures[i] := nil;
500 end;
501 {$ENDIF}
502 for i := 0 to FLAG_LAST do
503 begin
504 if FlagTextures[i] <> nil then
505 FlagTextures[i].Free;
506 FlagTextures[i] := nil;
507 end;
508 for i := 0 to WEAPON_LAST do
509 begin
510 if ShotTextures[i] <> nil then
511 ShotTextures[i].Free;
512 ShotTextures[i] := nil;
513 end;
514 {$IFDEF ENABLE_GFX}
515 gfxlist := nil;
516 for i := 0 to R_GFX_LAST do
517 begin
518 if GFXTextures[i] <> nil then
519 GFXTextures[i].Free;
520 GFXTextures[i] := nil;
521 end;
522 {$ENDIF}
523 for i := 1 to WP_LAST do
524 begin
525 for j := 0 to W_POS_LAST do
526 begin
527 for k := 0 to W_ACT_LAST do
528 begin
529 if WeapTextures[i, j, k] <> nil then
530 WeapTextures[i, j, k].Free;
531 WeapTextures[i, j, k] := nil;
532 end;
533 end;
534 end;
535 if Models <> nil then
536 for i := 0 to High(Models) do
537 r_Map_FreeModel(i);
538 for i := MONSTER_DEMON to MONSTER_MAN do
539 begin
540 for j := 0 to ANIM_LAST do
541 begin
542 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
543 begin
544 if MonTextures[i, j, d] <> nil then
545 MonTextures[i, j, d].Free;
546 MonTextures[i, j, d] := nil;
547 end;
548 end;
549 end;
550 for i := 0 to ITEM_LAST do
551 begin
552 if Items[i].tex <> nil then
553 Items[i].tex.Free;
554 Items[i].tex := nil;
555 end;
556 end;
557
558 procedure r_Map_LoadTextures;
559 const DefaultAnimInfo: TAnimInfo = (loop: true; delay: 1; frames: 1; back: false);
560 var i, n: Integer; txt: TAnimTextInfo;
561 begin
562 if Textures <> nil then
563 begin
564 n := Length(Textures);
565 SetLength(RenTextures, n);
566 for i := 0 to n - 1 do
567 begin
568 txt.anim := DefaultAnimInfo;
569 RenTextures[i].tex := nil;
570 case Textures[i].TextureName of
571 TEXTURE_NAME_WATER: RenTextures[i].spec := TEXTURE_SPECIAL_WATER;
572 TEXTURE_NAME_ACID1: RenTextures[i].spec := TEXTURE_SPECIAL_ACID1;
573 TEXTURE_NAME_ACID2: RenTextures[i].spec := TEXTURE_SPECIAL_ACID2;
574 else
575 RenTextures[i].spec := 0;
576 e_LogWritefln('r_Map_LoadTextures: begin load texture: %s', [Textures[i].FullName]);
577 RenTextures[i].tex := r_Textures_LoadMultiTextFromFile(Textures[i].FullName, txt);
578 e_LogWritefln('r_Map_LoadTextures: end load texture: %s', [Textures[i].FullName]);
579 if RenTextures[i].tex = nil then
580 e_LogWritefln('r_Map_LoadTextures: failed to load texture: %s', [Textures[i].FullName]);
581 end;
582 RenTextures[i].anim := txt.anim;
583 end;
584 end;
585 if gMapInfo.SkyFullName <> '' then
586 SkyTexture := r_Textures_LoadFromFile(gMapInfo.SkyFullName);
587 plist.Clear;
588 end;
589
590 procedure r_Map_FreeTextures;
591 var i: Integer;
592 begin
593 plist.Clear;
594 if SkyTexture <> nil then
595 SkyTexture.Free;
596 SkyTexture := nil;
597 if RenTextures <> nil then
598 for i := 0 to High(RenTextures) do
599 if RenTextures[i].tex <> nil then
600 RenTextures[i].tex.Free;
601 RenTextures := nil;
602 end;
603
604 procedure r_Map_DrawPanel (p: TPanel);
605 var Texture: Integer; t: TGLMultiTexture; tex: TGLTexture; count, frame: LongInt; a: TAnimInfo;
606 begin
607 ASSERT(p <> nil);
608 if p.FCurTexture >= 0 then
609 begin
610 Texture := p.TextureIDs[p.FCurTexture].Texture;
611 t := RenTextures[Texture].tex;
612 if (RenTextures[Texture].spec = 0) or (t <> nil) then
613 begin
614 count := 0; frame := 0;
615 if p.AnimTime <= gTime then
616 begin
617 a := RenTextures[Texture].anim;
618 a.loop := p.AnimLoop;
619 g_Anim_GetFrameByTime(a, (gTime - p.AnimTime) DIV GAME_TICK, count, frame);
620 end;
621 if t <> nil then
622 begin
623 tex := t.GetTexture(frame);
624 r_Draw_TextureRepeat(tex, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending);
625 end
626 else
627 r_Draw_TextureRepeat(nil, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255, false);
628 end;
629
630 if t = nil then
631 begin
632 case RenTextures[Texture].spec of
633 TEXTURE_SPECIAL_WATER: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 0, 255, 255);
634 TEXTURE_SPECIAL_ACID1: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 230, 0, 255);
635 TEXTURE_SPECIAL_ACID2: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 230, 0, 0, 255);
636 end
637 end
638 end
639 end;
640
641 procedure r_Map_DrawPanelType (panelTyp: DWORD);
642 var tagMask, i: Integer; p: TPanel;
643 begin
644 i := 0;
645 tagMask := PanelTypeToTag(panelTyp);
646 while plist.count > 0 do
647 begin
648 p := TPanel(plist.Front());
649 if (p.tag and tagMask) = 0 then
650 break;
651 r_Map_DrawPanel(p);
652 Inc(i);
653 plist.PopFront
654 end;
655 end;
656
657 procedure r_Map_DrawItems (x, y, w, h: Integer; drop: Boolean);
658 var i, fX, fY: Integer; it: PItem; t: TGLMultiTexture; tex: TGLTexture;
659 begin
660 if ggItems <> nil then
661 begin
662 for i := 0 to High(ggItems) do
663 begin
664 it := @ggItems[i];
665 if it.used and it.alive and (it.dropped = drop) and (it.ItemType > ITEM_NONE) and (it.ItemType <= ITEM_LAST) then
666 begin
667 t := Items[it.ItemType].tex;
668 if g_Collide(it.obj.x, it.obj.y, t.width, t.height, x, y, w, h) then
669 begin
670 it.obj.Lerp(gLerpFactor, fX, fY);
671 tex := t.GetTexture(Items[it.ItemType].frame);
672 r_Draw_TextureRepeat(tex, fX, fY, tex.width, tex.height, false, 255, 255, 255, 255, false);
673 end;
674 end;
675 end;
676 end;
677 // TODO draw g_debug_frames
678 end;
679
680 function r_Map_GetMonsterTexture (m, a: Integer; d: TDirection; out t: TGLMultiTexture; out dx, dy: Integer; out flip: Boolean): Boolean;
681 // var c: Integer;
682 begin
683 t := nil; dx := 0; dy := 0; flip := false;
684 result := MonTextures[m, a, d] <> nil;
685 if result = false then
686 begin
687 flip := true;
688 if d = TDirection.D_RIGHT then d := TDirection.D_LEFT else d := TDirection.D_RIGHT;
689 result := MonTextures[m, a, d] <> nil;
690 end;
691 if result = true then
692 begin
693 t := MonTextures[m, a, d];
694 if d = TDirection.D_LEFT then
695 begin
696 dx := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].X;
697 dy := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].Y;
698 end
699 else
700 begin
701 dx := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].X;
702 dy := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].Y;
703 end;
704 if flip then
705 begin
706 // c := (MONSTERTABLE[MonsterType].Rect.X - dx) + MONSTERTABLE[MonsterType].Rect.Width;
707 // dx := MTABLE[m].width - c - MONSTERTABLE[MonsterType].Rect.X;
708 dx := -dx;
709 end;
710 end;
711 end;
712
713 procedure r_Map_DrawMonsterAttack (constref mon: TMonster);
714 var o: TObj; count, frame: LongInt; tex: TGLTexture;
715 begin
716 if VileFire <> nil then
717 if (mon.MonsterType = MONSTER_VILE) and (mon.MonsterState = MONSTATE_SHOOT) then
718 if (mon.VileFireTime <= gTime) and GetPos(mon.MonsterTargetUID, @o) then
719 begin
720 g_Anim_GetFrameByTime(VileFireAnim, (gTime - mon.VileFireTime) DIV GAME_TICK, count, frame);
721 tex := VileFire.GetTexture(frame);
722 r_Draw_TextureRepeat(tex, o.x + o.rect.x + (o.rect.width div 2) - VILEFIRE_DX, o.y + o.rect.y + o.rect.height - VILEFIRE_DY, tex.width, tex.height, False, 255, 255, 255, 255, false);
723 end;
724 end;
725
726 procedure r_Map_DrawMonster (constref mon: TMonster);
727 var m, a, fX, fY, dx, dy: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture;
728 begin
729 m := mon.MonsterType;
730 a := mon.MonsterAnim;
731 d := mon.GameDirection;
732
733 mon.obj.Lerp(gLerpFactor, fX, fY);
734
735 if r_Map_GetMonsterTexture(m, a, d, t, dx, dy, flip) then
736 r_Draw_MultiTextureRepeat(t, mon.DirAnim[a, d], false, fX + dx, fY + dy, t.width, t.height, flip, 255, 255, 255, 255, false);
737
738 // TODO draw g_debug_frames
739 end;
740
741 procedure r_Map_DrawMonsters (x, y, w, h: Integer);
742 var i: Integer; m: TMonster;
743 begin
744 if gMonsters <> nil then
745 begin
746 for i := 0 to High(gMonsters) do
747 begin
748 m := gMonsters[i];
749 if m <> nil then
750 begin
751 r_Map_DrawMonsterAttack(m);
752 // TODO select from grid
753 if g_Collide(m.obj.x + m.obj.rect.x, m.obj.y + m.obj.rect.y, m.obj.rect.width, m.obj.rect.height, x, y, w, h) then
754 r_Map_DrawMonster(m);
755 end;
756 end;
757 end;
758 end;
759
760 function r_Map_GetPlayerModelTex (i: Integer; var a: Integer; var d: TDirection; out flip: Boolean): Boolean;
761 begin
762 flip := false;
763 result := Models[i].anim[d, a].base <> nil;
764 if result = false then
765 begin
766 flip := true;
767 if d = TDirection.D_LEFT then d := TDirection.D_RIGHT else d := TDirection.D_LEFT;
768 result := Models[i].anim[d, a].base <> nil;
769 end;
770 end;
771
772 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer; alpha: Byte);
773 var a, pos, act, xx, yy, angle: Integer; d: TDirection; flip, back: Boolean; t: TGLMultiTexture; tex: TGLTexture; c: TRGB;
774 begin
775 a := pm.CurrentAnimation;
776 d := pm.Direction;
777
778 (* draw flag*)
779 t := FlagTextures[pm.Flag];
780 if (t <> nil) and not (a in [A_DIE1, A_DIE2]) then
781 begin
782 flip := d = TDirection.D_RIGHT;
783 angle := PlayerModelsArray[pm.id].FlagAngle;
784 xx := PlayerModelsArray[pm.id].FlagPoint.X;
785 yy := PlayerModelsArray[pm.id].FlagPoint.Y;
786 tex := t.GetTexture(FlagFrame);
787 r_Draw_TextureRepeatRotate(
788 tex,
789 x + IfThen(flip, 2 * FLAG_BASEPOINT.X - xx + 1, xx - 1) - FLAG_BASEPOINT.X,
790 y + yy - FLAG_BASEPOINT.Y + 1,
791 tex.width,
792 tex.height,
793 flip,
794 255, 255, 255, 255, false,
795 IfThen(flip, 64 - FLAG_BASEPOINT.X, FLAG_BASEPOINT.X),
796 FLAG_BASEPOINT.Y,
797 IfThen(flip, angle, -angle)
798 );
799 end;
800
801 (* draw weapon *)
802 if PlayerModelsArray[pm.id].HaveWeapon and not (a in [A_DIE1, A_DIE2, A_PAIN]) then
803 begin
804 case a of
805 A_SEEUP, A_ATTACKUP: pos := W_POS_UP;
806 A_SEEDOWN, A_ATTACKDOWN: pos := W_POS_DOWN;
807 else pos := W_POS_NORMAL;
808 end;
809 if (a in [A_ATTACK, A_ATTACKUP, A_ATTACKDOWN]) or pm.GetFire() then
810 act := W_ACT_FIRE
811 else
812 act := W_ACT_NORMAL;
813 tex := WeapTextures[pm.CurrentWeapon, pos, act];
814 if tex <> nil then
815 begin
816 xx := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].X;
817 yy := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].Y;
818 r_Draw_Texture(
819 tex,
820 x + xx,
821 y + yy,
822 tex.width,
823 tex.height,
824 d = TDirection.D_LEFT,
825 255, 255, 255, alpha, false
826 );
827 end;
828 end;
829
830 (* draw body *)
831 if r_Map_GetPlayerModelTex(pm.id, a, d, flip) then
832 begin
833 t := Models[pm.id].anim[d, a].base;
834 back := PlayerModelsArray[pm.id].anim[d, a].back;
835 r_Draw_MultiTextureRepeat(t, pm.AnimState, back, x, y, t.width, t.height, flip, 255, 255, 255, alpha, false);
836 t := Models[pm.id].anim[d, a].mask;
837 if t <> nil then
838 begin
839 c := pm.Color;
840 r_Draw_MultiTextureRepeat(t, pm.AnimState, back, x, y, t.width, t.height, flip, c.r, c.g, c.b, alpha, false);
841 end;
842 end;
843 end;
844
845 procedure r_Map_DrawBubble (x, y: Integer; cb, cf: TRGB);
846 var dot: Integer;
847 begin
848 // Outer borders
849 r_Draw_Rect(x + 1, y, x + 18, y + 13, cb.R, cb.G, cb.B, 255);
850 r_Draw_Rect(x, y + 1, x + 19, y + 12, cb.R, cb.G, cb.B, 255);
851 // Inner box
852 r_Draw_FillRect(x + 1, y + 1, x + 18, y + 12, cf.R, cf.G, cf.B, 255);
853 // TODO Tail
854 // Dots
855 dot := 6;
856 r_Draw_FillRect(x + dot + 0, y + 8, x + dot + 0 + 1 + 1, y + 9 + 1, cb.R, cb.G, cb.B, 255);
857 r_Draw_FillRect(x + dot + 3, y + 8, x + dot + 3 + 1 + 1, y + 9 + 1, cb.R, cb.G, cb.B, 255);
858 r_Draw_FillRect(x + dot + 6, y + 8, x + dot + 6 + 1 + 1, y + 9 + 1, cb.R, cb.G, cb.B, 255);
859 end;
860
861 procedure r_Map_DrawTalkBubble (p: TPlayer);
862 var cobj: TObj; fx, fy, x, y: Integer; cb, cf: TRGB;
863 begin
864 {$IFDEF ENABLE_CORPSES}
865 cobj := g_Corpses_GetCameraObj(p);
866 {$ELSE}
867 cobj := p.Obj;
868 {$ENDIF}
869 cobj.Lerp(gLerpFactor, fx, fy);
870 x := fx + p.obj.rect.x + p.obj.rect.width div 2;
871 y := fy;
872 cb := _RGB(63, 63, 63);
873 cf := _RGB(240, 240, 240);
874 case gChatBubble of
875 1: // simple text
876 begin
877 r_Common_DrawText('[...]', x, y, 255, 255, 255, 255, stdfont, TBasePoint.BP_DOWN);
878 end;
879 2: // adv team color
880 begin
881 case p.Team of
882 TEAM_RED: cb := _RGB(255, 63, 63);
883 TEAM_BLUE: cb := _RGB(63, 63, 255);
884 end;
885 r_Map_DrawBubble(x, y - 18, cb, cf);
886 end;
887 3: // adv player color
888 begin
889 cb := p.Model.Color;
890 cf.R := MIN(cb.R * 2 + 64, 255);
891 cf.G := MIN(cb.G * 2 + 64, 255);
892 cf.B := MIN(cb.B * 2 + 64, 255);
893 if (ABS(cf.R - cb.R) < 32) or (ABS(cf.G - cb.G) < 32) or (ABS(cf.B - cb.B) < 32) then
894 begin
895 cb.R := MAX(cf.R div 2 - 16, 0);
896 cb.G := MAX(cf.G div 2 - 16, 0);
897 cb.B := MAX(cf.B div 2 - 16, 0);
898 end;
899 r_Map_DrawBubble(x, y - 18, cb, cf);
900 end;
901 4: // textured
902 if TalkTexture <> nil then
903 begin
904 r_Common_DrawTexture(TalkTexture, x + 5, y, TalkTexture.width, TalkTexture.height, TBasePoint.BP_DOWN);
905 end;
906 end;
907 end;
908
909 procedure r_Map_DrawPlayer (p, drawed: TPlayer);
910 var fX, fY, fSlope, ax, ay, w, h: Integer; b, flip: Boolean; t: TGLMultiTexture; tex: TGLTexture; alpha: Byte; count, frame: LongInt;
911 begin
912 if p.alive then
913 begin
914 fX := p.obj.x; fY := p.obj.y;
915 // TODO fix lerp
916 //p.obj.Lerp(gLerpFactor, fX, fY);
917 fSlope := nlerp(p.SlopeOld, p.obj.slopeUpLeft, gLerpFactor);
918
919 (* punch effect *)
920 if p.PunchTime <= gTime then
921 begin
922 g_Anim_GetFrameByTime(PunchAnim, (gTime - p.PunchTime) DIV GAME_TICK, count, frame);
923 if count < 1 then
924 begin
925 b := R_BERSERK in p.FRulez;
926 if p.FKeys[KEY_DOWN].pressed then
927 t := PunchTextures[b, 2]
928 else if p.FKeys[KEY_UP].pressed then
929 t := PunchTextures[b, 1]
930 else
931 t := PunchTextures[b, 0];
932 if t <> nil then
933 begin
934 flip := p.Direction = TDirection.D_LEFT;
935 ax := IfThen(flip, 15 - p.Obj.Rect.X, p.Obj.Rect.X - 15); // ???
936 ay := p.Obj.Rect.Y - 11;
937 tex := t.GetTexture(frame);
938 r_Draw_TextureRepeat(tex, fx + ax, fy + fSlope + ay, tex.width, tex.height, flip, 255, 255, 255, 255, false)
939 end;
940 end;
941 end;
942
943 (* invulnerability effect *)
944 if (InvulPenta <> nil) and (p.FMegaRulez[MR_INVUL] > gTime) and ((p <> drawed) or (p.SpawnInvul >= gTime)) then
945 begin
946 w := InvulPenta.width;
947 h := InvulPenta.height;
948 ax := p.Obj.Rect.X + (p.Obj.Rect.Width div 2) - (w div 2); // + IfThen(flip, +4, -2) // ???
949 ay := p.Obj.Rect.Y + (p.Obj.Rect.Height div 2) - (h div 2) - 7; // ???
950 r_Draw_Texture(InvulPenta, fx + ax, fy + ay + fSlope, w, h, false, 255, 255, 255, 255, false);
951 end;
952
953 (* invisibility effect *)
954 alpha := 255;
955 if p.FMegaRulez[MR_INVIS] > gTime then
956 begin
957 if (drawed <> nil) and ((p = drawed) or ((p.Team = drawed.Team) and (gGameSettings.GameMode <> GM_DM))) then
958 begin
959 if (p.FMegaRulez[MR_INVIS] - gTime > 2100) or not ODD((p.FMegaRulez[MR_INVIS] - gTime) div 300) then
960 alpha := 55;
961 end
962 else
963 alpha := 1; // ???
964 end;
965
966 r_Map_DrawPlayerModel(p.Model, fX, fY + fSlope, alpha);
967 end;
968 // TODO draw g_debug_frames
969
970 if (gChatBubble > 0) and p.FKeys[KEY_CHAT].Pressed and (p.Ghost = false) then
971 if (p.FMegaRulez[MR_INVIS] <= gTime) or ((drawed <> nil) and ((p = drawed) or (p.Team = drawed.Team) and (gGameSettings.GameMode <> GM_DM))) then
972 r_Map_DrawTalkBubble(p);
973
974 // TODO draw aim
975 end;
976
977 procedure r_Map_DrawPlayers (x, y, w, h: Integer; player: TPlayer);
978 var i: Integer;
979 begin
980 if gPlayers <> nil then
981 for i := 0 to High(gPlayers) do
982 if gPlayers[i] <> nil then
983 r_Map_DrawPlayer(gPlayers[i], player);
984 end;
985
986 {$IFDEF ENABLE_GIBS}
987 function r_Map_GetGibSize (m, i: Integer): TRectWH;
988 begin
989 result := Models[m].gibs.rect[i];
990 end;
991
992 procedure r_Map_DrawGibs (x, y, w, h: Integer);
993 var i, fx, fy, m, id, rx, ry, ra: Integer; p: PObj; t: TGLTexture;
994 begin
995 if gGibs <> nil then
996 begin
997 for i := 0 to High(gGibs) do
998 begin
999 if gGibs[i].alive then
1000 begin
1001 p := @gGibs[i].Obj;
1002 if g_Obj_Collide(x, y, w, h, p) then
1003 begin
1004 p.Lerp(gLerpFactor, fx, fy);
1005 id := gGibs[i].GibID;
1006 m := gGibs[i].ModelID;
1007 t := Models[m].gibs.base[id];
1008 if t <> nil then
1009 begin
1010 rx := p.Rect.X + p.Rect.Width div 2;
1011 ry := p.Rect.Y + p.Rect.Height div 2;
1012 ra := gGibs[i].RAngle;
1013 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, 255, 255, 255, 255, false, rx, ry, ra);
1014 t := Models[m].gibs.mask[id];
1015 if t <> nil then
1016 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, gGibs[i].Color.R, gGibs[i].Color.G, gGibs[i].Color.B, 255, false, rx, ry, ra);
1017 // r_Draw_TextureRepeatRotate(nil, fx + p.Rect.X, fy + p.Rect.Y, p.Rect.Width, p.Rect.Height, false, 255, 255, 255, 255, false, p.Rect.Width div 2, p.Rect.Height div 2, ra);
1018 end;
1019 end;
1020 end;
1021 end;
1022 end;
1023 // TODO draw g_debug_frames
1024 end;
1025 {$ENDIF}
1026
1027 {$IFDEF ENABLE_CORPSES}
1028 procedure r_Map_DrawCorpses (x, y, w, h: Integer);
1029 var i, fX, fY: Integer; p: TCorpse;
1030 begin
1031 if gCorpses <> nil then
1032 begin
1033 for i := 0 to High(gCorpses) do
1034 begin
1035 p := gCorpses[i];
1036 if (p <> nil) and (p.state <> CORPSE_STATE_REMOVEME) and (p.model <> nil) then
1037 begin
1038 p.obj.Lerp(gLerpFactor, fX, fY);
1039 r_Map_DrawPlayerModel(p.model, fX, fY, 255);
1040 end;
1041 end;
1042 end;
1043 // TODO draw g_debug_frames
1044 end;
1045 {$ENDIF}
1046
1047 {$IFDEF ENABLE_GFX}
1048 function r_Map_GetGFXID (): Integer;
1049 var i: Integer;
1050 begin
1051 i := 0;
1052 if gfxlist <> nil then
1053 begin
1054 while (i < Length(gfxlist)) and (gfxlist[i].typ > 0) do
1055 Inc(i);
1056 if i >= Length(gfxlist) then
1057 SetLength(gfxlist, Length(gfxlist) + 1)
1058 end
1059 else
1060 SetLength(gfxlist, 1);
1061 gfxlist[i].typ := R_GFX_NONE;
1062 result := i
1063 end;
1064
1065 procedure r_Map_NewGFX (typ, x, y: Integer);
1066 var i: Integer;
1067 begin
1068 if gpart_dbg_enabled and (typ > 0) and (typ <= R_GFX_LAST) then
1069 begin
1070 i := r_Map_GetGFXID();
1071 if i >= 0 then
1072 begin
1073 gfxlist[i].typ := typ;
1074 gfxlist[i].x := x;
1075 gfxlist[i].y := y;
1076 gfxlist[i].oldX := x;
1077 gfxlist[i].oldY := y;
1078 gfxlist[i].anim := GFXAnim[typ].anim;
1079 gfxlist[i].time := gTime DIV GAME_TICK;
1080 gfxlist[i].frame := 0;
1081 INC(gfxlist[i].anim.delay, Random(GFXAnim[typ].rdelay));
1082 end;
1083 end;
1084 end;
1085
1086 procedure r_Map_UpdateGFX (tick: LongWord);
1087 var i: Integer; count: LongInt;
1088 begin
1089 if gfxlist <> nil then
1090 begin
1091 for i := 0 to High(gfxlist) do
1092 begin
1093 if (gfxlist[i].typ > 0) and (tick >= gfxlist[i].time) then
1094 begin
1095 g_Anim_GetFrameByTime(gfxlist[i].anim, tick - gfxlist[i].time, count, gfxlist[i].frame);
1096 if count < 1 then
1097 begin
1098 gfxlist[i].oldX := gfxlist[i].x;
1099 gfxlist[i].oldY := gfxlist[i].y;
1100 case gfxlist[i].typ of
1101 R_GFX_FLAME, R_GFX_SMOKE:
1102 begin
1103 if Random(3) = 0 then
1104 gfxlist[i].x := gfxlist[i].x - 1 + Random(3);
1105 if Random(2) = 0 then
1106 gfxlist[i].y := gfxlist[i].y - Random(2);
1107 end;
1108 end;
1109 end
1110 else
1111 gfxlist[i].typ := R_GFX_NONE;
1112 end;
1113 end;
1114 end;
1115 end;
1116
1117 procedure r_Map_DrawGFX (x, y, w, h: Integer);
1118 var i, fx, fy, typ: Integer; t: TGLMultiTexture; tex: TGLTexture;
1119 begin
1120 if gfxlist <> nil then
1121 begin
1122 for i := 0 to High(gfxlist) do
1123 begin
1124 if gfxlist[i].typ > 0 then
1125 begin
1126 typ := gfxlist[i].typ;
1127 t := GFXTextures[typ];
1128 if t <> nil then
1129 begin
1130 fx := nlerp(gfxlist[i].oldX, gfxlist[i].x, gLerpFactor);
1131 fy := nlerp(gfxlist[i].oldY, gfxlist[i].y, gLerpFactor);
1132 tex := t.GetTexture(gfxlist[i].frame);
1133 r_Draw_TextureRepeat(tex, fx, fy, tex.width, tex.height, false, 255, 255, 255, 255 - GFXAnim[typ].alpha, false);
1134 end;
1135 end;
1136 end;
1137 end;
1138 end;
1139
1140 procedure r_Map_DrawParticles (x, y, w, h: Integer);
1141 var i, fx, fy: Integer;
1142 begin
1143 if gpart_dbg_enabled and (Particles <> nil) then
1144 begin
1145 glDisable(GL_TEXTURE_2D);
1146 if (g_dbg_scale < 0.6) then
1147 glPointSize(1)
1148 else if (g_dbg_scale > 1.3) then
1149 glPointSize(g_dbg_scale + 1)
1150 else
1151 glPointSize(2);
1152 glDisable(GL_POINT_SMOOTH);
1153 glEnable(GL_BLEND);
1154 glBlendFunc(GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA);
1155
1156 glBegin(GL_POINTS);
1157 for i := 0 to High(Particles) do
1158 begin
1159 if Particles[i].alive then
1160 begin
1161 fx := nlerp(Particles[i].oldX, Particles[i].x, gLerpFactor);
1162 fy := nlerp(Particles[i].oldY, Particles[i].y, gLerpFactor);
1163 glColor4ub(Particles[i].red, Particles[i].green, Particles[i].blue, Particles[i].alpha);
1164 glVertex2f(fx, fy);
1165 end;
1166 end;
1167 glEnd;
1168
1169 glDisable(GL_BLEND);
1170 end;
1171 end;
1172 {$ENDIF}
1173
1174 procedure r_Map_DrawShots (x, y, w, h: Integer);
1175 var i, a, fX, fY, pX, pY, typ: Integer; count, frame: LongInt; t: TGLMultiTexture; tex: TGLTexture;
1176 begin
1177 if Shots <> nil then
1178 begin
1179 for i := 0 to High(Shots) do
1180 begin
1181 typ := Shots[i].ShotType;
1182 if typ <> 0 then
1183 begin
1184 t := ShotTextures[typ];
1185 if t <> nil then
1186 begin
1187 a := 0;
1188 case typ of
1189 WEAPON_ROCKETLAUNCHER, WEAPON_BARON_FIRE, WEAPON_MANCUB_FIRE, WEAPON_SKEL_FIRE:
1190 a := -GetAngle2(Shots[i].Obj.Vel.X, Shots[i].Obj.Vel.Y)
1191 end;
1192 Shots[i].Obj.Lerp(gLerpFactor, fX, fY);
1193 pX := Shots[i].Obj.Rect.Width div 2;
1194 pY := Shots[i].Obj.Rect.Height div 2;
1195 g_Anim_GetFrameByTime(ShotAnim[typ].anim, (gTime - Shots[i].time) DIV GAME_TICK, count, frame);
1196 tex := t.GetTexture(frame);
1197 r_Draw_TextureRepeatRotate(tex, fX, fY, tex.width, tex.height, false, 255, 255, 255, 255, false, pX, pY, a);
1198 end;
1199 end;
1200 end;
1201 end;
1202 // TODO draw g_debug_frames
1203 end;
1204
1205 procedure r_Map_DrawFlags (x, y, w, h: Integer);
1206 var i, dx, fx, fy: Integer; flip: Boolean; t: TGLMultiTexture; tex: TGLTexture;
1207 begin
1208 if gGameSettings.GameMode = GM_CTF then
1209 begin
1210 for i := FLAG_RED to FLAG_BLUE do
1211 begin
1212 if not (gFlags[i].state in [FLAG_STATE_NONE, FLAG_STATE_CAPTURED]) then
1213 begin
1214 gFlags[i].Obj.Lerp(gLerpFactor, fx, fy);
1215 flip := gFlags[i].Direction = TDirection.D_LEFT;
1216 if flip then dx := -1 else dx := +1;
1217 t := FlagTextures[i];
1218 tex := t.GetTexture(FlagFrame);
1219 r_Draw_TextureRepeat(tex, fx + dx, fy + 1, tex.width, tex.height, flip, 255, 255, 255, 255, false)
1220 end;
1221 end;
1222 end;
1223 // TODO g_debug_frames
1224 end;
1225
1226 {$IFDEF ENABLE_SHELLS}
1227 procedure r_Map_DrawShells (x, y, w, h: Integer);
1228 var i, fx, fy, typ: Integer; t: TGLTexture; p: PObj;
1229 begin
1230 if gShells <> nil then
1231 begin
1232 for i := 0 to High(gShells) do
1233 begin
1234 if gShells[i].alive then
1235 begin
1236 typ := gShells[i].SType;
1237 if typ <= SHELL_LAST then
1238 begin
1239 p := @gShells[i].Obj;
1240 if g_Obj_Collide(x, y, w, h, p) then
1241 begin
1242 t := ShellTextures[typ];
1243 if t <> nil then
1244 begin
1245 p.Lerp(gLerpFactor, fx, fy);
1246 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, 255, 255, 255, 255, false, ShellAnim[typ].dx, ShellAnim[typ].dy, gShells[i].RAngle);
1247 end;
1248 end;
1249 end;
1250 end;
1251 end;
1252 end;
1253 end;
1254 {$ENDIF}
1255
1256 procedure r_Map_CalcSkyParallax (cx, cy, vw, vh, sw, sh, mw, mh: LongInt; out x, y, w, h: LongInt);
1257 const
1258 factor = 120; (* size ratio between view and sky (120%) *)
1259 limit = 100; (* max speed for parallax *)
1260 var
1261 msw, msh, mvw, mvh, svw, svh: LongInt;
1262 begin
1263 msw := vw * factor div 100;
1264 msh := vh * factor div 100;
1265 r_Common_CalcAspect(sw, sh, msw, msh, (sw / sh) <= (msw / msh), w, h);
1266
1267 (* calc x parallax or sky center on speed limit *)
1268 mvw := MAX(1, mw - vw);
1269 svw := w - vw;
1270 if 100 * svw div mvw <= limit then
1271 x := -cx * svw div mvw
1272 else
1273 x := -svw div 2;
1274
1275 (* calc y parallax or sky center on speed limit *)
1276 mvh := MAX(1, mh - vh);
1277 svh := h - vh;
1278 if 100 * svh div mvh <= limit then
1279 y := -cy * svh div mvh
1280 else
1281 y := -svh div 2;
1282
1283 (* handle out of map bounds *)
1284 if x > 0 then x := 0;
1285 if y > 0 then y := 0;
1286 if x < -svw then x := -svw;
1287 if y < -svh then y := -svh;
1288 end;
1289
1290 procedure r_Map_DrawScreenEffect (x, y, w, h, level: Integer; r, g, b: Byte);
1291 var i: Integer;
1292 begin
1293 if level > 0 then
1294 begin
1295 case level of
1296 0..14: i := 0;
1297 15..34: i := 1;
1298 35..54: i := 2;
1299 55..74: i := 3;
1300 75..94: i := 4;
1301 else i := 5
1302 end;
1303 r_Draw_FillRect(x, y, x + w, y + h, r, g, b, i * 50)
1304 end;
1305 end;
1306
1307 procedure r_Map_DrawScreenEffects (x, y, w, h: Integer; p: TPlayer);
1308 begin
1309 if p <> nil then
1310 begin
1311 r_Map_DrawScreenEffect(x, y, w, h, p.pain, 255, 0, 0);
1312 r_Map_DrawScreenEffect(x, y, w, h, p.pickup, 150, 200, 150);
1313 if (p.FMegaRulez[MR_INVUL] >= gTime) and (p.SpawnInvul < gTime) then
1314 begin
1315 if ((p.FMegaRulez[MR_INVUL] - gTime) > 2100) or not ODD((p.FMegaRulez[MR_INVUL] - gTime) div 300) then
1316 r_Draw_InvertRect(x, y, x + w, y + h, 191, 191, 191, 255);
1317 end;
1318 if p.FMegaRulez[MR_SUIT] >= gTime then
1319 begin
1320 if ((p.FMegaRulez[MR_SUIT] - gTime) > 2100) or not ODD((p.FMegaRulez[MR_SUIT] - gTime) div 300) then
1321 r_Draw_FillRect(x, y, x + w, y + h, 0, 96, 0, 55);
1322 end;
1323 if (p.Berserk >= 0) and (p.Berserk >= gTime) and (gFlash = 2) then
1324 begin
1325 r_Draw_FillRect(x, y, x + w, y + h, 255, 0, 0, 55);
1326 end;
1327 end;
1328 end;
1329
1330 procedure r_Map_DrawIndicator (p: TPlayer; color: TRGB; cx, cy, cw, ch: Integer);
1331 var a, ax, ay, fx, fy, fSlope, xx, yy: Integer;
1332 begin
1333 if (p <> nil) and p.Alive then
1334 begin
1335 p.obj.Lerp(gLerpFactor, fx, fy);
1336 fSlope := nlerp(p.SlopeOld, p.obj.slopeUpLeft, gLerpFactor);
1337 case gPlayerIndicatorStyle of
1338 0:
1339 if IndicatorTexture <> nil then
1340 begin
1341 ax := IndicatorTexture.width div 2;
1342 ay := IndicatorTexture.height div 2;
1343 if (p.obj.x + p.obj.rect.x) < cx then
1344 begin
1345 a := 90;
1346 xx := fx + p.obj.rect.x + p.obj.rect.width;
1347 yy := fy + p.obj.rect.y + (p.obj.rect.height - IndicatorTexture.width) div 2;
1348 end
1349 else if (p.obj.x + p.obj.rect.x + p.obj.rect.width) > (cx + cw) then
1350 begin
1351 a := 270;
1352 xx := fx + p.obj.rect.x - IndicatorTexture.height;
1353 yy := fy + p.obj.rect.y - (p.obj.rect.height - IndicatorTexture.width) div 2;
1354 end
1355 else if (p.obj.y - IndicatorTexture.height) < cy then
1356 begin
1357 a := 180;
1358 xx := fx + p.obj.rect.x + (p.obj.rect.width - IndicatorTexture.width) div 2;
1359 yy := fy + p.obj.rect.y + p.obj.rect.height;
1360 end
1361 else
1362 begin
1363 a := 0;
1364 xx := fx + p.obj.rect.x + (p.obj.rect.width - IndicatorTexture.width) div 2;
1365 yy := fy - IndicatorTexture.height;
1366 end;
1367 yy := yy + fSlope;
1368 xx := MIN(MAX(xx, cx), cx + cw - IndicatorTexture.width);
1369 yy := MIN(MAX(yy, cy), cy + ch - IndicatorTexture.height);
1370 r_Draw_TextureRepeatRotate(IndicatorTexture, xx, yy, IndicatorTexture.width, IndicatorTexture.height, false, color.r, color.g, color.b, 255, false, ax, ay, a);
1371 end;
1372 1:
1373 begin
1374 xx := fx + p.obj.rect.x + p.obj.rect.width div 2;
1375 yy := fy + fSlope;
1376 r_Common_DrawText(p.Name, xx, yy, color.r, color.g, color.b, 255, stdfont, TBasePoint.BP_DOWN);
1377 end;
1378 end;
1379 end;
1380 end;
1381
1382 procedure r_Map_DrawPlayerIndicators (player: TPlayer; cx, cy, cw, ch: Integer);
1383 var i: Integer; p: TPlayer;
1384 begin
1385 case gPlayerIndicator of
1386 1:
1387 if player <> nil then
1388 begin
1389 r_Map_DrawIndicator(player, _RGB(255, 255, 255), cx, cy, cw, ch);
1390 end;
1391 2:
1392 if gPlayers <> nil then
1393 begin
1394 for i := 0 to HIGH(gPlayers) do
1395 begin
1396 p := gPlayers[i];
1397 if p <> nil then
1398 begin
1399 if (player <> nil) and (p = player) then
1400 begin
1401 r_Map_DrawIndicator(p, _RGB(255, 255, 255), cx, cy, cw, ch);
1402 end
1403 else if (player = nil) or ((p.Team = player.Team) and (p.Team <> TEAM_NONE)) then
1404 begin
1405 case gPlayerIndicatorStyle of
1406 0: r_Map_DrawIndicator(p, p.GetColor(), cx, cy, cw, ch);
1407 1: r_Map_DrawIndicator(p, _RGB(192, 192, 192), cx, cy, cw, ch);
1408 end;
1409 end;
1410 end;
1411 end;
1412 end;
1413 end;
1414 end;
1415
1416 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer; player: TPlayer);
1417 var iter: TPanelGrid.Iter; p: PPanel; cx, cy, cw, ch, xx, yy, ww, hh: Integer; sx, sy, sw, sh: LongInt; l, t, r, b: Integer;
1418 begin
1419 r_Draw_GetRect(l, t, r, b);
1420 r_Draw_SetRect(x, y, x + w, y + h);
1421 glTranslatef(x, y, 0);
1422
1423 (* camera rect *)
1424 cx := (camx - w) + w div 2;
1425 cy := (camy - h) + h div 2;
1426 cw := w;
1427 ch := h;
1428
1429 (* camera bounds *)
1430 if g_dbg_ignore_bounds = false then
1431 begin
1432 if cx + cw > gMapInfo.Width then
1433 cx := gMapInfo.Width - cw;
1434 if cy + ch > gMapInfo.Height then
1435 cy := gMapInfo.Height - ch;
1436 if cx < 0 then
1437 cx := 0;
1438 if cy < 0 then
1439 cy := 0;
1440 end;
1441
1442 (* map bounds *)
1443 xx := cx;
1444 yy := cy;
1445 ww := cw;
1446 hh := ch;
1447 if xx + ww > gMapInfo.Width then
1448 xx := gMapInfo.Width - ww;
1449 if yy + hh > gMapInfo.Height then
1450 yy := gMapInfo.Height - hh;
1451 if xx < 0 then
1452 xx := 0;
1453 if yy < 0 then
1454 yy := 0;
1455
1456 plist.Clear;
1457 iter := mapGrid.ForEachInAABB(xx, yy, ww, hh, GridDrawableMask);
1458 for p in iter do
1459 if ((p^.tag and GridTagDoor) <> 0) = p^.door then
1460 plist.Insert(p^);
1461 iter.Release;
1462
1463 glPushMatrix;
1464 if DebugCameraScale <> 1.0 then
1465 begin
1466 glTranslatef(cw div 2, ch div 2, 0);
1467 glScalef(DebugCameraScale, DebugCameraScale, 1);
1468 glTranslatef(-w div 2, -h div 2, 0);
1469 end;
1470
1471 if SkyTexture <> nil then
1472 begin
1473 r_Map_CalcSkyParallax(cx, cy, w, h, SkyTexture.width, SkyTexture.height, gMapInfo.Width, gMapInfo.Height, sx, sy, sw, sh);
1474 r_Draw_Texture(SkyTexture, sx, sy, sw, sh, false, 255, 255, 255, 255, false);
1475 end;
1476
1477 glTranslatef(-cx, -cy, 0);
1478 r_Map_DrawPanelType(PANEL_BACK);
1479 r_Map_DrawPanelType(PANEL_STEP);
1480 r_Map_DrawItems(xx, yy, ww, hh, false);
1481 r_Map_DrawShots(xx, yy, ww, hh);
1482 {$IFDEF ENABLE_SHELLS}
1483 r_Map_DrawShells(xx, yy, ww, hh);
1484 {$ENDIF}
1485 r_Map_DrawPlayers(xx, yy, ww, hh, player);
1486 {$IFDEF ENABLE_GIBS}
1487 r_Map_DrawGibs(xx, yy, ww, hh);
1488 {$ENDIF}
1489 {$IFDEF ENABLE_CORPSES}
1490 r_Map_DrawCorpses(xx, yy, ww, hh);
1491 {$ENDIF}
1492 r_Map_DrawPanelType(PANEL_WALL);
1493 r_Map_DrawMonsters(xx, yy, ww, hh);
1494 r_Map_DrawItems(xx, yy, ww, hh, true);
1495 r_Map_DrawPanelType(PANEL_CLOSEDOOR);
1496 {$IFDEF ENABLE_GFX}
1497 r_Map_DrawParticles(xx, yy, ww, hh);
1498 r_Map_DrawGFX(xx, yy, ww, hh);
1499 {$ENDIF}
1500 r_Map_DrawFlags(xx, yy, ww, hh);
1501 r_Map_DrawPanelType(PANEL_ACID1);
1502 r_Map_DrawPanelType(PANEL_ACID2);
1503 r_Map_DrawPanelType(PANEL_WATER);
1504 r_Map_DrawPanelType(PANEL_FORE);
1505 // TODO draw monsters health bar
1506 // TODO draw players health bar
1507 if gGameSettings.GameMode <> GM_SINGLE then
1508 r_Map_DrawPlayerIndicators(player, cx, cy, cw, ch);
1509 if DebugCameraScale <> 1.0 then
1510 begin
1511 r_Draw_Rect (cx, cy, cx + cw, cy + ch, 0, 255, 0, 255);
1512 r_Draw_Rect (xx, yy, xx + ww, yy + hh, 255, 0, 0, 255);
1513 end;
1514 glPopMatrix;
1515
1516 r_Map_DrawScreenEffects(x, y, w, h, player);
1517
1518 // TODO draw minimap (gShowMap)
1519 // TODO draw g_debug_player
1520
1521 glTranslatef(-x, -y, 0);
1522 r_Draw_SetRect(l, t, r, b);
1523 end;
1524
1525 procedure r_Map_Update;
1526 var i, count, tick: LongInt;
1527 begin
1528 tick := gTime div GAME_TICK;
1529 for i := 0 to ITEM_LAST do
1530 g_Anim_GetFrameByTime(ItemAnim[i].anim, tick, count, Items[i].frame);
1531 r_Map_UpdateGFX(tick);
1532 g_Anim_GetFrameByTime(FlagAnim, tick, count, FlagFrame);
1533 end;
1534
1535 initialization
1536 conRegVar('r_debug_camera_scale', @DebugCameraScale, 0.0001, 1000.0, '', '');
1537 DebugCameraScale := 1.0;
1538 end.
[MIRROR] a port of Doom 2D Forever to FPC/SDL
[25/02/2024 19:55:35]
DEADSOFTWARE 2012-2024