src/game/sdl2/g_system.pas

   1 (* Copyright (C)  Doom 2D: Forever Developers
   2  *
   3  * This program is free software: you can redistribute it and/or modify
   4  * it under the terms of the GNU General Public License as published by
   5  * the Free Software Foundation, version 3 of the License ONLY.
   6  *
   7  * This program is distributed in the hope that it will be useful,
   8  * but WITHOUT ANY WARRANTY; without even the implied warranty of
   9  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  10  * GNU General Public License for more details.
  11  *
  12  * You should have received a copy of the GNU General Public License
  13  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  14  *)
  15 {$INCLUDE ../shared/a_modes.inc}
  16 unit g_system;
  17
  18 interface
  19
  20   uses Utils;
  21
  22   (* --- Utils --- *)
  23   function sys_GetTicks (): Int64;
  24   procedure sys_Delay (ms: Integer);
  25
  26   (* --- Graphics --- *)
  27   function sys_GetDisplayModes (bpp: Integer): SSArray;
  28   function sys_SetDisplayMode (w, h, bpp: Integer; fullscreen, maximized: Boolean): Boolean;
  29   procedure sys_EnableVSync (yes: Boolean);
  30   procedure sys_Repaint;
  31
  32   (* --- Input --- *)
  33   function sys_HandleInput (): Boolean;
  34   procedure sys_RequestQuit;
  35
  36   (* --- Init --- *)
  37   procedure sys_Init;
  38   procedure sys_Final;
  39
  40   var (* hooks *)
  41     sys_CharPress: procedure (ch: AnsiChar) = nil;
  42     sys_ScreenResize: procedure (w, h: Integer) = nil;
  43
  44 implementation
  45
  46   uses
  47     SysUtils, SDL2, Math, ctypes,
  48     e_log, e_input, e_sound,
  49     {$IFDEF ENABLE_HOLMES}
  50       sdlcarcass,
  51     {$ENDIF}
  52     g_touch, g_options, g_console, g_game, g_basic
  53   ;
  54
  55   const
  56     GameTitle = 'Doom 2D: Forever (SDL 2, %s)';
  57
  58   var
  59     window: PSDL_Window;
  60     context: TSDL_GLContext;
  61     display, wx, wy: Integer;
  62     wc: Boolean;
  63     JoystickHandle: array [0..e_MaxJoys - 1] of PSDL_Joystick;
  64     JoystickHatState: array [0..e_MaxJoys - 1, 0..e_MaxJoyHats - 1, HAT_LEFT..HAT_DOWN] of Boolean;
  65     JoystickZeroAxes: array [0..e_MaxJoys - 1, 0..e_MaxJoyAxes - 1] of Integer;
  66
  67   (* --------- Utils --------- *)
  68
  69   function sys_GetTicks (): Int64;
  70   begin
  71     result := SDL_GetTicks()
  72   end;
  73
  74   procedure sys_Delay (ms: Integer);
  75   begin
  76     SDL_Delay(ms)
  77   end;
  78
  79   (* --------- Graphics --------- *)
  80
  81   function GetTitle (): AnsiString;
  82     var info: AnsiString;
  83   begin
  84     info := g_GetBuildHash(false);
  85     if info = 'custom build' then
  86       info := info + ' by ' + g_GetBuilderName() + ' ' + GAME_BUILDDATE + ' ' + GAME_BUILDTIME;
  87     result := Format(GameTitle, [info]);
  88   end;
  89
  90   function InitWindow (w, h, bpp: Integer; fullScreen, maximized: Boolean): Boolean;
  91     var flags: UInt32; x, y: cint; title: AnsiString;
  92   begin
  93     // note: on window close make: if assigned(oglDeinitCB) then oglDeinitCB;
  94     e_LogWritefln('InitWindow %s %s %s %s', [w, h, bpp, fullScreen]);
  95     result := false;
  96     if window = nil then
  97     begin
  98       {$IFDEF USE_GLES1}
  99         SDL_GL_SetAttribute(SDL_GL_CONTEXT_MAJOR_VERSION, 1);
 100         SDL_GL_SetAttribute(SDL_GL_CONTEXT_MINOR_VERSION, 1);
 101         SDL_GL_SetAttribute(SDL_GL_CONTEXT_PROFILE_MASK, SDL_GL_CONTEXT_PROFILE_ES);
 102       {$ELSE}
 103         SDL_GL_SetAttribute(SDL_GL_CONTEXT_MAJOR_VERSION, 2);
 104         SDL_GL_SetAttribute(SDL_GL_CONTEXT_MINOR_VERSION, 1);
 105         SDL_GL_SetAttribute(SDL_GL_RED_SIZE, 8);
 106         SDL_GL_SetAttribute(SDL_GL_GREEN_SIZE, 8);
 107         SDL_GL_SetAttribute(SDL_GL_BLUE_SIZE, 8);
 108         SDL_GL_SetAttribute(SDL_GL_DEPTH_SIZE, 16);
 109         SDL_GL_SetAttribute(SDL_GL_DOUBLEBUFFER, 1);
 110         SDL_GL_SetAttribute(SDL_GL_STENCIL_SIZE, 8); // lights; it is enough to have 1-bit stencil buffer for lighting, but...
 111       {$ENDIF}
 112       flags := SDL_WINDOW_OPENGL or SDL_WINDOW_RESIZABLE;
 113       if fullScreen then flags := flags or SDL_WINDOW_FULLSCREEN;
 114       if maximized then flags := flags or SDL_WINDOW_MAXIMIZED;
 115       if wc then
 116       begin
 117         x := SDL_WINDOWPOS_CENTERED;
 118         y := SDL_WINDOWPOS_CENTERED
 119       end
 120       else
 121       begin
 122         x := wx;
 123         y := wy
 124       end;
 125       title := GetTitle();
 126       window := SDL_CreateWindow(PChar(title), x, y, w, h, flags);
 127       if window <> nil then
 128       begin
 129         context := SDL_GL_CreateContext(window);
 130         if context <> nil then
 131         begin
 132           if (fullscreen = false) and (maximized = false) and (wc = false) then
 133           begin
 134             SDL_GetWindowPosition(window, @x, @y);
 135             wx := x; wy := y
 136           end;
 137           gFullScreen := fullscreen;
 138           gWinMaximized := maximized;
 139           gRC_FullScreen := fullscreen;
 140           gRC_Maximized := maximized;
 141           if @sys_ScreenResize <> nil then
 142             sys_ScreenResize(w, h);
 143           result := true
 144         end
 145         else
 146         begin
 147           // SDL_DestroyWindow(window);
 148           e_LogWritefln('SDL: unable to create OpenGL context: %s', [SDL_GetError])
 149         end
 150       end
 151       else
 152       begin
 153         e_LogWritefln('SDL: unable to create window: %s', [SDL_GetError])
 154       end
 155     end
 156     else
 157     begin
 158       if fullScreen then flags := SDL_WINDOW_FULLSCREEN else flags := 0;
 159       SDL_SetWindowFullscreen(window, flags);
 160       SDL_SetWindowSize(window, w, h);
 161       if maximized then SDL_MaximizeWindow(window);
 162       // always reset to center when changing fullscreen->windowed for safety purposes
 163       if wc or (gFullscreen and not fullscreen) or (gWinMaximized and not maximized) then
 164       begin
 165         x := SDL_WINDOWPOS_CENTERED;
 166         y := SDL_WINDOWPOS_CENTERED
 167       end
 168       else
 169       begin
 170         x := wx;
 171         y := wy
 172       end;
 173       SDL_SetWindowPosition(window, x, y);
 174       if (fullscreen = false) and (maximized = false) and (wc = false) then
 175       begin
 176         SDL_GetWindowPosition(window, @x, @y);
 177         wx := x; wy := y
 178       end;
 179       gFullScreen := fullscreen;
 180       gWinMaximized := maximized;
 181       gRC_FullScreen := fullscreen;
 182       gRC_Maximized := maximized;
 183       if @sys_ScreenResize <> nil then
 184         sys_ScreenResize(w, h);
 185       result := true
 186     end
 187   end;
 188
 189   procedure sys_Repaint;
 190   begin
 191     SDL_GL_SwapWindow(window)
 192   end;
 193
 194   procedure sys_EnableVSync (yes: Boolean);
 195   begin
 196     if yes then
 197       SDL_GL_SetSwapInterval(1)
 198     else
 199       SDL_GL_SetSwapInterval(0)
 200   end;
 201
 202   function sys_GetDisplayModes (bpp: Integer): SSArray;
 203     var i, count, num, pw, ph: Integer; m: TSDL_DisplayMode;
 204   begin
 205     result := nil;
 206     num := SDL_GetNumDisplayModes(display);
 207     if num < 0 then
 208       e_LogWritefln('SDL: unable to get numer of available display modes: %s', [SDL_GetError]);
 209     if num > 0 then
 210     begin
 211       e_LogWritefln('Video modes for display %s:', [display]);
 212       SetLength(result, num);
 213       i := 0; count := 0; pw := 0; ph := 0;
 214       while i < num do
 215       begin
 216         SDL_GetDisplayMode(display, i, @m);
 217         if ((pw <> m.w) or (ph <> m.h)) then
 218         begin
 219           e_LogWritefln('* %sx%sx%s@%s', [m.w, m.h, SDL_BITSPERPIXEL(m.format), m.refresh_rate]);
 220           pw := m.w; ph := m.h;
 221           result[count] := IntToStr(m.w) + 'x' + IntToStr(m.h);
 222           Inc(count);
 223         end
 224         else
 225         begin
 226           e_LogWritefln('- %sx%sx%s@%s', [m.w, m.h, SDL_BITSPERPIXEL(m.format), m.refresh_rate]);
 227         end;
 228         Inc(i)
 229       end;
 230       SetLength(result, count)
 231     end
 232   end;
 233
 234   function sys_SetDisplayMode (w, h, bpp: Integer; fullScreen, maximized: Boolean): Boolean;
 235   begin
 236     result := InitWindow(w, h, bpp, fullScreen, maximized)
 237   end;
 238
 239   (* --------- Joystick --------- *)
 240
 241   procedure HandleJoyButton (var ev: TSDL_JoyButtonEvent);
 242     var down: Boolean; key: Integer;
 243   begin
 244     if (ev.which < e_MaxJoys) and (ev.button < e_MaxJoyBtns) then
 245     begin
 246       key := e_JoyButtonToKey(ev.which, ev.button);
 247       down := ev.type_ = SDL_JOYBUTTONDOWN;
 248       if g_dbg_input then
 249         e_LogWritefln('Input Debug: jbutton, joy=%s, button=%s, keycode=%s, press=%s', [ev.which, ev.button, key, down]);
 250       e_KeyUpDown(key, down);
 251       g_Console_ProcessBind(key, down)
 252     end
 253     else
 254     begin
 255       if g_dbg_input then
 256       begin
 257         down := ev.type_ = SDL_JOYBUTTONDOWN;
 258         e_LogWritefln('Input Debug: NOT IN RANGE! jbutton, joy=%s, button=%s, press=%s', [ev.which, ev.button, down])
 259       end
 260     end
 261   end;
 262
 263   procedure HandleJoyAxis (var ev: TSDL_JoyAxisEvent);
 264     var key, minuskey: Integer;
 265   begin
 266     if (ev.which < e_MaxJoys) and (ev.axis < e_MaxJoyAxes) then
 267     begin
 268       key := e_JoyAxisToKey(ev.which, ev.axis, AX_PLUS);
 269       minuskey := e_JoyAxisToKey(ev.which, ev.axis, AX_MINUS);
 270
 271       if g_dbg_input then
 272           e_LogWritefln('Input Debug: jaxis, joy=%s, axis=%s, value=%s, zeroaxes=%s, deadzone=%s', [ev.which, ev.axis, ev.value, JoystickZeroAxes[ev.which, ev.axis], e_JoystickDeadzones[ev.which]]);
 273
 274       if ev.value < JoystickZeroAxes[ev.which, ev.axis] - e_JoystickDeadzones[ev.which] then
 275       begin
 276         if (e_KeyPressed(key)) then
 277         begin
 278           e_KeyUpDown(key, False);
 279           g_Console_ProcessBind(key, False)
 280         end;
 281         e_KeyUpDown(minuskey, True);
 282         g_Console_ProcessBind(minuskey, True)
 283       end
 284       else if ev.value > JoystickZeroAxes[ev.which, ev.axis] + e_JoystickDeadzones[ev.which] then
 285       begin
 286         if (e_KeyPressed(minuskey)) then
 287         begin
 288           e_KeyUpDown(minuskey, False);
 289           g_Console_ProcessBind(minuskey, False)
 290         end;
 291         e_KeyUpDown(key, True);
 292         g_Console_ProcessBind(key, True)
 293       end
 294       else
 295       begin
 296         if (e_KeyPressed(minuskey)) then
 297         begin
 298           e_KeyUpDown(minuskey, False);
 299           g_Console_ProcessBind(minuskey, False)
 300         end;
 301         if (e_KeyPressed(key)) then
 302         begin
 303           e_KeyUpDown(key, False);
 304           g_Console_ProcessBind(key, False)
 305         end
 306       end
 307     end
 308     else
 309     begin
 310       if g_dbg_input then
 311         e_LogWritefln('Input Debug: NOT IN RANGE! jaxis, joy=%s, axis=%s, value=%s, zeroaxes=%s, deadzone=%s', [ev.which, ev.axis, ev.value, JoystickZeroAxes[ev.which, ev.axis], e_JoystickDeadzones[ev.which]])
 312     end
 313   end;
 314
 315   procedure HandleJoyHat (var ev: TSDL_JoyHatEvent);
 316     var
 317       down: Boolean;
 318       i, key: Integer;
 319       hat: array [HAT_LEFT..HAT_DOWN] of Boolean;
 320   begin
 321     if (ev.which < e_MaxJoys) and (ev.hat < e_MaxJoyHats) then
 322     begin
 323       if g_dbg_input then
 324         e_LogWritefln('Input Debug: jhat, joy=%s, hat=%s, value=%s', [ev.which, ev.hat, ev.value]);
 325       hat[HAT_UP] := LongBool(ev.value and SDL_HAT_UP);
 326       hat[HAT_DOWN] := LongBool(ev.value and SDL_HAT_DOWN);
 327       hat[HAT_LEFT] := LongBool(ev.value and SDL_HAT_LEFT);
 328       hat[HAT_RIGHT] := LongBool(ev.value and SDL_HAT_RIGHT);
 329       for i := HAT_LEFT to HAT_DOWN do
 330       begin
 331         if JoystickHatState[ev.which, ev.hat, i] <> hat[i] then
 332         begin
 333           down := hat[i];
 334           key := e_JoyHatToKey(ev.which, ev.hat, i);
 335           e_KeyUpDown(key, down);
 336           g_Console_ProcessBind(key, down)
 337         end
 338       end;
 339       JoystickHatState[ev.which, ev.hat] := hat
 340     end
 341     else
 342     begin
 343       if g_dbg_input then
 344         e_LogWritefln('Input Debug: NOT IN RANGE! jhat, joy=%s, hat=%s, value=%s', [ev.which, ev.hat, ev.value])
 345     end
 346   end;
 347
 348   procedure HandleJoyAdd (var ev: TSDL_JoyDeviceEvent);
 349     var i: Integer;
 350   begin
 351     if (ev.which < e_MaxJoys) then
 352     begin
 353       JoystickHandle[ev.which] := SDL_JoystickOpen(ev.which);
 354       if JoystickHandle[ev.which] <> nil then
 355       begin
 356         e_LogWritefln('Added Joystick %s', [ev.which]);
 357         e_JoystickAvailable[ev.which] := True;
 358         for i := 0 to Min(SDL_JoystickNumAxes(JoystickHandle[ev.which]), e_MaxJoyAxes) - 1 do
 359           JoystickZeroAxes[ev.which, i] := SDL_JoystickGetAxis(JoystickHandle[ev.which], i)
 360       end
 361       else
 362       begin
 363         e_LogWritefln('Warning! Failed to open Joystick %s', [ev.which])
 364       end
 365     end
 366     else
 367     begin
 368       e_LogWritefln('Warning! Added Joystick %s, but we support only <= %s', [ev.which, e_MaxJoys])
 369     end
 370   end;
 371
 372   procedure HandleJoyRemove (var ev: TSDL_JoyDeviceEvent);
 373   begin
 374     e_LogWritefln('Removed Joystick %s', [ev.which]);
 375     if (ev.which < e_MaxJoys) then
 376     begin
 377       e_JoystickAvailable[ev.which] := False;
 378       if JoystickHandle[ev.which] <> nil then
 379         SDL_JoystickClose(JoystickHandle[ev.which]);
 380       JoystickHandle[ev.which] := nil
 381     end
 382   end;
 383
 384   (* --------- Input --------- *)
 385
 386   function HandleWindow (var ev: TSDL_WindowEvent): Boolean;
 387   begin
 388     result := false;
 389     if g_dbg_input then
 390       e_LogWritefln('Window Event: event = %s, data1 = %s, data2 = %s', [ev.event, ev.data1, ev.data2]);
 391     case ev.event of
 392       SDL_WINDOWEVENT_RESIZED:
 393         if @sys_ScreenResize <> nil then
 394           sys_ScreenResize(ev.data1, ev.data2);
 395       SDL_WINDOWEVENT_EXPOSED: sys_Repaint;
 396       SDL_WINDOWEVENT_CLOSE: result := true;
 397       SDL_WINDOWEVENT_MOVED:
 398         begin
 399           wx := ev.data1;
 400           wy := ev.data2
 401         end;
 402       SDL_WINDOWEVENT_FOCUS_LOST, SDL_WINDOWEVENT_MINIMIZED:
 403         begin
 404           e_UnpressAllKeys;
 405           if gMuteWhenInactive then
 406             e_MuteChannels(true);
 407           {$IFDEF ENABLE_HOLMES}
 408             if assigned(winBlurCB) then winBlurCB;
 409           {$ENDIF}
 410         end;
 411       SDL_WINDOWEVENT_FOCUS_GAINED, SDL_WINDOWEVENT_MAXIMIZED, SDL_WINDOWEVENT_RESTORED:
 412         begin
 413           if ev.event = SDL_WINDOWEVENT_MAXIMIZED then
 414           begin
 415             gWinMaximized := true;
 416             gRC_Maximized := true
 417           end
 418           else if ev.event = SDL_WINDOWEVENT_RESTORED then
 419           begin
 420             gWinMaximized := false;
 421             gRC_Maximized := false
 422           end;
 423           e_MuteChannels(false);
 424           {$IFDEF ENABLE_HOLMES}
 425             if assigned(winFocusCB) then winFocusCB;
 426           {$ENDIF}
 427         end;
 428     end
 429   end;
 430
 431   procedure HandleKeyboard (var ev: TSDL_KeyboardEvent);
 432     var down: Boolean; key: Integer;
 433   begin
 434     key := ev.keysym.scancode;
 435     down := (ev.type_ = SDL_KEYDOWN);
 436     if key = SDL_SCANCODE_AC_BACK then
 437       key := SDL_SCANCODE_ESCAPE;
 438     {$IFDEF ENABLE_HOLMES}
 439       if fuiOnSDLEvent(PSDL_Event(@ev)^) then
 440       begin
 441         // event eaten, but...
 442         if not down then e_KeyUpDown(key, false);
 443         exit;
 444       end;
 445     {$ENDIF}
 446     if ev._repeat = 0 then
 447     begin
 448       if g_dbg_input then
 449         e_LogWritefln('Input Debug: keysym, press=%s, scancode=%s', [down, key]);
 450       e_KeyUpDown(key, down);
 451       g_Console_ProcessBind(key, down);
 452     end
 453     else
 454     begin
 455       if g_dbg_input then
 456         e_LogWritefln('Input Debug: keyrep, scancode=%s', [key]);
 457       g_Console_ProcessBindRepeat(key);
 458     end
 459   end;
 460
 461   procedure HandleTextInput (var ev: TSDL_TextInputEvent);
 462     var ch: UnicodeChar; sch: AnsiChar;
 463   begin
 464     Utf8ToUnicode(@ch, PChar(ev.text), 1);
 465     sch := AnsiChar(wchar2win(ch));
 466     if g_dbg_input then
 467       e_LogWritefln('Input Debug: text, text="%s", ch = %s, sch = %s', [ev.text, Ord(ch), Ord(sch)]);
 468     if @sys_CharPress <> nil then
 469       if IsValid1251(Word(ch)) and IsPrintable1251(ch) then
 470         sys_CharPress(sch)
 471   end;
 472
 473   function sys_HandleInput (): Boolean;
 474     var ev: TSDL_Event;
 475   begin
 476     result := false;
 477     ZeroMemory(@ev, sizeof(ev));
 478     while SDL_PollEvent(@ev) <> 0 do
 479     begin
 480       case ev.type_ of
 481         SDL_QUITEV: result := true;
 482         SDL_WINDOWEVENT: result := HandleWindow(ev.window);
 483         SDL_KEYUP, SDL_KEYDOWN: HandleKeyboard(ev.key);
 484         SDL_JOYBUTTONDOWN, SDL_JOYBUTTONUP: HandleJoyButton(ev.jbutton);
 485         SDL_JOYAXISMOTION: HandleJoyAxis(ev.jaxis);
 486         SDL_JOYHATMOTION: HandleJoyHat(ev.jhat);
 487         SDL_JOYDEVICEADDED: HandleJoyAdd(ev.jdevice);
 488         SDL_JOYDEVICEREMOVED: HandleJoyRemove(ev.jdevice);
 489         SDL_TEXTINPUT: HandleTextInput(ev.text);
 490         SDL_FINGERMOTION, SDL_FINGERDOWN, SDL_FINGERUP: g_Touch_HandleEvent(ev.tfinger);
 491         {$IFDEF ENABLE_HOLMES}
 492           SDL_MOUSEBUTTONDOWN, SDL_MOUSEBUTTONUP, SDL_MOUSEWHEEL, SDL_MOUSEMOTION: fuiOnSDLEvent(ev);
 493         {$ENDIF}
 494       end
 495     end
 496   end;
 497
 498   procedure sys_RequestQuit;
 499     var ev: TSDL_Event;
 500   begin
 501     ev.type_ := SDL_QUITEV;
 502     SDL_PushEvent(@ev)
 503   end;
 504
 505   (* --------- Init --------- *)
 506
 507   procedure sys_Init;
 508     var flags: UInt32;
 509   begin
 510     e_WriteLog('Init SDL2', TMsgType.Notify);
 511     {$IFDEF HEADLESS}
 512       {$IFDEF USE_SDLMIXER}
 513         flags := SDL_INIT_TIMER or SDL_INIT_AUDIO or $00004000;
 514       {$ELSE}
 515         flags := SDL_INIT_TIMER or $00004000;
 516       {$ENDIF}
 517     {$ELSE}
 518       flags := SDL_INIT_TIMER or SDL_INIT_VIDEO;
 519     {$ENDIF}
 520     SDL_SetHint(SDL_HINT_ACCELEROMETER_AS_JOYSTICK, '0');
 521     if SDL_Init(flags) <> 0 then
 522       raise Exception.Create('SDL: Init failed: ' + SDL_GetError);
 523     {$IFNDEF HEADLESS}
 524       if SDL_InitSubSystem(SDL_INIT_JOYSTICK) <> 0 then
 525         e_LogWritefln('SDL: Init subsystem failed: %s', [SDL_GetError()]);
 526     {$ENDIF}
 527     SDL_ShowCursor(SDL_DISABLE);
 528   end;
 529
 530   procedure sys_Final;
 531   begin
 532     e_WriteLog('Releasing SDL2', TMsgType.Notify);
 533     if context <> nil then
 534     begin
 535       SDL_GL_DeleteContext(context);
 536       context := nil;
 537     end;
 538     if window <> nil then
 539     begin
 540       SDL_DestroyWindow(window);
 541       window := nil;
 542     end;
 543     SDL_Quit
 544   end;
 545
 546 initialization
 547   conRegVar('sdl2_display_index', @display, 'use display index as base', '');
 548   conRegVar('sdl2_window_x', @wx, 'window position x', '');
 549   conRegVar('sdl2_window_y', @wy, 'window position y', '');
 550   conRegVar('sdl2_window_center', @wc, 'force window creation at center', '');
 551   display := 0;
 552   wx := SDL_WINDOWPOS_CENTERED;
 553   wy := SDL_WINDOWPOS_CENTERED;
 554   wc := false
 555 end.