DEADSOFTWARE

GIT / REPO / FRED-BOY
Projects / d2df-sdl.git / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
fix turret and projectiles
[d2df-sdl.git] / src / shared / utils.pas
1 (* Copyright (C) DooM 2D:Forever Developers
2 *
3 * This program is free software: you can redistribute it and/or modify
4 * it under the terms of the GNU General Public License as published by
5 * the Free Software Foundation, either version 3 of the License, or
6 * (at your option) any later version.
7 *
8 * This program is distributed in the hope that it will be useful,
9 * but WITHOUT ANY WARRANTY; without even the implied warranty of
10 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
11 * GNU General Public License for more details.
12 *
13 * You should have received a copy of the GNU General Public License
14 * along with this program. If not, see <http://www.gnu.org/licenses/>.
15 *)
16 {$MODE DELPHI}
17 unit utils;
18
19 interface
20
21 uses
22 SysUtils, Classes;
23
24
25 // does filename have one of ".wad", ".pk3", ".zip" extensions?
26 function hasWadExtension (fn: AnsiString): Boolean;
27
28 // does filepath have ".XXX:\" in it?
29 function isWadPath (fn: AnsiString): Boolean;
30
31 // adds ".wad" extension if filename doesn't have one of ".wad", ".pk3", ".zip"
32 function addWadExtension (fn: AnsiString): AnsiString;
33
34 // convert number to strig with nice commas
35 function Int64ToStrComma (i: Int64): AnsiString;
36
37 function UpCase1251 (ch: Char): Char;
38 function LoCase1251 (ch: Char): Char;
39
40 // `true` if strings are equal; ignoring case for cp1251
41 function StrEquCI1251 (const s0, s1: AnsiString): Boolean;
42
43 function utf8Valid (const s: AnsiString): Boolean;
44
45 function utf8to1251 (s: AnsiString): AnsiString;
46
47 // `pathname` will be modified if path is valid
48 // `lastIsDir` should be `true` if we are searching for directory
49 // nobody cares about shitdoze, so i'll use the same code path for it
50 function findFileCI (var pathname: AnsiString; lastIsDir: Boolean=false): Boolean;
51
52 // they throws
53 function openDiskFileRO (pathname: AnsiString): TStream;
54 function createDiskFile (pathname: AnsiString): TStream;
55
56 // little endian
57 procedure writeInt (st: TStream; v: Byte); overload;
58 procedure writeInt (st: TStream; v: ShortInt); overload;
59 procedure writeInt (st: TStream; v: Word); overload;
60 procedure writeInt (st: TStream; v: SmallInt); overload;
61 procedure writeInt (st: TStream; v: LongWord); overload;
62 procedure writeInt (st: TStream; v: LongInt); overload;
63 procedure writeInt (st: TStream; v: Int64); overload;
64 procedure writeInt (st: TStream; v: UInt64); overload;
65
66 function readByte (st: TStream): Byte;
67 function readShortInt (st: TStream): ShortInt;
68 function readWord (st: TStream): Word;
69 function readSmallInt (st: TStream): SmallInt;
70 function readLongWord (st: TStream): LongWord;
71 function readLongInt (st: TStream): LongInt;
72 function readInt64 (st: TStream): Int64;
73 function readUInt64 (st: TStream): UInt64;
74
75 // big endian
76 procedure writeIntBE (st: TStream; v: Byte); overload;
77 procedure writeIntBE (st: TStream; v: ShortInt); overload;
78 procedure writeIntBE (st: TStream; v: Word); overload;
79 procedure writeIntBE (st: TStream; v: SmallInt); overload;
80 procedure writeIntBE (st: TStream; v: LongWord); overload;
81 procedure writeIntBE (st: TStream; v: LongInt); overload;
82 procedure writeIntBE (st: TStream; v: Int64); overload;
83 procedure writeIntBE (st: TStream; v: UInt64); overload;
84
85 function readByteBE (st: TStream): Byte;
86 function readShortIntBE (st: TStream): ShortInt;
87 function readWordBE (st: TStream): Word;
88 function readSmallIntBE (st: TStream): SmallInt;
89 function readLongWordBE (st: TStream): LongWord;
90 function readLongIntBE (st: TStream): LongInt;
91 function readInt64BE (st: TStream): Int64;
92 function readUInt64BE (st: TStream): UInt64;
93
94
95 implementation
96
97
98 function hasWadExtension (fn: AnsiString): Boolean;
99 begin
100 fn := ExtractFileExt(fn);
101 result := StrEquCI1251(fn, '.wad') or StrEquCI1251(fn, '.pk3') or StrEquCI1251(fn, '.zip');
102 end;
103
104
105 function addWadExtension (fn: AnsiString): AnsiString;
106 begin
107 result := fn;
108 if not hasWadExtension(result) then result := result+'.wad';
109 end;
110
111
112 function isWadPath (fn: AnsiString): Boolean;
113 var
114 p: Integer;
115 s: AnsiString;
116 begin
117 result := false;
118 while true do
119 begin
120 p := Pos(':', fn);
121 if (p = 0) or (length(fn)-p < 1) then break;
122 if (p-4 > 1) and (fn[p-4] = '.') and ((fn[p+1] = '\') or (fn[p+1] = '/')) then
123 begin
124 s := Copy(fn, p-4, 4);
125 if StrEquCI1251(s, '.wad') or StrEquCI1251(s, '.pk3') or StrEquCI1251(s, '.zip') then
126 begin
127 result := true;
128 exit;
129 end;
130 end;
131 Delete(fn, 1, p);
132 end;
133 end;
134
135
136 function Int64ToStrComma (i: Int64): AnsiString;
137 var
138 f: Integer;
139 begin
140 Str(i, result);
141 f := Length(result)+1;
142 while f > 4 do
143 begin
144 Dec(f, 3); Insert(',', result, f);
145 end;
146 end;
147
148
149 function UpCase1251 (ch: Char): Char;
150 begin
151 if ch < #128 then
152 begin
153 if (ch >= 'a') and (ch <= 'z') then Dec(ch, 32);
154 end
155 else
156 begin
157 if (ch >= #224) and (ch <= #255) then
158 begin
159 Dec(ch, 32);
160 end
161 else
162 begin
163 case ch of
164 #184, #186, #191: Dec(ch, 16);
165 #162, #179: Dec(ch);
166 end;
167 end;
168 end;
169 result := ch;
170 end;
171
172
173 function LoCase1251 (ch: Char): Char;
174 begin
175 if ch < #128 then
176 begin
177 if (ch >= 'A') and (ch <= 'Z') then Inc(ch, 32);
178 end
179 else
180 begin
181 if (ch >= #192) and (ch <= #223) then
182 begin
183 Inc(ch, 32);
184 end
185 else
186 begin
187 case ch of
188 #168, #170, #175: Inc(ch, 16);
189 #161, #178: Inc(ch);
190 end;
191 end;
192 end;
193 result := ch;
194 end;
195
196
197 function StrEquCI1251 (const s0, s1: AnsiString): Boolean;
198 var
199 i: Integer;
200 begin
201 result := false;
202 if length(s0) <> length(s1) then exit;
203 for i := 1 to length(s0) do if UpCase1251(s0[i]) <> UpCase1251(s1[i]) then exit;
204 result := true;
205 end;
206
207
208 // ////////////////////////////////////////////////////////////////////////// //
209 // utils
210 // `ch`: utf8 start
211 // -1: invalid utf8
212 function utf8CodeLen (ch: Word): Integer;
213 begin
214 if ch < $80 then begin result := 1; exit; end;
215 if (ch and $FE) = $FC then begin result := 6; exit; end;
216 if (ch and $FC) = $F8 then begin result := 5; exit; end;
217 if (ch and $F8) = $F0 then begin result := 4; exit; end;
218 if (ch and $F0) = $E0 then begin result := 3; exit; end;
219 if (ch and $E0) = $C0 then begin result := 2; exit; end;
220 result := -1; // invalid
221 end;
222
223
224 function utf8Valid (const s: AnsiString): Boolean;
225 var
226 pos, len: Integer;
227 begin
228 result := false;
229 pos := 1;
230 while pos <= length(s) do
231 begin
232 len := utf8CodeLen(Byte(s[pos]));
233 if len < 1 then exit; // invalid sequence start
234 if pos+len-1 > length(s) then exit; // out of chars in string
235 Dec(len);
236 Inc(pos);
237 // check other sequence bytes
238 while len > 0 do
239 begin
240 if (Byte(s[pos]) and $C0) <> $80 then exit;
241 Dec(len);
242 Inc(pos);
243 end;
244 end;
245 result := true;
246 end;
247
248
249 // ////////////////////////////////////////////////////////////////////////// //
250 const
251 uni2wint: array [128..255] of Word = (
252 $0402,$0403,$201A,$0453,$201E,$2026,$2020,$2021,$20AC,$2030,$0409,$2039,$040A,$040C,$040B,$040F,
253 $0452,$2018,$2019,$201C,$201D,$2022,$2013,$2014,$003F,$2122,$0459,$203A,$045A,$045C,$045B,$045F,
254 $00A0,$040E,$045E,$0408,$00A4,$0490,$00A6,$00A7,$0401,$00A9,$0404,$00AB,$00AC,$00AD,$00AE,$0407,
255 $00B0,$00B1,$0406,$0456,$0491,$00B5,$00B6,$00B7,$0451,$2116,$0454,$00BB,$0458,$0405,$0455,$0457,
256 $0410,$0411,$0412,$0413,$0414,$0415,$0416,$0417,$0418,$0419,$041A,$041B,$041C,$041D,$041E,$041F,
257 $0420,$0421,$0422,$0423,$0424,$0425,$0426,$0427,$0428,$0429,$042A,$042B,$042C,$042D,$042E,$042F,
258 $0430,$0431,$0432,$0433,$0434,$0435,$0436,$0437,$0438,$0439,$043A,$043B,$043C,$043D,$043E,$043F,
259 $0440,$0441,$0442,$0443,$0444,$0445,$0446,$0447,$0448,$0449,$044A,$044B,$044C,$044D,$044E,$044F
260 );
261
262
263 function decodeUtf8Char (s: AnsiString; var pos: Integer): char;
264 var
265 b, c: Integer;
266 begin
267 (* The following encodings are valid, except for the 5 and 6 byte
268 * combinations:
269 * 0xxxxxxx
270 * 110xxxxx 10xxxxxx
271 * 1110xxxx 10xxxxxx 10xxxxxx
272 * 11110xxx 10xxxxxx 10xxxxxx 10xxxxxx
273 * 111110xx 10xxxxxx 10xxxxxx 10xxxxxx 10xxxxxx
274 * 1111110x 10xxxxxx 10xxxxxx 10xxxxxx 10xxxxxx 10xxxxxx
275 *)
276 result := '?';
277 if pos > length(s) then exit;
278
279 b := Byte(s[pos]);
280 Inc(pos);
281 if b < $80 then begin result := char(b); exit; end;
282
283 // mask out unused bits
284 if (b and $FE) = $FC then b := b and $01
285 else if (b and $FC) = $F8 then b := b and $03
286 else if (b and $F8) = $F0 then b := b and $07
287 else if (b and $F0) = $E0 then b := b and $0F
288 else if (b and $E0) = $C0 then b := b and $1F
289 else exit; // invalid utf8
290
291 // now continue
292 while pos <= length(s) do
293 begin
294 c := Byte(s[pos]);
295 if (c and $C0) <> $80 then break; // no more
296 b := b shl 6;
297 b := b or (c and $3F);
298 Inc(pos);
299 end;
300
301 // done, try 1251
302 for c := 128 to 255 do if uni2wint[c] = b then begin result := char(c and $FF); exit; end;
303 // alas
304 end;
305
306
307 function utf8to1251 (s: AnsiString): AnsiString;
308 var
309 pos: Integer;
310 begin
311 if not utf8Valid(s) then begin result := s; exit; end;
312 pos := 1;
313 while pos <= length(s) do
314 begin
315 if Byte(s[pos]) >= $80 then break;
316 Inc(pos);
317 end;
318 if pos > length(s) then begin result := s; exit; end; // nothing to do here
319 result := '';
320 pos := 1;
321 while pos <= length(s) do result := result+decodeUtf8Char(s, pos);
322 end;
323
324
325 // ////////////////////////////////////////////////////////////////////////// //
326 // `pathname` will be modified if path is valid
327 // `lastIsDir` should be `true` if we are searching for directory
328 // nobody cares about shitdoze, so i'll use the same code path for it
329 function findFileCI (var pathname: AnsiString; lastIsDir: Boolean=false): Boolean;
330 var
331 sr: TSearchRec;
332 npt: AnsiString;
333 newname: AnsiString = '';
334 curname: AnsiString;
335 wantdir: Boolean;
336 attr: LongInt;
337 foundher: Boolean;
338 begin
339 npt := pathname;
340 result := (length(npt) > 0);
341 if (length(npt) > 0) and ((npt[1] = '/') or (npt[1] = '\')) then newname := '/';
342 while length(npt) > 0 do
343 begin
344 // remove trailing slashes
345 while (length(npt) > 0) and ((npt[1] = '/') or (npt[1] = '\')) do Delete(npt, 1, 1);
346 if length(npt) = 0 then break;
347 // extract name
348 curname := '';
349 while (length(npt) > 0) and (npt[1] <> '/') and (npt[1] <> '\') do
350 begin
351 curname := curname+npt[1];
352 Delete(npt, 1, 1);
353 end;
354 // remove trailing slashes again
355 while (length(npt) > 0) and ((npt[1] = '/') or (npt[1] = '\')) do Delete(npt, 1, 1);
356 wantdir := lastIsDir or (length(npt) > 0); // do we want directory here?
357 //writeln(Format('npt=[%s]; newname=[%s]; curname=[%s]; wantdir=%d', [npt, newname, curname, Integer(wantdir)]));
358 // try the easiest case first
359 attr := FileGetAttr(newname+curname);
360 if attr <> -1 then
361 begin
362 if wantdir = ((attr and faDirectory) <> 0) then
363 begin
364 // i found her!
365 newname := newname+curname;
366 if wantdir then newname := newname+'/';
367 continue;
368 end;
369 end;
370 //writeln(Format('npt=[%s]; newname=[%s]; curname=[%s]; wantdir=%d', [npt, newname, curname, Integer(wantdir)]));
371 // alas, either not found, or invalid attributes
372 foundher := false;
373 try
374 if FindFirst(newname+'*', faAnyFile, sr) = 0 then
375 repeat
376 if (wantdir = ((sr.attr and faDirectory) <> 0)) and StrEquCI1251(sr.name, curname) then
377 begin
378 // i found her!
379 newname := newname+sr.name;
380 if wantdir then newname := newname+'/';
381 foundher := true;
382 break;
383 end;
384 until FindNext(sr) <> 0;
385 finally
386 FindClose(sr);
387 end;
388 if not foundher then begin newname := ''; result := false; break; end;
389 end;
390 if result then pathname := newname;
391 end;
392
393
394 function openDiskFileRO (pathname: AnsiString): TStream;
395 begin
396 if not findFileCI(pathname) then raise Exception.Create('can''t open file "'+pathname+'"');
397 result := TFileStream.Create(pathname, fmOpenRead or {fmShareDenyWrite}fmShareDenyNone);
398 end;
399
400 function createDiskFile (pathname: AnsiString): TStream;
401 var
402 path: AnsiString;
403 begin
404 path := ExtractFilePath(pathname);
405 if length(path) > 0 then
406 begin
407 if not findFileCI(path, true) then raise Exception.Create('can''t create file "'+pathname+'"');
408 end;
409 result := TFileStream.Create(path+ExtractFileName(pathname), fmCreate);
410 end;
411
412
413 procedure writeIntegerLE (st: TStream; vp: Pointer; size: Integer);
414 {$IFDEF ENDIAN_LITTLE}
415 begin
416 st.writeBuffer(vp^, size);
417 end;
418 {$ELSE}
419 var
420 p: PByte;
421 begin
422 p := PByte(vp)+size-1;
423 while size > 0 do
424 begin
425 st.writeBuffer(p^, 1);
426 Dec(size);
427 Dec(p);
428 end;
429 end;
430 {$ENDIF}
431
432 procedure writeIntegerBE (st: TStream; vp: Pointer; size: Integer);
433 {$IFDEF ENDIAN_LITTLE}
434 var
435 p: PByte;
436 begin
437 p := PByte(vp)+size-1;
438 while size > 0 do
439 begin
440 st.writeBuffer(p^, 1);
441 Dec(size);
442 Dec(p);
443 end;
444 end;
445 {$ELSE}
446 begin
447 st.writeBuffer(vp^, size);
448 end;
449 {$ENDIF}
450
451 procedure writeInt (st: TStream; v: Byte); overload; begin writeIntegerLE(st, @v, 1); end;
452 procedure writeInt (st: TStream; v: ShortInt); overload; begin writeIntegerLE(st, @v, 1); end;
453 procedure writeInt (st: TStream; v: Word); overload; begin writeIntegerLE(st, @v, 2); end;
454 procedure writeInt (st: TStream; v: SmallInt); overload; begin writeIntegerLE(st, @v, 2); end;
455 procedure writeInt (st: TStream; v: LongWord); overload; begin writeIntegerLE(st, @v, 4); end;
456 procedure writeInt (st: TStream; v: LongInt); overload; begin writeIntegerLE(st, @v, 4); end;
457 procedure writeInt (st: TStream; v: Int64); overload; begin writeIntegerLE(st, @v, 8); end;
458 procedure writeInt (st: TStream; v: UInt64); overload; begin writeIntegerLE(st, @v, 8); end;
459
460 procedure writeIntBE (st: TStream; v: Byte); overload; begin writeIntegerBE(st, @v, 1); end;
461 procedure writeIntBE (st: TStream; v: ShortInt); overload; begin writeIntegerBE(st, @v, 1); end;
462 procedure writeIntBE (st: TStream; v: Word); overload; begin writeIntegerBE(st, @v, 2); end;
463 procedure writeIntBE (st: TStream; v: SmallInt); overload; begin writeIntegerBE(st, @v, 2); end;
464 procedure writeIntBE (st: TStream; v: LongWord); overload; begin writeIntegerBE(st, @v, 4); end;
465 procedure writeIntBE (st: TStream; v: LongInt); overload; begin writeIntegerBE(st, @v, 4); end;
466 procedure writeIntBE (st: TStream; v: Int64); overload; begin writeIntegerBE(st, @v, 8); end;
467 procedure writeIntBE (st: TStream; v: UInt64); overload; begin writeIntegerBE(st, @v, 8); end;
468
469
470 procedure readIntegerLE (st: TStream; vp: Pointer; size: Integer);
471 {$IFDEF ENDIAN_LITTLE}
472 begin
473 st.readBuffer(vp^, size);
474 end;
475 {$ELSE}
476 var
477 p: PByte;
478 begin
479 p := PByte(vp)+size-1;
480 while size > 0 do
481 begin
482 st.readBuffer(p^, 1);
483 Dec(size);
484 Dec(p);
485 end;
486 end;
487 {$ENDIF}
488
489 procedure readIntegerBE (st: TStream; vp: Pointer; size: Integer);
490 {$IFDEF ENDIAN_LITTLE}
491 var
492 p: PByte;
493 begin
494 p := PByte(vp)+size-1;
495 while size > 0 do
496 begin
497 st.readBuffer(p^, 1);
498 Dec(size);
499 Dec(p);
500 end;
501 end;
502 {$ELSE}
503 begin
504 st.readBuffer(vp^, size);
505 end;
506 {$ENDIF}
507
508 function readByte (st: TStream): Byte; begin readIntegerLE(st, @result, 1); end;
509 function readShortInt (st: TStream): ShortInt; begin readIntegerLE(st, @result, 1); end;
510 function readWord (st: TStream): Word; begin readIntegerLE(st, @result, 2); end;
511 function readSmallInt (st: TStream): SmallInt; begin readIntegerLE(st, @result, 2); end;
512 function readLongWord (st: TStream): LongWord; begin readIntegerLE(st, @result, 4); end;
513 function readLongInt (st: TStream): LongInt; begin readIntegerLE(st, @result, 4); end;
514 function readInt64 (st: TStream): Int64; begin readIntegerLE(st, @result, 8); end;
515 function readUInt64 (st: TStream): UInt64; begin readIntegerLE(st, @result, 8); end;
516
517 function readByteBE (st: TStream): Byte; begin readIntegerBE(st, @result, 1); end;
518 function readShortIntBE (st: TStream): ShortInt; begin readIntegerBE(st, @result, 1); end;
519 function readWordBE (st: TStream): Word; begin readIntegerBE(st, @result, 2); end;
520 function readSmallIntBE (st: TStream): SmallInt; begin readIntegerBE(st, @result, 2); end;
521 function readLongWordBE (st: TStream): LongWord; begin readIntegerBE(st, @result, 4); end;
522 function readLongIntBE (st: TStream): LongInt; begin readIntegerBE(st, @result, 4); end;
523 function readInt64BE (st: TStream): Int64; begin readIntegerBE(st, @result, 8); end;
524 function readUInt64BE (st: TStream): UInt64; begin readIntegerBE(st, @result, 8); end;
525
526
527 end.
[MIRROR] a port of Doom 2D Forever to FPC/SDL
[15/08/2024 14:52:34]
DEADSOFTWARE 2012-2024