DEADSOFTWARE

GIT / REPO / FRED-BOY
Projects / d2df-sdl.git / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
gl: load item animations from table
[d2df-sdl.git] / src / game / renders / opengl / r_map.pas
1 (* Copyright (C) Doom 2D: Forever Developers
2 *
3 * This program is free software: you can redistribute it and/or modify
4 * it under the terms of the GNU General Public License as published by
5 * the Free Software Foundation, version 3 of the License ONLY.
6 *
7 * This program is distributed in the hope that it will be useful,
8 * but WITHOUT ANY WARRANTY; without even the implied warranty of
9 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
10 * GNU General Public License for more details.
11 *
12 * You should have received a copy of the GNU General Public License
13 * along with this program. If not, see <http://www.gnu.org/licenses/>.
14 *)
15 {$INCLUDE ../../../shared/a_modes.inc}
16 unit r_map;
17
18 interface
19
20 uses g_base; // TRectWH
21
22 procedure r_Map_Initialize;
23 procedure r_Map_Finalize;
24
25 procedure r_Map_Load;
26 procedure r_Map_Free;
27
28 procedure r_Map_LoadTextures;
29 procedure r_Map_FreeTextures;
30
31 {$IFDEF ENABLE_GFX}
32 procedure r_Map_NewGFX (typ, x, y: Integer);
33 {$ENDIF}
34 {$IFDEF ENABLE_GIBS}
35 function r_Map_GetGibSize (m, i: Integer): TRectWH;
36 {$ENDIF}
37
38 procedure r_Map_Update;
39
40 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer);
41
42 implementation
43
44 uses
45 Math,
46 {$IFDEF USE_GLES1}
47 GLES11,
48 {$ELSE}
49 GL, GLEXT,
50 {$ENDIF}
51 e_log,
52 binheap, MAPDEF, utils,
53 g_options, g_textures, g_basic, g_phys,
54 g_game, g_map, g_panel, g_items, g_monsters, g_playermodel, g_player, g_weapons,
55 {$IFDEF ENABLE_CORPSES}
56 g_corpses,
57 {$ENDIF}
58 {$IFDEF ENABLE_SHELLS}
59 g_shells,
60 {$ENDIF}
61 {$IFDEF ENABLE_GIBS}
62 g_gibs,
63 {$ENDIF}
64 {$IFDEF ENABLE_GFX}
65 g_gfx,
66 {$ENDIF}
67 r_textures, r_draw
68 ;
69
70 const
71 MTABLE: array [0..MONSTER_MAN] of record
72 w, h: Integer;
73 end = (
74 (w: 64; h: 64), // NONE
75 (w: 64; h: 64), // DEMON
76 (w: 64; h: 64), // IMP
77 (w: 64; h: 64), // ZOMBY
78 (w: 64; h: 64), // SERG
79 (w: 128; h: 128), // CYBER
80 (w: 64; h: 64), // CGUN
81 (w: 128; h: 128), // BARON
82 (w: 128; h: 128), // KNIGHT
83 (w: 128; h: 128), // CACO
84 (w: 64; h: 64), // SOUL (DIE is 128x128, see load code)
85 (w: 128; h: 128), // PAIN
86 (w: 256; h: 128), // SPIDER
87 (w: 128; h: 64), // BSP
88 (w: 128; h: 128), // MANCUB
89 (w: 128; h: 128), // SKEL
90 (w: 128; h: 128), // VILE
91 (w: 32; h: 32), // FISH
92 (w: 64; h: 64), // BARREL
93 (w: 128; h: 128), // ROBO
94 (w: 64; h: 64) // MAN
95 );
96 VILEFIRE_DX = 32;
97 VILEFIRE_DY = 128;
98
99 ItemAnim: array [0..ITEM_LAST] of record
100 name: AnsiString;
101 w, h: Integer;
102 d: Integer; // delay
103 n: Integer; // count
104 b: Boolean; // backanim
105 end = (
106 (name: ''; w: 0; h: 0; d: 0; n: 0; b: False),
107 (name: 'MED1'; w: 16; h: 16; d: 0; n: 1; b: False),
108 (name: 'MED2'; w: 32; h: 32; d: 0; n: 1; b: False),
109 (name: 'BMED'; w: 32; h: 32; d: 0; n: 1; b: False),
110 (name: 'ARMORGREEN'; w: 32; h: 16; d: 20; n: 3; b: True),
111 (name: 'ARMORBLUE'; w: 32; h: 16; d: 20; n: 3; b: True),
112 (name: 'SBLUE'; w: 32; h: 32; d: 15; n: 4; b: True),
113 (name: 'SWHITE'; w: 32; h: 32; d: 20; n: 4; b: True),
114 (name: 'SUIT'; w: 32; h: 64; d: 0; n: 1; b: False),
115 (name: 'OXYGEN'; w: 16; h: 32; d: 0; n: 1; b: False),
116 (name: 'INVUL'; w: 32; h: 32; d: 20; n: 4; b: True),
117 (name: 'SAW'; w: 64; h: 32; d: 0; n: 1; b: False),
118 (name: 'SHOTGUN1'; w: 64; h: 16; d: 0; n: 1; b: False),
119 (name: 'SHOTGUN2'; w: 64; h: 16; d: 0; n: 1; b: False),
120 (name: 'MGUN'; w: 64; h: 16; d: 0; n: 1; b: False),
121 (name: 'RLAUNCHER'; w: 64; h: 16; d: 0; n: 1; b: False),
122 (name: 'PGUN'; w: 64; h: 16; d: 0; n: 1; b: False),
123 (name: 'BFG'; w: 64; h: 64; d: 0; n: 1; b: False),
124 (name: 'SPULEMET'; w: 64; h: 16; d: 0; n: 1; b: False),
125 (name: 'CLIP'; w: 16; h: 16; d: 0; n: 1; b: False),
126 (name: 'AMMO'; w: 32; h: 16; d: 0; n: 1; b: False),
127 (name: 'SHELL1'; w: 16; h: 8; d: 0; n: 1; b: False),
128 (name: 'SHELL2'; w: 32; h: 16; d: 0; n: 1; b: False),
129 (name: 'ROCKET'; w: 16; h: 32; d: 0; n: 1; b: False),
130 (name: 'ROCKETS'; w: 64; h: 32; d: 0; n: 1; b: False),
131 (name: 'CELL'; w: 16; h: 16; d: 0; n: 1; b: False),
132 (name: 'CELL2'; w: 32; h: 32; d: 0; n: 1; b: False),
133 (name: 'BPACK'; w: 32; h: 32; d: 0; n: 1; b: False),
134 (name: 'KEYR'; w: 16; h: 16; d: 0; n: 1; b: False),
135 (name: 'KEYG'; w: 16; h: 16; d: 0; n: 1; b: False),
136 (name: 'KEYB'; w: 16; h: 16; d: 0; n: 1; b: False),
137 (name: 'KASTET'; w: 64; h: 32; d: 0; n: 1; b: False),
138 (name: 'PISTOL'; w: 64; h: 16; d: 0; n: 1; b: False),
139 (name: 'BOTTLE'; w: 16; h: 32; d: 20; n: 4; b: True),
140 (name: 'HELMET'; w: 16; h: 16; d: 20; n: 4; b: True),
141 (name: 'JETPACK'; w: 32; h: 32; d: 15; n: 3; b: True),
142 (name: 'INVIS'; w: 32; h: 32; d: 20; n: 4; b: True),
143 (name: 'FLAMETHROWER'; w: 64; h: 32; d: 0; n: 1; b: False),
144 (name: 'FUELCAN'; w: 16; h: 32; d: 0; n: 1; b: False)
145 );
146
147 {$IFDEF ENABLE_GFX}
148 GFXAnim: array [0..R_GFX_LAST] of record
149 name: AnsiString;
150 w, h: Integer;
151 count: Integer;
152 back: Boolean;
153 speed: Integer;
154 rspeed: Integer;
155 alpha: Integer;
156 end = (
157 (name: ''; w: 0; h: 0; count: 0; back: false; speed: 0; rspeed: 0; alpha: 0),
158 (name: 'TELEPORT'; w: 64; h: 64; count: 10; back: false; speed: 6; rspeed: 0; alpha: 0),
159 (name: 'FLAME'; w: 32; h: 32; count: 11; back: false; speed: 3; rspeed: 0; alpha: 0),
160 (name: 'EROCKET'; w: 128; h: 128; count: 6; back: false; speed: 6; rspeed: 0; alpha: 0),
161 (name: 'EBFG'; w: 128; h: 128; count: 6; back: false; speed: 6; rspeed: 0; alpha: 0),
162 (name: 'BFGHIT'; w: 64; h: 64; count: 4; back: false; speed: 4; rspeed: 0; alpha: 0),
163 (name: 'FIRE'; w: 64; h: 128; count: 8; back: false; speed: 4; rspeed: 2; alpha: 0),
164 (name: 'ITEMRESPAWN'; w: 32; h: 32; count: 5; back: true; speed: 4; rspeed: 0; alpha: 0),
165 (name: 'SMOKE'; w: 32; h: 32; count: 10; back: false; speed: 3; rspeed: 0; alpha: 0),
166 (name: 'ESKELFIRE'; w: 64; h: 64; count: 3; back: false; speed: 8; rspeed: 0; alpha: 0),
167 (name: 'EPLASMA'; w: 32; h: 32; count: 4; back: true; speed: 3; rspeed: 0; alpha: 0),
168 (name: 'EBSPFIRE'; w: 32; h: 32; count: 5; back: false; speed: 3; rspeed: 0; alpha: 0),
169 (name: 'EIMPFIRE'; w: 64; h: 64; count: 3; back: false; speed: 6; rspeed: 0; alpha: 0),
170 (name: 'ECACOFIRE'; w: 64; h: 64; count: 3; back: false; speed: 6; rspeed: 0; alpha: 0),
171 (name: 'EBARONFIRE'; w: 64; h: 64; count: 3; back: false; speed: 6; rspeed: 0; alpha: 0),
172 (name: 'TELEPORT'; w: 64; h: 64; count: 10; back: false; speed: 3; rspeed: 0; alpha: 0), // fast
173 (name: 'SMOKE'; w: 32; h: 32; count: 10; back: false; speed: 3; rspeed: 0; alpha: 150), // transparent
174 (name: 'FLAME'; w: 32; h: 32; count: 11; back: false; speed: 3; rspeed: 2; alpha: 0) // random
175 );
176 {$ENDIF}
177
178 ShotAnim: array [0..WEAPON_LAST] of record
179 name: AnsiString;
180 w, h: Integer;
181 count: Integer;
182 end = (
183 (name: ''; w: 0; h: 0; count: 0), // 0 KASTET
184 (name: ''; w: 0; h: 0; count: 0), // 1 SAW
185 (name: ''; w: 0; h: 0; count: 0), // 2 PISTOL
186 (name: ''; w: 0; h: 0; count: 0), // 3 SHOTGUN1
187 (name: ''; w: 0; h: 0; count: 0), // 4 SHOTGUN2
188 (name: ''; w: 0; h: 0; count: 0), // 5 CHAINGUN
189 (name: 'BROCKET'; w: 64; h: 32; count: 1), // 6 ROCKETLAUNCHER
190 (name: 'BPLASMA'; w: 16; h: 16; count: 2), // 7 PLASMA
191 (name: 'BBFG'; w: 64; h: 64; count: 2), // 8 BFG
192 (name: ''; w: 0; h: 0; count: 0), // 9 SUPERPULEMET
193 (name: 'FLAME'; w: 32; h: 32; count: 0{11}), // 10 FLAMETHROWER
194 (name: ''; w: 0; h: 0; count: 0), // 11
195 (name: ''; w: 0; h: 0; count: 0), // 12
196 (name: ''; w: 0; h: 0; count: 0), // 13
197 (name: ''; w: 0; h: 0; count: 0), // 14
198 (name: ''; w: 0; h: 0; count: 0), // 15
199 (name: ''; w: 0; h: 0; count: 0), // 16
200 (name: ''; w: 0; h: 0; count: 0), // 17
201 (name: ''; w: 0; h: 0; count: 0), // 18
202 (name: ''; w: 0; h: 0; count: 0), // 19
203 (name: ''; w: 0; h: 0; count: 0), // 20 ZOMPY_PISTOL
204 (name: 'BIMPFIRE'; w: 16; h: 16; count: 2), // 21 IMP_FIRE
205 (name: 'BBSPFIRE'; w: 16; h: 16; count: 2), // 22 BSP_FIRE
206 (name: 'BCACOFIRE'; w: 16; h: 16; count: 2), // 23 CACO_FIRE
207 (name: 'BBARONFIRE'; w: 64; h: 16; count: 2), // 24 BARON_FIRE
208 (name: 'BMANCUBFIRE'; w: 64; h: 32; count: 2), // 25 MANCUB_FIRE
209 (name: 'BSKELFIRE'; w: 64; h: 64; count: 2) // 26 SKEL_FIRE
210 );
211
212 {$IFDEF ENABLE_SHELLS}
213 ShellAnim: array [0..SHELL_LAST] of record
214 name: AnsiString;
215 dx, dy: Integer;
216 end = (
217 (name: 'EBULLET'; dx: 2; dy: 1), // 0 SHELL_BULLET
218 (name: 'ESHELL'; dx: 4; dy: 2), // 1 SHELL_SHELL
219 (name: 'ESHELL'; dx: 4; dy: 2) // 2 SHELL_DBLSHELL
220 );
221 {$ENDIF}
222
223 type
224 TBinHeapPanelDrawCmp = class
225 public
226 class function less (const a, b: TPanel): Boolean; inline;
227 end;
228
229 TBinHeapPanelDraw = specialize TBinaryHeapBase<TPanel, TBinHeapPanelDrawCmp>;
230
231 TMonsterAnims = array [0..ANIM_LAST, TDirection] of TGLMultiTexture;
232
233 var
234 SkyTexture: TGLTexture;
235 RenTextures: array of record
236 spec: LongInt;
237 tex: TGLMultiTexture;
238 end;
239 Items: array [0..ITEM_LAST] of record
240 tex: TGLMultiTexture;
241 anim: TAnimState;
242 end;
243 MonTextures: array [0..MONSTER_MAN] of TMonsterAnims;
244 WeapTextures: array [0..WP_LAST, 0..W_POS_LAST, 0..W_ACT_LAST] of TGLTexture;
245 ShotTextures: array [0..WEAPON_LAST] of TGLMultiTexture;
246 FlagTextures: array [0..FLAG_LAST] of TGLMultiTexture;
247 VileFire: TGLMultiTexture;
248 Models: array of record
249 anim: array [TDirection, 0..A_LAST] of record
250 base, mask: TGLMultiTexture;
251 end;
252 {$IFDEF ENABLE_GIBS}
253 gibs: record
254 base, mask: TGLTextureArray;
255 rect: TRectArray;
256 end;
257 {$ENDIF}
258 end;
259
260 StubShotAnim: TAnimState;
261 FlagAnim: TAnimState;
262
263 {$IFDEF ENABLE_SHELLS}
264 ShellTextures: array [0..SHELL_LAST] of TGLTexture;
265 {$ENDIF}
266 {$IFDEF ENABLE_GFX}
267 GFXTextures: array [0..R_GFX_LAST] of TGLMultiTexture;
268 gfxlist: array of record
269 typ: Byte;
270 alpha: Byte;
271 x, y: Integer;
272 oldX, oldY: Integer;
273 anim: TAnimState;
274 end = nil;
275 {$ENDIF}
276
277 plist: TBinHeapPanelDraw = nil;
278
279 class function TBinHeapPanelDrawCmp.less (const a, b: TPanel): Boolean; inline;
280 begin
281 if a.tag < b.tag then begin result := true; exit; end;
282 if a.tag > b.tag then begin result := false; exit; end;
283 result := a.arrIdx < b.arrIdx;
284 end;
285
286 procedure r_Map_Initialize;
287 begin
288 StubShotAnim := TAnimState.Create(true, 1, 1);
289 FlagAnim := TAnimState.Create(true, 8, 5);
290 plist := TBinHeapPanelDraw.Create();
291 end;
292
293 procedure r_Map_Finalize;
294 begin
295 plist.Free;
296 StubShotAnim.Invalidate;
297 end;
298
299 procedure r_Map_LoadModel (i: Integer);
300 var prefix: AnsiString; a: Integer; d: TDirection; m: ^TPlayerModelInfo;
301 begin
302 ASSERT(i < Length(Models));
303 ASSERT(i < Length(PlayerModelsArray));
304 m := @PlayerModelsArray[i];
305 prefix := m.FileName + ':TEXTURES/';
306 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
307 begin
308 for a := A_STAND to A_LAST do
309 begin
310 Models[i].anim[d, a].base := nil;
311 Models[i].anim[d, a].mask := nil;
312 if m.anim[d, a].resource <> '' then
313 Models[i].anim[d, a].base := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].resource, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
314 if m.anim[d, a].mask <> '' then
315 Models[i].anim[d, a].mask := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].mask, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
316 end
317 end;
318 {$IFDEF ENABLE_GIBS}
319 Models[i].gibs.base := nil;
320 Models[i].gibs.mask := nil;
321 Models[i].gibs.rect := nil;
322 if m.GibsCount > 0 then
323 begin
324 SetLength(Models[i].gibs.base, m.GibsCount);
325 SetLength(Models[i].gibs.mask, m.GibsCount);
326 SetLength(Models[i].gibs.rect, m.GibsCount);
327 for a := 0 to m.GibsCount - 1 do
328 Models[i].gibs.rect[a] := DefaultGibSize;
329 if r_Textures_LoadStreamFromFile(prefix + m.GibsResource, 32, 32, m.GibsCount, Models[i].gibs.base, Models[i].gibs.rect) then
330 begin
331 if r_Textures_LoadStreamFromFile(prefix + m.GibsMask, 32, 32, m.GibsCount, Models[i].gibs.mask, nil) then
332 begin
333 // ok
334 end;
335 end;
336 for a := 0 to m.GibsCount - 1 do
337 e_logwritefln('model %s gib %s: %sx%s:%sx%s', [i, a, Models[i].gibs.rect[a].x, Models[i].gibs.rect[a].y, Models[i].gibs.rect[a].width, Models[i].gibs.rect[a].height]);
338 end;
339 {$ENDIF}
340 end;
341
342 procedure r_Map_LoadMonsterAnim (m, a: Integer; d: TDirection);
343 const dir: array [TDirection] of AnsiString = ('_L', '');
344 var w, h, count: Integer;
345 begin
346 count := MONSTER_ANIMTABLE[m].AnimCount[a];
347 if count > 0 then
348 begin
349 w := MTABLE[m].w;
350 h := MTABLE[m].h;
351 if (m = MONSTER_SOUL) and (a = ANIM_DIE) then
352 begin
353 // special case
354 w := 128;
355 h := 128;
356 end;
357 MonTextures[m, a, d] := r_Textures_LoadMultiFromFileAndInfo(
358 GameWAD + ':MTEXTURES/' + MONSTERTABLE[m].name + '_' + ANIMTABLE[a].name + dir[d],
359 w,
360 h,
361 count,
362 False,
363 False
364 );
365 end
366 else
367 MonTextures[m, a, d] := nil;
368 end;
369
370 procedure r_Map_Load;
371 const
372 WeapName: array [0..WP_LAST] of AnsiString = ('', 'CSAW', 'HGUN', 'SG', 'SSG', 'MGUN', 'RKT', 'PLZ', 'BFG', 'SPL', 'FLM');
373 WeapPos: array [0..W_POS_LAST] of AnsiString = ('', '_UP', '_DN');
374 WeapAct: array [0..W_ACT_LAST] of AnsiString = ('', '_FIRE');
375 var
376 i, j, k: Integer; d: TDirection;
377 begin
378 // --------- items --------- //
379 for i := 0 to ITEM_LAST do
380 begin
381 if ItemAnim[i].n > 0 then
382 begin
383 Items[i].tex := r_Textures_LoadMultiFromFileAndInfo(
384 GameWAD + ':TEXTURES/' + ItemAnim[i].name,
385 ItemAnim[i].w,
386 ItemAnim[i].h,
387 ItemAnim[i].n,
388 ItemAnim[i].b,
389 false
390 );
391 k := IfThen(ItemAnim[i].b, ItemAnim[i].n * 2 - 2, ItemAnim[i].n);
392 Items[i].anim := TAnimState.Create(True, ItemAnim[i].d, k);
393 end;
394 end;
395 // --------- monsters --------- //
396 for i := MONSTER_DEMON to MONSTER_MAN do
397 for j := 0 to ANIM_LAST do
398 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
399 r_Map_LoadMonsterAnim(i, j, d);
400 VileFire := r_Textures_LoadMultiFromFileAndInfo(GameWAD + ':TEXTURES/FIRE', 64, 128, 8, False, False);
401 // --------- player models --------- //
402 if PlayerModelsArray <> nil then
403 begin
404 SetLength(Models, Length(PlayerModelsArray));
405 for i := 0 to High(PlayerModelsArray) do
406 r_Map_LoadModel(i);
407 end;
408 // --------- player weapons --------- //
409 for i := 1 to WP_LAST do
410 for j := 0 to W_POS_LAST do
411 for k := 0 to W_ACT_LAST do
412 WeapTextures[i, j, k] := r_Textures_LoadFromFile(GameWAD + ':WEAPONS\' + WeapName[i] + WeapPos[j] + WeapAct[k]);
413 // --------- gfx animations --------- //
414 {$IFDEF ENABLE_GFX}
415 for i := 1 to R_GFX_LAST do
416 if GFXAnim[i].count > 0 then
417 GFXTextures[i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/' + GFXAnim[i].name, GFXAnim[i].w, GFXAnim[i].h, GFXAnim[i].count, GFXAnim[i].back);
418 {$ENDIF}
419 // --------- shots --------- //
420 for i := 0 to WEAPON_LAST do
421 if ShotAnim[i].count > 0 then
422 ShotTextures[i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/' + ShotAnim[i].name, ShotAnim[i].w, ShotAnim[i].h, ShotAnim[i].count, false);
423 // --------- flags --------- //
424 FlagTextures[FLAG_NONE] := nil;
425 FlagTextures[FLAG_RED] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGRED', 64, 64, 5, false);
426 FlagTextures[FLAG_BLUE] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGBLUE', 64, 64, 5, false);
427 // FlagTextures[FLAG_DOM] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGDOM', 64, 64, 8, false);
428 // --------- shells --------- //
429 {$IFDEF ENABLE_SHELLS}
430 for i := 0 to SHELL_LAST do
431 ShellTextures[i] := r_Textures_LoadFromFile(GameWad + ':TEXTURES/' + ShellAnim[i].name);
432 {$ENDIF}
433 end;
434
435 procedure r_Map_Free;
436 var i, j, k, a: Integer; d: TDirection;
437 begin
438 {$IFDEF ENABLE_SHELLS}
439 for i := 0 to SHELL_LAST do
440 begin
441 if ShellTextures[i] <> nil then
442 ShellTextures[i].Free;
443 ShellTextures[i] := nil;
444 end;
445 {$ENDIF}
446 for i := 0 to FLAG_LAST do
447 begin
448 if FlagTextures[i] <> nil then
449 FlagTextures[i].Free;
450 FlagTextures[i] := nil;
451 end;
452 for i := 0 to WEAPON_LAST do
453 begin
454 if ShotTextures[i] <> nil then
455 ShotTextures[i].Free;
456 ShotTextures[i] := nil;
457 end;
458 {$IFDEF ENABLE_GFX}
459 gfxlist := nil;
460 for i := 0 to R_GFX_LAST do
461 begin
462 if GFXTextures[i] <> nil then
463 GFXTextures[i].Free;
464 GFXTextures[i] := nil;
465 end;
466 {$ENDIF}
467 for i := 1 to WP_LAST do
468 begin
469 for j := 0 to W_POS_LAST do
470 begin
471 for k := 0 to W_ACT_LAST do
472 begin
473 if WeapTextures[i, j, k] <> nil then
474 WeapTextures[i, j, k].Free;
475 WeapTextures[i, j, k] := nil;
476 end;
477 end;
478 end;
479 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
480 begin
481 for a := A_STAND to A_LAST do
482 begin
483 if Models[i].anim[d, a].base <> nil then
484 Models[i].anim[d, a].base.Free;
485 if Models[i].anim[d, a].mask <> nil then
486 Models[i].anim[d, a].mask.Free;
487 Models[i].anim[d, a].base := nil;
488 Models[i].anim[d, a].mask := nil;
489 end;
490 end;
491 for i := MONSTER_DEMON to MONSTER_MAN do
492 begin
493 for j := 0 to ANIM_LAST do
494 begin
495 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
496 begin
497 if MonTextures[i, j, d] <> nil then
498 MonTextures[i, j, d].Free;
499 MonTextures[i, j, d] := nil;
500 end;
501 end;
502 end;
503 for i := 0 to ITEM_LAST do
504 begin
505 if Items[i].tex <> nil then
506 begin
507 Items[i].tex.Free;
508 Items[i].tex := nil;
509 end;
510 Items[i].anim.Invalidate;
511 end;
512 end;
513
514 procedure r_Map_LoadTextures;
515 var i, n: Integer;
516 begin
517 if Textures <> nil then
518 begin
519 n := Length(Textures);
520 SetLength(RenTextures, n);
521 for i := 0 to n - 1 do
522 begin
523 RenTextures[i].tex := nil;
524 case Textures[i].TextureName of
525 TEXTURE_NAME_WATER: RenTextures[i].spec := TEXTURE_SPECIAL_WATER;
526 TEXTURE_NAME_ACID1: RenTextures[i].spec := TEXTURE_SPECIAL_ACID1;
527 TEXTURE_NAME_ACID2: RenTextures[i].spec := TEXTURE_SPECIAL_ACID2;
528 else
529 RenTextures[i].spec := 0;
530 RenTextures[i].tex := r_Textures_LoadMultiFromFile(Textures[i].FullName);
531 if RenTextures[i].tex = nil then
532 e_LogWritefln('r_Map_LoadTextures: failed to load texture: %s', [Textures[i].FullName]);
533 end;
534 end;
535 end;
536 if gMapInfo.SkyFullName <> '' then
537 SkyTexture := r_Textures_LoadFromFile(gMapInfo.SkyFullName);
538 plist.Clear;
539 end;
540
541 procedure r_Map_FreeTextures;
542 var i: Integer;
543 begin
544 plist.Clear;
545 if SkyTexture <> nil then
546 SkyTexture.Free;
547 SkyTexture := nil;
548 if RenTextures <> nil then
549 for i := 0 to High(RenTextures) do
550 if RenTextures[i].tex <> nil then
551 RenTextures[i].tex.Free;
552 RenTextures := nil;
553 end;
554
555 procedure r_Map_DrawPanel (p: TPanel);
556 var Texture: Integer; t: TGLMultiTexture;
557 begin
558 ASSERT(p <> nil);
559 if p.FCurTexture >= 0 then
560 begin
561 Texture := p.TextureIDs[p.FCurTexture].Texture;
562 t := RenTextures[Texture].tex;
563
564 if (RenTextures[Texture].spec = 0) or (t <> nil) then
565 begin
566 if t = nil then
567 r_Draw_TextureRepeat(nil, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
568 else if p.TextureIDs[p.FCurTexture].AnTex.IsValid() then
569 r_Draw_MultiTextureRepeat(t, p.TextureIDs[p.FCurTexture].AnTex, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
570 else
571 r_Draw_TextureRepeat(t.GetTexture(0), p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
572 end;
573
574 if t = nil then
575 begin
576 case RenTextures[Texture].spec of
577 TEXTURE_SPECIAL_WATER: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 0, 255, 255);
578 TEXTURE_SPECIAL_ACID1: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 230, 0, 255);
579 TEXTURE_SPECIAL_ACID2: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 230, 0, 0, 255);
580 end
581 end
582 end
583 end;
584
585 procedure r_Map_DrawPanelType (panelTyp: DWORD);
586 var tagMask, i: Integer; p: TPanel;
587 begin
588 i := 0;
589 tagMask := PanelTypeToTag(panelTyp);
590 while plist.count > 0 do
591 begin
592 p := TPanel(plist.Front());
593 if (p.tag and tagMask) = 0 then
594 break;
595 r_Map_DrawPanel(p);
596 Inc(i);
597 plist.PopFront
598 end;
599 end;
600
601 procedure r_Map_DrawItems (x, y, w, h: Integer; drop: Boolean);
602 var i, fX, fY: Integer; it: PItem; t: TGLMultiTexture;
603 begin
604 if ggItems <> nil then
605 begin
606 for i := 0 to High(ggItems) do
607 begin
608 it := @ggItems[i];
609 if it.used and it.alive and (it.dropped = drop) and (it.ItemType > ITEM_NONE) and (it.ItemType <= ITEM_LAST) then
610 begin
611 t := Items[it.ItemType].tex;
612 if g_Collide(it.obj.x, it.obj.y, t.width, t.height, x, y, w, h) then
613 begin
614 it.obj.Lerp(gLerpFactor, fX, fY);
615 r_Draw_MultiTextureRepeat(t, Items[it.ItemType].anim, fX, fY, t.width, t.height, false, 255, 255, 255, 255, false);
616 // if g_debug_frames then // TODO draw collision frame
617 end;
618 end;
619 end;
620 end;
621 end;
622
623 function r_Map_GetMonsterTexture (m, a: Integer; d: TDirection; out t: TGLMultiTexture; out dx, dy: Integer; out flip: Boolean): Boolean;
624 // var c: Integer;
625 begin
626 t := nil; dx := 0; dy := 0; flip := false;
627 result := MonTextures[m, a, d] <> nil;
628 if result = false then
629 begin
630 flip := true;
631 if d = TDirection.D_RIGHT then d := TDirection.D_LEFT else d := TDirection.D_RIGHT;
632 result := MonTextures[m, a, d] <> nil;
633 end;
634 if result = true then
635 begin
636 t := MonTextures[m, a, d];
637 if d = TDirection.D_LEFT then
638 begin
639 dx := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].X;
640 dy := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].Y;
641 end
642 else
643 begin
644 dx := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].X;
645 dy := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].Y;
646 end;
647 if flip then
648 begin
649 // c := (MONSTERTABLE[MonsterType].Rect.X - dx) + MONSTERTABLE[MonsterType].Rect.Width;
650 // dx := MTABLE[m].width - c - MONSTERTABLE[MonsterType].Rect.X;
651 dx := -dx;
652 end;
653 end;
654 end;
655
656 procedure r_Map_DrawMonsterAttack (constref mon: TMonster);
657 var o: TObj;
658 begin
659 if VileFire <> nil then
660 if (mon.MonsterType = MONSTER_VILE) and (mon.MonsterState = MONSTATE_SHOOT) then
661 if mon.VileFireAnim.IsValid() and GetPos(mon.MonsterTargetUID, @o) then
662 r_Draw_MultiTextureRepeat(VileFire, mon.VileFireAnim, o.x + o.rect.x + (o.rect.width div 2) - VILEFIRE_DX, o.y + o.rect.y + o.rect.height - VILEFIRE_DY, VileFire.width, VileFire.height, False, 255, 255, 255, 255, false);
663 end;
664
665 procedure r_Map_DrawMonster (constref mon: TMonster);
666 var m, a, fX, fY, dx, dy: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture;
667 begin
668 m := mon.MonsterType;
669 a := mon.MonsterAnim;
670 d := mon.GameDirection;
671
672 mon.obj.Lerp(gLerpFactor, fX, fY);
673
674 if r_Map_GetMonsterTexture(m, a, d, t, dx, dy, flip) then
675 r_Draw_MultiTextureRepeat(t, mon.DirAnim[a, d], fX + dx, fY + dy, t.width, t.height, flip, 255, 255, 255, 255, false);
676
677 {
678 if g_debug_frames
679 // TODO draw frame
680 }
681 end;
682
683 procedure r_Map_DrawMonsters (x, y, w, h: Integer);
684 var i: Integer; m: TMonster;
685 begin
686 if gMonsters <> nil then
687 begin
688 for i := 0 to High(gMonsters) do
689 begin
690 m := gMonsters[i];
691 if m <> nil then
692 begin
693 r_Map_DrawMonsterAttack(m);
694 // TODO select from grid
695 if g_Collide(m.obj.x + m.obj.rect.x, m.obj.y + m.obj.rect.y, m.obj.rect.width, m.obj.rect.height, x, y, w, h) then
696 r_Map_DrawMonster(m);
697 end;
698 end;
699 end;
700 end;
701
702 function r_Map_GetPlayerModelTex (i: Integer; var a: Integer; var d: TDirection; out flip: Boolean): Boolean;
703 begin
704 flip := false;
705 result := Models[i].anim[d, a].base <> nil;
706 if result = false then
707 begin
708 flip := true;
709 if d = TDirection.D_LEFT then d := TDirection.D_RIGHT else d := TDirection.D_LEFT;
710 result := Models[i].anim[d, a].base <> nil;
711 end;
712 end;
713
714 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer);
715 var a, pos, act, xx, yy, angle: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture; tex: TGLTexture; c: TRGB;
716 begin
717 a := pm.CurrentAnimation;
718 d := pm.Direction;
719
720 (* draw flag*)
721 t := FlagTextures[pm.Flag];
722 if (t <> nil) and not (a in [A_DIE1, A_DIE2]) then
723 begin
724 flip := d = TDirection.D_RIGHT;
725 angle := PlayerModelsArray[pm.id].FlagAngle;
726 xx := PlayerModelsArray[pm.id].FlagPoint.X;
727 yy := PlayerModelsArray[pm.id].FlagPoint.Y;
728 r_Draw_MultiTextureRepeatRotate(
729 t,
730 FlagAnim,
731 x + IfThen(flip, 2 * FLAG_BASEPOINT.X - xx + 1, xx - 1) - FLAG_BASEPOINT.X,
732 y + yy - FLAG_BASEPOINT.Y + 1,
733 t.width,
734 t.height,
735 flip,
736 255, 255, 255, 255, false,
737 IfThen(flip, 64 - FLAG_BASEPOINT.X, FLAG_BASEPOINT.X),
738 FLAG_BASEPOINT.Y,
739 IfThen(flip, angle, -angle)
740 );
741 end;
742
743 (* draw weapon *)
744 if PlayerModelsArray[pm.id].HaveWeapon and not (a in [A_DIE1, A_DIE2, A_PAIN]) then
745 begin
746 case a of
747 A_SEEUP, A_ATTACKUP: pos := W_POS_UP;
748 A_SEEDOWN, A_ATTACKDOWN: pos := W_POS_DOWN;
749 else pos := W_POS_NORMAL;
750 end;
751 if (a in [A_ATTACK, A_ATTACKUP, A_ATTACKDOWN]) or pm.GetFire() then
752 act := W_ACT_FIRE
753 else
754 act := W_ACT_NORMAL;
755 tex := WeapTextures[pm.CurrentWeapon, pos, act];
756 if tex <> nil then
757 begin
758 xx := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].X;
759 yy := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].Y;
760 r_Draw_Texture(
761 tex,
762 x + xx,
763 y + yy,
764 tex.width,
765 tex.height,
766 d = TDirection.D_LEFT,
767 255, 255, 255, 255, false
768 );
769 end;
770 end;
771
772 (* draw body *)
773 if r_Map_GetPlayerModelTex(pm.id, a, d, flip) then
774 begin
775 t := Models[pm.id].anim[d, a].base;
776 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip, 255, 255, 255, 255, false);
777 t := Models[pm.id].anim[d, a].mask;
778 if t <> nil then
779 begin
780 c := pm.Color;
781 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip, c.r, c.g, c.b, 255, false);
782 end;
783 end;
784 end;
785
786 procedure r_Map_DrawPlayer (p: TPlayer);
787 var fX, fY, fSlope: Integer;
788 begin
789 if p.alive then
790 begin
791 fX := p.obj.x; fY := p.obj.y;
792 // TODO fix lerp
793 //p.obj.Lerp(gLerpFactor, fX, fY);
794 fSlope := nlerp(p.SlopeOld, p.obj.slopeUpLeft, gLerpFactor);
795 // TODO draw punch
796 // TODO invul pentagram
797 // TODO draw it with transparency
798 r_Map_DrawPlayerModel(p.Model, fX, fY + fSlope);
799 end;
800 // TODO draw g_debug_frames
801 // TODO draw chat bubble
802 // TODO draw aim
803 end;
804
805 procedure r_Map_DrawPlayers (x, y, w, h: Integer);
806 var i: Integer;
807 begin
808 // TODO draw only visible
809 if gPlayers <> nil then
810 for i := 0 to High(gPlayers) do
811 if gPlayers[i] <> nil then
812 r_Map_DrawPlayer(gPlayers[i]);
813 end;
814
815 {$IFDEF ENABLE_GIBS}
816 function r_Map_GetGibSize (m, i: Integer): TRectWH;
817 begin
818 result := Models[m].gibs.rect[i];
819 end;
820
821 procedure r_Map_DrawGibs (x, y, w, h: Integer);
822 var i, fx, fy, m, id, rx, ry, ra: Integer; p: PObj; t: TGLTexture;
823 begin
824 if gGibs <> nil then
825 begin
826 for i := 0 to High(gGibs) do
827 begin
828 if gGibs[i].alive then
829 begin
830 p := @gGibs[i].Obj;
831 if g_Obj_Collide(x, y, w, h, p) then
832 begin
833 p.Lerp(gLerpFactor, fx, fy);
834 id := gGibs[i].GibID;
835 m := gGibs[i].ModelID;
836 t := Models[m].gibs.base[id];
837 if t <> nil then
838 begin
839 rx := p.Rect.X + p.Rect.Width div 2;
840 ry := p.Rect.Y + p.Rect.Height div 2;
841 ra := gGibs[i].RAngle;
842 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, 255, 255, 255, 255, false, rx, ry, ra);
843 t := Models[m].gibs.mask[id];
844 if t <> nil then
845 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, gGibs[i].Color.R, gGibs[i].Color.G, gGibs[i].Color.B, 255, false, rx, ry, ra);
846 // r_Draw_TextureRepeatRotate(nil, fx + p.Rect.X, fy + p.Rect.Y, p.Rect.Width, p.Rect.Height, false, 255, 255, 255, 255, false, p.Rect.Width div 2, p.Rect.Height div 2, ra);
847 end;
848 end;
849 end;
850 end;
851 end;
852 end;
853 {$ENDIF}
854
855 {$IFDEF ENABLE_CORPSES}
856 procedure r_Map_DrawCorpses (x, y, w, h: Integer);
857 var i, fX, fY: Integer; p: TCorpse;
858 begin
859 if gCorpses <> nil then
860 begin
861 for i := 0 to High(gCorpses) do
862 begin
863 p := gCorpses[i];
864 if (p <> nil) and (p.state <> CORPSE_STATE_REMOVEME) and (p.model <> nil) then
865 begin
866 p.obj.Lerp(gLerpFactor, fX, fY);
867 r_Map_DrawPlayerModel(p.model, fX, fY);
868 end;
869 end;
870 end;
871 end;
872 {$ENDIF}
873
874 {$IFDEF ENABLE_GFX}
875 function r_Map_GetGFXID (): Integer;
876 var i: Integer;
877 begin
878 i := 0;
879 if gfxlist <> nil then
880 begin
881 while (i < Length(gfxlist)) and gfxlist[i].anim.IsValid() do
882 Inc(i);
883 if i >= Length(gfxlist) then
884 SetLength(gfxlist, Length(gfxlist) + 1)
885 end
886 else
887 SetLength(gfxlist, 1);
888 gfxlist[i].typ := R_GFX_NONE;
889 gfxlist[i].anim.Invalidate;
890 result := i
891 end;
892
893 procedure r_Map_NewGFX (typ, x, y: Integer);
894 var i: Integer;
895 begin
896 if gpart_dbg_enabled and (typ > 0) and (typ <= R_GFX_LAST) then
897 begin
898 i := r_Map_GetGFXID();
899 if i >= 0 then
900 begin
901 gfxlist[i].typ := typ;
902 gfxlist[i].x := x;
903 gfxlist[i].y := y;
904 gfxlist[i].oldX := x;
905 gfxlist[i].oldY := y;
906 gfxlist[i].anim := TAnimState.Create(false, GFXAnim[typ].speed + Random(GFXAnim[typ].rspeed), GFXAnim[typ].count);
907 gfxlist[i].anim.Reset();
908 gfxlist[i].anim.Enable();
909 end;
910 end;
911 end;
912
913 procedure r_Map_UpdateGFX;
914 var i: Integer;
915 begin
916 if gfxlist <> nil then
917 begin
918 for i := 0 to High(gfxlist) do
919 begin
920 if gfxlist[i].anim.IsValid() then
921 begin
922 gfxlist[i].oldX := gfxlist[i].x;
923 gfxlist[i].oldY := gfxlist[i].y;
924 case gfxlist[i].typ of
925 R_GFX_FLAME, R_GFX_SMOKE:
926 begin
927 if Random(3) = 0 then
928 gfxlist[i].x := gfxlist[i].x - 1 + Random(3);
929 if Random(2) = 0 then
930 gfxlist[i].y := gfxlist[i].y - Random(2);
931 end;
932 end;
933 if gfxlist[i].anim.played then
934 gfxlist[i].anim.Invalidate
935 else
936 gfxlist[i].anim.Update
937 end;
938 end;
939 end;
940 end;
941
942 procedure r_Map_DrawParticles (x, y, w, h: Integer);
943 var i, fx, fy: Integer;
944 begin
945 if gpart_dbg_enabled and (Particles <> nil) then
946 begin
947 glDisable(GL_TEXTURE_2D);
948 if (g_dbg_scale < 0.6) then
949 glPointSize(1)
950 else if (g_dbg_scale > 1.3) then
951 glPointSize(g_dbg_scale + 1)
952 else
953 glPointSize(2);
954 glDisable(GL_POINT_SMOOTH);
955 glEnable(GL_BLEND);
956 glBlendFunc(GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA);
957
958 glBegin(GL_POINTS);
959 for i := 0 to High(Particles) do
960 begin
961 if Particles[i].alive then
962 begin
963 fx := nlerp(Particles[i].oldX, Particles[i].x, gLerpFactor);
964 fy := nlerp(Particles[i].oldY, Particles[i].y, gLerpFactor);
965 glColor4ub(Particles[i].red, Particles[i].green, Particles[i].blue, Particles[i].alpha);
966 glVertex2f(fx, fy);
967 end;
968 end;
969 glEnd;
970
971 glDisable(GL_BLEND);
972 end;
973 end;
974
975 procedure r_Map_DrawGFX (x, y, w, h: Integer);
976 var i, fx, fy, typ: Integer; tex: TGLMultiTexture;
977 begin
978 if gfxlist <> nil then
979 begin
980 for i := 0 to High(gfxlist) do
981 begin
982 if gfxlist[i].anim.IsValid() then
983 begin
984 typ := gfxlist[i].typ;
985 tex := GFXTextures[typ];
986 if tex <> nil then
987 begin
988 fx := nlerp(gfxlist[i].oldX, gfxlist[i].x, gLerpFactor);
989 fy := nlerp(gfxlist[i].oldY, gfxlist[i].y, gLerpFactor);
990 r_Draw_MultiTextureRepeat(tex, gfxlist[i].anim, fx, fy, tex.width, tex.height, false, 255, 255, 255, 255 - GFXAnim[typ].alpha, false);
991 end;
992 end;
993 end;
994 end;
995 end;
996 {$ENDIF}
997
998 procedure r_Map_DrawShots (x, y, w, h: Integer);
999 var i, a, fX, fY, pX, pY, typ: Integer; tex: TGLMultiTexture; anim: ^TAnimState;
1000 begin
1001 if Shots <> nil then
1002 begin
1003 for i := 0 to High(Shots) do
1004 begin
1005 typ := Shots[i].ShotType;
1006 if typ <> 0 then
1007 begin
1008 tex := ShotTextures[typ];
1009 if tex <> nil then
1010 begin
1011 a := 0;
1012 case typ of
1013 WEAPON_ROCKETLAUNCHER, WEAPON_BARON_FIRE, WEAPON_MANCUB_FIRE, WEAPON_SKEL_FIRE:
1014 a := -GetAngle2(Shots[i].Obj.Vel.X, Shots[i].Obj.Vel.Y)
1015 end;
1016 Shots[i].Obj.Lerp(gLerpFactor, fX, fY);
1017 pX := Shots[i].Obj.Rect.Width div 2;
1018 pY := Shots[i].Obj.Rect.Height div 2;
1019 // TODO fix this hack
1020 if Shots[i].Animation.IsValid() then anim := @Shots[i].Animation else anim := @StubShotAnim;
1021 r_Draw_MultiTextureRepeatRotate(tex, anim^, fX, fY, tex.width, tex.height, false, 255, 255, 255, 255, false, pX, pY, a);
1022 end;
1023 end;
1024 end;
1025 end;
1026 end;
1027
1028 procedure r_Map_DrawFlags (x, y, w, h: Integer);
1029 var i, dx, fx, fy: Integer; flip: Boolean; tex: TGLMultiTexture;
1030 begin
1031 if gGameSettings.GameMode = GM_CTF then
1032 begin
1033 for i := FLAG_RED to FLAG_BLUE do
1034 begin
1035 if not (gFlags[i].state in [FLAG_STATE_NONE, FLAG_STATE_CAPTURED]) then
1036 begin
1037 gFlags[i].Obj.Lerp(gLerpFactor, fx, fy);
1038 flip := gFlags[i].Direction = TDirection.D_LEFT;
1039 if flip then dx := -1 else dx := +1;
1040 tex := FlagTextures[i];
1041 r_Draw_MultiTextureRepeat(tex, FlagAnim, fx + dx, fy + 1, tex.width, tex.height, flip, 255, 255, 255, 255, false)
1042 // TODO g_debug_frames
1043 end;
1044 end;
1045 end;
1046 end;
1047
1048 {$IFDEF ENABLE_SHELLS}
1049 procedure r_Map_DrawShells (x, y, w, h: Integer);
1050 var i, fx, fy, typ: Integer; t: TGLTexture; p: PObj;
1051 begin
1052 if gShells <> nil then
1053 begin
1054 for i := 0 to High(gShells) do
1055 begin
1056 if gShells[i].alive then
1057 begin
1058 typ := gShells[i].SType;
1059 if typ <= SHELL_LAST then
1060 begin
1061 p := @gShells[i].Obj;
1062 if g_Obj_Collide(x, y, w, h, p) then
1063 begin
1064 t := ShellTextures[typ];
1065 if t <> nil then
1066 begin
1067 p.Lerp(gLerpFactor, fx, fy);
1068 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, 255, 255, 255, 255, false, ShellAnim[typ].dx, ShellAnim[typ].dy, gShells[i].RAngle);
1069 end;
1070 end;
1071 end;
1072 end;
1073 end;
1074 end;
1075 end;
1076 {$ENDIF}
1077
1078 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer);
1079 var iter: TPanelGrid.Iter; p: PPanel; cx, cy, xx, yy, ww, hh: Integer;
1080 begin
1081 cx := camx - w div 2;
1082 cy := camy - h div 2;
1083 xx := x + cx;
1084 yy := y + cy;
1085 ww := w;
1086 hh := h;
1087
1088 if SkyTexture <> nil then
1089 r_Draw_Texture(SkyTexture, x, y, w, h, false, 255, 255, 255, 255, false);
1090
1091 plist.Clear;
1092 iter := mapGrid.ForEachInAABB(xx, yy, ww, hh, GridDrawableMask);
1093 for p in iter do
1094 if ((p^.tag and GridTagDoor) <> 0) = p^.door then
1095 plist.Insert(p^);
1096 iter.Release;
1097
1098 glPushMatrix;
1099 glTranslatef(-cx, -cy, 0);
1100 r_Map_DrawPanelType(PANEL_BACK);
1101 r_Map_DrawPanelType(PANEL_STEP);
1102 r_Map_DrawItems(xx, yy, ww, hh, false);
1103 r_Map_DrawShots(xx, yy, ww, hh);
1104 {$IFDEF ENABLE_SHELLS}
1105 r_Map_DrawShells(xx, yy, ww, hh);
1106 {$ENDIF}
1107 r_Map_DrawPlayers(xx, yy, ww, hh);
1108 {$IFDEF ENABLE_GIBS}
1109 r_Map_DrawGibs(xx, yy, ww, hh);
1110 {$ENDIF}
1111 {$IFDEF ENABLE_CORPSES}
1112 r_Map_DrawCorpses(xx, yy, ww, hh);
1113 {$ENDIF}
1114 r_Map_DrawPanelType(PANEL_WALL);
1115 r_Map_DrawMonsters(xx, yy, ww, hh);
1116 r_Map_DrawItems(xx, yy, ww, hh, true);
1117 r_Map_DrawPanelType(PANEL_CLOSEDOOR);
1118 {$IFDEF ENABLE_GFX}
1119 r_Map_DrawParticles(xx, yy, ww, hh);
1120 r_Map_DrawGFX(xx, yy, ww, hh);
1121 {$ENDIF}
1122 r_Map_DrawFlags(xx, yy, ww, hh);
1123 r_Map_DrawPanelType(PANEL_ACID1);
1124 r_Map_DrawPanelType(PANEL_ACID2);
1125 r_Map_DrawPanelType(PANEL_WATER);
1126 r_Map_DrawPanelType(PANEL_FORE);
1127 glPopMatrix;
1128 end;
1129
1130 procedure r_Map_Update;
1131 var i: Integer;
1132 begin
1133 for i := 0 to ITEM_LAST do
1134 Items[i].anim.Update;
1135 r_Map_UpdateGFX;
1136 FlagAnim.Update;
1137 end;
1138
1139 end.
[MIRROR] a port of Doom 2D Forever to FPC/SDL
[25/02/2024 19:55:35]
DEADSOFTWARE 2012-2024