DEADSOFTWARE

GIT / REPO / FRED-BOY
Projects / d2df-sdl.git / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
gl: draw gui controls
[d2df-sdl.git] / src / game / renders / opengl / r_map.pas
1 (* Copyright (C) Doom 2D: Forever Developers
2 *
3 * This program is free software: you can redistribute it and/or modify
4 * it under the terms of the GNU General Public License as published by
5 * the Free Software Foundation, version 3 of the License ONLY.
6 *
7 * This program is distributed in the hope that it will be useful,
8 * but WITHOUT ANY WARRANTY; without even the implied warranty of
9 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
10 * GNU General Public License for more details.
11 *
12 * You should have received a copy of the GNU General Public License
13 * along with this program. If not, see <http://www.gnu.org/licenses/>.
14 *)
15 {$INCLUDE ../../../shared/a_modes.inc}
16 unit r_map;
17
18 interface
19
20 uses g_base, g_player, g_playermodel; // TRectWH, TPlayer, TPlayerModel
21
22 procedure r_Map_Initialize;
23 procedure r_Map_Finalize;
24
25 procedure r_Map_Load;
26 procedure r_Map_Free;
27
28 procedure r_Map_LoadTextures;
29 procedure r_Map_FreeTextures;
30
31 {$IFDEF ENABLE_GFX}
32 procedure r_Map_NewGFX (typ, x, y: Integer);
33 {$ENDIF}
34 {$IFDEF ENABLE_GIBS}
35 function r_Map_GetGibSize (m, i: Integer): TRectWH;
36 {$ENDIF}
37 {$IFDEF ENABLE_MENU}
38 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer; alpha: Byte);
39 {$ENDIF}
40
41
42 procedure r_Map_Update;
43
44 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer; player: TPlayer);
45
46 implementation
47
48 uses
49 Math,
50 {$IFDEF USE_GLES1}
51 GLES11,
52 {$ELSE}
53 GL, GLEXT,
54 {$ENDIF}
55 e_log,
56 binheap, MAPDEF, utils,
57 g_options, g_textures, g_basic, g_phys,
58 g_game, g_map, g_panel, g_items, g_monsters, g_weapons,
59 {$IFDEF ENABLE_CORPSES}
60 g_corpses,
61 {$ENDIF}
62 {$IFDEF ENABLE_SHELLS}
63 g_shells,
64 {$ENDIF}
65 {$IFDEF ENABLE_GIBS}
66 g_gibs,
67 {$ENDIF}
68 {$IFDEF ENABLE_GFX}
69 g_gfx,
70 {$ENDIF}
71 r_textures, r_draw
72 ;
73
74 const
75 MTABLE: array [0..MONSTER_MAN] of record
76 w, h: Integer;
77 end = (
78 (w: 64; h: 64), // NONE
79 (w: 64; h: 64), // DEMON
80 (w: 64; h: 64), // IMP
81 (w: 64; h: 64), // ZOMBY
82 (w: 64; h: 64), // SERG
83 (w: 128; h: 128), // CYBER
84 (w: 64; h: 64), // CGUN
85 (w: 128; h: 128), // BARON
86 (w: 128; h: 128), // KNIGHT
87 (w: 128; h: 128), // CACO
88 (w: 64; h: 64), // SOUL (DIE is 128x128, see load code)
89 (w: 128; h: 128), // PAIN
90 (w: 256; h: 128), // SPIDER
91 (w: 128; h: 64), // BSP
92 (w: 128; h: 128), // MANCUB
93 (w: 128; h: 128), // SKEL
94 (w: 128; h: 128), // VILE
95 (w: 32; h: 32), // FISH
96 (w: 64; h: 64), // BARREL
97 (w: 128; h: 128), // ROBO
98 (w: 64; h: 64) // MAN
99 );
100 VILEFIRE_DX = 32;
101 VILEFIRE_DY = 128;
102
103 ItemAnim: array [0..ITEM_LAST] of record
104 name: AnsiString;
105 w, h: Integer;
106 d: Integer; // delay
107 n: Integer; // count
108 b: Boolean; // backanim
109 end = (
110 (name: ''; w: 0; h: 0; d: 0; n: 0; b: False),
111 (name: 'MED1'; w: 16; h: 16; d: 0; n: 1; b: False),
112 (name: 'MED2'; w: 32; h: 32; d: 0; n: 1; b: False),
113 (name: 'BMED'; w: 32; h: 32; d: 0; n: 1; b: False),
114 (name: 'ARMORGREEN'; w: 32; h: 16; d: 20; n: 3; b: True),
115 (name: 'ARMORBLUE'; w: 32; h: 16; d: 20; n: 3; b: True),
116 (name: 'SBLUE'; w: 32; h: 32; d: 15; n: 4; b: True),
117 (name: 'SWHITE'; w: 32; h: 32; d: 20; n: 4; b: True),
118 (name: 'SUIT'; w: 32; h: 64; d: 0; n: 1; b: False),
119 (name: 'OXYGEN'; w: 16; h: 32; d: 0; n: 1; b: False),
120 (name: 'INVUL'; w: 32; h: 32; d: 20; n: 4; b: True),
121 (name: 'SAW'; w: 64; h: 32; d: 0; n: 1; b: False),
122 (name: 'SHOTGUN1'; w: 64; h: 16; d: 0; n: 1; b: False),
123 (name: 'SHOTGUN2'; w: 64; h: 16; d: 0; n: 1; b: False),
124 (name: 'MGUN'; w: 64; h: 16; d: 0; n: 1; b: False),
125 (name: 'RLAUNCHER'; w: 64; h: 16; d: 0; n: 1; b: False),
126 (name: 'PGUN'; w: 64; h: 16; d: 0; n: 1; b: False),
127 (name: 'BFG'; w: 64; h: 64; d: 0; n: 1; b: False),
128 (name: 'SPULEMET'; w: 64; h: 16; d: 0; n: 1; b: False),
129 (name: 'CLIP'; w: 16; h: 16; d: 0; n: 1; b: False),
130 (name: 'AMMO'; w: 32; h: 16; d: 0; n: 1; b: False),
131 (name: 'SHELL1'; w: 16; h: 8; d: 0; n: 1; b: False),
132 (name: 'SHELL2'; w: 32; h: 16; d: 0; n: 1; b: False),
133 (name: 'ROCKET'; w: 16; h: 32; d: 0; n: 1; b: False),
134 (name: 'ROCKETS'; w: 64; h: 32; d: 0; n: 1; b: False),
135 (name: 'CELL'; w: 16; h: 16; d: 0; n: 1; b: False),
136 (name: 'CELL2'; w: 32; h: 32; d: 0; n: 1; b: False),
137 (name: 'BPACK'; w: 32; h: 32; d: 0; n: 1; b: False),
138 (name: 'KEYR'; w: 16; h: 16; d: 0; n: 1; b: False),
139 (name: 'KEYG'; w: 16; h: 16; d: 0; n: 1; b: False),
140 (name: 'KEYB'; w: 16; h: 16; d: 0; n: 1; b: False),
141 (name: 'KASTET'; w: 64; h: 32; d: 0; n: 1; b: False),
142 (name: 'PISTOL'; w: 64; h: 16; d: 0; n: 1; b: False),
143 (name: 'BOTTLE'; w: 16; h: 32; d: 20; n: 4; b: True),
144 (name: 'HELMET'; w: 16; h: 16; d: 20; n: 4; b: True),
145 (name: 'JETPACK'; w: 32; h: 32; d: 15; n: 3; b: True),
146 (name: 'INVIS'; w: 32; h: 32; d: 20; n: 4; b: True),
147 (name: 'FLAMETHROWER'; w: 64; h: 32; d: 0; n: 1; b: False),
148 (name: 'FUELCAN'; w: 16; h: 32; d: 0; n: 1; b: False)
149 );
150
151 {$IFDEF ENABLE_GFX}
152 GFXAnim: array [0..R_GFX_LAST] of record
153 name: AnsiString;
154 w, h: Integer;
155 count: Integer;
156 back: Boolean;
157 speed: Integer;
158 rspeed: Integer;
159 alpha: Integer;
160 end = (
161 (name: ''; w: 0; h: 0; count: 0; back: false; speed: 0; rspeed: 0; alpha: 0),
162 (name: 'TELEPORT'; w: 64; h: 64; count: 10; back: false; speed: 6; rspeed: 0; alpha: 0),
163 (name: 'FLAME'; w: 32; h: 32; count: 11; back: false; speed: 3; rspeed: 0; alpha: 0),
164 (name: 'EROCKET'; w: 128; h: 128; count: 6; back: false; speed: 6; rspeed: 0; alpha: 0),
165 (name: 'EBFG'; w: 128; h: 128; count: 6; back: false; speed: 6; rspeed: 0; alpha: 0),
166 (name: 'BFGHIT'; w: 64; h: 64; count: 4; back: false; speed: 4; rspeed: 0; alpha: 0),
167 (name: 'FIRE'; w: 64; h: 128; count: 8; back: false; speed: 4; rspeed: 2; alpha: 0),
168 (name: 'ITEMRESPAWN'; w: 32; h: 32; count: 5; back: true; speed: 4; rspeed: 0; alpha: 0),
169 (name: 'SMOKE'; w: 32; h: 32; count: 10; back: false; speed: 3; rspeed: 0; alpha: 0),
170 (name: 'ESKELFIRE'; w: 64; h: 64; count: 3; back: false; speed: 8; rspeed: 0; alpha: 0),
171 (name: 'EPLASMA'; w: 32; h: 32; count: 4; back: true; speed: 3; rspeed: 0; alpha: 0),
172 (name: 'EBSPFIRE'; w: 32; h: 32; count: 5; back: false; speed: 3; rspeed: 0; alpha: 0),
173 (name: 'EIMPFIRE'; w: 64; h: 64; count: 3; back: false; speed: 6; rspeed: 0; alpha: 0),
174 (name: 'ECACOFIRE'; w: 64; h: 64; count: 3; back: false; speed: 6; rspeed: 0; alpha: 0),
175 (name: 'EBARONFIRE'; w: 64; h: 64; count: 3; back: false; speed: 6; rspeed: 0; alpha: 0),
176 (name: 'TELEPORT'; w: 64; h: 64; count: 10; back: false; speed: 3; rspeed: 0; alpha: 0), // fast
177 (name: 'SMOKE'; w: 32; h: 32; count: 10; back: false; speed: 3; rspeed: 0; alpha: 150), // transparent
178 (name: 'FLAME'; w: 32; h: 32; count: 11; back: false; speed: 3; rspeed: 2; alpha: 0) // random
179 );
180 {$ENDIF}
181
182 ShotAnim: array [0..WEAPON_LAST] of record
183 name: AnsiString;
184 w, h: Integer;
185 count: Integer;
186 end = (
187 (name: ''; w: 0; h: 0; count: 0), // 0 KASTET
188 (name: ''; w: 0; h: 0; count: 0), // 1 SAW
189 (name: ''; w: 0; h: 0; count: 0), // 2 PISTOL
190 (name: ''; w: 0; h: 0; count: 0), // 3 SHOTGUN1
191 (name: ''; w: 0; h: 0; count: 0), // 4 SHOTGUN2
192 (name: ''; w: 0; h: 0; count: 0), // 5 CHAINGUN
193 (name: 'BROCKET'; w: 64; h: 32; count: 1), // 6 ROCKETLAUNCHER
194 (name: 'BPLASMA'; w: 16; h: 16; count: 2), // 7 PLASMA
195 (name: 'BBFG'; w: 64; h: 64; count: 2), // 8 BFG
196 (name: ''; w: 0; h: 0; count: 0), // 9 SUPERPULEMET
197 (name: 'FLAME'; w: 32; h: 32; count: 0{11}), // 10 FLAMETHROWER
198 (name: ''; w: 0; h: 0; count: 0), // 11
199 (name: ''; w: 0; h: 0; count: 0), // 12
200 (name: ''; w: 0; h: 0; count: 0), // 13
201 (name: ''; w: 0; h: 0; count: 0), // 14
202 (name: ''; w: 0; h: 0; count: 0), // 15
203 (name: ''; w: 0; h: 0; count: 0), // 16
204 (name: ''; w: 0; h: 0; count: 0), // 17
205 (name: ''; w: 0; h: 0; count: 0), // 18
206 (name: ''; w: 0; h: 0; count: 0), // 19
207 (name: ''; w: 0; h: 0; count: 0), // 20 ZOMPY_PISTOL
208 (name: 'BIMPFIRE'; w: 16; h: 16; count: 2), // 21 IMP_FIRE
209 (name: 'BBSPFIRE'; w: 16; h: 16; count: 2), // 22 BSP_FIRE
210 (name: 'BCACOFIRE'; w: 16; h: 16; count: 2), // 23 CACO_FIRE
211 (name: 'BBARONFIRE'; w: 64; h: 16; count: 2), // 24 BARON_FIRE
212 (name: 'BMANCUBFIRE'; w: 64; h: 32; count: 2), // 25 MANCUB_FIRE
213 (name: 'BSKELFIRE'; w: 64; h: 64; count: 2) // 26 SKEL_FIRE
214 );
215
216 {$IFDEF ENABLE_SHELLS}
217 ShellAnim: array [0..SHELL_LAST] of record
218 name: AnsiString;
219 dx, dy: Integer;
220 end = (
221 (name: 'EBULLET'; dx: 2; dy: 1), // 0 SHELL_BULLET
222 (name: 'ESHELL'; dx: 4; dy: 2), // 1 SHELL_SHELL
223 (name: 'ESHELL'; dx: 4; dy: 2) // 2 SHELL_DBLSHELL
224 );
225 {$ENDIF}
226
227 type
228 TBinHeapPanelDrawCmp = class
229 public
230 class function less (const a, b: TPanel): Boolean; inline;
231 end;
232
233 TBinHeapPanelDraw = specialize TBinaryHeapBase<TPanel, TBinHeapPanelDrawCmp>;
234
235 TMonsterAnims = array [0..ANIM_LAST, TDirection] of TGLMultiTexture;
236
237 var
238 SkyTexture: TGLTexture;
239 RenTextures: array of record
240 spec: LongInt;
241 tex: TGLMultiTexture;
242 end;
243 Items: array [0..ITEM_LAST] of record
244 tex: TGLMultiTexture;
245 anim: TAnimState;
246 end;
247 MonTextures: array [0..MONSTER_MAN] of TMonsterAnims;
248 WeapTextures: array [0..WP_LAST, 0..W_POS_LAST, 0..W_ACT_LAST] of TGLTexture;
249 ShotTextures: array [0..WEAPON_LAST] of TGLMultiTexture;
250 FlagTextures: array [0..FLAG_LAST] of TGLMultiTexture;
251 PunchTextures: array [Boolean, 0..2] of TGLMultiTexture; // [berserk, center/up/down]
252 VileFire: TGLMultiTexture;
253 InvulPenta: TGLTexture;
254 Models: array of record
255 anim: array [TDirection, 0..A_LAST] of record
256 base, mask: TGLMultiTexture;
257 end;
258 {$IFDEF ENABLE_GIBS}
259 gibs: record
260 base, mask: TGLTextureArray;
261 rect: TRectArray;
262 end;
263 {$ENDIF}
264 end;
265
266 StubShotAnim: TAnimState; // TODO remove this hack
267 FlagAnim: TAnimState;
268
269 {$IFDEF ENABLE_SHELLS}
270 ShellTextures: array [0..SHELL_LAST] of TGLTexture;
271 {$ENDIF}
272 {$IFDEF ENABLE_GFX}
273 GFXTextures: array [0..R_GFX_LAST] of TGLMultiTexture;
274 gfxlist: array of record
275 typ: Byte;
276 alpha: Byte;
277 x, y: Integer;
278 oldX, oldY: Integer;
279 anim: TAnimState;
280 end = nil;
281 {$ENDIF}
282
283 plist: TBinHeapPanelDraw = nil;
284
285 class function TBinHeapPanelDrawCmp.less (const a, b: TPanel): Boolean; inline;
286 begin
287 if a.tag < b.tag then begin result := true; exit; end;
288 if a.tag > b.tag then begin result := false; exit; end;
289 result := a.arrIdx < b.arrIdx;
290 end;
291
292 procedure r_Map_Initialize;
293 begin
294 StubShotAnim := TAnimState.Create(true, 1, 1);
295 FlagAnim := TAnimState.Create(true, 8, 5);
296 plist := TBinHeapPanelDraw.Create();
297 end;
298
299 procedure r_Map_Finalize;
300 begin
301 plist.Free;
302 StubShotAnim.Invalidate;
303 end;
304
305 procedure r_Map_FreeModel (i: Integer);
306 var a: Integer; d: TDirection;
307 begin
308 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
309 begin
310 for a := A_STAND to A_LAST do
311 begin
312 if Models[i].anim[d, a].base <> nil then
313 Models[i].anim[d, a].base.Free;
314 if Models[i].anim[d, a].mask <> nil then
315 Models[i].anim[d, a].mask.Free;
316 Models[i].anim[d, a].base := nil;
317 Models[i].anim[d, a].mask := nil;
318 end;
319 end;
320 {$IFDEF ENABLE_GIBS}
321 if Models[i].gibs.base <> nil then
322 for a := 0 to High(Models[i].gibs.base) do
323 Models[i].gibs.base[a].Free;
324 if Models[i].gibs.mask <> nil then
325 for a := 0 to High(Models[i].gibs.mask) do
326 Models[i].gibs.mask[a].Free;
327 Models[i].gibs.base := nil;
328 Models[i].gibs.mask := nil;
329 Models[i].gibs.rect := nil;
330 {$ENDIF}
331 end;
332
333 procedure r_Map_LoadModel (i: Integer);
334 var prefix: AnsiString; a: Integer; d: TDirection; m: ^TPlayerModelInfo;
335 begin
336 ASSERT(i < Length(Models));
337 ASSERT(i < Length(PlayerModelsArray));
338 r_Map_FreeModel(i);
339 m := @PlayerModelsArray[i];
340 prefix := m.FileName + ':TEXTURES/';
341 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
342 begin
343 for a := A_STAND to A_LAST do
344 begin
345 Models[i].anim[d, a].base := nil;
346 Models[i].anim[d, a].mask := nil;
347 if m.anim[d, a].resource <> '' then
348 Models[i].anim[d, a].base := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].resource, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
349 if m.anim[d, a].mask <> '' then
350 Models[i].anim[d, a].mask := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].mask, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
351 end
352 end;
353 {$IFDEF ENABLE_GIBS}
354 Models[i].gibs.base := nil;
355 Models[i].gibs.mask := nil;
356 Models[i].gibs.rect := nil;
357 if m.GibsCount > 0 then
358 begin
359 SetLength(Models[i].gibs.base, m.GibsCount);
360 SetLength(Models[i].gibs.mask, m.GibsCount);
361 SetLength(Models[i].gibs.rect, m.GibsCount);
362 for a := 0 to m.GibsCount - 1 do
363 Models[i].gibs.rect[a] := DefaultGibSize;
364 if r_Textures_LoadStreamFromFile(prefix + m.GibsResource, 32, 32, m.GibsCount, m.GibsCount, Models[i].gibs.base, Models[i].gibs.rect) then
365 begin
366 if r_Textures_LoadStreamFromFile(prefix + m.GibsMask, 32, 32, m.GibsCount, m.GibsCount, Models[i].gibs.mask, nil) then
367 begin
368 // ok
369 end;
370 end;
371 end;
372 {$ENDIF}
373 end;
374
375 procedure r_Map_LoadMonsterAnim (m, a: Integer; d: TDirection);
376 const dir: array [TDirection] of AnsiString = ('_L', '');
377 var w, h, count: Integer;
378 begin
379 count := MONSTER_ANIMTABLE[m].AnimCount[a];
380 if count > 0 then
381 begin
382 w := MTABLE[m].w;
383 h := MTABLE[m].h;
384 if (m = MONSTER_SOUL) and (a = ANIM_DIE) then
385 begin
386 // special case
387 w := 128;
388 h := 128;
389 end;
390 MonTextures[m, a, d] := r_Textures_LoadMultiFromFileAndInfo(
391 GameWAD + ':MTEXTURES/' + MONSTERTABLE[m].name + '_' + ANIMTABLE[a].name + dir[d],
392 w,
393 h,
394 count,
395 False,
396 False
397 );
398 end
399 else
400 MonTextures[m, a, d] := nil;
401 end;
402
403 procedure r_Map_Load;
404 const
405 WeapName: array [0..WP_LAST] of AnsiString = ('', 'CSAW', 'HGUN', 'SG', 'SSG', 'MGUN', 'RKT', 'PLZ', 'BFG', 'SPL', 'FLM');
406 WeapPos: array [0..W_POS_LAST] of AnsiString = ('', '_UP', '_DN');
407 WeapAct: array [0..W_ACT_LAST] of AnsiString = ('', '_FIRE');
408 PunchName: array [Boolean] of AnsiString = ('PUNCH', 'PUNCHB');
409 var
410 i, j, k: Integer; d: TDirection; b: Boolean;
411 begin
412 // --------- items --------- //
413 for i := 0 to ITEM_LAST do
414 begin
415 if ItemAnim[i].n > 0 then
416 begin
417 Items[i].tex := r_Textures_LoadMultiFromFileAndInfo(
418 GameWAD + ':TEXTURES/' + ItemAnim[i].name,
419 ItemAnim[i].w,
420 ItemAnim[i].h,
421 ItemAnim[i].n,
422 ItemAnim[i].b,
423 false
424 );
425 k := IfThen(ItemAnim[i].b, ItemAnim[i].n * 2 - 2, ItemAnim[i].n);
426 Items[i].anim := TAnimState.Create(True, ItemAnim[i].d, k);
427 end;
428 end;
429 // --------- monsters --------- //
430 for i := MONSTER_DEMON to MONSTER_MAN do
431 for j := 0 to ANIM_LAST do
432 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
433 r_Map_LoadMonsterAnim(i, j, d);
434 VileFire := r_Textures_LoadMultiFromFileAndInfo(GameWAD + ':TEXTURES/FIRE', 64, 128, 8, False, False);
435 // --------- player models --------- //
436 if PlayerModelsArray <> nil then
437 begin
438 SetLength(Models, Length(PlayerModelsArray));
439 for i := 0 to High(PlayerModelsArray) do
440 r_Map_LoadModel(i);
441 end;
442 // --------- player weapons --------- //
443 for i := 1 to WP_LAST do
444 for j := 0 to W_POS_LAST do
445 for k := 0 to W_ACT_LAST do
446 WeapTextures[i, j, k] := r_Textures_LoadFromFile(GameWAD + ':WEAPONS\' + WeapName[i] + WeapPos[j] + WeapAct[k]);
447 // --------- gfx animations --------- //
448 {$IFDEF ENABLE_GFX}
449 for i := 1 to R_GFX_LAST do
450 if GFXAnim[i].count > 0 then
451 GFXTextures[i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/' + GFXAnim[i].name, GFXAnim[i].w, GFXAnim[i].h, GFXAnim[i].count, GFXAnim[i].back);
452 {$ENDIF}
453 // --------- shots --------- //
454 for i := 0 to WEAPON_LAST do
455 if ShotAnim[i].count > 0 then
456 ShotTextures[i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/' + ShotAnim[i].name, ShotAnim[i].w, ShotAnim[i].h, ShotAnim[i].count, false);
457 // --------- flags --------- //
458 FlagTextures[FLAG_NONE] := nil;
459 FlagTextures[FLAG_RED] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGRED', 64, 64, 5, false);
460 FlagTextures[FLAG_BLUE] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGBLUE', 64, 64, 5, false);
461 // FlagTextures[FLAG_DOM] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGDOM', 64, 64, 8, false);
462 // --------- shells --------- //
463 {$IFDEF ENABLE_SHELLS}
464 for i := 0 to SHELL_LAST do
465 ShellTextures[i] := r_Textures_LoadFromFile(GameWad + ':TEXTURES/' + ShellAnim[i].name);
466 {$ENDIF}
467 // --------- punch --------- //
468 for b := false to true do
469 begin
470 for i := 0 to 2 do
471 PunchTextures[b, i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':WEAPONS/' + PunchName[b] + WeapPos[i], 64, 64, 4, false);
472 end;
473 // --------- other --------- //
474 InvulPenta := r_Textures_LoadFromFile(GameWad + ':TEXTURES/PENTA');
475 end;
476
477 procedure r_Map_Free;
478 var i, j, k: Integer; d: TDirection; b: Boolean;
479 begin
480 if InvulPenta <> nil then
481 InvulPenta.Free;
482 InvulPenta := nil;
483 for b := false to true do
484 begin
485 for i := 0 to 2 do
486 begin
487 if PunchTextures[b, i] <> nil then
488 PunchTextures[b, i].Free;
489 PunchTextures[b, i] := nil;
490 end;
491 end;
492 {$IFDEF ENABLE_SHELLS}
493 for i := 0 to SHELL_LAST do
494 begin
495 if ShellTextures[i] <> nil then
496 ShellTextures[i].Free;
497 ShellTextures[i] := nil;
498 end;
499 {$ENDIF}
500 for i := 0 to FLAG_LAST do
501 begin
502 if FlagTextures[i] <> nil then
503 FlagTextures[i].Free;
504 FlagTextures[i] := nil;
505 end;
506 for i := 0 to WEAPON_LAST do
507 begin
508 if ShotTextures[i] <> nil then
509 ShotTextures[i].Free;
510 ShotTextures[i] := nil;
511 end;
512 {$IFDEF ENABLE_GFX}
513 gfxlist := nil;
514 for i := 0 to R_GFX_LAST do
515 begin
516 if GFXTextures[i] <> nil then
517 GFXTextures[i].Free;
518 GFXTextures[i] := nil;
519 end;
520 {$ENDIF}
521 for i := 1 to WP_LAST do
522 begin
523 for j := 0 to W_POS_LAST do
524 begin
525 for k := 0 to W_ACT_LAST do
526 begin
527 if WeapTextures[i, j, k] <> nil then
528 WeapTextures[i, j, k].Free;
529 WeapTextures[i, j, k] := nil;
530 end;
531 end;
532 end;
533 if Models <> nil then
534 for i := 0 to High(Models) do
535 r_Map_FreeModel(i);
536 for i := MONSTER_DEMON to MONSTER_MAN do
537 begin
538 for j := 0 to ANIM_LAST do
539 begin
540 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
541 begin
542 if MonTextures[i, j, d] <> nil then
543 MonTextures[i, j, d].Free;
544 MonTextures[i, j, d] := nil;
545 end;
546 end;
547 end;
548 for i := 0 to ITEM_LAST do
549 begin
550 if Items[i].tex <> nil then
551 begin
552 Items[i].tex.Free;
553 Items[i].tex := nil;
554 end;
555 Items[i].anim.Invalidate;
556 end;
557 end;
558
559 procedure r_Map_LoadTextures;
560 var i, n: Integer;
561 begin
562 if Textures <> nil then
563 begin
564 n := Length(Textures);
565 SetLength(RenTextures, n);
566 for i := 0 to n - 1 do
567 begin
568 RenTextures[i].tex := nil;
569 case Textures[i].TextureName of
570 TEXTURE_NAME_WATER: RenTextures[i].spec := TEXTURE_SPECIAL_WATER;
571 TEXTURE_NAME_ACID1: RenTextures[i].spec := TEXTURE_SPECIAL_ACID1;
572 TEXTURE_NAME_ACID2: RenTextures[i].spec := TEXTURE_SPECIAL_ACID2;
573 else
574 RenTextures[i].spec := 0;
575 RenTextures[i].tex := r_Textures_LoadMultiFromFile(Textures[i].FullName);
576 if RenTextures[i].tex = nil then
577 e_LogWritefln('r_Map_LoadTextures: failed to load texture: %s', [Textures[i].FullName]);
578 end;
579 end;
580 end;
581 if gMapInfo.SkyFullName <> '' then
582 SkyTexture := r_Textures_LoadFromFile(gMapInfo.SkyFullName);
583 plist.Clear;
584 end;
585
586 procedure r_Map_FreeTextures;
587 var i: Integer;
588 begin
589 plist.Clear;
590 if SkyTexture <> nil then
591 SkyTexture.Free;
592 SkyTexture := nil;
593 if RenTextures <> nil then
594 for i := 0 to High(RenTextures) do
595 if RenTextures[i].tex <> nil then
596 RenTextures[i].tex.Free;
597 RenTextures := nil;
598 end;
599
600 procedure r_Map_DrawPanel (p: TPanel);
601 var Texture: Integer; t: TGLMultiTexture;
602 begin
603 ASSERT(p <> nil);
604 if p.FCurTexture >= 0 then
605 begin
606 Texture := p.TextureIDs[p.FCurTexture].Texture;
607 t := RenTextures[Texture].tex;
608
609 if (RenTextures[Texture].spec = 0) or (t <> nil) then
610 begin
611 if t = nil then
612 r_Draw_TextureRepeat(nil, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
613 else if p.TextureIDs[p.FCurTexture].AnTex.IsValid() then
614 r_Draw_MultiTextureRepeat(t, p.TextureIDs[p.FCurTexture].AnTex, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
615 else
616 r_Draw_TextureRepeat(t.GetTexture(0), p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
617 end;
618
619 if t = nil then
620 begin
621 case RenTextures[Texture].spec of
622 TEXTURE_SPECIAL_WATER: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 0, 255, 255);
623 TEXTURE_SPECIAL_ACID1: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 230, 0, 255);
624 TEXTURE_SPECIAL_ACID2: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 230, 0, 0, 255);
625 end
626 end
627 end
628 end;
629
630 procedure r_Map_DrawPanelType (panelTyp: DWORD);
631 var tagMask, i: Integer; p: TPanel;
632 begin
633 i := 0;
634 tagMask := PanelTypeToTag(panelTyp);
635 while plist.count > 0 do
636 begin
637 p := TPanel(plist.Front());
638 if (p.tag and tagMask) = 0 then
639 break;
640 r_Map_DrawPanel(p);
641 Inc(i);
642 plist.PopFront
643 end;
644 end;
645
646 procedure r_Map_DrawItems (x, y, w, h: Integer; drop: Boolean);
647 var i, fX, fY: Integer; it: PItem; t: TGLMultiTexture;
648 begin
649 if ggItems <> nil then
650 begin
651 for i := 0 to High(ggItems) do
652 begin
653 it := @ggItems[i];
654 if it.used and it.alive and (it.dropped = drop) and (it.ItemType > ITEM_NONE) and (it.ItemType <= ITEM_LAST) then
655 begin
656 t := Items[it.ItemType].tex;
657 if g_Collide(it.obj.x, it.obj.y, t.width, t.height, x, y, w, h) then
658 begin
659 it.obj.Lerp(gLerpFactor, fX, fY);
660 r_Draw_MultiTextureRepeat(t, Items[it.ItemType].anim, fX, fY, t.width, t.height, false, 255, 255, 255, 255, false);
661 end;
662 end;
663 end;
664 end;
665 // TODO draw g_debug_frames
666 end;
667
668 function r_Map_GetMonsterTexture (m, a: Integer; d: TDirection; out t: TGLMultiTexture; out dx, dy: Integer; out flip: Boolean): Boolean;
669 // var c: Integer;
670 begin
671 t := nil; dx := 0; dy := 0; flip := false;
672 result := MonTextures[m, a, d] <> nil;
673 if result = false then
674 begin
675 flip := true;
676 if d = TDirection.D_RIGHT then d := TDirection.D_LEFT else d := TDirection.D_RIGHT;
677 result := MonTextures[m, a, d] <> nil;
678 end;
679 if result = true then
680 begin
681 t := MonTextures[m, a, d];
682 if d = TDirection.D_LEFT then
683 begin
684 dx := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].X;
685 dy := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].Y;
686 end
687 else
688 begin
689 dx := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].X;
690 dy := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].Y;
691 end;
692 if flip then
693 begin
694 // c := (MONSTERTABLE[MonsterType].Rect.X - dx) + MONSTERTABLE[MonsterType].Rect.Width;
695 // dx := MTABLE[m].width - c - MONSTERTABLE[MonsterType].Rect.X;
696 dx := -dx;
697 end;
698 end;
699 end;
700
701 procedure r_Map_DrawMonsterAttack (constref mon: TMonster);
702 var o: TObj;
703 begin
704 if VileFire <> nil then
705 if (mon.MonsterType = MONSTER_VILE) and (mon.MonsterState = MONSTATE_SHOOT) then
706 if mon.VileFireAnim.IsValid() and GetPos(mon.MonsterTargetUID, @o) then
707 r_Draw_MultiTextureRepeat(VileFire, mon.VileFireAnim, o.x + o.rect.x + (o.rect.width div 2) - VILEFIRE_DX, o.y + o.rect.y + o.rect.height - VILEFIRE_DY, VileFire.width, VileFire.height, False, 255, 255, 255, 255, false);
708 end;
709
710 procedure r_Map_DrawMonster (constref mon: TMonster);
711 var m, a, fX, fY, dx, dy: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture;
712 begin
713 m := mon.MonsterType;
714 a := mon.MonsterAnim;
715 d := mon.GameDirection;
716
717 mon.obj.Lerp(gLerpFactor, fX, fY);
718
719 if r_Map_GetMonsterTexture(m, a, d, t, dx, dy, flip) then
720 r_Draw_MultiTextureRepeat(t, mon.DirAnim[a, d], fX + dx, fY + dy, t.width, t.height, flip, 255, 255, 255, 255, false);
721
722 // TODO draw g_debug_frames
723 end;
724
725 procedure r_Map_DrawMonsters (x, y, w, h: Integer);
726 var i: Integer; m: TMonster;
727 begin
728 if gMonsters <> nil then
729 begin
730 for i := 0 to High(gMonsters) do
731 begin
732 m := gMonsters[i];
733 if m <> nil then
734 begin
735 r_Map_DrawMonsterAttack(m);
736 // TODO select from grid
737 if g_Collide(m.obj.x + m.obj.rect.x, m.obj.y + m.obj.rect.y, m.obj.rect.width, m.obj.rect.height, x, y, w, h) then
738 r_Map_DrawMonster(m);
739 end;
740 end;
741 end;
742 end;
743
744 function r_Map_GetPlayerModelTex (i: Integer; var a: Integer; var d: TDirection; out flip: Boolean): Boolean;
745 begin
746 flip := false;
747 result := Models[i].anim[d, a].base <> nil;
748 if result = false then
749 begin
750 flip := true;
751 if d = TDirection.D_LEFT then d := TDirection.D_RIGHT else d := TDirection.D_LEFT;
752 result := Models[i].anim[d, a].base <> nil;
753 end;
754 end;
755
756 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer; alpha: Byte);
757 var a, pos, act, xx, yy, angle: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture; tex: TGLTexture; c: TRGB;
758 begin
759 a := pm.CurrentAnimation;
760 d := pm.Direction;
761
762 (* draw flag*)
763 t := FlagTextures[pm.Flag];
764 if (t <> nil) and not (a in [A_DIE1, A_DIE2]) then
765 begin
766 flip := d = TDirection.D_RIGHT;
767 angle := PlayerModelsArray[pm.id].FlagAngle;
768 xx := PlayerModelsArray[pm.id].FlagPoint.X;
769 yy := PlayerModelsArray[pm.id].FlagPoint.Y;
770 r_Draw_MultiTextureRepeatRotate(
771 t,
772 FlagAnim,
773 x + IfThen(flip, 2 * FLAG_BASEPOINT.X - xx + 1, xx - 1) - FLAG_BASEPOINT.X,
774 y + yy - FLAG_BASEPOINT.Y + 1,
775 t.width,
776 t.height,
777 flip,
778 255, 255, 255, 255, false,
779 IfThen(flip, 64 - FLAG_BASEPOINT.X, FLAG_BASEPOINT.X),
780 FLAG_BASEPOINT.Y,
781 IfThen(flip, angle, -angle)
782 );
783 end;
784
785 (* draw weapon *)
786 if PlayerModelsArray[pm.id].HaveWeapon and not (a in [A_DIE1, A_DIE2, A_PAIN]) then
787 begin
788 case a of
789 A_SEEUP, A_ATTACKUP: pos := W_POS_UP;
790 A_SEEDOWN, A_ATTACKDOWN: pos := W_POS_DOWN;
791 else pos := W_POS_NORMAL;
792 end;
793 if (a in [A_ATTACK, A_ATTACKUP, A_ATTACKDOWN]) or pm.GetFire() then
794 act := W_ACT_FIRE
795 else
796 act := W_ACT_NORMAL;
797 tex := WeapTextures[pm.CurrentWeapon, pos, act];
798 if tex <> nil then
799 begin
800 xx := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].X;
801 yy := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].Y;
802 r_Draw_Texture(
803 tex,
804 x + xx,
805 y + yy,
806 tex.width,
807 tex.height,
808 d = TDirection.D_LEFT,
809 255, 255, 255, alpha, false
810 );
811 end;
812 end;
813
814 (* draw body *)
815 if r_Map_GetPlayerModelTex(pm.id, a, d, flip) then
816 begin
817 t := Models[pm.id].anim[d, a].base;
818 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip, 255, 255, 255, alpha, false);
819 t := Models[pm.id].anim[d, a].mask;
820 if t <> nil then
821 begin
822 c := pm.Color;
823 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip, c.r, c.g, c.b, alpha, false);
824 end;
825 end;
826 end;
827
828 procedure r_Map_DrawPlayer (p, drawed: TPlayer);
829 var fX, fY, fSlope, ax, ay, w, h: Integer; b, flip: Boolean; t: TGLMultiTexture; alpha: Byte;
830 begin
831 if p.alive then
832 begin
833 fX := p.obj.x; fY := p.obj.y;
834 // TODO fix lerp
835 //p.obj.Lerp(gLerpFactor, fX, fY);
836 fSlope := nlerp(p.SlopeOld, p.obj.slopeUpLeft, gLerpFactor);
837
838 (* punch effect *)
839 if p.PunchAnim.IsValid() and p.PunchAnim.enabled then
840 begin
841 b := R_BERSERK in p.FRulez;
842 if p.FKeys[KEY_DOWN].pressed then
843 t := PunchTextures[b, 2]
844 else if p.FKeys[KEY_UP].pressed then
845 t := PunchTextures[b, 1]
846 else
847 t := PunchTextures[b, 0];
848 if t <> nil then
849 begin
850 flip := p.Direction = TDirection.D_LEFT;
851 ax := IfThen(flip, 15 - p.Obj.Rect.X, p.Obj.Rect.X - 15); // ???
852 ay := p.Obj.Rect.Y - 11;
853 r_Draw_MultiTextureRepeat(t, p.PunchAnim, fx + ax, fy + fSlope + ay, t.width, t.height, flip, 255, 255, 255, 255, false)
854 end;
855 end;
856
857 (* invulnerability effect *)
858 if (InvulPenta <> nil) and (p.FMegaRulez[MR_INVUL] > gTime) and ((p <> drawed) or (p.SpawnInvul >= gTime)) then
859 begin
860 w := InvulPenta.width;
861 h := InvulPenta.height;
862 ax := p.Obj.Rect.X + (p.Obj.Rect.Width div 2) - (w div 2); // + IfThen(flip, +4, -2) // ???
863 ay := p.Obj.Rect.Y + (p.Obj.Rect.Height div 2) - (h div 2) - 7; // ???
864 r_Draw_Texture(InvulPenta, fx + ax, fy + ay + fSlope, w, h, false, 255, 255, 255, 255, false);
865 end;
866
867 (* invisibility effect *)
868 alpha := 255;
869 if p.FMegaRulez[MR_INVIS] > gTime then
870 begin
871 if (drawed <> nil) and ((p = drawed) or ((p.Team = drawed.Team) and (gGameSettings.GameMode <> GM_DM))) then
872 begin
873 if (p.FMegaRulez[MR_INVIS] - gTime > 2100) or not ODD((p.FMegaRulez[MR_INVIS] - gTime) div 300) then
874 alpha := 55;
875 end
876 else
877 alpha := 1; // ???
878 end;
879
880 r_Map_DrawPlayerModel(p.Model, fX, fY + fSlope, alpha);
881 end;
882 // TODO draw g_debug_frames
883 // TODO draw chat bubble
884 // TODO draw aim
885 end;
886
887 procedure r_Map_DrawPlayers (x, y, w, h: Integer; player: TPlayer);
888 var i: Integer;
889 begin
890 if gPlayers <> nil then
891 for i := 0 to High(gPlayers) do
892 if gPlayers[i] <> nil then
893 r_Map_DrawPlayer(gPlayers[i], player);
894 end;
895
896 {$IFDEF ENABLE_GIBS}
897 function r_Map_GetGibSize (m, i: Integer): TRectWH;
898 begin
899 result := Models[m].gibs.rect[i];
900 end;
901
902 procedure r_Map_DrawGibs (x, y, w, h: Integer);
903 var i, fx, fy, m, id, rx, ry, ra: Integer; p: PObj; t: TGLTexture;
904 begin
905 if gGibs <> nil then
906 begin
907 for i := 0 to High(gGibs) do
908 begin
909 if gGibs[i].alive then
910 begin
911 p := @gGibs[i].Obj;
912 if g_Obj_Collide(x, y, w, h, p) then
913 begin
914 p.Lerp(gLerpFactor, fx, fy);
915 id := gGibs[i].GibID;
916 m := gGibs[i].ModelID;
917 t := Models[m].gibs.base[id];
918 if t <> nil then
919 begin
920 rx := p.Rect.X + p.Rect.Width div 2;
921 ry := p.Rect.Y + p.Rect.Height div 2;
922 ra := gGibs[i].RAngle;
923 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, 255, 255, 255, 255, false, rx, ry, ra);
924 t := Models[m].gibs.mask[id];
925 if t <> nil then
926 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, gGibs[i].Color.R, gGibs[i].Color.G, gGibs[i].Color.B, 255, false, rx, ry, ra);
927 // r_Draw_TextureRepeatRotate(nil, fx + p.Rect.X, fy + p.Rect.Y, p.Rect.Width, p.Rect.Height, false, 255, 255, 255, 255, false, p.Rect.Width div 2, p.Rect.Height div 2, ra);
928 end;
929 end;
930 end;
931 end;
932 end;
933 // TODO draw g_debug_frames
934 end;
935 {$ENDIF}
936
937 {$IFDEF ENABLE_CORPSES}
938 procedure r_Map_DrawCorpses (x, y, w, h: Integer);
939 var i, fX, fY: Integer; p: TCorpse;
940 begin
941 if gCorpses <> nil then
942 begin
943 for i := 0 to High(gCorpses) do
944 begin
945 p := gCorpses[i];
946 if (p <> nil) and (p.state <> CORPSE_STATE_REMOVEME) and (p.model <> nil) then
947 begin
948 p.obj.Lerp(gLerpFactor, fX, fY);
949 r_Map_DrawPlayerModel(p.model, fX, fY, 255);
950 end;
951 end;
952 end;
953 // TODO draw g_debug_frames
954 end;
955 {$ENDIF}
956
957 {$IFDEF ENABLE_GFX}
958 function r_Map_GetGFXID (): Integer;
959 var i: Integer;
960 begin
961 i := 0;
962 if gfxlist <> nil then
963 begin
964 while (i < Length(gfxlist)) and gfxlist[i].anim.IsValid() do
965 Inc(i);
966 if i >= Length(gfxlist) then
967 SetLength(gfxlist, Length(gfxlist) + 1)
968 end
969 else
970 SetLength(gfxlist, 1);
971 gfxlist[i].typ := R_GFX_NONE;
972 gfxlist[i].anim.Invalidate;
973 result := i
974 end;
975
976 procedure r_Map_NewGFX (typ, x, y: Integer);
977 var i: Integer;
978 begin
979 if gpart_dbg_enabled and (typ > 0) and (typ <= R_GFX_LAST) then
980 begin
981 i := r_Map_GetGFXID();
982 if i >= 0 then
983 begin
984 gfxlist[i].typ := typ;
985 gfxlist[i].x := x;
986 gfxlist[i].y := y;
987 gfxlist[i].oldX := x;
988 gfxlist[i].oldY := y;
989 gfxlist[i].anim := TAnimState.Create(false, GFXAnim[typ].speed + Random(GFXAnim[typ].rspeed), GFXAnim[typ].count);
990 gfxlist[i].anim.Reset();
991 gfxlist[i].anim.Enable();
992 end;
993 end;
994 end;
995
996 procedure r_Map_UpdateGFX;
997 var i: Integer;
998 begin
999 if gfxlist <> nil then
1000 begin
1001 for i := 0 to High(gfxlist) do
1002 begin
1003 if gfxlist[i].anim.IsValid() then
1004 begin
1005 gfxlist[i].oldX := gfxlist[i].x;
1006 gfxlist[i].oldY := gfxlist[i].y;
1007 case gfxlist[i].typ of
1008 R_GFX_FLAME, R_GFX_SMOKE:
1009 begin
1010 if Random(3) = 0 then
1011 gfxlist[i].x := gfxlist[i].x - 1 + Random(3);
1012 if Random(2) = 0 then
1013 gfxlist[i].y := gfxlist[i].y - Random(2);
1014 end;
1015 end;
1016 if gfxlist[i].anim.played then
1017 gfxlist[i].anim.Invalidate
1018 else
1019 gfxlist[i].anim.Update
1020 end;
1021 end;
1022 end;
1023 end;
1024
1025 procedure r_Map_DrawParticles (x, y, w, h: Integer);
1026 var i, fx, fy: Integer;
1027 begin
1028 if gpart_dbg_enabled and (Particles <> nil) then
1029 begin
1030 glDisable(GL_TEXTURE_2D);
1031 if (g_dbg_scale < 0.6) then
1032 glPointSize(1)
1033 else if (g_dbg_scale > 1.3) then
1034 glPointSize(g_dbg_scale + 1)
1035 else
1036 glPointSize(2);
1037 glDisable(GL_POINT_SMOOTH);
1038 glEnable(GL_BLEND);
1039 glBlendFunc(GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA);
1040
1041 glBegin(GL_POINTS);
1042 for i := 0 to High(Particles) do
1043 begin
1044 if Particles[i].alive then
1045 begin
1046 fx := nlerp(Particles[i].oldX, Particles[i].x, gLerpFactor);
1047 fy := nlerp(Particles[i].oldY, Particles[i].y, gLerpFactor);
1048 glColor4ub(Particles[i].red, Particles[i].green, Particles[i].blue, Particles[i].alpha);
1049 glVertex2f(fx, fy);
1050 end;
1051 end;
1052 glEnd;
1053
1054 glDisable(GL_BLEND);
1055 end;
1056 end;
1057
1058 procedure r_Map_DrawGFX (x, y, w, h: Integer);
1059 var i, fx, fy, typ: Integer; tex: TGLMultiTexture;
1060 begin
1061 if gfxlist <> nil then
1062 begin
1063 for i := 0 to High(gfxlist) do
1064 begin
1065 if gfxlist[i].anim.IsValid() then
1066 begin
1067 typ := gfxlist[i].typ;
1068 tex := GFXTextures[typ];
1069 if tex <> nil then
1070 begin
1071 fx := nlerp(gfxlist[i].oldX, gfxlist[i].x, gLerpFactor);
1072 fy := nlerp(gfxlist[i].oldY, gfxlist[i].y, gLerpFactor);
1073 r_Draw_MultiTextureRepeat(tex, gfxlist[i].anim, fx, fy, tex.width, tex.height, false, 255, 255, 255, 255 - GFXAnim[typ].alpha, false);
1074 end;
1075 end;
1076 end;
1077 end;
1078 end;
1079 {$ENDIF}
1080
1081 procedure r_Map_DrawShots (x, y, w, h: Integer);
1082 var i, a, fX, fY, pX, pY, typ: Integer; tex: TGLMultiTexture; anim: ^TAnimState;
1083 begin
1084 if Shots <> nil then
1085 begin
1086 for i := 0 to High(Shots) do
1087 begin
1088 typ := Shots[i].ShotType;
1089 if typ <> 0 then
1090 begin
1091 tex := ShotTextures[typ];
1092 if tex <> nil then
1093 begin
1094 a := 0;
1095 case typ of
1096 WEAPON_ROCKETLAUNCHER, WEAPON_BARON_FIRE, WEAPON_MANCUB_FIRE, WEAPON_SKEL_FIRE:
1097 a := -GetAngle2(Shots[i].Obj.Vel.X, Shots[i].Obj.Vel.Y)
1098 end;
1099 Shots[i].Obj.Lerp(gLerpFactor, fX, fY);
1100 pX := Shots[i].Obj.Rect.Width div 2;
1101 pY := Shots[i].Obj.Rect.Height div 2;
1102 // TODO fix this hack
1103 if Shots[i].Animation.IsValid() then anim := @Shots[i].Animation else anim := @StubShotAnim;
1104 r_Draw_MultiTextureRepeatRotate(tex, anim^, fX, fY, tex.width, tex.height, false, 255, 255, 255, 255, false, pX, pY, a);
1105 end;
1106 end;
1107 end;
1108 end;
1109 // TODO draw g_debug_frames
1110 end;
1111
1112 procedure r_Map_DrawFlags (x, y, w, h: Integer);
1113 var i, dx, fx, fy: Integer; flip: Boolean; tex: TGLMultiTexture;
1114 begin
1115 if gGameSettings.GameMode = GM_CTF then
1116 begin
1117 for i := FLAG_RED to FLAG_BLUE do
1118 begin
1119 if not (gFlags[i].state in [FLAG_STATE_NONE, FLAG_STATE_CAPTURED]) then
1120 begin
1121 gFlags[i].Obj.Lerp(gLerpFactor, fx, fy);
1122 flip := gFlags[i].Direction = TDirection.D_LEFT;
1123 if flip then dx := -1 else dx := +1;
1124 tex := FlagTextures[i];
1125 r_Draw_MultiTextureRepeat(tex, FlagAnim, fx + dx, fy + 1, tex.width, tex.height, flip, 255, 255, 255, 255, false)
1126 end;
1127 end;
1128 end;
1129 // TODO g_debug_frames
1130 end;
1131
1132 {$IFDEF ENABLE_SHELLS}
1133 procedure r_Map_DrawShells (x, y, w, h: Integer);
1134 var i, fx, fy, typ: Integer; t: TGLTexture; p: PObj;
1135 begin
1136 if gShells <> nil then
1137 begin
1138 for i := 0 to High(gShells) do
1139 begin
1140 if gShells[i].alive then
1141 begin
1142 typ := gShells[i].SType;
1143 if typ <= SHELL_LAST then
1144 begin
1145 p := @gShells[i].Obj;
1146 if g_Obj_Collide(x, y, w, h, p) then
1147 begin
1148 t := ShellTextures[typ];
1149 if t <> nil then
1150 begin
1151 p.Lerp(gLerpFactor, fx, fy);
1152 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, 255, 255, 255, 255, false, ShellAnim[typ].dx, ShellAnim[typ].dy, gShells[i].RAngle);
1153 end;
1154 end;
1155 end;
1156 end;
1157 end;
1158 end;
1159 end;
1160 {$ENDIF}
1161
1162 procedure r_Map_CalcAspect (ow, oh, nw, nh: LongInt; horizontal: Boolean; out ww, hh: LongInt);
1163 begin
1164 if horizontal then
1165 begin
1166 ww := nw;
1167 hh := nw * oh div ow;
1168 end
1169 else
1170 begin
1171 ww := nh * ow div oh;
1172 hh := nh;
1173 end;
1174 end;
1175
1176 procedure r_Map_CalcSkyParallax (cx, cy, vw, vh, sw, sh, mw, mh: LongInt; out x, y, w, h: LongInt);
1177 const
1178 factor = 120; (* size ratio between view and sky (120%) *)
1179 limit = 100; (* max speed for parallax *)
1180 var
1181 msw, msh, mvw, mvh, svw, svh: LongInt;
1182 begin
1183 msw := vw * factor div 100;
1184 msh := vh * factor div 100;
1185 r_Map_CalcAspect(sw, sh, msw, msh, (sw / sh) <= (msw / msh), w, h);
1186
1187 (* calc x parallax or sky center on speed limit *)
1188 mvw := MAX(1, mw - vw);
1189 svw := w - vw;
1190 if 100 * svw div mvw <= limit then
1191 x := -cx * svw div mvw
1192 else
1193 x := -svw div 2;
1194
1195 (* calc y parallax or sky center on speed limit *)
1196 mvh := MAX(1, mh - vh);
1197 svh := h - vh;
1198 if 100 * svh div mvh <= limit then
1199 y := -cy * svh div mvh
1200 else
1201 y := -svh div 2;
1202
1203 (* handle out of map bounds *)
1204 if x > 0 then x := 0;
1205 if y > 0 then y := 0;
1206 if x < -svw then x := -svw;
1207 if y < -svh then y := -svh;
1208 end;
1209
1210 procedure r_Map_DrawScreenEffect (x, y, w, h, level: Integer; r, g, b: Byte);
1211 var i: Integer;
1212 begin
1213 if level > 0 then
1214 begin
1215 case level of
1216 0..14: i := 0;
1217 15..34: i := 1;
1218 35..54: i := 2;
1219 55..74: i := 3;
1220 75..94: i := 4;
1221 else i := 5
1222 end;
1223 r_Draw_FillRect(x, y, x + w, y + h, r, g, b, i * 50)
1224 end;
1225 end;
1226
1227 procedure r_Map_DrawScreenEffects (x, y, w, h: Integer; p: TPlayer);
1228 begin
1229 if p <> nil then
1230 begin
1231 r_Map_DrawScreenEffect(x, y, w, h, p.pain, 255, 0, 0);
1232 r_Map_DrawScreenEffect(x, y, w, h, p.pickup, 150, 200, 150);
1233 if (p.FMegaRulez[MR_INVUL] >= gTime) and (p.SpawnInvul < gTime) then
1234 begin
1235 if ((p.FMegaRulez[MR_INVUL] - gTime) > 2100) or not ODD((p.FMegaRulez[MR_INVUL] - gTime) div 300) then
1236 r_Draw_InvertRect(x, y, x + w, y + h, 191, 191, 191, 255);
1237 end;
1238 if p.FMegaRulez[MR_SUIT] >= gTime then
1239 begin
1240 if ((p.FMegaRulez[MR_SUIT] - gTime) > 2100) or not ODD((p.FMegaRulez[MR_SUIT] - gTime) div 300) then
1241 r_Draw_FillRect(x, y, x + w, y + h, 0, 96, 0, 55);
1242 end;
1243 if (p.Berserk >= 0) and (p.Berserk >= gTime) and (gFlash = 2) then
1244 begin
1245 r_Draw_FillRect(x, y, x + w, y + h, 255, 0, 0, 55);
1246 end;
1247 end;
1248 end;
1249
1250 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer; player: TPlayer);
1251 var iter: TPanelGrid.Iter; p: PPanel; cx, cy, xx, yy, ww, hh: Integer; sx, sy, sw, sh: LongInt;
1252 begin
1253 cx := camx - w div 2;
1254 cy := camy - h div 2;
1255 xx := x + cx;
1256 yy := y + cy;
1257 ww := w;
1258 hh := h;
1259
1260 if g_dbg_ignore_bounds = false then
1261 begin
1262 if xx + ww > gMapInfo.Width then
1263 xx := gMapInfo.Width - ww;
1264 if yy + hh > gMapInfo.Height then
1265 yy := gMapInfo.Height - hh;
1266 if xx < 0 then
1267 xx := 0;
1268 if yy < 0 then
1269 yy := 0;
1270 cx := xx - x;
1271 cy := yy - y;
1272 end;
1273
1274 if SkyTexture <> nil then
1275 begin
1276 r_Map_CalcSkyParallax(cx, cy, ww, hh, SkyTexture.width, SkyTexture.height, gMapInfo.Width, gMapInfo.Height, sx, sy, sw, sh);
1277 r_Draw_Texture(SkyTexture, x + sx, y + sy, sw, sh, false, 255, 255, 255, 255, false);
1278 end;
1279
1280 plist.Clear;
1281 iter := mapGrid.ForEachInAABB(xx, yy, ww, hh, GridDrawableMask);
1282 for p in iter do
1283 if ((p^.tag and GridTagDoor) <> 0) = p^.door then
1284 plist.Insert(p^);
1285 iter.Release;
1286
1287 glPushMatrix;
1288 glTranslatef(-cx, -cy, 0);
1289 r_Map_DrawPanelType(PANEL_BACK);
1290 r_Map_DrawPanelType(PANEL_STEP);
1291 r_Map_DrawItems(xx, yy, ww, hh, false);
1292 r_Map_DrawShots(xx, yy, ww, hh);
1293 {$IFDEF ENABLE_SHELLS}
1294 r_Map_DrawShells(xx, yy, ww, hh);
1295 {$ENDIF}
1296 r_Map_DrawPlayers(xx, yy, ww, hh, player);
1297 {$IFDEF ENABLE_GIBS}
1298 r_Map_DrawGibs(xx, yy, ww, hh);
1299 {$ENDIF}
1300 {$IFDEF ENABLE_CORPSES}
1301 r_Map_DrawCorpses(xx, yy, ww, hh);
1302 {$ENDIF}
1303 r_Map_DrawPanelType(PANEL_WALL);
1304 r_Map_DrawMonsters(xx, yy, ww, hh);
1305 r_Map_DrawItems(xx, yy, ww, hh, true);
1306 r_Map_DrawPanelType(PANEL_CLOSEDOOR);
1307 {$IFDEF ENABLE_GFX}
1308 r_Map_DrawParticles(xx, yy, ww, hh);
1309 r_Map_DrawGFX(xx, yy, ww, hh);
1310 {$ENDIF}
1311 r_Map_DrawFlags(xx, yy, ww, hh);
1312 r_Map_DrawPanelType(PANEL_ACID1);
1313 r_Map_DrawPanelType(PANEL_ACID2);
1314 r_Map_DrawPanelType(PANEL_WATER);
1315 r_Map_DrawPanelType(PANEL_FORE);
1316 // TODO draw monsters health bar
1317 // TODO draw players health bar
1318 // TODO draw players indicators
1319 glPopMatrix;
1320
1321 r_Map_DrawScreenEffects(x, y, w, h, player);
1322
1323 // TODO draw minimap (gShowMap)
1324 // TODO draw g_debug_player
1325 end;
1326
1327 procedure r_Map_Update;
1328 var i: Integer;
1329 begin
1330 for i := 0 to ITEM_LAST do
1331 Items[i].anim.Update;
1332 r_Map_UpdateGFX;
1333 FlagAnim.Update;
1334 end;
1335
1336 end.
[MIRROR] a port of Doom 2D Forever to FPC/SDL
[25/02/2024 19:55:35]
DEADSOFTWARE 2012-2024