DEADSOFTWARE

GIT / REPO / FRED-BOY
Projects / d2df-sdl.git / blob


60f1ee62e66605d3bd441719db1e02cdc075ecaa
[d2df-sdl.git] / src / game / renders / opengl / r_map.pas
1 (* Copyright (C) Doom 2D: Forever Developers
2 *
3 * This program is free software: you can redistribute it and/or modify
4 * it under the terms of the GNU General Public License as published by
5 * the Free Software Foundation, version 3 of the License ONLY.
6 *
7 * This program is distributed in the hope that it will be useful,
8 * but WITHOUT ANY WARRANTY; without even the implied warranty of
9 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
10 * GNU General Public License for more details.
11 *
12 * You should have received a copy of the GNU General Public License
13 * along with this program. If not, see <http://www.gnu.org/licenses/>.
14 *)
15 {$INCLUDE ../../../shared/a_modes.inc}
16 unit r_map;
17
18 interface
19
20 procedure r_Map_Initialize;
21 procedure r_Map_Finalize;
22
23 procedure r_Map_Load;
24 procedure r_Map_Free;
25
26 procedure r_Map_LoadTextures;
27 procedure r_Map_FreeTextures;
28
29 procedure r_Map_Update;
30
31 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer);
32
33 implementation
34
35 uses
36 {$IFDEF USE_GLES1}
37 GLES11,
38 {$ELSE}
39 GL, GLEXT,
40 {$ENDIF}
41 e_log,
42 binheap, MAPDEF, utils,
43 g_options, g_textures, g_basic, g_base, g_phys,
44 g_game, g_map, g_panel, g_items, g_monsters, g_playermodel, g_player, g_weapons,
45 {$IFDEF ENABLE_CORPSES}
46 g_corpses,
47 {$ENDIF}
48 r_textures, r_draw
49 ;
50
51 const
52 MTABLE: array [0..MONSTER_MAN] of record
53 w, h: Integer;
54 end = (
55 (w: 64; h: 64), // NONE
56 (w: 64; h: 64), // DEMON
57 (w: 64; h: 64), // IMP
58 (w: 64; h: 64), // ZOMBY
59 (w: 64; h: 64), // SERG
60 (w: 128; h: 128), // CYBER
61 (w: 64; h: 64), // CGUN
62 (w: 128; h: 128), // BARON
63 (w: 128; h: 128), // KNIGHT
64 (w: 128; h: 128), // CACO
65 (w: 64; h: 64), // SOUL (DIE is 128x128, see load code)
66 (w: 128; h: 128), // PAIN
67 (w: 256; h: 128), // SPIDER
68 (w: 128; h: 64), // BSP
69 (w: 128; h: 128), // MANCUB
70 (w: 128; h: 128), // SKEL
71 (w: 128; h: 128), // VILE
72 (w: 32; h: 32), // FISH
73 (w: 64; h: 64), // BARREL
74 (w: 128; h: 128), // ROBO
75 (w: 64; h: 64) // MAN
76 );
77 VILEFIRE_DX = 32;
78 VILEFIRE_DY = 128;
79
80 type
81 TBinHeapPanelDrawCmp = class
82 public
83 class function less (const a, b: TPanel): Boolean; inline;
84 end;
85
86 TBinHeapPanelDraw = specialize TBinaryHeapBase<TPanel, TBinHeapPanelDrawCmp>;
87
88 TMonsterAnims = array [0..ANIM_LAST, TDirection] of TGLMultiTexture;
89
90 var
91 SkyTexture: TGLTexture;
92 RenTextures: array of record
93 spec: LongInt;
94 tex: TGLMultiTexture;
95 end;
96 Items: array [0..ITEM_MAX] of record
97 tex: TGLMultiTexture;
98 anim: TAnimState;
99 end;
100 MonTextures: array [0..MONSTER_MAN] of TMonsterAnims;
101 WeapTextures: array [0..WP_LAST, 0..W_POS_LAST, 0..W_ACT_LAST] of TGLTexture;
102 VileFire: TGLMultiTexture;
103 Models: array of record
104 anim: array [TDirection, 0..A_LAST] of record
105 base, mask: TGLMultiTexture;
106 end;
107 (*
108 {$IFDEF ENABLE_GIBS}
109 gibs: array of record
110 base, mask: TGLTexture;
111 rect: TRectWH;
112 end;
113 {$ENDIF}
114 *)
115 end;
116
117 plist: TBinHeapPanelDraw = nil;
118
119 class function TBinHeapPanelDrawCmp.less (const a, b: TPanel): Boolean; inline;
120 begin
121 if a.tag < b.tag then begin result := true; exit; end;
122 if a.tag > b.tag then begin result := false; exit; end;
123 result := a.arrIdx < b.arrIdx;
124 end;
125
126 procedure r_Map_Initialize;
127 begin
128 plist := TBinHeapPanelDraw.Create();
129 end;
130
131 procedure r_Map_Finalize;
132 begin
133 plist.Free
134 end;
135
136 procedure r_Map_LoadModel (i: Integer);
137 var prefix: AnsiString; a: Integer; d: TDirection; m: ^TPlayerModelInfo;
138 begin
139 m := @PlayerModelsArray[i];
140 prefix := m.FileName + ':TEXTURES/';
141 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
142 begin
143 for a := A_STAND to A_LAST do
144 begin
145 Models[i].anim[d, a].base := nil;
146 Models[i].anim[d, a].mask := nil;
147 if m.anim[d, a].resource <> '' then
148 Models[i].anim[d, a].base := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].resource, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
149 if m.anim[d, a].mask <> '' then
150 Models[i].anim[d, a].mask := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].mask, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
151 end
152 end;
153 (*
154 {$IFDEF ENABLE_GIBS}
155 Models[i].gibs := nil;
156 if m.GibsCount > 0 then
157 begin
158 SetLength(Models[i].gibs, m.GibsCount);
159 end;
160 {$ENDIF}
161 *)
162 end;
163
164
165 procedure r_Map_Load;
166 const
167 WeapName: array [0..WP_LAST] of AnsiString = ('', 'CSAW', 'HGUN', 'SG', 'SSG', 'MGUN', 'RKT', 'PLZ', 'BFG', 'SPL', 'FLM');
168 WeapPos: array [0..W_POS_LAST] of AnsiString = ('', '_UP', '_DN');
169 WeapAct: array [0..W_ACT_LAST] of AnsiString = ('', '_FIRE');
170 var
171 i, j, k: Integer; d: TDirection;
172
173 procedure LoadItem (i: Integer; const name: AnsiString; w, h, delay, count: Integer; backanim: Boolean);
174 begin
175 ASSERT(i >= 0);
176 ASSERT(i <= ITEM_MAX);
177 Items[i].tex := r_Textures_LoadMultiFromFileAndInfo(GameWAD + ':TEXTURES/' + name, w, h, count, backanim, false);
178 if backanim then count := count * 2 - 2;
179 Items[i].anim := TAnimState.Create(True, delay, count);
180 ASSERT(Items[i].tex <> NIL);
181 end;
182
183 procedure LoadMonster (m, a: Integer; d: TDirection);
184 const
185 dir: array [TDirection] of AnsiString = ('_L', '');
186 var
187 w, h, count: Integer;
188 begin
189 count := MONSTER_ANIMTABLE[m].AnimCount[a];
190 if count > 0 then
191 begin
192 w := MTABLE[m].w;
193 h := MTABLE[m].h;
194 if (m = MONSTER_SOUL) and (a = ANIM_DIE) then
195 begin
196 // special case
197 w := 128;
198 h := 128;
199 end;
200 MonTextures[m, a, d] := r_Textures_LoadMultiFromFileAndInfo(
201 GameWAD + ':MTEXTURES/' + MONSTERTABLE[m].name + '_' + ANIMTABLE[a].name + dir[d],
202 w,
203 h,
204 count,
205 False,
206 False
207 )
208 end
209 else
210 MonTextures[m, a, d] := nil
211 end;
212
213 begin
214 // --------- items --------- //
215 // i name w h d n backanim
216 LoadItem(ITEM_NONE, 'NOTEXTURE', 16, 16, 0, 1, False);
217 LoadItem(ITEM_MEDKIT_SMALL, 'MED1', 16, 16, 0, 1, False);
218 LoadItem(ITEM_MEDKIT_LARGE, 'MED2', 32, 32, 0, 1, False);
219 LoadItem(ITEM_MEDKIT_BLACK, 'BMED', 32, 32, 0, 1, False);
220 LoadItem(ITEM_ARMOR_GREEN, 'ARMORGREEN', 32, 16, 20, 3, True);
221 LoadItem(ITEM_ARMOR_BLUE, 'ARMORBLUE', 32, 16, 20, 3, True);
222 LoadItem(ITEM_SPHERE_BLUE, 'SBLUE', 32, 32, 15, 4, True);
223 LoadItem(ITEM_SPHERE_WHITE, 'SWHITE', 32, 32, 20, 4, True);
224 LoadItem(ITEM_SUIT, 'SUIT', 32, 64, 0, 1, False);
225 LoadItem(ITEM_OXYGEN, 'OXYGEN', 16, 32, 0, 1, False);
226 LoadItem(ITEM_INVUL, 'INVUL', 32, 32, 20, 4, True);
227 LoadItem(ITEM_WEAPON_SAW, 'SAW', 64, 32, 0, 1, False);
228 LoadItem(ITEM_WEAPON_SHOTGUN1, 'SHOTGUN1', 64, 16, 0, 1, False);
229 LoadItem(ITEM_WEAPON_SHOTGUN2, 'SHOTGUN2', 64, 16, 0, 1, False);
230 LoadItem(ITEM_WEAPON_CHAINGUN, 'MGUN', 64, 16, 0, 1, False);
231 LoadItem(ITEM_WEAPON_ROCKETLAUNCHER, 'RLAUNCHER', 64, 16, 0, 1, False);
232 LoadItem(ITEM_WEAPON_PLASMA, 'PGUN', 64, 16, 0, 1, False);
233 LoadItem(ITEM_WEAPON_BFG, 'BFG', 64, 64, 0, 1, False);
234 LoadItem(ITEM_WEAPON_SUPERPULEMET, 'SPULEMET', 64, 16, 0, 1, False);
235 LoadItem(ITEM_AMMO_BULLETS, 'CLIP', 16, 16, 0, 1, False);
236 LoadItem(ITEM_AMMO_BULLETS_BOX, 'AMMO', 32, 16, 0, 1, False);
237 LoadItem(ITEM_AMMO_SHELLS, 'SHELL1', 16, 8, 0, 1, False);
238 LoadItem(ITEM_AMMO_SHELLS_BOX, 'SHELL2', 32, 16, 0, 1, False);
239 LoadItem(ITEM_AMMO_ROCKET, 'ROCKET', 16, 32, 0, 1, False);
240 LoadItem(ITEM_AMMO_ROCKET_BOX, 'ROCKETS', 64, 32, 0, 1, False);
241 LoadItem(ITEM_AMMO_CELL, 'CELL', 16, 16, 0, 1, False);
242 LoadItem(ITEM_AMMO_CELL_BIG, 'CELL2', 32, 32, 0, 1, False);
243 LoadItem(ITEM_AMMO_BACKPACK, 'BPACK', 32, 32, 0, 1, False);
244 LoadItem(ITEM_KEY_RED, 'KEYR', 16, 16, 0, 1, False);
245 LoadItem(ITEM_KEY_GREEN, 'KEYG', 16, 16, 0, 1, False);
246 LoadItem(ITEM_KEY_BLUE, 'KEYB', 16, 16, 0, 1, False);
247 LoadItem(ITEM_WEAPON_KASTET, 'KASTET', 64, 32, 0, 1, False);
248 LoadItem(ITEM_WEAPON_PISTOL, 'PISTOL', 64, 16, 0, 1, False);
249 LoadItem(ITEM_BOTTLE, 'BOTTLE', 16, 32, 20, 4, True);
250 LoadItem(ITEM_HELMET, 'HELMET', 16, 16, 20, 4, True);
251 LoadItem(ITEM_JETPACK, 'JETPACK', 32, 32, 15, 3, True);
252 LoadItem(ITEM_INVIS, 'INVIS', 32, 32, 20, 4, True);
253 LoadItem(ITEM_WEAPON_FLAMETHROWER, 'FLAMETHROWER', 64, 32, 0, 1, False);
254 LoadItem(ITEM_AMMO_FUELCAN, 'FUELCAN', 16, 32, 0, 1, False);
255 // fill with NOTEXURE forgotten item
256 for i := ITEM_AMMO_FUELCAN + 1 to ITEM_MAX do
257 LoadItem(i,'NOTEXTURE', 16, 16, 0, 1, False);
258 // --------- monsters --------- //
259 for i := MONSTER_DEMON to MONSTER_MAN do
260 for j := 0 to ANIM_LAST do
261 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
262 LoadMonster(i, j, d);
263 VileFire := r_Textures_LoadMultiFromFileAndInfo(GameWAD + ':TEXTURES/FIRE', 64, 128, 8, False, False);
264 // --------- player models --------- //
265 if PlayerModelsArray <> nil then
266 begin
267 SetLength(Models, Length(PlayerModelsArray));
268 for i := 0 to High(PlayerModelsArray) do
269 r_Map_LoadModel(i);
270 end;
271 // --------- player weapons --------- //
272 for i := 1 to WP_LAST do
273 for j := 0 to W_POS_LAST do
274 for k := 0 to W_ACT_LAST do
275 WeapTextures[i, j, k] := r_Textures_LoadFromFile(GameWAD + ':WEAPONS\' + WeapName[i] + WeapPos[j] + WeapAct[k]);
276 end;
277
278 procedure r_Map_Free;
279 var i, j: Integer; d: TDirection;
280 begin
281 for i := MONSTER_DEMON to MONSTER_MAN do
282 begin
283 for j := 0 to ANIM_LAST do
284 begin
285 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
286 begin
287 if MonTextures[i, j, d] <> nil then
288 MonTextures[i, j, d].Free;
289 MonTextures[i, j, d] := nil;
290 end;
291 end;
292 end;
293 for i := 0 to ITEM_MAX do
294 begin
295 if Items[i].tex <> nil then
296 begin
297 Items[i].tex.Free;
298 Items[i].tex := nil;
299 end;
300 Items[i].anim.Invalidate;
301 end;
302 end;
303
304 procedure r_Map_LoadTextures;
305 var i, n: Integer;
306 begin
307 if Textures <> nil then
308 begin
309 n := Length(Textures);
310 SetLength(RenTextures, n);
311 for i := 0 to n - 1 do
312 begin
313 RenTextures[i].tex := nil;
314 case Textures[i].TextureName of
315 TEXTURE_NAME_WATER: RenTextures[i].spec := TEXTURE_SPECIAL_WATER;
316 TEXTURE_NAME_ACID1: RenTextures[i].spec := TEXTURE_SPECIAL_ACID1;
317 TEXTURE_NAME_ACID2: RenTextures[i].spec := TEXTURE_SPECIAL_ACID2;
318 else
319 RenTextures[i].spec := 0;
320 RenTextures[i].tex := r_Textures_LoadMultiFromFile(Textures[i].FullName);
321 if RenTextures[i].tex = nil then
322 e_LogWritefln('r_Map_LoadTextures: failed to load texture: %s', [Textures[i].FullName]);
323 end;
324 end;
325 end;
326 if gMapInfo.SkyFullName <> '' then
327 SkyTexture := r_Textures_LoadFromFile(gMapInfo.SkyFullName);
328 plist.Clear;
329 end;
330
331 procedure r_Map_FreeTextures;
332 var i: Integer;
333 begin
334 plist.Clear;
335 if SkyTexture <> nil then
336 SkyTexture.Free;
337 SkyTexture := nil;
338 if RenTextures <> nil then
339 for i := 0 to High(RenTextures) do
340 if RenTextures[i].tex <> nil then
341 RenTextures[i].tex.Free;
342 RenTextures := nil;
343 end;
344
345 procedure r_Map_Update;
346 var i: Integer;
347 begin
348 for i := 0 to ITEM_MAX do
349 Items[i].anim.Update;
350 end;
351
352 procedure r_Map_DrawPanel (p: TPanel);
353 var Texture: Integer; t: TGLMultiTexture;
354 begin
355 ASSERT(p <> nil);
356 if p.FCurTexture >= 0 then
357 begin
358 Texture := p.TextureIDs[p.FCurTexture].Texture;
359 t := RenTextures[Texture].tex;
360
361 if (RenTextures[Texture].spec = 0) or (t <> nil) then
362 begin
363 // TODO set alpha and blending type
364 if t = nil then
365 r_Draw_TextureRepeat(nil, p.x, p.y, p.width, p.height, false)
366 else if p.TextureIDs[p.FCurTexture].AnTex.IsValid() then
367 r_Draw_MultiTextureRepeat(t, p.TextureIDs[p.FCurTexture].AnTex, p.x, p.y, p.width, p.height, false)
368 else
369 r_Draw_TextureRepeat(t.GetTexture(0), p.x, p.y, p.width, p.height, false)
370 end;
371
372 if t = nil then
373 begin
374 case RenTextures[Texture].spec of
375 TEXTURE_SPECIAL_WATER: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 0, 255, 255);
376 TEXTURE_SPECIAL_ACID1: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 230, 0, 255);
377 TEXTURE_SPECIAL_ACID2: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 230, 0, 0, 255);
378 end
379 end
380 end
381 end;
382
383 procedure r_Map_DrawPanelType (panelTyp: DWORD);
384 var tagMask, i: Integer; p: TPanel;
385 begin
386 i := 0;
387 tagMask := PanelTypeToTag(panelTyp);
388 while plist.count > 0 do
389 begin
390 p := TPanel(plist.Front());
391 if (p.tag and tagMask) = 0 then
392 break;
393 r_Map_DrawPanel(p);
394 Inc(i);
395 plist.PopFront
396 end;
397 end;
398
399 procedure r_Map_DrawItems (x, y, w, h: Integer; drop: Boolean);
400 var i, fX, fY: Integer; it: PItem; t: TGLMultiTexture;
401 begin
402 if ggItems <> nil then
403 begin
404 for i := 0 to High(ggItems) do
405 begin
406 it := @ggItems[i];
407 if it.used and it.alive and (it.dropped = drop) and (it.ItemType <> ITEM_NONE) then
408 begin
409 t := Items[it.ItemType].tex;
410 if g_Collide(it.obj.x, it.obj.y, t.width, t.height, x, y, w, h) then
411 begin
412 it.obj.Lerp(gLerpFactor, fX, fY);
413 r_Draw_MultiTextureRepeat(t, Items[it.ItemType].anim, fX, fY, t.width, t.height, false);
414 // if g_debug_frames then // TODO draw collision frame
415 end;
416 end;
417 end;
418 end;
419 end;
420
421 function r_Map_GetMonsterTexture (m, a: Integer; d: TDirection; out t: TGLMultiTexture; out dx, dy: Integer; out flip: Boolean): Boolean;
422 // var c: Integer;
423 begin
424 t := nil; dx := 0; dy := 0; flip := false;
425 result := MonTextures[m, a, d] <> nil;
426 if result = false then
427 begin
428 flip := true;
429 if d = TDirection.D_RIGHT then d := TDirection.D_LEFT else d := TDirection.D_RIGHT;
430 result := MonTextures[m, a, d] <> nil;
431 end;
432 if result = true then
433 begin
434 t := MonTextures[m, a, d];
435 if d = TDirection.D_LEFT then
436 begin
437 dx := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].X;
438 dy := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].Y;
439 end
440 else
441 begin
442 dx := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].X;
443 dy := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].Y;
444 end;
445 if flip then
446 begin
447 // c := (MONSTERTABLE[MonsterType].Rect.X - dx) + MONSTERTABLE[MonsterType].Rect.Width;
448 // dx := MTABLE[m].width - c - MONSTERTABLE[MonsterType].Rect.X;
449 dx := -dx;
450 end;
451 end;
452 end;
453
454 procedure r_Map_DrawMonsterAttack (constref mon: TMonster);
455 var o: TObj;
456 begin
457 if VileFire <> nil then
458 if (mon.MonsterType = MONSTER_VILE) and (mon.MonsterState = MONSTATE_SHOOT) then
459 if mon.VileFireAnim.IsValid() and GetPos(mon.MonsterTargetUID, @o) then
460 r_Draw_MultiTextureRepeat(VileFire, mon.VileFireAnim, o.x + o.rect.x + (o.rect.width div 2) - VILEFIRE_DX, o.y + o.rect.y + o.rect.height - VILEFIRE_DY, VileFire.width, VileFire.height, False);
461 end;
462
463 procedure r_Map_DrawMonster (constref mon: TMonster);
464 var m, a, fX, fY, dx, dy: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture;
465 begin
466 m := mon.MonsterType;
467 a := mon.MonsterAnim;
468 d := mon.GameDirection;
469
470 mon.obj.Lerp(gLerpFactor, fX, fY);
471
472 if r_Map_GetMonsterTexture(m, a, d, t, dx, dy, flip) then
473 r_Draw_MultiTextureRepeat(t, mon.DirAnim[a, d], fX + dx, fY + dy, t.width, t.height, flip);
474
475 {
476 if g_debug_frames
477 // TODO draw frame
478 }
479 end;
480
481 procedure r_Map_DrawMonsters (x, y, w, h: Integer);
482 var i: Integer; m: TMonster;
483 begin
484 if gMonsters <> nil then
485 begin
486 for i := 0 to High(gMonsters) do
487 begin
488 m := gMonsters[i];
489 if m <> nil then
490 begin
491 r_Map_DrawMonsterAttack(m);
492 // TODO select from grid
493 if g_Collide(m.obj.x + m.obj.rect.x, m.obj.y + m.obj.rect.y, m.obj.rect.width, m.obj.rect.height, x, y, w, h) then
494 r_Map_DrawMonster(m);
495 end;
496 end;
497 end;
498 end;
499
500 function r_Map_GetPlayerModelTex (i: Integer; var a: Integer; var d: TDirection; out flip: Boolean): Boolean;
501 begin
502 flip := false;
503 result := Models[i].anim[d, a].base <> nil;
504 if result = false then
505 begin
506 flip := true;
507 if d = TDirection.D_LEFT then d := TDirection.D_RIGHT else d := TDirection.D_LEFT;
508 result := Models[i].anim[d, a].base <> nil;
509 end;
510 end;
511
512 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer);
513 var a, pos, act, xx, yy: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture; tex: TGLTexture;
514 begin
515 a := pm.CurrentAnimation;
516 d := pm.Direction;
517 // TODO draw flag
518 if PlayerModelsArray[pm.id].HaveWeapon and not (pm.CurrentAnimation in [A_DIE1, A_DIE2, A_PAIN]) then
519 begin
520 case a of
521 A_SEEUP, A_ATTACKUP: pos := W_POS_UP;
522 A_SEEDOWN, A_ATTACKDOWN: pos := W_POS_DOWN;
523 else pos := W_POS_NORMAL;
524 end;
525 if (a in [A_ATTACK, A_ATTACKUP, A_ATTACKDOWN]) or pm.GetFire() then
526 act := W_ACT_FIRE
527 else
528 act := W_ACT_NORMAL;
529 tex := WeapTextures[pm.CurrentWeapon, pos, act];
530 if tex <> nil then
531 begin
532 xx := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].X;
533 yy := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].Y;
534 r_Draw_Texture(
535 tex,
536 x + xx,
537 y + yy,
538 tex.width,
539 tex.height,
540 d = TDirection.D_LEFT
541 );
542 end;
543 end;
544 if r_Map_GetPlayerModelTex(pm.id, a, d, flip) then
545 begin
546 t := Models[pm.id].anim[d, a].base;
547 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip);
548 // TODO colorize mask
549 t := Models[pm.id].anim[d, a].mask;
550 if t <> nil then
551 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip);
552 end;
553 end;
554
555 procedure r_Map_DrawPlayer (p: TPlayer);
556 var fX, fY, fSlope: Integer;
557 begin
558 if p.alive then
559 begin
560 fX := p.obj.x; fY := p.obj.y;
561 // TODO fix lerp
562 //p.obj.Lerp(gLerpFactor, fX, fY);
563 fSlope := nlerp(p.SlopeOld, p.obj.slopeUpLeft, gLerpFactor);
564 // TODO draw punch
565 // TODO invul pentagram
566 // TODO draw it with transparency
567 r_Map_DrawPlayerModel(p.Model, fX, fY + fSlope);
568 end;
569 // TODO draw g_debug_frames
570 // TODO draw chat bubble
571 // TODO draw aim
572 end;
573
574 procedure r_Map_DrawPlayers (x, y, w, h: Integer);
575 var i: Integer;
576 begin
577 // TODO draw only visible
578 if gPlayers <> nil then
579 for i := 0 to High(gPlayers) do
580 if gPlayers[i] <> nil then
581 r_Map_DrawPlayer(gPlayers[i]);
582 end;
583
584 {$IFDEF ENABLE_CORPSES}
585 procedure r_Map_DrawCorpses (x, y, w, h: Integer);
586 var i, fX, fY: Integer; p: TCorpse;
587 begin
588 if gCorpses <> nil then
589 begin
590 for i := 0 to High(gCorpses) do
591 begin
592 p := gCorpses[i];
593 if (p <> nil) and (p.state <> CORPSE_STATE_REMOVEME) and (p.model <> nil) then
594 begin
595 p.obj.Lerp(gLerpFactor, fX, fY);
596 r_Map_DrawPlayerModel(p.model, fX, fY);
597 end;
598 end;
599 end;
600 end;
601 {$ENDIF}
602
603 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer);
604 var iter: TPanelGrid.Iter; p: PPanel; cx, cy, xx, yy, ww, hh: Integer;
605 begin
606 cx := camx - w div 2;
607 cy := camy - h div 2;
608 xx := x + cx;
609 yy := y + cy;
610 ww := w;
611 hh := h;
612
613 if SkyTexture <> nil then
614 r_Draw_Texture(SkyTexture, x, y, w, h, false);
615
616 plist.Clear;
617 iter := mapGrid.ForEachInAABB(xx, yy, ww, hh, GridDrawableMask);
618 for p in iter do
619 if ((p^.tag and GridTagDoor) <> 0) = p^.door then
620 plist.Insert(p^);
621 iter.Release;
622
623 glPushMatrix;
624 glTranslatef(-cx, -cy, 0);
625 r_Map_DrawPanelType(PANEL_BACK);
626 r_Map_DrawPanelType(PANEL_STEP);
627 r_Map_DrawItems(xx, yy, ww, hh, false);
628 // TODO draw weapons
629 // TODO draw shells
630 r_Map_DrawPlayers(xx, yy, ww, hh);
631 // TODO draw gibs
632 {$IFDEF ENABLE_CORPSES}
633 r_Map_DrawCorpses(xx, yy, ww, hh);
634 {$ENDIF}
635 r_Map_DrawPanelType(PANEL_WALL);
636 r_Map_DrawMonsters(xx, yy, ww, hh);
637 r_Map_DrawItems(xx, yy, ww, hh, true);
638 r_Map_DrawPanelType(PANEL_CLOSEDOOR);
639 // TODO draw gfx
640 // TODO draw flags
641 r_Map_DrawPanelType(PANEL_ACID1);
642 r_Map_DrawPanelType(PANEL_ACID2);
643 r_Map_DrawPanelType(PANEL_WATER);
644 r_Map_DrawPanelType(PANEL_FORE);
645 glPopMatrix;
646 end;
647
648 end.
[MIRROR] a port of Doom 2D Forever to FPC/SDL
[25/02/2024 19:55:35]
DEADSOFTWARE 2012-2024