DEADSOFTWARE

GIT / REPO / FRED-BOY
Projects / d2df-sdl.git / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
gl: handle punch animation in render
[d2df-sdl.git] / src / game / renders / opengl / r_map.pas
1 (* Copyright (C) Doom 2D: Forever Developers
2 *
3 * This program is free software: you can redistribute it and/or modify
4 * it under the terms of the GNU General Public License as published by
5 * the Free Software Foundation, version 3 of the License ONLY.
6 *
7 * This program is distributed in the hope that it will be useful,
8 * but WITHOUT ANY WARRANTY; without even the implied warranty of
9 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
10 * GNU General Public License for more details.
11 *
12 * You should have received a copy of the GNU General Public License
13 * along with this program. If not, see <http://www.gnu.org/licenses/>.
14 *)
15 {$INCLUDE ../../../shared/a_modes.inc}
16 unit r_map;
17
18 interface
19
20 uses g_base, g_player, g_playermodel; // TRectWH, TPlayer, TPlayerModel
21
22 procedure r_Map_Initialize;
23 procedure r_Map_Finalize;
24
25 procedure r_Map_Load;
26 procedure r_Map_Free;
27
28 procedure r_Map_LoadTextures;
29 procedure r_Map_FreeTextures;
30
31 {$IFDEF ENABLE_GFX}
32 procedure r_Map_NewGFX (typ, x, y: Integer);
33 {$ENDIF}
34 {$IFDEF ENABLE_GIBS}
35 function r_Map_GetGibSize (m, i: Integer): TRectWH;
36 {$ENDIF}
37 {$IFDEF ENABLE_MENU}
38 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer; alpha: Byte);
39 {$ENDIF}
40
41 procedure r_Map_Update;
42
43 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer; player: TPlayer);
44
45 implementation
46
47 uses
48 Math, SysUtils,
49 {$IFDEF USE_GLES1}
50 GLES11,
51 {$ELSE}
52 GL, GLEXT,
53 {$ENDIF}
54 e_log,
55 binheap, MAPDEF, utils,
56 g_options, g_animations, g_basic, g_phys,
57 g_game, g_map, g_panel, g_items, g_monsters, g_weapons,
58 {$IFDEF ENABLE_CORPSES}
59 g_corpses,
60 {$ENDIF}
61 {$IFDEF ENABLE_SHELLS}
62 g_shells,
63 {$ENDIF}
64 {$IFDEF ENABLE_GIBS}
65 g_gibs,
66 {$ENDIF}
67 {$IFDEF ENABLE_GFX}
68 g_gfx,
69 {$ENDIF}
70 r_textures, r_draw, r_common
71 ;
72
73 const
74 MTABLE: array [0..MONSTER_MAN] of record
75 w, h: Integer;
76 end = (
77 (w: 64; h: 64), // NONE
78 (w: 64; h: 64), // DEMON
79 (w: 64; h: 64), // IMP
80 (w: 64; h: 64), // ZOMBY
81 (w: 64; h: 64), // SERG
82 (w: 128; h: 128), // CYBER
83 (w: 64; h: 64), // CGUN
84 (w: 128; h: 128), // BARON
85 (w: 128; h: 128), // KNIGHT
86 (w: 128; h: 128), // CACO
87 (w: 64; h: 64), // SOUL (DIE is 128x128, see load code)
88 (w: 128; h: 128), // PAIN
89 (w: 256; h: 128), // SPIDER
90 (w: 128; h: 64), // BSP
91 (w: 128; h: 128), // MANCUB
92 (w: 128; h: 128), // SKEL
93 (w: 128; h: 128), // VILE
94 (w: 32; h: 32), // FISH
95 (w: 64; h: 64), // BARREL
96 (w: 128; h: 128), // ROBO
97 (w: 64; h: 64) // MAN
98 );
99 VILEFIRE_DX = 32;
100 VILEFIRE_DY = 128;
101
102 ItemAnim: array [0..ITEM_LAST] of record
103 name: AnsiString;
104 w, h: Integer;
105 anim: TAnimInfo;
106 end = (
107 (name: 'NOTEXTURE'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
108 (name: 'MED1'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
109 (name: 'MED2'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
110 (name: 'BMED'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
111 (name: 'ARMORGREEN'; w: 32; h: 16; anim: (loop: true; delay: 20; frames: 3; back: true)),
112 (name: 'ARMORBLUE'; w: 32; h: 16; anim: (loop: true; delay: 20; frames: 3; back: true)),
113 (name: 'SBLUE'; w: 32; h: 32; anim: (loop: true; delay: 15; frames: 4; back: true)),
114 (name: 'SWHITE'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
115 (name: 'SUIT'; w: 32; h: 64; anim: (loop: true; delay: 1; frames: 1; back: false)),
116 (name: 'OXYGEN'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
117 (name: 'INVUL'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
118 (name: 'SAW'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
119 (name: 'SHOTGUN1'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
120 (name: 'SHOTGUN2'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
121 (name: 'MGUN'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
122 (name: 'RLAUNCHER'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
123 (name: 'PGUN'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
124 (name: 'BFG'; w: 64; h: 64; anim: (loop: true; delay: 1; frames: 1; back: false)),
125 (name: 'SPULEMET'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
126 (name: 'CLIP'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
127 (name: 'AMMO'; w: 32; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
128 (name: 'SHELL1'; w: 16; h: 8; anim: (loop: true; delay: 1; frames: 1; back: false)),
129 (name: 'SHELL2'; w: 32; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
130 (name: 'ROCKET'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
131 (name: 'ROCKETS'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
132 (name: 'CELL'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
133 (name: 'CELL2'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
134 (name: 'BPACK'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
135 (name: 'KEYR'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
136 (name: 'KEYG'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
137 (name: 'KEYB'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
138 (name: 'KASTET'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
139 (name: 'PISTOL'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
140 (name: 'BOTTLE'; w: 16; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
141 (name: 'HELMET'; w: 16; h: 16; anim: (loop: true; delay: 20; frames: 4; back: true)),
142 (name: 'JETPACK'; w: 32; h: 32; anim: (loop: true; delay: 15; frames: 3; back: true)),
143 (name: 'INVIS'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
144 (name: 'FLAMETHROWER'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
145 (name: 'FUELCAN'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false))
146 );
147
148 {$IFDEF ENABLE_GFX}
149 GFXAnim: array [0..R_GFX_LAST] of record
150 name: AnsiString;
151 w, h: Integer;
152 anim: TAnimInfo;
153 rdelay: Integer;
154 alpha: Integer;
155 end = (
156 (name: ''; w: 0; h: 0; anim: (loop: false; delay: 0; frames: 0; back: false); rdelay: 0; alpha: 0),
157 (name: 'TELEPORT'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 10; back: false); rdelay: 0; alpha: 0),
158 (name: 'FLAME'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 11; back: false); rdelay: 0; alpha: 0),
159 (name: 'EROCKET'; w: 128; h: 128; anim: (loop: false; delay: 6; frames: 6; back: false); rdelay: 0; alpha: 0),
160 (name: 'EBFG'; w: 128; h: 128; anim: (loop: false; delay: 6; frames: 6; back: false); rdelay: 0; alpha: 0),
161 (name: 'BFGHIT'; w: 64; h: 64; anim: (loop: false; delay: 4; frames: 4; back: false); rdelay: 0; alpha: 0),
162 (name: 'FIRE'; w: 64; h: 128; anim: (loop: false; delay: 4; frames: 8; back: false); rdelay: 2; alpha: 0),
163 (name: 'ITEMRESPAWN'; w: 32; h: 32; anim: (loop: false; delay: 4; frames: 5; back: true); rdelay: 0; alpha: 0),
164 (name: 'SMOKE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 0),
165 (name: 'ESKELFIRE'; w: 64; h: 64; anim: (loop: false; delay: 8; frames: 3; back: false); rdelay: 0; alpha: 0),
166 (name: 'EPLASMA'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 4; back: true); rdelay: 0; alpha: 0),
167 (name: 'EBSPFIRE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 5; back: false); rdelay: 0; alpha: 0),
168 (name: 'EIMPFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
169 (name: 'ECACOFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
170 (name: 'EBARONFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
171 (name: 'TELEPORT'; w: 64; h: 64; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 0), // fast
172 (name: 'SMOKE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 150), // transparent
173 (name: 'FLAME'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 11; back: false); rdelay: 2; alpha: 0) // random
174 );
175 {$ENDIF}
176
177 ShotAnim: array [0..WEAPON_LAST] of record
178 name: AnsiString;
179 w, h: Integer;
180 anim: TAnimInfo;
181 end = (
182 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 0 KASTET
183 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 1 SAW
184 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 2 PISTOL
185 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 3 SHOTGUN1
186 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 4 SHOTGUN2
187 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 5 CHAINGUN
188 (name: 'BROCKET'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)), // 6 ROCKETLAUNCHER
189 (name: 'BPLASMA'; w: 16; h: 16; anim: (loop: true; delay: 5; frames: 2; back: false)), // 7 PLASMA
190 (name: 'BBFG'; w: 64; h: 64; anim: (loop: true; delay: 6; frames: 2; back: false)), // 8 BFG
191 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 9 SUPERPULEMET
192 (name: 'FLAME'; w: 32; h: 32; anim: (loop: true; delay: 6; frames: 0{11}; back: false)), // 10 FLAMETHROWER
193 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 11
194 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 12
195 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 13
196 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 14
197 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 15
198 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 16
199 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 17
200 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 18
201 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 19
202 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 20 ZOMPY_PISTOL
203 (name: 'BIMPFIRE'; w: 16; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 21 IMP_FIRE
204 (name: 'BBSPFIRE'; w: 16; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 22 BSP_FIRE
205 (name: 'BCACOFIRE'; w: 16; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 23 CACO_FIRE
206 (name: 'BBARONFIRE'; w: 64; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 24 BARON_FIRE
207 (name: 'BMANCUBFIRE'; w: 64; h: 32; anim: (loop: true; delay: 4; frames: 2; back: false)), // 25 MANCUB_FIRE
208 (name: 'BSKELFIRE'; w: 64; h: 64; anim: (loop: true; delay: 5; frames: 2; back: false)) // 26 SKEL_FIRE
209 );
210
211 {$IFDEF ENABLE_SHELLS}
212 ShellAnim: array [0..SHELL_LAST] of record
213 name: AnsiString;
214 dx, dy: Integer;
215 end = (
216 (name: 'EBULLET'; dx: 2; dy: 1), // 0 SHELL_BULLET
217 (name: 'ESHELL'; dx: 4; dy: 2), // 1 SHELL_SHELL
218 (name: 'ESHELL'; dx: 4; dy: 2) // 2 SHELL_DBLSHELL
219 );
220 {$ENDIF}
221
222 PunchAnim: TAnimInfo = (loop: false; delay: 1; frames: 4; back: false);
223 FlagAnim: TAnimInfo = (loop: true; delay: 8; frames: 5; back: false);
224
225 type
226 TBinHeapPanelDrawCmp = class
227 public
228 class function less (const a, b: TPanel): Boolean; inline;
229 end;
230
231 TBinHeapPanelDraw = specialize TBinaryHeapBase<TPanel, TBinHeapPanelDrawCmp>;
232
233 TMonsterAnims = array [0..ANIM_LAST, TDirection] of TGLMultiTexture;
234
235 var
236 SkyTexture: TGLTexture;
237 RenTextures: array of record
238 spec: LongInt;
239 tex: TGLMultiTexture;
240 end;
241 Items: array [0..ITEM_LAST] of record
242 tex: TGLMultiTexture;
243 frame: Integer;
244 end;
245 MonTextures: array [0..MONSTER_MAN] of TMonsterAnims;
246 WeapTextures: array [0..WP_LAST, 0..W_POS_LAST, 0..W_ACT_LAST] of TGLTexture;
247 ShotTextures: array [0..WEAPON_LAST] of TGLMultiTexture;
248 FlagTextures: array [0..FLAG_LAST] of TGLMultiTexture;
249 PunchTextures: array [Boolean, 0..2] of TGLMultiTexture; // [berserk, center/up/down]
250 VileFire: TGLMultiTexture;
251 InvulPenta: TGLTexture;
252 Models: array of record
253 anim: array [TDirection, 0..A_LAST] of record
254 base, mask: TGLMultiTexture;
255 end;
256 {$IFDEF ENABLE_GIBS}
257 gibs: record
258 base, mask: TGLTextureArray;
259 rect: TRectArray;
260 end;
261 {$ENDIF}
262 end;
263
264 {$IFDEF ENABLE_SHELLS}
265 ShellTextures: array [0..SHELL_LAST] of TGLTexture;
266 {$ENDIF}
267 {$IFDEF ENABLE_GFX}
268 GFXTextures: array [0..R_GFX_LAST] of TGLMultiTexture;
269 gfxlist: array of record
270 typ: Byte;
271 x, y: Integer;
272 oldX, oldY: Integer;
273 anim: TAnimInfo;
274 time: LongWord;
275 frame: LongInt;
276 end = nil;
277 {$ENDIF}
278
279 FlagFrame: LongInt;
280 plist: TBinHeapPanelDraw = nil;
281
282 class function TBinHeapPanelDrawCmp.less (const a, b: TPanel): Boolean; inline;
283 begin
284 if a.tag < b.tag then begin result := true; exit; end;
285 if a.tag > b.tag then begin result := false; exit; end;
286 result := a.arrIdx < b.arrIdx;
287 end;
288
289 procedure r_Map_Initialize;
290 begin
291 FlagFrame := 0;
292 plist := TBinHeapPanelDraw.Create();
293 end;
294
295 procedure r_Map_Finalize;
296 begin
297 plist.Free;
298 FlagFrame := 0;
299 end;
300
301 procedure r_Map_FreeModel (i: Integer);
302 var a: Integer; d: TDirection;
303 begin
304 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
305 begin
306 for a := A_STAND to A_LAST do
307 begin
308 if Models[i].anim[d, a].base <> nil then
309 Models[i].anim[d, a].base.Free;
310 if Models[i].anim[d, a].mask <> nil then
311 Models[i].anim[d, a].mask.Free;
312 Models[i].anim[d, a].base := nil;
313 Models[i].anim[d, a].mask := nil;
314 end;
315 end;
316 {$IFDEF ENABLE_GIBS}
317 if Models[i].gibs.base <> nil then
318 for a := 0 to High(Models[i].gibs.base) do
319 Models[i].gibs.base[a].Free;
320 if Models[i].gibs.mask <> nil then
321 for a := 0 to High(Models[i].gibs.mask) do
322 Models[i].gibs.mask[a].Free;
323 Models[i].gibs.base := nil;
324 Models[i].gibs.mask := nil;
325 Models[i].gibs.rect := nil;
326 {$ENDIF}
327 end;
328
329 procedure r_Map_LoadModel (i: Integer);
330 var prefix: AnsiString; a: Integer; d: TDirection; m: ^TPlayerModelInfo;
331 begin
332 ASSERT(i < Length(Models));
333 ASSERT(i < Length(PlayerModelsArray));
334 r_Map_FreeModel(i);
335 m := @PlayerModelsArray[i];
336 prefix := m.FileName + ':TEXTURES/';
337 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
338 begin
339 for a := A_STAND to A_LAST do
340 begin
341 Models[i].anim[d, a].base := nil;
342 Models[i].anim[d, a].mask := nil;
343 if m.anim[d, a].resource <> '' then
344 Models[i].anim[d, a].base := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].resource, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
345 if m.anim[d, a].mask <> '' then
346 Models[i].anim[d, a].mask := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].mask, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
347 end
348 end;
349 {$IFDEF ENABLE_GIBS}
350 Models[i].gibs.base := nil;
351 Models[i].gibs.mask := nil;
352 Models[i].gibs.rect := nil;
353 if m.GibsCount > 0 then
354 begin
355 SetLength(Models[i].gibs.base, m.GibsCount);
356 SetLength(Models[i].gibs.mask, m.GibsCount);
357 SetLength(Models[i].gibs.rect, m.GibsCount);
358 for a := 0 to m.GibsCount - 1 do
359 Models[i].gibs.rect[a] := DefaultGibSize;
360 if r_Textures_LoadStreamFromFile(prefix + m.GibsResource, 32, 32, m.GibsCount, m.GibsCount, Models[i].gibs.base, Models[i].gibs.rect) then
361 begin
362 if r_Textures_LoadStreamFromFile(prefix + m.GibsMask, 32, 32, m.GibsCount, m.GibsCount, Models[i].gibs.mask, nil) then
363 begin
364 // ok
365 end;
366 end;
367 end;
368 {$ENDIF}
369 end;
370
371 procedure r_Map_LoadMonsterAnim (m, a: Integer; d: TDirection);
372 const dir: array [TDirection] of AnsiString = ('_L', '');
373 var w, h, count: Integer;
374 begin
375 count := MONSTER_ANIMTABLE[m].AnimCount[a];
376 if count > 0 then
377 begin
378 w := MTABLE[m].w;
379 h := MTABLE[m].h;
380 if (m = MONSTER_SOUL) and (a = ANIM_DIE) then
381 begin
382 // special case
383 w := 128;
384 h := 128;
385 end;
386 MonTextures[m, a, d] := r_Textures_LoadMultiFromFileAndInfo(
387 GameWAD + ':MTEXTURES/' + MONSTERTABLE[m].name + '_' + ANIMTABLE[a].name + dir[d],
388 w,
389 h,
390 count,
391 False,
392 False
393 );
394 end
395 else
396 MonTextures[m, a, d] := nil;
397 end;
398
399 procedure r_Map_Load;
400 const
401 WeapName: array [0..WP_LAST] of AnsiString = ('', 'CSAW', 'HGUN', 'SG', 'SSG', 'MGUN', 'RKT', 'PLZ', 'BFG', 'SPL', 'FLM');
402 WeapPos: array [0..W_POS_LAST] of AnsiString = ('', '_UP', '_DN');
403 WeapAct: array [0..W_ACT_LAST] of AnsiString = ('', '_FIRE');
404 PunchName: array [Boolean] of AnsiString = ('PUNCH', 'PUNCHB');
405 var
406 i, j, k: Integer; d: TDirection; b: Boolean;
407 begin
408 // --------- items --------- //
409 for i := 0 to ITEM_LAST do
410 begin
411 Items[i].tex := r_Textures_LoadMultiFromFileAndInfo(
412 GameWAD + ':TEXTURES/' + ItemAnim[i].name,
413 ItemAnim[i].w,
414 ItemAnim[i].h,
415 ItemAnim[i].anim.frames,
416 ItemAnim[i].anim.back,
417 false
418 );
419 Items[i].frame := 0;
420 end;
421 // --------- monsters --------- //
422 for i := MONSTER_DEMON to MONSTER_MAN do
423 for j := 0 to ANIM_LAST do
424 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
425 r_Map_LoadMonsterAnim(i, j, d);
426 VileFire := r_Textures_LoadMultiFromFileAndInfo(GameWAD + ':TEXTURES/FIRE', 64, 128, 8, False, False);
427 // --------- player models --------- //
428 if PlayerModelsArray <> nil then
429 begin
430 SetLength(Models, Length(PlayerModelsArray));
431 for i := 0 to High(PlayerModelsArray) do
432 r_Map_LoadModel(i);
433 end;
434 // --------- player weapons --------- //
435 for i := 1 to WP_LAST do
436 for j := 0 to W_POS_LAST do
437 for k := 0 to W_ACT_LAST do
438 WeapTextures[i, j, k] := r_Textures_LoadFromFile(GameWAD + ':WEAPONS\' + WeapName[i] + WeapPos[j] + WeapAct[k]);
439 // --------- gfx animations --------- //
440 {$IFDEF ENABLE_GFX}
441 for i := 1 to R_GFX_LAST do
442 if GFXAnim[i].anim.frames > 0 then
443 GFXTextures[i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/' + GFXAnim[i].name, GFXAnim[i].w, GFXAnim[i].h, GFXAnim[i].anim.frames, GFXAnim[i].anim.back);
444 {$ENDIF}
445 // --------- shots --------- //
446 for i := 0 to WEAPON_LAST do
447 if ShotAnim[i].anim.frames > 0 then
448 ShotTextures[i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/' + ShotAnim[i].name, ShotAnim[i].w, ShotAnim[i].h, ShotAnim[i].anim.frames, ShotAnim[i].anim.back);
449 // --------- flags --------- //
450 FlagTextures[FLAG_NONE] := nil;
451 FlagTextures[FLAG_RED] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGRED', 64, 64, 5, false);
452 FlagTextures[FLAG_BLUE] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGBLUE', 64, 64, 5, false);
453 // FlagTextures[FLAG_DOM] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGDOM', 64, 64, 8, false);
454 // --------- shells --------- //
455 {$IFDEF ENABLE_SHELLS}
456 for i := 0 to SHELL_LAST do
457 ShellTextures[i] := r_Textures_LoadFromFile(GameWad + ':TEXTURES/' + ShellAnim[i].name);
458 {$ENDIF}
459 // --------- punch --------- //
460 for b := false to true do
461 begin
462 for i := 0 to 2 do
463 PunchTextures[b, i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':WEAPONS/' + PunchName[b] + WeapPos[i], 64, 64, PunchAnim.frames, PunchAnim.back);
464 end;
465 // --------- other --------- //
466 InvulPenta := r_Textures_LoadFromFile(GameWad + ':TEXTURES/PENTA');
467 end;
468
469 procedure r_Map_Free;
470 var i, j, k: Integer; d: TDirection; b: Boolean;
471 begin
472 if InvulPenta <> nil then
473 InvulPenta.Free;
474 InvulPenta := nil;
475 for b := false to true do
476 begin
477 for i := 0 to 2 do
478 begin
479 if PunchTextures[b, i] <> nil then
480 PunchTextures[b, i].Free;
481 PunchTextures[b, i] := nil;
482 end;
483 end;
484 {$IFDEF ENABLE_SHELLS}
485 for i := 0 to SHELL_LAST do
486 begin
487 if ShellTextures[i] <> nil then
488 ShellTextures[i].Free;
489 ShellTextures[i] := nil;
490 end;
491 {$ENDIF}
492 for i := 0 to FLAG_LAST do
493 begin
494 if FlagTextures[i] <> nil then
495 FlagTextures[i].Free;
496 FlagTextures[i] := nil;
497 end;
498 for i := 0 to WEAPON_LAST do
499 begin
500 if ShotTextures[i] <> nil then
501 ShotTextures[i].Free;
502 ShotTextures[i] := nil;
503 end;
504 {$IFDEF ENABLE_GFX}
505 gfxlist := nil;
506 for i := 0 to R_GFX_LAST do
507 begin
508 if GFXTextures[i] <> nil then
509 GFXTextures[i].Free;
510 GFXTextures[i] := nil;
511 end;
512 {$ENDIF}
513 for i := 1 to WP_LAST do
514 begin
515 for j := 0 to W_POS_LAST do
516 begin
517 for k := 0 to W_ACT_LAST do
518 begin
519 if WeapTextures[i, j, k] <> nil then
520 WeapTextures[i, j, k].Free;
521 WeapTextures[i, j, k] := nil;
522 end;
523 end;
524 end;
525 if Models <> nil then
526 for i := 0 to High(Models) do
527 r_Map_FreeModel(i);
528 for i := MONSTER_DEMON to MONSTER_MAN do
529 begin
530 for j := 0 to ANIM_LAST do
531 begin
532 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
533 begin
534 if MonTextures[i, j, d] <> nil then
535 MonTextures[i, j, d].Free;
536 MonTextures[i, j, d] := nil;
537 end;
538 end;
539 end;
540 for i := 0 to ITEM_LAST do
541 begin
542 if Items[i].tex <> nil then
543 Items[i].tex.Free;
544 Items[i].tex := nil;
545 end;
546 end;
547
548 procedure r_Map_LoadTextures;
549 var i, n: Integer;
550 begin
551 if Textures <> nil then
552 begin
553 n := Length(Textures);
554 SetLength(RenTextures, n);
555 for i := 0 to n - 1 do
556 begin
557 RenTextures[i].tex := nil;
558 case Textures[i].TextureName of
559 TEXTURE_NAME_WATER: RenTextures[i].spec := TEXTURE_SPECIAL_WATER;
560 TEXTURE_NAME_ACID1: RenTextures[i].spec := TEXTURE_SPECIAL_ACID1;
561 TEXTURE_NAME_ACID2: RenTextures[i].spec := TEXTURE_SPECIAL_ACID2;
562 else
563 RenTextures[i].spec := 0;
564 RenTextures[i].tex := r_Textures_LoadMultiFromFile(Textures[i].FullName);
565 if RenTextures[i].tex = nil then
566 e_LogWritefln('r_Map_LoadTextures: failed to load texture: %s', [Textures[i].FullName]);
567 end;
568 end;
569 end;
570 if gMapInfo.SkyFullName <> '' then
571 SkyTexture := r_Textures_LoadFromFile(gMapInfo.SkyFullName);
572 plist.Clear;
573 end;
574
575 procedure r_Map_FreeTextures;
576 var i: Integer;
577 begin
578 plist.Clear;
579 if SkyTexture <> nil then
580 SkyTexture.Free;
581 SkyTexture := nil;
582 if RenTextures <> nil then
583 for i := 0 to High(RenTextures) do
584 if RenTextures[i].tex <> nil then
585 RenTextures[i].tex.Free;
586 RenTextures := nil;
587 end;
588
589 procedure r_Map_DrawPanel (p: TPanel);
590 var Texture: Integer; t: TGLMultiTexture;
591 begin
592 ASSERT(p <> nil);
593 if p.FCurTexture >= 0 then
594 begin
595 Texture := p.TextureIDs[p.FCurTexture].Texture;
596 t := RenTextures[Texture].tex;
597
598 if (RenTextures[Texture].spec = 0) or (t <> nil) then
599 begin
600 if t = nil then
601 r_Draw_TextureRepeat(nil, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
602 else if p.TextureIDs[p.FCurTexture].AnTex.IsValid() then
603 r_Draw_MultiTextureRepeat(t, p.TextureIDs[p.FCurTexture].AnTex, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
604 else
605 r_Draw_TextureRepeat(t.GetTexture(0), p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
606 end;
607
608 if t = nil then
609 begin
610 case RenTextures[Texture].spec of
611 TEXTURE_SPECIAL_WATER: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 0, 255, 255);
612 TEXTURE_SPECIAL_ACID1: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 230, 0, 255);
613 TEXTURE_SPECIAL_ACID2: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 230, 0, 0, 255);
614 end
615 end
616 end
617 end;
618
619 procedure r_Map_DrawPanelType (panelTyp: DWORD);
620 var tagMask, i: Integer; p: TPanel;
621 begin
622 i := 0;
623 tagMask := PanelTypeToTag(panelTyp);
624 while plist.count > 0 do
625 begin
626 p := TPanel(plist.Front());
627 if (p.tag and tagMask) = 0 then
628 break;
629 r_Map_DrawPanel(p);
630 Inc(i);
631 plist.PopFront
632 end;
633 end;
634
635 procedure r_Map_DrawItems (x, y, w, h: Integer; drop: Boolean);
636 var i, fX, fY: Integer; it: PItem; t: TGLMultiTexture; tex: TGLTexture;
637 begin
638 if ggItems <> nil then
639 begin
640 for i := 0 to High(ggItems) do
641 begin
642 it := @ggItems[i];
643 if it.used and it.alive and (it.dropped = drop) and (it.ItemType > ITEM_NONE) and (it.ItemType <= ITEM_LAST) then
644 begin
645 t := Items[it.ItemType].tex;
646 if g_Collide(it.obj.x, it.obj.y, t.width, t.height, x, y, w, h) then
647 begin
648 it.obj.Lerp(gLerpFactor, fX, fY);
649 tex := t.GetTexture(Items[it.ItemType].frame);
650 r_Draw_TextureRepeat(tex, fX, fY, tex.width, tex.height, false, 255, 255, 255, 255, false);
651 end;
652 end;
653 end;
654 end;
655 // TODO draw g_debug_frames
656 end;
657
658 function r_Map_GetMonsterTexture (m, a: Integer; d: TDirection; out t: TGLMultiTexture; out dx, dy: Integer; out flip: Boolean): Boolean;
659 // var c: Integer;
660 begin
661 t := nil; dx := 0; dy := 0; flip := false;
662 result := MonTextures[m, a, d] <> nil;
663 if result = false then
664 begin
665 flip := true;
666 if d = TDirection.D_RIGHT then d := TDirection.D_LEFT else d := TDirection.D_RIGHT;
667 result := MonTextures[m, a, d] <> nil;
668 end;
669 if result = true then
670 begin
671 t := MonTextures[m, a, d];
672 if d = TDirection.D_LEFT then
673 begin
674 dx := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].X;
675 dy := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].Y;
676 end
677 else
678 begin
679 dx := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].X;
680 dy := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].Y;
681 end;
682 if flip then
683 begin
684 // c := (MONSTERTABLE[MonsterType].Rect.X - dx) + MONSTERTABLE[MonsterType].Rect.Width;
685 // dx := MTABLE[m].width - c - MONSTERTABLE[MonsterType].Rect.X;
686 dx := -dx;
687 end;
688 end;
689 end;
690
691 procedure r_Map_DrawMonsterAttack (constref mon: TMonster);
692 var o: TObj;
693 begin
694 if VileFire <> nil then
695 if (mon.MonsterType = MONSTER_VILE) and (mon.MonsterState = MONSTATE_SHOOT) then
696 if mon.VileFireAnim.IsValid() and GetPos(mon.MonsterTargetUID, @o) then
697 r_Draw_MultiTextureRepeat(VileFire, mon.VileFireAnim, o.x + o.rect.x + (o.rect.width div 2) - VILEFIRE_DX, o.y + o.rect.y + o.rect.height - VILEFIRE_DY, VileFire.width, VileFire.height, False, 255, 255, 255, 255, false);
698 end;
699
700 procedure r_Map_DrawMonster (constref mon: TMonster);
701 var m, a, fX, fY, dx, dy: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture;
702 begin
703 m := mon.MonsterType;
704 a := mon.MonsterAnim;
705 d := mon.GameDirection;
706
707 mon.obj.Lerp(gLerpFactor, fX, fY);
708
709 if r_Map_GetMonsterTexture(m, a, d, t, dx, dy, flip) then
710 r_Draw_MultiTextureRepeat(t, mon.DirAnim[a, d], fX + dx, fY + dy, t.width, t.height, flip, 255, 255, 255, 255, false);
711
712 // TODO draw g_debug_frames
713 end;
714
715 procedure r_Map_DrawMonsters (x, y, w, h: Integer);
716 var i: Integer; m: TMonster;
717 begin
718 if gMonsters <> nil then
719 begin
720 for i := 0 to High(gMonsters) do
721 begin
722 m := gMonsters[i];
723 if m <> nil then
724 begin
725 r_Map_DrawMonsterAttack(m);
726 // TODO select from grid
727 if g_Collide(m.obj.x + m.obj.rect.x, m.obj.y + m.obj.rect.y, m.obj.rect.width, m.obj.rect.height, x, y, w, h) then
728 r_Map_DrawMonster(m);
729 end;
730 end;
731 end;
732 end;
733
734 function r_Map_GetPlayerModelTex (i: Integer; var a: Integer; var d: TDirection; out flip: Boolean): Boolean;
735 begin
736 flip := false;
737 result := Models[i].anim[d, a].base <> nil;
738 if result = false then
739 begin
740 flip := true;
741 if d = TDirection.D_LEFT then d := TDirection.D_RIGHT else d := TDirection.D_LEFT;
742 result := Models[i].anim[d, a].base <> nil;
743 end;
744 end;
745
746 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer; alpha: Byte);
747 var a, pos, act, xx, yy, angle: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture; tex: TGLTexture; c: TRGB;
748 begin
749 a := pm.CurrentAnimation;
750 d := pm.Direction;
751
752 (* draw flag*)
753 t := FlagTextures[pm.Flag];
754 if (t <> nil) and not (a in [A_DIE1, A_DIE2]) then
755 begin
756 flip := d = TDirection.D_RIGHT;
757 angle := PlayerModelsArray[pm.id].FlagAngle;
758 xx := PlayerModelsArray[pm.id].FlagPoint.X;
759 yy := PlayerModelsArray[pm.id].FlagPoint.Y;
760 tex := t.GetTexture(FlagFrame);
761 r_Draw_TextureRepeatRotate(
762 tex,
763 x + IfThen(flip, 2 * FLAG_BASEPOINT.X - xx + 1, xx - 1) - FLAG_BASEPOINT.X,
764 y + yy - FLAG_BASEPOINT.Y + 1,
765 tex.width,
766 tex.height,
767 flip,
768 255, 255, 255, 255, false,
769 IfThen(flip, 64 - FLAG_BASEPOINT.X, FLAG_BASEPOINT.X),
770 FLAG_BASEPOINT.Y,
771 IfThen(flip, angle, -angle)
772 );
773 end;
774
775 (* draw weapon *)
776 if PlayerModelsArray[pm.id].HaveWeapon and not (a in [A_DIE1, A_DIE2, A_PAIN]) then
777 begin
778 case a of
779 A_SEEUP, A_ATTACKUP: pos := W_POS_UP;
780 A_SEEDOWN, A_ATTACKDOWN: pos := W_POS_DOWN;
781 else pos := W_POS_NORMAL;
782 end;
783 if (a in [A_ATTACK, A_ATTACKUP, A_ATTACKDOWN]) or pm.GetFire() then
784 act := W_ACT_FIRE
785 else
786 act := W_ACT_NORMAL;
787 tex := WeapTextures[pm.CurrentWeapon, pos, act];
788 if tex <> nil then
789 begin
790 xx := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].X;
791 yy := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].Y;
792 r_Draw_Texture(
793 tex,
794 x + xx,
795 y + yy,
796 tex.width,
797 tex.height,
798 d = TDirection.D_LEFT,
799 255, 255, 255, alpha, false
800 );
801 end;
802 end;
803
804 (* draw body *)
805 if r_Map_GetPlayerModelTex(pm.id, a, d, flip) then
806 begin
807 t := Models[pm.id].anim[d, a].base;
808 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip, 255, 255, 255, alpha, false);
809 t := Models[pm.id].anim[d, a].mask;
810 if t <> nil then
811 begin
812 c := pm.Color;
813 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip, c.r, c.g, c.b, alpha, false);
814 end;
815 end;
816 end;
817
818 procedure r_Map_DrawPlayer (p, drawed: TPlayer);
819 var fX, fY, fSlope, ax, ay, w, h: Integer; b, flip: Boolean; t: TGLMultiTexture; tex: TGLTexture; alpha: Byte; count, frame: LongInt;
820 begin
821 if p.alive then
822 begin
823 fX := p.obj.x; fY := p.obj.y;
824 // TODO fix lerp
825 //p.obj.Lerp(gLerpFactor, fX, fY);
826 fSlope := nlerp(p.SlopeOld, p.obj.slopeUpLeft, gLerpFactor);
827
828 (* punch effect *)
829 if p.PunchTime <= gTime then
830 begin
831 g_Anim_GetFrameByTime(PunchAnim, (gTime - p.PunchTime) DIV GAME_TICK, count, frame);
832 if count < 1 then
833 begin
834 b := R_BERSERK in p.FRulez;
835 if p.FKeys[KEY_DOWN].pressed then
836 t := PunchTextures[b, 2]
837 else if p.FKeys[KEY_UP].pressed then
838 t := PunchTextures[b, 1]
839 else
840 t := PunchTextures[b, 0];
841 if t <> nil then
842 begin
843 flip := p.Direction = TDirection.D_LEFT;
844 ax := IfThen(flip, 15 - p.Obj.Rect.X, p.Obj.Rect.X - 15); // ???
845 ay := p.Obj.Rect.Y - 11;
846 tex := t.GetTexture(frame);
847 r_Draw_TextureRepeat(tex, fx + ax, fy + fSlope + ay, tex.width, tex.height, flip, 255, 255, 255, 255, false)
848 end;
849 end;
850 end;
851
852 (* invulnerability effect *)
853 if (InvulPenta <> nil) and (p.FMegaRulez[MR_INVUL] > gTime) and ((p <> drawed) or (p.SpawnInvul >= gTime)) then
854 begin
855 w := InvulPenta.width;
856 h := InvulPenta.height;
857 ax := p.Obj.Rect.X + (p.Obj.Rect.Width div 2) - (w div 2); // + IfThen(flip, +4, -2) // ???
858 ay := p.Obj.Rect.Y + (p.Obj.Rect.Height div 2) - (h div 2) - 7; // ???
859 r_Draw_Texture(InvulPenta, fx + ax, fy + ay + fSlope, w, h, false, 255, 255, 255, 255, false);
860 end;
861
862 (* invisibility effect *)
863 alpha := 255;
864 if p.FMegaRulez[MR_INVIS] > gTime then
865 begin
866 if (drawed <> nil) and ((p = drawed) or ((p.Team = drawed.Team) and (gGameSettings.GameMode <> GM_DM))) then
867 begin
868 if (p.FMegaRulez[MR_INVIS] - gTime > 2100) or not ODD((p.FMegaRulez[MR_INVIS] - gTime) div 300) then
869 alpha := 55;
870 end
871 else
872 alpha := 1; // ???
873 end;
874
875 r_Map_DrawPlayerModel(p.Model, fX, fY + fSlope, alpha);
876 end;
877 // TODO draw g_debug_frames
878 // TODO draw chat bubble
879 // TODO draw aim
880 end;
881
882 procedure r_Map_DrawPlayers (x, y, w, h: Integer; player: TPlayer);
883 var i: Integer;
884 begin
885 if gPlayers <> nil then
886 for i := 0 to High(gPlayers) do
887 if gPlayers[i] <> nil then
888 r_Map_DrawPlayer(gPlayers[i], player);
889 end;
890
891 {$IFDEF ENABLE_GIBS}
892 function r_Map_GetGibSize (m, i: Integer): TRectWH;
893 begin
894 result := Models[m].gibs.rect[i];
895 end;
896
897 procedure r_Map_DrawGibs (x, y, w, h: Integer);
898 var i, fx, fy, m, id, rx, ry, ra: Integer; p: PObj; t: TGLTexture;
899 begin
900 if gGibs <> nil then
901 begin
902 for i := 0 to High(gGibs) do
903 begin
904 if gGibs[i].alive then
905 begin
906 p := @gGibs[i].Obj;
907 if g_Obj_Collide(x, y, w, h, p) then
908 begin
909 p.Lerp(gLerpFactor, fx, fy);
910 id := gGibs[i].GibID;
911 m := gGibs[i].ModelID;
912 t := Models[m].gibs.base[id];
913 if t <> nil then
914 begin
915 rx := p.Rect.X + p.Rect.Width div 2;
916 ry := p.Rect.Y + p.Rect.Height div 2;
917 ra := gGibs[i].RAngle;
918 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, 255, 255, 255, 255, false, rx, ry, ra);
919 t := Models[m].gibs.mask[id];
920 if t <> nil then
921 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, gGibs[i].Color.R, gGibs[i].Color.G, gGibs[i].Color.B, 255, false, rx, ry, ra);
922 // r_Draw_TextureRepeatRotate(nil, fx + p.Rect.X, fy + p.Rect.Y, p.Rect.Width, p.Rect.Height, false, 255, 255, 255, 255, false, p.Rect.Width div 2, p.Rect.Height div 2, ra);
923 end;
924 end;
925 end;
926 end;
927 end;
928 // TODO draw g_debug_frames
929 end;
930 {$ENDIF}
931
932 {$IFDEF ENABLE_CORPSES}
933 procedure r_Map_DrawCorpses (x, y, w, h: Integer);
934 var i, fX, fY: Integer; p: TCorpse;
935 begin
936 if gCorpses <> nil then
937 begin
938 for i := 0 to High(gCorpses) do
939 begin
940 p := gCorpses[i];
941 if (p <> nil) and (p.state <> CORPSE_STATE_REMOVEME) and (p.model <> nil) then
942 begin
943 p.obj.Lerp(gLerpFactor, fX, fY);
944 r_Map_DrawPlayerModel(p.model, fX, fY, 255);
945 end;
946 end;
947 end;
948 // TODO draw g_debug_frames
949 end;
950 {$ENDIF}
951
952 {$IFDEF ENABLE_GFX}
953 function r_Map_GetGFXID (): Integer;
954 var i: Integer;
955 begin
956 i := 0;
957 if gfxlist <> nil then
958 begin
959 while (i < Length(gfxlist)) and (gfxlist[i].typ > 0) do
960 Inc(i);
961 if i >= Length(gfxlist) then
962 SetLength(gfxlist, Length(gfxlist) + 1)
963 end
964 else
965 SetLength(gfxlist, 1);
966 gfxlist[i].typ := R_GFX_NONE;
967 result := i
968 end;
969
970 procedure r_Map_NewGFX (typ, x, y: Integer);
971 var i: Integer;
972 begin
973 if gpart_dbg_enabled and (typ > 0) and (typ <= R_GFX_LAST) then
974 begin
975 i := r_Map_GetGFXID();
976 if i >= 0 then
977 begin
978 gfxlist[i].typ := typ;
979 gfxlist[i].x := x;
980 gfxlist[i].y := y;
981 gfxlist[i].oldX := x;
982 gfxlist[i].oldY := y;
983 gfxlist[i].anim := GFXAnim[typ].anim;
984 gfxlist[i].time := gTime DIV GAME_TICK;
985 gfxlist[i].frame := 0;
986 INC(gfxlist[i].anim.delay, Random(GFXAnim[typ].rdelay));
987 end;
988 end;
989 end;
990
991 procedure r_Map_UpdateGFX (tick: LongWord);
992 var i: Integer; count: LongInt;
993 begin
994 if gfxlist <> nil then
995 begin
996 for i := 0 to High(gfxlist) do
997 begin
998 if (gfxlist[i].typ > 0) and (tick >= gfxlist[i].time) then
999 begin
1000 g_Anim_GetFrameByTime(gfxlist[i].anim, tick - gfxlist[i].time, count, gfxlist[i].frame);
1001 if count < 1 then
1002 begin
1003 gfxlist[i].oldX := gfxlist[i].x;
1004 gfxlist[i].oldY := gfxlist[i].y;
1005 case gfxlist[i].typ of
1006 R_GFX_FLAME, R_GFX_SMOKE:
1007 begin
1008 if Random(3) = 0 then
1009 gfxlist[i].x := gfxlist[i].x - 1 + Random(3);
1010 if Random(2) = 0 then
1011 gfxlist[i].y := gfxlist[i].y - Random(2);
1012 end;
1013 end;
1014 end
1015 else
1016 gfxlist[i].typ := R_GFX_NONE;
1017 end;
1018 end;
1019 end;
1020 end;
1021
1022 procedure r_Map_DrawGFX (x, y, w, h: Integer);
1023 var i, fx, fy, typ: Integer; t: TGLMultiTexture; tex: TGLTexture;
1024 begin
1025 if gfxlist <> nil then
1026 begin
1027 for i := 0 to High(gfxlist) do
1028 begin
1029 if gfxlist[i].typ > 0 then
1030 begin
1031 typ := gfxlist[i].typ;
1032 t := GFXTextures[typ];
1033 if t <> nil then
1034 begin
1035 fx := nlerp(gfxlist[i].oldX, gfxlist[i].x, gLerpFactor);
1036 fy := nlerp(gfxlist[i].oldY, gfxlist[i].y, gLerpFactor);
1037 tex := t.GetTexture(gfxlist[i].frame);
1038 r_Draw_TextureRepeat(tex, fx, fy, tex.width, tex.height, false, 255, 255, 255, 255 - GFXAnim[typ].alpha, false);
1039 end;
1040 end;
1041 end;
1042 end;
1043 end;
1044
1045 procedure r_Map_DrawParticles (x, y, w, h: Integer);
1046 var i, fx, fy: Integer;
1047 begin
1048 if gpart_dbg_enabled and (Particles <> nil) then
1049 begin
1050 glDisable(GL_TEXTURE_2D);
1051 if (g_dbg_scale < 0.6) then
1052 glPointSize(1)
1053 else if (g_dbg_scale > 1.3) then
1054 glPointSize(g_dbg_scale + 1)
1055 else
1056 glPointSize(2);
1057 glDisable(GL_POINT_SMOOTH);
1058 glEnable(GL_BLEND);
1059 glBlendFunc(GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA);
1060
1061 glBegin(GL_POINTS);
1062 for i := 0 to High(Particles) do
1063 begin
1064 if Particles[i].alive then
1065 begin
1066 fx := nlerp(Particles[i].oldX, Particles[i].x, gLerpFactor);
1067 fy := nlerp(Particles[i].oldY, Particles[i].y, gLerpFactor);
1068 glColor4ub(Particles[i].red, Particles[i].green, Particles[i].blue, Particles[i].alpha);
1069 glVertex2f(fx, fy);
1070 end;
1071 end;
1072 glEnd;
1073
1074 glDisable(GL_BLEND);
1075 end;
1076 end;
1077 {$ENDIF}
1078
1079 procedure r_Map_DrawShots (x, y, w, h: Integer);
1080 var i, a, fX, fY, pX, pY, typ: Integer; count, frame: LongInt; t: TGLMultiTexture; tex: TGLTexture;
1081 begin
1082 if Shots <> nil then
1083 begin
1084 for i := 0 to High(Shots) do
1085 begin
1086 typ := Shots[i].ShotType;
1087 if typ <> 0 then
1088 begin
1089 t := ShotTextures[typ];
1090 if t <> nil then
1091 begin
1092 a := 0;
1093 case typ of
1094 WEAPON_ROCKETLAUNCHER, WEAPON_BARON_FIRE, WEAPON_MANCUB_FIRE, WEAPON_SKEL_FIRE:
1095 a := -GetAngle2(Shots[i].Obj.Vel.X, Shots[i].Obj.Vel.Y)
1096 end;
1097 Shots[i].Obj.Lerp(gLerpFactor, fX, fY);
1098 pX := Shots[i].Obj.Rect.Width div 2;
1099 pY := Shots[i].Obj.Rect.Height div 2;
1100 g_Anim_GetFrameByTime(ShotAnim[typ].anim, (gTime - Shots[i].time) DIV GAME_TICK, count, frame);
1101 tex := t.GetTexture(frame);
1102 r_Draw_TextureRepeatRotate(tex, fX, fY, tex.width, tex.height, false, 255, 255, 255, 255, false, pX, pY, a);
1103 end;
1104 end;
1105 end;
1106 end;
1107 // TODO draw g_debug_frames
1108 end;
1109
1110 procedure r_Map_DrawFlags (x, y, w, h: Integer);
1111 var i, dx, fx, fy: Integer; flip: Boolean; t: TGLMultiTexture; tex: TGLTexture;
1112 begin
1113 if gGameSettings.GameMode = GM_CTF then
1114 begin
1115 for i := FLAG_RED to FLAG_BLUE do
1116 begin
1117 if not (gFlags[i].state in [FLAG_STATE_NONE, FLAG_STATE_CAPTURED]) then
1118 begin
1119 gFlags[i].Obj.Lerp(gLerpFactor, fx, fy);
1120 flip := gFlags[i].Direction = TDirection.D_LEFT;
1121 if flip then dx := -1 else dx := +1;
1122 t := FlagTextures[i];
1123 tex := t.GetTexture(FlagFrame);
1124 r_Draw_TextureRepeat(tex, fx + dx, fy + 1, tex.width, tex.height, flip, 255, 255, 255, 255, false)
1125 end;
1126 end;
1127 end;
1128 // TODO g_debug_frames
1129 end;
1130
1131 {$IFDEF ENABLE_SHELLS}
1132 procedure r_Map_DrawShells (x, y, w, h: Integer);
1133 var i, fx, fy, typ: Integer; t: TGLTexture; p: PObj;
1134 begin
1135 if gShells <> nil then
1136 begin
1137 for i := 0 to High(gShells) do
1138 begin
1139 if gShells[i].alive then
1140 begin
1141 typ := gShells[i].SType;
1142 if typ <= SHELL_LAST then
1143 begin
1144 p := @gShells[i].Obj;
1145 if g_Obj_Collide(x, y, w, h, p) then
1146 begin
1147 t := ShellTextures[typ];
1148 if t <> nil then
1149 begin
1150 p.Lerp(gLerpFactor, fx, fy);
1151 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, 255, 255, 255, 255, false, ShellAnim[typ].dx, ShellAnim[typ].dy, gShells[i].RAngle);
1152 end;
1153 end;
1154 end;
1155 end;
1156 end;
1157 end;
1158 end;
1159 {$ENDIF}
1160
1161 procedure r_Map_CalcAspect (ow, oh, nw, nh: LongInt; horizontal: Boolean; out ww, hh: LongInt);
1162 begin
1163 if horizontal then
1164 begin
1165 ww := nw;
1166 hh := nw * oh div ow;
1167 end
1168 else
1169 begin
1170 ww := nh * ow div oh;
1171 hh := nh;
1172 end;
1173 end;
1174
1175 procedure r_Map_CalcSkyParallax (cx, cy, vw, vh, sw, sh, mw, mh: LongInt; out x, y, w, h: LongInt);
1176 const
1177 factor = 120; (* size ratio between view and sky (120%) *)
1178 limit = 100; (* max speed for parallax *)
1179 var
1180 msw, msh, mvw, mvh, svw, svh: LongInt;
1181 begin
1182 msw := vw * factor div 100;
1183 msh := vh * factor div 100;
1184 r_Map_CalcAspect(sw, sh, msw, msh, (sw / sh) <= (msw / msh), w, h);
1185
1186 (* calc x parallax or sky center on speed limit *)
1187 mvw := MAX(1, mw - vw);
1188 svw := w - vw;
1189 if 100 * svw div mvw <= limit then
1190 x := -cx * svw div mvw
1191 else
1192 x := -svw div 2;
1193
1194 (* calc y parallax or sky center on speed limit *)
1195 mvh := MAX(1, mh - vh);
1196 svh := h - vh;
1197 if 100 * svh div mvh <= limit then
1198 y := -cy * svh div mvh
1199 else
1200 y := -svh div 2;
1201
1202 (* handle out of map bounds *)
1203 if x > 0 then x := 0;
1204 if y > 0 then y := 0;
1205 if x < -svw then x := -svw;
1206 if y < -svh then y := -svh;
1207 end;
1208
1209 procedure r_Map_DrawScreenEffect (x, y, w, h, level: Integer; r, g, b: Byte);
1210 var i: Integer;
1211 begin
1212 if level > 0 then
1213 begin
1214 case level of
1215 0..14: i := 0;
1216 15..34: i := 1;
1217 35..54: i := 2;
1218 55..74: i := 3;
1219 75..94: i := 4;
1220 else i := 5
1221 end;
1222 r_Draw_FillRect(x, y, x + w, y + h, r, g, b, i * 50)
1223 end;
1224 end;
1225
1226 procedure r_Map_DrawScreenEffects (x, y, w, h: Integer; p: TPlayer);
1227 begin
1228 if p <> nil then
1229 begin
1230 r_Map_DrawScreenEffect(x, y, w, h, p.pain, 255, 0, 0);
1231 r_Map_DrawScreenEffect(x, y, w, h, p.pickup, 150, 200, 150);
1232 if (p.FMegaRulez[MR_INVUL] >= gTime) and (p.SpawnInvul < gTime) then
1233 begin
1234 if ((p.FMegaRulez[MR_INVUL] - gTime) > 2100) or not ODD((p.FMegaRulez[MR_INVUL] - gTime) div 300) then
1235 r_Draw_InvertRect(x, y, x + w, y + h, 191, 191, 191, 255);
1236 end;
1237 if p.FMegaRulez[MR_SUIT] >= gTime then
1238 begin
1239 if ((p.FMegaRulez[MR_SUIT] - gTime) > 2100) or not ODD((p.FMegaRulez[MR_SUIT] - gTime) div 300) then
1240 r_Draw_FillRect(x, y, x + w, y + h, 0, 96, 0, 55);
1241 end;
1242 if (p.Berserk >= 0) and (p.Berserk >= gTime) and (gFlash = 2) then
1243 begin
1244 r_Draw_FillRect(x, y, x + w, y + h, 255, 0, 0, 55);
1245 end;
1246 end;
1247 end;
1248
1249 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer; player: TPlayer);
1250 var iter: TPanelGrid.Iter; p: PPanel; cx, cy, xx, yy, ww, hh: Integer; sx, sy, sw, sh: LongInt;
1251 begin
1252 cx := camx - w div 2;
1253 cy := camy - h div 2;
1254 xx := x + cx;
1255 yy := y + cy;
1256 ww := w;
1257 hh := h;
1258
1259 if g_dbg_ignore_bounds = false then
1260 begin
1261 if xx + ww > gMapInfo.Width then
1262 xx := gMapInfo.Width - ww;
1263 if yy + hh > gMapInfo.Height then
1264 yy := gMapInfo.Height - hh;
1265 if xx < 0 then
1266 xx := 0;
1267 if yy < 0 then
1268 yy := 0;
1269 cx := xx - x;
1270 cy := yy - y;
1271 end;
1272
1273 if SkyTexture <> nil then
1274 begin
1275 r_Map_CalcSkyParallax(cx, cy, ww, hh, SkyTexture.width, SkyTexture.height, gMapInfo.Width, gMapInfo.Height, sx, sy, sw, sh);
1276 r_Draw_Texture(SkyTexture, x + sx, y + sy, sw, sh, false, 255, 255, 255, 255, false);
1277 end;
1278
1279 plist.Clear;
1280 iter := mapGrid.ForEachInAABB(xx, yy, ww, hh, GridDrawableMask);
1281 for p in iter do
1282 if ((p^.tag and GridTagDoor) <> 0) = p^.door then
1283 plist.Insert(p^);
1284 iter.Release;
1285
1286 glPushMatrix;
1287 glTranslatef(-cx, -cy, 0);
1288 r_Map_DrawPanelType(PANEL_BACK);
1289 r_Map_DrawPanelType(PANEL_STEP);
1290 r_Map_DrawItems(xx, yy, ww, hh, false);
1291 r_Map_DrawShots(xx, yy, ww, hh);
1292 {$IFDEF ENABLE_SHELLS}
1293 r_Map_DrawShells(xx, yy, ww, hh);
1294 {$ENDIF}
1295 r_Map_DrawPlayers(xx, yy, ww, hh, player);
1296 {$IFDEF ENABLE_GIBS}
1297 r_Map_DrawGibs(xx, yy, ww, hh);
1298 {$ENDIF}
1299 {$IFDEF ENABLE_CORPSES}
1300 r_Map_DrawCorpses(xx, yy, ww, hh);
1301 {$ENDIF}
1302 r_Map_DrawPanelType(PANEL_WALL);
1303 r_Map_DrawMonsters(xx, yy, ww, hh);
1304 r_Map_DrawItems(xx, yy, ww, hh, true);
1305 r_Map_DrawPanelType(PANEL_CLOSEDOOR);
1306 {$IFDEF ENABLE_GFX}
1307 r_Map_DrawParticles(xx, yy, ww, hh);
1308 r_Map_DrawGFX(xx, yy, ww, hh);
1309 {$ENDIF}
1310 r_Map_DrawFlags(xx, yy, ww, hh);
1311 r_Map_DrawPanelType(PANEL_ACID1);
1312 r_Map_DrawPanelType(PANEL_ACID2);
1313 r_Map_DrawPanelType(PANEL_WATER);
1314 r_Map_DrawPanelType(PANEL_FORE);
1315 // TODO draw monsters health bar
1316 // TODO draw players health bar
1317 // TODO draw players indicators
1318 glPopMatrix;
1319
1320 r_Map_DrawScreenEffects(x, y, w, h, player);
1321
1322 // TODO draw minimap (gShowMap)
1323 // TODO draw g_debug_player
1324 end;
1325
1326 procedure r_Map_Update;
1327 var i, count, tick: LongInt;
1328 begin
1329 tick := gTime div GAME_TICK;
1330 for i := 0 to ITEM_LAST do
1331 g_Anim_GetFrameByTime(ItemAnim[i].anim, tick, count, Items[i].frame);
1332 r_Map_UpdateGFX(tick);
1333 g_Anim_GetFrameByTime(FlagAnim, tick, count, FlagFrame);
1334 end;
1335
1336 end.
[MIRROR] a port of Doom 2D Forever to FPC/SDL
[15/08/2024 14:52:34]
DEADSOFTWARE 2012-2024