DEADSOFTWARE

GIT / REPO / FRED-BOY
Projects / d2df-sdl.git / blob


695195d3548efc03e6bc15818aeabd39007fd4bf
[d2df-sdl.git] / src / game / renders / opengl / r_map.pas
1 (* Copyright (C) Doom 2D: Forever Developers
2 *
3 * This program is free software: you can redistribute it and/or modify
4 * it under the terms of the GNU General Public License as published by
5 * the Free Software Foundation, version 3 of the License ONLY.
6 *
7 * This program is distributed in the hope that it will be useful,
8 * but WITHOUT ANY WARRANTY; without even the implied warranty of
9 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
10 * GNU General Public License for more details.
11 *
12 * You should have received a copy of the GNU General Public License
13 * along with this program. If not, see <http://www.gnu.org/licenses/>.
14 *)
15 {$INCLUDE ../../../shared/a_modes.inc}
16 unit r_map;
17
18 interface
19
20 procedure r_Map_Initialize;
21 procedure r_Map_Finalize;
22
23 procedure r_Map_Load;
24 procedure r_Map_Free;
25
26 procedure r_Map_LoadTextures;
27 procedure r_Map_FreeTextures;
28
29 procedure r_Map_Update;
30
31 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer);
32
33 implementation
34
35 uses
36 {$IFDEF USE_GLES1}
37 GLES11,
38 {$ELSE}
39 GL, GLEXT,
40 {$ENDIF}
41 e_log,
42 binheap, MAPDEF, utils,
43 g_options, g_textures, g_basic, g_base, g_phys,
44 g_game, g_map, g_panel, g_items, g_monsters, g_playermodel, g_player, g_weapons,
45 {$IFDEF ENABLE_CORPSES}
46 g_corpses,
47 {$ENDIF}
48 r_textures, r_draw
49 ;
50
51 const
52 MTABLE: array [0..MONSTER_MAN] of record
53 w, h: Integer;
54 end = (
55 (w: 64; h: 64), // NONE
56 (w: 64; h: 64), // DEMON
57 (w: 64; h: 64), // IMP
58 (w: 64; h: 64), // ZOMBY
59 (w: 64; h: 64), // SERG
60 (w: 128; h: 128), // CYBER
61 (w: 64; h: 64), // CGUN
62 (w: 128; h: 128), // BARON
63 (w: 128; h: 128), // KNIGHT
64 (w: 128; h: 128), // CACO
65 (w: 64; h: 64), // SOUL (DIE is 128x128, see load code)
66 (w: 128; h: 128), // PAIN
67 (w: 256; h: 128), // SPIDER
68 (w: 128; h: 64), // BSP
69 (w: 128; h: 128), // MANCUB
70 (w: 128; h: 128), // SKEL
71 (w: 128; h: 128), // VILE
72 (w: 32; h: 32), // FISH
73 (w: 64; h: 64), // BARREL
74 (w: 128; h: 128), // ROBO
75 (w: 64; h: 64) // MAN
76 );
77 VILEFIRE_DX = 32;
78 VILEFIRE_DY = 128;
79
80 type
81 TBinHeapPanelDrawCmp = class
82 public
83 class function less (const a, b: TPanel): Boolean; inline;
84 end;
85
86 TBinHeapPanelDraw = specialize TBinaryHeapBase<TPanel, TBinHeapPanelDrawCmp>;
87
88 TMonsterAnims = array [0..ANIM_LAST, TDirection] of TGLMultiTexture;
89
90 var
91 SkyTexture: TGLTexture;
92 RenTextures: array of record
93 spec: LongInt;
94 tex: TGLMultiTexture;
95 end;
96 Items: array [0..ITEM_MAX] of record
97 tex: TGLMultiTexture;
98 anim: TAnimState;
99 end;
100 MonTextures: array [0..MONSTER_MAN] of TMonsterAnims;
101 WeapTextures: array [0..WP_LAST, 0..W_POS_LAST, 0..W_ACT_LAST] of TGLTexture;
102 VileFire: TGLMultiTexture;
103 Models: array of record
104 anim: array [TDirection, 0..A_LAST] of record
105 base, mask: TGLMultiTexture;
106 end;
107 (*
108 {$IFDEF ENABLE_GIBS}
109 gibs: array of record
110 base, mask: TGLTexture;
111 rect: TRectWH;
112 end;
113 {$ENDIF}
114 *)
115 end;
116
117 plist: TBinHeapPanelDraw = nil;
118
119 class function TBinHeapPanelDrawCmp.less (const a, b: TPanel): Boolean; inline;
120 begin
121 if a.tag < b.tag then begin result := true; exit; end;
122 if a.tag > b.tag then begin result := false; exit; end;
123 result := a.arrIdx < b.arrIdx;
124 end;
125
126 procedure r_Map_Initialize;
127 begin
128 plist := TBinHeapPanelDraw.Create();
129 end;
130
131 procedure r_Map_Finalize;
132 begin
133 plist.Free
134 end;
135
136 procedure r_Map_LoadModel (i: Integer);
137 var prefix: AnsiString; a: Integer; d: TDirection; m: ^TPlayerModelInfo;
138 begin
139 m := @PlayerModelsArray[i];
140 prefix := m.FileName + ':TEXTURES/';
141 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
142 begin
143 for a := A_STAND to A_LAST do
144 begin
145 Models[i].anim[d, a].base := nil;
146 Models[i].anim[d, a].mask := nil;
147 if m.anim[d, a].resource <> '' then
148 Models[i].anim[d, a].base := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].resource, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
149 if m.anim[d, a].mask <> '' then
150 Models[i].anim[d, a].mask := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].mask, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
151 end
152 end;
153 (*
154 {$IFDEF ENABLE_GIBS}
155 Models[i].gibs := nil;
156 if m.GibsCount > 0 then
157 begin
158 SetLength(Models[i].gibs, m.GibsCount);
159 end;
160 {$ENDIF}
161 *)
162 end;
163
164
165 procedure r_Map_Load;
166 const
167 WeapName: array [0..WP_LAST] of AnsiString = ('', 'CSAW', 'HGUN', 'SG', 'SSG', 'MGUN', 'RKT', 'PLZ', 'BFG', 'SPL', 'FLM');
168 WeapPos: array [0..W_POS_LAST] of AnsiString = ('', '_UP', '_DN');
169 WeapAct: array [0..W_ACT_LAST] of AnsiString = ('', '_FIRE');
170 var
171 i, j, k: Integer; d: TDirection;
172
173 procedure LoadItem (i: Integer; const name: AnsiString; w, h, delay, count: Integer; backanim: Boolean);
174 begin
175 ASSERT(i >= 0);
176 ASSERT(i <= ITEM_MAX);
177 Items[i].tex := r_Textures_LoadMultiFromFileAndInfo(GameWAD + ':TEXTURES/' + name, w, h, count, backanim, false);
178 if backanim then count := count * 2 - 2;
179 Items[i].anim := TAnimState.Create(True, delay, count);
180 ASSERT(Items[i].tex <> NIL);
181 end;
182
183 procedure LoadMonster (m, a: Integer; d: TDirection);
184 const
185 dir: array [TDirection] of AnsiString = ('_L', '');
186 var
187 w, h, count: Integer;
188 begin
189 count := MONSTER_ANIMTABLE[m].AnimCount[a];
190 if count > 0 then
191 begin
192 w := MTABLE[m].w;
193 h := MTABLE[m].h;
194 if (m = MONSTER_SOUL) and (a = ANIM_DIE) then
195 begin
196 // special case
197 w := 128;
198 h := 128;
199 end;
200 MonTextures[m, a, d] := r_Textures_LoadMultiFromFileAndInfo(
201 GameWAD + ':MTEXTURES/' + MONSTERTABLE[m].name + '_' + ANIMTABLE[a].name + dir[d],
202 w,
203 h,
204 count,
205 False,
206 False
207 )
208 end
209 else
210 MonTextures[m, a, d] := nil
211 end;
212
213 begin
214 // --------- items --------- //
215 // i name w h d n backanim
216 LoadItem(ITEM_NONE, 'NOTEXTURE', 16, 16, 0, 1, False);
217 LoadItem(ITEM_MEDKIT_SMALL, 'MED1', 16, 16, 0, 1, False);
218 LoadItem(ITEM_MEDKIT_LARGE, 'MED2', 32, 32, 0, 1, False);
219 LoadItem(ITEM_MEDKIT_BLACK, 'BMED', 32, 32, 0, 1, False);
220 LoadItem(ITEM_ARMOR_GREEN, 'ARMORGREEN', 32, 16, 20, 3, True);
221 LoadItem(ITEM_ARMOR_BLUE, 'ARMORBLUE', 32, 16, 20, 3, True);
222 LoadItem(ITEM_SPHERE_BLUE, 'SBLUE', 32, 32, 15, 4, True);
223 LoadItem(ITEM_SPHERE_WHITE, 'SWHITE', 32, 32, 20, 4, True);
224 LoadItem(ITEM_SUIT, 'SUIT', 32, 64, 0, 1, False);
225 LoadItem(ITEM_OXYGEN, 'OXYGEN', 16, 32, 0, 1, False);
226 LoadItem(ITEM_INVUL, 'INVUL', 32, 32, 20, 4, True);
227 LoadItem(ITEM_WEAPON_SAW, 'SAW', 64, 32, 0, 1, False);
228 LoadItem(ITEM_WEAPON_SHOTGUN1, 'SHOTGUN1', 64, 16, 0, 1, False);
229 LoadItem(ITEM_WEAPON_SHOTGUN2, 'SHOTGUN2', 64, 16, 0, 1, False);
230 LoadItem(ITEM_WEAPON_CHAINGUN, 'MGUN', 64, 16, 0, 1, False);
231 LoadItem(ITEM_WEAPON_ROCKETLAUNCHER, 'RLAUNCHER', 64, 16, 0, 1, False);
232 LoadItem(ITEM_WEAPON_PLASMA, 'PGUN', 64, 16, 0, 1, False);
233 LoadItem(ITEM_WEAPON_BFG, 'BFG', 64, 64, 0, 1, False);
234 LoadItem(ITEM_WEAPON_SUPERPULEMET, 'SPULEMET', 64, 16, 0, 1, False);
235 LoadItem(ITEM_AMMO_BULLETS, 'CLIP', 16, 16, 0, 1, False);
236 LoadItem(ITEM_AMMO_BULLETS_BOX, 'AMMO', 32, 16, 0, 1, False);
237 LoadItem(ITEM_AMMO_SHELLS, 'SHELL1', 16, 8, 0, 1, False);
238 LoadItem(ITEM_AMMO_SHELLS_BOX, 'SHELL2', 32, 16, 0, 1, False);
239 LoadItem(ITEM_AMMO_ROCKET, 'ROCKET', 16, 32, 0, 1, False);
240 LoadItem(ITEM_AMMO_ROCKET_BOX, 'ROCKETS', 64, 32, 0, 1, False);
241 LoadItem(ITEM_AMMO_CELL, 'CELL', 16, 16, 0, 1, False);
242 LoadItem(ITEM_AMMO_CELL_BIG, 'CELL2', 32, 32, 0, 1, False);
243 LoadItem(ITEM_AMMO_BACKPACK, 'BPACK', 32, 32, 0, 1, False);
244 LoadItem(ITEM_KEY_RED, 'KEYR', 16, 16, 0, 1, False);
245 LoadItem(ITEM_KEY_GREEN, 'KEYG', 16, 16, 0, 1, False);
246 LoadItem(ITEM_KEY_BLUE, 'KEYB', 16, 16, 0, 1, False);
247 LoadItem(ITEM_WEAPON_KASTET, 'KASTET', 64, 32, 0, 1, False);
248 LoadItem(ITEM_WEAPON_PISTOL, 'PISTOL', 64, 16, 0, 1, False);
249 LoadItem(ITEM_BOTTLE, 'BOTTLE', 16, 32, 20, 4, True);
250 LoadItem(ITEM_HELMET, 'HELMET', 16, 16, 20, 4, True);
251 LoadItem(ITEM_JETPACK, 'JETPACK', 32, 32, 15, 3, True);
252 LoadItem(ITEM_INVIS, 'INVIS', 32, 32, 20, 4, True);
253 LoadItem(ITEM_WEAPON_FLAMETHROWER, 'FLAMETHROWER', 64, 32, 0, 1, False);
254 LoadItem(ITEM_AMMO_FUELCAN, 'FUELCAN', 16, 32, 0, 1, False);
255 // fill with NOTEXURE forgotten item
256 for i := ITEM_AMMO_FUELCAN + 1 to ITEM_MAX do
257 LoadItem(i,'NOTEXTURE', 16, 16, 0, 1, False);
258 // --------- monsters --------- //
259 for i := MONSTER_DEMON to MONSTER_MAN do
260 for j := 0 to ANIM_LAST do
261 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
262 LoadMonster(i, j, d);
263 VileFire := r_Textures_LoadMultiFromFileAndInfo(GameWAD + ':TEXTURES/FIRE', 64, 128, 8, False, False);
264 // --------- player models --------- //
265 if PlayerModelsArray <> nil then
266 begin
267 SetLength(Models, Length(PlayerModelsArray));
268 for i := 0 to High(PlayerModelsArray) do
269 r_Map_LoadModel(i);
270 end;
271 // --------- player weapons --------- //
272 for i := 1 to WP_LAST do
273 for j := 0 to W_POS_LAST do
274 for k := 0 to W_ACT_LAST do
275 WeapTextures[i, j, k] := r_Textures_LoadFromFile(GameWAD + ':WEAPONS\' + WeapName[i] + WeapPos[j] + WeapAct[k]);
276 end;
277
278 procedure r_Map_Free;
279 var i, j, k: Integer; d: TDirection;
280 begin
281 for i := 1 to WP_LAST do
282 begin
283 for j := 0 to W_POS_LAST do
284 begin
285 for k := 0 to W_ACT_LAST do
286 begin
287 if WeapTextures[i, j, k] <> nil then
288 WeapTextures[i, j, k].Free;
289 WeapTextures[i, j, k] := nil;
290 end;
291 end;
292 end;
293 for i := MONSTER_DEMON to MONSTER_MAN do
294 begin
295 for j := 0 to ANIM_LAST do
296 begin
297 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
298 begin
299 if MonTextures[i, j, d] <> nil then
300 MonTextures[i, j, d].Free;
301 MonTextures[i, j, d] := nil;
302 end;
303 end;
304 end;
305 for i := 0 to ITEM_MAX do
306 begin
307 if Items[i].tex <> nil then
308 begin
309 Items[i].tex.Free;
310 Items[i].tex := nil;
311 end;
312 Items[i].anim.Invalidate;
313 end;
314 end;
315
316 procedure r_Map_LoadTextures;
317 var i, n: Integer;
318 begin
319 if Textures <> nil then
320 begin
321 n := Length(Textures);
322 SetLength(RenTextures, n);
323 for i := 0 to n - 1 do
324 begin
325 RenTextures[i].tex := nil;
326 case Textures[i].TextureName of
327 TEXTURE_NAME_WATER: RenTextures[i].spec := TEXTURE_SPECIAL_WATER;
328 TEXTURE_NAME_ACID1: RenTextures[i].spec := TEXTURE_SPECIAL_ACID1;
329 TEXTURE_NAME_ACID2: RenTextures[i].spec := TEXTURE_SPECIAL_ACID2;
330 else
331 RenTextures[i].spec := 0;
332 RenTextures[i].tex := r_Textures_LoadMultiFromFile(Textures[i].FullName);
333 if RenTextures[i].tex = nil then
334 e_LogWritefln('r_Map_LoadTextures: failed to load texture: %s', [Textures[i].FullName]);
335 end;
336 end;
337 end;
338 if gMapInfo.SkyFullName <> '' then
339 SkyTexture := r_Textures_LoadFromFile(gMapInfo.SkyFullName);
340 plist.Clear;
341 end;
342
343 procedure r_Map_FreeTextures;
344 var i: Integer;
345 begin
346 plist.Clear;
347 if SkyTexture <> nil then
348 SkyTexture.Free;
349 SkyTexture := nil;
350 if RenTextures <> nil then
351 for i := 0 to High(RenTextures) do
352 if RenTextures[i].tex <> nil then
353 RenTextures[i].tex.Free;
354 RenTextures := nil;
355 end;
356
357 procedure r_Map_Update;
358 var i: Integer;
359 begin
360 for i := 0 to ITEM_MAX do
361 Items[i].anim.Update;
362 end;
363
364 procedure r_Map_DrawPanel (p: TPanel);
365 var Texture: Integer; t: TGLMultiTexture;
366 begin
367 ASSERT(p <> nil);
368 if p.FCurTexture >= 0 then
369 begin
370 Texture := p.TextureIDs[p.FCurTexture].Texture;
371 t := RenTextures[Texture].tex;
372
373 if (RenTextures[Texture].spec = 0) or (t <> nil) then
374 begin
375 // TODO set alpha and blending type
376 if t = nil then
377 r_Draw_TextureRepeat(nil, p.x, p.y, p.width, p.height, false)
378 else if p.TextureIDs[p.FCurTexture].AnTex.IsValid() then
379 r_Draw_MultiTextureRepeat(t, p.TextureIDs[p.FCurTexture].AnTex, p.x, p.y, p.width, p.height, false)
380 else
381 r_Draw_TextureRepeat(t.GetTexture(0), p.x, p.y, p.width, p.height, false)
382 end;
383
384 if t = nil then
385 begin
386 case RenTextures[Texture].spec of
387 TEXTURE_SPECIAL_WATER: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 0, 255, 255);
388 TEXTURE_SPECIAL_ACID1: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 230, 0, 255);
389 TEXTURE_SPECIAL_ACID2: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 230, 0, 0, 255);
390 end
391 end
392 end
393 end;
394
395 procedure r_Map_DrawPanelType (panelTyp: DWORD);
396 var tagMask, i: Integer; p: TPanel;
397 begin
398 i := 0;
399 tagMask := PanelTypeToTag(panelTyp);
400 while plist.count > 0 do
401 begin
402 p := TPanel(plist.Front());
403 if (p.tag and tagMask) = 0 then
404 break;
405 r_Map_DrawPanel(p);
406 Inc(i);
407 plist.PopFront
408 end;
409 end;
410
411 procedure r_Map_DrawItems (x, y, w, h: Integer; drop: Boolean);
412 var i, fX, fY: Integer; it: PItem; t: TGLMultiTexture;
413 begin
414 if ggItems <> nil then
415 begin
416 for i := 0 to High(ggItems) do
417 begin
418 it := @ggItems[i];
419 if it.used and it.alive and (it.dropped = drop) and (it.ItemType <> ITEM_NONE) then
420 begin
421 t := Items[it.ItemType].tex;
422 if g_Collide(it.obj.x, it.obj.y, t.width, t.height, x, y, w, h) then
423 begin
424 it.obj.Lerp(gLerpFactor, fX, fY);
425 r_Draw_MultiTextureRepeat(t, Items[it.ItemType].anim, fX, fY, t.width, t.height, false);
426 // if g_debug_frames then // TODO draw collision frame
427 end;
428 end;
429 end;
430 end;
431 end;
432
433 function r_Map_GetMonsterTexture (m, a: Integer; d: TDirection; out t: TGLMultiTexture; out dx, dy: Integer; out flip: Boolean): Boolean;
434 // var c: Integer;
435 begin
436 t := nil; dx := 0; dy := 0; flip := false;
437 result := MonTextures[m, a, d] <> nil;
438 if result = false then
439 begin
440 flip := true;
441 if d = TDirection.D_RIGHT then d := TDirection.D_LEFT else d := TDirection.D_RIGHT;
442 result := MonTextures[m, a, d] <> nil;
443 end;
444 if result = true then
445 begin
446 t := MonTextures[m, a, d];
447 if d = TDirection.D_LEFT then
448 begin
449 dx := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].X;
450 dy := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].Y;
451 end
452 else
453 begin
454 dx := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].X;
455 dy := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].Y;
456 end;
457 if flip then
458 begin
459 // c := (MONSTERTABLE[MonsterType].Rect.X - dx) + MONSTERTABLE[MonsterType].Rect.Width;
460 // dx := MTABLE[m].width - c - MONSTERTABLE[MonsterType].Rect.X;
461 dx := -dx;
462 end;
463 end;
464 end;
465
466 procedure r_Map_DrawMonsterAttack (constref mon: TMonster);
467 var o: TObj;
468 begin
469 if VileFire <> nil then
470 if (mon.MonsterType = MONSTER_VILE) and (mon.MonsterState = MONSTATE_SHOOT) then
471 if mon.VileFireAnim.IsValid() and GetPos(mon.MonsterTargetUID, @o) then
472 r_Draw_MultiTextureRepeat(VileFire, mon.VileFireAnim, o.x + o.rect.x + (o.rect.width div 2) - VILEFIRE_DX, o.y + o.rect.y + o.rect.height - VILEFIRE_DY, VileFire.width, VileFire.height, False);
473 end;
474
475 procedure r_Map_DrawMonster (constref mon: TMonster);
476 var m, a, fX, fY, dx, dy: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture;
477 begin
478 m := mon.MonsterType;
479 a := mon.MonsterAnim;
480 d := mon.GameDirection;
481
482 mon.obj.Lerp(gLerpFactor, fX, fY);
483
484 if r_Map_GetMonsterTexture(m, a, d, t, dx, dy, flip) then
485 r_Draw_MultiTextureRepeat(t, mon.DirAnim[a, d], fX + dx, fY + dy, t.width, t.height, flip);
486
487 {
488 if g_debug_frames
489 // TODO draw frame
490 }
491 end;
492
493 procedure r_Map_DrawMonsters (x, y, w, h: Integer);
494 var i: Integer; m: TMonster;
495 begin
496 if gMonsters <> nil then
497 begin
498 for i := 0 to High(gMonsters) do
499 begin
500 m := gMonsters[i];
501 if m <> nil then
502 begin
503 r_Map_DrawMonsterAttack(m);
504 // TODO select from grid
505 if g_Collide(m.obj.x + m.obj.rect.x, m.obj.y + m.obj.rect.y, m.obj.rect.width, m.obj.rect.height, x, y, w, h) then
506 r_Map_DrawMonster(m);
507 end;
508 end;
509 end;
510 end;
511
512 function r_Map_GetPlayerModelTex (i: Integer; var a: Integer; var d: TDirection; out flip: Boolean): Boolean;
513 begin
514 flip := false;
515 result := Models[i].anim[d, a].base <> nil;
516 if result = false then
517 begin
518 flip := true;
519 if d = TDirection.D_LEFT then d := TDirection.D_RIGHT else d := TDirection.D_LEFT;
520 result := Models[i].anim[d, a].base <> nil;
521 end;
522 end;
523
524 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer);
525 var a, pos, act, xx, yy: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture; tex: TGLTexture;
526 begin
527 a := pm.CurrentAnimation;
528 d := pm.Direction;
529 // TODO draw flag
530 if PlayerModelsArray[pm.id].HaveWeapon and not (a in [A_DIE1, A_DIE2, A_PAIN]) then
531 begin
532 case a of
533 A_SEEUP, A_ATTACKUP: pos := W_POS_UP;
534 A_SEEDOWN, A_ATTACKDOWN: pos := W_POS_DOWN;
535 else pos := W_POS_NORMAL;
536 end;
537 if (a in [A_ATTACK, A_ATTACKUP, A_ATTACKDOWN]) or pm.GetFire() then
538 act := W_ACT_FIRE
539 else
540 act := W_ACT_NORMAL;
541 tex := WeapTextures[pm.CurrentWeapon, pos, act];
542 if tex <> nil then
543 begin
544 xx := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].X;
545 yy := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].Y;
546 r_Draw_Texture(
547 tex,
548 x + xx,
549 y + yy,
550 tex.width,
551 tex.height,
552 d = TDirection.D_LEFT
553 );
554 end;
555 end;
556 if r_Map_GetPlayerModelTex(pm.id, a, d, flip) then
557 begin
558 t := Models[pm.id].anim[d, a].base;
559 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip);
560 // TODO colorize mask
561 t := Models[pm.id].anim[d, a].mask;
562 if t <> nil then
563 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip);
564 end;
565 end;
566
567 procedure r_Map_DrawPlayer (p: TPlayer);
568 var fX, fY, fSlope: Integer;
569 begin
570 if p.alive then
571 begin
572 fX := p.obj.x; fY := p.obj.y;
573 // TODO fix lerp
574 //p.obj.Lerp(gLerpFactor, fX, fY);
575 fSlope := nlerp(p.SlopeOld, p.obj.slopeUpLeft, gLerpFactor);
576 // TODO draw punch
577 // TODO invul pentagram
578 // TODO draw it with transparency
579 r_Map_DrawPlayerModel(p.Model, fX, fY + fSlope);
580 end;
581 // TODO draw g_debug_frames
582 // TODO draw chat bubble
583 // TODO draw aim
584 end;
585
586 procedure r_Map_DrawPlayers (x, y, w, h: Integer);
587 var i: Integer;
588 begin
589 // TODO draw only visible
590 if gPlayers <> nil then
591 for i := 0 to High(gPlayers) do
592 if gPlayers[i] <> nil then
593 r_Map_DrawPlayer(gPlayers[i]);
594 end;
595
596 {$IFDEF ENABLE_CORPSES}
597 procedure r_Map_DrawCorpses (x, y, w, h: Integer);
598 var i, fX, fY: Integer; p: TCorpse;
599 begin
600 if gCorpses <> nil then
601 begin
602 for i := 0 to High(gCorpses) do
603 begin
604 p := gCorpses[i];
605 if (p <> nil) and (p.state <> CORPSE_STATE_REMOVEME) and (p.model <> nil) then
606 begin
607 p.obj.Lerp(gLerpFactor, fX, fY);
608 r_Map_DrawPlayerModel(p.model, fX, fY);
609 end;
610 end;
611 end;
612 end;
613 {$ENDIF}
614
615 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer);
616 var iter: TPanelGrid.Iter; p: PPanel; cx, cy, xx, yy, ww, hh: Integer;
617 begin
618 cx := camx - w div 2;
619 cy := camy - h div 2;
620 xx := x + cx;
621 yy := y + cy;
622 ww := w;
623 hh := h;
624
625 if SkyTexture <> nil then
626 r_Draw_Texture(SkyTexture, x, y, w, h, false);
627
628 plist.Clear;
629 iter := mapGrid.ForEachInAABB(xx, yy, ww, hh, GridDrawableMask);
630 for p in iter do
631 if ((p^.tag and GridTagDoor) <> 0) = p^.door then
632 plist.Insert(p^);
633 iter.Release;
634
635 glPushMatrix;
636 glTranslatef(-cx, -cy, 0);
637 r_Map_DrawPanelType(PANEL_BACK);
638 r_Map_DrawPanelType(PANEL_STEP);
639 r_Map_DrawItems(xx, yy, ww, hh, false);
640 // TODO draw weapons
641 // TODO draw shells
642 r_Map_DrawPlayers(xx, yy, ww, hh);
643 // TODO draw gibs
644 {$IFDEF ENABLE_CORPSES}
645 r_Map_DrawCorpses(xx, yy, ww, hh);
646 {$ENDIF}
647 r_Map_DrawPanelType(PANEL_WALL);
648 r_Map_DrawMonsters(xx, yy, ww, hh);
649 r_Map_DrawItems(xx, yy, ww, hh, true);
650 r_Map_DrawPanelType(PANEL_CLOSEDOOR);
651 // TODO draw gfx
652 // TODO draw flags
653 r_Map_DrawPanelType(PANEL_ACID1);
654 r_Map_DrawPanelType(PANEL_ACID2);
655 r_Map_DrawPanelType(PANEL_WATER);
656 r_Map_DrawPanelType(PANEL_FORE);
657 glPopMatrix;
658 end;
659
660 end.
[MIRROR] a port of Doom 2D Forever to FPC/SDL
[25/02/2024 19:55:35]
DEADSOFTWARE 2012-2024