src/game/sdl2/g_system.pas

   1 (* Copyright (C)  Doom 2D: Forever Developers
   2  *
   3  * This program is free software: you can redistribute it and/or modify
   4  * it under the terms of the GNU General Public License as published by
   5  * the Free Software Foundation, version 3 of the License ONLY.
   6  *
   7  * This program is distributed in the hope that it will be useful,
   8  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   9  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  10  * GNU General Public License for more details.
  11  *
  12  * You should have received a copy of the GNU General Public License
  13  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  14  *)
  15 {$INCLUDE ../shared/a_modes.inc}
  16 unit g_system;
  17
  18 interface
  19
  20   uses Utils;
  21
  22   (* --- Graphics --- *)
  23   function sys_GetDisplayModes (bpp: Integer): SSArray;
  24   function sys_SetDisplayMode (w, h, bpp: Integer; fullscreen, maximized: Boolean): Boolean;
  25   procedure sys_EnableVSync (yes: Boolean);
  26   procedure sys_Repaint;
  27
  28   (* --- Input --- *)
  29   function sys_HandleInput (): Boolean;
  30   procedure sys_RequestQuit;
  31
  32   (* --- Init --- *)
  33   procedure sys_Init;
  34   procedure sys_Final;
  35
  36   var (* hooks *)
  37     sys_CharPress: procedure (ch: AnsiChar) = nil;
  38     sys_ScreenResize: procedure (w, h: Integer) = nil;
  39
  40 implementation
  41
  42   uses
  43     SysUtils, SDL2, Math, ctypes,
  44     e_log, e_input, e_sound,
  45     {$IFDEF ENABLE_HOLMES}
  46       sdlcarcass,
  47     {$ENDIF}
  48     g_touch, g_options, g_console, g_game, g_basic
  49   ;
  50
  51   const
  52     GameTitle = 'Doom 2D: Forever (SDL 2, %s)';
  53
  54   var
  55     window: PSDL_Window;
  56     context: TSDL_GLContext;
  57     display, wx, wy: Integer;
  58     wc: Boolean;
  59     JoystickHandle: array [0..e_MaxJoys - 1] of PSDL_Joystick;
  60     JoystickHatState: array [0..e_MaxJoys - 1, 0..e_MaxJoyHats - 1, HAT_LEFT..HAT_DOWN] of Boolean;
  61     JoystickZeroAxes: array [0..e_MaxJoys - 1, 0..e_MaxJoyAxes - 1] of Integer;
  62
  63   (* --------- Graphics --------- *)
  64
  65   function GetTitle (): AnsiString;
  66     var info: AnsiString;
  67   begin
  68     info := g_GetBuildHash(false);
  69     if info = 'custom build' then
  70       info := info + ' by ' + g_GetBuilderName() + ' ' + GAME_BUILDDATE + ' ' + GAME_BUILDTIME;
  71     result := Format(GameTitle, [info]);
  72   end;
  73
  74   function InitWindow (w, h, bpp: Integer; fullScreen, maximized: Boolean): Boolean;
  75     var flags: UInt32; x, y: cint; title: AnsiString;
  76   begin
  77     // note: on window close make: if assigned(oglDeinitCB) then oglDeinitCB;
  78     e_LogWritefln('InitWindow %s %s %s %s', [w, h, bpp, fullScreen]);
  79     result := false;
  80     if window = nil then
  81     begin
  82       {$IFDEF USE_GLES1}
  83         SDL_GL_SetAttribute(SDL_GL_CONTEXT_MAJOR_VERSION, 1);
  84         SDL_GL_SetAttribute(SDL_GL_CONTEXT_MINOR_VERSION, 1);
  85         SDL_GL_SetAttribute(SDL_GL_CONTEXT_PROFILE_MASK, SDL_GL_CONTEXT_PROFILE_ES);
  86       {$ELSE}
  87         SDL_GL_SetAttribute(SDL_GL_CONTEXT_MAJOR_VERSION, 2);
  88         SDL_GL_SetAttribute(SDL_GL_CONTEXT_MINOR_VERSION, 1);
  89         SDL_GL_SetAttribute(SDL_GL_RED_SIZE, 8);
  90         SDL_GL_SetAttribute(SDL_GL_GREEN_SIZE, 8);
  91         SDL_GL_SetAttribute(SDL_GL_BLUE_SIZE, 8);
  92         SDL_GL_SetAttribute(SDL_GL_DEPTH_SIZE, 16);
  93         SDL_GL_SetAttribute(SDL_GL_DOUBLEBUFFER, 1);
  94         SDL_GL_SetAttribute(SDL_GL_STENCIL_SIZE, 8); // lights; it is enough to have 1-bit stencil buffer for lighting, but...
  95       {$ENDIF}
  96       flags := SDL_WINDOW_OPENGL or SDL_WINDOW_RESIZABLE;
  97       if fullScreen then flags := flags or SDL_WINDOW_FULLSCREEN;
  98       if maximized then flags := flags or SDL_WINDOW_MAXIMIZED;
  99       if wc then
 100       begin
 101         x := SDL_WINDOWPOS_CENTERED;
 102         y := SDL_WINDOWPOS_CENTERED
 103       end
 104       else
 105       begin
 106         x := wx;
 107         y := wy
 108       end;
 109       title := GetTitle();
 110       window := SDL_CreateWindow(PChar(title), x, y, w, h, flags);
 111       if window <> nil then
 112       begin
 113         context := SDL_GL_CreateContext(window);
 114         if context <> nil then
 115         begin
 116           if (fullscreen = false) and (maximized = false) and (wc = false) then
 117           begin
 118             SDL_GetWindowPosition(window, @x, @y);
 119             wx := x; wy := y
 120           end;
 121           gFullScreen := fullscreen;
 122           gWinMaximized := maximized;
 123           gRC_FullScreen := fullscreen;
 124           gRC_Maximized := maximized;
 125           if @sys_ScreenResize <> nil then
 126             sys_ScreenResize(w, h);
 127           result := true
 128         end
 129         else
 130         begin
 131           // SDL_DestroyWindow(window);
 132           e_LogWritefln('SDL: unable to create OpenGL context: %s', [SDL_GetError])
 133         end
 134       end
 135       else
 136       begin
 137         e_LogWritefln('SDL: unable to create window: %s', [SDL_GetError])
 138       end
 139     end
 140     else
 141     begin
 142       if fullScreen then flags := SDL_WINDOW_FULLSCREEN else flags := 0;
 143       SDL_SetWindowFullscreen(window, flags);
 144       SDL_SetWindowSize(window, w, h);
 145       if maximized then SDL_MaximizeWindow(window);
 146       // always reset to center when changing fullscreen->windowed for safety purposes
 147       if wc or (gFullscreen and not fullscreen) or (gWinMaximized and not maximized) then
 148       begin
 149         x := SDL_WINDOWPOS_CENTERED;
 150         y := SDL_WINDOWPOS_CENTERED
 151       end
 152       else
 153       begin
 154         x := wx;
 155         y := wy
 156       end;
 157       SDL_SetWindowPosition(window, x, y);
 158       if (fullscreen = false) and (maximized = false) and (wc = false) then
 159       begin
 160         SDL_GetWindowPosition(window, @x, @y);
 161         wx := x; wy := y
 162       end;
 163       gFullScreen := fullscreen;
 164       gWinMaximized := maximized;
 165       gRC_FullScreen := fullscreen;
 166       gRC_Maximized := maximized;
 167       if @sys_ScreenResize <> nil then
 168         sys_ScreenResize(w, h);
 169       result := true
 170     end
 171   end;
 172
 173   procedure sys_Repaint;
 174   begin
 175     SDL_GL_SwapWindow(window)
 176   end;
 177
 178   procedure sys_EnableVSync (yes: Boolean);
 179   begin
 180     if yes then
 181       SDL_GL_SetSwapInterval(1)
 182     else
 183       SDL_GL_SetSwapInterval(0)
 184   end;
 185
 186   function sys_GetDisplayModes (bpp: Integer): SSArray;
 187     var i, count, num, pw, ph: Integer; m: TSDL_DisplayMode;
 188   begin
 189     result := nil;
 190     num := SDL_GetNumDisplayModes(display);
 191     if num < 0 then
 192       e_LogWritefln('SDL: unable to get numer of available display modes: %s', [SDL_GetError]);
 193     if num > 0 then
 194     begin
 195       e_LogWritefln('Video modes for display %s:', [display]);
 196       SetLength(result, num);
 197       i := 0; count := 0; pw := 0; ph := 0;
 198       while i < num do
 199       begin
 200         SDL_GetDisplayMode(display, i, @m);
 201         if ((pw <> m.w) or (ph <> m.h)) then
 202         begin
 203           e_LogWritefln('* %sx%sx%s@%s', [m.w, m.h, SDL_BITSPERPIXEL(m.format), m.refresh_rate]);
 204           pw := m.w; ph := m.h;
 205           result[count] := IntToStr(m.w) + 'x' + IntToStr(m.h);
 206           Inc(count);
 207         end
 208         else
 209         begin
 210           e_LogWritefln('- %sx%sx%s@%s', [m.w, m.h, SDL_BITSPERPIXEL(m.format), m.refresh_rate]);
 211         end;
 212         Inc(i)
 213       end;
 214       SetLength(result, count)
 215     end
 216   end;
 217
 218   function sys_SetDisplayMode (w, h, bpp: Integer; fullScreen, maximized: Boolean): Boolean;
 219   begin
 220     result := InitWindow(w, h, bpp, fullScreen, maximized)
 221   end;
 222
 223   (* --------- Joystick --------- *)
 224
 225   procedure HandleJoyButton (var ev: TSDL_JoyButtonEvent);
 226     var down: Boolean; key: Integer;
 227   begin
 228     if (ev.which < e_MaxJoys) and (ev.button < e_MaxJoyBtns) then
 229     begin
 230       key := e_JoyButtonToKey(ev.which, ev.button);
 231       down := ev.type_ = SDL_JOYBUTTONDOWN;
 232       if g_dbg_input then
 233         e_LogWritefln('Input Debug: jbutton, joy=%s, button=%s, keycode=%s, press=%s', [ev.which, ev.button, key, down]);
 234       e_KeyUpDown(key, down);
 235       g_Console_ProcessBind(key, down)
 236     end
 237     else
 238     begin
 239       if g_dbg_input then
 240       begin
 241         down := ev.type_ = SDL_JOYBUTTONDOWN;
 242         e_LogWritefln('Input Debug: NOT IN RANGE! jbutton, joy=%s, button=%s, press=%s', [ev.which, ev.button, down])
 243       end
 244     end
 245   end;
 246
 247   procedure HandleJoyAxis (var ev: TSDL_JoyAxisEvent);
 248     var key, minuskey: Integer;
 249   begin
 250     if (ev.which < e_MaxJoys) and (ev.axis < e_MaxJoyAxes) then
 251     begin
 252       key := e_JoyAxisToKey(ev.which, ev.axis, AX_PLUS);
 253       minuskey := e_JoyAxisToKey(ev.which, ev.axis, AX_MINUS);
 254
 255       if g_dbg_input then
 256           e_LogWritefln('Input Debug: jaxis, joy=%s, axis=%s, value=%s, zeroaxes=%s, deadzone=%s', [ev.which, ev.axis, ev.value, JoystickZeroAxes[ev.which, ev.axis], e_JoystickDeadzones[ev.which]]);
 257
 258       if ev.value < JoystickZeroAxes[ev.which, ev.axis] - e_JoystickDeadzones[ev.which] then
 259       begin
 260         if (e_KeyPressed(key)) then
 261         begin
 262           e_KeyUpDown(key, False);
 263           g_Console_ProcessBind(key, False)
 264         end;
 265         e_KeyUpDown(minuskey, True);
 266         g_Console_ProcessBind(minuskey, True)
 267       end
 268       else if ev.value > JoystickZeroAxes[ev.which, ev.axis] + e_JoystickDeadzones[ev.which] then
 269       begin
 270         if (e_KeyPressed(minuskey)) then
 271         begin
 272           e_KeyUpDown(minuskey, False);
 273           g_Console_ProcessBind(minuskey, False)
 274         end;
 275         e_KeyUpDown(key, True);
 276         g_Console_ProcessBind(key, True)
 277       end
 278       else
 279       begin
 280         if (e_KeyPressed(minuskey)) then
 281         begin
 282           e_KeyUpDown(minuskey, False);
 283           g_Console_ProcessBind(minuskey, False)
 284         end;
 285         if (e_KeyPressed(key)) then
 286         begin
 287           e_KeyUpDown(key, False);
 288           g_Console_ProcessBind(key, False)
 289         end
 290       end
 291     end
 292     else
 293     begin
 294       if g_dbg_input then
 295         e_LogWritefln('Input Debug: NOT IN RANGE! jaxis, joy=%s, axis=%s, value=%s, zeroaxes=%s, deadzone=%s', [ev.which, ev.axis, ev.value, JoystickZeroAxes[ev.which, ev.axis], e_JoystickDeadzones[ev.which]])
 296     end
 297   end;
 298
 299   procedure HandleJoyHat (var ev: TSDL_JoyHatEvent);
 300     var
 301       down: Boolean;
 302       i, key: Integer;
 303       hat: array [HAT_LEFT..HAT_DOWN] of Boolean;
 304   begin
 305     if (ev.which < e_MaxJoys) and (ev.hat < e_MaxJoyHats) then
 306     begin
 307       if g_dbg_input then
 308         e_LogWritefln('Input Debug: jhat, joy=%s, hat=%s, value=%s', [ev.which, ev.hat, ev.value]);
 309       hat[HAT_UP] := LongBool(ev.value and SDL_HAT_UP);
 310       hat[HAT_DOWN] := LongBool(ev.value and SDL_HAT_DOWN);
 311       hat[HAT_LEFT] := LongBool(ev.value and SDL_HAT_LEFT);
 312       hat[HAT_RIGHT] := LongBool(ev.value and SDL_HAT_RIGHT);
 313       for i := HAT_LEFT to HAT_DOWN do
 314       begin
 315         if JoystickHatState[ev.which, ev.hat, i] <> hat[i] then
 316         begin
 317           down := hat[i];
 318           key := e_JoyHatToKey(ev.which, ev.hat, i);
 319           e_KeyUpDown(key, down);
 320           g_Console_ProcessBind(key, down)
 321         end
 322       end;
 323       JoystickHatState[ev.which, ev.hat] := hat
 324     end
 325     else
 326     begin
 327       if g_dbg_input then
 328         e_LogWritefln('Input Debug: NOT IN RANGE! jhat, joy=%s, hat=%s, value=%s', [ev.which, ev.hat, ev.value])
 329     end
 330   end;
 331
 332   procedure HandleJoyAdd (var ev: TSDL_JoyDeviceEvent);
 333     var i: Integer;
 334   begin
 335     if (ev.which < e_MaxJoys) then
 336     begin
 337       JoystickHandle[ev.which] := SDL_JoystickOpen(ev.which);
 338       if JoystickHandle[ev.which] <> nil then
 339       begin
 340         e_LogWritefln('Added Joystick %s', [ev.which]);
 341         e_JoystickAvailable[ev.which] := True;
 342         for i := 0 to Min(SDL_JoystickNumAxes(JoystickHandle[ev.which]), e_MaxJoyAxes) - 1 do
 343           JoystickZeroAxes[ev.which, i] := SDL_JoystickGetAxis(JoystickHandle[ev.which], i)
 344       end
 345       else
 346       begin
 347         e_LogWritefln('Warning! Failed to open Joystick %s', [ev.which])
 348       end
 349     end
 350     else
 351     begin
 352       e_LogWritefln('Warning! Added Joystick %s, but we support only <= %s', [ev.which, e_MaxJoys])
 353     end
 354   end;
 355
 356   procedure HandleJoyRemove (var ev: TSDL_JoyDeviceEvent);
 357   begin
 358     e_LogWritefln('Removed Joystick %s', [ev.which]);
 359     if (ev.which < e_MaxJoys) then
 360     begin
 361       e_JoystickAvailable[ev.which] := False;
 362       if JoystickHandle[ev.which] <> nil then
 363         SDL_JoystickClose(JoystickHandle[ev.which]);
 364       JoystickHandle[ev.which] := nil
 365     end
 366   end;
 367
 368   (* --------- Input --------- *)
 369
 370   function HandleWindow (var ev: TSDL_WindowEvent): Boolean;
 371   begin
 372     result := false;
 373     if g_dbg_input then
 374       e_LogWritefln('Window Event: event = %s, data1 = %s, data2 = %s', [ev.event, ev.data1, ev.data2]);
 375     case ev.event of
 376       SDL_WINDOWEVENT_RESIZED:
 377         if @sys_ScreenResize <> nil then
 378           sys_ScreenResize(ev.data1, ev.data2);
 379       SDL_WINDOWEVENT_EXPOSED: sys_Repaint;
 380       SDL_WINDOWEVENT_CLOSE: result := true;
 381       SDL_WINDOWEVENT_MOVED:
 382         begin
 383           wx := ev.data1;
 384           wy := ev.data2
 385         end;
 386       SDL_WINDOWEVENT_FOCUS_LOST, SDL_WINDOWEVENT_MINIMIZED:
 387         begin
 388           e_UnpressAllKeys;
 389           if gMuteWhenInactive then
 390             e_MuteChannels(true);
 391           {$IFDEF ENABLE_HOLMES}
 392             if assigned(winBlurCB) then winBlurCB;
 393           {$ENDIF}
 394         end;
 395       SDL_WINDOWEVENT_FOCUS_GAINED, SDL_WINDOWEVENT_MAXIMIZED, SDL_WINDOWEVENT_RESTORED:
 396         begin
 397           if ev.event = SDL_WINDOWEVENT_MAXIMIZED then
 398           begin
 399             gWinMaximized := true;
 400             gRC_Maximized := true
 401           end
 402           else if ev.event = SDL_WINDOWEVENT_RESTORED then
 403           begin
 404             gWinMaximized := false;
 405             gRC_Maximized := false
 406           end;
 407           e_MuteChannels(false);
 408           {$IFDEF ENABLE_HOLMES}
 409             if assigned(winFocusCB) then winFocusCB;
 410           {$ENDIF}
 411         end;
 412     end
 413   end;
 414
 415   procedure HandleKeyboard (var ev: TSDL_KeyboardEvent);
 416     var down: Boolean; key: Integer;
 417   begin
 418     key := ev.keysym.scancode;
 419     down := (ev.type_ = SDL_KEYDOWN);
 420     if key = SDL_SCANCODE_AC_BACK then
 421       key := SDL_SCANCODE_ESCAPE;
 422     {$IFDEF ENABLE_HOLMES}
 423       if fuiOnSDLEvent(PSDL_Event(@ev)^) then
 424       begin
 425         // event eaten, but...
 426         if not down then e_KeyUpDown(key, false);
 427         exit;
 428       end;
 429     {$ENDIF}
 430     if ev._repeat = 0 then
 431     begin
 432       if g_dbg_input then
 433         e_LogWritefln('Input Debug: keysym, press=%s, scancode=%s', [down, key]);
 434       e_KeyUpDown(key, down);
 435       g_Console_ProcessBind(key, down);
 436     end
 437     else
 438     begin
 439       if g_dbg_input then
 440         e_LogWritefln('Input Debug: keyrep, scancode=%s', [key]);
 441       g_Console_ProcessBindRepeat(key);
 442     end
 443   end;
 444
 445   procedure HandleTextInput (var ev: TSDL_TextInputEvent);
 446     var ch: UnicodeChar; sch: AnsiChar;
 447   begin
 448     Utf8ToUnicode(@ch, PChar(ev.text), 1);
 449     sch := AnsiChar(wchar2win(ch));
 450     if g_dbg_input then
 451       e_LogWritefln('Input Debug: text, text="%s", ch = %s, sch = %s', [ev.text, Ord(ch), Ord(sch)]);
 452     if @sys_CharPress <> nil then
 453       if IsValid1251(Word(ch)) and IsPrintable1251(ch) then
 454         sys_CharPress(sch)
 455   end;
 456
 457   function sys_HandleInput (): Boolean;
 458     var ev: TSDL_Event;
 459   begin
 460     result := false;
 461     ZeroMemory(@ev, sizeof(ev));
 462     while SDL_PollEvent(@ev) <> 0 do
 463     begin
 464       case ev.type_ of
 465         SDL_QUITEV: result := true;
 466         SDL_WINDOWEVENT: result := HandleWindow(ev.window);
 467         SDL_KEYUP, SDL_KEYDOWN: HandleKeyboard(ev.key);
 468         SDL_JOYBUTTONDOWN, SDL_JOYBUTTONUP: HandleJoyButton(ev.jbutton);
 469         SDL_JOYAXISMOTION: HandleJoyAxis(ev.jaxis);
 470         SDL_JOYHATMOTION: HandleJoyHat(ev.jhat);
 471         SDL_JOYDEVICEADDED: HandleJoyAdd(ev.jdevice);
 472         SDL_JOYDEVICEREMOVED: HandleJoyRemove(ev.jdevice);
 473         SDL_TEXTINPUT: HandleTextInput(ev.text);
 474         SDL_FINGERMOTION, SDL_FINGERDOWN, SDL_FINGERUP: g_Touch_HandleEvent(ev.tfinger);
 475         {$IFDEF ENABLE_HOLMES}
 476           SDL_MOUSEBUTTONDOWN, SDL_MOUSEBUTTONUP, SDL_MOUSEWHEEL, SDL_MOUSEMOTION: fuiOnSDLEvent(ev);
 477         {$ENDIF}
 478       end
 479     end
 480   end;
 481
 482   procedure sys_RequestQuit;
 483     var ev: TSDL_Event;
 484   begin
 485     ev.type_ := SDL_QUITEV;
 486     SDL_PushEvent(@ev)
 487   end;
 488
 489   (* --------- Init --------- *)
 490
 491   procedure sys_Init;
 492     var flags: UInt32;
 493   begin
 494     e_WriteLog('Init SDL2', TMsgType.Notify);
 495     {$IFDEF HEADLESS}
 496       {$IFDEF USE_SDLMIXER}
 497         flags := SDL_INIT_TIMER or SDL_INIT_AUDIO or $00004000;
 498       {$ELSE}
 499         flags := SDL_INIT_TIMER or $00004000;
 500       {$ENDIF}
 501     {$ELSE}
 502       flags := SDL_INIT_TIMER or SDL_INIT_VIDEO;
 503     {$ENDIF}
 504     SDL_SetHint(SDL_HINT_ACCELEROMETER_AS_JOYSTICK, '0');
 505     if SDL_Init(flags) <> 0 then
 506       raise Exception.Create('SDL: Init failed: ' + SDL_GetError);
 507     {$IFNDEF HEADLESS}
 508       if SDL_InitSubSystem(SDL_INIT_JOYSTICK) <> 0 then
 509         e_LogWritefln('SDL: Init subsystem failed: %s', [SDL_GetError()]);
 510     {$ENDIF}
 511     SDL_ShowCursor(SDL_DISABLE);
 512   end;
 513
 514   procedure sys_Final;
 515   begin
 516     e_WriteLog('Releasing SDL2', TMsgType.Notify);
 517     if context <> nil then
 518     begin
 519       SDL_GL_DeleteContext(context);
 520       context := nil;
 521     end;
 522     if window <> nil then
 523     begin
 524       SDL_DestroyWindow(window);
 525       window := nil;
 526     end;
 527     SDL_Quit
 528   end;
 529
 530 initialization
 531   conRegVar('sdl2_display_index', @display, 'use display index as base', '');
 532   conRegVar('sdl2_window_x', @wx, 'window position x', '');
 533   conRegVar('sdl2_window_y', @wy, 'window position y', '');
 534   conRegVar('sdl2_window_center', @wc, 'force window creation at center', '');
 535   display := 0;
 536   wx := SDL_WINDOWPOS_CENTERED;
 537   wy := SDL_WINDOWPOS_CENTERED;
 538   wc := false
 539 end.