DEADSOFTWARE

GIT / REPO / FRED-BOY
Projects / d2df-sdl.git / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
gl: draw invul pentagram
[d2df-sdl.git] / src / game / renders / opengl / r_map.pas
1 (* Copyright (C) Doom 2D: Forever Developers
2 *
3 * This program is free software: you can redistribute it and/or modify
4 * it under the terms of the GNU General Public License as published by
5 * the Free Software Foundation, version 3 of the License ONLY.
6 *
7 * This program is distributed in the hope that it will be useful,
8 * but WITHOUT ANY WARRANTY; without even the implied warranty of
9 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
10 * GNU General Public License for more details.
11 *
12 * You should have received a copy of the GNU General Public License
13 * along with this program. If not, see <http://www.gnu.org/licenses/>.
14 *)
15 {$INCLUDE ../../../shared/a_modes.inc}
16 unit r_map;
17
18 interface
19
20 uses g_base, g_player; // TRectWH, TPlayer
21
22 procedure r_Map_Initialize;
23 procedure r_Map_Finalize;
24
25 procedure r_Map_Load;
26 procedure r_Map_Free;
27
28 procedure r_Map_LoadTextures;
29 procedure r_Map_FreeTextures;
30
31 {$IFDEF ENABLE_GFX}
32 procedure r_Map_NewGFX (typ, x, y: Integer);
33 {$ENDIF}
34 {$IFDEF ENABLE_GIBS}
35 function r_Map_GetGibSize (m, i: Integer): TRectWH;
36 {$ENDIF}
37
38 procedure r_Map_Update;
39
40 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer; player: TPlayer);
41
42 implementation
43
44 uses
45 Math,
46 {$IFDEF USE_GLES1}
47 GLES11,
48 {$ELSE}
49 GL, GLEXT,
50 {$ENDIF}
51 e_log,
52 binheap, MAPDEF, utils,
53 g_options, g_textures, g_basic, g_phys,
54 g_game, g_map, g_panel, g_items, g_monsters, g_playermodel, g_weapons,
55 {$IFDEF ENABLE_CORPSES}
56 g_corpses,
57 {$ENDIF}
58 {$IFDEF ENABLE_SHELLS}
59 g_shells,
60 {$ENDIF}
61 {$IFDEF ENABLE_GIBS}
62 g_gibs,
63 {$ENDIF}
64 {$IFDEF ENABLE_GFX}
65 g_gfx,
66 {$ENDIF}
67 r_textures, r_draw
68 ;
69
70 const
71 MTABLE: array [0..MONSTER_MAN] of record
72 w, h: Integer;
73 end = (
74 (w: 64; h: 64), // NONE
75 (w: 64; h: 64), // DEMON
76 (w: 64; h: 64), // IMP
77 (w: 64; h: 64), // ZOMBY
78 (w: 64; h: 64), // SERG
79 (w: 128; h: 128), // CYBER
80 (w: 64; h: 64), // CGUN
81 (w: 128; h: 128), // BARON
82 (w: 128; h: 128), // KNIGHT
83 (w: 128; h: 128), // CACO
84 (w: 64; h: 64), // SOUL (DIE is 128x128, see load code)
85 (w: 128; h: 128), // PAIN
86 (w: 256; h: 128), // SPIDER
87 (w: 128; h: 64), // BSP
88 (w: 128; h: 128), // MANCUB
89 (w: 128; h: 128), // SKEL
90 (w: 128; h: 128), // VILE
91 (w: 32; h: 32), // FISH
92 (w: 64; h: 64), // BARREL
93 (w: 128; h: 128), // ROBO
94 (w: 64; h: 64) // MAN
95 );
96 VILEFIRE_DX = 32;
97 VILEFIRE_DY = 128;
98
99 ItemAnim: array [0..ITEM_LAST] of record
100 name: AnsiString;
101 w, h: Integer;
102 d: Integer; // delay
103 n: Integer; // count
104 b: Boolean; // backanim
105 end = (
106 (name: ''; w: 0; h: 0; d: 0; n: 0; b: False),
107 (name: 'MED1'; w: 16; h: 16; d: 0; n: 1; b: False),
108 (name: 'MED2'; w: 32; h: 32; d: 0; n: 1; b: False),
109 (name: 'BMED'; w: 32; h: 32; d: 0; n: 1; b: False),
110 (name: 'ARMORGREEN'; w: 32; h: 16; d: 20; n: 3; b: True),
111 (name: 'ARMORBLUE'; w: 32; h: 16; d: 20; n: 3; b: True),
112 (name: 'SBLUE'; w: 32; h: 32; d: 15; n: 4; b: True),
113 (name: 'SWHITE'; w: 32; h: 32; d: 20; n: 4; b: True),
114 (name: 'SUIT'; w: 32; h: 64; d: 0; n: 1; b: False),
115 (name: 'OXYGEN'; w: 16; h: 32; d: 0; n: 1; b: False),
116 (name: 'INVUL'; w: 32; h: 32; d: 20; n: 4; b: True),
117 (name: 'SAW'; w: 64; h: 32; d: 0; n: 1; b: False),
118 (name: 'SHOTGUN1'; w: 64; h: 16; d: 0; n: 1; b: False),
119 (name: 'SHOTGUN2'; w: 64; h: 16; d: 0; n: 1; b: False),
120 (name: 'MGUN'; w: 64; h: 16; d: 0; n: 1; b: False),
121 (name: 'RLAUNCHER'; w: 64; h: 16; d: 0; n: 1; b: False),
122 (name: 'PGUN'; w: 64; h: 16; d: 0; n: 1; b: False),
123 (name: 'BFG'; w: 64; h: 64; d: 0; n: 1; b: False),
124 (name: 'SPULEMET'; w: 64; h: 16; d: 0; n: 1; b: False),
125 (name: 'CLIP'; w: 16; h: 16; d: 0; n: 1; b: False),
126 (name: 'AMMO'; w: 32; h: 16; d: 0; n: 1; b: False),
127 (name: 'SHELL1'; w: 16; h: 8; d: 0; n: 1; b: False),
128 (name: 'SHELL2'; w: 32; h: 16; d: 0; n: 1; b: False),
129 (name: 'ROCKET'; w: 16; h: 32; d: 0; n: 1; b: False),
130 (name: 'ROCKETS'; w: 64; h: 32; d: 0; n: 1; b: False),
131 (name: 'CELL'; w: 16; h: 16; d: 0; n: 1; b: False),
132 (name: 'CELL2'; w: 32; h: 32; d: 0; n: 1; b: False),
133 (name: 'BPACK'; w: 32; h: 32; d: 0; n: 1; b: False),
134 (name: 'KEYR'; w: 16; h: 16; d: 0; n: 1; b: False),
135 (name: 'KEYG'; w: 16; h: 16; d: 0; n: 1; b: False),
136 (name: 'KEYB'; w: 16; h: 16; d: 0; n: 1; b: False),
137 (name: 'KASTET'; w: 64; h: 32; d: 0; n: 1; b: False),
138 (name: 'PISTOL'; w: 64; h: 16; d: 0; n: 1; b: False),
139 (name: 'BOTTLE'; w: 16; h: 32; d: 20; n: 4; b: True),
140 (name: 'HELMET'; w: 16; h: 16; d: 20; n: 4; b: True),
141 (name: 'JETPACK'; w: 32; h: 32; d: 15; n: 3; b: True),
142 (name: 'INVIS'; w: 32; h: 32; d: 20; n: 4; b: True),
143 (name: 'FLAMETHROWER'; w: 64; h: 32; d: 0; n: 1; b: False),
144 (name: 'FUELCAN'; w: 16; h: 32; d: 0; n: 1; b: False)
145 );
146
147 {$IFDEF ENABLE_GFX}
148 GFXAnim: array [0..R_GFX_LAST] of record
149 name: AnsiString;
150 w, h: Integer;
151 count: Integer;
152 back: Boolean;
153 speed: Integer;
154 rspeed: Integer;
155 alpha: Integer;
156 end = (
157 (name: ''; w: 0; h: 0; count: 0; back: false; speed: 0; rspeed: 0; alpha: 0),
158 (name: 'TELEPORT'; w: 64; h: 64; count: 10; back: false; speed: 6; rspeed: 0; alpha: 0),
159 (name: 'FLAME'; w: 32; h: 32; count: 11; back: false; speed: 3; rspeed: 0; alpha: 0),
160 (name: 'EROCKET'; w: 128; h: 128; count: 6; back: false; speed: 6; rspeed: 0; alpha: 0),
161 (name: 'EBFG'; w: 128; h: 128; count: 6; back: false; speed: 6; rspeed: 0; alpha: 0),
162 (name: 'BFGHIT'; w: 64; h: 64; count: 4; back: false; speed: 4; rspeed: 0; alpha: 0),
163 (name: 'FIRE'; w: 64; h: 128; count: 8; back: false; speed: 4; rspeed: 2; alpha: 0),
164 (name: 'ITEMRESPAWN'; w: 32; h: 32; count: 5; back: true; speed: 4; rspeed: 0; alpha: 0),
165 (name: 'SMOKE'; w: 32; h: 32; count: 10; back: false; speed: 3; rspeed: 0; alpha: 0),
166 (name: 'ESKELFIRE'; w: 64; h: 64; count: 3; back: false; speed: 8; rspeed: 0; alpha: 0),
167 (name: 'EPLASMA'; w: 32; h: 32; count: 4; back: true; speed: 3; rspeed: 0; alpha: 0),
168 (name: 'EBSPFIRE'; w: 32; h: 32; count: 5; back: false; speed: 3; rspeed: 0; alpha: 0),
169 (name: 'EIMPFIRE'; w: 64; h: 64; count: 3; back: false; speed: 6; rspeed: 0; alpha: 0),
170 (name: 'ECACOFIRE'; w: 64; h: 64; count: 3; back: false; speed: 6; rspeed: 0; alpha: 0),
171 (name: 'EBARONFIRE'; w: 64; h: 64; count: 3; back: false; speed: 6; rspeed: 0; alpha: 0),
172 (name: 'TELEPORT'; w: 64; h: 64; count: 10; back: false; speed: 3; rspeed: 0; alpha: 0), // fast
173 (name: 'SMOKE'; w: 32; h: 32; count: 10; back: false; speed: 3; rspeed: 0; alpha: 150), // transparent
174 (name: 'FLAME'; w: 32; h: 32; count: 11; back: false; speed: 3; rspeed: 2; alpha: 0) // random
175 );
176 {$ENDIF}
177
178 ShotAnim: array [0..WEAPON_LAST] of record
179 name: AnsiString;
180 w, h: Integer;
181 count: Integer;
182 end = (
183 (name: ''; w: 0; h: 0; count: 0), // 0 KASTET
184 (name: ''; w: 0; h: 0; count: 0), // 1 SAW
185 (name: ''; w: 0; h: 0; count: 0), // 2 PISTOL
186 (name: ''; w: 0; h: 0; count: 0), // 3 SHOTGUN1
187 (name: ''; w: 0; h: 0; count: 0), // 4 SHOTGUN2
188 (name: ''; w: 0; h: 0; count: 0), // 5 CHAINGUN
189 (name: 'BROCKET'; w: 64; h: 32; count: 1), // 6 ROCKETLAUNCHER
190 (name: 'BPLASMA'; w: 16; h: 16; count: 2), // 7 PLASMA
191 (name: 'BBFG'; w: 64; h: 64; count: 2), // 8 BFG
192 (name: ''; w: 0; h: 0; count: 0), // 9 SUPERPULEMET
193 (name: 'FLAME'; w: 32; h: 32; count: 0{11}), // 10 FLAMETHROWER
194 (name: ''; w: 0; h: 0; count: 0), // 11
195 (name: ''; w: 0; h: 0; count: 0), // 12
196 (name: ''; w: 0; h: 0; count: 0), // 13
197 (name: ''; w: 0; h: 0; count: 0), // 14
198 (name: ''; w: 0; h: 0; count: 0), // 15
199 (name: ''; w: 0; h: 0; count: 0), // 16
200 (name: ''; w: 0; h: 0; count: 0), // 17
201 (name: ''; w: 0; h: 0; count: 0), // 18
202 (name: ''; w: 0; h: 0; count: 0), // 19
203 (name: ''; w: 0; h: 0; count: 0), // 20 ZOMPY_PISTOL
204 (name: 'BIMPFIRE'; w: 16; h: 16; count: 2), // 21 IMP_FIRE
205 (name: 'BBSPFIRE'; w: 16; h: 16; count: 2), // 22 BSP_FIRE
206 (name: 'BCACOFIRE'; w: 16; h: 16; count: 2), // 23 CACO_FIRE
207 (name: 'BBARONFIRE'; w: 64; h: 16; count: 2), // 24 BARON_FIRE
208 (name: 'BMANCUBFIRE'; w: 64; h: 32; count: 2), // 25 MANCUB_FIRE
209 (name: 'BSKELFIRE'; w: 64; h: 64; count: 2) // 26 SKEL_FIRE
210 );
211
212 {$IFDEF ENABLE_SHELLS}
213 ShellAnim: array [0..SHELL_LAST] of record
214 name: AnsiString;
215 dx, dy: Integer;
216 end = (
217 (name: 'EBULLET'; dx: 2; dy: 1), // 0 SHELL_BULLET
218 (name: 'ESHELL'; dx: 4; dy: 2), // 1 SHELL_SHELL
219 (name: 'ESHELL'; dx: 4; dy: 2) // 2 SHELL_DBLSHELL
220 );
221 {$ENDIF}
222
223 type
224 TBinHeapPanelDrawCmp = class
225 public
226 class function less (const a, b: TPanel): Boolean; inline;
227 end;
228
229 TBinHeapPanelDraw = specialize TBinaryHeapBase<TPanel, TBinHeapPanelDrawCmp>;
230
231 TMonsterAnims = array [0..ANIM_LAST, TDirection] of TGLMultiTexture;
232
233 var
234 SkyTexture: TGLTexture;
235 RenTextures: array of record
236 spec: LongInt;
237 tex: TGLMultiTexture;
238 end;
239 Items: array [0..ITEM_LAST] of record
240 tex: TGLMultiTexture;
241 anim: TAnimState;
242 end;
243 MonTextures: array [0..MONSTER_MAN] of TMonsterAnims;
244 WeapTextures: array [0..WP_LAST, 0..W_POS_LAST, 0..W_ACT_LAST] of TGLTexture;
245 ShotTextures: array [0..WEAPON_LAST] of TGLMultiTexture;
246 FlagTextures: array [0..FLAG_LAST] of TGLMultiTexture;
247 PunchTextures: array [Boolean, 0..2] of TGLMultiTexture; // [berserk, center/up/down]
248 VileFire: TGLMultiTexture;
249 InvulPenta: TGLTexture;
250 Models: array of record
251 anim: array [TDirection, 0..A_LAST] of record
252 base, mask: TGLMultiTexture;
253 end;
254 {$IFDEF ENABLE_GIBS}
255 gibs: record
256 base, mask: TGLTextureArray;
257 rect: TRectArray;
258 end;
259 {$ENDIF}
260 end;
261
262 StubShotAnim: TAnimState; // TODO remove this hack
263 FlagAnim: TAnimState;
264
265 {$IFDEF ENABLE_SHELLS}
266 ShellTextures: array [0..SHELL_LAST] of TGLTexture;
267 {$ENDIF}
268 {$IFDEF ENABLE_GFX}
269 GFXTextures: array [0..R_GFX_LAST] of TGLMultiTexture;
270 gfxlist: array of record
271 typ: Byte;
272 alpha: Byte;
273 x, y: Integer;
274 oldX, oldY: Integer;
275 anim: TAnimState;
276 end = nil;
277 {$ENDIF}
278
279 plist: TBinHeapPanelDraw = nil;
280
281 class function TBinHeapPanelDrawCmp.less (const a, b: TPanel): Boolean; inline;
282 begin
283 if a.tag < b.tag then begin result := true; exit; end;
284 if a.tag > b.tag then begin result := false; exit; end;
285 result := a.arrIdx < b.arrIdx;
286 end;
287
288 procedure r_Map_Initialize;
289 begin
290 StubShotAnim := TAnimState.Create(true, 1, 1);
291 FlagAnim := TAnimState.Create(true, 8, 5);
292 plist := TBinHeapPanelDraw.Create();
293 end;
294
295 procedure r_Map_Finalize;
296 begin
297 plist.Free;
298 StubShotAnim.Invalidate;
299 end;
300
301 procedure r_Map_FreeModel (i: Integer);
302 var a: Integer; d: TDirection;
303 begin
304 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
305 begin
306 for a := A_STAND to A_LAST do
307 begin
308 if Models[i].anim[d, a].base <> nil then
309 Models[i].anim[d, a].base.Free;
310 if Models[i].anim[d, a].mask <> nil then
311 Models[i].anim[d, a].mask.Free;
312 Models[i].anim[d, a].base := nil;
313 Models[i].anim[d, a].mask := nil;
314 end;
315 end;
316 {$IFDEF ENABLE_GIBS}
317 if Models[i].gibs.base <> nil then
318 for a := 0 to High(Models[i].gibs.base) do
319 Models[i].gibs.base[a].Free;
320 if Models[i].gibs.mask <> nil then
321 for a := 0 to High(Models[i].gibs.mask) do
322 Models[i].gibs.mask[a].Free;
323 Models[i].gibs.base := nil;
324 Models[i].gibs.mask := nil;
325 Models[i].gibs.rect := nil;
326 {$ENDIF}
327 end;
328
329 procedure r_Map_LoadModel (i: Integer);
330 var prefix: AnsiString; a: Integer; d: TDirection; m: ^TPlayerModelInfo;
331 begin
332 ASSERT(i < Length(Models));
333 ASSERT(i < Length(PlayerModelsArray));
334 r_Map_FreeModel(i);
335 m := @PlayerModelsArray[i];
336 prefix := m.FileName + ':TEXTURES/';
337 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
338 begin
339 for a := A_STAND to A_LAST do
340 begin
341 Models[i].anim[d, a].base := nil;
342 Models[i].anim[d, a].mask := nil;
343 if m.anim[d, a].resource <> '' then
344 Models[i].anim[d, a].base := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].resource, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
345 if m.anim[d, a].mask <> '' then
346 Models[i].anim[d, a].mask := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].mask, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
347 end
348 end;
349 {$IFDEF ENABLE_GIBS}
350 Models[i].gibs.base := nil;
351 Models[i].gibs.mask := nil;
352 Models[i].gibs.rect := nil;
353 if m.GibsCount > 0 then
354 begin
355 SetLength(Models[i].gibs.base, m.GibsCount);
356 SetLength(Models[i].gibs.mask, m.GibsCount);
357 SetLength(Models[i].gibs.rect, m.GibsCount);
358 for a := 0 to m.GibsCount - 1 do
359 Models[i].gibs.rect[a] := DefaultGibSize;
360 if r_Textures_LoadStreamFromFile(prefix + m.GibsResource, 32, 32, m.GibsCount, Models[i].gibs.base, Models[i].gibs.rect) then
361 begin
362 if r_Textures_LoadStreamFromFile(prefix + m.GibsMask, 32, 32, m.GibsCount, Models[i].gibs.mask, nil) then
363 begin
364 // ok
365 end;
366 end;
367 end;
368 {$ENDIF}
369 end;
370
371 procedure r_Map_LoadMonsterAnim (m, a: Integer; d: TDirection);
372 const dir: array [TDirection] of AnsiString = ('_L', '');
373 var w, h, count: Integer;
374 begin
375 count := MONSTER_ANIMTABLE[m].AnimCount[a];
376 if count > 0 then
377 begin
378 w := MTABLE[m].w;
379 h := MTABLE[m].h;
380 if (m = MONSTER_SOUL) and (a = ANIM_DIE) then
381 begin
382 // special case
383 w := 128;
384 h := 128;
385 end;
386 MonTextures[m, a, d] := r_Textures_LoadMultiFromFileAndInfo(
387 GameWAD + ':MTEXTURES/' + MONSTERTABLE[m].name + '_' + ANIMTABLE[a].name + dir[d],
388 w,
389 h,
390 count,
391 False,
392 False
393 );
394 end
395 else
396 MonTextures[m, a, d] := nil;
397 end;
398
399 procedure r_Map_Load;
400 const
401 WeapName: array [0..WP_LAST] of AnsiString = ('', 'CSAW', 'HGUN', 'SG', 'SSG', 'MGUN', 'RKT', 'PLZ', 'BFG', 'SPL', 'FLM');
402 WeapPos: array [0..W_POS_LAST] of AnsiString = ('', '_UP', '_DN');
403 WeapAct: array [0..W_ACT_LAST] of AnsiString = ('', '_FIRE');
404 PunchName: array [Boolean] of AnsiString = ('PUNCH', 'PUNCHB');
405 var
406 i, j, k: Integer; d: TDirection; b: Boolean;
407 begin
408 // --------- items --------- //
409 for i := 0 to ITEM_LAST do
410 begin
411 if ItemAnim[i].n > 0 then
412 begin
413 Items[i].tex := r_Textures_LoadMultiFromFileAndInfo(
414 GameWAD + ':TEXTURES/' + ItemAnim[i].name,
415 ItemAnim[i].w,
416 ItemAnim[i].h,
417 ItemAnim[i].n,
418 ItemAnim[i].b,
419 false
420 );
421 k := IfThen(ItemAnim[i].b, ItemAnim[i].n * 2 - 2, ItemAnim[i].n);
422 Items[i].anim := TAnimState.Create(True, ItemAnim[i].d, k);
423 end;
424 end;
425 // --------- monsters --------- //
426 for i := MONSTER_DEMON to MONSTER_MAN do
427 for j := 0 to ANIM_LAST do
428 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
429 r_Map_LoadMonsterAnim(i, j, d);
430 VileFire := r_Textures_LoadMultiFromFileAndInfo(GameWAD + ':TEXTURES/FIRE', 64, 128, 8, False, False);
431 // --------- player models --------- //
432 if PlayerModelsArray <> nil then
433 begin
434 SetLength(Models, Length(PlayerModelsArray));
435 for i := 0 to High(PlayerModelsArray) do
436 r_Map_LoadModel(i);
437 end;
438 // --------- player weapons --------- //
439 for i := 1 to WP_LAST do
440 for j := 0 to W_POS_LAST do
441 for k := 0 to W_ACT_LAST do
442 WeapTextures[i, j, k] := r_Textures_LoadFromFile(GameWAD + ':WEAPONS\' + WeapName[i] + WeapPos[j] + WeapAct[k]);
443 // --------- gfx animations --------- //
444 {$IFDEF ENABLE_GFX}
445 for i := 1 to R_GFX_LAST do
446 if GFXAnim[i].count > 0 then
447 GFXTextures[i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/' + GFXAnim[i].name, GFXAnim[i].w, GFXAnim[i].h, GFXAnim[i].count, GFXAnim[i].back);
448 {$ENDIF}
449 // --------- shots --------- //
450 for i := 0 to WEAPON_LAST do
451 if ShotAnim[i].count > 0 then
452 ShotTextures[i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/' + ShotAnim[i].name, ShotAnim[i].w, ShotAnim[i].h, ShotAnim[i].count, false);
453 // --------- flags --------- //
454 FlagTextures[FLAG_NONE] := nil;
455 FlagTextures[FLAG_RED] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGRED', 64, 64, 5, false);
456 FlagTextures[FLAG_BLUE] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGBLUE', 64, 64, 5, false);
457 // FlagTextures[FLAG_DOM] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGDOM', 64, 64, 8, false);
458 // --------- shells --------- //
459 {$IFDEF ENABLE_SHELLS}
460 for i := 0 to SHELL_LAST do
461 ShellTextures[i] := r_Textures_LoadFromFile(GameWad + ':TEXTURES/' + ShellAnim[i].name);
462 {$ENDIF}
463 // --------- punch --------- //
464 for b := false to true do
465 begin
466 for i := 0 to 2 do
467 PunchTextures[b, i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':WEAPONS/' + PunchName[b] + WeapPos[i], 64, 64, 4, false);
468 end;
469 // --------- other --------- //
470 InvulPenta := r_Textures_LoadFromFile(GameWad + ':TEXTURES/PENTA');
471 end;
472
473 procedure r_Map_Free;
474 var i, j, k: Integer; d: TDirection; b: Boolean;
475 begin
476 if InvulPenta <> nil then
477 InvulPenta.Free;
478 InvulPenta := nil;
479 for b := false to true do
480 begin
481 for i := 0 to 2 do
482 begin
483 if PunchTextures[b, i] <> nil then
484 PunchTextures[b, i].Free;
485 PunchTextures[b, i] := nil;
486 end;
487 end;
488 {$IFDEF ENABLE_SHELLS}
489 for i := 0 to SHELL_LAST do
490 begin
491 if ShellTextures[i] <> nil then
492 ShellTextures[i].Free;
493 ShellTextures[i] := nil;
494 end;
495 {$ENDIF}
496 for i := 0 to FLAG_LAST do
497 begin
498 if FlagTextures[i] <> nil then
499 FlagTextures[i].Free;
500 FlagTextures[i] := nil;
501 end;
502 for i := 0 to WEAPON_LAST do
503 begin
504 if ShotTextures[i] <> nil then
505 ShotTextures[i].Free;
506 ShotTextures[i] := nil;
507 end;
508 {$IFDEF ENABLE_GFX}
509 gfxlist := nil;
510 for i := 0 to R_GFX_LAST do
511 begin
512 if GFXTextures[i] <> nil then
513 GFXTextures[i].Free;
514 GFXTextures[i] := nil;
515 end;
516 {$ENDIF}
517 for i := 1 to WP_LAST do
518 begin
519 for j := 0 to W_POS_LAST do
520 begin
521 for k := 0 to W_ACT_LAST do
522 begin
523 if WeapTextures[i, j, k] <> nil then
524 WeapTextures[i, j, k].Free;
525 WeapTextures[i, j, k] := nil;
526 end;
527 end;
528 end;
529 if Models <> nil then
530 for i := 0 to High(Models) do
531 r_Map_FreeModel(i);
532 for i := MONSTER_DEMON to MONSTER_MAN do
533 begin
534 for j := 0 to ANIM_LAST do
535 begin
536 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
537 begin
538 if MonTextures[i, j, d] <> nil then
539 MonTextures[i, j, d].Free;
540 MonTextures[i, j, d] := nil;
541 end;
542 end;
543 end;
544 for i := 0 to ITEM_LAST do
545 begin
546 if Items[i].tex <> nil then
547 begin
548 Items[i].tex.Free;
549 Items[i].tex := nil;
550 end;
551 Items[i].anim.Invalidate;
552 end;
553 end;
554
555 procedure r_Map_LoadTextures;
556 var i, n: Integer;
557 begin
558 if Textures <> nil then
559 begin
560 n := Length(Textures);
561 SetLength(RenTextures, n);
562 for i := 0 to n - 1 do
563 begin
564 RenTextures[i].tex := nil;
565 case Textures[i].TextureName of
566 TEXTURE_NAME_WATER: RenTextures[i].spec := TEXTURE_SPECIAL_WATER;
567 TEXTURE_NAME_ACID1: RenTextures[i].spec := TEXTURE_SPECIAL_ACID1;
568 TEXTURE_NAME_ACID2: RenTextures[i].spec := TEXTURE_SPECIAL_ACID2;
569 else
570 RenTextures[i].spec := 0;
571 RenTextures[i].tex := r_Textures_LoadMultiFromFile(Textures[i].FullName);
572 if RenTextures[i].tex = nil then
573 e_LogWritefln('r_Map_LoadTextures: failed to load texture: %s', [Textures[i].FullName]);
574 end;
575 end;
576 end;
577 if gMapInfo.SkyFullName <> '' then
578 SkyTexture := r_Textures_LoadFromFile(gMapInfo.SkyFullName);
579 plist.Clear;
580 end;
581
582 procedure r_Map_FreeTextures;
583 var i: Integer;
584 begin
585 plist.Clear;
586 if SkyTexture <> nil then
587 SkyTexture.Free;
588 SkyTexture := nil;
589 if RenTextures <> nil then
590 for i := 0 to High(RenTextures) do
591 if RenTextures[i].tex <> nil then
592 RenTextures[i].tex.Free;
593 RenTextures := nil;
594 end;
595
596 procedure r_Map_DrawPanel (p: TPanel);
597 var Texture: Integer; t: TGLMultiTexture;
598 begin
599 ASSERT(p <> nil);
600 if p.FCurTexture >= 0 then
601 begin
602 Texture := p.TextureIDs[p.FCurTexture].Texture;
603 t := RenTextures[Texture].tex;
604
605 if (RenTextures[Texture].spec = 0) or (t <> nil) then
606 begin
607 if t = nil then
608 r_Draw_TextureRepeat(nil, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
609 else if p.TextureIDs[p.FCurTexture].AnTex.IsValid() then
610 r_Draw_MultiTextureRepeat(t, p.TextureIDs[p.FCurTexture].AnTex, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
611 else
612 r_Draw_TextureRepeat(t.GetTexture(0), p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
613 end;
614
615 if t = nil then
616 begin
617 case RenTextures[Texture].spec of
618 TEXTURE_SPECIAL_WATER: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 0, 255, 255);
619 TEXTURE_SPECIAL_ACID1: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 230, 0, 255);
620 TEXTURE_SPECIAL_ACID2: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 230, 0, 0, 255);
621 end
622 end
623 end
624 end;
625
626 procedure r_Map_DrawPanelType (panelTyp: DWORD);
627 var tagMask, i: Integer; p: TPanel;
628 begin
629 i := 0;
630 tagMask := PanelTypeToTag(panelTyp);
631 while plist.count > 0 do
632 begin
633 p := TPanel(plist.Front());
634 if (p.tag and tagMask) = 0 then
635 break;
636 r_Map_DrawPanel(p);
637 Inc(i);
638 plist.PopFront
639 end;
640 end;
641
642 procedure r_Map_DrawItems (x, y, w, h: Integer; drop: Boolean);
643 var i, fX, fY: Integer; it: PItem; t: TGLMultiTexture;
644 begin
645 if ggItems <> nil then
646 begin
647 for i := 0 to High(ggItems) do
648 begin
649 it := @ggItems[i];
650 if it.used and it.alive and (it.dropped = drop) and (it.ItemType > ITEM_NONE) and (it.ItemType <= ITEM_LAST) then
651 begin
652 t := Items[it.ItemType].tex;
653 if g_Collide(it.obj.x, it.obj.y, t.width, t.height, x, y, w, h) then
654 begin
655 it.obj.Lerp(gLerpFactor, fX, fY);
656 r_Draw_MultiTextureRepeat(t, Items[it.ItemType].anim, fX, fY, t.width, t.height, false, 255, 255, 255, 255, false);
657 end;
658 end;
659 end;
660 end;
661 // TODO draw g_debug_frames
662 end;
663
664 function r_Map_GetMonsterTexture (m, a: Integer; d: TDirection; out t: TGLMultiTexture; out dx, dy: Integer; out flip: Boolean): Boolean;
665 // var c: Integer;
666 begin
667 t := nil; dx := 0; dy := 0; flip := false;
668 result := MonTextures[m, a, d] <> nil;
669 if result = false then
670 begin
671 flip := true;
672 if d = TDirection.D_RIGHT then d := TDirection.D_LEFT else d := TDirection.D_RIGHT;
673 result := MonTextures[m, a, d] <> nil;
674 end;
675 if result = true then
676 begin
677 t := MonTextures[m, a, d];
678 if d = TDirection.D_LEFT then
679 begin
680 dx := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].X;
681 dy := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].Y;
682 end
683 else
684 begin
685 dx := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].X;
686 dy := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].Y;
687 end;
688 if flip then
689 begin
690 // c := (MONSTERTABLE[MonsterType].Rect.X - dx) + MONSTERTABLE[MonsterType].Rect.Width;
691 // dx := MTABLE[m].width - c - MONSTERTABLE[MonsterType].Rect.X;
692 dx := -dx;
693 end;
694 end;
695 end;
696
697 procedure r_Map_DrawMonsterAttack (constref mon: TMonster);
698 var o: TObj;
699 begin
700 if VileFire <> nil then
701 if (mon.MonsterType = MONSTER_VILE) and (mon.MonsterState = MONSTATE_SHOOT) then
702 if mon.VileFireAnim.IsValid() and GetPos(mon.MonsterTargetUID, @o) then
703 r_Draw_MultiTextureRepeat(VileFire, mon.VileFireAnim, o.x + o.rect.x + (o.rect.width div 2) - VILEFIRE_DX, o.y + o.rect.y + o.rect.height - VILEFIRE_DY, VileFire.width, VileFire.height, False, 255, 255, 255, 255, false);
704 end;
705
706 procedure r_Map_DrawMonster (constref mon: TMonster);
707 var m, a, fX, fY, dx, dy: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture;
708 begin
709 m := mon.MonsterType;
710 a := mon.MonsterAnim;
711 d := mon.GameDirection;
712
713 mon.obj.Lerp(gLerpFactor, fX, fY);
714
715 if r_Map_GetMonsterTexture(m, a, d, t, dx, dy, flip) then
716 r_Draw_MultiTextureRepeat(t, mon.DirAnim[a, d], fX + dx, fY + dy, t.width, t.height, flip, 255, 255, 255, 255, false);
717
718 // TODO draw g_debug_frames
719 end;
720
721 procedure r_Map_DrawMonsters (x, y, w, h: Integer);
722 var i: Integer; m: TMonster;
723 begin
724 if gMonsters <> nil then
725 begin
726 for i := 0 to High(gMonsters) do
727 begin
728 m := gMonsters[i];
729 if m <> nil then
730 begin
731 r_Map_DrawMonsterAttack(m);
732 // TODO select from grid
733 if g_Collide(m.obj.x + m.obj.rect.x, m.obj.y + m.obj.rect.y, m.obj.rect.width, m.obj.rect.height, x, y, w, h) then
734 r_Map_DrawMonster(m);
735 end;
736 end;
737 end;
738 end;
739
740 function r_Map_GetPlayerModelTex (i: Integer; var a: Integer; var d: TDirection; out flip: Boolean): Boolean;
741 begin
742 flip := false;
743 result := Models[i].anim[d, a].base <> nil;
744 if result = false then
745 begin
746 flip := true;
747 if d = TDirection.D_LEFT then d := TDirection.D_RIGHT else d := TDirection.D_LEFT;
748 result := Models[i].anim[d, a].base <> nil;
749 end;
750 end;
751
752 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer);
753 var a, pos, act, xx, yy, angle: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture; tex: TGLTexture; c: TRGB;
754 begin
755 a := pm.CurrentAnimation;
756 d := pm.Direction;
757
758 (* draw flag*)
759 t := FlagTextures[pm.Flag];
760 if (t <> nil) and not (a in [A_DIE1, A_DIE2]) then
761 begin
762 flip := d = TDirection.D_RIGHT;
763 angle := PlayerModelsArray[pm.id].FlagAngle;
764 xx := PlayerModelsArray[pm.id].FlagPoint.X;
765 yy := PlayerModelsArray[pm.id].FlagPoint.Y;
766 r_Draw_MultiTextureRepeatRotate(
767 t,
768 FlagAnim,
769 x + IfThen(flip, 2 * FLAG_BASEPOINT.X - xx + 1, xx - 1) - FLAG_BASEPOINT.X,
770 y + yy - FLAG_BASEPOINT.Y + 1,
771 t.width,
772 t.height,
773 flip,
774 255, 255, 255, 255, false,
775 IfThen(flip, 64 - FLAG_BASEPOINT.X, FLAG_BASEPOINT.X),
776 FLAG_BASEPOINT.Y,
777 IfThen(flip, angle, -angle)
778 );
779 end;
780
781 (* draw weapon *)
782 if PlayerModelsArray[pm.id].HaveWeapon and not (a in [A_DIE1, A_DIE2, A_PAIN]) then
783 begin
784 case a of
785 A_SEEUP, A_ATTACKUP: pos := W_POS_UP;
786 A_SEEDOWN, A_ATTACKDOWN: pos := W_POS_DOWN;
787 else pos := W_POS_NORMAL;
788 end;
789 if (a in [A_ATTACK, A_ATTACKUP, A_ATTACKDOWN]) or pm.GetFire() then
790 act := W_ACT_FIRE
791 else
792 act := W_ACT_NORMAL;
793 tex := WeapTextures[pm.CurrentWeapon, pos, act];
794 if tex <> nil then
795 begin
796 xx := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].X;
797 yy := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].Y;
798 r_Draw_Texture(
799 tex,
800 x + xx,
801 y + yy,
802 tex.width,
803 tex.height,
804 d = TDirection.D_LEFT,
805 255, 255, 255, 255, false
806 );
807 end;
808 end;
809
810 (* draw body *)
811 if r_Map_GetPlayerModelTex(pm.id, a, d, flip) then
812 begin
813 t := Models[pm.id].anim[d, a].base;
814 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip, 255, 255, 255, 255, false);
815 t := Models[pm.id].anim[d, a].mask;
816 if t <> nil then
817 begin
818 c := pm.Color;
819 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip, c.r, c.g, c.b, 255, false);
820 end;
821 end;
822 end;
823
824 procedure r_Map_DrawPlayer (p, drawed: TPlayer);
825 var fX, fY, fSlope, ax, ay, w, h: Integer; b, flip: Boolean; t: TGLMultiTexture;
826 begin
827 if p.alive then
828 begin
829 fX := p.obj.x; fY := p.obj.y;
830 // TODO fix lerp
831 //p.obj.Lerp(gLerpFactor, fX, fY);
832 fSlope := nlerp(p.SlopeOld, p.obj.slopeUpLeft, gLerpFactor);
833 if p.PunchAnim.IsValid() and p.PunchAnim.enabled then
834 begin
835 b := R_BERSERK in p.FRulez;
836 if p.FKeys[KEY_DOWN].pressed then
837 t := PunchTextures[b, 2]
838 else if p.FKeys[KEY_UP].pressed then
839 t := PunchTextures[b, 1]
840 else
841 t := PunchTextures[b, 0];
842 if t <> nil then
843 begin
844 flip := p.Direction = TDirection.D_LEFT;
845 ax := IfThen(flip, 15 - p.Obj.Rect.X, p.Obj.Rect.X - 15); // ???
846 ay := p.Obj.Rect.Y - 11;
847 r_Draw_MultiTextureRepeat(t, p.PunchAnim, fx + ax, fy + fSlope + ay, t.width, t.height, flip, 255, 255, 255, 255, false)
848 end;
849 end;
850 if (InvulPenta <> nil) and (p.FMegaRulez[MR_INVUL] > gTime) and ((p <> drawed) or (p.SpawnInvul >= gTime)) then
851 begin
852 w := InvulPenta.width;
853 h := InvulPenta.height;
854 ax := p.Obj.Rect.X + (p.Obj.Rect.Width div 2) - (w div 2); // + IfThen(flip, +4, -2) // ???
855 ay := p.Obj.Rect.Y + (p.Obj.Rect.Height div 2) - (h div 2) - 7; // ???
856 r_Draw_Texture(InvulPenta, fx + ax, fy + ay + fSlope, w, h, false, 255, 255, 255, 255, false);
857 end;
858 // TODO draw it with transparency
859 r_Map_DrawPlayerModel(p.Model, fX, fY + fSlope);
860 end;
861 // TODO draw g_debug_frames
862 // TODO draw chat bubble
863 // TODO draw aim
864 end;
865
866 procedure r_Map_DrawPlayers (x, y, w, h: Integer; player: TPlayer);
867 var i: Integer;
868 begin
869 if gPlayers <> nil then
870 for i := 0 to High(gPlayers) do
871 if gPlayers[i] <> nil then
872 r_Map_DrawPlayer(gPlayers[i], player);
873 end;
874
875 {$IFDEF ENABLE_GIBS}
876 function r_Map_GetGibSize (m, i: Integer): TRectWH;
877 begin
878 result := Models[m].gibs.rect[i];
879 end;
880
881 procedure r_Map_DrawGibs (x, y, w, h: Integer);
882 var i, fx, fy, m, id, rx, ry, ra: Integer; p: PObj; t: TGLTexture;
883 begin
884 if gGibs <> nil then
885 begin
886 for i := 0 to High(gGibs) do
887 begin
888 if gGibs[i].alive then
889 begin
890 p := @gGibs[i].Obj;
891 if g_Obj_Collide(x, y, w, h, p) then
892 begin
893 p.Lerp(gLerpFactor, fx, fy);
894 id := gGibs[i].GibID;
895 m := gGibs[i].ModelID;
896 t := Models[m].gibs.base[id];
897 if t <> nil then
898 begin
899 rx := p.Rect.X + p.Rect.Width div 2;
900 ry := p.Rect.Y + p.Rect.Height div 2;
901 ra := gGibs[i].RAngle;
902 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, 255, 255, 255, 255, false, rx, ry, ra);
903 t := Models[m].gibs.mask[id];
904 if t <> nil then
905 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, gGibs[i].Color.R, gGibs[i].Color.G, gGibs[i].Color.B, 255, false, rx, ry, ra);
906 // r_Draw_TextureRepeatRotate(nil, fx + p.Rect.X, fy + p.Rect.Y, p.Rect.Width, p.Rect.Height, false, 255, 255, 255, 255, false, p.Rect.Width div 2, p.Rect.Height div 2, ra);
907 end;
908 end;
909 end;
910 end;
911 end;
912 // TODO draw g_debug_frames
913 end;
914 {$ENDIF}
915
916 {$IFDEF ENABLE_CORPSES}
917 procedure r_Map_DrawCorpses (x, y, w, h: Integer);
918 var i, fX, fY: Integer; p: TCorpse;
919 begin
920 if gCorpses <> nil then
921 begin
922 for i := 0 to High(gCorpses) do
923 begin
924 p := gCorpses[i];
925 if (p <> nil) and (p.state <> CORPSE_STATE_REMOVEME) and (p.model <> nil) then
926 begin
927 p.obj.Lerp(gLerpFactor, fX, fY);
928 r_Map_DrawPlayerModel(p.model, fX, fY);
929 end;
930 end;
931 end;
932 // TODO draw g_debug_frames
933 end;
934 {$ENDIF}
935
936 {$IFDEF ENABLE_GFX}
937 function r_Map_GetGFXID (): Integer;
938 var i: Integer;
939 begin
940 i := 0;
941 if gfxlist <> nil then
942 begin
943 while (i < Length(gfxlist)) and gfxlist[i].anim.IsValid() do
944 Inc(i);
945 if i >= Length(gfxlist) then
946 SetLength(gfxlist, Length(gfxlist) + 1)
947 end
948 else
949 SetLength(gfxlist, 1);
950 gfxlist[i].typ := R_GFX_NONE;
951 gfxlist[i].anim.Invalidate;
952 result := i
953 end;
954
955 procedure r_Map_NewGFX (typ, x, y: Integer);
956 var i: Integer;
957 begin
958 if gpart_dbg_enabled and (typ > 0) and (typ <= R_GFX_LAST) then
959 begin
960 i := r_Map_GetGFXID();
961 if i >= 0 then
962 begin
963 gfxlist[i].typ := typ;
964 gfxlist[i].x := x;
965 gfxlist[i].y := y;
966 gfxlist[i].oldX := x;
967 gfxlist[i].oldY := y;
968 gfxlist[i].anim := TAnimState.Create(false, GFXAnim[typ].speed + Random(GFXAnim[typ].rspeed), GFXAnim[typ].count);
969 gfxlist[i].anim.Reset();
970 gfxlist[i].anim.Enable();
971 end;
972 end;
973 end;
974
975 procedure r_Map_UpdateGFX;
976 var i: Integer;
977 begin
978 if gfxlist <> nil then
979 begin
980 for i := 0 to High(gfxlist) do
981 begin
982 if gfxlist[i].anim.IsValid() then
983 begin
984 gfxlist[i].oldX := gfxlist[i].x;
985 gfxlist[i].oldY := gfxlist[i].y;
986 case gfxlist[i].typ of
987 R_GFX_FLAME, R_GFX_SMOKE:
988 begin
989 if Random(3) = 0 then
990 gfxlist[i].x := gfxlist[i].x - 1 + Random(3);
991 if Random(2) = 0 then
992 gfxlist[i].y := gfxlist[i].y - Random(2);
993 end;
994 end;
995 if gfxlist[i].anim.played then
996 gfxlist[i].anim.Invalidate
997 else
998 gfxlist[i].anim.Update
999 end;
1000 end;
1001 end;
1002 end;
1003
1004 procedure r_Map_DrawParticles (x, y, w, h: Integer);
1005 var i, fx, fy: Integer;
1006 begin
1007 if gpart_dbg_enabled and (Particles <> nil) then
1008 begin
1009 glDisable(GL_TEXTURE_2D);
1010 if (g_dbg_scale < 0.6) then
1011 glPointSize(1)
1012 else if (g_dbg_scale > 1.3) then
1013 glPointSize(g_dbg_scale + 1)
1014 else
1015 glPointSize(2);
1016 glDisable(GL_POINT_SMOOTH);
1017 glEnable(GL_BLEND);
1018 glBlendFunc(GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA);
1019
1020 glBegin(GL_POINTS);
1021 for i := 0 to High(Particles) do
1022 begin
1023 if Particles[i].alive then
1024 begin
1025 fx := nlerp(Particles[i].oldX, Particles[i].x, gLerpFactor);
1026 fy := nlerp(Particles[i].oldY, Particles[i].y, gLerpFactor);
1027 glColor4ub(Particles[i].red, Particles[i].green, Particles[i].blue, Particles[i].alpha);
1028 glVertex2f(fx, fy);
1029 end;
1030 end;
1031 glEnd;
1032
1033 glDisable(GL_BLEND);
1034 end;
1035 end;
1036
1037 procedure r_Map_DrawGFX (x, y, w, h: Integer);
1038 var i, fx, fy, typ: Integer; tex: TGLMultiTexture;
1039 begin
1040 if gfxlist <> nil then
1041 begin
1042 for i := 0 to High(gfxlist) do
1043 begin
1044 if gfxlist[i].anim.IsValid() then
1045 begin
1046 typ := gfxlist[i].typ;
1047 tex := GFXTextures[typ];
1048 if tex <> nil then
1049 begin
1050 fx := nlerp(gfxlist[i].oldX, gfxlist[i].x, gLerpFactor);
1051 fy := nlerp(gfxlist[i].oldY, gfxlist[i].y, gLerpFactor);
1052 r_Draw_MultiTextureRepeat(tex, gfxlist[i].anim, fx, fy, tex.width, tex.height, false, 255, 255, 255, 255 - GFXAnim[typ].alpha, false);
1053 end;
1054 end;
1055 end;
1056 end;
1057 end;
1058 {$ENDIF}
1059
1060 procedure r_Map_DrawShots (x, y, w, h: Integer);
1061 var i, a, fX, fY, pX, pY, typ: Integer; tex: TGLMultiTexture; anim: ^TAnimState;
1062 begin
1063 if Shots <> nil then
1064 begin
1065 for i := 0 to High(Shots) do
1066 begin
1067 typ := Shots[i].ShotType;
1068 if typ <> 0 then
1069 begin
1070 tex := ShotTextures[typ];
1071 if tex <> nil then
1072 begin
1073 a := 0;
1074 case typ of
1075 WEAPON_ROCKETLAUNCHER, WEAPON_BARON_FIRE, WEAPON_MANCUB_FIRE, WEAPON_SKEL_FIRE:
1076 a := -GetAngle2(Shots[i].Obj.Vel.X, Shots[i].Obj.Vel.Y)
1077 end;
1078 Shots[i].Obj.Lerp(gLerpFactor, fX, fY);
1079 pX := Shots[i].Obj.Rect.Width div 2;
1080 pY := Shots[i].Obj.Rect.Height div 2;
1081 // TODO fix this hack
1082 if Shots[i].Animation.IsValid() then anim := @Shots[i].Animation else anim := @StubShotAnim;
1083 r_Draw_MultiTextureRepeatRotate(tex, anim^, fX, fY, tex.width, tex.height, false, 255, 255, 255, 255, false, pX, pY, a);
1084 end;
1085 end;
1086 end;
1087 end;
1088 // TODO draw g_debug_frames
1089 end;
1090
1091 procedure r_Map_DrawFlags (x, y, w, h: Integer);
1092 var i, dx, fx, fy: Integer; flip: Boolean; tex: TGLMultiTexture;
1093 begin
1094 if gGameSettings.GameMode = GM_CTF then
1095 begin
1096 for i := FLAG_RED to FLAG_BLUE do
1097 begin
1098 if not (gFlags[i].state in [FLAG_STATE_NONE, FLAG_STATE_CAPTURED]) then
1099 begin
1100 gFlags[i].Obj.Lerp(gLerpFactor, fx, fy);
1101 flip := gFlags[i].Direction = TDirection.D_LEFT;
1102 if flip then dx := -1 else dx := +1;
1103 tex := FlagTextures[i];
1104 r_Draw_MultiTextureRepeat(tex, FlagAnim, fx + dx, fy + 1, tex.width, tex.height, flip, 255, 255, 255, 255, false)
1105 end;
1106 end;
1107 end;
1108 // TODO g_debug_frames
1109 end;
1110
1111 {$IFDEF ENABLE_SHELLS}
1112 procedure r_Map_DrawShells (x, y, w, h: Integer);
1113 var i, fx, fy, typ: Integer; t: TGLTexture; p: PObj;
1114 begin
1115 if gShells <> nil then
1116 begin
1117 for i := 0 to High(gShells) do
1118 begin
1119 if gShells[i].alive then
1120 begin
1121 typ := gShells[i].SType;
1122 if typ <= SHELL_LAST then
1123 begin
1124 p := @gShells[i].Obj;
1125 if g_Obj_Collide(x, y, w, h, p) then
1126 begin
1127 t := ShellTextures[typ];
1128 if t <> nil then
1129 begin
1130 p.Lerp(gLerpFactor, fx, fy);
1131 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, 255, 255, 255, 255, false, ShellAnim[typ].dx, ShellAnim[typ].dy, gShells[i].RAngle);
1132 end;
1133 end;
1134 end;
1135 end;
1136 end;
1137 end;
1138 end;
1139 {$ENDIF}
1140
1141 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer; player: TPlayer);
1142 var iter: TPanelGrid.Iter; p: PPanel; cx, cy, xx, yy, ww, hh: Integer;
1143 begin
1144 cx := camx - w div 2;
1145 cy := camy - h div 2;
1146 xx := x + cx;
1147 yy := y + cy;
1148 ww := w;
1149 hh := h;
1150
1151 // TODO lock camera at map bounds
1152
1153 // TODO draw paralax
1154 if SkyTexture <> nil then
1155 r_Draw_Texture(SkyTexture, x, y, w, h, false, 255, 255, 255, 255, false);
1156
1157 plist.Clear;
1158 iter := mapGrid.ForEachInAABB(xx, yy, ww, hh, GridDrawableMask);
1159 for p in iter do
1160 if ((p^.tag and GridTagDoor) <> 0) = p^.door then
1161 plist.Insert(p^);
1162 iter.Release;
1163
1164 glPushMatrix;
1165 glTranslatef(-cx, -cy, 0);
1166 r_Map_DrawPanelType(PANEL_BACK);
1167 r_Map_DrawPanelType(PANEL_STEP);
1168 r_Map_DrawItems(xx, yy, ww, hh, false);
1169 r_Map_DrawShots(xx, yy, ww, hh);
1170 {$IFDEF ENABLE_SHELLS}
1171 r_Map_DrawShells(xx, yy, ww, hh);
1172 {$ENDIF}
1173 r_Map_DrawPlayers(xx, yy, ww, hh, player);
1174 {$IFDEF ENABLE_GIBS}
1175 r_Map_DrawGibs(xx, yy, ww, hh);
1176 {$ENDIF}
1177 {$IFDEF ENABLE_CORPSES}
1178 r_Map_DrawCorpses(xx, yy, ww, hh);
1179 {$ENDIF}
1180 r_Map_DrawPanelType(PANEL_WALL);
1181 r_Map_DrawMonsters(xx, yy, ww, hh);
1182 r_Map_DrawItems(xx, yy, ww, hh, true);
1183 r_Map_DrawPanelType(PANEL_CLOSEDOOR);
1184 {$IFDEF ENABLE_GFX}
1185 r_Map_DrawParticles(xx, yy, ww, hh);
1186 r_Map_DrawGFX(xx, yy, ww, hh);
1187 {$ENDIF}
1188 r_Map_DrawFlags(xx, yy, ww, hh);
1189 r_Map_DrawPanelType(PANEL_ACID1);
1190 r_Map_DrawPanelType(PANEL_ACID2);
1191 r_Map_DrawPanelType(PANEL_WATER);
1192 r_Map_DrawPanelType(PANEL_FORE);
1193 // TODO draw monsters health bar
1194 // TODO draw players health bar
1195 // TODO draw players indicators
1196 glPopMatrix;
1197
1198 // TODO draw player pain
1199 // TODO draw player pickup
1200 // TODO draw player invul
1201 // TODO draw minimap
1202 // TODO draw g_debug_player
1203 end;
1204
1205 procedure r_Map_Update;
1206 var i: Integer;
1207 begin
1208 for i := 0 to ITEM_LAST do
1209 Items[i].anim.Update;
1210 r_Map_UpdateGFX;
1211 FlagAnim.Update;
1212 end;
1213
1214 end.
[MIRROR] a port of Doom 2D Forever to FPC/SDL
[25/02/2024 19:55:35]
DEADSOFTWARE 2012-2024