DEADSOFTWARE

GIT / REPO / FRED-BOY
Projects / d2df-sdl.git / blob


9a984283979f63d9676da548bc34d8bffe020035
[d2df-sdl.git] / src / game / renders / opengl / r_map.pas
1 (* Copyright (C) Doom 2D: Forever Developers
2 *
3 * This program is free software: you can redistribute it and/or modify
4 * it under the terms of the GNU General Public License as published by
5 * the Free Software Foundation, version 3 of the License ONLY.
6 *
7 * This program is distributed in the hope that it will be useful,
8 * but WITHOUT ANY WARRANTY; without even the implied warranty of
9 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
10 * GNU General Public License for more details.
11 *
12 * You should have received a copy of the GNU General Public License
13 * along with this program. If not, see <http://www.gnu.org/licenses/>.
14 *)
15 {$INCLUDE ../../../shared/a_modes.inc}
16 unit r_map;
17
18 interface
19
20 uses g_base; // TRectWH
21
22 procedure r_Map_Initialize;
23 procedure r_Map_Finalize;
24
25 procedure r_Map_Load;
26 procedure r_Map_Free;
27
28 procedure r_Map_LoadTextures;
29 procedure r_Map_FreeTextures;
30
31 {$IFDEF ENABLE_GFX}
32 procedure r_Map_NewGFX (typ, x, y: Integer);
33 {$ENDIF}
34 {$IFDEF ENABLE_GIBS}
35 function r_Map_GetGibSize (m, i: Integer): TRectWH;
36 {$ENDIF}
37
38 procedure r_Map_Update;
39
40 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer);
41
42 implementation
43
44 uses
45 Math,
46 {$IFDEF USE_GLES1}
47 GLES11,
48 {$ELSE}
49 GL, GLEXT,
50 {$ENDIF}
51 e_log,
52 binheap, MAPDEF, utils,
53 g_options, g_textures, g_basic, g_phys,
54 g_game, g_map, g_panel, g_items, g_monsters, g_playermodel, g_player, g_weapons,
55 {$IFDEF ENABLE_CORPSES}
56 g_corpses,
57 {$ENDIF}
58 {$IFDEF ENABLE_SHELLS}
59 g_shells,
60 {$ENDIF}
61 {$IFDEF ENABLE_GIBS}
62 g_gibs,
63 {$ENDIF}
64 {$IFDEF ENABLE_GFX}
65 g_gfx,
66 {$ENDIF}
67 r_textures, r_draw
68 ;
69
70 const
71 MTABLE: array [0..MONSTER_MAN] of record
72 w, h: Integer;
73 end = (
74 (w: 64; h: 64), // NONE
75 (w: 64; h: 64), // DEMON
76 (w: 64; h: 64), // IMP
77 (w: 64; h: 64), // ZOMBY
78 (w: 64; h: 64), // SERG
79 (w: 128; h: 128), // CYBER
80 (w: 64; h: 64), // CGUN
81 (w: 128; h: 128), // BARON
82 (w: 128; h: 128), // KNIGHT
83 (w: 128; h: 128), // CACO
84 (w: 64; h: 64), // SOUL (DIE is 128x128, see load code)
85 (w: 128; h: 128), // PAIN
86 (w: 256; h: 128), // SPIDER
87 (w: 128; h: 64), // BSP
88 (w: 128; h: 128), // MANCUB
89 (w: 128; h: 128), // SKEL
90 (w: 128; h: 128), // VILE
91 (w: 32; h: 32), // FISH
92 (w: 64; h: 64), // BARREL
93 (w: 128; h: 128), // ROBO
94 (w: 64; h: 64) // MAN
95 );
96 VILEFIRE_DX = 32;
97 VILEFIRE_DY = 128;
98
99 ItemAnim: array [0..ITEM_LAST] of record
100 name: AnsiString;
101 w, h: Integer;
102 d: Integer; // delay
103 n: Integer; // count
104 b: Boolean; // backanim
105 end = (
106 (name: ''; w: 0; h: 0; d: 0; n: 0; b: False),
107 (name: 'MED1'; w: 16; h: 16; d: 0; n: 1; b: False),
108 (name: 'MED2'; w: 32; h: 32; d: 0; n: 1; b: False),
109 (name: 'BMED'; w: 32; h: 32; d: 0; n: 1; b: False),
110 (name: 'ARMORGREEN'; w: 32; h: 16; d: 20; n: 3; b: True),
111 (name: 'ARMORBLUE'; w: 32; h: 16; d: 20; n: 3; b: True),
112 (name: 'SBLUE'; w: 32; h: 32; d: 15; n: 4; b: True),
113 (name: 'SWHITE'; w: 32; h: 32; d: 20; n: 4; b: True),
114 (name: 'SUIT'; w: 32; h: 64; d: 0; n: 1; b: False),
115 (name: 'OXYGEN'; w: 16; h: 32; d: 0; n: 1; b: False),
116 (name: 'INVUL'; w: 32; h: 32; d: 20; n: 4; b: True),
117 (name: 'SAW'; w: 64; h: 32; d: 0; n: 1; b: False),
118 (name: 'SHOTGUN1'; w: 64; h: 16; d: 0; n: 1; b: False),
119 (name: 'SHOTGUN2'; w: 64; h: 16; d: 0; n: 1; b: False),
120 (name: 'MGUN'; w: 64; h: 16; d: 0; n: 1; b: False),
121 (name: 'RLAUNCHER'; w: 64; h: 16; d: 0; n: 1; b: False),
122 (name: 'PGUN'; w: 64; h: 16; d: 0; n: 1; b: False),
123 (name: 'BFG'; w: 64; h: 64; d: 0; n: 1; b: False),
124 (name: 'SPULEMET'; w: 64; h: 16; d: 0; n: 1; b: False),
125 (name: 'CLIP'; w: 16; h: 16; d: 0; n: 1; b: False),
126 (name: 'AMMO'; w: 32; h: 16; d: 0; n: 1; b: False),
127 (name: 'SHELL1'; w: 16; h: 8; d: 0; n: 1; b: False),
128 (name: 'SHELL2'; w: 32; h: 16; d: 0; n: 1; b: False),
129 (name: 'ROCKET'; w: 16; h: 32; d: 0; n: 1; b: False),
130 (name: 'ROCKETS'; w: 64; h: 32; d: 0; n: 1; b: False),
131 (name: 'CELL'; w: 16; h: 16; d: 0; n: 1; b: False),
132 (name: 'CELL2'; w: 32; h: 32; d: 0; n: 1; b: False),
133 (name: 'BPACK'; w: 32; h: 32; d: 0; n: 1; b: False),
134 (name: 'KEYR'; w: 16; h: 16; d: 0; n: 1; b: False),
135 (name: 'KEYG'; w: 16; h: 16; d: 0; n: 1; b: False),
136 (name: 'KEYB'; w: 16; h: 16; d: 0; n: 1; b: False),
137 (name: 'KASTET'; w: 64; h: 32; d: 0; n: 1; b: False),
138 (name: 'PISTOL'; w: 64; h: 16; d: 0; n: 1; b: False),
139 (name: 'BOTTLE'; w: 16; h: 32; d: 20; n: 4; b: True),
140 (name: 'HELMET'; w: 16; h: 16; d: 20; n: 4; b: True),
141 (name: 'JETPACK'; w: 32; h: 32; d: 15; n: 3; b: True),
142 (name: 'INVIS'; w: 32; h: 32; d: 20; n: 4; b: True),
143 (name: 'FLAMETHROWER'; w: 64; h: 32; d: 0; n: 1; b: False),
144 (name: 'FUELCAN'; w: 16; h: 32; d: 0; n: 1; b: False)
145 );
146
147 {$IFDEF ENABLE_GFX}
148 GFXAnim: array [0..R_GFX_LAST] of record
149 name: AnsiString;
150 w, h: Integer;
151 count: Integer;
152 back: Boolean;
153 speed: Integer;
154 rspeed: Integer;
155 alpha: Integer;
156 end = (
157 (name: ''; w: 0; h: 0; count: 0; back: false; speed: 0; rspeed: 0; alpha: 0),
158 (name: 'TELEPORT'; w: 64; h: 64; count: 10; back: false; speed: 6; rspeed: 0; alpha: 0),
159 (name: 'FLAME'; w: 32; h: 32; count: 11; back: false; speed: 3; rspeed: 0; alpha: 0),
160 (name: 'EROCKET'; w: 128; h: 128; count: 6; back: false; speed: 6; rspeed: 0; alpha: 0),
161 (name: 'EBFG'; w: 128; h: 128; count: 6; back: false; speed: 6; rspeed: 0; alpha: 0),
162 (name: 'BFGHIT'; w: 64; h: 64; count: 4; back: false; speed: 4; rspeed: 0; alpha: 0),
163 (name: 'FIRE'; w: 64; h: 128; count: 8; back: false; speed: 4; rspeed: 2; alpha: 0),
164 (name: 'ITEMRESPAWN'; w: 32; h: 32; count: 5; back: true; speed: 4; rspeed: 0; alpha: 0),
165 (name: 'SMOKE'; w: 32; h: 32; count: 10; back: false; speed: 3; rspeed: 0; alpha: 0),
166 (name: 'ESKELFIRE'; w: 64; h: 64; count: 3; back: false; speed: 8; rspeed: 0; alpha: 0),
167 (name: 'EPLASMA'; w: 32; h: 32; count: 4; back: true; speed: 3; rspeed: 0; alpha: 0),
168 (name: 'EBSPFIRE'; w: 32; h: 32; count: 5; back: false; speed: 3; rspeed: 0; alpha: 0),
169 (name: 'EIMPFIRE'; w: 64; h: 64; count: 3; back: false; speed: 6; rspeed: 0; alpha: 0),
170 (name: 'ECACOFIRE'; w: 64; h: 64; count: 3; back: false; speed: 6; rspeed: 0; alpha: 0),
171 (name: 'EBARONFIRE'; w: 64; h: 64; count: 3; back: false; speed: 6; rspeed: 0; alpha: 0),
172 (name: 'TELEPORT'; w: 64; h: 64; count: 10; back: false; speed: 3; rspeed: 0; alpha: 0), // fast
173 (name: 'SMOKE'; w: 32; h: 32; count: 10; back: false; speed: 3; rspeed: 0; alpha: 150), // transparent
174 (name: 'FLAME'; w: 32; h: 32; count: 11; back: false; speed: 3; rspeed: 2; alpha: 0) // random
175 );
176 {$ENDIF}
177
178 ShotAnim: array [0..WEAPON_LAST] of record
179 name: AnsiString;
180 w, h: Integer;
181 count: Integer;
182 end = (
183 (name: ''; w: 0; h: 0; count: 0), // 0 KASTET
184 (name: ''; w: 0; h: 0; count: 0), // 1 SAW
185 (name: ''; w: 0; h: 0; count: 0), // 2 PISTOL
186 (name: ''; w: 0; h: 0; count: 0), // 3 SHOTGUN1
187 (name: ''; w: 0; h: 0; count: 0), // 4 SHOTGUN2
188 (name: ''; w: 0; h: 0; count: 0), // 5 CHAINGUN
189 (name: 'BROCKET'; w: 64; h: 32; count: 1), // 6 ROCKETLAUNCHER
190 (name: 'BPLASMA'; w: 16; h: 16; count: 2), // 7 PLASMA
191 (name: 'BBFG'; w: 64; h: 64; count: 2), // 8 BFG
192 (name: ''; w: 0; h: 0; count: 0), // 9 SUPERPULEMET
193 (name: 'FLAME'; w: 32; h: 32; count: 0{11}), // 10 FLAMETHROWER
194 (name: ''; w: 0; h: 0; count: 0), // 11
195 (name: ''; w: 0; h: 0; count: 0), // 12
196 (name: ''; w: 0; h: 0; count: 0), // 13
197 (name: ''; w: 0; h: 0; count: 0), // 14
198 (name: ''; w: 0; h: 0; count: 0), // 15
199 (name: ''; w: 0; h: 0; count: 0), // 16
200 (name: ''; w: 0; h: 0; count: 0), // 17
201 (name: ''; w: 0; h: 0; count: 0), // 18
202 (name: ''; w: 0; h: 0; count: 0), // 19
203 (name: ''; w: 0; h: 0; count: 0), // 20 ZOMPY_PISTOL
204 (name: 'BIMPFIRE'; w: 16; h: 16; count: 2), // 21 IMP_FIRE
205 (name: 'BBSPFIRE'; w: 16; h: 16; count: 2), // 22 BSP_FIRE
206 (name: 'BCACOFIRE'; w: 16; h: 16; count: 2), // 23 CACO_FIRE
207 (name: 'BBARONFIRE'; w: 64; h: 16; count: 2), // 24 BARON_FIRE
208 (name: 'BMANCUBFIRE'; w: 64; h: 32; count: 2), // 25 MANCUB_FIRE
209 (name: 'BSKELFIRE'; w: 64; h: 64; count: 2) // 26 SKEL_FIRE
210 );
211
212 {$IFDEF ENABLE_SHELLS}
213 ShellAnim: array [0..SHELL_LAST] of record
214 name: AnsiString;
215 dx, dy: Integer;
216 end = (
217 (name: 'EBULLET'; dx: 2; dy: 1), // 0 SHELL_BULLET
218 (name: 'ESHELL'; dx: 4; dy: 2), // 1 SHELL_SHELL
219 (name: 'ESHELL'; dx: 4; dy: 2) // 2 SHELL_DBLSHELL
220 );
221 {$ENDIF}
222
223 type
224 TBinHeapPanelDrawCmp = class
225 public
226 class function less (const a, b: TPanel): Boolean; inline;
227 end;
228
229 TBinHeapPanelDraw = specialize TBinaryHeapBase<TPanel, TBinHeapPanelDrawCmp>;
230
231 TMonsterAnims = array [0..ANIM_LAST, TDirection] of TGLMultiTexture;
232
233 var
234 SkyTexture: TGLTexture;
235 RenTextures: array of record
236 spec: LongInt;
237 tex: TGLMultiTexture;
238 end;
239 Items: array [0..ITEM_LAST] of record
240 tex: TGLMultiTexture;
241 anim: TAnimState;
242 end;
243 MonTextures: array [0..MONSTER_MAN] of TMonsterAnims;
244 WeapTextures: array [0..WP_LAST, 0..W_POS_LAST, 0..W_ACT_LAST] of TGLTexture;
245 ShotTextures: array [0..WEAPON_LAST] of TGLMultiTexture;
246 FlagTextures: array [0..FLAG_LAST] of TGLMultiTexture;
247 PunchTextures: array [Boolean, 0..2] of TGLMultiTexture; // [berserk, center/up/down]
248 VileFire: TGLMultiTexture;
249 Models: array of record
250 anim: array [TDirection, 0..A_LAST] of record
251 base, mask: TGLMultiTexture;
252 end;
253 {$IFDEF ENABLE_GIBS}
254 gibs: record
255 base, mask: TGLTextureArray;
256 rect: TRectArray;
257 end;
258 {$ENDIF}
259 end;
260
261 StubShotAnim: TAnimState; // TODO remove this hack
262 FlagAnim: TAnimState;
263
264 {$IFDEF ENABLE_SHELLS}
265 ShellTextures: array [0..SHELL_LAST] of TGLTexture;
266 {$ENDIF}
267 {$IFDEF ENABLE_GFX}
268 GFXTextures: array [0..R_GFX_LAST] of TGLMultiTexture;
269 gfxlist: array of record
270 typ: Byte;
271 alpha: Byte;
272 x, y: Integer;
273 oldX, oldY: Integer;
274 anim: TAnimState;
275 end = nil;
276 {$ENDIF}
277
278 plist: TBinHeapPanelDraw = nil;
279
280 class function TBinHeapPanelDrawCmp.less (const a, b: TPanel): Boolean; inline;
281 begin
282 if a.tag < b.tag then begin result := true; exit; end;
283 if a.tag > b.tag then begin result := false; exit; end;
284 result := a.arrIdx < b.arrIdx;
285 end;
286
287 procedure r_Map_Initialize;
288 begin
289 StubShotAnim := TAnimState.Create(true, 1, 1);
290 FlagAnim := TAnimState.Create(true, 8, 5);
291 plist := TBinHeapPanelDraw.Create();
292 end;
293
294 procedure r_Map_Finalize;
295 begin
296 plist.Free;
297 StubShotAnim.Invalidate;
298 end;
299
300 procedure r_Map_FreeModel (i: Integer);
301 var a: Integer; d: TDirection;
302 begin
303 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
304 begin
305 for a := A_STAND to A_LAST do
306 begin
307 if Models[i].anim[d, a].base <> nil then
308 Models[i].anim[d, a].base.Free;
309 if Models[i].anim[d, a].mask <> nil then
310 Models[i].anim[d, a].mask.Free;
311 Models[i].anim[d, a].base := nil;
312 Models[i].anim[d, a].mask := nil;
313 end;
314 end;
315 {$IFDEF ENABLE_GIBS}
316 if Models[i].gibs.base <> nil then
317 for a := 0 to High(Models[i].gibs.base) do
318 Models[i].gibs.base[a].Free;
319 if Models[i].gibs.mask <> nil then
320 for a := 0 to High(Models[i].gibs.mask) do
321 Models[i].gibs.mask[a].Free;
322 Models[i].gibs.base := nil;
323 Models[i].gibs.mask := nil;
324 Models[i].gibs.rect := nil;
325 {$ENDIF}
326 end;
327
328 procedure r_Map_LoadModel (i: Integer);
329 var prefix: AnsiString; a: Integer; d: TDirection; m: ^TPlayerModelInfo;
330 begin
331 ASSERT(i < Length(Models));
332 ASSERT(i < Length(PlayerModelsArray));
333 r_Map_FreeModel(i);
334 m := @PlayerModelsArray[i];
335 prefix := m.FileName + ':TEXTURES/';
336 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
337 begin
338 for a := A_STAND to A_LAST do
339 begin
340 Models[i].anim[d, a].base := nil;
341 Models[i].anim[d, a].mask := nil;
342 if m.anim[d, a].resource <> '' then
343 Models[i].anim[d, a].base := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].resource, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
344 if m.anim[d, a].mask <> '' then
345 Models[i].anim[d, a].mask := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].mask, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
346 end
347 end;
348 {$IFDEF ENABLE_GIBS}
349 Models[i].gibs.base := nil;
350 Models[i].gibs.mask := nil;
351 Models[i].gibs.rect := nil;
352 if m.GibsCount > 0 then
353 begin
354 SetLength(Models[i].gibs.base, m.GibsCount);
355 SetLength(Models[i].gibs.mask, m.GibsCount);
356 SetLength(Models[i].gibs.rect, m.GibsCount);
357 for a := 0 to m.GibsCount - 1 do
358 Models[i].gibs.rect[a] := DefaultGibSize;
359 if r_Textures_LoadStreamFromFile(prefix + m.GibsResource, 32, 32, m.GibsCount, Models[i].gibs.base, Models[i].gibs.rect) then
360 begin
361 if r_Textures_LoadStreamFromFile(prefix + m.GibsMask, 32, 32, m.GibsCount, Models[i].gibs.mask, nil) then
362 begin
363 // ok
364 end;
365 end;
366 for a := 0 to m.GibsCount - 1 do
367 e_logwritefln('model %s gib %s: %sx%s:%sx%s', [i, a, Models[i].gibs.rect[a].x, Models[i].gibs.rect[a].y, Models[i].gibs.rect[a].width, Models[i].gibs.rect[a].height]);
368 end;
369 {$ENDIF}
370 end;
371
372 procedure r_Map_LoadMonsterAnim (m, a: Integer; d: TDirection);
373 const dir: array [TDirection] of AnsiString = ('_L', '');
374 var w, h, count: Integer;
375 begin
376 count := MONSTER_ANIMTABLE[m].AnimCount[a];
377 if count > 0 then
378 begin
379 w := MTABLE[m].w;
380 h := MTABLE[m].h;
381 if (m = MONSTER_SOUL) and (a = ANIM_DIE) then
382 begin
383 // special case
384 w := 128;
385 h := 128;
386 end;
387 MonTextures[m, a, d] := r_Textures_LoadMultiFromFileAndInfo(
388 GameWAD + ':MTEXTURES/' + MONSTERTABLE[m].name + '_' + ANIMTABLE[a].name + dir[d],
389 w,
390 h,
391 count,
392 False,
393 False
394 );
395 end
396 else
397 MonTextures[m, a, d] := nil;
398 end;
399
400 procedure r_Map_Load;
401 const
402 WeapName: array [0..WP_LAST] of AnsiString = ('', 'CSAW', 'HGUN', 'SG', 'SSG', 'MGUN', 'RKT', 'PLZ', 'BFG', 'SPL', 'FLM');
403 WeapPos: array [0..W_POS_LAST] of AnsiString = ('', '_UP', '_DN');
404 WeapAct: array [0..W_ACT_LAST] of AnsiString = ('', '_FIRE');
405 PunchName: array [Boolean] of AnsiString = ('PUNCH', 'PUNCHB');
406 var
407 i, j, k: Integer; d: TDirection; b: Boolean;
408 begin
409 // --------- items --------- //
410 for i := 0 to ITEM_LAST do
411 begin
412 if ItemAnim[i].n > 0 then
413 begin
414 Items[i].tex := r_Textures_LoadMultiFromFileAndInfo(
415 GameWAD + ':TEXTURES/' + ItemAnim[i].name,
416 ItemAnim[i].w,
417 ItemAnim[i].h,
418 ItemAnim[i].n,
419 ItemAnim[i].b,
420 false
421 );
422 k := IfThen(ItemAnim[i].b, ItemAnim[i].n * 2 - 2, ItemAnim[i].n);
423 Items[i].anim := TAnimState.Create(True, ItemAnim[i].d, k);
424 end;
425 end;
426 // --------- monsters --------- //
427 for i := MONSTER_DEMON to MONSTER_MAN do
428 for j := 0 to ANIM_LAST do
429 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
430 r_Map_LoadMonsterAnim(i, j, d);
431 VileFire := r_Textures_LoadMultiFromFileAndInfo(GameWAD + ':TEXTURES/FIRE', 64, 128, 8, False, False);
432 // --------- player models --------- //
433 if PlayerModelsArray <> nil then
434 begin
435 SetLength(Models, Length(PlayerModelsArray));
436 for i := 0 to High(PlayerModelsArray) do
437 r_Map_LoadModel(i);
438 end;
439 // --------- player weapons --------- //
440 for i := 1 to WP_LAST do
441 for j := 0 to W_POS_LAST do
442 for k := 0 to W_ACT_LAST do
443 WeapTextures[i, j, k] := r_Textures_LoadFromFile(GameWAD + ':WEAPONS\' + WeapName[i] + WeapPos[j] + WeapAct[k]);
444 // --------- gfx animations --------- //
445 {$IFDEF ENABLE_GFX}
446 for i := 1 to R_GFX_LAST do
447 if GFXAnim[i].count > 0 then
448 GFXTextures[i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/' + GFXAnim[i].name, GFXAnim[i].w, GFXAnim[i].h, GFXAnim[i].count, GFXAnim[i].back);
449 {$ENDIF}
450 // --------- shots --------- //
451 for i := 0 to WEAPON_LAST do
452 if ShotAnim[i].count > 0 then
453 ShotTextures[i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/' + ShotAnim[i].name, ShotAnim[i].w, ShotAnim[i].h, ShotAnim[i].count, false);
454 // --------- flags --------- //
455 FlagTextures[FLAG_NONE] := nil;
456 FlagTextures[FLAG_RED] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGRED', 64, 64, 5, false);
457 FlagTextures[FLAG_BLUE] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGBLUE', 64, 64, 5, false);
458 // FlagTextures[FLAG_DOM] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGDOM', 64, 64, 8, false);
459 // --------- shells --------- //
460 {$IFDEF ENABLE_SHELLS}
461 for i := 0 to SHELL_LAST do
462 ShellTextures[i] := r_Textures_LoadFromFile(GameWad + ':TEXTURES/' + ShellAnim[i].name);
463 {$ENDIF}
464 // --------- punch --------- //
465 for b := false to true do
466 begin
467 for i := 0 to 2 do
468 PunchTextures[b, i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':WEAPONS/' + PunchName[b] + WeapPos[i], 64, 64, 4, false);
469 end;
470 end;
471
472 procedure r_Map_Free;
473 var i, j, k: Integer; d: TDirection; b: Boolean;
474 begin
475 for b := false to true do
476 begin
477 for i := 0 to 2 do
478 begin
479 if PunchTextures[b, i] <> nil then
480 PunchTextures[b, i].Free;
481 PunchTextures[b, i] := nil;
482 end;
483 end;
484 {$IFDEF ENABLE_SHELLS}
485 for i := 0 to SHELL_LAST do
486 begin
487 if ShellTextures[i] <> nil then
488 ShellTextures[i].Free;
489 ShellTextures[i] := nil;
490 end;
491 {$ENDIF}
492 for i := 0 to FLAG_LAST do
493 begin
494 if FlagTextures[i] <> nil then
495 FlagTextures[i].Free;
496 FlagTextures[i] := nil;
497 end;
498 for i := 0 to WEAPON_LAST do
499 begin
500 if ShotTextures[i] <> nil then
501 ShotTextures[i].Free;
502 ShotTextures[i] := nil;
503 end;
504 {$IFDEF ENABLE_GFX}
505 gfxlist := nil;
506 for i := 0 to R_GFX_LAST do
507 begin
508 if GFXTextures[i] <> nil then
509 GFXTextures[i].Free;
510 GFXTextures[i] := nil;
511 end;
512 {$ENDIF}
513 for i := 1 to WP_LAST do
514 begin
515 for j := 0 to W_POS_LAST do
516 begin
517 for k := 0 to W_ACT_LAST do
518 begin
519 if WeapTextures[i, j, k] <> nil then
520 WeapTextures[i, j, k].Free;
521 WeapTextures[i, j, k] := nil;
522 end;
523 end;
524 end;
525 if Models <> nil then
526 for i := 0 to High(Models) do
527 r_Map_FreeModel(i);
528 for i := MONSTER_DEMON to MONSTER_MAN do
529 begin
530 for j := 0 to ANIM_LAST do
531 begin
532 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
533 begin
534 if MonTextures[i, j, d] <> nil then
535 MonTextures[i, j, d].Free;
536 MonTextures[i, j, d] := nil;
537 end;
538 end;
539 end;
540 for i := 0 to ITEM_LAST do
541 begin
542 if Items[i].tex <> nil then
543 begin
544 Items[i].tex.Free;
545 Items[i].tex := nil;
546 end;
547 Items[i].anim.Invalidate;
548 end;
549 end;
550
551 procedure r_Map_LoadTextures;
552 var i, n: Integer;
553 begin
554 if Textures <> nil then
555 begin
556 n := Length(Textures);
557 SetLength(RenTextures, n);
558 for i := 0 to n - 1 do
559 begin
560 RenTextures[i].tex := nil;
561 case Textures[i].TextureName of
562 TEXTURE_NAME_WATER: RenTextures[i].spec := TEXTURE_SPECIAL_WATER;
563 TEXTURE_NAME_ACID1: RenTextures[i].spec := TEXTURE_SPECIAL_ACID1;
564 TEXTURE_NAME_ACID2: RenTextures[i].spec := TEXTURE_SPECIAL_ACID2;
565 else
566 RenTextures[i].spec := 0;
567 RenTextures[i].tex := r_Textures_LoadMultiFromFile(Textures[i].FullName);
568 if RenTextures[i].tex = nil then
569 e_LogWritefln('r_Map_LoadTextures: failed to load texture: %s', [Textures[i].FullName]);
570 end;
571 end;
572 end;
573 if gMapInfo.SkyFullName <> '' then
574 SkyTexture := r_Textures_LoadFromFile(gMapInfo.SkyFullName);
575 plist.Clear;
576 end;
577
578 procedure r_Map_FreeTextures;
579 var i: Integer;
580 begin
581 plist.Clear;
582 if SkyTexture <> nil then
583 SkyTexture.Free;
584 SkyTexture := nil;
585 if RenTextures <> nil then
586 for i := 0 to High(RenTextures) do
587 if RenTextures[i].tex <> nil then
588 RenTextures[i].tex.Free;
589 RenTextures := nil;
590 end;
591
592 procedure r_Map_DrawPanel (p: TPanel);
593 var Texture: Integer; t: TGLMultiTexture;
594 begin
595 ASSERT(p <> nil);
596 if p.FCurTexture >= 0 then
597 begin
598 Texture := p.TextureIDs[p.FCurTexture].Texture;
599 t := RenTextures[Texture].tex;
600
601 if (RenTextures[Texture].spec = 0) or (t <> nil) then
602 begin
603 if t = nil then
604 r_Draw_TextureRepeat(nil, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
605 else if p.TextureIDs[p.FCurTexture].AnTex.IsValid() then
606 r_Draw_MultiTextureRepeat(t, p.TextureIDs[p.FCurTexture].AnTex, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
607 else
608 r_Draw_TextureRepeat(t.GetTexture(0), p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
609 end;
610
611 if t = nil then
612 begin
613 case RenTextures[Texture].spec of
614 TEXTURE_SPECIAL_WATER: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 0, 255, 255);
615 TEXTURE_SPECIAL_ACID1: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 230, 0, 255);
616 TEXTURE_SPECIAL_ACID2: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 230, 0, 0, 255);
617 end
618 end
619 end
620 end;
621
622 procedure r_Map_DrawPanelType (panelTyp: DWORD);
623 var tagMask, i: Integer; p: TPanel;
624 begin
625 i := 0;
626 tagMask := PanelTypeToTag(panelTyp);
627 while plist.count > 0 do
628 begin
629 p := TPanel(plist.Front());
630 if (p.tag and tagMask) = 0 then
631 break;
632 r_Map_DrawPanel(p);
633 Inc(i);
634 plist.PopFront
635 end;
636 end;
637
638 procedure r_Map_DrawItems (x, y, w, h: Integer; drop: Boolean);
639 var i, fX, fY: Integer; it: PItem; t: TGLMultiTexture;
640 begin
641 if ggItems <> nil then
642 begin
643 for i := 0 to High(ggItems) do
644 begin
645 it := @ggItems[i];
646 if it.used and it.alive and (it.dropped = drop) and (it.ItemType > ITEM_NONE) and (it.ItemType <= ITEM_LAST) then
647 begin
648 t := Items[it.ItemType].tex;
649 if g_Collide(it.obj.x, it.obj.y, t.width, t.height, x, y, w, h) then
650 begin
651 it.obj.Lerp(gLerpFactor, fX, fY);
652 r_Draw_MultiTextureRepeat(t, Items[it.ItemType].anim, fX, fY, t.width, t.height, false, 255, 255, 255, 255, false);
653 end;
654 end;
655 end;
656 end;
657 // TODO draw g_debug_frames
658 end;
659
660 function r_Map_GetMonsterTexture (m, a: Integer; d: TDirection; out t: TGLMultiTexture; out dx, dy: Integer; out flip: Boolean): Boolean;
661 // var c: Integer;
662 begin
663 t := nil; dx := 0; dy := 0; flip := false;
664 result := MonTextures[m, a, d] <> nil;
665 if result = false then
666 begin
667 flip := true;
668 if d = TDirection.D_RIGHT then d := TDirection.D_LEFT else d := TDirection.D_RIGHT;
669 result := MonTextures[m, a, d] <> nil;
670 end;
671 if result = true then
672 begin
673 t := MonTextures[m, a, d];
674 if d = TDirection.D_LEFT then
675 begin
676 dx := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].X;
677 dy := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].Y;
678 end
679 else
680 begin
681 dx := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].X;
682 dy := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].Y;
683 end;
684 if flip then
685 begin
686 // c := (MONSTERTABLE[MonsterType].Rect.X - dx) + MONSTERTABLE[MonsterType].Rect.Width;
687 // dx := MTABLE[m].width - c - MONSTERTABLE[MonsterType].Rect.X;
688 dx := -dx;
689 end;
690 end;
691 end;
692
693 procedure r_Map_DrawMonsterAttack (constref mon: TMonster);
694 var o: TObj;
695 begin
696 if VileFire <> nil then
697 if (mon.MonsterType = MONSTER_VILE) and (mon.MonsterState = MONSTATE_SHOOT) then
698 if mon.VileFireAnim.IsValid() and GetPos(mon.MonsterTargetUID, @o) then
699 r_Draw_MultiTextureRepeat(VileFire, mon.VileFireAnim, o.x + o.rect.x + (o.rect.width div 2) - VILEFIRE_DX, o.y + o.rect.y + o.rect.height - VILEFIRE_DY, VileFire.width, VileFire.height, False, 255, 255, 255, 255, false);
700 end;
701
702 procedure r_Map_DrawMonster (constref mon: TMonster);
703 var m, a, fX, fY, dx, dy: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture;
704 begin
705 m := mon.MonsterType;
706 a := mon.MonsterAnim;
707 d := mon.GameDirection;
708
709 mon.obj.Lerp(gLerpFactor, fX, fY);
710
711 if r_Map_GetMonsterTexture(m, a, d, t, dx, dy, flip) then
712 r_Draw_MultiTextureRepeat(t, mon.DirAnim[a, d], fX + dx, fY + dy, t.width, t.height, flip, 255, 255, 255, 255, false);
713
714 // TODO draw g_debug_frames
715 end;
716
717 procedure r_Map_DrawMonsters (x, y, w, h: Integer);
718 var i: Integer; m: TMonster;
719 begin
720 if gMonsters <> nil then
721 begin
722 for i := 0 to High(gMonsters) do
723 begin
724 m := gMonsters[i];
725 if m <> nil then
726 begin
727 r_Map_DrawMonsterAttack(m);
728 // TODO select from grid
729 if g_Collide(m.obj.x + m.obj.rect.x, m.obj.y + m.obj.rect.y, m.obj.rect.width, m.obj.rect.height, x, y, w, h) then
730 r_Map_DrawMonster(m);
731 end;
732 end;
733 end;
734 end;
735
736 function r_Map_GetPlayerModelTex (i: Integer; var a: Integer; var d: TDirection; out flip: Boolean): Boolean;
737 begin
738 flip := false;
739 result := Models[i].anim[d, a].base <> nil;
740 if result = false then
741 begin
742 flip := true;
743 if d = TDirection.D_LEFT then d := TDirection.D_RIGHT else d := TDirection.D_LEFT;
744 result := Models[i].anim[d, a].base <> nil;
745 end;
746 end;
747
748 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer);
749 var a, pos, act, xx, yy, angle: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture; tex: TGLTexture; c: TRGB;
750 begin
751 a := pm.CurrentAnimation;
752 d := pm.Direction;
753
754 (* draw flag*)
755 t := FlagTextures[pm.Flag];
756 if (t <> nil) and not (a in [A_DIE1, A_DIE2]) then
757 begin
758 flip := d = TDirection.D_RIGHT;
759 angle := PlayerModelsArray[pm.id].FlagAngle;
760 xx := PlayerModelsArray[pm.id].FlagPoint.X;
761 yy := PlayerModelsArray[pm.id].FlagPoint.Y;
762 r_Draw_MultiTextureRepeatRotate(
763 t,
764 FlagAnim,
765 x + IfThen(flip, 2 * FLAG_BASEPOINT.X - xx + 1, xx - 1) - FLAG_BASEPOINT.X,
766 y + yy - FLAG_BASEPOINT.Y + 1,
767 t.width,
768 t.height,
769 flip,
770 255, 255, 255, 255, false,
771 IfThen(flip, 64 - FLAG_BASEPOINT.X, FLAG_BASEPOINT.X),
772 FLAG_BASEPOINT.Y,
773 IfThen(flip, angle, -angle)
774 );
775 end;
776
777 (* draw weapon *)
778 if PlayerModelsArray[pm.id].HaveWeapon and not (a in [A_DIE1, A_DIE2, A_PAIN]) then
779 begin
780 case a of
781 A_SEEUP, A_ATTACKUP: pos := W_POS_UP;
782 A_SEEDOWN, A_ATTACKDOWN: pos := W_POS_DOWN;
783 else pos := W_POS_NORMAL;
784 end;
785 if (a in [A_ATTACK, A_ATTACKUP, A_ATTACKDOWN]) or pm.GetFire() then
786 act := W_ACT_FIRE
787 else
788 act := W_ACT_NORMAL;
789 tex := WeapTextures[pm.CurrentWeapon, pos, act];
790 if tex <> nil then
791 begin
792 xx := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].X;
793 yy := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].Y;
794 r_Draw_Texture(
795 tex,
796 x + xx,
797 y + yy,
798 tex.width,
799 tex.height,
800 d = TDirection.D_LEFT,
801 255, 255, 255, 255, false
802 );
803 end;
804 end;
805
806 (* draw body *)
807 if r_Map_GetPlayerModelTex(pm.id, a, d, flip) then
808 begin
809 t := Models[pm.id].anim[d, a].base;
810 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip, 255, 255, 255, 255, false);
811 t := Models[pm.id].anim[d, a].mask;
812 if t <> nil then
813 begin
814 c := pm.Color;
815 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip, c.r, c.g, c.b, 255, false);
816 end;
817 end;
818 end;
819
820 procedure r_Map_DrawPlayer (p: TPlayer);
821 var fX, fY, fSlope, ax, ay: Integer; b, flip: Boolean; t: TGLMultiTexture;
822 begin
823 if p.alive then
824 begin
825 fX := p.obj.x; fY := p.obj.y;
826 // TODO fix lerp
827 //p.obj.Lerp(gLerpFactor, fX, fY);
828 fSlope := nlerp(p.SlopeOld, p.obj.slopeUpLeft, gLerpFactor);
829 if p.PunchAnim.IsValid() and p.PunchAnim.enabled then
830 begin
831 b := R_BERSERK in p.FRulez;
832 if p.FKeys[KEY_DOWN].pressed then
833 t := PunchTextures[b, 2]
834 else if p.FKeys[KEY_UP].pressed then
835 t := PunchTextures[b, 1]
836 else
837 t := PunchTextures[b, 0];
838 if t <> nil then
839 begin
840 flip := p.Direction = TDirection.D_LEFT;
841 ax := IfThen(flip, 15 - p.Obj.Rect.X, p.Obj.Rect.X - 15); // ???
842 ay := p.Obj.Rect.Y - 11;
843 r_Draw_MultiTextureRepeat(t, p.PunchAnim, fx + ax, fy + fSlope + ay, t.width, t.height, flip, 255, 255, 255, 255, false)
844 end;
845 end;
846 // TODO invul pentagram
847 // TODO draw it with transparency
848 r_Map_DrawPlayerModel(p.Model, fX, fY + fSlope);
849 end;
850 // TODO draw g_debug_frames
851 // TODO draw chat bubble
852 // TODO draw aim
853 end;
854
855 procedure r_Map_DrawPlayers (x, y, w, h: Integer);
856 var i: Integer;
857 begin
858 if gPlayers <> nil then
859 for i := 0 to High(gPlayers) do
860 if gPlayers[i] <> nil then
861 r_Map_DrawPlayer(gPlayers[i]);
862 end;
863
864 {$IFDEF ENABLE_GIBS}
865 function r_Map_GetGibSize (m, i: Integer): TRectWH;
866 begin
867 result := Models[m].gibs.rect[i];
868 end;
869
870 procedure r_Map_DrawGibs (x, y, w, h: Integer);
871 var i, fx, fy, m, id, rx, ry, ra: Integer; p: PObj; t: TGLTexture;
872 begin
873 if gGibs <> nil then
874 begin
875 for i := 0 to High(gGibs) do
876 begin
877 if gGibs[i].alive then
878 begin
879 p := @gGibs[i].Obj;
880 if g_Obj_Collide(x, y, w, h, p) then
881 begin
882 p.Lerp(gLerpFactor, fx, fy);
883 id := gGibs[i].GibID;
884 m := gGibs[i].ModelID;
885 t := Models[m].gibs.base[id];
886 if t <> nil then
887 begin
888 rx := p.Rect.X + p.Rect.Width div 2;
889 ry := p.Rect.Y + p.Rect.Height div 2;
890 ra := gGibs[i].RAngle;
891 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, 255, 255, 255, 255, false, rx, ry, ra);
892 t := Models[m].gibs.mask[id];
893 if t <> nil then
894 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, gGibs[i].Color.R, gGibs[i].Color.G, gGibs[i].Color.B, 255, false, rx, ry, ra);
895 // r_Draw_TextureRepeatRotate(nil, fx + p.Rect.X, fy + p.Rect.Y, p.Rect.Width, p.Rect.Height, false, 255, 255, 255, 255, false, p.Rect.Width div 2, p.Rect.Height div 2, ra);
896 end;
897 end;
898 end;
899 end;
900 end;
901 // TODO draw g_debug_frames
902 end;
903 {$ENDIF}
904
905 {$IFDEF ENABLE_CORPSES}
906 procedure r_Map_DrawCorpses (x, y, w, h: Integer);
907 var i, fX, fY: Integer; p: TCorpse;
908 begin
909 if gCorpses <> nil then
910 begin
911 for i := 0 to High(gCorpses) do
912 begin
913 p := gCorpses[i];
914 if (p <> nil) and (p.state <> CORPSE_STATE_REMOVEME) and (p.model <> nil) then
915 begin
916 p.obj.Lerp(gLerpFactor, fX, fY);
917 r_Map_DrawPlayerModel(p.model, fX, fY);
918 end;
919 end;
920 end;
921 // TODO draw g_debug_frames
922 end;
923 {$ENDIF}
924
925 {$IFDEF ENABLE_GFX}
926 function r_Map_GetGFXID (): Integer;
927 var i: Integer;
928 begin
929 i := 0;
930 if gfxlist <> nil then
931 begin
932 while (i < Length(gfxlist)) and gfxlist[i].anim.IsValid() do
933 Inc(i);
934 if i >= Length(gfxlist) then
935 SetLength(gfxlist, Length(gfxlist) + 1)
936 end
937 else
938 SetLength(gfxlist, 1);
939 gfxlist[i].typ := R_GFX_NONE;
940 gfxlist[i].anim.Invalidate;
941 result := i
942 end;
943
944 procedure r_Map_NewGFX (typ, x, y: Integer);
945 var i: Integer;
946 begin
947 if gpart_dbg_enabled and (typ > 0) and (typ <= R_GFX_LAST) then
948 begin
949 i := r_Map_GetGFXID();
950 if i >= 0 then
951 begin
952 gfxlist[i].typ := typ;
953 gfxlist[i].x := x;
954 gfxlist[i].y := y;
955 gfxlist[i].oldX := x;
956 gfxlist[i].oldY := y;
957 gfxlist[i].anim := TAnimState.Create(false, GFXAnim[typ].speed + Random(GFXAnim[typ].rspeed), GFXAnim[typ].count);
958 gfxlist[i].anim.Reset();
959 gfxlist[i].anim.Enable();
960 end;
961 end;
962 end;
963
964 procedure r_Map_UpdateGFX;
965 var i: Integer;
966 begin
967 if gfxlist <> nil then
968 begin
969 for i := 0 to High(gfxlist) do
970 begin
971 if gfxlist[i].anim.IsValid() then
972 begin
973 gfxlist[i].oldX := gfxlist[i].x;
974 gfxlist[i].oldY := gfxlist[i].y;
975 case gfxlist[i].typ of
976 R_GFX_FLAME, R_GFX_SMOKE:
977 begin
978 if Random(3) = 0 then
979 gfxlist[i].x := gfxlist[i].x - 1 + Random(3);
980 if Random(2) = 0 then
981 gfxlist[i].y := gfxlist[i].y - Random(2);
982 end;
983 end;
984 if gfxlist[i].anim.played then
985 gfxlist[i].anim.Invalidate
986 else
987 gfxlist[i].anim.Update
988 end;
989 end;
990 end;
991 end;
992
993 procedure r_Map_DrawParticles (x, y, w, h: Integer);
994 var i, fx, fy: Integer;
995 begin
996 if gpart_dbg_enabled and (Particles <> nil) then
997 begin
998 glDisable(GL_TEXTURE_2D);
999 if (g_dbg_scale < 0.6) then
1000 glPointSize(1)
1001 else if (g_dbg_scale > 1.3) then
1002 glPointSize(g_dbg_scale + 1)
1003 else
1004 glPointSize(2);
1005 glDisable(GL_POINT_SMOOTH);
1006 glEnable(GL_BLEND);
1007 glBlendFunc(GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA);
1008
1009 glBegin(GL_POINTS);
1010 for i := 0 to High(Particles) do
1011 begin
1012 if Particles[i].alive then
1013 begin
1014 fx := nlerp(Particles[i].oldX, Particles[i].x, gLerpFactor);
1015 fy := nlerp(Particles[i].oldY, Particles[i].y, gLerpFactor);
1016 glColor4ub(Particles[i].red, Particles[i].green, Particles[i].blue, Particles[i].alpha);
1017 glVertex2f(fx, fy);
1018 end;
1019 end;
1020 glEnd;
1021
1022 glDisable(GL_BLEND);
1023 end;
1024 end;
1025
1026 procedure r_Map_DrawGFX (x, y, w, h: Integer);
1027 var i, fx, fy, typ: Integer; tex: TGLMultiTexture;
1028 begin
1029 if gfxlist <> nil then
1030 begin
1031 for i := 0 to High(gfxlist) do
1032 begin
1033 if gfxlist[i].anim.IsValid() then
1034 begin
1035 typ := gfxlist[i].typ;
1036 tex := GFXTextures[typ];
1037 if tex <> nil then
1038 begin
1039 fx := nlerp(gfxlist[i].oldX, gfxlist[i].x, gLerpFactor);
1040 fy := nlerp(gfxlist[i].oldY, gfxlist[i].y, gLerpFactor);
1041 r_Draw_MultiTextureRepeat(tex, gfxlist[i].anim, fx, fy, tex.width, tex.height, false, 255, 255, 255, 255 - GFXAnim[typ].alpha, false);
1042 end;
1043 end;
1044 end;
1045 end;
1046 end;
1047 {$ENDIF}
1048
1049 procedure r_Map_DrawShots (x, y, w, h: Integer);
1050 var i, a, fX, fY, pX, pY, typ: Integer; tex: TGLMultiTexture; anim: ^TAnimState;
1051 begin
1052 if Shots <> nil then
1053 begin
1054 for i := 0 to High(Shots) do
1055 begin
1056 typ := Shots[i].ShotType;
1057 if typ <> 0 then
1058 begin
1059 tex := ShotTextures[typ];
1060 if tex <> nil then
1061 begin
1062 a := 0;
1063 case typ of
1064 WEAPON_ROCKETLAUNCHER, WEAPON_BARON_FIRE, WEAPON_MANCUB_FIRE, WEAPON_SKEL_FIRE:
1065 a := -GetAngle2(Shots[i].Obj.Vel.X, Shots[i].Obj.Vel.Y)
1066 end;
1067 Shots[i].Obj.Lerp(gLerpFactor, fX, fY);
1068 pX := Shots[i].Obj.Rect.Width div 2;
1069 pY := Shots[i].Obj.Rect.Height div 2;
1070 // TODO fix this hack
1071 if Shots[i].Animation.IsValid() then anim := @Shots[i].Animation else anim := @StubShotAnim;
1072 r_Draw_MultiTextureRepeatRotate(tex, anim^, fX, fY, tex.width, tex.height, false, 255, 255, 255, 255, false, pX, pY, a);
1073 end;
1074 end;
1075 end;
1076 end;
1077 // TODO draw g_debug_frames
1078 end;
1079
1080 procedure r_Map_DrawFlags (x, y, w, h: Integer);
1081 var i, dx, fx, fy: Integer; flip: Boolean; tex: TGLMultiTexture;
1082 begin
1083 if gGameSettings.GameMode = GM_CTF then
1084 begin
1085 for i := FLAG_RED to FLAG_BLUE do
1086 begin
1087 if not (gFlags[i].state in [FLAG_STATE_NONE, FLAG_STATE_CAPTURED]) then
1088 begin
1089 gFlags[i].Obj.Lerp(gLerpFactor, fx, fy);
1090 flip := gFlags[i].Direction = TDirection.D_LEFT;
1091 if flip then dx := -1 else dx := +1;
1092 tex := FlagTextures[i];
1093 r_Draw_MultiTextureRepeat(tex, FlagAnim, fx + dx, fy + 1, tex.width, tex.height, flip, 255, 255, 255, 255, false)
1094 end;
1095 end;
1096 end;
1097 // TODO g_debug_frames
1098 end;
1099
1100 {$IFDEF ENABLE_SHELLS}
1101 procedure r_Map_DrawShells (x, y, w, h: Integer);
1102 var i, fx, fy, typ: Integer; t: TGLTexture; p: PObj;
1103 begin
1104 if gShells <> nil then
1105 begin
1106 for i := 0 to High(gShells) do
1107 begin
1108 if gShells[i].alive then
1109 begin
1110 typ := gShells[i].SType;
1111 if typ <= SHELL_LAST then
1112 begin
1113 p := @gShells[i].Obj;
1114 if g_Obj_Collide(x, y, w, h, p) then
1115 begin
1116 t := ShellTextures[typ];
1117 if t <> nil then
1118 begin
1119 p.Lerp(gLerpFactor, fx, fy);
1120 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, 255, 255, 255, 255, false, ShellAnim[typ].dx, ShellAnim[typ].dy, gShells[i].RAngle);
1121 end;
1122 end;
1123 end;
1124 end;
1125 end;
1126 end;
1127 end;
1128 {$ENDIF}
1129
1130 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer);
1131 var iter: TPanelGrid.Iter; p: PPanel; cx, cy, xx, yy, ww, hh: Integer;
1132 begin
1133 cx := camx - w div 2;
1134 cy := camy - h div 2;
1135 xx := x + cx;
1136 yy := y + cy;
1137 ww := w;
1138 hh := h;
1139
1140 // TODO lock camera at map bounds
1141
1142 // TODO draw paralax
1143 if SkyTexture <> nil then
1144 r_Draw_Texture(SkyTexture, x, y, w, h, false, 255, 255, 255, 255, false);
1145
1146 plist.Clear;
1147 iter := mapGrid.ForEachInAABB(xx, yy, ww, hh, GridDrawableMask);
1148 for p in iter do
1149 if ((p^.tag and GridTagDoor) <> 0) = p^.door then
1150 plist.Insert(p^);
1151 iter.Release;
1152
1153 glPushMatrix;
1154 glTranslatef(-cx, -cy, 0);
1155 r_Map_DrawPanelType(PANEL_BACK);
1156 r_Map_DrawPanelType(PANEL_STEP);
1157 r_Map_DrawItems(xx, yy, ww, hh, false);
1158 r_Map_DrawShots(xx, yy, ww, hh);
1159 {$IFDEF ENABLE_SHELLS}
1160 r_Map_DrawShells(xx, yy, ww, hh);
1161 {$ENDIF}
1162 r_Map_DrawPlayers(xx, yy, ww, hh);
1163 {$IFDEF ENABLE_GIBS}
1164 r_Map_DrawGibs(xx, yy, ww, hh);
1165 {$ENDIF}
1166 {$IFDEF ENABLE_CORPSES}
1167 r_Map_DrawCorpses(xx, yy, ww, hh);
1168 {$ENDIF}
1169 r_Map_DrawPanelType(PANEL_WALL);
1170 r_Map_DrawMonsters(xx, yy, ww, hh);
1171 r_Map_DrawItems(xx, yy, ww, hh, true);
1172 r_Map_DrawPanelType(PANEL_CLOSEDOOR);
1173 {$IFDEF ENABLE_GFX}
1174 r_Map_DrawParticles(xx, yy, ww, hh);
1175 r_Map_DrawGFX(xx, yy, ww, hh);
1176 {$ENDIF}
1177 r_Map_DrawFlags(xx, yy, ww, hh);
1178 r_Map_DrawPanelType(PANEL_ACID1);
1179 r_Map_DrawPanelType(PANEL_ACID2);
1180 r_Map_DrawPanelType(PANEL_WATER);
1181 r_Map_DrawPanelType(PANEL_FORE);
1182 // TODO draw monsters health bar
1183 // TODO draw players health bar
1184 // TODO draw players indicators
1185 glPopMatrix;
1186
1187 // TODO draw player pain
1188 // TODO draw player pickup
1189 // TODO draw player invul
1190 // TODO draw minimap
1191 // TODO draw g_debug_player
1192 end;
1193
1194 procedure r_Map_Update;
1195 var i: Integer;
1196 begin
1197 for i := 0 to ITEM_LAST do
1198 Items[i].anim.Update;
1199 r_Map_UpdateGFX;
1200 FlagAnim.Update;
1201 end;
1202
1203 end.
[MIRROR] a port of Doom 2D Forever to FPC/SDL
[25/02/2024 19:55:35]
DEADSOFTWARE 2012-2024