src/game/g_items.pas

   1 (* Copyright (C)  Doom 2D: Forever Developers
   2  *
   3  * This program is free software: you can redistribute it and/or modify
   4  * it under the terms of the GNU General Public License as published by
   5  * the Free Software Foundation, version 3 of the License ONLY.
   6  *
   7  * This program is distributed in the hope that it will be useful,
   8  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   9  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  10  * GNU General Public License for more details.
  11  *
  12  * You should have received a copy of the GNU General Public License
  13  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  14  *)
  15 {$INCLUDE ../shared/a_modes.inc}
  16 unit g_items;
  17
  18 interface
  19
  20 uses
  21   SysUtils, Classes,
  22   MAPDEF, g_phys, g_saveload;
  23
  24 const
  25   ITEM_LAST = ITEM_MAX;
  26
  27 Type
  28   PItem = ^TItem;
  29   TItem = record
  30   private
  31     //treeNode: Integer;
  32     slotIsUsed: Boolean;
  33     arrIdx: Integer; // in ggItems
  34
  35   public
  36     ItemType: Byte;
  37     Respawnable: Boolean;
  38     InitX, InitY: Integer;
  39     RespawnTime: Word;
  40     alive: Boolean;
  41     Fall: Boolean;
  42     QuietRespawn: Boolean;
  43     SpawnTrigger: Integer;
  44     Obj: TObj;
  45     dropped: Boolean; // dropped from the monster? drops should be rendered after corpses, so zombie corpse will not obscure ammo container, for example
  46     NeedSend: Boolean;
  47
  48     procedure positionChanged (); //WARNING! call this after monster position was changed, or coldet will not work right!
  49     procedure getMapBox (out x, y, w, h: Integer); inline;
  50     procedure moveBy (dx, dy: Integer); inline;
  51
  52     property used: Boolean read slotIsUsed;
  53     property myid: Integer read arrIdx;
  54   end;
  55
  56 procedure g_Items_LoadData();
  57 procedure g_Items_FreeData();
  58 procedure g_Items_Init();
  59 procedure g_Items_Free();
  60 function g_Items_Create(X, Y: Integer; ItemType: Byte;
  61            Fall, Respawnable: Boolean; AdjCoord: Boolean = False; ForcedID: Integer = -1): DWORD;
  62 procedure g_Items_SetDrop (ID: DWORD);
  63 procedure g_Items_PreUpdate();
  64 procedure g_Items_Update();
  65 procedure g_Items_Pick(ID: DWORD);
  66 procedure g_Items_Remove(ID: DWORD);
  67 procedure g_Items_SaveState (st: TStream);
  68 procedure g_Items_LoadState (st: TStream);
  69
  70 procedure g_Items_RestartRound ();
  71
  72 function g_Items_ValidId (idx: Integer): Boolean; inline;
  73 function g_Items_ByIdx (idx: Integer): PItem;
  74 function g_Items_ObjByIdx (idx: Integer): PObj;
  75
  76 procedure g_Items_EmitPickupSound (idx: Integer); // at item position
  77 procedure g_Items_EmitPickupSoundAt (idx, x, y: Integer);
  78
  79 procedure g_Items_AddDynLights();
  80
  81
  82 type
  83   TItemEachAliveCB = function (it: PItem): Boolean is nested; // return `true` to stop
  84
  85 function g_Items_ForEachAlive (cb: TItemEachAliveCB; backwards: Boolean=false): Boolean;
  86 function g_Items_NextAlive (startIdx: Integer): PItem;
  87
  88 var
  89   gMaxDist: Integer = 1; // for sounds
  90
  91   var (* private state *)
  92     ggItems: Array of TItem = nil;
  93
  94 implementation
  95
  96   uses
  97     {$IFDEF ENABLE_GFX}
  98       g_gfx,
  99     {$ENDIF}
 100     Math,
 101     g_basic, g_sound, g_map,
 102     g_game, g_triggers, g_console, g_player, g_net, g_netmsg,
 103     e_log, g_options,
 104     g_grid, binheap, idpool, utils, xstreams
 105   ;
 106
 107 // ////////////////////////////////////////////////////////////////////////// //
 108 var
 109   freeIds: TIdPool = nil;
 110
 111
 112 // ////////////////////////////////////////////////////////////////////////// //
 113 function g_Items_ValidId (idx: Integer): Boolean; inline;
 114 begin
 115   result := false;
 116   if (idx < 0) or (idx > High(ggItems)) then exit;
 117   if not ggItems[idx].slotIsUsed then exit;
 118   result := true;
 119 end;
 120
 121
 122 function g_Items_ByIdx (idx: Integer): PItem;
 123 begin
 124   if (idx < 0) or (idx > High(ggItems)) then raise Exception.Create('g_ItemObjByIdx: invalid index');
 125   result := @ggItems[idx];
 126   if not result.slotIsUsed then raise Exception.Create('g_ItemObjByIdx: requested inexistent item');
 127 end;
 128
 129
 130 function g_Items_ObjByIdx (idx: Integer): PObj;
 131 begin
 132   if (idx < 0) or (idx > High(ggItems)) then raise Exception.Create('g_ItemObjByIdx: invalid index');
 133   if not ggItems[idx].slotIsUsed then raise Exception.Create('g_ItemObjByIdx: requested inexistent item');
 134   result := @ggItems[idx].Obj;
 135 end;
 136
 137
 138 // ////////////////////////////////////////////////////////////////////////// //
 139 procedure TItem.positionChanged ();
 140 begin
 141   NeedSend := NeedSend or (Obj.X <> Obj.oldX) or (Obj.Y <> Obj.oldY);
 142 end;
 143
 144 procedure TItem.getMapBox (out x, y, w, h: Integer); inline;
 145 begin
 146   x := Obj.X+Obj.Rect.X;
 147   y := Obj.Y+Obj.Rect.Y;
 148   w := Obj.Rect.Width;
 149   h := Obj.Rect.Height;
 150 end;
 151
 152 procedure TItem.moveBy (dx, dy: Integer); inline;
 153 begin
 154   if (dx <> 0) or (dy <> 0) then
 155   begin
 156     Obj.X += dx;
 157     Obj.Y += dy;
 158     positionChanged();
 159   end;
 160 end;
 161
 162 // ////////////////////////////////////////////////////////////////////////// //
 163 const
 164   ITEM_SIGNATURE = $4D455449; // 'ITEM'
 165
 166   ITEMSIZE: Array [ITEM_MEDKIT_SMALL..ITEM_MAX] of Array [0..1] of Byte =
 167     (((14), (15)), // MEDKIT_SMALL
 168      ((28), (19)), // MEDKIT_LARGE
 169      ((28), (19)), // MEDKIT_BLACK
 170      ((31), (16)), // ARMOR_GREEN
 171      ((31), (16)), // ARMOR_BLUE
 172      ((25), (25)), // SPHERE_BLUE
 173      ((25), (25)), // SPHERE_WHITE
 174      ((24), (47)), // SUIT
 175      ((14), (27)), // OXYGEN
 176      ((25), (25)), // INVUL
 177      ((62), (24)), // WEAPON_SAW
 178      ((63), (12)), // WEAPON_SHOTGUN1
 179      ((54), (13)), // WEAPON_SHOTGUN2
 180      ((54), (16)), // WEAPON_CHAINGUN
 181      ((62), (16)), // WEAPON_ROCKETLAUNCHER
 182      ((54), (16)), // WEAPON_PLASMA
 183      ((61), (36)), // WEAPON_BFG
 184      ((54), (16)), // WEAPON_SUPERPULEMET
 185      (( 9), (11)), // AMMO_BULLETS
 186      ((28), (16)), // AMMO_BULLETS_BOX
 187      ((15), ( 7)), // AMMO_SHELLS
 188      ((32), (12)), // AMMO_SHELLS_BOX
 189      ((12), (27)), // AMMO_ROCKET
 190      ((54), (21)), // AMMO_ROCKET_BOX
 191      ((15), (12)), // AMMO_CELL
 192      ((32), (21)), // AMMO_CELL_BIG
 193      ((22), (29)), // AMMO_BACKPACK
 194      ((16), (16)), // KEY_RED
 195      ((16), (16)), // KEY_GREEN
 196      ((16), (16)), // KEY_BLUE
 197      (( 1), ( 1)), // WEAPON_KASTET
 198      ((43), (16)), // WEAPON_PISTOL
 199      ((14), (18)), // BOTTLE
 200      ((16), (15)), // HELMET
 201      ((32), (24)), // JETPACK
 202      ((25), (25)), // INVIS
 203      ((53), (20)), // WEAPON_FLAMETHROWER
 204      ((13), (20))); // AMMO_FUELCAN
 205
 206 procedure g_Items_LoadData();
 207 begin
 208   e_WriteLog('Loading items data...', TMsgType.Notify);
 209
 210   g_Sound_CreateWADEx('SOUND_ITEM_RESPAWNITEM', GameWAD+':SOUNDS\RESPAWNITEM');
 211   g_Sound_CreateWADEx('SOUND_ITEM_GETRULEZ', GameWAD+':SOUNDS\GETRULEZ');
 212   g_Sound_CreateWADEx('SOUND_ITEM_GETWEAPON', GameWAD+':SOUNDS\GETWEAPON');
 213   g_Sound_CreateWADEx('SOUND_ITEM_GETITEM', GameWAD+':SOUNDS\GETITEM');
 214
 215   freeIds := TIdPool.Create();
 216 end;
 217
 218
 219 procedure g_Items_FreeData();
 220 begin
 221   e_WriteLog('Releasing items data...', TMsgType.Notify);
 222
 223   g_Sound_Delete('SOUND_ITEM_RESPAWNITEM');
 224   g_Sound_Delete('SOUND_ITEM_GETRULEZ');
 225   g_Sound_Delete('SOUND_ITEM_GETWEAPON');
 226   g_Sound_Delete('SOUND_ITEM_GETITEM');
 227
 228   freeIds.Free();
 229   freeIds := nil;
 230 end;
 231
 232
 233 procedure releaseItem (idx: Integer);
 234 var
 235   it: PItem;
 236 begin
 237   if (idx < 0) or (idx > High(ggItems)) then raise Exception.Create('releaseItem: invalid item id');
 238   if not freeIds.hasAlloced[LongWord(idx)] then raise Exception.Create('releaseItem: trying to release unallocated item (0)');
 239   it := @ggItems[idx];
 240   if not it.slotIsUsed then raise Exception.Create('releaseItem: trying to release unallocated item (1)');
 241   if (it.arrIdx <> idx) then raise Exception.Create('releaseItem: arrIdx inconsistency');
 242   it.slotIsUsed := false;
 243   it.alive := False;
 244   it.SpawnTrigger := -1;
 245   it.ItemType := ITEM_NONE;
 246   it.NeedSend := false;
 247   freeIds.release(LongWord(idx));
 248 end;
 249
 250
 251 procedure growItemArrayTo (newsz: Integer);
 252 var
 253   i, olen: Integer;
 254   it: PItem;
 255 begin
 256   if (newsz < Length(ggItems)) then exit;
 257   // no free slots
 258   olen := Length(ggItems);
 259   SetLength(ggItems, newsz);
 260   for i := olen to High(ggItems) do
 261   begin
 262     it := @ggItems[i];
 263     it.slotIsUsed := false;
 264     it.arrIdx := i;
 265     it.ItemType := ITEM_NONE;
 266     it.alive := false;
 267     it.SpawnTrigger := -1;
 268     it.Respawnable := false;
 269     it.NeedSend := false;
 270     //if not freeIds.hasFree[LongWord(i)] then raise Exception.Create('internal error in item idx manager');
 271   end;
 272 end;
 273
 274
 275 function allocItem (): DWORD;
 276 begin
 277   result := freeIds.alloc();
 278   if (result >= Length(ggItems)) then growItemArrayTo(Integer(result)+64);
 279   if (Integer(result) > High(ggItems)) then raise Exception.Create('allocItem: freeid list corrupted');
 280   if (ggItems[result].arrIdx <> Integer(result)) then raise Exception.Create('allocItem: arrIdx inconsistency');
 281 end;
 282
 283
 284 // it will be slow if the slot is free (we have to rebuild the heap)
 285 function wantItemSlot (slot: Integer): Integer;
 286 var
 287   olen: Integer;
 288   it: PItem;
 289 begin
 290   if (slot < 0) or (slot > $0fffffff) then raise Exception.Create('wantItemSlot: bad item slot request');
 291   // do we need to grow item storate?
 292   olen := Length(ggItems);
 293   if (slot >= olen) then growItemArrayTo(slot+64);
 294
 295   it := @ggItems[slot];
 296   if not it.slotIsUsed then
 297   begin
 298     freeIds.alloc(LongWord(slot));
 299   end
 300   else
 301   begin
 302     if not freeIds.hasAlloced[slot] then raise Exception.Create('wantItemSlot: internal error in item idx manager');
 303   end;
 304   it.slotIsUsed := false;
 305
 306   result := slot;
 307 end;
 308
 309
 310 // ////////////////////////////////////////////////////////////////////////// //
 311 procedure g_Items_Init ();
 312 var
 313   a, b: Integer;
 314 begin
 315   if gMapInfo.Height > gPlayerScreenSize.Y then a := gMapInfo.Height-gPlayerScreenSize.Y else a := gMapInfo.Height;
 316   if gMapInfo.Width > gPlayerScreenSize.X then b := gMapInfo.Width-gPlayerScreenSize.X else b := gMapInfo.Width;
 317   gMaxDist := Trunc(Hypot(a, b));
 318 end;
 319
 320
 321 procedure g_Items_Free ();
 322 begin
 323   if (ggItems <> nil) then
 324     ggItems := nil;
 325   freeIds.clear();
 326 end;
 327
 328
 329 function g_Items_Create (X, Y: Integer; ItemType: Byte;
 330            Fall, Respawnable: Boolean; AdjCoord: Boolean = False; ForcedID: Integer = -1): DWORD;
 331 var
 332   find_id: DWORD;
 333   it: PItem;
 334 begin
 335   if ForcedID < 0 then find_id := allocItem() else find_id := wantItemSlot(ForcedID);
 336
 337   //{$IF DEFINED(D2F_DEBUG)}e_WriteLog(Format('allocated item #%d', [Integer(find_id)]), MSG_NOTIFY);{$ENDIF}
 338
 339   it := @ggItems[find_id];
 340
 341   if (it.arrIdx <> Integer(find_id)) then raise Exception.Create('g_Items_Create: arrIdx inconsistency');
 342   //it.arrIdx := find_id;
 343   it.slotIsUsed := true;
 344
 345   it.ItemType := ItemType;
 346   it.Respawnable := Respawnable;
 347   it.InitX := X;
 348   it.InitY := Y;
 349   it.RespawnTime := 0;
 350   it.Fall := Fall;
 351   it.alive := True;
 352   it.QuietRespawn := False;
 353   it.dropped := false;
 354   it.NeedSend := false;
 355
 356   g_Obj_Init(@it.Obj);
 357   it.Obj.X := X;
 358   it.Obj.Y := Y;
 359   it.Obj.Rect.Width := ITEMSIZE[ItemType][0];
 360   it.Obj.Rect.Height := ITEMSIZE[ItemType][1];
 361
 362   it.SpawnTrigger := -1;
 363
 364   // Êîîðäèíàòû îòíîñèòåëüíî öåíòðà íèæíåãî ðåáðà
 365   if AdjCoord then
 366   begin
 367     with it^ do
 368     begin
 369       Obj.X := X - (Obj.Rect.Width div 2);
 370       Obj.Y := Y - Obj.Rect.Height;
 371       InitX := Obj.X;
 372       InitY := Obj.Y;
 373     end;
 374   end;
 375
 376   it.Obj.oldX := it.Obj.X;
 377   it.Obj.oldY := it.Obj.Y;
 378
 379   it.positionChanged();
 380
 381   result := find_id;
 382 end;
 383
 384 procedure g_Items_PreUpdate ();
 385 var
 386   i: Integer;
 387 begin
 388   if (ggItems = nil) then Exit;
 389   for i := 0 to High(ggItems) do
 390     if (ggItems[i].ItemType <> ITEM_NONE) and ggItems[i].slotIsUsed then
 391     begin
 392       ggItems[i].Obj.oldX := ggItems[i].Obj.X;
 393       ggItems[i].Obj.oldY := ggItems[i].Obj.Y;
 394     end;
 395 end;
 396
 397 procedure g_Items_Update ();
 398 var
 399   i, j, k: Integer;
 400   m, ItemRespawnTime: Word;
 401   r, nxt: Boolean;
 402 begin
 403   if (ggItems = nil) then exit;
 404
 405   // respawn items in 15 seconds regardless of settings during warmup
 406   ItemRespawnTime := IfThen(gLMSRespawn = LMS_RESPAWN_NONE, gGameSettings.ItemRespawnTime, 15);
 407
 408   for i := 0 to High(ggItems) do
 409   begin
 410     if (ggItems[i].ItemType = ITEM_NONE) then continue;
 411     if not ggItems[i].slotIsUsed then continue; // just in case
 412
 413     with ggItems[i] do
 414     begin
 415       nxt := False;
 416
 417       if alive then
 418       begin
 419         if Fall then
 420         begin
 421           m := g_Obj_Move(@Obj, True, True);
 422           positionChanged(); // this updates spatial accelerators
 423
 424           // Ñîïðîòèâëåíèå âîçäóõà
 425           if gTime mod (GAME_TICK*2) = 0 then Obj.Vel.X := z_dec(Obj.Vel.X, 1);
 426
 427           // Åñëè âûïàë çà êàðòó
 428           if WordBool(m and MOVE_FALLOUT) then
 429           begin
 430             if SpawnTrigger = -1 then
 431             begin
 432               g_Items_Pick(i);
 433             end
 434             else
 435             begin
 436               g_Items_Remove(i);
 437               if g_Game_IsServer and g_Game_IsNet then MH_SEND_ItemDestroy(True, i);
 438             end;
 439             continue;
 440           end;
 441         end;
 442
 443         // Åñëè èãðîêè ïîáëèçîñòè
 444         if (gPlayers <> nil) then
 445         begin
 446           j := Random(Length(gPlayers))-1;
 447
 448           for k := 0 to High(gPlayers) do
 449           begin
 450             Inc(j);
 451             if j > High(gPlayers) then j := 0;
 452
 453             if (gPlayers[j] <> nil) and gPlayers[j].alive and g_Obj_Collide(@gPlayers[j].Obj, @Obj) then
 454             begin
 455               if g_Game_IsClient then continue;
 456
 457               if not gPlayers[j].PickItem(ItemType, Respawnable, r) then continue;
 458
 459               if g_Game_IsNet then MH_SEND_PlayerStats(gPlayers[j].UID);
 460
 461               {
 462                 Doom 2D: Original:
 463                 1. I_NONE,I_CLIP,I_SHEL,I_ROCKET,I_CELL,I_AMMO,I_SBOX,I_RBOX,I_CELP,I_BPACK,I_CSAW,I_SGUN,I_SGUN2,I_MGUN,I_LAUN,I_PLAS,I_BFG,I_GUN2
 464                 +2. I_MEGA,I_INVL,I_SUPER
 465                 3. I_STIM,I_MEDI,I_ARM1,I_ARM2,I_AQUA,I_KEYR,I_KEYG,I_KEYB,I_SUIT,I_RTORCH,I_GTORCH,I_BTORCH,I_GOR1,I_FCAN
 466               }
 467               g_Items_EmitPickupSoundAt(i, gPlayers[j].Obj.X, gPlayers[j].Obj.Y);
 468
 469               // Íàäî óáðàòü ñ êàðòû, åñëè ýòî íå êëþ÷, êîòîðûì íóæíî ïîäåëèòüñÿ ñ äðóãèì èãðîêîì
 470               if r then
 471               begin
 472                 if not (Respawnable and (ItemRespawnTime > 0)) then
 473                   g_Items_Remove(i)
 474                 else
 475                   g_Items_Pick(i);
 476                 if g_Game_IsNet then MH_SEND_ItemDestroy(False, i);
 477                 nxt := True;
 478                 break;
 479               end;
 480             end;
 481           end;
 482         end;
 483
 484         if nxt then continue;
 485       end;
 486
 487       if Respawnable and g_Game_IsServer then
 488       begin
 489         DecMin(RespawnTime, 0);
 490         if (RespawnTime = 0) and (not alive) then
 491         begin
 492           if not QuietRespawn then g_Sound_PlayExAt('SOUND_ITEM_RESPAWNITEM', InitX, InitY);
 493           {$IFDEF ENABLE_GFX}
 494             g_GFX_QueueEffect(
 495               R_GFX_ITEM_RESPAWN,
 496               InitX + (Obj.Rect.Width div 2) - 16,
 497               InitY + (Obj.Rect.Height div 2) - 16
 498             );
 499           {$ENDIF}
 500           Obj.oldX := InitX;
 501           Obj.oldY := InitY;
 502           Obj.X := InitX;
 503           Obj.Y := InitY;
 504           Obj.Vel.X := 0;
 505           Obj.Vel.Y := 0;
 506           Obj.Accel.X := 0;
 507           Obj.Accel.Y := 0;
 508           positionChanged(); // this updates spatial accelerators
 509
 510           alive := true;
 511
 512           if g_Game_IsNet then MH_SEND_ItemSpawn(QuietRespawn, i);
 513           QuietRespawn := false;
 514         end;
 515       end;
 516     end;
 517   end;
 518 end;
 519
 520 procedure g_Items_SetDrop (ID: DWORD);
 521 begin
 522   if (ID < Length(ggItems)) then
 523   begin
 524     ggItems[ID].dropped := true;
 525   end;
 526 end;
 527
 528
 529 procedure g_Items_Pick (ID: DWORD);
 530 begin
 531   if (ID < Length(ggItems)) then
 532   begin
 533     ggItems[ID].Obj.oldX := ggItems[ID].Obj.X;
 534     ggItems[ID].Obj.oldY := ggItems[ID].Obj.Y;
 535     ggItems[ID].alive := false;
 536     ggItems[ID].RespawnTime := IfThen(gLMSRespawn = LMS_RESPAWN_NONE, gGameSettings.ItemRespawnTime, 15) * 36;
 537   end;
 538 end;
 539
 540
 541 procedure g_Items_Remove (ID: DWORD);
 542 var
 543   it: PItem;
 544   trig: Integer;
 545 begin
 546   if not g_Items_ValidId(ID) then
 547   begin
 548     //writeln('g_Items_Remove: invalid item id: ', ID);
 549     raise Exception.Create('g_Items_Remove: invalid item id');
 550     //exit;
 551   end;
 552
 553   it := @ggItems[ID];
 554   if (it.arrIdx <> Integer(ID)) then raise Exception.Create('g_Items_Remove: arrIdx desync');
 555
 556   it.Obj.oldX := it.Obj.X;
 557   it.Obj.oldY := it.Obj.Y;
 558   trig := it.SpawnTrigger;
 559
 560   releaseItem(ID);
 561
 562   if (trig > -1) then g_Triggers_DecreaseSpawner(trig);
 563 end;
 564
 565
 566 procedure g_Items_SaveState (st: TStream);
 567 var
 568   count, i: Integer;
 569   tt: Byte;
 570 begin
 571   // Ñ÷èòàåì êîëè÷åñòâî ñóùåñòâóþùèõ ïðåäìåòîâ
 572   count := 0;
 573   for i := 0 to High(ggItems) do if (ggItems[i].ItemType <> ITEM_NONE) and (ggItems[i].slotIsUsed) then Inc(count);
 574
 575   // Êîëè÷åñòâî ïðåäìåòîâ
 576   utils.writeInt(st, LongInt(count));
 577   if (count = 0) then exit;
 578
 579   for i := 0 to High(ggItems) do
 580   begin
 581     if (ggItems[i].ItemType <> ITEM_NONE) and (ggItems[i].slotIsUsed) then
 582     begin
 583       // Ñèãíàòóðà ïðåäìåòà
 584       utils.writeSign(st, 'ITEM');
 585       utils.writeInt(st, Byte(0));
 586       // Òèï ïðåäìåòà
 587       tt := ggItems[i].ItemType;
 588       if ggItems[i].dropped then tt := tt or $80;
 589       utils.writeInt(st, Byte(tt));
 590       // Åñòü ëè ðåñïàóí
 591       utils.writeBool(st, ggItems[i].Respawnable);
 592       // Êîîðäèíàòû ðåñïóíà
 593       utils.writeInt(st, LongInt(ggItems[i].InitX));
 594       utils.writeInt(st, LongInt(ggItems[i].InitY));
 595       // Âðåìÿ äî ðåñïàóíà
 596       utils.writeInt(st, Word(ggItems[i].RespawnTime));
 597       // Ñóùåñòâóåò ëè ýòîò ïðåäìåò
 598       utils.writeBool(st, ggItems[i].alive);
 599       // Ìîæåò ëè îí ïàäàòü
 600       utils.writeBool(st, ggItems[i].Fall);
 601       // Èíäåêñ òðèããåðà, ñîçäàâøåãî ïðåäìåò
 602       utils.writeInt(st, LongInt(ggItems[i].SpawnTrigger));
 603       // Îáúåêò ïðåäìåòà
 604       Obj_SaveState(st, @ggItems[i].Obj);
 605     end;
 606   end;
 607 end;
 608
 609
 610 procedure g_Items_LoadState (st: TStream);
 611 var
 612   count, i, a: Integer;
 613   b: Byte;
 614 begin
 615   assert(st <> nil);
 616
 617   g_Items_Free();
 618
 619   // Êîëè÷åñòâî ïðåäìåòîâ
 620   count := utils.readLongInt(st);
 621   if (count = 0) then exit;
 622   if (count < 0) or (count > 1024*1024) then raise XStreamError.Create('invalid number of items');
 623
 624   for a := 0 to count-1 do
 625   begin
 626     // Ñèãíàòóðà ïðåäìåòà
 627     if not utils.checkSign(st, 'ITEM') then raise XStreamError.Create('invalid item signature');
 628     if (utils.readByte(st) <> 0) then raise XStreamError.Create('invalid item version');
 629     // Òèï ïðåäìåòà
 630     b := utils.readByte(st); // bit7=1: monster drop
 631     // Ñîçäàåì ïðåäìåò
 632     i := g_Items_Create(0, 0, b and $7F, False, False);
 633     if ((b and $80) <> 0) then g_Items_SetDrop(i);
 634     // Åñòü ëè ðåñïàóí
 635     ggItems[i].Respawnable := utils.readBool(st);
 636     // Êîîðäèíàòû ðåñïóíà
 637     ggItems[i].InitX := utils.readLongInt(st);
 638     ggItems[i].InitY := utils.readLongInt(st);
 639     // Âðåìÿ äî ðåñïàóíà
 640     ggItems[i].RespawnTime := utils.readWord(st);
 641     // Ñóùåñòâóåò ëè ýòîò ïðåäìåò
 642     ggItems[i].alive := utils.readBool(st);
 643     // Ìîæåò ëè îí ïàäàòü
 644     ggItems[i].Fall := utils.readBool(st);
 645     // Èíäåêñ òðèããåðà, ñîçäàâøåãî ïðåäìåò
 646     ggItems[i].SpawnTrigger := utils.readLongInt(st);
 647     // Îáúåêò ïðåäìåòà
 648     Obj_LoadState(@ggItems[i].Obj, st);
 649   end;
 650 end;
 651
 652
 653 procedure g_Items_RestartRound ();
 654 var
 655   i: Integer;
 656   it: PItem;
 657 begin
 658   for i := 0 to High(ggItems) do
 659   begin
 660     it := @ggItems[i];
 661     it.Obj.oldX := it.Obj.X;
 662     it.Obj.oldY := it.Obj.Y;
 663     if not it.slotIsUsed then continue;
 664     if it.Respawnable and (it.ItemType <> ITEM_NONE) then
 665     begin
 666       it.QuietRespawn := True;
 667       it.RespawnTime := 0;
 668     end
 669     else
 670     begin
 671       g_Items_Remove(i);
 672       if g_Game_IsNet then MH_SEND_ItemDestroy(True, i);
 673     end;
 674   end;
 675 end;
 676
 677
 678 function g_Items_ForEachAlive (cb: TItemEachAliveCB; backwards: Boolean=false): Boolean;
 679 var
 680   idx: Integer;
 681 begin
 682   result := false;
 683   if (ggItems = nil) or not assigned(cb) then exit;
 684
 685   if backwards then
 686   begin
 687     for idx := High(ggItems) downto 0 do
 688     begin
 689       if ggItems[idx].alive and ggItems[idx].slotIsUsed then
 690       begin
 691         result := cb(@ggItems[idx]);
 692         if result then exit;
 693       end;
 694     end;
 695   end
 696   else
 697   begin
 698     for idx := 0 to High(ggItems) do
 699     begin
 700       if ggItems[idx].alive and ggItems[idx].slotIsUsed then
 701       begin
 702         result := cb(@ggItems[idx]);
 703         if result then exit;
 704       end;
 705     end;
 706   end;
 707 end;
 708
 709 function g_Items_NextAlive (startIdx: Integer): PItem;
 710 var
 711   idx: Integer;
 712 begin
 713   result := nil;
 714   if (ggItems = nil) or (startIdx >= High(ggItems)) then exit;
 715   for idx := startIdx + 1 to High(ggItems) do
 716     if ggItems[idx].alive and ggItems[idx].slotIsUsed then
 717     begin
 718       result := @ggItems[idx];
 719       exit;
 720     end;
 721 end;
 722
 723 // ////////////////////////////////////////////////////////////////////////// //
 724 procedure g_Items_EmitPickupSound (idx: Integer);
 725 var
 726   it: PItem;
 727 begin
 728   if not g_Items_ValidId(idx) then exit;
 729   it := @ggItems[idx];
 730   g_Items_EmitPickupSoundAt(idx, it.Obj.X, it.Obj.Y);
 731 end;
 732
 733 procedure g_Items_EmitPickupSoundAt (idx, x, y: Integer);
 734 var
 735   it: PItem;
 736 begin
 737   if not g_Items_ValidId(idx) then exit;
 738
 739   it := @ggItems[idx];
 740   if gSoundEffectsDF then
 741   begin
 742     if it.ItemType in [ITEM_SPHERE_BLUE, ITEM_SPHERE_WHITE, ITEM_INVUL,
 743                        ITEM_INVIS, ITEM_MEDKIT_BLACK, ITEM_JETPACK] then
 744     begin
 745       g_Sound_PlayExAt('SOUND_ITEM_GETRULEZ', x, y);
 746     end
 747     else if it.ItemType in [ITEM_WEAPON_SAW, ITEM_WEAPON_PISTOL, ITEM_WEAPON_SHOTGUN1, ITEM_WEAPON_SHOTGUN2,
 748                             ITEM_WEAPON_CHAINGUN, ITEM_WEAPON_ROCKETLAUNCHER, ITEM_WEAPON_PLASMA,
 749                             ITEM_WEAPON_BFG, ITEM_WEAPON_SUPERPULEMET, ITEM_WEAPON_FLAMETHROWER,
 750                             ITEM_AMMO_BACKPACK] then
 751     begin
 752       g_Sound_PlayExAt('SOUND_ITEM_GETWEAPON', x, y);
 753     end
 754     else
 755     begin
 756       g_Sound_PlayExAt('SOUND_ITEM_GETITEM', x, y);
 757     end;
 758   end
 759   else
 760   begin
 761     if it.ItemType in [ITEM_SPHERE_BLUE, ITEM_SPHERE_WHITE, ITEM_SUIT,
 762                        ITEM_MEDKIT_BLACK, ITEM_INVUL, ITEM_INVIS, ITEM_JETPACK] then
 763     begin
 764       g_Sound_PlayExAt('SOUND_ITEM_GETRULEZ', x, y);
 765     end
 766     else if it.ItemType in [ITEM_WEAPON_SAW, ITEM_WEAPON_PISTOL, ITEM_WEAPON_SHOTGUN1, ITEM_WEAPON_SHOTGUN2,
 767                             ITEM_WEAPON_CHAINGUN, ITEM_WEAPON_ROCKETLAUNCHER, ITEM_WEAPON_PLASMA,
 768                             ITEM_WEAPON_BFG, ITEM_WEAPON_SUPERPULEMET, ITEM_WEAPON_FLAMETHROWER] then
 769     begin
 770       g_Sound_PlayExAt('SOUND_ITEM_GETWEAPON', x, y);
 771     end
 772     else
 773     begin
 774       g_Sound_PlayExAt('SOUND_ITEM_GETITEM', x, y);
 775     end;
 776   end;
 777 end;
 778
 779
 780 procedure g_Items_AddDynLights();
 781 var
 782   f: Integer;
 783   it: PItem;
 784 begin
 785   for f := 0 to High(ggItems) do
 786   begin
 787     it := @ggItems[f];
 788     if not it.alive then continue;
 789     case it.ItemType of
 790       ITEM_KEY_RED: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 24,  1.0, 0.0, 0.0, 0.6);
 791       ITEM_KEY_GREEN: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 24,  0.0, 1.0, 0.0, 0.6);
 792       ITEM_KEY_BLUE: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 24,  0.0, 0.0, 1.0, 0.6);
 793       ITEM_ARMOR_GREEN: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 42,  0.0, 1.0, 0.0, 0.6);
 794       ITEM_ARMOR_BLUE: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 42,  0.0, 0.0, 1.0, 0.6);
 795       ITEM_JETPACK: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 32,  1.0, 1.0, 1.0, 0.6);
 796       ITEM_SPHERE_BLUE: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 32,  0.0, 1.0, 0.0, 0.6);
 797       ITEM_SPHERE_WHITE: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 32,  1.0, 1.0, 1.0, 0.6);
 798       ITEM_INVUL: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 32,  1.0, 0.0, 0.0, 0.6);
 799       ITEM_INVIS: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 32,  1.0, 1.0, 0.0, 0.6);
 800       ITEM_BOTTLE: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 16,  0.0, 0.0, 0.8, 0.6);
 801       ITEM_HELMET: g_AddDynLight(it.Obj.X+(it.Obj.Rect.Width div 2), it.Obj.Y+(it.Obj.Rect.Height div 2), 16,  0.0, 0.8, 0.0, 0.6);
 802     end;
 803   end;
 804 end;
 805
 806
 807 end.