DEADSOFTWARE

GIT / REPO / FRED-BOY
Projects / d2df-sdl.git / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
gl: implement d_frames
[d2df-sdl.git] / src / game / renders / opengl / r_map.pas
1 (* Copyright (C) Doom 2D: Forever Developers
2 *
3 * This program is free software: you can redistribute it and/or modify
4 * it under the terms of the GNU General Public License as published by
5 * the Free Software Foundation, version 3 of the License ONLY.
6 *
7 * This program is distributed in the hope that it will be useful,
8 * but WITHOUT ANY WARRANTY; without even the implied warranty of
9 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
10 * GNU General Public License for more details.
11 *
12 * You should have received a copy of the GNU General Public License
13 * along with this program. If not, see <http://www.gnu.org/licenses/>.
14 *)
15 {$INCLUDE ../../../shared/a_modes.inc}
16 unit r_map;
17
18 interface
19
20 uses g_base, g_player, g_playermodel; // TRectWH, TPlayer, TPlayerModel
21
22 procedure r_Map_Initialize;
23 procedure r_Map_Finalize;
24
25 procedure r_Map_Load;
26 procedure r_Map_Free;
27
28 procedure r_Map_LoadTextures;
29 procedure r_Map_FreeTextures;
30
31 {$IFDEF ENABLE_GFX}
32 procedure r_Map_NewGFX (typ, x, y: Integer);
33 {$ENDIF}
34 {$IFDEF ENABLE_GIBS}
35 function r_Map_GetGibSize (m, i: Integer): TRectWH;
36 {$ENDIF}
37 {$IFDEF ENABLE_MENU}
38 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer; alpha: Byte);
39 {$ENDIF}
40
41 procedure r_Map_Reset;
42 procedure r_Map_Update;
43
44 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer; player: TPlayer; out acx, acy: Integer);
45
46 implementation
47
48 uses
49 {$I ../../../nogl/noGLuses.inc}
50 Math, SysUtils,
51 e_log,
52 binheap, MAPDEF, utils,
53 g_options, g_animations, g_basic, g_phys,
54 g_game, g_map, g_panel, g_items, g_monsters, g_weapons,
55 g_console, g_language,
56 {$IFDEF ENABLE_CORPSES}
57 g_corpses,
58 {$ENDIF}
59 {$IFDEF ENABLE_SHELLS}
60 g_shells,
61 {$ENDIF}
62 {$IFDEF ENABLE_GIBS}
63 g_gibs,
64 {$ENDIF}
65 {$IFDEF ENABLE_GFX}
66 g_gfx,
67 {$ENDIF}
68 r_textures, r_draw, r_common
69 ;
70
71 const
72 MTABLE: array [0..MONSTER_MAN] of record
73 w, h: Integer;
74 end = (
75 (w: 64; h: 64), // NONE
76 (w: 64; h: 64), // DEMON
77 (w: 64; h: 64), // IMP
78 (w: 64; h: 64), // ZOMBY
79 (w: 64; h: 64), // SERG
80 (w: 128; h: 128), // CYBER
81 (w: 64; h: 64), // CGUN
82 (w: 128; h: 128), // BARON
83 (w: 128; h: 128), // KNIGHT
84 (w: 128; h: 128), // CACO
85 (w: 64; h: 64), // SOUL (DIE is 128x128, see load code)
86 (w: 128; h: 128), // PAIN
87 (w: 256; h: 128), // SPIDER
88 (w: 128; h: 64), // BSP
89 (w: 128; h: 128), // MANCUB
90 (w: 128; h: 128), // SKEL
91 (w: 128; h: 128), // VILE
92 (w: 32; h: 32), // FISH
93 (w: 64; h: 64), // BARREL
94 (w: 128; h: 128), // ROBO
95 (w: 64; h: 64) // MAN
96 );
97 VILEFIRE_DX = 32;
98 VILEFIRE_DY = 128;
99
100 ItemAnim: array [0..ITEM_LAST] of record
101 name: AnsiString;
102 w, h: Integer;
103 anim: TAnimInfo;
104 end = (
105 (name: 'NOTEXTURE'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
106 (name: 'MED1'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
107 (name: 'MED2'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
108 (name: 'BMED'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
109 (name: 'ARMORGREEN'; w: 32; h: 16; anim: (loop: true; delay: 20; frames: 3; back: true)),
110 (name: 'ARMORBLUE'; w: 32; h: 16; anim: (loop: true; delay: 20; frames: 3; back: true)),
111 (name: 'SBLUE'; w: 32; h: 32; anim: (loop: true; delay: 15; frames: 4; back: true)),
112 (name: 'SWHITE'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
113 (name: 'SUIT'; w: 32; h: 64; anim: (loop: true; delay: 1; frames: 1; back: false)),
114 (name: 'OXYGEN'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
115 (name: 'INVUL'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
116 (name: 'SAW'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
117 (name: 'SHOTGUN1'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
118 (name: 'SHOTGUN2'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
119 (name: 'MGUN'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
120 (name: 'RLAUNCHER'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
121 (name: 'PGUN'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
122 (name: 'BFG'; w: 64; h: 64; anim: (loop: true; delay: 1; frames: 1; back: false)),
123 (name: 'SPULEMET'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
124 (name: 'CLIP'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
125 (name: 'AMMO'; w: 32; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
126 (name: 'SHELL1'; w: 16; h: 8; anim: (loop: true; delay: 1; frames: 1; back: false)),
127 (name: 'SHELL2'; w: 32; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
128 (name: 'ROCKET'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
129 (name: 'ROCKETS'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
130 (name: 'CELL'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
131 (name: 'CELL2'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
132 (name: 'BPACK'; w: 32; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
133 (name: 'KEYR'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
134 (name: 'KEYG'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
135 (name: 'KEYB'; w: 16; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
136 (name: 'KASTET'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
137 (name: 'PISTOL'; w: 64; h: 16; anim: (loop: true; delay: 1; frames: 1; back: false)),
138 (name: 'BOTTLE'; w: 16; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
139 (name: 'HELMET'; w: 16; h: 16; anim: (loop: true; delay: 20; frames: 4; back: true)),
140 (name: 'JETPACK'; w: 32; h: 32; anim: (loop: true; delay: 15; frames: 3; back: true)),
141 (name: 'INVIS'; w: 32; h: 32; anim: (loop: true; delay: 20; frames: 4; back: true)),
142 (name: 'FLAMETHROWER'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)),
143 (name: 'FUELCAN'; w: 16; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false))
144 );
145
146 {$IFDEF ENABLE_GFX}
147 GFXAnim: array [0..R_GFX_LAST] of record
148 name: AnsiString;
149 w, h: Integer;
150 anim: TAnimInfo;
151 rdelay: Integer;
152 alpha: Integer;
153 end = (
154 (name: ''; w: 0; h: 0; anim: (loop: false; delay: 0; frames: 0; back: false); rdelay: 0; alpha: 0),
155 (name: 'TELEPORT'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 10; back: false); rdelay: 0; alpha: 0),
156 (name: 'FLAME'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 11; back: false); rdelay: 0; alpha: 0),
157 (name: 'EROCKET'; w: 128; h: 128; anim: (loop: false; delay: 6; frames: 6; back: false); rdelay: 0; alpha: 0),
158 (name: 'EBFG'; w: 128; h: 128; anim: (loop: false; delay: 6; frames: 6; back: false); rdelay: 0; alpha: 0),
159 (name: 'BFGHIT'; w: 64; h: 64; anim: (loop: false; delay: 4; frames: 4; back: false); rdelay: 0; alpha: 0),
160 (name: 'FIRE'; w: 64; h: 128; anim: (loop: false; delay: 4; frames: 8; back: false); rdelay: 2; alpha: 0),
161 (name: 'ITEMRESPAWN'; w: 32; h: 32; anim: (loop: false; delay: 4; frames: 5; back: true); rdelay: 0; alpha: 0),
162 (name: 'SMOKE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 0),
163 (name: 'ESKELFIRE'; w: 64; h: 64; anim: (loop: false; delay: 8; frames: 3; back: false); rdelay: 0; alpha: 0),
164 (name: 'EPLASMA'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 4; back: true); rdelay: 0; alpha: 0),
165 (name: 'EBSPFIRE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 5; back: false); rdelay: 0; alpha: 0),
166 (name: 'EIMPFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
167 (name: 'ECACOFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
168 (name: 'EBARONFIRE'; w: 64; h: 64; anim: (loop: false; delay: 6; frames: 3; back: false); rdelay: 0; alpha: 0),
169 (name: 'TELEPORT'; w: 64; h: 64; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 0), // fast
170 (name: 'SMOKE'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 10; back: false); rdelay: 0; alpha: 150), // transparent
171 (name: 'FLAME'; w: 32; h: 32; anim: (loop: false; delay: 3; frames: 11; back: false); rdelay: 2; alpha: 0) // random
172 );
173 {$ENDIF}
174
175 ShotAnim: array [0..WEAPON_LAST] of record
176 name: AnsiString;
177 w, h: Integer;
178 anim: TAnimInfo;
179 end = (
180 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 0 KASTET
181 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 1 SAW
182 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 2 PISTOL
183 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 3 SHOTGUN1
184 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 4 SHOTGUN2
185 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 5 CHAINGUN
186 (name: 'BROCKET'; w: 64; h: 32; anim: (loop: true; delay: 1; frames: 1; back: false)), // 6 ROCKETLAUNCHER
187 (name: 'BPLASMA'; w: 16; h: 16; anim: (loop: true; delay: 5; frames: 2; back: false)), // 7 PLASMA
188 (name: 'BBFG'; w: 64; h: 64; anim: (loop: true; delay: 6; frames: 2; back: false)), // 8 BFG
189 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 9 SUPERPULEMET
190 (name: 'FLAME'; w: 32; h: 32; anim: (loop: true; delay: 6; frames: 0{11}; back: false)), // 10 FLAMETHROWER
191 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 11
192 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 12
193 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 13
194 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 14
195 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 15
196 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 16
197 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 17
198 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 18
199 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 19
200 (name: ''; w: 0; h: 0; anim: (loop: true; delay: 0; frames: 0; back: false)), // 20 ZOMPY_PISTOL
201 (name: 'BIMPFIRE'; w: 16; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 21 IMP_FIRE
202 (name: 'BBSPFIRE'; w: 16; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 22 BSP_FIRE
203 (name: 'BCACOFIRE'; w: 16; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 23 CACO_FIRE
204 (name: 'BBARONFIRE'; w: 64; h: 16; anim: (loop: true; delay: 4; frames: 2; back: false)), // 24 BARON_FIRE
205 (name: 'BMANCUBFIRE'; w: 64; h: 32; anim: (loop: true; delay: 4; frames: 2; back: false)), // 25 MANCUB_FIRE
206 (name: 'BSKELFIRE'; w: 64; h: 64; anim: (loop: true; delay: 5; frames: 2; back: false)) // 26 SKEL_FIRE
207 );
208
209 {$IFDEF ENABLE_SHELLS}
210 ShellAnim: array [0..SHELL_LAST] of record
211 name: AnsiString;
212 dx, dy: Integer;
213 end = (
214 (name: 'EBULLET'; dx: 2; dy: 1), // 0 SHELL_BULLET
215 (name: 'ESHELL'; dx: 4; dy: 2), // 1 SHELL_SHELL
216 (name: 'ESHELL'; dx: 4; dy: 2) // 2 SHELL_DBLSHELL
217 );
218 {$ENDIF}
219
220 PunchAnim: TAnimInfo = (loop: false; delay: 1; frames: 4; back: false);
221 FlagAnim: TAnimInfo = (loop: true; delay: 8; frames: 5; back: false);
222 VileFireAnim: TAnimInfo = (loop: true; delay: 2; frames: 8; back: false);
223
224 type
225 TBinHeapPanelDrawCmp = class
226 public
227 class function less (const a, b: TPanel): Boolean; inline;
228 end;
229
230 TBinHeapPanelDraw = specialize TBinaryHeapBase<TPanel, TBinHeapPanelDrawCmp>;
231
232 TMonsterAnims = array [0..ANIM_LAST, TDirection] of TGLMultiTexture;
233
234 var
235 DebugFrames: Boolean;
236 DebugCameraScale: Single;
237 FillOutsizeArea: Boolean;
238 SkyTexture: TGLTexture;
239 RenTextures: array of record
240 spec: LongInt;
241 tex: TGLMultiTexture;
242 anim: TAnimInfo;
243 end;
244 Items: array [0..ITEM_LAST] of record
245 tex: TGLMultiTexture;
246 frame: Integer;
247 end;
248 MonTextures: array [0..MONSTER_MAN] of TMonsterAnims;
249 WeapTextures: array [0..WP_LAST, 0..W_POS_LAST, 0..W_ACT_LAST] of TGLTexture;
250 ShotTextures: array [0..WEAPON_LAST] of TGLMultiTexture;
251 FlagTextures: array [0..FLAG_LAST] of TGLMultiTexture;
252 PunchTextures: array [Boolean, 0..2] of TGLMultiTexture; // [berserk, center/up/down]
253 VileFire: TGLMultiTexture;
254 InvulPenta: TGLTexture;
255 IndicatorTexture: TGLTexture;
256 TalkTexture: TGLTexture;
257 Models: array of record
258 anim: array [TDirection, 0..A_LAST] of record
259 base, mask: TGLMultiTexture;
260 end;
261 {$IFDEF ENABLE_GIBS}
262 gibs: record
263 base, mask: TGLTextureArray;
264 rect: TRectArray;
265 end;
266 {$ENDIF}
267 end;
268
269 {$IFDEF ENABLE_SHELLS}
270 ShellTextures: array [0..SHELL_LAST] of TGLTexture;
271 {$ENDIF}
272 {$IFDEF ENABLE_GFX}
273 GFXTextures: array [0..R_GFX_LAST] of TGLMultiTexture;
274 gfxlist: array of record
275 typ: Byte;
276 x, y: Integer;
277 oldX, oldY: Integer;
278 anim: TAnimInfo;
279 time: LongWord;
280 frame: LongInt;
281 end = nil;
282 {$ENDIF}
283
284 FlagFrame: LongInt;
285 plist: TBinHeapPanelDraw = nil;
286
287 class function TBinHeapPanelDrawCmp.less (const a, b: TPanel): Boolean; inline;
288 begin
289 if a.tag < b.tag then begin result := true; exit; end;
290 if a.tag > b.tag then begin result := false; exit; end;
291 result := a.arrIdx < b.arrIdx;
292 end;
293
294 procedure r_Map_Initialize;
295 begin
296 FlagFrame := 0;
297 plist := TBinHeapPanelDraw.Create();
298 end;
299
300 procedure r_Map_Finalize;
301 begin
302 r_Common_FreeAndNil(plist);
303 FlagFrame := 0;
304 end;
305
306 procedure r_Map_FreeModel (i: Integer);
307 var a: Integer; d: TDirection;
308 begin
309 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
310 begin
311 for a := A_STAND to A_LAST do
312 begin
313 r_Common_FreeAndNil(Models[i].anim[d, a].base);
314 r_Common_FreeAndNil(Models[i].anim[d, a].mask);
315 end;
316 end;
317 {$IFDEF ENABLE_GIBS}
318 if Models[i].gibs.base <> nil then
319 for a := 0 to High(Models[i].gibs.base) do
320 r_Common_FreeAndNil(Models[i].gibs.base[a]);
321 if Models[i].gibs.mask <> nil then
322 for a := 0 to High(Models[i].gibs.mask) do
323 r_Common_FreeAndNil(Models[i].gibs.mask[a]);
324 Models[i].gibs.base := nil;
325 Models[i].gibs.mask := nil;
326 Models[i].gibs.rect := nil;
327 {$ENDIF}
328 end;
329
330 procedure r_Map_LoadModel (i: Integer);
331 var prefix: AnsiString; a: Integer; d: TDirection; m: ^TPlayerModelInfo;
332 begin
333 ASSERT(i < Length(Models));
334 ASSERT(i < Length(PlayerModelsArray));
335 r_Map_FreeModel(i);
336 m := @PlayerModelsArray[i];
337 prefix := m.FileName + ':TEXTURES/';
338 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
339 begin
340 for a := A_STAND to A_LAST do
341 begin
342 Models[i].anim[d, a].base := nil;
343 Models[i].anim[d, a].mask := nil;
344 if m.anim[d, a].resource <> '' then
345 Models[i].anim[d, a].base := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].resource, 64, 64, m.anim[d, a].frames, [TGLHints.txNoRepeat], true);
346 if m.anim[d, a].mask <> '' then
347 Models[i].anim[d, a].mask := r_Textures_LoadMultiFromFileAndInfo(prefix + m.anim[d, a].mask, 64, 64, m.anim[d, a].frames, [TGLHints.txNoRepeat], true);
348 end
349 end;
350 {$IFDEF ENABLE_GIBS}
351 Models[i].gibs.base := nil;
352 Models[i].gibs.mask := nil;
353 Models[i].gibs.rect := nil;
354 if m.GibsCount > 0 then
355 begin
356 SetLength(Models[i].gibs.base, m.GibsCount);
357 SetLength(Models[i].gibs.mask, m.GibsCount);
358 SetLength(Models[i].gibs.rect, m.GibsCount);
359 for a := 0 to m.GibsCount - 1 do
360 Models[i].gibs.rect[a] := DefaultGibSize;
361 if r_Textures_LoadStreamFromFile(prefix + m.GibsResource, 32, 32, m.GibsCount, m.GibsCount, Models[i].gibs.base, Models[i].gibs.rect, [TGLHints.txNoRepeat]) then
362 begin
363 if r_Textures_LoadStreamFromFile(prefix + m.GibsMask, 32, 32, m.GibsCount, m.GibsCount, Models[i].gibs.mask, nil, [TGLHints.txNoRepeat]) then
364 begin
365 // ok
366 end;
367 end;
368 end;
369 {$ENDIF}
370 end;
371
372 procedure r_Map_LoadMonsterAnim (m, a: Integer; d: TDirection);
373 const dir: array [TDirection] of AnsiString = ('_L', '');
374 var w, h, count: Integer;
375 begin
376 count := MONSTER_ANIMTABLE[m].AnimCount[a];
377 if count > 0 then
378 begin
379 w := MTABLE[m].w;
380 h := MTABLE[m].h;
381 if (m = MONSTER_SOUL) and (a = ANIM_DIE) then
382 begin
383 // special case
384 w := 128;
385 h := 128;
386 end;
387 MonTextures[m, a, d] := r_Textures_LoadMultiFromFileAndInfo(
388 GameWAD + ':MTEXTURES/' + MONSTERTABLE[m].name + '_' + ANIMTABLE[a].name + dir[d],
389 w,
390 h,
391 count,
392 [TGLHints.txNoRepeat],
393 False
394 );
395 end
396 else
397 MonTextures[m, a, d] := nil;
398 end;
399
400 procedure r_Map_Load;
401 const
402 WeapName: array [0..WP_LAST] of AnsiString = ('', 'CSAW', 'HGUN', 'SG', 'SSG', 'MGUN', 'RKT', 'PLZ', 'BFG', 'SPL', 'FLM');
403 WeapPos: array [0..W_POS_LAST] of AnsiString = ('', '_UP', '_DN');
404 WeapAct: array [0..W_ACT_LAST] of AnsiString = ('', '_FIRE');
405 PunchName: array [Boolean] of AnsiString = ('PUNCH', 'PUNCHB');
406 var
407 i, j, k: Integer; d: TDirection; b: Boolean;
408 begin
409 // --------- items --------- //
410 r_Common_SetLoading(_lc[I_LOAD_ITEMS_DATA], ITEM_LAST + 1);
411 for i := 0 to ITEM_LAST do
412 begin
413 Items[i].tex := r_Common_LoadTextureMultiFromFileAndInfo(
414 GameWAD + ':TEXTURES/' + ItemAnim[i].name,
415 ItemAnim[i].w,
416 ItemAnim[i].h,
417 ItemAnim[i].anim.frames,
418 [TGLHints.txNoRepeat],
419 false
420 );
421 Items[i].frame := 0;
422 end;
423 // --------- monsters --------- //
424 r_Common_SetLoading(_lc[I_LOAD_MONSTER_TEXTURES], MONSTER_MAN - MONSTER_DEMON + 1);
425 for i := MONSTER_DEMON to MONSTER_MAN do
426 begin
427 for j := 0 to ANIM_LAST do
428 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
429 r_Map_LoadMonsterAnim(i, j, d);
430 r_Common_StepLoading(1);
431 end;
432 VileFire := r_Textures_LoadMultiFromFileAndInfo(GameWAD + ':TEXTURES/FIRE', 64, 128, VileFireAnim.frames, [TGLHints.txNoRepeat]);
433 // --------- player models --------- //
434 if PlayerModelsArray <> nil then
435 begin
436 r_Common_SetLoading(_lc[I_LOAD_MODELS], Length(PlayerModelsArray));
437 SetLength(Models, Length(PlayerModelsArray));
438 for i := 0 to High(PlayerModelsArray) do
439 begin
440 r_Map_LoadModel(i);
441 r_Common_StepLoading(1);
442 end;
443 end;
444 // --------- player weapons --------- //
445 r_Common_SetLoading(_lc[I_LOAD_WEAPONS_DATA], WP_LAST);
446 for i := 1 to WP_LAST do
447 begin
448 for j := 0 to W_POS_LAST do
449 for k := 0 to W_ACT_LAST do
450 WeapTextures[i, j, k] := r_Textures_LoadFromFile(GameWAD + ':WEAPONS\' + WeapName[i] + WeapPos[j] + WeapAct[k], [TGLHints.txNoRepeat]);
451 r_Common_StepLoading(1);
452 end;
453 // --------- gfx animations --------- //
454 {$IFDEF ENABLE_GFX}
455 r_Common_SetLoading('GFX Effects', R_GFX_LAST);
456 for i := 1 to R_GFX_LAST do
457 begin
458 if GFXAnim[i].anim.frames > 0 then
459 GFXTextures[i] := r_Common_LoadTextureMultiFromFileAndInfo(GameWad + ':TEXTURES/' + GFXAnim[i].name, GFXAnim[i].w, GFXAnim[i].h, GFXAnim[i].anim.frames, [TGLHints.txNoRepeat]);
460 end;
461 {$ENDIF}
462 // --------- shots --------- //
463 r_Common_SetLoading('Weapon splahses', WEAPON_LAST + 1);
464 for i := 0 to WEAPON_LAST do
465 begin
466 if ShotAnim[i].anim.frames > 0 then
467 ShotTextures[i] := r_Common_LoadTextureMultiFromFileAndInfo(GameWad + ':TEXTURES/' + ShotAnim[i].name, ShotAnim[i].w, ShotAnim[i].h, ShotAnim[i].anim.frames, [TGLHints.txNoRepeat]);
468 end;
469 // --------- flags --------- //
470 r_Common_SetLoading('Flags', 2);
471 FlagTextures[FLAG_NONE] := nil;
472 FlagTextures[FLAG_RED] := r_Common_LoadTextureMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGRED', 64, 64, 5, [TGLHints.txNoRepeat]);
473 FlagTextures[FLAG_BLUE] := r_Common_LoadTextureMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGBLUE', 64, 64, 5, [TGLHints.txNoRepeat]);
474 // FlagTextures[FLAG_DOM] := r_Common_LoadTextureMultiFromFileAndInfo(GameWad + ':TEXTURES/FLAGDOM', 64, 64, 8, [TGLHints.txNoRepeat]);
475 // --------- shells --------- //
476 {$IFDEF ENABLE_SHELLS}
477 r_Common_SetLoading('Shells', SHELL_LAST + 1);
478 for i := 0 to SHELL_LAST do
479 ShellTextures[i] := r_Common_LoadTextureFromFile(GameWad + ':TEXTURES/' + ShellAnim[i].name, [TGLHints.txNoRepeat]);
480 {$ENDIF}
481 // --------- other --------- //
482 r_Common_SetLoading('Effects', 3 * 2 + 3);
483 for b := false to true do
484 begin
485 for i := 0 to 2 do
486 PunchTextures[b, i] := r_Common_LoadTextureMultiFromFileAndInfo(GameWad + ':WEAPONS/' + PunchName[b] + WeapPos[i], 64, 64, PunchAnim.frames, [TGLHints.txNoRepeat]);
487 end;
488 InvulPenta := r_Common_LoadTextureFromFile(GameWad + ':TEXTURES/PENTA', [TGLHints.txNoRepeat]);
489 IndicatorTexture := r_Common_LoadTextureFromFile(GameWad + ':TEXTURES/PLRIND', [TGLHints.txNoRepeat]);
490 TalkTexture := r_Common_LoadTextureFromFile(GameWad + ':TEXTURES/TALKBUBBLE', [TGLHints.txNoRepeat]);
491 end;
492
493 procedure r_Map_Free;
494 var i, j, k: Integer; d: TDirection; b: Boolean;
495 begin
496 r_Common_FreeAndNil(TalkTexture);
497 r_Common_FreeAndNil(IndicatorTexture);
498 r_Common_FreeAndNil(InvulPenta);
499 for b := false to true do
500 for i := 0 to 2 do
501 r_Common_FreeAndNil(PunchTextures[b, i]);
502 {$IFDEF ENABLE_SHELLS}
503 for i := 0 to SHELL_LAST do
504 r_Common_FreeAndNil(ShellTextures[i]);
505 {$ENDIF}
506 for i := 0 to FLAG_LAST do
507 r_Common_FreeAndNil(FlagTextures[i]);
508 for i := 0 to WEAPON_LAST do
509 r_Common_FreeAndNil(ShotTextures[i]);
510 {$IFDEF ENABLE_GFX}
511 SetLength(gfxlist, 0);
512 for i := 0 to R_GFX_LAST do
513 r_Common_FreeAndNil(GFXTextures[i]);
514 {$ENDIF}
515 for i := 1 to WP_LAST do
516 for j := 0 to W_POS_LAST do
517 for k := 0 to W_ACT_LAST do
518 r_Common_FreeAndNil(WeapTextures[i, j, k]);
519 if Models <> nil then
520 for i := 0 to High(Models) do
521 r_Map_FreeModel(i);
522 for i := MONSTER_DEMON to MONSTER_MAN do
523 for j := 0 to ANIM_LAST do
524 for d := TDirection.D_LEFT to TDirection.D_RIGHT do
525 r_Common_FreeAndNil(MonTextures[i, j, d]);
526 for i := 0 to ITEM_LAST do
527 r_Common_FreeAndNil(Items[i].tex);
528 end;
529
530 procedure r_Map_FreeTextures;
531 var i: Integer;
532 begin
533 plist.Clear;
534 r_Common_FreeAndNil(SkyTexture);
535 if RenTextures <> nil then
536 for i := 0 to High(RenTextures) do
537 r_Common_FreeAndNil(RenTextures[i].tex);
538 SetLength(RenTextures, 0);
539 end;
540
541 procedure r_Map_LoadTextures;
542 const DefaultAnimInfo: TAnimInfo = (loop: true; delay: 1; frames: 1; back: false);
543 var i, n: Integer; txt: TAnimTextInfo;
544 begin
545 r_Map_FreeTextures;
546 if Textures <> nil then
547 begin
548 n := Length(Textures);
549 SetLength(RenTextures, n);
550 r_Common_SetLoading(_lc[I_LOAD_TEXTURES], n);
551 for i := 0 to n - 1 do
552 begin
553 RenTextures[i].tex := nil;
554 RenTextures[i].anim := DefaultAnimInfo;
555 case Textures[i].TextureName of
556 TEXTURE_NAME_WATER: RenTextures[i].spec := TEXTURE_SPECIAL_WATER;
557 TEXTURE_NAME_ACID1: RenTextures[i].spec := TEXTURE_SPECIAL_ACID1;
558 TEXTURE_NAME_ACID2: RenTextures[i].spec := TEXTURE_SPECIAL_ACID2;
559 else
560 RenTextures[i].spec := 0;
561 RenTextures[i].tex := r_Textures_LoadMultiTextFromFile(Textures[i].FullName, txt, []);
562 if RenTextures[i].tex <> nil then
563 begin
564 RenTextures[i].anim := txt.anim;
565 r_Common_StepLoading(1);
566 end
567 else
568 begin
569 e_LogWritefln('r_Map_LoadTextures: failed to load texture: %s', [Textures[i].FullName]);
570 end;
571 end;
572 ASSERT(RenTextures[i].anim.frames > 0);
573 ASSERT(RenTextures[i].anim.delay > 0);
574 end;
575 end;
576 if gMapInfo.SkyFullName <> '' then
577 begin
578 r_Common_SetLoading(_lc[I_LOAD_SKY], 1);
579 SkyTexture := r_Common_LoadTextureFromFile(gMapInfo.SkyFullName, [TGLHints.txNoRepeat]);
580 end;
581 plist.Clear;
582 end;
583
584 procedure r_Map_DrawPanel (p: TPanel);
585 var Texture: Integer; t: TGLMultiTexture; tex: TGLTexture; count, frame: LongInt; a: TAnimInfo;
586 begin
587 ASSERT(p <> nil);
588 if p.FCurTexture >= 0 then
589 begin
590 ASSERT(p.FCurTexture <= High(p.TextureIDs));
591 Texture := p.TextureIDs[p.FCurTexture].Texture;
592 t := nil;
593 ASSERT(Texture >= -1);
594 ASSERT(Texture <= High(RenTextures));
595 if Texture >= 0 then
596 begin
597 t := RenTextures[Texture].tex;
598 if (RenTextures[Texture].spec = 0) or (t <> nil) then
599 begin
600 count := 0; frame := 0;
601 if p.AnimTime <= gTime then
602 begin
603 a := RenTextures[Texture].anim;
604 a.loop := p.AnimLoop;
605 g_Anim_GetFrameByTime(a, (gTime - p.AnimTime) DIV GAME_TICK, count, frame);
606 end;
607 if t <> nil then
608 begin
609 tex := t.GetTexture(frame);
610 r_Draw_TextureRepeat(tex, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255 - p.alpha, p.blending);
611 end
612 else
613 r_Draw_TextureRepeat(nil, p.x, p.y, p.width, p.height, false, 255, 255, 255, 255, false);
614 end;
615 end;
616
617 if t = nil then
618 begin
619 case RenTextures[Texture].spec of
620 TEXTURE_SPECIAL_WATER: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 0, 255, 255);
621 TEXTURE_SPECIAL_ACID1: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 0, 230, 0, 255);
622 TEXTURE_SPECIAL_ACID2: r_Draw_Filter(p.x, p.y, p.x + p.width, p.y + p.height, 230, 0, 0, 255);
623 end
624 end
625 end
626 end;
627
628 procedure r_Map_DrawPanelType (panelTyp: DWORD);
629 var tagMask, i: Integer; p: TPanel;
630 begin
631 i := 0;
632 tagMask := PanelTypeToTag(panelTyp);
633 while plist.count > 0 do
634 begin
635 p := TPanel(plist.Front());
636 if (p.tag and tagMask) = 0 then
637 break;
638 r_Map_DrawPanel(p);
639 Inc(i);
640 plist.PopFront
641 end;
642 end;
643
644 procedure r_Map_DrawItems (x, y, w, h: Integer; drop: Boolean);
645 var i, xx, yy: Integer; it: PItem; t: TGLMultiTexture; tex: TGLTexture;
646 begin
647 if ggItems <> nil then
648 begin
649 for i := 0 to High(ggItems) do
650 begin
651 it := @ggItems[i];
652 if it.used and it.alive and (it.dropped = drop) and (it.ItemType > ITEM_NONE) and (it.ItemType <= ITEM_LAST) then
653 begin
654 t := Items[it.ItemType].tex;
655 if g_Collide(it.obj.x, it.obj.y, t.width, t.height, x, y, w, h) then
656 begin
657 r_Common_GetObjectPos(it.obj, xx, yy);
658 tex := t.GetTexture(Items[it.ItemType].frame);
659 r_Draw_TextureRepeat(tex, xx, yy, tex.width, tex.height, false, 255, 255, 255, 255, false);
660 if DebugFrames then
661 begin
662 r_Draw_Rect(
663 xx + it.obj.rect.x, // it.obj.x + it.obj.rect.x,
664 yy + it.obj.rect.y, // it.obj.y + it.obj.rect.y,
665 xx + it.obj.rect.x + it.obj.rect.width, // it.obj.x + it.obj.rect.x + it.obj.rect.width,
666 yy + it.obj.rect.y + it.obj.rect.height, // it.obj.y + it.obj.rect.y + it.obj.rect.height,
667 0, 255, 0, 255
668 );
669 end;
670 end;
671 end;
672 end;
673 end;
674 end;
675
676 function r_Map_GetMonsterTexture (m, a: Integer; d: TDirection; out t: TGLMultiTexture; out dx, dy: Integer; out flip: Boolean): Boolean;
677 // var c: Integer;
678 begin
679 t := nil; dx := 0; dy := 0; flip := false;
680 result := MonTextures[m, a, d] <> nil;
681 if result = false then
682 begin
683 flip := true;
684 if d = TDirection.D_RIGHT then d := TDirection.D_LEFT else d := TDirection.D_RIGHT;
685 result := MonTextures[m, a, d] <> nil;
686 end;
687 if result = true then
688 begin
689 t := MonTextures[m, a, d];
690 if d = TDirection.D_LEFT then
691 begin
692 dx := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].X;
693 dy := MONSTER_ANIMTABLE[m].AnimDeltaLeft[a].Y;
694 end
695 else
696 begin
697 dx := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].X;
698 dy := MONSTER_ANIMTABLE[m].AnimDeltaRight[a].Y;
699 end;
700 if flip then
701 begin
702 // c := (MONSTERTABLE[MonsterType].Rect.X - dx) + MONSTERTABLE[MonsterType].Rect.Width;
703 // dx := MTABLE[m].width - c - MONSTERTABLE[MonsterType].Rect.X;
704 dx := -dx;
705 end;
706 end;
707 end;
708
709 procedure r_Map_DrawMonsterAttack (constref mon: TMonster);
710 var o: TObj; count, frame, xx, yy: LongInt; tex: TGLTexture;
711 begin
712 if VileFire <> nil then
713 begin
714 if (mon.MonsterType = MONSTER_VILE) and (mon.MonsterState = MONSTATE_SHOOT) and (mon.VileFireTime <= gTime) then
715 begin
716 if r_Common_GetPosByUID(mon.MonsterTargetUID, o, xx, yy) then
717 begin
718 g_Anim_GetFrameByTime(VileFireAnim, (gTime - mon.VileFireTime) DIV GAME_TICK, count, frame);
719 tex := VileFire.GetTexture(frame);
720 r_Draw_TextureRepeat(tex, xx + o.rect.x + (o.rect.width div 2) - VILEFIRE_DX, yy + o.rect.y + o.rect.height - VILEFIRE_DY, tex.width, tex.height, False, 255, 255, 255, 255, false);
721 end;
722 end;
723 end;
724 end;
725
726 procedure r_Map_DrawMonster (constref mon: TMonster);
727 var m, a, xx, yy, dx, dy: Integer; d: TDirection; flip: Boolean; t: TGLMultiTexture;
728 begin
729 m := mon.MonsterType;
730 a := mon.MonsterAnim;
731 d := mon.GameDirection;
732
733 r_Common_GetObjectPos(mon.obj, xx, yy);
734 if r_Map_GetMonsterTexture(m, a, d, t, dx, dy, flip) then
735 begin
736 r_Draw_MultiTextureRepeat(t, mon.DirAnim[a, d], false, xx + dx, yy + dy, t.width, t.height, flip, 255, 255, 255, 255, false);
737 end;
738 if DebugFrames then
739 begin
740 r_Draw_Rect(
741 xx + mon.obj.rect.x, // mon.obj.x + mon.obj.rect.x,
742 yy + mon.obj.rect.y, // mon.obj.y + mon.obj.rect.y,
743 xx + mon.obj.rect.x + mon.obj.rect.width, // mon.obj.x + mon.obj.rect.x + mon.obj.rect.width,
744 yy + mon.obj.rect.y + mon.obj.rect.height, // mon.obj.y + mon.obj.rect.y + mon.obj.rect.height,
745 0, 255, 0, 255
746 );
747 end;
748 end;
749
750 procedure r_Map_DrawMonsters (x, y, w, h: Integer);
751 var i: Integer; m: TMonster;
752 begin
753 if gMonsters <> nil then
754 begin
755 for i := 0 to High(gMonsters) do
756 begin
757 m := gMonsters[i];
758 if m <> nil then
759 begin
760 r_Map_DrawMonsterAttack(m);
761 // TODO select from grid
762 if g_Collide(m.obj.x + m.obj.rect.x, m.obj.y + m.obj.rect.y, m.obj.rect.width, m.obj.rect.height, x, y, w, h) then
763 r_Map_DrawMonster(m);
764 end;
765 end;
766 end;
767 end;
768
769 function r_Map_GetPlayerModelTex (i: Integer; var a: Integer; var d: TDirection; out flip: Boolean): Boolean;
770 begin
771 flip := false;
772 result := Models[i].anim[d, a].base <> nil;
773 if result = false then
774 begin
775 flip := true;
776 if d = TDirection.D_LEFT then d := TDirection.D_RIGHT else d := TDirection.D_LEFT;
777 result := Models[i].anim[d, a].base <> nil;
778 end;
779 end;
780
781 procedure r_Map_DrawPlayerModel (pm: TPlayerModel; x, y: Integer; alpha: Byte);
782 var a, pos, act, xx, yy, angle: Integer; d: TDirection; flip, back: Boolean; t: TGLMultiTexture; tex: TGLTexture; c: TRGB;
783 begin
784 a := pm.CurrentAnimation;
785 d := pm.Direction;
786
787 (* draw flag*)
788 t := FlagTextures[pm.Flag];
789 if (t <> nil) and not (a in [A_DIE1, A_DIE2]) then
790 begin
791 flip := d = TDirection.D_RIGHT;
792 angle := PlayerModelsArray[pm.id].FlagAngle;
793 xx := PlayerModelsArray[pm.id].FlagPoint.X;
794 yy := PlayerModelsArray[pm.id].FlagPoint.Y;
795 tex := t.GetTexture(FlagFrame);
796 r_Draw_TextureRepeatRotate(
797 tex,
798 x + IfThen(flip, 2 * FLAG_BASEPOINT.X - xx + 1, xx - 1) - FLAG_BASEPOINT.X,
799 y + yy - FLAG_BASEPOINT.Y + 1,
800 tex.width,
801 tex.height,
802 flip,
803 255, 255, 255, 255, false,
804 IfThen(flip, 64 - FLAG_BASEPOINT.X, FLAG_BASEPOINT.X),
805 FLAG_BASEPOINT.Y,
806 IfThen(flip, angle, -angle)
807 );
808 end;
809
810 (* draw weapon *)
811 if PlayerModelsArray[pm.id].HaveWeapon and not (a in [A_DIE1, A_DIE2, A_PAIN]) then
812 begin
813 case a of
814 A_SEEUP, A_ATTACKUP: pos := W_POS_UP;
815 A_SEEDOWN, A_ATTACKDOWN: pos := W_POS_DOWN;
816 else pos := W_POS_NORMAL;
817 end;
818 if (a in [A_ATTACK, A_ATTACKUP, A_ATTACKDOWN]) or pm.GetFire() then
819 act := W_ACT_FIRE
820 else
821 act := W_ACT_NORMAL;
822 tex := WeapTextures[pm.CurrentWeapon, pos, act];
823 if tex <> nil then
824 begin
825 xx := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].X;
826 yy := PlayerModelsArray[pm.id].WeaponPoints[pm.CurrentWeapon, a, d, pm.AnimState.CurrentFrame].Y;
827 r_Draw_Texture(
828 tex,
829 x + xx,
830 y + yy,
831 tex.width,
832 tex.height,
833 d = TDirection.D_LEFT,
834 255, 255, 255, alpha, false
835 );
836 end;
837 end;
838
839 (* draw body *)
840 if r_Map_GetPlayerModelTex(pm.id, a, d, flip) then
841 begin
842 t := Models[pm.id].anim[d, a].base;
843 back := PlayerModelsArray[pm.id].anim[d, a].back;
844 r_Draw_MultiTextureRepeat(t, pm.AnimState, back, x, y, t.width, t.height, flip, 255, 255, 255, alpha, false);
845 t := Models[pm.id].anim[d, a].mask;
846 if t <> nil then
847 begin
848 c := pm.Color;
849 r_Draw_MultiTextureRepeat(t, pm.AnimState, back, x, y, t.width, t.height, flip, c.r, c.g, c.b, alpha, false);
850 end;
851 end;
852 end;
853
854 procedure r_Map_DrawBubble (x, y: Integer; cb, cf: TRGB);
855 const w = 20; h = 14;
856 const dx = 6; dy = 8; dot = 6; size = 2;
857 const tx = 6; ty = h - 1;
858 begin
859 // Outer box (top/down)
860 r_Draw_FillRect(x + 1, y, x + w - 1, y + 1, cb.R, cb.G, cb.B, 255);
861 r_Draw_FillRect(x + 1, y + h - 1, x + w - 1, y + h, cb.R, cb.G, cb.B, 255);
862 // Outer box (left/right)
863 r_Draw_FillRect(x, y + 1, x + 1, y + h - 1, cb.R, cb.G, cb.B, 255);
864 r_Draw_FillRect(x + w - 1, y + 1, x + w, y + h - 1, cb.R, cb.G, cb.B, 255);
865 // Outer tail
866 r_Draw_FillRect(x + tx - 1, y + ty + 0, x + tx + 3 + 1, y + ty + 1, cb.R, cb.G, cb.B, 255);
867 r_Draw_FillRect(x + tx - 1, y + ty + 1, x + tx + 2 + 1, y + ty + 2, cb.R, cb.G, cb.B, 255);
868 r_Draw_FillRect(x + tx - 1, y + ty + 2, x + tx + 1 + 1, y + ty + 3, cb.R, cb.G, cb.B, 255);
869 r_Draw_FillRect(x + tx - 1, y + ty + 3, x + tx + 0 + 1, y + ty + 4, cb.R, cb.G, cb.B, 255);
870 // Inner tail
871 r_Draw_FillRect(x + tx, y + ty + 0, x + tx + 3, y + ty + 1, cf.R, cf.G, cf.B, 255);
872 r_Draw_FillRect(x + tx, y + ty + 1, x + tx + 2, y + ty + 2, cf.R, cf.G, cf.B, 255);
873 r_Draw_FillRect(x + tx, y + ty + 2, x + tx + 1, y + ty + 3, cf.R, cf.G, cf.B, 255);
874 // Inner box
875 r_Draw_FillRect(x + 1, y + 1, x + w - 1, y + h - 1, cf.R, cf.G, cf.B, 255);
876 // Dots
877 r_Draw_FillRect(x + dx + 0*3, y + dy, x + dx + 0*3 + size, y + dy + size, cb.R, cb.G, cb.B, 255);
878 r_Draw_FillRect(x + dx + 1*3, y + dy, x + dx + 1*3 + size, y + dy + size, cb.R, cb.G, cb.B, 255);
879 r_Draw_FillRect(x + dx + 2*3, y + dy, x + dx + 2*3 + size, y + dy + size, cb.R, cb.G, cb.B, 255);
880 end;
881
882 procedure r_Map_DrawTalkBubble (p: TPlayer);
883 var xx, yy, x, y: Integer; cb, cf: TRGB;
884 begin
885 r_Common_GetPlayerPos(p, xx, yy);
886 x := xx + p.obj.rect.x + p.obj.rect.width div 2;
887 y := yy;
888 cb := _RGB(63, 63, 63);
889 cf := _RGB(240, 240, 240);
890 case gChatBubble of
891 1: // simple text
892 begin
893 r_Common_DrawText('[...]', x, y, 255, 255, 255, 255, stdfont, TBasePoint.BP_DOWN);
894 end;
895 2: // adv team color
896 begin
897 case p.Team of
898 TEAM_RED: cb := _RGB(255, 63, 63);
899 TEAM_BLUE: cb := _RGB(63, 63, 255);
900 end;
901 r_Map_DrawBubble(x, y - 18, cb, cf);
902 end;
903 3: // adv player color
904 begin
905 cb := p.Model.Color;
906 cf.R := MIN(cb.R * 2 + 64, 255);
907 cf.G := MIN(cb.G * 2 + 64, 255);
908 cf.B := MIN(cb.B * 2 + 64, 255);
909 if (ABS(cf.R - cb.R) < 32) or (ABS(cf.G - cb.G) < 32) or (ABS(cf.B - cb.B) < 32) then
910 begin
911 cb.R := MAX(cf.R div 2 - 16, 0);
912 cb.G := MAX(cf.G div 2 - 16, 0);
913 cb.B := MAX(cf.B div 2 - 16, 0);
914 end;
915 r_Map_DrawBubble(x, y - 18, cb, cf);
916 end;
917 4: // textured
918 if TalkTexture <> nil then
919 begin
920 r_Common_DrawTexture(TalkTexture, x + 5, y, TalkTexture.width, TalkTexture.height, TBasePoint.BP_DOWN);
921 end;
922 end;
923 end;
924
925 procedure r_Map_DrawPlayer (p, drawed: TPlayer);
926 var x, y, ax, ay, w, h: Integer; b, flip: Boolean; t: TGLMultiTexture; tex: TGLTexture; alpha: Byte; count, frame: LongInt;
927 begin
928 if p.alive then
929 begin
930 r_Common_GetPlayerPos(p, x, y);
931
932 (* punch effect *)
933 if p.PunchTime <= gTime then
934 begin
935 g_Anim_GetFrameByTime(PunchAnim, (gTime - p.PunchTime) DIV GAME_TICK, count, frame);
936 if count < 1 then
937 begin
938 b := R_BERSERK in p.FRulez;
939 if p.FKeys[KEY_DOWN].pressed then
940 t := PunchTextures[b, 2]
941 else if p.FKeys[KEY_UP].pressed then
942 t := PunchTextures[b, 1]
943 else
944 t := PunchTextures[b, 0];
945 if t <> nil then
946 begin
947 flip := p.Direction = TDirection.D_LEFT;
948 ax := IfThen(flip, 15 - p.Obj.Rect.X, p.Obj.Rect.X - 15); // ???
949 ay := p.Obj.Rect.Y - 11;
950 tex := t.GetTexture(frame);
951 r_Draw_TextureRepeat(tex, x + ax, y + ay, tex.width, tex.height, flip, 255, 255, 255, 255, false)
952 end;
953 end;
954 end;
955
956 (* invulnerability effect *)
957 if (InvulPenta <> nil) and (p.FMegaRulez[MR_INVUL] > gTime) and ((p <> drawed) or (p.SpawnInvul >= gTime)) then
958 begin
959 w := InvulPenta.width;
960 h := InvulPenta.height;
961 ax := p.Obj.Rect.X + (p.Obj.Rect.Width div 2) - (w div 2); // + IfThen(flip, +4, -2) // ???
962 ay := p.Obj.Rect.Y + (p.Obj.Rect.Height div 2) - (h div 2) - 7; // ???
963 r_Draw_Texture(InvulPenta, x + ax, y + ay, w, h, false, 255, 255, 255, 255, false);
964 end;
965
966 (* invisibility effect *)
967 alpha := 255;
968 if p.FMegaRulez[MR_INVIS] > gTime then
969 begin
970 if (drawed <> nil) and ((p = drawed) or ((p.Team = drawed.Team) and (gGameSettings.GameMode <> GM_DM))) then
971 begin
972 if (p.FMegaRulez[MR_INVIS] - gTime > 2100) or not ODD((p.FMegaRulez[MR_INVIS] - gTime) div 300) then
973 alpha := 55;
974 end
975 else
976 alpha := 1; // ???
977 end;
978
979 r_Map_DrawPlayerModel(p.Model, x, y, alpha);
980 end;
981
982 if DebugFrames then
983 begin
984 r_Draw_Rect(
985 x + p.obj.rect.x, // p.obj.x + p.obj.rect.x,
986 y + p.obj.rect.y, // p.obj.y + p.obj.rect.y,
987 x + p.obj.rect.x + p.obj.rect.width, // p.obj.x + p.obj.rect.x + p.obj.rect.width,
988 y + p.obj.rect.y + p.obj.rect.height, // p.obj.y + p.obj.rect.y + p.obj.rect.height,
989 0, 255, 0, 255
990 );
991 end;
992
993 if (gChatBubble > 0) and p.FKeys[KEY_CHAT].Pressed and (p.Ghost = false) then
994 if (p.FMegaRulez[MR_INVIS] <= gTime) or ((drawed <> nil) and ((p = drawed) or (p.Team = drawed.Team) and (gGameSettings.GameMode <> GM_DM))) then
995 r_Map_DrawTalkBubble(p);
996
997 // TODO draw aim
998 end;
999
1000 procedure r_Map_DrawPlayers (x, y, w, h: Integer; player: TPlayer);
1001 var i: Integer;
1002 begin
1003 if gPlayers <> nil then
1004 for i := 0 to High(gPlayers) do
1005 if gPlayers[i] <> nil then
1006 r_Map_DrawPlayer(gPlayers[i], player);
1007 end;
1008
1009 {$IFDEF ENABLE_GIBS}
1010 function r_Map_GetGibSize (m, i: Integer): TRectWH;
1011 begin
1012 result := Models[m].gibs.rect[i];
1013 end;
1014
1015 procedure r_Map_DrawGibs (x, y, w, h: Integer);
1016 var i, xx, yy, m, id, rx, ry, ra: Integer; p: PObj; t: TGLTexture;
1017 begin
1018 if gGibs <> nil then
1019 begin
1020 for i := 0 to High(gGibs) do
1021 begin
1022 if gGibs[i].alive then
1023 begin
1024 p := @gGibs[i].Obj;
1025 if g_Obj_Collide(x, y, w, h, p) then
1026 begin
1027 r_Common_GetObjectPos(p^, xx, yy);
1028 id := gGibs[i].GibID;
1029 m := gGibs[i].ModelID;
1030 t := Models[m].gibs.base[id];
1031 if t <> nil then
1032 begin
1033 rx := p.Rect.X + p.Rect.Width div 2;
1034 ry := p.Rect.Y + p.Rect.Height div 2;
1035 ra := gGibs[i].RAngle;
1036 r_Draw_TextureRepeatRotate(t, xx, yy, t.width, t.height, false, 255, 255, 255, 255, false, rx, ry, ra);
1037 t := Models[m].gibs.mask[id];
1038 if t <> nil then
1039 r_Draw_TextureRepeatRotate(t, xx, yy, t.width, t.height, false, gGibs[i].Color.R, gGibs[i].Color.G, gGibs[i].Color.B, 255, false, rx, ry, ra);
1040 // r_Draw_TextureRepeatRotate(nil, xx + p.Rect.X, yy + p.Rect.Y, p.Rect.Width, p.Rect.Height, false, 255, 255, 255, 255, false, p.Rect.Width div 2, p.Rect.Height div 2, ra);
1041 end;
1042 end;
1043 end;
1044 end;
1045 end;
1046 end;
1047 {$ENDIF}
1048
1049 {$IFDEF ENABLE_CORPSES}
1050 procedure r_Map_DrawCorpses (x, y, w, h: Integer);
1051 var i, xx, yy: Integer; p: TCorpse;
1052 begin
1053 if gCorpses <> nil then
1054 begin
1055 for i := 0 to High(gCorpses) do
1056 begin
1057 p := gCorpses[i];
1058 if (p <> nil) and (p.state <> CORPSE_STATE_REMOVEME) and (p.model <> nil) then
1059 begin
1060 r_Common_GetObjectPos(p.obj, xx, yy);
1061 r_Map_DrawPlayerModel(p.model, xx, yy, 255);
1062 end;
1063 end;
1064 end;
1065 end;
1066 {$ENDIF}
1067
1068 {$IFDEF ENABLE_GFX}
1069 function r_Map_GetGFXID (): Integer;
1070 var i: Integer;
1071 begin
1072 i := 0;
1073 if gfxlist <> nil then
1074 begin
1075 while (i < Length(gfxlist)) and (gfxlist[i].typ > 0) do
1076 Inc(i);
1077 if i >= Length(gfxlist) then
1078 SetLength(gfxlist, Length(gfxlist) + 1)
1079 end
1080 else
1081 SetLength(gfxlist, 1);
1082 gfxlist[i].typ := R_GFX_NONE;
1083 result := i
1084 end;
1085
1086 procedure r_Map_NewGFX (typ, x, y: Integer);
1087 var i: Integer;
1088 begin
1089 if gpart_dbg_enabled and (typ > 0) and (typ <= R_GFX_LAST) then
1090 begin
1091 i := r_Map_GetGFXID();
1092 if i >= 0 then
1093 begin
1094 gfxlist[i].typ := typ;
1095 gfxlist[i].x := x;
1096 gfxlist[i].y := y;
1097 gfxlist[i].oldX := x;
1098 gfxlist[i].oldY := y;
1099 gfxlist[i].anim := GFXAnim[typ].anim;
1100 gfxlist[i].time := gTime DIV GAME_TICK;
1101 gfxlist[i].frame := 0;
1102 INC(gfxlist[i].anim.delay, Random(GFXAnim[typ].rdelay));
1103 end;
1104 end;
1105 end;
1106
1107 procedure r_Map_ResetGFX;
1108 begin
1109 SetLength(gfxlist, 0);
1110 end;
1111
1112 procedure r_Map_UpdateGFX (tick: LongWord);
1113 var i: Integer; count: LongInt;
1114 begin
1115 if gfxlist <> nil then
1116 begin
1117 for i := 0 to High(gfxlist) do
1118 begin
1119 if (gfxlist[i].typ > 0) and (tick >= gfxlist[i].time) then
1120 begin
1121 g_Anim_GetFrameByTime(gfxlist[i].anim, tick - gfxlist[i].time, count, gfxlist[i].frame);
1122 if count < 1 then
1123 begin
1124 gfxlist[i].oldX := gfxlist[i].x;
1125 gfxlist[i].oldY := gfxlist[i].y;
1126 case gfxlist[i].typ of
1127 R_GFX_FLAME, R_GFX_SMOKE:
1128 begin
1129 if Random(3) = 0 then
1130 gfxlist[i].x := gfxlist[i].x - 1 + Random(3);
1131 if Random(2) = 0 then
1132 gfxlist[i].y := gfxlist[i].y - Random(2);
1133 end;
1134 end;
1135 end
1136 else
1137 gfxlist[i].typ := R_GFX_NONE;
1138 end;
1139 end;
1140 end;
1141 end;
1142
1143 procedure r_Map_DrawGFX (x, y, w, h: Integer);
1144 var i, fx, fy, typ: Integer; t: TGLMultiTexture; tex: TGLTexture;
1145 begin
1146 if gfxlist <> nil then
1147 begin
1148 for i := 0 to High(gfxlist) do
1149 begin
1150 if gfxlist[i].typ > 0 then
1151 begin
1152 typ := gfxlist[i].typ;
1153 t := GFXTextures[typ];
1154 if t <> nil then
1155 begin
1156 fx := nlerp(gfxlist[i].oldX, gfxlist[i].x, gLerpFactor);
1157 fy := nlerp(gfxlist[i].oldY, gfxlist[i].y, gLerpFactor);
1158 tex := t.GetTexture(gfxlist[i].frame);
1159 r_Draw_TextureRepeat(tex, fx, fy, tex.width, tex.height, false, 255, 255, 255, 255 - GFXAnim[typ].alpha, false);
1160 end;
1161 end;
1162 end;
1163 end;
1164 end;
1165
1166 procedure r_Map_DrawParticles (x, y, w, h: Integer);
1167 var i, fx, fy: Integer; factor: Single;
1168 begin
1169 if gpart_dbg_enabled and (Particles <> nil) then
1170 begin
1171 r_Draw_EnableTexture2D(false);
1172 factor := r_pixel_scale * g_dbg_scale;
1173 if factor < 0.6 then
1174 glPointSize(1)
1175 else if factor > 1.3 then
1176 glPointSize(factor + 1)
1177 else
1178 glPointSize(2);
1179 glDisable(GL_POINT_SMOOTH);
1180 glEnable(GL_BLEND);
1181 glBlendFunc(GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA);
1182
1183 r_Draw_SetColor(255, 255, 255, 255);
1184 glBegin(GL_POINTS);
1185 for i := 0 to High(Particles) do
1186 begin
1187 if Particles[i].alive then
1188 begin
1189 fx := nlerp(Particles[i].oldX, Particles[i].x, gLerpFactor);
1190 fy := nlerp(Particles[i].oldY, Particles[i].y, gLerpFactor);
1191 glColor4ub(Particles[i].red, Particles[i].green, Particles[i].blue, Particles[i].alpha);
1192 glVertex2i(fx, fy);
1193 end;
1194 end;
1195 glEnd;
1196 r_Draw_SetColor(0, 0, 0, 255);
1197
1198 glDisable(GL_BLEND);
1199 end;
1200 end;
1201 {$ENDIF}
1202
1203 procedure r_Map_DrawShots (x, y, w, h: Integer);
1204 var i, a, xx, yy, pX, pY, typ: Integer; count, frame: LongInt; t: TGLMultiTexture; tex: TGLTexture;
1205 begin
1206 if Shots <> nil then
1207 begin
1208 for i := 0 to High(Shots) do
1209 begin
1210 typ := Shots[i].ShotType;
1211 if typ <> 0 then
1212 begin
1213 t := ShotTextures[typ];
1214 if t <> nil then
1215 begin
1216 a := 0;
1217 case typ of
1218 WEAPON_ROCKETLAUNCHER, WEAPON_BARON_FIRE, WEAPON_MANCUB_FIRE, WEAPON_SKEL_FIRE:
1219 a := -GetAngle2(Shots[i].Obj.Vel.X, Shots[i].Obj.Vel.Y)
1220 end;
1221 r_Common_GetObjectPos(Shots[i].Obj, xx, yy);
1222 pX := Shots[i].Obj.Rect.Width div 2;
1223 pY := Shots[i].Obj.Rect.Height div 2;
1224 g_Anim_GetFrameByTime(ShotAnim[typ].anim, (gTime - Shots[i].time) DIV GAME_TICK, count, frame);
1225 tex := t.GetTexture(frame);
1226 r_Draw_TextureRepeatRotate(tex, xx, yy, tex.width, tex.height, false, 255, 255, 255, 255, false, pX, pY, a);
1227 if DebugFrames then
1228 begin
1229 r_Draw_Rect(
1230 xx + Shots[i].obj.rect.x, // Shots[i].obj.x + Shots[i].obj.rect.x,
1231 yy + Shots[i].obj.rect.y, // Shots[i].obj.y + Shots[i].obj.rect.y,
1232 xx + Shots[i].obj.rect.x + Shots[i].obj.rect.width, // Shots[i].obj.x + Shots[i].obj.rect.x + Shots[i].obj.rect.width,
1233 yy + Shots[i].obj.rect.y + Shots[i].obj.rect.height, // Shots[i].obj.y + Shots[i].obj.rect.y + Shots[i].obj.rect.height,
1234 0, 255, 0, 255
1235 );
1236 end;
1237 end;
1238 end;
1239 end;
1240 end;
1241 end;
1242
1243 procedure r_Map_DrawFlags (x, y, w, h: Integer);
1244 var i, dx, xx, yy: Integer; flip: Boolean; t: TGLMultiTexture; tex: TGLTexture;
1245 begin
1246 if gGameSettings.GameMode = GM_CTF then
1247 begin
1248 for i := FLAG_RED to FLAG_BLUE do
1249 begin
1250 if not (gFlags[i].state in [FLAG_STATE_NONE, FLAG_STATE_CAPTURED]) then
1251 begin
1252 r_Common_GetObjectPos(gFlags[i].Obj, xx, yy);
1253 flip := gFlags[i].Direction = TDirection.D_LEFT;
1254 if flip then dx := -1 else dx := +1;
1255 t := FlagTextures[i];
1256 tex := t.GetTexture(FlagFrame);
1257 r_Draw_TextureRepeat(tex, xx + dx, yy + 1, tex.width, tex.height, flip, 255, 255, 255, 255, false);
1258 if DebugFrames then
1259 begin
1260 r_Draw_Rect(
1261 xx + gFlags[i].obj.rect.x, // gFlags[i].obj.x + gFlags[i].obj.rect.x,
1262 yy + gFlags[i].obj.rect.y, // gFlags[i].obj.y + gFlags[i].obj.rect.y,
1263 xx + gFlags[i].obj.rect.x + gFlags[i].obj.rect.width, // gFlags[i].obj.x + gFlags[i].obj.rect.x + gFlags[i].obj.rect.width,
1264 yy + gFlags[i].obj.rect.y + gFlags[i].obj.rect.height, // gFlags[i].obj.y + gFlags[i].obj.rect.y + gFlags[i].obj.rect.height,
1265 0, 255, 0, 255
1266 );
1267 end;
1268 end;
1269 end;
1270 end;
1271 end;
1272
1273 {$IFDEF ENABLE_SHELLS}
1274 procedure r_Map_DrawShells (x, y, w, h: Integer);
1275 var i, xx, yy, typ: Integer; t: TGLTexture; p: PObj;
1276 begin
1277 if gShells <> nil then
1278 begin
1279 for i := 0 to High(gShells) do
1280 begin
1281 if gShells[i].alive then
1282 begin
1283 typ := gShells[i].SType;
1284 if typ <= SHELL_LAST then
1285 begin
1286 p := @gShells[i].Obj;
1287 if g_Obj_Collide(x, y, w, h, p) then
1288 begin
1289 t := ShellTextures[typ];
1290 if t <> nil then
1291 begin
1292 r_Common_GetObjectPos(p^, xx, yy);
1293 r_Draw_TextureRepeatRotate(t, xx, yy, t.width, t.height, false, 255, 255, 255, 255, false, ShellAnim[typ].dx, ShellAnim[typ].dy, gShells[i].RAngle);
1294 end;
1295 end;
1296 end;
1297 end;
1298 end;
1299 end;
1300 end;
1301 {$ENDIF}
1302
1303 procedure r_Map_CalcSkyParallax (cx, cy, vw, vh, sw, sh, mw, mh: LongInt; out x, y, w, h: LongInt);
1304 const
1305 factor = 120; (* size ratio between view and sky (120%) *)
1306 limit = 100; (* max speed for parallax *)
1307 var
1308 msw, msh, mvw, mvh, svw, svh: LongInt;
1309 begin
1310 msw := vw * factor div 100;
1311 msh := vh * factor div 100;
1312 r_Common_CalcAspect(sw, sh, msw, msh, (sw / sh) <= (msw / msh), w, h);
1313
1314 (* calc x parallax or sky center on speed limit *)
1315 mvw := MAX(1, mw - vw);
1316 svw := w - vw;
1317 if 100 * svw div mvw <= limit then
1318 x := -cx * svw div mvw
1319 else
1320 x := -svw div 2;
1321
1322 (* calc y parallax or sky center on speed limit *)
1323 mvh := MAX(1, mh - vh);
1324 svh := h - vh;
1325 if 100 * svh div mvh <= limit then
1326 y := -cy * svh div mvh
1327 else
1328 y := -svh div 2;
1329
1330 (* handle out of map bounds *)
1331 if x > 0 then x := 0;
1332 if y > 0 then y := 0;
1333 if x < -svw then x := -svw;
1334 if y < -svh then y := -svh;
1335 end;
1336
1337 procedure r_Map_DrawScreenEffect (x, y, w, h, level: Integer; r, g, b: Byte);
1338 var i: Integer;
1339 begin
1340 if level > 0 then
1341 begin
1342 case level of
1343 0..14: i := 0;
1344 15..34: i := 1;
1345 35..54: i := 2;
1346 55..74: i := 3;
1347 75..94: i := 4;
1348 else i := 5
1349 end;
1350 r_Draw_FillRect(x, y, x + w, y + h, r, g, b, i * 50)
1351 end;
1352 end;
1353
1354 procedure r_Map_DrawScreenEffects (x, y, w, h: Integer; p: TPlayer);
1355 begin
1356 if p <> nil then
1357 begin
1358 r_Map_DrawScreenEffect(x, y, w, h, p.pain, 255, 0, 0);
1359 r_Map_DrawScreenEffect(x, y, w, h, p.pickup, 150, 200, 150);
1360 if (p.FMegaRulez[MR_INVUL] >= gTime) and (p.SpawnInvul < gTime) then
1361 begin
1362 if ((p.FMegaRulez[MR_INVUL] - gTime) > 2100) or not ODD((p.FMegaRulez[MR_INVUL] - gTime) div 300) then
1363 r_Draw_InvertRect(x, y, x + w, y + h, 191, 191, 191, 255);
1364 end;
1365 if p.FMegaRulez[MR_SUIT] >= gTime then
1366 begin
1367 if ((p.FMegaRulez[MR_SUIT] - gTime) > 2100) or not ODD((p.FMegaRulez[MR_SUIT] - gTime) div 300) then
1368 r_Draw_FillRect(x, y, x + w, y + h, 0, 96, 0, 55);
1369 end;
1370 if (p.Berserk >= 0) and (p.Berserk >= gTime) and (gFlash = 2) then
1371 begin
1372 r_Draw_FillRect(x, y, x + w, y + h, 255, 0, 0, 55);
1373 end;
1374 end;
1375 end;
1376
1377 procedure r_Map_DrawIndicator (p: TPlayer; color: TRGB; cx, cy, cw, ch: Integer);
1378 var a, ax, ay, fx, fy, xx, yy: Integer;
1379 begin
1380 if (p <> nil) and p.Alive and (p.Spectator = false) then
1381 begin
1382 r_Common_GetPlayerPos(p, fx, fy);
1383 case gPlayerIndicatorStyle of
1384 0:
1385 if IndicatorTexture <> nil then
1386 begin
1387 ax := IndicatorTexture.width div 2;
1388 ay := IndicatorTexture.height div 2;
1389 if (p.obj.x + p.obj.rect.x) < cx then
1390 begin
1391 a := 90;
1392 xx := fx + p.obj.rect.x + p.obj.rect.width;
1393 yy := fy + p.obj.rect.y + (p.obj.rect.height - IndicatorTexture.width) div 2;
1394 end
1395 else if (p.obj.x + p.obj.rect.x + p.obj.rect.width) > (cx + cw) then
1396 begin
1397 a := 270;
1398 xx := fx + p.obj.rect.x - IndicatorTexture.height;
1399 yy := fy + p.obj.rect.y - (p.obj.rect.height - IndicatorTexture.width) div 2;
1400 end
1401 else if (p.obj.y - IndicatorTexture.height) < cy then
1402 begin
1403 a := 180;
1404 xx := fx + p.obj.rect.x + (p.obj.rect.width - IndicatorTexture.width) div 2;
1405 yy := fy + p.obj.rect.y + p.obj.rect.height;
1406 end
1407 else
1408 begin
1409 a := 0;
1410 xx := fx + p.obj.rect.x + (p.obj.rect.width - IndicatorTexture.width) div 2;
1411 yy := fy - IndicatorTexture.height;
1412 end;
1413 xx := MIN(MAX(xx, cx), cx + cw - IndicatorTexture.width);
1414 yy := MIN(MAX(yy, cy), cy + ch - IndicatorTexture.height);
1415 r_Draw_TextureRepeatRotate(IndicatorTexture, xx, yy, IndicatorTexture.width, IndicatorTexture.height, false, color.r, color.g, color.b, 255, false, ax, ay, a);
1416 end;
1417 1:
1418 begin
1419 xx := fx + p.obj.rect.x + p.obj.rect.width div 2;
1420 yy := fy;
1421 r_Common_DrawText(p.Name, xx, yy, color.r, color.g, color.b, 255, stdfont, TBasePoint.BP_DOWN);
1422 end;
1423 end;
1424 end;
1425 end;
1426
1427 procedure r_Map_DrawPlayerIndicators (player: TPlayer; cx, cy, cw, ch: Integer);
1428 var i: Integer; p: TPlayer;
1429 begin
1430 case gPlayerIndicator of
1431 1:
1432 if player <> nil then
1433 begin
1434 r_Map_DrawIndicator(player, _RGB(255, 255, 255), cx, cy, cw, ch);
1435 end;
1436 2:
1437 if gPlayers <> nil then
1438 begin
1439 for i := 0 to HIGH(gPlayers) do
1440 begin
1441 p := gPlayers[i];
1442 if p <> nil then
1443 begin
1444 if (player <> nil) and (p = player) then
1445 begin
1446 r_Map_DrawIndicator(p, _RGB(255, 255, 255), cx, cy, cw, ch);
1447 end
1448 else if (player = nil) or ((p.Team = player.Team) and (p.Team <> TEAM_NONE)) then
1449 begin
1450 case gPlayerIndicatorStyle of
1451 0: r_Map_DrawIndicator(p, p.GetColor(), cx, cy, cw, ch);
1452 1: r_Map_DrawIndicator(p, _RGB(192, 192, 192), cx, cy, cw, ch);
1453 end;
1454 end;
1455 end;
1456 end;
1457 end;
1458 end;
1459 end;
1460
1461 procedure r_Map_DrawGame (xx, yy, ww, hh: Integer; player: TPlayer);
1462 (* xx/yy/ww/hh are in map units *)
1463 var iter: TPanelGrid.Iter; p: PPanel;
1464 begin
1465 plist.Clear;
1466 iter := mapGrid.ForEachInAABB(xx, yy, ww, hh, GridDrawableMask);
1467 for p in iter do
1468 if ((p^.tag and GridTagDoor) <> 0) = p^.door then
1469 plist.Insert(p^);
1470 iter.Release;
1471
1472 r_Map_DrawPanelType(PANEL_BACK);
1473 r_Map_DrawPanelType(PANEL_STEP);
1474 r_Map_DrawItems(xx, yy, ww, hh, false);
1475 r_Map_DrawShots(xx, yy, ww, hh);
1476 {$IFDEF ENABLE_SHELLS}
1477 r_Map_DrawShells(xx, yy, ww, hh);
1478 {$ENDIF}
1479 r_Map_DrawPlayers(xx, yy, ww, hh, player);
1480 {$IFDEF ENABLE_GIBS}
1481 r_Map_DrawGibs(xx, yy, ww, hh);
1482 {$ENDIF}
1483 {$IFDEF ENABLE_CORPSES}
1484 r_Map_DrawCorpses(xx, yy, ww, hh);
1485 {$ENDIF}
1486 r_Map_DrawPanelType(PANEL_WALL);
1487 r_Map_DrawMonsters(xx, yy, ww, hh);
1488 r_Map_DrawItems(xx, yy, ww, hh, true);
1489 r_Map_DrawPanelType(PANEL_CLOSEDOOR);
1490 {$IFDEF ENABLE_GFX}
1491 r_Map_DrawParticles(xx, yy, ww, hh);
1492 r_Map_DrawGFX(xx, yy, ww, hh);
1493 {$ENDIF}
1494 r_Map_DrawFlags(xx, yy, ww, hh);
1495 r_Map_DrawPanelType(PANEL_ACID1);
1496 r_Map_DrawPanelType(PANEL_ACID2);
1497 r_Map_DrawPanelType(PANEL_WATER);
1498 r_Map_DrawPanelType(PANEL_FORE);
1499 // TODO draw monsters health bar
1500 // TODO draw players health bar
1501 end;
1502
1503 procedure r_Map_DrawScaled (w, h, camx, camy: Integer; player: TPlayer; out acx, acy, acw, ach, axx, ayy, aww, ahh: Integer);
1504 (* w/h/camx/camy are in map units (scaled) *)
1505 const limit = 32767;
1506 var cx, cy, cw, ch, xx, yy, ww, hh{, ml, mt, mr, mb}: Integer; sx, sy, sw, sh: LongInt;
1507 begin
1508 (* camera rect *)
1509 cx := camx - w div 2;
1510 cy := camy - h div 2;
1511 cw := w;
1512 ch := h;
1513
1514 (* camera bounds *)
1515 if g_dbg_ignore_bounds = false then
1516 begin
1517 if w > gMapInfo.Width then
1518 cx := gMapInfo.Width div 2 - w div 2
1519 else if cx + cw > gMapInfo.Width then
1520 cx := gMapInfo.Width - cw
1521 else if cx < 0 then
1522 cx := 0;
1523
1524 if h > gMapInfo.Height then
1525 cy := gMapInfo.Height div 2 - h div 2
1526 else if cy + ch > gMapInfo.Height then
1527 cy := gMapInfo.Height - ch
1528 else if cy < 0 then
1529 cy := 0;
1530 end;
1531
1532 acx := cx;
1533 acy := cy;
1534 acw := cw;
1535 ach := ch;
1536
1537 (* map bounds *)
1538 xx := cx;
1539 yy := cy;
1540 ww := cw;
1541 hh := ch;
1542 if xx + ww > gMapInfo.Width then
1543 xx := gMapInfo.Width - ww;
1544 if yy + hh > gMapInfo.Height then
1545 yy := gMapInfo.Height - hh;
1546 if xx < 0 then
1547 xx := 0;
1548 if yy < 0 then
1549 yy := 0;
1550 axx := xx;
1551 ayy := yy;
1552 aww := ww;
1553 ahh := hh;
1554
1555 {
1556 (* view bounds *)
1557 ml := x; mt := y; mr := x + w; mb := y + h;
1558 if FillOutsizeArea and (DebugCameraScale = 1.0) then
1559 begin
1560 ml := MAX(cx + ml, 0) - cx;
1561 mt := MAX(cy + mt, 0) - cy;
1562 mr := MIN(cx + mr, gMapInfo.Width - 1) - cx;
1563 mb := MIN(cy + mb, gMapInfo.Height - 1) - cy;
1564 end;
1565 r_Draw_SetRect(ml, mt, mr, mb);
1566 }
1567
1568 if DebugCameraScale <> 1.0 then
1569 begin
1570 glTranslatef(cw div 2, ch div 2, 0);
1571 glScalef(DebugCameraScale, DebugCameraScale, 1);
1572 glTranslatef(-w div 2, -h div 2, 0);
1573 end;
1574
1575 if SkyTexture <> nil then
1576 begin
1577 r_Map_CalcSkyParallax(cx, cy, w, h, SkyTexture.width, SkyTexture.height, gMapInfo.Width, gMapInfo.Height, sx, sy, sw, sh);
1578 r_Draw_Texture(SkyTexture, sx, sy, sw, sh, false, 255, 255, 255, 255, false);
1579 end;
1580
1581 glTranslatef(-cx, -cy, 0);
1582 r_Map_DrawGame(xx, yy, ww, hh, player);
1583 if FillOutsizeArea and (DebugCameraScale = 1.0) then
1584 begin
1585 (* top *) r_Draw_FillRect(0 - limit, 0 - limit, gMapInfo.Width + limit, 0, 0, 0, 0, 255);
1586 (* left *) r_Draw_FillRect(0 - limit, 0, 0, gMapInfo.Height + limit, 0, 0, 0, 255);
1587 (* right *) r_Draw_FillRect(gMapInfo.Width, 0, gMapInfo.Width + limit, gMapInfo.Height + limit, 0, 0, 0, 255);
1588 (* bottom *) r_Draw_FillRect(0 - limit, gMapInfo.Height, gMapInfo.Width + limit, gMapInfo.Height + limit, 0, 0, 0, 255);
1589 end;
1590 glTranslatef(cx, cy, 0);
1591 end;
1592
1593 procedure r_Map_Draw (x, y, w, h, camx, camy: Integer; player: TPlayer; out acx, acy: Integer);
1594 var cx, cy, cw, ch, xx, yy, ww, hh, ml, mt, mr, mb, mcx, mcy: Integer; l, t, r, b: Integer;
1595 begin
1596 glPushMatrix;
1597 r_Draw_GetRect(l, t, r, b);
1598 glTranslatef(x, y, 0);
1599 glScalef(g_dbg_scale, g_dbg_scale, 0);
1600
1601 r_Draw_SetRect(x, y, x + w, y + h);
1602 r_Map_DrawScaled(Round(w / g_dbg_scale), Round(h / g_dbg_scale), camx, camy, player, cx, cy, cw, ch, xx, yy, ww, hh);
1603 acx := cx;
1604 acy := cy;
1605 r_Draw_SetRect(x, y, x + w, y + h);
1606
1607 if DebugCameraScale <> 1.0 then
1608 begin
1609 r_Draw_Rect(0, 0, cw, ch, 0, 255, 0, 255);
1610 r_Draw_Rect(-cx + xx, -cy + yy, -cx + xx + ww, -cy + yy + hh, 255, 0, 0, 255);
1611 end;
1612
1613 if gGameSettings.GameMode <> GM_SINGLE then
1614 begin
1615 glTranslatef(-cx, -cy, 0);
1616 r_Map_DrawPlayerIndicators(player, cx, cy, cw, ch);
1617 end;
1618
1619 // TODO draw g_debug_player
1620
1621 //glTranslatef(-x, -y, 0);
1622 r_Draw_SetRect(l, t, r, b);
1623 glPopMatrix;
1624
1625 r_Map_DrawScreenEffects(x, y, w, h, player);
1626 end;
1627
1628 procedure r_Map_Reset;
1629 begin
1630 {$IFDEF ENABLE_GFX}
1631 r_Map_ResetGFX;
1632 {$ENDIF}
1633 end;
1634
1635 procedure r_Map_Update;
1636 var i, count, tick: LongInt;
1637 begin
1638 tick := gTime div GAME_TICK;
1639 for i := 0 to ITEM_LAST do
1640 g_Anim_GetFrameByTime(ItemAnim[i].anim, tick, count, Items[i].frame);
1641 r_Map_UpdateGFX(tick);
1642 g_Anim_GetFrameByTime(FlagAnim, tick, count, FlagFrame);
1643 end;
1644
1645 initialization
1646 conRegVar('r_debug_camera_scale', @DebugCameraScale, 0.0001, 1000.0, '', '');
1647 conRegVar('r_gl_fill_outside', @FillOutsizeArea, '', '');
1648 conRegVar('d_frames', @DebugFrames, '', '');
1649 DebugCameraScale := 1.0;
1650 FillOutsizeArea := true;
1651 DebugFrames := false;
1652 end.
[MIRROR] a port of Doom 2D Forever to FPC/SDL
[25/02/2024 19:55:35]
DEADSOFTWARE 2012-2024