DEADSOFTWARE

GIT / REPO / FRED-BOY
Projects / d2df-sdl.git / blob


2ca5f3ef193854bff9789eea2e4d9e37bc5528aa
[d2df-sdl.git] / src / game / renders / opengl / r_map.pas
1 (* Copyright (C) Doom 2D: Forever Developers
2 *
3 * This program is free software: you can redistribute it and/or modify
4 * it under the terms of the GNU General Public License as published by
5 * the Free Software Foundation, version 3 of the License ONLY.
6 *
7 * This program is distributed in the hope that it will be useful,
8 * but WITHOUT ANY WARRANTY; without even the implied warranty of
9 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
10 * GNU General Public License for more details.
11 *
12 * You should have received a copy of the GNU General Public License
13 * along with this program. If not, see <http://www.gnu.org/licenses/>.
14 *)
15 {$INCLUDE ../../../shared/a_modes.inc}
16 unit r_map;
17
18 interface
19
20 uses g_base; // TRectWH
21
22 procedure r_Map_Initialize;
23 procedure r_Map_Finalize;
24
25 procedure r_Map_Load;
26 procedure r_Map_Free;
27
28 procedure r_Map_LoadTextures;
29 procedure r_Map_FreeTextures;
30
31 {$IFDEF ENABLE_GFX}
32 procedure r_Map_NewGFX (typ, x, y: Integer);
33 {$ENDIF}
34 {$IFDEF ENABLE_GIBS}
35 function r_Map_GetGibSize (m, i: Integer): TRectWH;
36 {$ENDIF}
37
38 procedure r_Map_Update;
39
40 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer);
41
42 implementation
43
44 uses
45 Math,
46 {$IFDEF USE_GLES1}
47 GLES11,
48 {$ELSE}
49 GL, GLEXT,
50 {$ENDIF}
51 e_log,
52 binheap, MAPDEF, utils,
53 g_options, g_textures, g_basic, g_phys,
54 g_game, g_map, g_panel, g_items, g_monsters, g_playermodel, g_player, g_weapons,
55 {$IFDEF ENABLE_CORPSES}
56 g_corpses,
57 {$ENDIF}
58 {$IFDEF ENABLE_SHELLS}
59 g_shells,
60 {$ENDIF}
61 {$IFDEF ENABLE_GIBS}
62 g_gibs,
63 {$ENDIF}
64 {$IFDEF ENABLE_GFX}
65 g_gfx,
66 {$ENDIF}
67 r_textures, r_draw
68 ;
69
70 const
71 MTABLE: array [0..MONSTER_MAN] of record
72 w, h: Integer;
73 end = (
74 (w: 64; h: 64), // NONE
75 (w: 64; h: 64), // DEMON
76 (w: 64; h: 64), // IMP
77 (w: 64; h: 64), // ZOMBY
78 (w: 64; h: 64), // SERG
79 (w: 128; h: 128), // CYBER
80 (w: 64; h: 64), // CGUN
81 (w: 128; h: 128), // BARON
82 (w: 128; h: 128), // KNIGHT
83 (w: 128; h: 128), // CACO
84 (w: 64; h: 64), // SOUL (DIE is 128x128, see load code)
85 (w: 128; h: 128), // PAIN
86 (w: 256; h: 128), // SPIDER
87 (w: 128; h: 64), // BSP
88 (w: 128; h: 128), // MANCUB
89 (w: 128; h: 128), // SKEL
90 (w: 128; h: 128), // VILE
91 (w: 32; h: 32), // FISH
92 (w: 64; h: 64), // BARREL
93 (w: 128; h: 128), // ROBO
94 (w: 64; h: 64) // MAN
95 );
96 VILEFIRE_DX = 32;
97 VILEFIRE_DY = 128;
98
99 ItemAnim: array [0..ITEM_LAST] of record
100 name: AnsiString;
101 w, h: Integer;
102 d: Integer; // delay
103 n: Integer; // count
104 b: Boolean; // backanim
105 end = (
106 (name: ''; w: 0; h: 0; d: 0; n: 0; b: False),
107 (name: 'MED1'; w: 16; h: 16; d: 0; n: 1; b: False),
108 (name: 'MED2'; w: 32; h: 32; d: 0; n: 1; b: False),
109 (name: 'BMED'; w: 32; h: 32; d: 0; n: 1; b: False),
110 (name: 'ARMORGREEN'; w: 32; h: 16; d: 20; n: 3; b: True),
111 (name: 'ARMORBLUE'; w: 32; h: 16; d: 20; n: 3; b: True),
112 (name: 'SBLUE'; w: 32; h: 32; d: 15; n: 4; b: True),
113 (name: 'SWHITE'; w: 32; h: 32; d: 20; n: 4; b: True),
114 (name: 'SUIT'; w: 32; h: 64; d: 0; n: 1; b: False),
115 (name: 'OXYGEN'; w: 16; h: 32; d: 0; n: 1; b: False),
116 (name: 'INVUL'; w: 32; h: 32; d: 20; n: 4; b: True),
117 (name: 'SAW'; w: 64; h: 32; d: 0; n: 1; b: False),
118 (name: 'SHOTGUN1'; w: 64; h: 16; d: 0; n: 1; b: False),
119 (name: 'SHOTGUN2'; w: 64; h: 16; d: 0; n: 1; b: False),
120 (name: 'MGUN'; w: 64; h: 16; d: 0; n: 1; b: False),
121 (name: 'RLAUNCHER'; w: 64; h: 16; d: 0; n: 1; b: False),
122 (name: 'PGUN'; w: 64; h: 16; d: 0; n: 1; b: False),
123 (name: 'BFG'; w: 64; h: 64; d: 0; n: 1; b: False),
124 (name: 'SPULEMET'; w: 64; h: 16; d: 0; n: 1; b: False),
125 (name: 'CLIP'; w: 16; h: 16; d: 0; n: 1; b: False),
126 (name: 'AMMO'; w: 32; h: 16; d: 0; n: 1; b: False),
127 (name: 'SHELL1'; w: 16; h: 8; d: 0; n: 1; b: False),
128 (name: 'SHELL2'; w: 32; h: 16; d: 0; n: 1; b: False),
129 (name: 'ROCKET'; w: 16; h: 32; d: 0; n: 1; b: False),
130 (name: 'ROCKETS'; w: 64; h: 32; d: 0; n: 1; b: False),
131 (name: 'CELL'; w: 16; h: 16; d: 0; n: 1; b: False),
132 (name: 'CELL2'; w: 32; h: 32; d: 0; n: 1; b: False),
133 (name: 'BPACK'; w: 32; h: 32; d: 0; n: 1; b: False),
134 (name: 'KEYR'; w: 16; h: 16; d: 0; n: 1; b: False),
135 (name: 'KEYG'; w: 16; h: 16; d: 0; n: 1; b: False),
136 (name: 'KEYB'; w: 16; h: 16; d: 0; n: 1; b: False),
137 (name: 'KASTET'; w: 64; h: 32; d: 0; n: 1; b: False),
138 (name: 'PISTOL'; w: 64; h: 16; d: 0; n: 1; b: False),
139 (name: 'BOTTLE'; w: 16; h: 32; d: 20; n: 4; b: True),
140 (name: 'HELMET'; w: 16; h: 16; d: 20; n: 4; b: True),
141 (name: 'JETPACK'; w: 32; h: 32; d: 15; n: 3; b: True),
142 (name: 'INVIS'; w: 32; h: 32; d: 20; n: 4; b: True),
143 (name: 'FLAMETHROWER'; w: 64; h: 32; d: 0; n: 1; b: False),
144 (name: 'FUELCAN'; w: 16; h: 32; d: 0; n: 1; b: False)
145 );
146
147 {$IFDEF ENABLE_GFX}
148 GFXAnim: array [0..R_GFX_LAST] of record
149 name: AnsiString;
150 w, h: Integer;
151 count: Integer;
152 back: Boolean;
153 speed: Integer;
154 rspeed: Integer;
155 alpha: Integer;
156 end = (
157 (name: ''; w: 0; h: 0; count: 0; back: false; speed: 0; rspeed: 0; alpha: 0),
158 (name: 'TELEPORT'; w: 64; h: 64; count: 10; back: false; speed: 6; rspeed: 0; alpha: 0),
159 (name: 'FLAME'; w: 32; h: 32; count: 11; back: false; speed: 3; rspeed: 0; alpha: 0),
160 (name: 'EROCKET'; w: 128; h: 128; count: 6; back: false; speed: 6; rspeed: 0; alpha: 0),
161 (name: 'EBFG'; w: 128; h: 128; count: 6; back: false; speed: 6; rspeed: 0; alpha: 0),
162 (name: 'BFGHIT'; w: 64; h: 64; count: 4; back: false; speed: 4; rspeed: 0; alpha: 0),
163 (name: 'FIRE'; w: 64; h: 128; count: 8; back: false; speed: 4; rspeed: 2; alpha: 0),
164 (name: 'ITEMRESPAWN'; w: 32; h: 32; count: 5; back: true; speed: 4; rspeed: 0; alpha: 0),
165 (name: 'SMOKE'; w: 32; h: 32; count: 10; back: false; speed: 3; rspeed: 0; alpha: 0),
166 (name: 'ESKELFIRE'; w: 64; h: 64; count: 3; back: false; speed: 8; rspeed: 0; alpha: 0),
167 (name: 'EPLASMA'; w: 32; h: 32; count: 4; back: true; speed: 3; rspeed: 0; alpha: 0),
168 (name: 'EBSPFIRE'; w: 32; h: 32; count: 5; back: false; speed: 3; rspeed: 0; alpha: 0),
169 (name: 'EIMPFIRE'; w: 64; h: 64; count: 3; back: false; speed: 6; rspeed: 0; alpha: 0),
170 (name: 'ECACOFIRE'; w: 64; h: 64; count: 3; back: false; speed: 6; rspeed: 0; alpha: 0),
171 (name: 'EBARONFIRE'; w: 64; h: 64; count: 3; back: false; speed: 6; rspeed: 0; alpha: 0),
172 (name: 'TELEPORT'; w: 64; h: 64; count: 10; back: false; speed: 3; rspeed: 0; alpha: 0), // fast
173 (name: 'SMOKE'; w: 32; h: 32; count: 10; back: false; speed: 3; rspeed: 0; alpha: 150), // transparent
174 (name: 'FLAME'; w: 32; h: 32; count: 11; back: false; speed: 3; rspeed: 2; alpha: 0) // random
175 );
176 {$ENDIF}
177
178 ShotAnim: array [0..WEAPON_LAST] of record
179 name: AnsiString;
180 w, h: Integer;
181 count: Integer;
182 end = (
183 (name: ''; w: 0; h: 0; count: 0), // 0 KASTET
184 (name: ''; w: 0; h: 0; count: 0), // 1 SAW
185 (name: ''; w: 0; h: 0; count: 0), // 2 PISTOL
186 (name: ''; w: 0; h: 0; count: 0), // 3 SHOTGUN1
187 (name: ''; w: 0; h: 0; count: 0), // 4 SHOTGUN2
188 (name: ''; w: 0; h: 0; count: 0), // 5 CHAINGUN
189 (name: 'BROCKET'; w: 64; h: 32; count: 1), // 6 ROCKETLAUNCHER
190 (name: 'BPLASMA'; w: 16; h: 16; count: 2), // 7 PLASMA
191 (name: 'BBFG'; w: 64; h: 64; count: 2), // 8 BFG
192 (name: ''; w: 0; h: 0; count: 0), // 9 SUPERPULEMET
193 (name: 'FLAME'; w: 32; h: 32; count: 0{11}), // 10 FLAMETHROWER
194 (name: ''; w: 0; h: 0; count: 0), // 11
195 (name: ''; w: 0; h: 0; count: 0), // 12
196 (name: ''; w: 0; h: 0; count: 0), // 13
197 (name: ''; w: 0; h: 0; count: 0), // 14
198 (name: ''; w: 0; h: 0; count: 0), // 15
199 (name: ''; w: 0; h: 0; count: 0), // 16
200 (name: ''; w: 0; h: 0; count: 0), // 17
201 (name: ''; w: 0; h: 0; count: 0), // 18
202 (name: ''; w: 0; h: 0; count: 0), // 19
203 (name: ''; w: 0; h: 0; count: 0), // 20 ZOMPY_PISTOL
204 (name: 'BIMPFIRE'; w: 16; h: 16; count: 2), // 21 IMP_FIRE
205 (name: 'BBSPFIRE'; w: 16; h: 16; count: 2), // 22 BSP_FIRE
206 (name: 'BCACOFIRE'; w: 16; h: 16; count: 2), // 23 CACO_FIRE
207 (name: 'BBARONFIRE'; w: 64; h: 16; count: 2), // 24 BARON_FIRE
208 (name: 'BMANCUBFIRE'; w: 64; h: 32; count: 2), // 25 MANCUB_FIRE
209 (name: 'BSKELFIRE'; w: 64; h: 64; count: 2) // 26 SKEL_FIRE
210 );
211
212 {$IFDEF ENABLE_SHELLS}
213 ShellAnim: array [0..SHELL_LAST] of record
214 name: AnsiString;
215 dx, dy: Integer;
216 end = (
217 (name: 'EBULLET'; dx: 2; dy: 1), // 0 SHELL_BULLET
218 (name: 'ESHELL'; dx: 4; dy: 2), // 1 SHELL_SHELL
219 (name: 'ESHELL'; dx: 4; dy: 2) // 2 SHELL_DBLSHELL
220 );
221 {$ENDIF}
222
223 type
224 TBinHeapPanelDrawCmp = class
225 public
226 class function less (const a, b: TPanel): Boolean; inline;
227 end;
228
229 TBinHeapPanelDraw = specialize TBinaryHeapBase<TPanel, TBinHeapPanelDrawCmp>;
230
231 TMonsterAnims = array [0..ANIM_LAST, TDirection] of TGLMultiTexture;
232
233 var
234 SkyTexture: TGLTexture;
235 RenTextures: array of record
236 spec: LongInt;
237 tex: TGLMultiTexture;
238 end;
239 Items: array [0..ITEM_LAST] of record
240 tex: TGLMultiTexture;
241 anim: TAnimState;
242 end;
243 MonTextures: array [0..MONSTER_MAN] of TMonsterAnims;
244 WeapTextures: array [0..WP_LAST, 0..W_POS_LAST, 0..W_ACT_LAST] of TGLTexture;
245 ShotTextures: array [0..WEAPON_LAST] of TGLMultiTexture;
246 FlagTextures: array [0..FLAG_LAST] of TGLMultiTexture;
247 VileFire: TGLMultiTexture;
248 Models: array of record
249 anim: array [TDirection, 0..A_LAST] of record
250 base, mask: TGLMultiTexture;
251 end;
252 {$IFDEF ENABLE_GIBS}
253 gibs: record
254 base, mask: TGLTextureArray;
255 rect: TRectArray;
256 end;
257 {$ENDIF}
258 end;
259
260 StubShotAnim: TAnimState;
261 FlagAnim: TAnimState;
262
263 {$IFDEF ENABLE_SHELLS}
264 ShellTextures: array [0..SHELL_LAST] of TGLTexture;
265 {$ENDIF}
266 {$IFDEF ENABLE_GFX}
267 GFXTextures: array [0..R_GFX_LAST] of TGLMultiTexture;
268 gfxlist: array of record
269 typ: Byte;
270 alpha: Byte;
271 x, y: Integer;
272 oldX, oldY: Integer;
273 anim: TAnimState;
274 end = nil;
275 {$ENDIF}
276
277 plist: TBinHeapPanelDraw = nil;
278
279 class function TBinHeapPanelDrawCmp.less (const a, b: TPanel): Boolean; inline;
280 begin
281 if a.tag < b.tag then begin result := true; exit; end;
282 if a.tag > b.tag then begin result := false; exit; end;
283 result := a.arrIdx < b.arrIdx;
284 end;
285
286 procedure r_Map_Initialize;
287 begin
288 StubShotAnim := TAnimState.Create(true, 1, 1);
289 FlagAnim := TAnimState.Create(true, 8, 5);
290 plist := TBinHeapPanelDraw.Create();
291 end;
292
293 procedure r_Map_Finalize;
294 begin
295 plist.Free;
296 StubShotAnim.Invalidate;
297 end;
298
299 procedure r_Map_FreeModel (i: Integer);
300 var a: Integer; d: TDirection;
301 begin
302 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
303 begin
304 for a := A_STAND to A_LAST do
305 begin
306 if Models[i].anim[d, a].base <> nil then
307 Models[i].anim[d, a].base.Free;
308 if Models[i].anim[d, a].mask <> nil then
309 Models[i].anim[d, a].mask.Free;
310 Models[i].anim[d, a].base := nil;
311 Models[i].anim[d, a].mask := nil;
312 end;
313 end;
314 {$IFDEF ENABLE_GIBS}
315 if Models[i].gibs.base <> nil then
316 for a := 0 to High(Models[i].gibs.base) do
317 Models[i].gibs.base[a].Free;
318 if Models[i].gibs.mask <> nil then
319 for a := 0 to High(Models[i].gibs.mask) do
320 Models[i].gibs.mask[a].Free;
321 Models[i].gibs.base := nil;
322 Models[i].gibs.mask := nil;
323 Models[i].gibs.rect := nil;
324 {$ENDIF}
325 end;
326
327 procedure r_Map_LoadModel (i: Integer);
328 var prefix: AnsiString; a: Integer; d: TDirection; m: ^TPlayerModelInfo;
329 begin
330 ASSERT(i < Length(Models));
331 ASSERT(i < Length(PlayerModelsArray));
332 r_Map_FreeModel(i);
333 m := @PlayerModelsArray[i];
334 prefix := m.FileName + ':TEXTURES/';
335 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
336 begin
337 for a := A_STAND to A_LAST do
338 begin
339 Models[i].anim[d, a].base := nil;
340 Models[i].anim[d, a].mask := nil;
341 if m.anim[d, a].resource <> '' then
342 Models[i].anim[d, a].base := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].resource, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
343 if m.anim[d, a].mask <> '' then
344 Models[i].anim[d, a].mask := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].mask, 64, 64, m.anim[d, a].frames, m.anim[d, a].back, true);
345 end
346 end;
347 {$IFDEF ENABLE_GIBS}
348 Models[i].gibs.base := nil;
349 Models[i].gibs.mask := nil;
350 Models[i].gibs.rect := nil;
351 if m.GibsCount > 0 then
352 begin
353 SetLength(Models[i].gibs.base, m.GibsCount);
354 SetLength(Models[i].gibs.mask, m.GibsCount);
355 SetLength(Models[i].gibs.rect, m.GibsCount);
356 for a := 0 to m.GibsCount - 1 do
357 Models[i].gibs.rect[a] := DefaultGibSize;
358 if r_Textures_LoadStreamFromFile(prefix + m.GibsResource, 32, 32, m.GibsCount, Models[i].gibs.base, Models[i].gibs.rect) then
359 begin
360 if r_Textures_LoadStreamFromFile(prefix + m.GibsMask, 32, 32, m.GibsCount, Models[i].gibs.mask, nil) then
361 begin
362 // ok
363 end;
364 end;
365 for a := 0 to m.GibsCount - 1 do
366 e_logwritefln('model %s gib %s: %sx%s:%sx%s', [i, a, Models[i].gibs.rect[a].x, Models[i].gibs.rect[a].y, Models[i].gibs.rect[a].width, Models[i].gibs.rect[a].height]);
367 end;
368 {$ENDIF}
369 end;
370
371 procedure r_Map_LoadMonsterAnim (m, a: Integer; d: TDirection);
372 const dir: array [TDirection] of AnsiString = ('_L', '');
373 var w, h, count: Integer;
374 begin
375 count := MONSTER_ANIMTABLE[m].AnimCount[a];
376 if count > 0 then
377 begin
378 w := MTABLE[m].w;
379 h := MTABLE[m].h;
380 if (m = MONSTER_SOUL) and (a = ANIM_DIE) then
381 begin
382 // special case
383 w := 128;
384 h := 128;
385 end;
386 MonTextures[m, a, d] := r_Textures_LoadMultiFromFileAndInfo(
387 GameWAD + ':MTEXTURES/' + MONSTERTABLE[m].name + '_' + ANIMTABLE[a].name + dir[d],
388 w,
389 h,
390 count,
391 False,
392 False
393 );
394 end
395 else
396 MonTextures[m, a, d] := nil;
397 end;
398
399 procedure r_Map_Load;
400 const
401 WeapName: array [0..WP_LAST] of AnsiString = ('', 'CSAW', 'HGUN', 'SG', 'SSG', 'MGUN', 'RKT', 'PLZ', 'BFG', 'SPL', 'FLM');
402 WeapPos: array [0..W_POS_LAST] of AnsiString = ('', '_UP', '_DN');
403 WeapAct: array [0..W_ACT_LAST] of AnsiString = ('', '_FIRE');
404 var
405 i, j, k: Integer; d: TDirection;
406 begin
407 // --------- items --------- //
408 for i := 0 to ITEM_LAST do
409 begin
410 if ItemAnim[i].n > 0 then
411 begin
412 Items[i].tex := r_Textures_LoadMultiFromFileAndInfo(
413 GameWAD + ':TEXTURES/' + ItemAnim[i].name,
414 ItemAnim[i].w,
415 ItemAnim[i].h,
416 ItemAnim[i].n,
417 ItemAnim[i].b,
418 false
419 );
420 k := IfThen(ItemAnim[i].b, ItemAnim[i].n * 2 - 2, ItemAnim[i].n);
421 Items[i].anim := TAnimState.Create(True, ItemAnim[i].d, k);
422 end;
423 end;
424 // --------- monsters --------- //
425 for i := MONSTER_DEMON to MONSTER_MAN do
426 for j := 0 to ANIM_LAST do
427 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
428 r_Map_LoadMonsterAnim(i, j, d);
429 VileFire := r_Textures_LoadMultiFromFileAndInfo(GameWAD + ':TEXTURES/FIRE', 64, 128, 8, False, False);
430 // --------- player models --------- //
431 if PlayerModelsArray <> nil then
432 begin
433 SetLength(Models, Length(PlayerModelsArray));
434 for i := 0 to High(PlayerModelsArray) do
435 r_Map_LoadModel(i);
436 end;
437 // --------- player weapons --------- //
438 for i := 1 to WP_LAST do
439 for j := 0 to W_POS_LAST do
440 for k := 0 to W_ACT_LAST do
441 WeapTextures[i, j, k] := r_Textures_LoadFromFile(GameWAD + ':WEAPONS\' + WeapName[i] + WeapPos[j] + WeapAct[k]);
442 // --------- gfx animations --------- //
443 {$IFDEF ENABLE_GFX}
444 for i := 1 to R_GFX_LAST do
445 if GFXAnim[i].count > 0 then
446 GFXTextures[i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/' + GFXAnim[i].name, GFXAnim[i].w, GFXAnim[i].h, GFXAnim[i].count, GFXAnim[i].back);
447 {$ENDIF}
448 // --------- shots --------- //
449 for i := 0 to WEAPON_LAST do
450 if ShotAnim[i].count > 0 then
451 ShotTextures[i] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/' + ShotAnim[i].name, ShotAnim[i].w, ShotAnim[i].h, ShotAnim[i].count, false);
452 // --------- flags --------- //
453 FlagTextures[FLAG_NONE] := nil;
454 FlagTextures[FLAG_RED] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGRED', 64, 64, 5, false);
455 FlagTextures[FLAG_BLUE] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGBLUE', 64, 64, 5, false);
456 // FlagTextures[FLAG_DOM] := r_Textures_LoadMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGDOM', 64, 64, 8, false);
457 // --------- shells --------- //
458 {$IFDEF ENABLE_SHELLS}
459 for i := 0 to SHELL_LAST do
460 ShellTextures[i] := r_Textures_LoadFromFile(GameWad + ':TEXTURES/' + ShellAnim[i].name);
461 {$ENDIF}
462 end;
463
464 procedure r_Map_Free;
465 var i, j, k, a: Integer; d: TDirection;
466 begin
467 {$IFDEF ENABLE_SHELLS}
468 for i := 0 to SHELL_LAST do
469 begin
470 if ShellTextures[i] <> nil then
471 ShellTextures[i].Free;
472 ShellTextures[i] := nil;
473 end;
474 {$ENDIF}
475 for i := 0 to FLAG_LAST do
476 begin
477 if FlagTextures[i] <> nil then
478 FlagTextures[i].Free;
479 FlagTextures[i] := nil;
480 end;
481 for i := 0 to WEAPON_LAST do
482 begin
483 if ShotTextures[i] <> nil then
484 ShotTextures[i].Free;
485 ShotTextures[i] := nil;
486 end;
487 {$IFDEF ENABLE_GFX}
488 gfxlist := nil;
489 for i := 0 to R_GFX_LAST do
490 begin
491 if GFXTextures[i] <> nil then
492 GFXTextures[i].Free;
493 GFXTextures[i] := nil;
494 end;
495 {$ENDIF}
496 for i := 1 to WP_LAST do
497 begin
498 for j := 0 to W_POS_LAST do
499 begin
500 for k := 0 to W_ACT_LAST do
501 begin
502 if WeapTextures[i, j, k] <> nil then
503 WeapTextures[i, j, k].Free;
504 WeapTextures[i, j, k] := nil;
505 end;
506 end;
507 end;
508 if Models <> nil then
509 for i := 0 to High(Models) do
510 r_Map_FreeModel(i);
511 for i := MONSTER_DEMON to MONSTER_MAN do
512 begin
513 for j := 0 to ANIM_LAST do
514 begin
515 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
516 begin
517 if MonTextures[i, j, d] <> nil then
518 MonTextures[i, j, d].Free;
519 MonTextures[i, j, d] := nil;
520 end;
521 end;
522 end;
523 for i := 0 to ITEM_LAST do
524 begin
525 if Items[i].tex <> nil then
526 begin
527 Items[i].tex.Free;
528 Items[i].tex := nil;
529 end;
530 Items[i].anim.Invalidate;
531 end;
532 end;
533
534 procedure r_Map_LoadTextures;
535 var i, n: Integer;
536 begin
537 if Textures <> nil then
538 begin
539 n := Length(Textures);
540 SetLength(RenTextures, n);
541 for i := 0 to n - 1 do
542 begin
543 RenTextures[i].tex := nil;
544 case Textures[i].TextureName of
545 TEXTURE_NAME_WATER: RenTextures[i].spec := TEXTURE_SPECIAL_WATER;
546 TEXTURE_NAME_ACID1: RenTextures[i].spec := TEXTURE_SPECIAL_ACID1;
547 TEXTURE_NAME_ACID2: RenTextures[i].spec := TEXTURE_SPECIAL_ACID2;
548 else
549 RenTextures[i].spec := 0;
550 RenTextures[i].tex := r_Textures_LoadMultiFromFile(Textures[i].FullName);
551 if RenTextures[i].tex = nil then
552 e_LogWritefln('r_Map_LoadTextures: failed to load texture: %s', [Textures[i].FullName]);
553 end;
554 end;
555 end;
556 if gMapInfo.SkyFullName <> '' then
557 SkyTexture := r_Textures_LoadFromFile(gMapInfo.SkyFullName);
558 plist.Clear;
559 end;
560
561 procedure r_Map_FreeTextures;
562 var i: Integer;
563 begin
564 plist.Clear;
565 if SkyTexture <> nil then
566 SkyTexture.Free;
567 SkyTexture := nil;
568 if RenTextures <> nil then
569 for i := 0 to High(RenTextures) do
570 if RenTextures[i].tex <> nil then
571 RenTextures[i].tex.Free;
572 RenTextures := nil;
573 end;
574
575 procedure r_Map_DrawPanel (p: TPanel);
576 var Texture: Integer; t: TGLMultiTexture;
577 begin
578 ASSERT(p <> nil);
579 if p.FCurTexture >= 0 then
580 begin
581 Texture := p.TextureIDs[p.FCurTexture].Texture;
582 t := RenTextures[Texture].tex;
583
584 if (RenTextures[Texture].spec = 0) or (t <> nil) then
585 begin
586 if t = nil then
587 r_Draw_TextureRepeat(nil, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
588 else if p.TextureIDs[p.FCurTexture].AnTex.IsValid() then
589 r_Draw_MultiTextureRepeat(t, p.TextureIDs[p.FCurTexture].AnTex, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
590 else
591 r_Draw_TextureRepeat(t.GetTexture(0), p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending)
592 end;
593
594 if t = nil then
595 begin
596 case RenTextures[Texture].spec of
597 TEXTURE_SPECIAL_WATER: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 0, 255, 255);
598 TEXTURE_SPECIAL_ACID1: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 230, 0, 255);
599 TEXTURE_SPECIAL_ACID2: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 230, 0, 0, 255);
600 end
601 end
602 end
603 end;
604
605 procedure r_Map_DrawPanelType (panelTyp: DWORD);
606 var tagMask, i: Integer; p: TPanel;
607 begin
608 i := 0;
609 tagMask := PanelTypeToTag(panelTyp);
610 while plist.count > 0 do
611 begin
612 p := TPanel(plist.Front());
613 if (p.tag and tagMask) = 0 then
614 break;
615 r_Map_DrawPanel(p);
616 Inc(i);
617 plist.PopFront
618 end;
619 end;
620
621 procedure r_Map_DrawItems (x, y, w, h: Integer; drop: Boolean);
622 var i, fX, fY: Integer; it: PItem; t: TGLMultiTexture;
623 begin
624 if ggItems <> nil then
625 begin
626 for i := 0 to High(ggItems) do
627 begin
628 it := @ggItems[i];
629 if it.used and it.alive and (it.dropped = drop) and (it.ItemType > ITEM_NONE) and (it.ItemType <= ITEM_LAST) then
630 begin
631 t := Items[it.ItemType].tex;
632 if g_Collide(it.obj.x, it.obj.y, t.width, t.height, x, y, w, h) then
633 begin
634 it.obj.Lerp(gLerpFactor, fX, fY);
635 r_Draw_MultiTextureRepeat(t, Items[it.ItemType].anim, fX, fY, t.width, t.height, false, 255, 255, 255, 255, false);
636 // if g_debug_frames then // TODO draw collision frame
637 end;
638 end;
639 end;
640 end;
641 end;
642
643 function r_Map_GetMonsterTexture (m, a: Integer; d: TDirection; out t: TGLMultiTexture; out dx, dy: Integer; out flip: Boolean): Boolean;
644 // var c: Integer;
645 begin
646 t := nil; dx := 0; dy := 0; flip := false;
647 result := MonTextures[m, a, d] <> nil;
648 if result = false then
649 begin
650 flip := true;
651 if d = TDirection.D_RIGHT then d := TDirection.D_LEFT else d := TDirection.D_RIGHT;
652 result := MonTextures[m, a, d] <> nil;
653 end;
654 if result = true then
655 begin
656 t := MonTextures[m, a, d];
657 if d = TDirection.D_LEFT then
658 begin
659 dx := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].X;
660 dy := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].Y;
661 end
662 else
663 begin
664 dx := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].X;
665 dy := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].Y;
666 end;
667 if flip then
668 begin
669 // c := (MONSTERTABLE[MonsterType].Rect.X - dx) + MONSTERTABLE[MonsterType].Rect.Width;
670 // dx := MTABLE[m].width - c - MONSTERTABLE[MonsterType].Rect.X;
671 dx := -dx;
672 end;
673 end;
674 end;
675
676 procedure r_Map_DrawMonsterAttack (constref mon: TMonster);
677 var o: TObj;
678 begin
679 if VileFire <> nil then
680 if (mon.MonsterType = MONSTER_VILE) and (mon.MonsterState = MONSTATE_SHOOT) then
681 if mon.VileFireAnim.IsValid() and GetPos(mon.MonsterTargetUID, @o) then
682 r_Draw_MultiTextureRepeat(VileFire, mon.VileFireAnim, o.x + o.rect.x + (o.rect.width div 2) - VILEFIRE_DX, o.y + o.rect.y + o.rect.height - VILEFIRE_DY, VileFire.width, VileFire.height, False, 255, 255, 255, 255, false);
683 end;
684
685 procedure r_Map_DrawMonster (constref mon: TMonster);
686 var m, a, fX, fY, dx, dy: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture;
687 begin
688 m := mon.MonsterType;
689 a := mon.MonsterAnim;
690 d := mon.GameDirection;
691
692 mon.obj.Lerp(gLerpFactor, fX, fY);
693
694 if r_Map_GetMonsterTexture(m, a, d, t, dx, dy, flip) then
695 r_Draw_MultiTextureRepeat(t, mon.DirAnim[a, d], fX + dx, fY + dy, t.width, t.height, flip, 255, 255, 255, 255, false);
696
697 {
698 if g_debug_frames
699 // TODO draw frame
700 }
701 end;
702
703 procedure r_Map_DrawMonsters (x, y, w, h: Integer);
704 var i: Integer; m: TMonster;
705 begin
706 if gMonsters <> nil then
707 begin
708 for i := 0 to High(gMonsters) do
709 begin
710 m := gMonsters[i];
711 if m <> nil then
712 begin
713 r_Map_DrawMonsterAttack(m);
714 // TODO select from grid
715 if g_Collide(m.obj.x + m.obj.rect.x, m.obj.y + m.obj.rect.y, m.obj.rect.width, m.obj.rect.height, x, y, w, h) then
716 r_Map_DrawMonster(m);
717 end;
718 end;
719 end;
720 end;
721
722 function r_Map_GetPlayerModelTex (i: Integer; var a: Integer; var d: TDirection; out flip: Boolean): Boolean;
723 begin
724 flip := false;
725 result := Models[i].anim[d, a].base <> nil;
726 if result = false then
727 begin
728 flip := true;
729 if d = TDirection.D_LEFT then d := TDirection.D_RIGHT else d := TDirection.D_LEFT;
730 result := Models[i].anim[d, a].base <> nil;
731 end;
732 end;
733
734 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer);
735 var a, pos, act, xx, yy, angle: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture; tex: TGLTexture; c: TRGB;
736 begin
737 a := pm.CurrentAnimation;
738 d := pm.Direction;
739
740 (* draw flag*)
741 t := FlagTextures[pm.Flag];
742 if (t <> nil) and not (a in [A_DIE1, A_DIE2]) then
743 begin
744 flip := d = TDirection.D_RIGHT;
745 angle := PlayerModelsArray[pm.id].FlagAngle;
746 xx := PlayerModelsArray[pm.id].FlagPoint.X;
747 yy := PlayerModelsArray[pm.id].FlagPoint.Y;
748 r_Draw_MultiTextureRepeatRotate(
749 t,
750 FlagAnim,
751 x + IfThen(flip, 2 * FLAG_BASEPOINT.X - xx + 1, xx - 1) - FLAG_BASEPOINT.X,
752 y + yy - FLAG_BASEPOINT.Y + 1,
753 t.width,
754 t.height,
755 flip,
756 255, 255, 255, 255, false,
757 IfThen(flip, 64 - FLAG_BASEPOINT.X, FLAG_BASEPOINT.X),
758 FLAG_BASEPOINT.Y,
759 IfThen(flip, angle, -angle)
760 );
761 end;
762
763 (* draw weapon *)
764 if PlayerModelsArray[pm.id].HaveWeapon and not (a in [A_DIE1, A_DIE2, A_PAIN]) then
765 begin
766 case a of
767 A_SEEUP, A_ATTACKUP: pos := W_POS_UP;
768 A_SEEDOWN, A_ATTACKDOWN: pos := W_POS_DOWN;
769 else pos := W_POS_NORMAL;
770 end;
771 if (a in [A_ATTACK, A_ATTACKUP, A_ATTACKDOWN]) or pm.GetFire() then
772 act := W_ACT_FIRE
773 else
774 act := W_ACT_NORMAL;
775 tex := WeapTextures[pm.CurrentWeapon, pos, act];
776 if tex <> nil then
777 begin
778 xx := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].X;
779 yy := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].Y;
780 r_Draw_Texture(
781 tex,
782 x + xx,
783 y + yy,
784 tex.width,
785 tex.height,
786 d = TDirection.D_LEFT,
787 255, 255, 255, 255, false
788 );
789 end;
790 end;
791
792 (* draw body *)
793 if r_Map_GetPlayerModelTex(pm.id, a, d, flip) then
794 begin
795 t := Models[pm.id].anim[d, a].base;
796 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip, 255, 255, 255, 255, false);
797 t := Models[pm.id].anim[d, a].mask;
798 if t <> nil then
799 begin
800 c := pm.Color;
801 r_Draw_MultiTextureRepeat(t, pm.AnimState, x, y, t.width, t.height, flip, c.r, c.g, c.b, 255, false);
802 end;
803 end;
804 end;
805
806 procedure r_Map_DrawPlayer (p: TPlayer);
807 var fX, fY, fSlope: Integer;
808 begin
809 if p.alive then
810 begin
811 fX := p.obj.x; fY := p.obj.y;
812 // TODO fix lerp
813 //p.obj.Lerp(gLerpFactor, fX, fY);
814 fSlope := nlerp(p.SlopeOld, p.obj.slopeUpLeft, gLerpFactor);
815 // TODO draw punch
816 // TODO invul pentagram
817 // TODO draw it with transparency
818 r_Map_DrawPlayerModel(p.Model, fX, fY + fSlope);
819 end;
820 // TODO draw g_debug_frames
821 // TODO draw chat bubble
822 // TODO draw aim
823 end;
824
825 procedure r_Map_DrawPlayers (x, y, w, h: Integer);
826 var i: Integer;
827 begin
828 // TODO draw only visible
829 if gPlayers <> nil then
830 for i := 0 to High(gPlayers) do
831 if gPlayers[i] <> nil then
832 r_Map_DrawPlayer(gPlayers[i]);
833 end;
834
835 {$IFDEF ENABLE_GIBS}
836 function r_Map_GetGibSize (m, i: Integer): TRectWH;
837 begin
838 result := Models[m].gibs.rect[i];
839 end;
840
841 procedure r_Map_DrawGibs (x, y, w, h: Integer);
842 var i, fx, fy, m, id, rx, ry, ra: Integer; p: PObj; t: TGLTexture;
843 begin
844 if gGibs <> nil then
845 begin
846 for i := 0 to High(gGibs) do
847 begin
848 if gGibs[i].alive then
849 begin
850 p := @gGibs[i].Obj;
851 if g_Obj_Collide(x, y, w, h, p) then
852 begin
853 p.Lerp(gLerpFactor, fx, fy);
854 id := gGibs[i].GibID;
855 m := gGibs[i].ModelID;
856 t := Models[m].gibs.base[id];
857 if t <> nil then
858 begin
859 rx := p.Rect.X + p.Rect.Width div 2;
860 ry := p.Rect.Y + p.Rect.Height div 2;
861 ra := gGibs[i].RAngle;
862 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, 255, 255, 255, 255, false, rx, ry, ra);
863 t := Models[m].gibs.mask[id];
864 if t <> nil then
865 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, gGibs[i].Color.R, gGibs[i].Color.G, gGibs[i].Color.B, 255, false, rx, ry, ra);
866 // r_Draw_TextureRepeatRotate(nil, fx + p.Rect.X, fy + p.Rect.Y, p.Rect.Width, p.Rect.Height, false, 255, 255, 255, 255, false, p.Rect.Width div 2, p.Rect.Height div 2, ra);
867 end;
868 end;
869 end;
870 end;
871 end;
872 end;
873 {$ENDIF}
874
875 {$IFDEF ENABLE_CORPSES}
876 procedure r_Map_DrawCorpses (x, y, w, h: Integer);
877 var i, fX, fY: Integer; p: TCorpse;
878 begin
879 if gCorpses <> nil then
880 begin
881 for i := 0 to High(gCorpses) do
882 begin
883 p := gCorpses[i];
884 if (p <> nil) and (p.state <> CORPSE_STATE_REMOVEME) and (p.model <> nil) then
885 begin
886 p.obj.Lerp(gLerpFactor, fX, fY);
887 r_Map_DrawPlayerModel(p.model, fX, fY);
888 end;
889 end;
890 end;
891 end;
892 {$ENDIF}
893
894 {$IFDEF ENABLE_GFX}
895 function r_Map_GetGFXID (): Integer;
896 var i: Integer;
897 begin
898 i := 0;
899 if gfxlist <> nil then
900 begin
901 while (i < Length(gfxlist)) and gfxlist[i].anim.IsValid() do
902 Inc(i);
903 if i >= Length(gfxlist) then
904 SetLength(gfxlist, Length(gfxlist) + 1)
905 end
906 else
907 SetLength(gfxlist, 1);
908 gfxlist[i].typ := R_GFX_NONE;
909 gfxlist[i].anim.Invalidate;
910 result := i
911 end;
912
913 procedure r_Map_NewGFX (typ, x, y: Integer);
914 var i: Integer;
915 begin
916 if gpart_dbg_enabled and (typ > 0) and (typ <= R_GFX_LAST) then
917 begin
918 i := r_Map_GetGFXID();
919 if i >= 0 then
920 begin
921 gfxlist[i].typ := typ;
922 gfxlist[i].x := x;
923 gfxlist[i].y := y;
924 gfxlist[i].oldX := x;
925 gfxlist[i].oldY := y;
926 gfxlist[i].anim := TAnimState.Create(false, GFXAnim[typ].speed + Random(GFXAnim[typ].rspeed), GFXAnim[typ].count);
927 gfxlist[i].anim.Reset();
928 gfxlist[i].anim.Enable();
929 end;
930 end;
931 end;
932
933 procedure r_Map_UpdateGFX;
934 var i: Integer;
935 begin
936 if gfxlist <> nil then
937 begin
938 for i := 0 to High(gfxlist) do
939 begin
940 if gfxlist[i].anim.IsValid() then
941 begin
942 gfxlist[i].oldX := gfxlist[i].x;
943 gfxlist[i].oldY := gfxlist[i].y;
944 case gfxlist[i].typ of
945 R_GFX_FLAME, R_GFX_SMOKE:
946 begin
947 if Random(3) = 0 then
948 gfxlist[i].x := gfxlist[i].x - 1 + Random(3);
949 if Random(2) = 0 then
950 gfxlist[i].y := gfxlist[i].y - Random(2);
951 end;
952 end;
953 if gfxlist[i].anim.played then
954 gfxlist[i].anim.Invalidate
955 else
956 gfxlist[i].anim.Update
957 end;
958 end;
959 end;
960 end;
961
962 procedure r_Map_DrawParticles (x, y, w, h: Integer);
963 var i, fx, fy: Integer;
964 begin
965 if gpart_dbg_enabled and (Particles <> nil) then
966 begin
967 glDisable(GL_TEXTURE_2D);
968 if (g_dbg_scale < 0.6) then
969 glPointSize(1)
970 else if (g_dbg_scale > 1.3) then
971 glPointSize(g_dbg_scale + 1)
972 else
973 glPointSize(2);
974 glDisable(GL_POINT_SMOOTH);
975 glEnable(GL_BLEND);
976 glBlendFunc(GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA);
977
978 glBegin(GL_POINTS);
979 for i := 0 to High(Particles) do
980 begin
981 if Particles[i].alive then
982 begin
983 fx := nlerp(Particles[i].oldX, Particles[i].x, gLerpFactor);
984 fy := nlerp(Particles[i].oldY, Particles[i].y, gLerpFactor);
985 glColor4ub(Particles[i].red, Particles[i].green, Particles[i].blue, Particles[i].alpha);
986 glVertex2f(fx, fy);
987 end;
988 end;
989 glEnd;
990
991 glDisable(GL_BLEND);
992 end;
993 end;
994
995 procedure r_Map_DrawGFX (x, y, w, h: Integer);
996 var i, fx, fy, typ: Integer; tex: TGLMultiTexture;
997 begin
998 if gfxlist <> nil then
999 begin
1000 for i := 0 to High(gfxlist) do
1001 begin
1002 if gfxlist[i].anim.IsValid() then
1003 begin
1004 typ := gfxlist[i].typ;
1005 tex := GFXTextures[typ];
1006 if tex <> nil then
1007 begin
1008 fx := nlerp(gfxlist[i].oldX, gfxlist[i].x, gLerpFactor);
1009 fy := nlerp(gfxlist[i].oldY, gfxlist[i].y, gLerpFactor);
1010 r_Draw_MultiTextureRepeat(tex, gfxlist[i].anim, fx, fy, tex.width, tex.height, false, 255, 255, 255, 255 - GFXAnim[typ].alpha, false);
1011 end;
1012 end;
1013 end;
1014 end;
1015 end;
1016 {$ENDIF}
1017
1018 procedure r_Map_DrawShots (x, y, w, h: Integer);
1019 var i, a, fX, fY, pX, pY, typ: Integer; tex: TGLMultiTexture; anim: ^TAnimState;
1020 begin
1021 if Shots <> nil then
1022 begin
1023 for i := 0 to High(Shots) do
1024 begin
1025 typ := Shots[i].ShotType;
1026 if typ <> 0 then
1027 begin
1028 tex := ShotTextures[typ];
1029 if tex <> nil then
1030 begin
1031 a := 0;
1032 case typ of
1033 WEAPON_ROCKETLAUNCHER, WEAPON_BARON_FIRE, WEAPON_MANCUB_FIRE, WEAPON_SKEL_FIRE:
1034 a := -GetAngle2(Shots[i].Obj.Vel.X, Shots[i].Obj.Vel.Y)
1035 end;
1036 Shots[i].Obj.Lerp(gLerpFactor, fX, fY);
1037 pX := Shots[i].Obj.Rect.Width div 2;
1038 pY := Shots[i].Obj.Rect.Height div 2;
1039 // TODO fix this hack
1040 if Shots[i].Animation.IsValid() then anim := @Shots[i].Animation else anim := @StubShotAnim;
1041 r_Draw_MultiTextureRepeatRotate(tex, anim^, fX, fY, tex.width, tex.height, false, 255, 255, 255, 255, false, pX, pY, a);
1042 end;
1043 end;
1044 end;
1045 end;
1046 end;
1047
1048 procedure r_Map_DrawFlags (x, y, w, h: Integer);
1049 var i, dx, fx, fy: Integer; flip: Boolean; tex: TGLMultiTexture;
1050 begin
1051 if gGameSettings.GameMode = GM_CTF then
1052 begin
1053 for i := FLAG_RED to FLAG_BLUE do
1054 begin
1055 if not (gFlags[i].state in [FLAG_STATE_NONE, FLAG_STATE_CAPTURED]) then
1056 begin
1057 gFlags[i].Obj.Lerp(gLerpFactor, fx, fy);
1058 flip := gFlags[i].Direction = TDirection.D_LEFT;
1059 if flip then dx := -1 else dx := +1;
1060 tex := FlagTextures[i];
1061 r_Draw_MultiTextureRepeat(tex, FlagAnim, fx + dx, fy + 1, tex.width, tex.height, flip, 255, 255, 255, 255, false)
1062 // TODO g_debug_frames
1063 end;
1064 end;
1065 end;
1066 end;
1067
1068 {$IFDEF ENABLE_SHELLS}
1069 procedure r_Map_DrawShells (x, y, w, h: Integer);
1070 var i, fx, fy, typ: Integer; t: TGLTexture; p: PObj;
1071 begin
1072 if gShells <> nil then
1073 begin
1074 for i := 0 to High(gShells) do
1075 begin
1076 if gShells[i].alive then
1077 begin
1078 typ := gShells[i].SType;
1079 if typ <= SHELL_LAST then
1080 begin
1081 p := @gShells[i].Obj;
1082 if g_Obj_Collide(x, y, w, h, p) then
1083 begin
1084 t := ShellTextures[typ];
1085 if t <> nil then
1086 begin
1087 p.Lerp(gLerpFactor, fx, fy);
1088 r_Draw_TextureRepeatRotate(t, fx, fy, t.width, t.height, false, 255, 255, 255, 255, false, ShellAnim[typ].dx, ShellAnim[typ].dy, gShells[i].RAngle);
1089 end;
1090 end;
1091 end;
1092 end;
1093 end;
1094 end;
1095 end;
1096 {$ENDIF}
1097
1098 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer);
1099 var iter: TPanelGrid.Iter; p: PPanel; cx, cy, xx, yy, ww, hh: Integer;
1100 begin
1101 cx := camx - w div 2;
1102 cy := camy - h div 2;
1103 xx := x + cx;
1104 yy := y + cy;
1105 ww := w;
1106 hh := h;
1107
1108 if SkyTexture <> nil then
1109 r_Draw_Texture(SkyTexture, x, y, w, h, false, 255, 255, 255, 255, false);
1110
1111 plist.Clear;
1112 iter := mapGrid.ForEachInAABB(xx, yy, ww, hh, GridDrawableMask);
1113 for p in iter do
1114 if ((p^.tag and GridTagDoor) <> 0) = p^.door then
1115 plist.Insert(p^);
1116 iter.Release;
1117
1118 glPushMatrix;
1119 glTranslatef(-cx, -cy, 0);
1120 r_Map_DrawPanelType(PANEL_BACK);
1121 r_Map_DrawPanelType(PANEL_STEP);
1122 r_Map_DrawItems(xx, yy, ww, hh, false);
1123 r_Map_DrawShots(xx, yy, ww, hh);
1124 {$IFDEF ENABLE_SHELLS}
1125 r_Map_DrawShells(xx, yy, ww, hh);
1126 {$ENDIF}
1127 r_Map_DrawPlayers(xx, yy, ww, hh);
1128 {$IFDEF ENABLE_GIBS}
1129 r_Map_DrawGibs(xx, yy, ww, hh);
1130 {$ENDIF}
1131 {$IFDEF ENABLE_CORPSES}
1132 r_Map_DrawCorpses(xx, yy, ww, hh);
1133 {$ENDIF}
1134 r_Map_DrawPanelType(PANEL_WALL);
1135 r_Map_DrawMonsters(xx, yy, ww, hh);
1136 r_Map_DrawItems(xx, yy, ww, hh, true);
1137 r_Map_DrawPanelType(PANEL_CLOSEDOOR);
1138 {$IFDEF ENABLE_GFX}
1139 r_Map_DrawParticles(xx, yy, ww, hh);
1140 r_Map_DrawGFX(xx, yy, ww, hh);
1141 {$ENDIF}
1142 r_Map_DrawFlags(xx, yy, ww, hh);
1143 r_Map_DrawPanelType(PANEL_ACID1);
1144 r_Map_DrawPanelType(PANEL_ACID2);
1145 r_Map_DrawPanelType(PANEL_WATER);
1146 r_Map_DrawPanelType(PANEL_FORE);
1147 glPopMatrix;
1148 end;
1149
1150 procedure r_Map_Update;
1151 var i: Integer;
1152 begin
1153 for i := 0 to ITEM_LAST do
1154 Items[i].anim.Update;
1155 r_Map_UpdateGFX;
1156 FlagAnim.Update;
1157 end;
1158
1159 end.
[MIRROR] a port of Doom 2D Forever to FPC/SDL
[25/02/2024 19:55:35]
DEADSOFTWARE 2012-2024