src/generic/Dev/Mod/CPR.cp

   1 MODULE DevCPR;
   2
   3   IMPORT Strings, DevCPM, DevCPT;
   4
   5   CONST
   6     MaxIdLen = LEN(DevCPT.Name);
   7
   8     (* symbol values *)
   9     null = 0;
  10     if = 1; then = 2; else = 3; elsif = 4; end = 5; new = 6;
  11     ident = 7; plus = 8; minus = 9;
  12     not = 10; and = 11; or = 12; rpar = 13; lpar = 14;
  13     endcom = 15; eof = 16;
  14
  15     (* func numbers *)
  16     var = 0; defined = 1;
  17
  18   TYPE
  19     Context = POINTER TO RECORD
  20       next: Context; (* upper level block *)
  21       alt: BOOLEAN;  (* else branch *)
  22       val: BOOLEAN;  (* condition value, inverted if alt *)
  23       ref: INTEGER   (* ELSIF count *)
  24     END;
  25
  26     Selector = POINTER TO RECORD
  27       next: Selector;
  28       name: DevCPT.Name;
  29       val: BOOLEAN;
  30       num: BYTE
  31     END;
  32
  33   VAR
  34     ch: CHAR; (* current character *)
  35     name: DevCPT.Name; (* ident *)
  36
  37   VAR
  38     sym: BYTE; (* parser symbol *)
  39     fold: INTEGER; (* condition folding *)
  40     scope: Selector;
  41     top: Context;
  42
  43   PROCEDURE err (n: SHORTINT);
  44   BEGIN DevCPM.err(n)
  45   END err;
  46
  47   PROCEDURE Identifier (VAR sym: BYTE);
  48     VAR i, res: INTEGER; n: ARRAY MaxIdLen OF CHAR;
  49   BEGIN i := 0;
  50     REPEAT
  51       n[i] := ch; INC(i); DevCPM.Get(ch)
  52     UNTIL ~Strings.IsIdent(ch) OR (i = MaxIdLen);
  53     IF i = MaxIdLen THEN err(240); DEC(i) END ;
  54     n[i] := 0X; Strings.StringToUtf8(n, name, res); sym := ident;
  55     IF res = 1 (*truncated*) THEN err(240) END
  56   END Identifier;
  57
  58   PROCEDURE Get (VAR sym: BYTE);
  59   BEGIN
  60     DevCPM.errpos := DevCPM.curpos - 1;
  61     WHILE (ch # DevCPM.Eot) & ((ch <= " ") OR (ch = 0A0X)) DO DevCPM.Get(ch) END;
  62     DevCPM.startpos := DevCPM.curpos - 1;
  63     CASE ch OF
  64     | DevCPM.Eot: sym := eof
  65     | "&": sym := and; DevCPM.Get(ch)
  66     | "(": sym := lpar; DevCPM.Get(ch)
  67     | ")": sym := rpar; DevCPM.Get(ch)
  68     | "*":
  69         sym := null; DevCPM.Get(ch);
  70         IF ch = ">" THEN sym := endcom; DevCPM.Get(ch) END
  71     | "+": sym := plus; DevCPM.Get(ch)
  72     | "-": sym := minus; DevCPM.Get(ch)
  73     | "E": Identifier(sym);
  74         IF name = "END" THEN sym := end
  75         ELSIF name = "ELSE" THEN sym := else
  76         ELSIF name = "ELSIF" THEN sym := elsif
  77         END
  78     | "I": Identifier(sym); IF name = "IF" THEN sym := if END
  79     | "N": Identifier(sym); IF name = "NEW" THEN sym := new END
  80     | "O": Identifier(sym); IF name = "OR" THEN sym := or END
  81     | "T": Identifier(sym); IF name = "THEN" THEN sym := then END
  82     | "A".."D", "J".."M", "P".."S", "U".."Z", "a".."z", "_": Identifier(sym)
  83     | "~": sym := not; DevCPM.Get(ch)
  84     ELSE
  85       IF Strings.IsIdent(ch) THEN Identifier(sym) ELSE sym := null; DevCPM.Get(ch) END
  86     END
  87   END Get;
  88
  89   PROCEDURE New (IN name: DevCPT.Name; val: BOOLEAN): Selector;
  90     VAR s: Selector;
  91   BEGIN
  92     s := scope;
  93     WHILE (s.next # NIL) & (s.next.name$ # name$) DO s := s.next END;
  94     IF s.next = NIL THEN
  95       NEW(s.next); s.next.name := name$; s.next.num := var; s.next.val := val
  96     ELSE err(1)
  97     END;
  98     RETURN s.next
  99   END New;
 100
 101   PROCEDURE Old (IN name: DevCPT.Name): Selector;
 102     VAR s: Selector;
 103   BEGIN
 104     s := scope;
 105     WHILE (s.next # NIL) & (s.next.name$ # name$) DO s := s.next END;
 106     IF s.next = NIL THEN
 107       err(0); NEW(s.next); s.next.name := name$; s.next.num := var; s.next.val := FALSE
 108     END;
 109     RETURN s.next
 110   END Old;
 111
 112   PROCEDURE Find (IN name: DevCPT.Name): Selector;
 113     VAR s: Selector;
 114   BEGIN
 115     s := scope;
 116     WHILE (s.next # NIL) & (s.next.name$ # name$) DO s := s.next END;
 117     RETURN s.next
 118   END Find;
 119
 120   PROCEDURE Set* (IN name: DevCPT.Name; val: BOOLEAN);
 121     VAR s: Selector;
 122   BEGIN
 123     s := scope;
 124     WHILE (s.next # NIL) & (s.next.name$ # name$) DO s := s.next END;
 125     IF s.next = NIL THEN NEW(s.next) END;
 126     s.next.name := name$; s.next.num := var; s.next.val := val
 127   END Set;
 128
 129   PROCEDURE ^ Expression (VAR x: BOOLEAN);
 130
 131   PROCEDURE Factor (VAR x: BOOLEAN);
 132     VAR s: Selector;
 133   BEGIN x := FALSE;
 134     IF sym = ident THEN
 135       s := Old(name); Get(sym);
 136       IF s.num = var THEN
 137          x := s.val
 138       ELSIF sym = lpar THEN
 139         Get(sym);
 140         ASSERT(s.num = defined);
 141         IF sym = ident THEN
 142           x := Find(name) # NIL; Get(sym)
 143         ELSE err(48)
 144         END;
 145         IF sym # rpar THEN err(23)
 146         ELSE Get(sym)
 147         END
 148       ELSE
 149         err(40)
 150       END
 151     ELSIF sym = lpar THEN
 152       Get(sym); Expression(x);
 153       IF sym # rpar THEN err(23)
 154       ELSE Get(sym)
 155       END
 156     ELSIF sym = not THEN
 157       Get(sym); Factor(x); x := ~x
 158     ELSE
 159       err(13)
 160     END
 161   END Factor;
 162
 163   PROCEDURE Term (VAR x: BOOLEAN);
 164     VAR y: BOOLEAN;
 165   BEGIN
 166     Factor(x);
 167     WHILE sym = and DO
 168       Get(sym); Factor(y); x := x & y
 169     END
 170   END Term;
 171
 172   PROCEDURE Expression (VAR x: BOOLEAN);
 173     VAR y: BOOLEAN;
 174   BEGIN
 175     Term(x);
 176     WHILE sym = or DO
 177       Get(sym); Term(y); x := x OR y
 178     END
 179   END Expression;
 180
 181   PROCEDURE If (cond: BOOLEAN);
 182     VAR c: Context;
 183   BEGIN
 184     NEW(c); c.next := top; c.alt := FALSE; c.val := cond; c.ref := 0; top := c;
 185     INC(fold)
 186   END If;
 187
 188   PROCEDURE Else;
 189   BEGIN
 190     IF top.alt THEN err(14) (* double ELSE *)
 191     ELSE top.alt := TRUE; top.val := ~top.val;
 192     END
 193   END Else;
 194
 195   PROCEDURE End;
 196     VAR i, ref: INTEGER;
 197   BEGIN
 198     i := 0; ref := top.ref; DEC(fold, ref + 1);
 199     WHILE (top # NIL) & (i <= ref) DO top := top.next; INC(i) END;
 200     IF top = NIL THEN err(51); fold := 0; If(TRUE) END
 201   END End;
 202
 203   PROCEDURE Parse*;
 204     VAR val: BOOLEAN; s: Selector;
 205   BEGIN
 206     Get(sym);
 207     IF sym = new THEN
 208       Get(sym);
 209       IF sym = ident THEN s := New(name, FALSE); Get(sym)
 210       ELSE err(48)
 211       END
 212     ELSIF sym = ident THEN
 213       Get(sym);
 214       IF sym = plus THEN Old(name).val := TRUE; Get(sym)
 215       ELSIF sym = minus THEN Old(name).val := FALSE; Get(sym)
 216       ELSE err(41)
 217       END
 218     ELSIF sym = if THEN
 219       Get(sym); Expression(val); If(val);
 220       IF sym = then THEN Get(sym)
 221       ELSE err(27)
 222       END
 223     ELSIF sym = elsif THEN
 224       IF fold <= 1 THEN err(14) END; (* ELSIF without IF *)
 225       Else; Get(sym); Expression(val); If(val); INC(top.ref);
 226       IF sym = then THEN Get(sym)
 227       ELSE err(27)
 228       END
 229     ELSIF sym = else THEN
 230       IF fold <= 1 THEN err(14) END; (* ELSE without IF *)
 231       Else; Get(sym)
 232     ELSIF sym = end THEN
 233       IF fold <= 1 THEN err(14) END; (* END without IF *)
 234       End; Get(sym)
 235     ELSE
 236       err(14)
 237     END;
 238     IF sym # endcom THEN err(5) ELSE DevCPM.errpos := DevCPM.curpos - 1 END
 239   END Parse;
 240
 241   PROCEDURE Printable* (): BOOLEAN;
 242     VAR c: Context;
 243   BEGIN
 244     c := top;
 245     WHILE (c # NIL) & c.val DO c := c.next END;
 246     RETURN c = NIL
 247   END Printable;
 248
 249   PROCEDURE Check*;
 250   BEGIN
 251     IF fold # 1 THEN err(14) END
 252   END Check;
 253
 254   PROCEDURE Close*;
 255   BEGIN
 256     ch := " "; sym := eof; name := "";
 257     fold := 0; top := NIL; scope := NIL
 258   END Close;
 259
 260   PROCEDURE Init*;
 261     VAR s: Selector;
 262   BEGIN
 263     Close;
 264     If(TRUE);
 265     NEW(scope);
 266     s := New("TRUE", TRUE);
 267     s := New("FALSE", FALSE);
 268     s := New("DEFINED", FALSE); s.num := defined
 269   END Init;
 270
 271 END DevCPR.